t/t7519/fsmonitor-watchman

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use IPC::Open2;
   6
   7 # An example hook script to integrate Watchman
   8 # (https://facebook.github.io/watchman/) with git to speed up detecting
   9 # new and modified files.
  10 #
  11 # The hook is passed a version (currently 1) and a time in nanoseconds
  12 # formatted as a string and outputs to stdout all files that have been
  13 # modified since the given time. Paths must be relative to the root of
  14 # the working tree and separated by a single NUL.
  15 #
  16 # To enable this hook, rename this file to "query-watchman" and set
  17 # 'git config core.fsmonitor .git/hooks/query-watchman'
  18 #
  19 my ($version, $time) = @ARGV;
  20 #print STDERR "$0 $version $time\n";
  21
  22 # Check the hook interface version
  23
  24 if ($version == 1) {
  25         # convert nanoseconds to seconds
  26         $time = int $time / 1000000000;
  27 } else {
  28         die "Unsupported query-fsmonitor hook version '$version'.\n" .
  29             "Falling back to scanning...\n";
  30 }
  31
  32 # Convert unix style paths to escaped Windows style paths when running
  33 # in Windows command prompt
  34
  35 my $system = `uname -s`;
  36 $system =~ s/[\r\n]+//g;
  37 my $git_work_tree;
  38
  39 if ($system =~ m/^MSYS_NT/ || $system =~ m/^MINGW/) {
  40         $git_work_tree = `cygpath -aw "\$PWD"`;
  41         $git_work_tree =~ s/[\r\n]+//g;
  42         $git_work_tree =~ s,\\,/,g;
  43 } else {
  44         $git_work_tree = $ENV{'PWD'};
  45 }
  46
  47 my $retry = 1;
  48
  49 launch_watchman();
  50
  51 sub launch_watchman {
  52
  53         # Set input record separator
  54         local $/ = 0666;
  55
  56         my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'watchman -j')
  57             or die "open2() failed: $!\n" .
  58             "Falling back to scanning...\n";
  59
  60         # In the query expression below we're asking for names of files that
  61         # changed since $time but were not transient (ie created after
  62         # $time but no longer exist).
  63         #
  64         # To accomplish this, we're using the "since" generator to use the
  65         # recency index to select candidate nodes and "fields" to limit the
  66         # output to file names only. Then we're using the "expression" term to
  67         # further constrain the results.
  68         #
  69         # The category of transient files that we want to ignore will have a
  70         # creation clock (cclock) newer than $time_t value and will also not
  71         # currently exist.
  72
  73         my $query = <<" END";
  74                 ["query", "$git_work_tree", {
  75                         "since": $time,
  76                         "fields": ["name"],
  77                         "expression": ["not", ["allof", ["since", $time, "cclock"], ["not", "exists"]]]
  78                 }]
  79         END
  80
  81         open (my $fh, ">", ".git/watchman-query.json");
  82         print $fh $query;
  83         close $fh;
  84
  85         print CHLD_IN $query;
  86         my $response = <CHLD_OUT>;
  87
  88         open ($fh, ">", ".git/watchman-response.json");
  89         print $fh $response;
  90         close $fh;
  91
  92         die "Watchman: command returned no output.\n" .
  93             "Falling back to scanning...\n" if $response eq "";
  94         die "Watchman: command returned invalid output: $response\n" .
  95             "Falling back to scanning...\n" unless $response =~ /^\{/;
  96
  97         my $json_pkg;
  98         eval {
  99                 require JSON::XS;
 100                 $json_pkg = "JSON::XS";
 101                 1;
 102         } or do {
 103                 require JSON::PP;
 104                 $json_pkg = "JSON::PP";
 105         };
 106
 107         my $o = $json_pkg->new->utf8->decode($response);
 108
 109         if ($retry > 0 and $o->{error} and $o->{error} =~ m/unable to resolve root .* directory (.*) is not watched/) {
 110                 print STDERR "Adding '$git_work_tree' to watchman's watch list.\n";
 111                 $retry--;
 112                 qx/watchman watch "$git_work_tree"/;
 113                 die "Failed to make watchman watch '$git_work_tree'.\n" .
 114                     "Falling back to scanning...\n" if $? != 0;
 115
 116                 # Watchman will always return all files on the first query so
 117                 # return the fast "everything is dirty" flag to git and do the
 118                 # Watchman query just to get it over with now so we won't pay
 119                 # the cost in git to look up each individual file.
 120
 121                 open ($fh, ">", ".git/watchman-output.out");
 122                 print "/\0";
 123                 close $fh;
 124
 125                 print "/\0";
 126                 eval { launch_watchman() };
 127                 exit 0;
 128         }
 129
 130         die "Watchman: $o->{error}.\n" .
 131             "Falling back to scanning...\n" if $o->{error};
 132
 133         open ($fh, ">", ".git/watchman-output.out");
 134         print $fh @{$o->{files}};
 135         close $fh;
 136
 137         binmode STDOUT, ":utf8";
 138         local $, = "\0";
 139         print @{$o->{files}};
 140 }