lib/commit.tcl

   1 # git-gui misc. commit reading/writing support
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 proc load_last_commit {} {
   5         global HEAD PARENT MERGE_HEAD commit_type ui_comm
   6         global repo_config
   7
   8         if {[llength $PARENT] == 0} {
   9                 error_popup {There is nothing to amend.
  10
  11 You are about to create the initial commit.  There is no commit before this to amend.
  12 }
  13                 return
  14         }
  15
  16         repository_state curType curHEAD curMERGE_HEAD
  17         if {$curType eq {merge}} {
  18                 error_popup {Cannot amend while merging.
  19
  20 You are currently in the middle of a merge that has not been fully completed.  You cannot amend the prior commit unless you first abort the current merge activity.
  21 }
  22                 return
  23         }
  24
  25         set msg {}
  26         set parents [list]
  27         if {[catch {
  28                         set fd [git_read cat-file commit $curHEAD]
  29                         fconfigure $fd -encoding binary -translation lf
  30                         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
  31                                 set enc utf-8
  32                         }
  33                         while {[gets $fd line] > 0} {
  34                                 if {[string match {parent *} $line]} {
  35                                         lappend parents [string range $line 7 end]
  36                                 } elseif {[string match {encoding *} $line]} {
  37                                         set enc [string tolower [string range $line 9 end]]
  38                                 }
  39                         }
  40                         set msg [encoding convertfrom $enc [read $fd]]
  41                         set msg [string trim $msg]
  42                         close $fd
  43                 } err]} {
  44                 error_popup "Error loading commit data for amend:\n\n$err"
  45                 return
  46         }
  47
  48         set HEAD $curHEAD
  49         set PARENT $parents
  50         set MERGE_HEAD [list]
  51         switch -- [llength $parents] {
  52         0       {set commit_type amend-initial}
  53         1       {set commit_type amend}
  54         default {set commit_type amend-merge}
  55         }
  56
  57         $ui_comm delete 0.0 end
  58         $ui_comm insert end $msg
  59         $ui_comm edit reset
  60         $ui_comm edit modified false
  61         rescan ui_ready
  62 }
  63
  64 set GIT_COMMITTER_IDENT {}
  65
  66 proc committer_ident {} {
  67         global GIT_COMMITTER_IDENT
  68
  69         if {$GIT_COMMITTER_IDENT eq {}} {
  70                 if {[catch {set me [git var GIT_COMMITTER_IDENT]} err]} {
  71                         error_popup "Unable to obtain your identity:\n\n$err"
  72                         return {}
  73                 }
  74                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
  75                         $me me GIT_COMMITTER_IDENT]} {
  76                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
  77                         return {}
  78                 }
  79         }
  80
  81         return $GIT_COMMITTER_IDENT
  82 }
  83
  84 proc do_signoff {} {
  85         global ui_comm
  86
  87         set me [committer_ident]
  88         if {$me eq {}} return
  89
  90         set sob "Signed-off-by: $me"
  91         set last [$ui_comm get {end -1c linestart} {end -1c}]
  92         if {$last ne $sob} {
  93                 $ui_comm edit separator
  94                 if {$last ne {}
  95                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
  96                         $ui_comm insert end "\n"
  97                 }
  98                 $ui_comm insert end "\n$sob"
  99                 $ui_comm edit separator
 100                 $ui_comm see end
 101         }
 102 }
 103
 104 proc create_new_commit {} {
 105         global commit_type ui_comm
 106
 107         set commit_type normal
 108         $ui_comm delete 0.0 end
 109         $ui_comm edit reset
 110         $ui_comm edit modified false
 111         rescan ui_ready
 112 }
 113
 114 proc commit_tree {} {
 115         global HEAD commit_type file_states ui_comm repo_config
 116         global pch_error
 117
 118         if {[committer_ident] eq {}} return
 119         if {![lock_index update]} return
 120
 121         # -- Our in memory state should match the repository.
 122         #
 123         repository_state curType curHEAD curMERGE_HEAD
 124         if {[string match amend* $commit_type]
 125                 && $curType eq {normal}
 126                 && $curHEAD eq $HEAD} {
 127         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 128                 info_popup {Last scanned state does not match repository state.
 129
 130 Another Git program has modified this repository since the last scan.  A rescan must be performed before another commit can be created.
 131
 132 The rescan will be automatically started now.
 133 }
 134                 unlock_index
 135                 rescan ui_ready
 136                 return
 137         }
 138
 139         # -- At least one file should differ in the index.
 140         #
 141         set files_ready 0
 142         foreach path [array names file_states] {
 143                 switch -glob -- [lindex $file_states($path) 0] {
 144                 _? {continue}
 145                 A? -
 146                 D? -
 147                 M? {set files_ready 1}
 148                 U? {
 149                         error_popup "Unmerged files cannot be committed.
 150
 151 File [short_path $path] has merge conflicts.  You must resolve them and add the file before committing.
 152 "
 153                         unlock_index
 154                         return
 155                 }
 156                 default {
 157                         error_popup "Unknown file state [lindex $s 0] detected.
 158
 159 File [short_path $path] cannot be committed by this program.
 160 "
 161                 }
 162                 }
 163         }
 164         if {!$files_ready && ![string match *merge $curType]} {
 165                 info_popup {No changes to commit.
 166
 167 You must add at least 1 file before you can commit.
 168 }
 169                 unlock_index
 170                 return
 171         }
 172
 173         # -- A message is required.
 174         #
 175         set msg [string trim [$ui_comm get 1.0 end]]
 176         regsub -all -line {[ \t\r]+$} $msg {} msg
 177         if {$msg eq {}} {
 178                 error_popup {Please supply a commit message.
 179
 180 A good commit message has the following format:
 181
 182 - First line: Describe in one sentance what you did.
 183 - Second line: Blank
 184 - Remaining lines: Describe why this change is good.
 185 }
 186                 unlock_index
 187                 return
 188         }
 189
 190         # -- Run the pre-commit hook.
 191         #
 192         set pchook [gitdir hooks pre-commit]
 193
 194         # On Cygwin [file executable] might lie so we need to ask
 195         # the shell if the hook is executable.  Yes that's annoying.
 196         #
 197         if {[is_Cygwin] && [file isfile $pchook]} {
 198                 set pchook [list sh -c [concat \
 199                         "if test -x \"$pchook\";" \
 200                         "then exec \"$pchook\" 2>&1;" \
 201                         "fi"]]
 202         } elseif {[file executable $pchook]} {
 203                 set pchook [list $pchook |& cat]
 204         } else {
 205                 commit_writetree $curHEAD $msg
 206                 return
 207         }
 208
 209         ui_status {Calling pre-commit hook...}
 210         set pch_error {}
 211         set fd_ph [open "| $pchook" r]
 212         fconfigure $fd_ph -blocking 0 -translation binary
 213         fileevent $fd_ph readable \
 214                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 215 }
 216
 217 proc commit_prehook_wait {fd_ph curHEAD msg} {
 218         global pch_error
 219
 220         append pch_error [read $fd_ph]
 221         fconfigure $fd_ph -blocking 1
 222         if {[eof $fd_ph]} {
 223                 if {[catch {close $fd_ph}]} {
 224                         ui_status {Commit declined by pre-commit hook.}
 225                         hook_failed_popup pre-commit $pch_error
 226                         unlock_index
 227                 } else {
 228                         commit_writetree $curHEAD $msg
 229                 }
 230                 set pch_error {}
 231                 return
 232         }
 233         fconfigure $fd_ph -blocking 0
 234 }
 235
 236 proc commit_writetree {curHEAD msg} {
 237         ui_status {Committing changes...}
 238         set fd_wt [git_read write-tree]
 239         fileevent $fd_wt readable \
 240                 [list commit_committree $fd_wt $curHEAD $msg]
 241 }
 242
 243 proc commit_committree {fd_wt curHEAD msg} {
 244         global HEAD PARENT MERGE_HEAD commit_type
 245         global current_branch
 246         global ui_comm selected_commit_type
 247         global file_states selected_paths rescan_active
 248         global repo_config
 249
 250         gets $fd_wt tree_id
 251         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
 252                 error_popup "write-tree failed:\n\n$err"
 253                 ui_status {Commit failed.}
 254                 unlock_index
 255                 return
 256         }
 257
 258         # -- Verify this wasn't an empty change.
 259         #
 260         if {$commit_type eq {normal}} {
 261                 set fd_ot [open "| git cat-file commit $PARENT" r]
 262                 fconfigure $fd_ot -encoding binary -translation lf
 263                 set old_tree [gets $fd_ot]
 264                 close $fd_ot
 265
 266                 if {[string equal -length 5 {tree } $old_tree]
 267                         && [string length $old_tree] == 45} {
 268                         set old_tree [string range $old_tree 5 end]
 269                 } else {
 270                         error "Commit $PARENT appears to be corrupt"
 271                 }
 272
 273                 if {$tree_id eq $old_tree} {
 274                         info_popup {No changes to commit.
 275
 276 No files were modified by this commit and it was not a merge commit.
 277
 278 A rescan will be automatically started now.
 279 }
 280                         unlock_index
 281                         rescan {ui_status {No changes to commit.}}
 282                         return
 283                 }
 284         }
 285
 286         # -- Build the message.
 287         #
 288         set msg_p [gitdir COMMIT_EDITMSG]
 289         set msg_wt [open $msg_p w]
 290         if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 291                 set enc utf-8
 292         }
 293         fconfigure $msg_wt -encoding binary -translation binary
 294         puts -nonewline $msg_wt [encoding convertto $enc $msg]
 295         close $msg_wt
 296
 297         # -- Create the commit.
 298         #
 299         set cmd [list commit-tree $tree_id]
 300         foreach p [concat $PARENT $MERGE_HEAD] {
 301                 lappend cmd -p $p
 302         }
 303         lappend cmd <$msg_p
 304         if {[catch {set cmt_id [eval git $cmd]} err]} {
 305                 error_popup "commit-tree failed:\n\n$err"
 306                 ui_status {Commit failed.}
 307                 unlock_index
 308                 return
 309         }
 310
 311         # -- Update the HEAD ref.
 312         #
 313         set reflogm commit
 314         if {$commit_type ne {normal}} {
 315                 append reflogm " ($commit_type)"
 316         }
 317         set i [string first "\n" $msg]
 318         if {$i >= 0} {
 319                 set subject [string range $msg 0 [expr {$i - 1}]]
 320         } else {
 321                 set subject $msg
 322         }
 323         append reflogm {: } $subject
 324         if {[catch {
 325                         git update-ref -m $reflogm HEAD $cmt_id $curHEAD
 326                 } err]} {
 327                 error_popup "update-ref failed:\n\n$err"
 328                 ui_status {Commit failed.}
 329                 unlock_index
 330                 return
 331         }
 332
 333         # -- Cleanup after ourselves.
 334         #
 335         catch {file delete $msg_p}
 336         catch {file delete [gitdir MERGE_HEAD]}
 337         catch {file delete [gitdir MERGE_MSG]}
 338         catch {file delete [gitdir SQUASH_MSG]}
 339         catch {file delete [gitdir GITGUI_MSG]}
 340
 341         # -- Let rerere do its thing.
 342         #
 343         if {[get_config rerere.enabled] eq {}} {
 344                 set rerere [file isdirectory [gitdir rr-cache]]
 345         } else {
 346                 set rerere [is_config_true rerere.enabled]
 347         }
 348         if {$rerere} {
 349                 catch {git rerere}
 350         }
 351
 352         # -- Run the post-commit hook.
 353         #
 354         set pchook [gitdir hooks post-commit]
 355         if {[is_Cygwin] && [file isfile $pchook]} {
 356                 set pchook [list sh -c [concat \
 357                         "if test -x \"$pchook\";" \
 358                         "then exec \"$pchook\";" \
 359                         "fi"]]
 360         } elseif {![file executable $pchook]} {
 361                 set pchook {}
 362         }
 363         if {$pchook ne {}} {
 364                 catch {exec $pchook &}
 365         }
 366
 367         $ui_comm delete 0.0 end
 368         $ui_comm edit reset
 369         $ui_comm edit modified false
 370
 371         if {[is_enabled singlecommit]} do_quit
 372
 373         # -- Update in memory status
 374         #
 375         set selected_commit_type new
 376         set commit_type normal
 377         set HEAD $cmt_id
 378         set PARENT $cmt_id
 379         set MERGE_HEAD [list]
 380
 381         foreach path [array names file_states] {
 382                 set s $file_states($path)
 383                 set m [lindex $s 0]
 384                 switch -glob -- $m {
 385                 _O -
 386                 _M -
 387                 _D {continue}
 388                 __ -
 389                 A_ -
 390                 M_ -
 391                 D_ {
 392                         unset file_states($path)
 393                         catch {unset selected_paths($path)}
 394                 }
 395                 DO {
 396                         set file_states($path) [list _O [lindex $s 1] {} {}]
 397                 }
 398                 AM -
 399                 AD -
 400                 MM -
 401                 MD {
 402                         set file_states($path) [list \
 403                                 _[string index $m 1] \
 404                                 [lindex $s 1] \
 405                                 [lindex $s 3] \
 406                                 {}]
 407                 }
 408                 }
 409         }
 410
 411         display_all_files
 412         unlock_index
 413         reshow_diff
 414         ui_status "Created commit [string range $cmt_id 0 7]: $subject"
 415 }