git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use File::Basename qw/dirname basename/;
  15 use File::Path qw/mkpath/;
  16 use File::Spec;
  17 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  18 use Memoize;
  19
  20 use Git::SVN;
  21 use Git::SVN::Editor;
  22 use Git::SVN::Fetcher;
  23 use Git::SVN::Ra;
  24 use Git::SVN::Prompt;
  25 use Git::SVN::Log;
  26 use Git::SVN::Migration;
  27
  28 use Git::SVN::Utils qw(
  29         fatal
  30         can_compress
  31         canonicalize_path
  32         canonicalize_url
  33         join_paths
  34         add_path_to_url
  35         join_paths
  36 );
  37
  38 use Git qw(
  39         git_cmd_try
  40         command
  41         command_oneline
  42         command_noisy
  43         command_output_pipe
  44         command_close_pipe
  45         command_bidi_pipe
  46         command_close_bidi_pipe
  47         get_record
  48 );
  49
  50 BEGIN {
  51         Memoize::memoize 'Git::config';
  52         Memoize::memoize 'Git::config_bool';
  53 }
  54
  55
  56 # From which subdir have we been invoked?
  57 my $cmd_dir_prefix = eval {
  58         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  59 } || '';
  60
  61 $Git::SVN::Ra::_log_window_size = 100;
  62
  63 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  64         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  65 }
  66
  67 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  68         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  69         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  70 }
  71
  72 $Git::SVN::Log::TZ = $ENV{TZ};
  73 $ENV{TZ} = 'UTC';
  74 $| = 1; # unbuffer STDOUT
  75
  76 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  77 # repository decides to close the connection which we expect to be kept alive.
  78 $SIG{PIPE} = 'IGNORE';
  79
  80 # Given a dot separated version number, "subtract" it from
  81 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  82 # is at least at the version the caller asked for.
  83 sub compare_svn_version {
  84         my (@ours) = split(/\./, $SVN::Core::VERSION);
  85         my (@theirs) = split(/\./, $_[0]);
  86         my ($i, $diff);
  87
  88         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  89                 $diff = $ours[$i] - $theirs[$i];
  90                 return $diff if ($diff);
  91         }
  92         return 1 if ($i < @ours);
  93         return -1 if ($i < @theirs);
  94         return 0;
  95 }
  96
  97 sub _req_svn {
  98         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  99         require SVN::Ra;
 100         require SVN::Delta;
 101         if (::compare_svn_version('1.1.0') < 0) {
 102                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 103         }
 104 }
 105
 106 $sha1 = qr/[a-f\d]{40}/;
 107 $sha1_short = qr/[a-f\d]{4,40}/;
 108 my ($_stdin, $_help, $_edit,
 109         $_message, $_file, $_branch_dest,
 110         $_template, $_shared,
 111         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 112         $_before, $_after,
 113         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
 114         $_prefix, $_no_checkout, $_url, $_verbose,
 115         $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
 116
 117 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 118 sub opt_prefix { return $_prefix || '' }
 119
 120 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 121 $_q ||= 0;
 122 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 123                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 124                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 125                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 126                     'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 127                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 128 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 129                 'authors-file|A=s' => \$_authors,
 130                 'authors-prog=s' => \$_authors_prog,
 131                 'repack:i' => \$Git::SVN::_repack,
 132                 'noMetadata' => \$Git::SVN::_no_metadata,
 133                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 134                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 135                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 136                 'no-checkout' => \$_no_checkout,
 137                 'quiet|q+' => \$_q,
 138                 'repack-flags|repack-args|repack-opts=s' =>
 139                    \$Git::SVN::_repack_flags,
 140                 'use-log-author' => \$Git::SVN::_use_log_author,
 141                 'add-author-from' => \$Git::SVN::_add_author_from,
 142                 'localtime' => \$Git::SVN::_localtime,
 143                 %remote_opts );
 144
 145 my ($_trunk, @_tags, @_branches, $_stdlayout);
 146 my %icv;
 147 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 148                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 149                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 150                   'stdlayout|s' => \$_stdlayout,
 151                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 152                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 153                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 154                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 155                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 156                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 157                   %remote_opts );
 158 my %cmt_opts = ( 'edit|e' => \$_edit,
 159                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 160                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 161                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 162                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 163 );
 164
 165 my %cmd = (
 166         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 167                         { 'revision|r=s' => \$_revision,
 168                           'fetch-all|all' => \$_fetch_all,
 169                           'parent|p' => \$_fetch_parent,
 170                            %fc_opts } ],
 171         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 172                         { 'revision|r=s' => \$_revision,
 173                           'preserve-empty-dirs' =>
 174                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 175                           'placeholder-filename=s' =>
 176                                 \$Git::SVN::Fetcher::_placeholder_filename,
 177                            %fc_opts, %init_opts } ],
 178         init => [ \&cmd_init, "Initialize a repo for tracking" .
 179                           " (requires URL argument)",
 180                           \%init_opts ],
 181         'multi-init' => [ \&cmd_multi_init,
 182                           "Deprecated alias for ".
 183                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 184                           \%init_opts ],
 185         dcommit => [ \&cmd_dcommit,
 186                      'Commit several diffs to merge with upstream',
 187                         { 'merge|m|M' => \$_merge,
 188                           'strategy|s=s' => \$_strategy,
 189                           'verbose|v' => \$_verbose,
 190                           'dry-run|n' => \$_dry_run,
 191                           'fetch-all|all' => \$_fetch_all,
 192                           'commit-url=s' => \$_commit_url,
 193                           'set-svn-props=s' => \$_set_svn_props,
 194                           'revision|r=i' => \$_revision,
 195                           'no-rebase' => \$_no_rebase,
 196                           'mergeinfo=s' => \$_merge_info,
 197                           'interactive|i' => \$_interactive,
 198                         %cmt_opts, %fc_opts } ],
 199         branch => [ \&cmd_branch,
 200                     'Create a branch in the SVN repository',
 201                     { 'message|m=s' => \$_message,
 202                       'destination|d=s' => \$_branch_dest,
 203                       'dry-run|n' => \$_dry_run,
 204                       'parents' => \$_parents,
 205                       'tag|t' => \$_tag,
 206                       'username=s' => \$Git::SVN::Prompt::_username,
 207                       'commit-url=s' => \$_commit_url } ],
 208         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 209                  'Create a tag in the SVN repository',
 210                  { 'message|m=s' => \$_message,
 211                    'destination|d=s' => \$_branch_dest,
 212                    'dry-run|n' => \$_dry_run,
 213                    'parents' => \$_parents,
 214                    'username=s' => \$Git::SVN::Prompt::_username,
 215                    'commit-url=s' => \$_commit_url } ],
 216         'set-tree' => [ \&cmd_set_tree,
 217                         "Set an SVN repository to a git tree-ish",
 218                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 219         'create-ignore' => [ \&cmd_create_ignore,
 220                              'Create a .gitignore per svn:ignore',
 221                              { 'revision|r=i' => \$_revision
 222                              } ],
 223         'mkdirs' => [ \&cmd_mkdirs ,
 224                       "recreate empty directories after a checkout",
 225                       { 'revision|r=i' => \$_revision } ],
 226         'propget' => [ \&cmd_propget,
 227                        'Print the value of a property on a file or directory',
 228                        { 'revision|r=i' => \$_revision } ],
 229         'propset' => [ \&cmd_propset,
 230                        'Set the value of a property on a file or directory - will be set on commit',
 231                        {} ],
 232         'proplist' => [ \&cmd_proplist,
 233                        'List all properties of a file or directory',
 234                        { 'revision|r=i' => \$_revision } ],
 235         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 236                         { 'revision|r=i' => \$_revision
 237                         } ],
 238         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 239                         { 'revision|r=i' => \$_revision
 240                         } ],
 241         'multi-fetch' => [ \&cmd_multi_fetch,
 242                            "Deprecated alias for $0 fetch --all",
 243                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 244         'migrate' => [ sub { },
 245                        # no-op, we automatically run this anyways,
 246                        'Migrate configuration/metadata/layout from
 247                         previous versions of git-svn',
 248                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 249                          %remote_opts } ],
 250         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 251                         { 'limit=i' => \$Git::SVN::Log::limit,
 252                           'revision|r=s' => \$_revision,
 253                           'verbose|v' => \$Git::SVN::Log::verbose,
 254                           'incremental' => \$Git::SVN::Log::incremental,
 255                           'oneline' => \$Git::SVN::Log::oneline,
 256                           'show-commit' => \$Git::SVN::Log::show_commit,
 257                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 258                           'authors-file|A=s' => \$_authors,
 259                           'color' => \$Git::SVN::Log::color,
 260                           'pager=s' => \$Git::SVN::Log::pager
 261                         } ],
 262         'find-rev' => [ \&cmd_find_rev,
 263                         "Translate between SVN revision numbers and tree-ish",
 264                         { 'B|before' => \$_before,
 265                           'A|after' => \$_after } ],
 266         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 267                         { 'merge|m|M' => \$_merge,
 268                           'verbose|v' => \$_verbose,
 269                           'strategy|s=s' => \$_strategy,
 270                           'local|l' => \$_local,
 271                           'fetch-all|all' => \$_fetch_all,
 272                           'dry-run|n' => \$_dry_run,
 273                           'preserve-merges|p' => \$_preserve_merges,
 274                           %fc_opts } ],
 275         'commit-diff' => [ \&cmd_commit_diff,
 276                            'Commit a diff between two trees',
 277                         { 'message|m=s' => \$_message,
 278                           'file|F=s' => \$_file,
 279                           'revision|r=s' => \$_revision,
 280                         %cmt_opts } ],
 281         'info' => [ \&cmd_info,
 282                     "Show info about the latest SVN revision
 283                      on the current branch",
 284                     { 'url' => \$_url, } ],
 285         'blame' => [ \&Git::SVN::Log::cmd_blame,
 286                     "Show what revision and author last modified each line of a file",
 287                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 288         'reset' => [ \&cmd_reset,
 289                      "Undo fetches back to the specified SVN revision",
 290                      { 'revision|r=s' => \$_revision,
 291                        'parent|p' => \$_fetch_parent } ],
 292         'gc' => [ \&cmd_gc,
 293                   "Compress unhandled.log files in .git/svn and remove " .
 294                   "index files in .git/svn",
 295                 {} ],
 296 );
 297
 298 package FakeTerm;
 299 sub new {
 300         my ($class, $reason) = @_;
 301         return bless \$reason, shift;
 302 }
 303 sub readline {
 304         my $self = shift;
 305         die "Cannot use readline on FakeTerm: $$self";
 306 }
 307 package main;
 308
 309 my $term;
 310 sub term_init {
 311         $term = eval {
 312                 require Term::ReadLine;
 313                 $ENV{"GIT_SVN_NOTTY"}
 314                         ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 315                         : new Term::ReadLine 'git-svn';
 316         };
 317         if ($@) {
 318                 $term = new FakeTerm "$@: going non-interactive";
 319         }
 320 }
 321
 322 my $cmd;
 323 for (my $i = 0; $i < @ARGV; $i++) {
 324         if (defined $cmd{$ARGV[$i]}) {
 325                 $cmd = $ARGV[$i];
 326                 splice @ARGV, $i, 1;
 327                 last;
 328         } elsif ($ARGV[$i] eq 'help') {
 329                 $cmd = $ARGV[$i+1];
 330                 usage(0);
 331         }
 332 };
 333
 334 # make sure we're always running at the top-level working directory
 335 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 336         $ENV{GIT_DIR} ||= ".git";
 337         # catch the submodule case
 338         if (-f $ENV{GIT_DIR}) {
 339                 open(my $fh, '<', $ENV{GIT_DIR}) or
 340                         die "failed to open $ENV{GIT_DIR}: $!\n";
 341                 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
 342         }
 343 } elsif ($cmd) {
 344         my ($git_dir, $cdup);
 345         git_cmd_try {
 346                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 347         } "Unable to find .git directory\n";
 348         git_cmd_try {
 349                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 350                 chomp $cdup if ($cdup);
 351                 $cdup = "." unless ($cdup && length $cdup);
 352         } "Already at toplevel, but $git_dir not found\n";
 353         $ENV{GIT_DIR} = $git_dir;
 354         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 355         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 356 }
 357
 358 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 359
 360 read_git_config(\%opts) if $ENV{GIT_DIR};
 361 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 362         Getopt::Long::Configure('pass_through');
 363 }
 364 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 365                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 366                     'id|i=s' => \$Git::SVN::default_ref_id,
 367                     'svn-remote|remote|R=s' => sub {
 368                        $Git::SVN::no_reuse_existing = 1;
 369                        $Git::SVN::default_repo_id = $_[1] });
 370 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 371
 372 usage(0) if $_help;
 373 version() if $_version;
 374 usage(1) unless defined $cmd;
 375 load_authors() if $_authors;
 376 if (defined $_authors_prog) {
 377         my $abs_file = File::Spec->rel2abs($_authors_prog);
 378         $_authors_prog = "'" . $abs_file . "'" if -x $abs_file;
 379 }
 380
 381 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 382         Git::SVN::Migration::migration_check();
 383 }
 384 Git::SVN::init_vars();
 385 eval {
 386         Git::SVN::verify_remotes_sanity();
 387         $cmd{$cmd}->[0]->(@ARGV);
 388         post_fetch_checkout();
 389 };
 390 fatal $@ if $@;
 391 exit 0;
 392
 393 ####################### primary functions ######################
 394 sub usage {
 395         my $exit = shift || 0;
 396         my $fd = $exit ? \*STDERR : \*STDOUT;
 397         print $fd <<"";
 398 git-svn - bidirectional operations between a single Subversion tree and git
 399 usage: git svn <command> [options] [arguments]\n
 400
 401         print $fd "Available commands:\n" unless $cmd;
 402
 403         foreach (sort keys %cmd) {
 404                 next if $cmd && $cmd ne $_;
 405                 next if /^multi-/; # don't show deprecated commands
 406                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 407                 foreach (sort keys %{$cmd{$_}->[2]}) {
 408                         # mixed-case options are for .git/config only
 409                         next if /[A-Z]/ && /^[a-z]+$/i;
 410                         # prints out arguments as they should be passed:
 411                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 412                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 413                                                         "--$_" : "-$_" }
 414                                                 split /\|/,$_)," $x\n";
 415                 }
 416         }
 417         print $fd <<"";
 418 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 419 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 420 one git repository and want to keep them separate.  See git-svn(1) for more
 421 information.
 422
 423         exit $exit;
 424 }
 425
 426 sub version {
 427         ::_req_svn();
 428         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 429         exit 0;
 430 }
 431
 432 sub ask {
 433         my ($prompt, %arg) = @_;
 434         my $valid_re = $arg{valid_re};
 435         my $default = $arg{default};
 436         my $resp;
 437         my $i = 0;
 438         term_init() unless $term;
 439
 440         if ( !( defined($term->IN)
 441             && defined( fileno($term->IN) )
 442             && defined( $term->OUT )
 443             && defined( fileno($term->OUT) ) ) ){
 444                 return defined($default) ? $default : undef;
 445         }
 446
 447         while ($i++ < 10) {
 448                 $resp = $term->readline($prompt);
 449                 if (!defined $resp) { # EOF
 450                         print "\n";
 451                         return defined $default ? $default : undef;
 452                 }
 453                 if ($resp eq '' and defined $default) {
 454                         return $default;
 455                 }
 456                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 457                         return $resp;
 458                 }
 459         }
 460         return undef;
 461 }
 462
 463 sub do_git_init_db {
 464         unless (-d $ENV{GIT_DIR}) {
 465                 my @init_db = ('init');
 466                 push @init_db, "--template=$_template" if defined $_template;
 467                 if (defined $_shared) {
 468                         if ($_shared =~ /[a-z]/) {
 469                                 push @init_db, "--shared=$_shared";
 470                         } else {
 471                                 push @init_db, "--shared";
 472                         }
 473                 }
 474                 command_noisy(@init_db);
 475                 $_repository = Git->repository(Repository => ".git");
 476         }
 477         my $set;
 478         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 479         foreach my $i (keys %icv) {
 480                 die "'$set' and '$i' cannot both be set\n" if $set;
 481                 next unless defined $icv{$i};
 482                 command_noisy('config', "$pfx.$i", $icv{$i});
 483                 $set = $i;
 484         }
 485         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 486         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 487                 if defined $$ignore_paths_regex;
 488         my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 489         command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 490                 if defined $$include_paths_regex;
 491         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 492         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 493                 if defined $$ignore_refs_regex;
 494
 495         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 496                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 497                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 498                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 499         }
 500 }
 501
 502 sub init_subdir {
 503         my $repo_path = shift or return;
 504         mkpath([$repo_path]) unless -d $repo_path;
 505         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 506         $ENV{GIT_DIR} = '.git';
 507         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 508 }
 509
 510 sub cmd_clone {
 511         my ($url, $path) = @_;
 512         if (!$url) {
 513                 die "SVN repository location required ",
 514                     "as a command-line argument\n";
 515         } elsif (!defined $path &&
 516             (defined $_trunk || @_branches || @_tags ||
 517              defined $_stdlayout) &&
 518             $url !~ m#^[a-z\+]+://#) {
 519                 $path = $url;
 520         }
 521         $path = basename($url) if !defined $path || !length $path;
 522         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 523         cmd_init($url, $path);
 524         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 525             if $_authors;
 526         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 527 }
 528
 529 sub cmd_init {
 530         if (defined $_stdlayout) {
 531                 $_trunk = 'trunk' if (!defined $_trunk);
 532                 @_tags = 'tags' if (! @_tags);
 533                 @_branches = 'branches' if (! @_branches);
 534         }
 535         if (defined $_trunk || @_branches || @_tags) {
 536                 return cmd_multi_init(@_);
 537         }
 538         my $url = shift or die "SVN repository location required ",
 539                                "as a command-line argument\n";
 540         $url = canonicalize_url($url);
 541         init_subdir(@_);
 542         do_git_init_db();
 543
 544         if ($Git::SVN::_minimize_url eq 'unset') {
 545                 $Git::SVN::_minimize_url = 0;
 546         }
 547
 548         Git::SVN->init($url);
 549 }
 550
 551 sub cmd_fetch {
 552         if (grep /^\d+=./, @_) {
 553                 die "'<rev>=<commit>' fetch arguments are ",
 554                     "no longer supported.\n";
 555         }
 556         my ($remote) = @_;
 557         if (@_ > 1) {
 558                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 559         }
 560         $Git::SVN::no_reuse_existing = undef;
 561         if ($_fetch_parent) {
 562                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 563                 unless ($gs) {
 564                         die "Unable to determine upstream SVN information from ",
 565                             "working tree history\n";
 566                 }
 567                 # just fetch, don't checkout.
 568                 $_no_checkout = 'true';
 569                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 570         } elsif ($_fetch_all) {
 571                 cmd_multi_fetch();
 572         } else {
 573                 $remote ||= $Git::SVN::default_repo_id;
 574                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 575         }
 576 }
 577
 578 sub cmd_set_tree {
 579         my (@commits) = @_;
 580         if ($_stdin || !@commits) {
 581                 print "Reading from stdin...\n";
 582                 @commits = ();
 583                 while (<STDIN>) {
 584                         if (/\b($sha1_short)\b/o) {
 585                                 unshift @commits, $1;
 586                         }
 587                 }
 588         }
 589         my @revs;
 590         foreach my $c (@commits) {
 591                 my @tmp = command('rev-parse',$c);
 592                 if (scalar @tmp == 1) {
 593                         push @revs, $tmp[0];
 594                 } elsif (scalar @tmp > 1) {
 595                         push @revs, reverse(command('rev-list',@tmp));
 596                 } else {
 597                         fatal "Failed to rev-parse $c";
 598                 }
 599         }
 600         my $gs = Git::SVN->new;
 601         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 602         $gs->fetch;
 603         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 604                 fatal "There are new revisions that were fetched ",
 605                       "and need to be merged (or acknowledged) ",
 606                       "before committing.\nlast rev: $r_last\n",
 607                       " current: $gs->{last_rev}";
 608         }
 609         $gs->set_tree($_) foreach @revs;
 610         print "Done committing ",scalar @revs," revisions to SVN\n";
 611         unlink $gs->{index};
 612 }
 613
 614 sub split_merge_info_range {
 615         my ($range) = @_;
 616         if ($range =~ /(\d+)-(\d+)/) {
 617                 return (int($1), int($2));
 618         } else {
 619                 return (int($range), int($range));
 620         }
 621 }
 622
 623 sub combine_ranges {
 624         my ($in) = @_;
 625
 626         my @fnums = ();
 627         my @arr = split(/,/, $in);
 628         for my $element (@arr) {
 629                 my ($start, $end) = split_merge_info_range($element);
 630                 push @fnums, $start;
 631         }
 632
 633         my @sorted = @arr [ sort {
 634                 $fnums[$a] <=> $fnums[$b]
 635         } 0..$#arr ];
 636
 637         my @return = ();
 638         my $last = -1;
 639         my $first = -1;
 640         for my $element (@sorted) {
 641                 my ($start, $end) = split_merge_info_range($element);
 642
 643                 if ($last == -1) {
 644                         $first = $start;
 645                         $last = $end;
 646                         next;
 647                 }
 648                 if ($start <= $last+1) {
 649                         if ($end > $last) {
 650                                 $last = $end;
 651                         }
 652                         next;
 653                 }
 654                 if ($first == $last) {
 655                         push @return, "$first";
 656                 } else {
 657                         push @return, "$first-$last";
 658                 }
 659                 $first = $start;
 660                 $last = $end;
 661         }
 662
 663         if ($first != -1) {
 664                 if ($first == $last) {
 665                         push @return, "$first";
 666                 } else {
 667                         push @return, "$first-$last";
 668                 }
 669         }
 670
 671         return join(',', @return);
 672 }
 673
 674 sub merge_revs_into_hash {
 675         my ($hash, $minfo) = @_;
 676         my @lines = split(' ', $minfo);
 677
 678         for my $line (@lines) {
 679                 my ($branchpath, $revs) = split(/:/, $line);
 680
 681                 if (exists($hash->{$branchpath})) {
 682                         # Merge the two revision sets
 683                         my $combined = "$hash->{$branchpath},$revs";
 684                         $hash->{$branchpath} = combine_ranges($combined);
 685                 } else {
 686                         # Just do range combining for consolidation
 687                         $hash->{$branchpath} = combine_ranges($revs);
 688                 }
 689         }
 690 }
 691
 692 sub merge_merge_info {
 693         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 694         my %result_hash = ();
 695
 696         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 697         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 698
 699         delete $result_hash{$ignore_branch} if $ignore_branch;
 700
 701         my $result = '';
 702         # Sort below is for consistency's sake
 703         for my $branchname (sort keys(%result_hash)) {
 704                 my $revlist = $result_hash{$branchname};
 705                 $result .= "$branchname:$revlist\n"
 706         }
 707         return $result;
 708 }
 709
 710 sub populate_merge_info {
 711         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 712
 713         my %parentshash;
 714         read_commit_parents(\%parentshash, $d);
 715         my @parents = @{$parentshash{$d}};
 716         if ($#parents > 0) {
 717                 # Merge commit
 718                 my $all_parents_ok = 1;
 719                 my $aggregate_mergeinfo = '';
 720                 my $rooturl = $gs->repos_root;
 721                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 722
 723                 if (defined($rewritten_parent)) {
 724                         # Replace first parent with newly-rewritten version
 725                         shift @parents;
 726                         unshift @parents, $rewritten_parent;
 727                 }
 728
 729                 foreach my $parent (@parents) {
 730                         my ($branchurl, $svnrev, $paruuid) =
 731                                 cmt_metadata($parent);
 732
 733                         unless (defined($svnrev)) {
 734                                 # Should have been caught be preflight check
 735                                 fatal "merge commit $d has ancestor $parent, but that change "
 736                      ."does not have git-svn metadata!";
 737                         }
 738                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 739                                 fatal "commit $parent git-svn metadata changed mid-run!";
 740                         }
 741                         my $branchpath = $1;
 742
 743                         my $ra = Git::SVN::Ra->new($branchurl);
 744                         my (undef, undef, $props) =
 745                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 746                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 747                         unless (defined $par_mergeinfo) {
 748                                 $par_mergeinfo = '';
 749                         }
 750                         # Merge previous mergeinfo values
 751                         $aggregate_mergeinfo =
 752                                 merge_merge_info($aggregate_mergeinfo,
 753                                                                 $par_mergeinfo,
 754                                                                 $target_branch);
 755
 756                         next if $parent eq $parents[0]; # Skip first parent
 757                         # Add new changes being placed in tree by merge
 758                         my @cmd = (qw/rev-list --reverse/,
 759                                            $parent, qw/--not/);
 760                         foreach my $par (@parents) {
 761                                 unless ($par eq $parent) {
 762                                         push @cmd, $par;
 763                                 }
 764                         }
 765                         my @revsin = ();
 766                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 767                         while (<$revlist>) {
 768                                 my $irev = $_;
 769                                 chomp $irev;
 770                                 my (undef, $csvnrev, undef) =
 771                                         cmt_metadata($irev);
 772                                 unless (defined $csvnrev) {
 773                                         # A child is missing SVN annotations...
 774                                         # this might be OK, or might not be.
 775                                         warn "W:child $irev is merged into revision "
 776                                                  ."$d but does not have git-svn metadata. "
 777                                                  ."This means git-svn cannot determine the "
 778                                                  ."svn revision numbers to place into the "
 779                                                  ."svn:mergeinfo property. You must ensure "
 780                                                  ."a branch is entirely committed to "
 781                                                  ."SVN before merging it in order for "
 782                                                  ."svn:mergeinfo population to function "
 783                                                  ."properly";
 784                                 }
 785                                 push @revsin, $csvnrev;
 786                         }
 787                         command_close_pipe($revlist, $ctx);
 788
 789                         last unless $all_parents_ok;
 790
 791                         # We now have a list of all SVN revnos which are
 792                         # merged by this particular parent. Integrate them.
 793                         next if $#revsin == -1;
 794                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 795                         $aggregate_mergeinfo =
 796                                 merge_merge_info($aggregate_mergeinfo,
 797                                                                 $newmergeinfo,
 798                                                                 $target_branch);
 799                 }
 800                 if ($all_parents_ok and $aggregate_mergeinfo) {
 801                         return $aggregate_mergeinfo;
 802                 }
 803         }
 804
 805         return undef;
 806 }
 807
 808 sub dcommit_rebase {
 809         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 810         my @diff;
 811
 812         if ($svn_error) {
 813                 print STDERR "\nERROR from SVN:\n",
 814                                 $svn_error->expanded_message, "\n";
 815         }
 816         unless ($_no_rebase) {
 817                 # we always want to rebase against the current HEAD,
 818                 # not any head that was passed to us
 819                 @diff = command('diff-tree', $current,
 820                            $fetched_ref, '--');
 821                 my @finish;
 822                 if (@diff) {
 823                         @finish = rebase_cmd();
 824                         print STDERR "W: $current and ", $fetched_ref,
 825                                      " differ, using @finish:\n",
 826                                      join("\n", @diff), "\n";
 827                 } elsif ($is_last) {
 828                         print "No changes between ", $current, " and ",
 829                               $fetched_ref,
 830                               "\nResetting to the latest ",
 831                               $fetched_ref, "\n";
 832                         @finish = qw/reset --mixed/;
 833                 }
 834                 command_noisy(@finish, $fetched_ref) if @finish;
 835         }
 836         if ($svn_error) {
 837                 die "ERROR: Not all changes have been committed into SVN"
 838                         .($_no_rebase ? ".\n" : ", however the committed\n"
 839                         ."ones (if any) seem to be successfully integrated "
 840                         ."into the working tree.\n")
 841                         ."Please see the above messages for details.\n";
 842         }
 843         return @diff;
 844 }
 845
 846 sub cmd_dcommit {
 847         my $head = shift;
 848         command_noisy(qw/update-index --refresh/);
 849         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 850                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 851                 . "or stash them with `git stash'.\n";
 852         $head ||= 'HEAD';
 853
 854         my $old_head;
 855         if ($head ne 'HEAD') {
 856                 $old_head = eval {
 857                         command_oneline([qw/symbolic-ref -q HEAD/])
 858                 };
 859                 if ($old_head) {
 860                         $old_head =~ s{^refs/heads/}{};
 861                 } else {
 862                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 863                 }
 864                 command(['checkout', $head], STDERR => 0);
 865         }
 866
 867         my @refs;
 868         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 869         unless ($gs) {
 870                 die "Unable to determine upstream SVN information from ",
 871                     "$head history.\nPerhaps the repository is empty.";
 872         }
 873
 874         if (defined $_commit_url) {
 875                 $url = $_commit_url;
 876         } else {
 877                 $url = eval { command_oneline('config', '--get',
 878                               "svn-remote.$gs->{repo_id}.commiturl") };
 879                 if (!$url) {
 880                         $url = $gs->full_pushurl
 881                 }
 882         }
 883
 884         my $last_rev = $_revision if defined $_revision;
 885         if ($url) {
 886                 print "Committing to $url ...\n";
 887         }
 888         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 889         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 890                 warn "Attempting to commit more than one change while ",
 891                      "--no-rebase is enabled.\n",
 892                      "If these changes depend on each other, re-running ",
 893                      "without --no-rebase may be required."
 894         }
 895
 896         if (defined $_interactive){
 897                 my $ask_default = "y";
 898                 foreach my $d (@$linear_refs){
 899                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 900                         while (<$fh>){
 901                                 print $_;
 902                         }
 903                         command_close_pipe($fh, $ctx);
 904                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 905                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 906                                  default => $ask_default);
 907                         die "Commit this patch reply required" unless defined $_;
 908                         if (/^[nq]/i) {
 909                                 exit(0);
 910                         } elsif (/^a/i) {
 911                                 last;
 912                         }
 913                 }
 914         }
 915
 916         my $expect_url = $url;
 917
 918         my $push_merge_info = eval {
 919                 command_oneline(qw/config --get svn.pushmergeinfo/)
 920                 };
 921         if (not defined($push_merge_info)
 922                         or $push_merge_info eq "false"
 923                         or $push_merge_info eq "no"
 924                         or $push_merge_info eq "never") {
 925                 $push_merge_info = 0;
 926         }
 927
 928         unless (defined($_merge_info) || ! $push_merge_info) {
 929                 # Preflight check of changes to ensure no issues with mergeinfo
 930                 # This includes check for uncommitted-to-SVN parents
 931                 # (other than the first parent, which we will handle),
 932                 # information from different SVN repos, and paths
 933                 # which are not underneath this repository root.
 934                 my $rooturl = $gs->repos_root;
 935                 Git::SVN::remove_username($rooturl);
 936                 foreach my $d (@$linear_refs) {
 937                         my %parentshash;
 938                         read_commit_parents(\%parentshash, $d);
 939                         my @realparents = @{$parentshash{$d}};
 940                         if ($#realparents > 0) {
 941                                 # Merge commit
 942                                 shift @realparents; # Remove/ignore first parent
 943                                 foreach my $parent (@realparents) {
 944                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 945                                         unless (defined $paruuid) {
 946                                                 # A parent is missing SVN annotations...
 947                                                 # abort the whole operation.
 948                                                 fatal "$parent is merged into revision $d, "
 949                                                          ."but does not have git-svn metadata. "
 950                                                          ."Either dcommit the branch or use a "
 951                                                          ."local cherry-pick, FF merge, or rebase "
 952                                                          ."instead of an explicit merge commit.";
 953                                         }
 954
 955                                         unless ($paruuid eq $uuid) {
 956                                                 # Parent has SVN metadata from different repository
 957                                                 fatal "merge parent $parent for change $d has "
 958                                                          ."git-svn uuid $paruuid, while current change "
 959                                                          ."has uuid $uuid!";
 960                                         }
 961
 962                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 963                                                 # This branch is very strange indeed.
 964                                                 fatal "merge parent $parent for $d is on branch "
 965                                                          ."$branchurl, which is not under the "
 966                                                          ."git-svn root $rooturl!";
 967                                         }
 968                                 }
 969                         }
 970                 }
 971         }
 972
 973         my $rewritten_parent;
 974         my $current_head = command_oneline(qw/rev-parse HEAD/);
 975         Git::SVN::remove_username($expect_url);
 976         if (defined($_merge_info)) {
 977                 $_merge_info =~ tr{ }{\n};
 978         }
 979         while (1) {
 980                 my $d = shift @$linear_refs or last;
 981                 unless (defined $last_rev) {
 982                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 983                         unless (defined $last_rev) {
 984                                 fatal "Unable to extract revision information ",
 985                                       "from commit $d~1";
 986                         }
 987                 }
 988                 if ($_dry_run) {
 989                         print "diff-tree $d~1 $d\n";
 990                 } else {
 991                         my $cmt_rev;
 992
 993                         unless (defined($_merge_info) || ! $push_merge_info) {
 994                                 $_merge_info = populate_merge_info($d, $gs,
 995                                                              $uuid,
 996                                                              $linear_refs,
 997                                                              $rewritten_parent);
 998                         }
 999
1000                         my %ed_opts = ( r => $last_rev,
1001                                         log => get_commit_entry($d)->{log},
1002                                         ra => Git::SVN::Ra->new($url),
1003                                         config => SVN::Core::config_get_config(
1004                                                 $Git::SVN::Ra::config_dir
1005                                         ),
1006                                         tree_a => "$d~1",
1007                                         tree_b => $d,
1008                                         editor_cb => sub {
1009                                                print "Committed r$_[0]\n";
1010                                                $cmt_rev = $_[0];
1011                                         },
1012                                         mergeinfo => $_merge_info,
1013                                         svn_path => '');
1014
1015                         my $err_handler = $SVN::Error::handler;
1016                         $SVN::Error::handler = sub {
1017                                 my $err = shift;
1018                                 dcommit_rebase(1, $current_head, $gs->refname,
1019                                         $err);
1020                         };
1021
1022                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1023                                 print "No changes\n$d~1 == $d\n";
1024                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1025                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1026                                                                $parents->{$d};
1027                         }
1028                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1029                         $SVN::Error::handler = $err_handler;
1030                         $last_rev = $cmt_rev;
1031                         next if $_no_rebase;
1032
1033                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1034                                                 $gs->refname, undef);
1035
1036                         $rewritten_parent = command_oneline(qw/rev-parse/,
1037                                                         $gs->refname);
1038
1039                         if (@diff) {
1040                                 $current_head = command_oneline(qw/rev-parse
1041                                                                 HEAD/);
1042                                 @refs = ();
1043                                 my ($url_, $rev_, $uuid_, $gs_) =
1044                                               working_head_info('HEAD', \@refs);
1045                                 my ($linear_refs_, $parents_) =
1046                                               linearize_history($gs_, \@refs);
1047                                 if (scalar(@$linear_refs) !=
1048                                     scalar(@$linear_refs_)) {
1049                                         fatal "# of revisions changed ",
1050                                           "\nbefore:\n",
1051                                           join("\n", @$linear_refs),
1052                                           "\n\nafter:\n",
1053                                           join("\n", @$linear_refs_), "\n",
1054                                           'If you are attempting to commit ',
1055                                           "merges, try running:\n\t",
1056                                           'git rebase --interactive',
1057                                           '--preserve-merges ',
1058                                           $gs->refname,
1059                                           "\nBefore dcommitting";
1060                                 }
1061                                 if ($url_ ne $expect_url) {
1062                                         if ($url_ eq $gs->metadata_url) {
1063                                                 print
1064                                                   "Accepting rewritten URL:",
1065                                                   " $url_\n";
1066                                         } else {
1067                                                 fatal
1068                                                   "URL mismatch after rebase:",
1069                                                   " $url_ != $expect_url";
1070                                         }
1071                                 }
1072                                 if ($uuid_ ne $uuid) {
1073                                         fatal "uuid mismatch after rebase: ",
1074                                               "$uuid_ != $uuid";
1075                                 }
1076                                 # remap parents
1077                                 my (%p, @l, $i);
1078                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1079                                         my $new = $linear_refs_->[$i] or next;
1080                                         $p{$new} =
1081                                                 $parents->{$linear_refs->[$i]};
1082                                         push @l, $new;
1083                                 }
1084                                 $parents = \%p;
1085                                 $linear_refs = \@l;
1086                                 undef $last_rev;
1087                         }
1088                 }
1089         }
1090
1091         if ($old_head) {
1092                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1093                 my $new_is_symbolic = eval {
1094                         command_oneline(qw/symbolic-ref -q HEAD/);
1095                 };
1096                 if ($new_is_symbolic) {
1097                         print "dcommitted the branch ", $head, "\n";
1098                 } else {
1099                         print "dcommitted on a detached HEAD because you gave ",
1100                               "a revision argument.\n",
1101                               "The rewritten commit is: ", $new_head, "\n";
1102                 }
1103                 command(['checkout', $old_head], STDERR => 0);
1104         }
1105
1106         unlink $gs->{index};
1107 }
1108
1109 sub cmd_branch {
1110         my ($branch_name, $head) = @_;
1111
1112         unless (defined $branch_name && length $branch_name) {
1113                 die(($_tag ? "tag" : "branch") . " name required\n");
1114         }
1115         $head ||= 'HEAD';
1116
1117         my (undef, $rev, undef, $gs) = working_head_info($head);
1118         my $src = $gs->full_pushurl;
1119
1120         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1121         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1122         my $glob;
1123         if ($#{$allglobs} == 0) {
1124                 $glob = $allglobs->[0];
1125         } else {
1126                 unless(defined $_branch_dest) {
1127                         die "Multiple ",
1128                             $_tag ? "tag" : "branch",
1129                             " paths defined for Subversion repository.\n",
1130                             "You must specify where you want to create the ",
1131                             $_tag ? "tag" : "branch",
1132                             " with the --destination argument.\n";
1133                 }
1134                 foreach my $g (@{$allglobs}) {
1135                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1136                         if ($_branch_dest =~ /$re/) {
1137                                 $glob = $g;
1138                                 last;
1139                         }
1140                 }
1141                 unless (defined $glob) {
1142                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1143                         foreach my $g (@{$allglobs}) {
1144                                 $g->{path}->{left} =~ /$dest_re/ or next;
1145                                 if (defined $glob) {
1146                                         die "Ambiguous destination: ",
1147                                             $_branch_dest, "\nmatches both '",
1148                                             $glob->{path}->{left}, "' and '",
1149                                             $g->{path}->{left}, "'\n";
1150                                 }
1151                                 $glob = $g;
1152                         }
1153                         unless (defined $glob) {
1154                                 die "Unknown ",
1155                                     $_tag ? "tag" : "branch",
1156                                     " destination $_branch_dest\n";
1157                         }
1158                 }
1159         }
1160         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1161         my $url;
1162         if (defined $_commit_url) {
1163                 $url = $_commit_url;
1164         } else {
1165                 $url = eval { command_oneline('config', '--get',
1166                         "svn-remote.$gs->{repo_id}.commiturl") };
1167                 if (!$url) {
1168                         $url = $remote->{pushurl} || $remote->{url};
1169                 }
1170         }
1171         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1172
1173         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1174                 $src=~s/^http:/https:/;
1175         }
1176
1177         ::_req_svn();
1178         require SVN::Client;
1179
1180         my ($config, $baton, undef) = Git::SVN::Ra::prepare_config_once();
1181         my $ctx = SVN::Client->new(
1182                 auth => $baton,
1183                 config => $config,
1184                 log_msg => sub {
1185                         ${ $_[0] } = defined $_message
1186                                 ? $_message
1187                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1188                                 . $branch_name;
1189                 },
1190         );
1191
1192         eval {
1193                 $ctx->ls($dst, 'HEAD', 0);
1194         } and die "branch ${branch_name} already exists\n";
1195
1196         if ($_parents) {
1197                 mk_parent_dirs($ctx, $dst);
1198         }
1199
1200         print "Copying ${src} at r${rev} to ${dst}...\n";
1201         $ctx->copy($src, $rev, $dst)
1202                 unless $_dry_run;
1203
1204         # Release resources held by ctx before creating another SVN::Ra
1205         # so destruction is orderly.  This seems necessary with SVN 1.9.5
1206         # to avoid segfaults.
1207         $ctx = undef;
1208
1209         $gs->fetch_all;
1210 }
1211
1212 sub mk_parent_dirs {
1213         my ($ctx, $parent) = @_;
1214         $parent =~ s{/[^/]*$}{};
1215
1216         if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1217                 mk_parent_dirs($ctx, $parent);
1218                 print "Creating parent folder ${parent} ...\n";
1219                 $ctx->mkdir($parent) unless $_dry_run;
1220         }
1221 }
1222
1223 sub cmd_find_rev {
1224         my $revision_or_hash = shift or die "SVN or git revision required ",
1225                                             "as a command-line argument\n";
1226         my $result;
1227         if ($revision_or_hash =~ /^r\d+$/) {
1228                 my $head = shift;
1229                 $head ||= 'HEAD';
1230                 my @refs;
1231                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1232                 unless ($gs) {
1233                         die "Unable to determine upstream SVN information from ",
1234                             "$head history\n";
1235                 }
1236                 my $desired_revision = substr($revision_or_hash, 1);
1237                 if ($_before) {
1238                         $result = $gs->find_rev_before($desired_revision, 1);
1239                 } elsif ($_after) {
1240                         $result = $gs->find_rev_after($desired_revision, 1);
1241                 } else {
1242                         $result = $gs->rev_map_get($desired_revision, $uuid);
1243                 }
1244         } else {
1245                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1246                 $result = $rev;
1247         }
1248         print "$result\n" if $result;
1249 }
1250
1251 sub auto_create_empty_directories {
1252         my ($gs) = @_;
1253         my $var = eval { command_oneline('config', '--get', '--bool',
1254                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1255         # By default, create empty directories by consulting the unhandled log,
1256         # but allow setting it to 'false' to skip it.
1257         return !($var && $var eq 'false');
1258 }
1259
1260 sub cmd_rebase {
1261         command_noisy(qw/update-index --refresh/);
1262         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1263         unless ($gs) {
1264                 die "Unable to determine upstream SVN information from ",
1265                     "working tree history\n";
1266         }
1267         if ($_dry_run) {
1268                 print "Remote Branch: " . $gs->refname . "\n";
1269                 print "SVN URL: " . $url . "\n";
1270                 return;
1271         }
1272         if (command(qw/diff-index HEAD --/)) {
1273                 print STDERR "Cannot rebase with uncommitted changes:\n";
1274                 command_noisy('status');
1275                 exit 1;
1276         }
1277         unless ($_local) {
1278                 # rebase will checkout for us, so no need to do it explicitly
1279                 $_no_checkout = 'true';
1280                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1281         }
1282         command_noisy(rebase_cmd(), $gs->refname);
1283         if (auto_create_empty_directories($gs)) {
1284                 $gs->mkemptydirs;
1285         }
1286 }
1287
1288 sub cmd_show_ignore {
1289         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1290         $gs ||= Git::SVN->new;
1291         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1292         $gs->prop_walk($gs->path, $r, sub {
1293                 my ($gs, $path, $props) = @_;
1294                 print STDOUT "\n# $path\n";
1295                 my $s = $props->{'svn:ignore'} or return;
1296                 $s =~ s/[\r\n]+/\n/g;
1297                 $s =~ s/^\n+//;
1298                 chomp $s;
1299                 $s =~ s#^#$path#gm;
1300                 print STDOUT "$s\n";
1301         });
1302 }
1303
1304 sub cmd_show_externals {
1305         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1306         $gs ||= Git::SVN->new;
1307         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1308         $gs->prop_walk($gs->path, $r, sub {
1309                 my ($gs, $path, $props) = @_;
1310                 print STDOUT "\n# $path\n";
1311                 my $s = $props->{'svn:externals'} or return;
1312                 $s =~ s/[\r\n]+/\n/g;
1313                 chomp $s;
1314                 $s =~ s#^#$path#gm;
1315                 print STDOUT "$s\n";
1316         });
1317 }
1318
1319 sub cmd_create_ignore {
1320         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1321         $gs ||= Git::SVN->new;
1322         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1323         $gs->prop_walk($gs->path, $r, sub {
1324                 my ($gs, $path, $props) = @_;
1325                 # $path is of the form /path/to/dir/
1326                 $path = '.' . $path;
1327                 # SVN can have attributes on empty directories,
1328                 # which git won't track
1329                 mkpath([$path]) unless -d $path;
1330                 my $ignore = $path . '.gitignore';
1331                 my $s = $props->{'svn:ignore'} or return;
1332                 open(GITIGNORE, '>', $ignore)
1333                   or fatal("Failed to open `$ignore' for writing: $!");
1334                 $s =~ s/[\r\n]+/\n/g;
1335                 $s =~ s/^\n+//;
1336                 chomp $s;
1337                 # Prefix all patterns so that the ignore doesn't apply
1338                 # to sub-directories.
1339                 $s =~ s#^#/#gm;
1340                 print GITIGNORE "$s\n";
1341                 close(GITIGNORE)
1342                   or fatal("Failed to close `$ignore': $!");
1343                 command_noisy('add', '-f', $ignore);
1344         });
1345 }
1346
1347 sub cmd_mkdirs {
1348         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1349         $gs ||= Git::SVN->new;
1350         $gs->mkemptydirs($_revision);
1351 }
1352
1353 # get_svnprops(PATH)
1354 # ------------------
1355 # Helper for cmd_propget and cmd_proplist below.
1356 sub get_svnprops {
1357         my $path = shift;
1358         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1359         $gs ||= Git::SVN->new;
1360
1361         # prefix THE PATH by the sub-directory from which the user
1362         # invoked us.
1363         $path = $cmd_dir_prefix . $path;
1364         fatal("No such file or directory: $path") unless -e $path;
1365         my $is_dir = -d $path ? 1 : 0;
1366         $path = join_paths($gs->path, $path);
1367
1368         # canonicalize the path (otherwise libsvn will abort or fail to
1369         # find the file)
1370         $path = canonicalize_path($path);
1371
1372         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1373         my $props;
1374         if ($is_dir) {
1375                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1376         }
1377         else {
1378                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1379         }
1380         return $props;
1381 }
1382
1383 # cmd_propget (PROP, PATH)
1384 # ------------------------
1385 # Print the SVN property PROP for PATH.
1386 sub cmd_propget {
1387         my ($prop, $path) = @_;
1388         $path = '.' if not defined $path;
1389         usage(1) if not defined $prop;
1390         my $props = get_svnprops($path);
1391         if (not defined $props->{$prop}) {
1392                 fatal("`$path' does not have a `$prop' SVN property.");
1393         }
1394         print $props->{$prop} . "\n";
1395 }
1396
1397 # cmd_propset (PROPNAME, PROPVAL, PATH)
1398 # ------------------------
1399 # Adjust the SVN property PROPNAME to PROPVAL for PATH.
1400 sub cmd_propset {
1401         my ($propname, $propval, $path) = @_;
1402         $path = '.' if not defined $path;
1403         $path = $cmd_dir_prefix . $path;
1404         usage(1) if not defined $propname;
1405         usage(1) if not defined $propval;
1406         my $file = basename($path);
1407         my $dn = dirname($path);
1408         my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1409         my @new_props;
1410         if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1411                 push @new_props, "$propname=$propval";
1412         } else {
1413                 # TODO: handle combining properties better
1414                 my @props = split(/;/, $cur_props);
1415                 my $replaced_prop;
1416                 foreach my $prop (@props) {
1417                         # Parse 'name=value' syntax and set the property.
1418                         if ($prop =~ /([^=]+)=(.*)/) {
1419                                 my ($n,$v) = ($1,$2);
1420                                 if ($n eq $propname) {
1421                                         $v = $propval;
1422                                         $replaced_prop = 1;
1423                                 }
1424                                 push @new_props, "$n=$v";
1425                         }
1426                 }
1427                 if (!$replaced_prop) {
1428                         push @new_props, "$propname=$propval";
1429                 }
1430         }
1431         my $attrfile = "$dn/.gitattributes";
1432         open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1433         # TODO: don't simply append here if $file already has svn-properties
1434         my $new_props = join(';', @new_props);
1435         print $attrfh "$file svn-properties=$new_props\n" or
1436                 die "write to $attrfile: $!\n";
1437         close $attrfh or die "close $attrfile: $!\n";
1438 }
1439
1440 # cmd_proplist (PATH)
1441 # -------------------
1442 # Print the list of SVN properties for PATH.
1443 sub cmd_proplist {
1444         my $path = shift;
1445         $path = '.' if not defined $path;
1446         my $props = get_svnprops($path);
1447         print "Properties on '$path':\n";
1448         foreach (sort keys %{$props}) {
1449                 print "  $_\n";
1450         }
1451 }
1452
1453 sub cmd_multi_init {
1454         my $url = shift;
1455         unless (defined $_trunk || @_branches || @_tags) {
1456                 usage(1);
1457         }
1458
1459         $_prefix = 'origin/' unless defined $_prefix;
1460         if (defined $url) {
1461                 $url = canonicalize_url($url);
1462                 init_subdir(@_);
1463         }
1464         do_git_init_db();
1465         if (defined $_trunk) {
1466                 $_trunk =~ s#^/+##;
1467                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1468                 # try both old-style and new-style lookups:
1469                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1470                 unless ($gs_trunk) {
1471                         my ($trunk_url, $trunk_path) =
1472                                               complete_svn_url($url, $_trunk);
1473                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1474                                                    undef, $trunk_ref);
1475                 }
1476         }
1477         return unless @_branches || @_tags;
1478         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1479         foreach my $path (@_branches) {
1480                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1481         }
1482         foreach my $path (@_tags) {
1483                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1484         }
1485 }
1486
1487 sub cmd_multi_fetch {
1488         $Git::SVN::no_reuse_existing = undef;
1489         my $remotes = Git::SVN::read_all_remotes();
1490         foreach my $repo_id (sort keys %$remotes) {
1491                 if ($remotes->{$repo_id}->{url}) {
1492                         Git::SVN::fetch_all($repo_id, $remotes);
1493                 }
1494         }
1495 }
1496
1497 # this command is special because it requires no metadata
1498 sub cmd_commit_diff {
1499         my ($ta, $tb, $url) = @_;
1500         my $usage = "usage: $0 commit-diff -r<revision> ".
1501                     "<tree-ish> <tree-ish> [<URL>]";
1502         fatal($usage) if (!defined $ta || !defined $tb);
1503         my $svn_path = '';
1504         if (!defined $url) {
1505                 my $gs = eval { Git::SVN->new };
1506                 if (!$gs) {
1507                         fatal("Needed URL or usable git-svn --id in ",
1508                               "the command-line\n", $usage);
1509                 }
1510                 $url = $gs->url;
1511                 $svn_path = $gs->path;
1512         }
1513         unless (defined $_revision) {
1514                 fatal("-r|--revision is a required argument\n", $usage);
1515         }
1516         if (defined $_message && defined $_file) {
1517                 fatal("Both --message/-m and --file/-F specified ",
1518                       "for the commit message.\n",
1519                       "I have no idea what you mean");
1520         }
1521         if (defined $_file) {
1522                 $_message = file_to_s($_file);
1523         } else {
1524                 $_message ||= get_commit_entry($tb)->{log};
1525         }
1526         my $ra ||= Git::SVN::Ra->new($url);
1527         my $r = $_revision;
1528         if ($r eq 'HEAD') {
1529                 $r = $ra->get_latest_revnum;
1530         } elsif ($r !~ /^\d+$/) {
1531                 die "revision argument: $r not understood by git-svn\n";
1532         }
1533         my %ed_opts = ( r => $r,
1534                         log => $_message,
1535                         ra => $ra,
1536                         tree_a => $ta,
1537                         tree_b => $tb,
1538                         editor_cb => sub { print "Committed r$_[0]\n" },
1539                         svn_path => $svn_path );
1540         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1541                 print "No changes\n$ta == $tb\n";
1542         }
1543 }
1544
1545 sub cmd_info {
1546         my $path_arg = defined($_[0]) ? $_[0] : '.';
1547         my $path = $path_arg;
1548         if (File::Spec->file_name_is_absolute($path)) {
1549                 $path = canonicalize_path($path);
1550
1551                 my $toplevel = eval {
1552                         my @cmd = qw/rev-parse --show-toplevel/;
1553                         command_oneline(\@cmd, STDERR => 0);
1554                 };
1555
1556                 # remove $toplevel from the absolute path:
1557                 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1558                 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1559                 my @dirs = File::Spec->splitdir($dirs);
1560                 my @tdirs = File::Spec->splitdir($tdirs);
1561                 pop @dirs if $dirs[-1] eq '';
1562                 pop @tdirs if $tdirs[-1] eq '';
1563                 push @dirs, $file;
1564                 push @tdirs, $tfile;
1565                 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1566                         shift @dirs;
1567                         shift @tdirs;
1568                 }
1569                 $dirs = File::Spec->catdir(@dirs);
1570                 $path = File::Spec->catpath($vol, $dirs);
1571
1572                 $path = canonicalize_path($path);
1573         } else {
1574                 $path = canonicalize_path($cmd_dir_prefix . $path);
1575         }
1576         if (exists $_[1]) {
1577                 die "Too many arguments specified\n";
1578         }
1579
1580         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1581
1582         if (!$file_type && !$diff_status) {
1583                 print STDERR "svn: '$path' is not under version control\n";
1584                 exit 1;
1585         }
1586
1587         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1588         unless ($gs) {
1589                 die "Unable to determine upstream SVN information from ",
1590                     "working tree history\n";
1591         }
1592
1593         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1594         $path = "." if $path eq "";
1595
1596         my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1597
1598         if ($_url) {
1599                 print "$full_url\n";
1600                 return;
1601         }
1602
1603         my $result = "Path: $path_arg\n";
1604         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1605         $result .= "URL: $full_url\n";
1606
1607         eval {
1608                 my $repos_root = $gs->repos_root;
1609                 Git::SVN::remove_username($repos_root);
1610                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1611         };
1612         if ($@) {
1613                 $result .= "Repository Root: (offline)\n";
1614         }
1615         ::_req_svn();
1616         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1617                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1618         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1619
1620         $result .= "Node Kind: " .
1621                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1622
1623         my $schedule = $diff_status eq "A"
1624                        ? "add"
1625                        : ($diff_status eq "D" ? "delete" : "normal");
1626         $result .= "Schedule: $schedule\n";
1627
1628         if ($diff_status eq "A") {
1629                 print $result, "\n";
1630                 return;
1631         }
1632
1633         my ($lc_author, $lc_rev, $lc_date_utc);
1634         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1635         my $log = command_output_pipe(@args);
1636         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1637         while (<$log>) {
1638                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1639                         $lc_author = $1;
1640                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1641                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1642                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1643                 }
1644         }
1645         close $log;
1646
1647         Git::SVN::Log::set_local_timezone();
1648
1649         $result .= "Last Changed Author: $lc_author\n";
1650         $result .= "Last Changed Rev: $lc_rev\n";
1651         $result .= "Last Changed Date: " .
1652                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1653
1654         if ($file_type ne "dir") {
1655                 my $text_last_updated_date =
1656                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1657                 $result .=
1658                     "Text Last Updated: " .
1659                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1660                     "\n";
1661                 my $checksum;
1662                 if ($diff_status eq "D") {
1663                         my ($fh, $ctx) =
1664                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1665                         if ($file_type eq "link") {
1666                                 my $file_name = <$fh>;
1667                                 $checksum = md5sum("link $file_name");
1668                         } else {
1669                                 $checksum = md5sum($fh);
1670                         }
1671                         command_close_pipe($fh, $ctx);
1672                 } elsif ($file_type eq "link") {
1673                         my $file_name =
1674                             command(qw(cat-file blob), "HEAD:$path");
1675                         $checksum =
1676                             md5sum("link " . $file_name);
1677                 } else {
1678                         open FILE, "<", $path or die $!;
1679                         $checksum = md5sum(\*FILE);
1680                         close FILE or die $!;
1681                 }
1682                 $result .= "Checksum: " . $checksum . "\n";
1683         }
1684
1685         print $result, "\n";
1686 }
1687
1688 sub cmd_reset {
1689         my $target = shift || $_revision or die "SVN revision required\n";
1690         $target = $1 if $target =~ /^r(\d+)$/;
1691         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1692         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1693         unless ($gs) {
1694                 die "Unable to determine upstream SVN information from ".
1695                     "history\n";
1696         }
1697         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1698         die "Cannot find SVN revision $target\n" unless defined($c);
1699         $gs->rev_map_set($r, $c, 'reset', $uuid);
1700         print "r$r = $c ($gs->{ref_id})\n";
1701 }
1702
1703 sub cmd_gc {
1704         require File::Find;
1705         if (!can_compress()) {
1706                 warn "Compress::Zlib could not be found; unhandled.log " .
1707                      "files will not be compressed.\n";
1708         }
1709         File::Find::find({ wanted => \&gc_directory, no_chdir => 1},
1710                          Git::SVN::svn_dir());
1711 }
1712
1713 ########################### utility functions #########################
1714
1715 sub rebase_cmd {
1716         my @cmd = qw/rebase/;
1717         push @cmd, '-v' if $_verbose;
1718         push @cmd, qw/--merge/ if $_merge;
1719         push @cmd, "--strategy=$_strategy" if $_strategy;
1720         push @cmd, "--preserve-merges" if $_preserve_merges;
1721         @cmd;
1722 }
1723
1724 sub post_fetch_checkout {
1725         return if $_no_checkout;
1726         return if verify_ref('HEAD^0');
1727         my $gs = $Git::SVN::_head or return;
1728
1729         # look for "trunk" ref if it exists
1730         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1731         my $fetch = $remote->{fetch};
1732         if ($fetch) {
1733                 foreach my $p (keys %$fetch) {
1734                         basename($fetch->{$p}) eq 'trunk' or next;
1735                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1736                         last;
1737                 }
1738         }
1739
1740         command_noisy(qw(update-ref HEAD), $gs->refname);
1741         return unless verify_ref('HEAD^0');
1742
1743         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1744         my $index = command_oneline(qw(rev-parse --git-path index));
1745         return if -f $index;
1746
1747         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1748         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1749         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1750         print STDERR "Checked out HEAD:\n  ",
1751                      $gs->full_url, " r", $gs->last_rev, "\n";
1752         if (auto_create_empty_directories($gs)) {
1753                 $gs->mkemptydirs($gs->last_rev);
1754         }
1755 }
1756
1757 sub complete_svn_url {
1758         my ($url, $path) = @_;
1759
1760         if ($path =~ m#^[a-z\+]+://#i) { # path is a URL
1761                 $path = canonicalize_url($path);
1762         } else {
1763                 $path = canonicalize_path($path);
1764                 if (!defined $url || $url !~ m#^[a-z\+]+://#i) {
1765                         fatal("E: '$path' is not a complete URL ",
1766                               "and a separate URL is not specified");
1767                 }
1768                 return ($url, $path);
1769         }
1770         return ($path, '');
1771 }
1772
1773 sub complete_url_ls_init {
1774         my ($ra, $repo_path, $switch, $pfx) = @_;
1775         unless ($repo_path) {
1776                 print STDERR "W: $switch not specified\n";
1777                 return;
1778         }
1779         if ($repo_path =~ m#^[a-z\+]+://#i) {
1780                 $repo_path = canonicalize_url($repo_path);
1781                 $ra = Git::SVN::Ra->new($repo_path);
1782                 $repo_path = '';
1783         } else {
1784                 $repo_path = canonicalize_path($repo_path);
1785                 $repo_path =~ s#^/+##;
1786                 unless ($ra) {
1787                         fatal("E: '$repo_path' is not a complete URL ",
1788                               "and a separate URL is not specified");
1789                 }
1790         }
1791         my $url = $ra->url;
1792         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1793         my $k = "svn-remote.$gs->{repo_id}.url";
1794         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1795         if ($orig_url && ($orig_url ne $gs->url)) {
1796                 die "$k already set: $orig_url\n",
1797                     "wanted to set to: $gs->url\n";
1798         }
1799         command_oneline('config', $k, $gs->url) unless $orig_url;
1800
1801         my $remote_path = join_paths( $gs->path, $repo_path );
1802         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1803         $remote_path =~ s#^/##g;
1804         $remote_path .= "/*" if $remote_path !~ /\*/;
1805         my ($n) = ($switch =~ /^--(\w+)/);
1806         if (length $pfx && $pfx !~ m#/$#) {
1807                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1808         }
1809         command_noisy('config',
1810                       '--add',
1811                       "svn-remote.$gs->{repo_id}.$n",
1812                       "$remote_path:refs/remotes/$pfx*" .
1813                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1814 }
1815
1816 sub verify_ref {
1817         my ($ref) = @_;
1818         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1819                                { STDERR => 0 }); };
1820 }
1821
1822 sub get_tree_from_treeish {
1823         my ($treeish) = @_;
1824         # $treeish can be a symbolic ref, too:
1825         my $type = command_oneline(qw/cat-file -t/, $treeish);
1826         my $expected;
1827         while ($type eq 'tag') {
1828                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1829         }
1830         if ($type eq 'commit') {
1831                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1832                                                     $treeish))[0];
1833                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1834                 die "Unable to get tree from $treeish\n" unless $expected;
1835         } elsif ($type eq 'tree') {
1836                 $expected = $treeish;
1837         } else {
1838                 die "$treeish is a $type, expected tree, tag or commit\n";
1839         }
1840         return $expected;
1841 }
1842
1843 sub get_commit_entry {
1844         my ($treeish) = shift;
1845         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1846         my @git_path = qw(rev-parse --git-path);
1847         my $commit_editmsg = command_oneline(@git_path, 'COMMIT_EDITMSG');
1848         my $commit_msg = command_oneline(@git_path, 'COMMIT_MSG');
1849         open my $log_fh, '>', $commit_editmsg or croak $!;
1850
1851         my $type = command_oneline(qw/cat-file -t/, $treeish);
1852         if ($type eq 'commit' || $type eq 'tag') {
1853                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1854                                                          $type, $treeish);
1855                 my $in_msg = 0;
1856                 my $author;
1857                 my $saw_from = 0;
1858                 my $msgbuf = "";
1859                 while (<$msg_fh>) {
1860                         if (!$in_msg) {
1861                                 $in_msg = 1 if (/^$/);
1862                                 $author = $1 if (/^author (.*>)/);
1863                         } elsif (/^git-svn-id: /) {
1864                                 # skip this for now, we regenerate the
1865                                 # correct one on re-fetch anyways
1866                                 # TODO: set *:merge properties or like...
1867                         } else {
1868                                 if (/^From:/ || /^Signed-off-by:/) {
1869                                         $saw_from = 1;
1870                                 }
1871                                 $msgbuf .= $_;
1872                         }
1873                 }
1874                 $msgbuf =~ s/\s+$//s;
1875                 $msgbuf =~ s/\r\n/\n/sg; # SVN 1.6+ disallows CRLF
1876                 if ($Git::SVN::_add_author_from && defined($author)
1877                     && !$saw_from) {
1878                         $msgbuf .= "\n\nFrom: $author";
1879                 }
1880                 print $log_fh $msgbuf or croak $!;
1881                 command_close_pipe($msg_fh, $ctx);
1882         }
1883         close $log_fh or croak $!;
1884
1885         if ($_edit || ($type eq 'tree')) {
1886                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1887                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1888         }
1889         rename $commit_editmsg, $commit_msg or croak $!;
1890         {
1891                 require Encode;
1892                 # SVN requires messages to be UTF-8 when entering the repo
1893                 open $log_fh, '<', $commit_msg or croak $!;
1894                 binmode $log_fh;
1895                 chomp($log_entry{log} = get_record($log_fh, undef));
1896
1897                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1898                 my $msg = $log_entry{log};
1899
1900                 eval { $msg = Encode::decode($enc, $msg, 1) };
1901                 if ($@) {
1902                         die "Could not decode as $enc:\n", $msg,
1903                             "\nPerhaps you need to set i18n.commitencoding\n";
1904                 }
1905
1906                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1907                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1908
1909                 $log_entry{log} = $msg;
1910
1911                 close $log_fh or croak $!;
1912         }
1913         unlink $commit_msg;
1914         \%log_entry;
1915 }
1916
1917 sub s_to_file {
1918         my ($str, $file, $mode) = @_;
1919         open my $fd,'>',$file or croak $!;
1920         print $fd $str,"\n" or croak $!;
1921         close $fd or croak $!;
1922         chmod ($mode &~ umask, $file) if (defined $mode);
1923 }
1924
1925 sub file_to_s {
1926         my $file = shift;
1927         open my $fd,'<',$file or croak "$!: file: $file\n";
1928         local $/;
1929         my $ret = <$fd>;
1930         close $fd or croak $!;
1931         $ret =~ s/\s*$//s;
1932         return $ret;
1933 }
1934
1935 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1936 sub load_authors {
1937         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1938         my $log = $cmd eq 'log';
1939         while (<$authors>) {
1940                 chomp;
1941                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.*)>\s*$/;
1942                 my ($user, $name, $email) = ($1, $2, $3);
1943                 if ($log) {
1944                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1945                 } else {
1946                         $users{$user} = [$name, $email];
1947                 }
1948         }
1949         close $authors or croak $!;
1950 }
1951
1952 # convert GetOpt::Long specs for use by git-config
1953 sub read_git_config {
1954         my $opts = shift;
1955         my @config_only;
1956         foreach my $o (keys %$opts) {
1957                 # if we have mixedCase and a long option-only, then
1958                 # it's a config-only variable that we don't need for
1959                 # the command-line.
1960                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1961                 my $v = $opts->{$o};
1962                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1963                 $key =~ s/-//g;
1964                 my $arg = 'git config';
1965                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1966                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1967                 if (ref $v eq 'ARRAY') {
1968                         chomp(my @tmp = `$arg --get-all svn.$key`);
1969                         @$v = @tmp if @tmp;
1970                 } else {
1971                         chomp(my $tmp = `$arg --get svn.$key`);
1972                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1973                                 $$v = $tmp;
1974                         }
1975                 }
1976         }
1977         delete @$opts{@config_only} if @config_only;
1978 }
1979
1980 sub extract_metadata {
1981         my $id = shift or return (undef, undef, undef);
1982         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1983                                                         \s([a-f\d\-]+)$/ix);
1984         if (!defined $rev || !$uuid || !$url) {
1985                 # some of the original repositories I made had
1986                 # identifiers like this:
1987                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1988         }
1989         return ($url, $rev, $uuid);
1990 }
1991
1992 sub cmt_metadata {
1993         return extract_metadata((grep(/^git-svn-id: /,
1994                 command(qw/cat-file commit/, shift)))[-1]);
1995 }
1996
1997 sub cmt_sha2rev_batch {
1998         my %s2r;
1999         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
2000         my $list = shift;
2001
2002         foreach my $sha (@{$list}) {
2003                 my $first = 1;
2004                 my $size = 0;
2005                 print $out $sha, "\n";
2006
2007                 while (my $line = <$in>) {
2008                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
2009                                 last;
2010                         } elsif ($first &&
2011                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
2012                                 $first = 0;
2013                                 $size = $1;
2014                                 next;
2015                         } elsif ($line =~ /^(git-svn-id: )/) {
2016                                 my (undef, $rev, undef) =
2017                                                       extract_metadata($line);
2018                                 $s2r{$sha} = $rev;
2019                         }
2020
2021                         $size -= length($line);
2022                         last if ($size == 0);
2023                 }
2024         }
2025
2026         command_close_bidi_pipe($pid, $in, $out, $ctx);
2027
2028         return \%s2r;
2029 }
2030
2031 sub working_head_info {
2032         my ($head, $refs) = @_;
2033         my @args = qw/rev-list --first-parent --pretty=medium/;
2034         my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2035         my $hash;
2036         my %max;
2037         while (<$fh>) {
2038                 if ( m{^commit ($::sha1)$} ) {
2039                         unshift @$refs, $hash if $hash and $refs;
2040                         $hash = $1;
2041                         next;
2042                 }
2043                 next unless s{^\s*(git-svn-id:)}{$1};
2044                 my ($url, $rev, $uuid) = extract_metadata($_);
2045                 if (defined $url && defined $rev) {
2046                         next if $max{$url} and $max{$url} < $rev;
2047                         if (my $gs = Git::SVN->find_by_url($url)) {
2048                                 my $c = $gs->rev_map_get($rev, $uuid);
2049                                 if ($c && $c eq $hash) {
2050                                         close $fh; # break the pipe
2051                                         return ($url, $rev, $uuid, $gs);
2052                                 } else {
2053                                         $max{$url} ||= $gs->rev_map_max;
2054                                 }
2055                         }
2056                 }
2057         }
2058         command_close_pipe($fh, $ctx);
2059         (undef, undef, undef, undef);
2060 }
2061
2062 sub read_commit_parents {
2063         my ($parents, $c) = @_;
2064         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2065         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2066         @{$parents->{$c}} = split(/ /, $p);
2067 }
2068
2069 sub linearize_history {
2070         my ($gs, $refs) = @_;
2071         my %parents;
2072         foreach my $c (@$refs) {
2073                 read_commit_parents(\%parents, $c);
2074         }
2075
2076         my @linear_refs;
2077         my %skip = ();
2078         my $last_svn_commit = $gs->last_commit;
2079         foreach my $c (reverse @$refs) {
2080                 next if $c eq $last_svn_commit;
2081                 last if $skip{$c};
2082
2083                 unshift @linear_refs, $c;
2084                 $skip{$c} = 1;
2085
2086                 # we only want the first parent to diff against for linear
2087                 # history, we save the rest to inject when we finalize the
2088                 # svn commit
2089                 my $fp_a = verify_ref("$c~1");
2090                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2091                 if (!$fp_a || !$fp_b) {
2092                         die "Commit $c\n",
2093                             "has no parent commit, and therefore ",
2094                             "nothing to diff against.\n",
2095                             "You should be working from a repository ",
2096                             "originally created by git-svn\n";
2097                 }
2098                 if ($fp_a ne $fp_b) {
2099                         die "$c~1 = $fp_a, however parsing commit $c ",
2100                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2101                 }
2102
2103                 foreach my $p (@{$parents{$c}}) {
2104                         $skip{$p} = 1;
2105                 }
2106         }
2107         (\@linear_refs, \%parents);
2108 }
2109
2110 sub find_file_type_and_diff_status {
2111         my ($path) = @_;
2112         return ('dir', '') if $path eq '';
2113
2114         my $diff_output =
2115             command_oneline(qw(diff --cached --name-status --), $path) || "";
2116         my $diff_status = (split(' ', $diff_output))[0] || "";
2117
2118         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2119
2120         return (undef, undef) if !$diff_status && !$ls_tree;
2121
2122         if ($diff_status eq "A") {
2123                 return ("link", $diff_status) if -l $path;
2124                 return ("dir", $diff_status) if -d $path;
2125                 return ("file", $diff_status);
2126         }
2127
2128         my $mode = (split(' ', $ls_tree))[0] || "";
2129
2130         return ("link", $diff_status) if $mode eq "120000";
2131         return ("dir", $diff_status) if $mode eq "040000";
2132         return ("file", $diff_status);
2133 }
2134
2135 sub md5sum {
2136         my $arg = shift;
2137         my $ref = ref $arg;
2138         require Digest::MD5;
2139         my $md5 = Digest::MD5->new();
2140         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2141                 $md5->addfile($arg) or croak $!;
2142         } elsif ($ref eq 'SCALAR') {
2143                 $md5->add($$arg) or croak $!;
2144         } elsif (!$ref) {
2145                 $md5->add($arg) or croak $!;
2146         } else {
2147                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2148         }
2149         return $md5->hexdigest();
2150 }
2151
2152 sub gc_directory {
2153         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2154                 my $out_filename = $_ . ".gz";
2155                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2156                 binmode $in_fh;
2157                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2158                                 die "Unable to open $out_filename: $!\n";
2159
2160                 my $res;
2161                 while ($res = sysread($in_fh, my $str, 1024)) {
2162                         $gz->gzwrite($str) or
2163                                 die "Unable to write: ".$gz->gzerror()."!\n";
2164                 }
2165                 no warnings 'once'; # $File::Find::name would warn
2166                 unlink $_ or die "unlink $File::Find::name: $!\n";
2167         } elsif (-f $_ && basename($_) eq "index") {
2168                 unlink $_ or die "unlink $_: $!\n";
2169         }
2170 }
2171
2172 __END__
2173
2174 Data structures:
2175
2176
2177 $remotes = { # returned by read_all_remotes()
2178         'svn' => {
2179                 # svn-remote.svn.url=https://svn.musicpd.org
2180                 url => 'https://svn.musicpd.org',
2181                 # svn-remote.svn.fetch=mpd/trunk:trunk
2182                 fetch => {
2183                         'mpd/trunk' => 'trunk',
2184                 },
2185                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2186                 tags => {
2187                         path => {
2188                                 left => 'mpd/tags',
2189                                 right => '',
2190                                 regex => qr!mpd/tags/([^/]+)$!,
2191                                 glob => 'tags/*',
2192                         },
2193                         ref => {
2194                                 left => 'tags',
2195                                 right => '',
2196                                 regex => qr!tags/([^/]+)$!,
2197                                 glob => 'tags/*',
2198                         },
2199                 }
2200         }
2201 };
2202
2203 $log_entry hashref as returned by libsvn_log_entry()
2204 {
2205         log => 'whitespace-formatted log entry
2206 ',                                              # trailing newline is preserved
2207         revision => '8',                        # integer
2208         date => '2004-02-24T17:01:44.108345Z',  # commit date
2209         author => 'committer name'
2210 };
2211
2212
2213 # this is generated by generate_diff();
2214 @mods = array of diff-index line hashes, each element represents one line
2215         of diff-index output
2216
2217 diff-index line ($m hash)
2218 {
2219         mode_a => first column of diff-index output, no leading ':',
2220         mode_b => second column of diff-index output,
2221         sha1_b => sha1sum of the final blob,
2222         chg => change type [MCRADT],
2223         file_a => original file name of a file (iff chg is 'C' or 'R')
2224         file_b => new/current file name of a file (any chg)
2225 }
2226 ;
2227
2228 # retval of read_url_paths{,_all}();
2229 $l_map = {
2230         # repository root url
2231         'https://svn.musicpd.org' => {
2232                 # repository path               # GIT_SVN_ID
2233                 'mpd/trunk'             =>      'trunk',
2234                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2235         },
2236 }
2237
2238 Notes:
2239         I don't trust the each() function on unless I created %hash myself
2240         because the internal iterator may not have started at base.