git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49 git send-email --dump-aliases
  50
  51   Composing:
  52     --from                  <str>  * Email From:
  53     --[no-]to               <str>  * Email To:
  54     --[no-]cc               <str>  * Email Cc:
  55     --[no-]bcc              <str>  * Email Bcc:
  56     --subject               <str>  * Email "Subject:"
  57     --in-reply-to           <str>  * Email "In-Reply-To:"
  58     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  59     --[no-]annotate                * Review each patch that will be sent in an editor.
  60     --compose                      * Open an editor for introduction.
  61     --compose-encoding      <str>  * Encoding to assume for introduction.
  62     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  63     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  64
  65   Sending:
  66     --envelope-sender       <str>  * Email envelope sender.
  67     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  68                                      is optional. Default 'localhost'.
  69     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  70     --smtp-server-port      <int>  * Outgoing SMTP server port.
  71     --smtp-user             <str>  * Username for SMTP-AUTH.
  72     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  73     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  74     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  75     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  76                                      Pass an empty string to disable certificate
  77                                      verification.
  78     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  79     --smtp-auth             <str>  * Space-separated list of allowed AUTH mechanisms.
  80                                      This setting forces to use one of the listed mechanisms.
  81     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  82
  83   Automating:
  84     --identity              <str>  * Use the sendemail.<id> options.
  85     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  86     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  87     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  88     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  89     --[no-]to-cover                * Email To: addresses in the cover letter.
  90     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  91     --[no-]suppress-from           * Send to self. Default off.
  92     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  93     --[no-]thread                  * Use In-Reply-To: field. Default on.
  94
  95   Administering:
  96     --confirm               <str>  * Confirm recipients before sending;
  97                                      auto, cc, compose, always, or never.
  98     --quiet                        * Output one line of info per email.
  99     --dry-run                      * Don't actually send the emails.
 100     --[no-]validate                * Perform patch sanity checks. Default on.
 101     --[no-]format-patch            * understand any non optional arguments as
 102                                      `git format-patch` ones.
 103     --force                        * Send even if safety checks would prevent it.
 104
 105   Information:
 106     --dump-aliases                 * Dump configured aliases and exit.
 107
 108 EOT
 109         exit(1);
 110 }
 111
 112 # most mail servers generate the Date: header, but not all...
 113 sub format_2822_time {
 114         my ($time) = @_;
 115         my @localtm = localtime($time);
 116         my @gmttm = gmtime($time);
 117         my $localmin = $localtm[1] + $localtm[2] * 60;
 118         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 119         if ($localtm[0] != $gmttm[0]) {
 120                 die "local zone differs from GMT by a non-minute interval\n";
 121         }
 122         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 123                 $localmin += 1440;
 124         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 125                 $localmin -= 1440;
 126         } elsif ($gmttm[6] != $localtm[6]) {
 127                 die "local time offset greater than or equal to 24 hours\n";
 128         }
 129         my $offset = $localmin - $gmtmin;
 130         my $offhour = $offset / 60;
 131         my $offmin = abs($offset % 60);
 132         if (abs($offhour) >= 24) {
 133                 die ("local time offset greater than or equal to 24 hours\n");
 134         }
 135
 136         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 137                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 138                        $localtm[3],
 139                        qw(Jan Feb Mar Apr May Jun
 140                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 141                        $localtm[5]+1900,
 142                        $localtm[2],
 143                        $localtm[1],
 144                        $localtm[0],
 145                        ($offset >= 0) ? '+' : '-',
 146                        abs($offhour),
 147                        $offmin,
 148                        );
 149 }
 150
 151 my $have_email_valid = eval { require Email::Valid; 1 };
 152 my $have_mail_address = eval { require Mail::Address; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 # Regexes for RFC 2047 productions.
 157 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 158 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 159 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 160
 161 # Variables we fill in automatically, or via prompting:
 162 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 163         $initial_reply_to,$initial_subject,@files,
 164         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184 my $format_patch;
 185 my $compose_filename;
 186 my $force = 0;
 187 my $dump_aliases = 0;
 188
 189 # Handle interactive edition of files.
 190 my $multiedit;
 191 my $editor;
 192
 193 sub do_edit {
 194         if (!defined($editor)) {
 195                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 196         }
 197         if (defined($multiedit) && !$multiedit) {
 198                 map {
 199                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 200                         if (($? & 127) || ($? >> 8)) {
 201                                 die("the editor exited uncleanly, aborting everything");
 202                         }
 203                 } @_;
 204         } else {
 205                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 206                 if (($? & 127) || ($? >> 8)) {
 207                         die("the editor exited uncleanly, aborting everything");
 208                 }
 209         }
 210 }
 211
 212 # Variables with corresponding config settings
 213 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 214 my ($cover_cc, $cover_to);
 215 my ($to_cmd, $cc_cmd);
 216 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 217 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 218 my ($identity, $aliasfiletype, @alias_files, $smtp_domain, $smtp_auth);
 219 my ($validate, $confirm);
 220 my (@suppress_cc);
 221 my ($auto_8bit_encoding);
 222 my ($compose_encoding);
 223 my ($target_xfer_encoding);
 224
 225 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 226
 227 my %config_bool_settings = (
 228     "thread" => [\$thread, 1],
 229     "chainreplyto" => [\$chain_reply_to, 0],
 230     "suppressfrom" => [\$suppress_from, undef],
 231     "signedoffbycc" => [\$signed_off_by_cc, undef],
 232     "cccover" => [\$cover_cc, undef],
 233     "tocover" => [\$cover_to, undef],
 234     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 235     "validate" => [\$validate, 1],
 236     "multiedit" => [\$multiedit, undef],
 237     "annotate" => [\$annotate, undef],
 238     "xmailer" => [\$use_xmailer, 1]
 239 );
 240
 241 my %config_settings = (
 242     "smtpserver" => \$smtp_server,
 243     "smtpserverport" => \$smtp_server_port,
 244     "smtpserveroption" => \@smtp_server_options,
 245     "smtpuser" => \$smtp_authuser,
 246     "smtppass" => \$smtp_authpass,
 247     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 248     "smtpdomain" => \$smtp_domain,
 249     "smtpauth" => \$smtp_auth,
 250     "to" => \@initial_to,
 251     "tocmd" => \$to_cmd,
 252     "cc" => \@initial_cc,
 253     "cccmd" => \$cc_cmd,
 254     "aliasfiletype" => \$aliasfiletype,
 255     "bcc" => \@bcclist,
 256     "suppresscc" => \@suppress_cc,
 257     "envelopesender" => \$envelope_sender,
 258     "confirm"   => \$confirm,
 259     "from" => \$sender,
 260     "assume8bitencoding" => \$auto_8bit_encoding,
 261     "composeencoding" => \$compose_encoding,
 262     "transferencoding" => \$target_xfer_encoding,
 263 );
 264
 265 my %config_path_settings = (
 266     "aliasesfile" => \@alias_files,
 267 );
 268
 269 # Handle Uncouth Termination
 270 sub signal_handler {
 271
 272         # Make text normal
 273         print color("reset"), "\n";
 274
 275         # SMTP password masked
 276         system "stty echo";
 277
 278         # tmp files from --compose
 279         if (defined $compose_filename) {
 280                 if (-e $compose_filename) {
 281                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 282                 }
 283                 if (-e ($compose_filename . ".final")) {
 284                         print "'$compose_filename.final' contains the composed email.\n"
 285                 }
 286         }
 287
 288         exit;
 289 };
 290
 291 $SIG{TERM} = \&signal_handler;
 292 $SIG{INT}  = \&signal_handler;
 293
 294 # Begin by accumulating all the variables (defined above), that we will end up
 295 # needing, first, from the command line:
 296
 297 my $help;
 298 my $rc = GetOptions("h" => \$help,
 299                     "dump-aliases" => \$dump_aliases);
 300 usage() unless $rc;
 301 die "--dump-aliases incompatible with other options\n"
 302     if !$help and $dump_aliases and @ARGV;
 303 $rc = GetOptions(
 304                     "sender|from=s" => \$sender,
 305                     "in-reply-to=s" => \$initial_reply_to,
 306                     "subject=s" => \$initial_subject,
 307                     "to=s" => \@initial_to,
 308                     "to-cmd=s" => \$to_cmd,
 309                     "no-to" => \$no_to,
 310                     "cc=s" => \@initial_cc,
 311                     "no-cc" => \$no_cc,
 312                     "bcc=s" => \@bcclist,
 313                     "no-bcc" => \$no_bcc,
 314                     "chain-reply-to!" => \$chain_reply_to,
 315                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 316                     "smtp-server=s" => \$smtp_server,
 317                     "smtp-server-option=s" => \@smtp_server_options,
 318                     "smtp-server-port=s" => \$smtp_server_port,
 319                     "smtp-user=s" => \$smtp_authuser,
 320                     "smtp-pass:s" => \$smtp_authpass,
 321                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 322                     "smtp-encryption=s" => \$smtp_encryption,
 323                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 324                     "smtp-debug:i" => \$debug_net_smtp,
 325                     "smtp-domain:s" => \$smtp_domain,
 326                     "smtp-auth=s" => \$smtp_auth,
 327                     "identity=s" => \$identity,
 328                     "annotate!" => \$annotate,
 329                     "no-annotate" => sub {$annotate = 0},
 330                     "compose" => \$compose,
 331                     "quiet" => \$quiet,
 332                     "cc-cmd=s" => \$cc_cmd,
 333                     "suppress-from!" => \$suppress_from,
 334                     "no-suppress-from" => sub {$suppress_from = 0},
 335                     "suppress-cc=s" => \@suppress_cc,
 336                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 337                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 338                     "cc-cover|cc-cover!" => \$cover_cc,
 339                     "no-cc-cover" => sub {$cover_cc = 0},
 340                     "to-cover|to-cover!" => \$cover_to,
 341                     "no-to-cover" => sub {$cover_to = 0},
 342                     "confirm=s" => \$confirm,
 343                     "dry-run" => \$dry_run,
 344                     "envelope-sender=s" => \$envelope_sender,
 345                     "thread!" => \$thread,
 346                     "no-thread" => sub {$thread = 0},
 347                     "validate!" => \$validate,
 348                     "no-validate" => sub {$validate = 0},
 349                     "transfer-encoding=s" => \$target_xfer_encoding,
 350                     "format-patch!" => \$format_patch,
 351                     "no-format-patch" => sub {$format_patch = 0},
 352                     "8bit-encoding=s" => \$auto_8bit_encoding,
 353                     "compose-encoding=s" => \$compose_encoding,
 354                     "force" => \$force,
 355                     "xmailer!" => \$use_xmailer,
 356                     "no-xmailer" => sub {$use_xmailer = 0},
 357          );
 358
 359 usage() if $help;
 360 unless ($rc) {
 361     usage();
 362 }
 363
 364 die "Cannot run git format-patch from outside a repository\n"
 365         if $format_patch and not $repo;
 366
 367 # Now, let's fill any that aren't set in with defaults:
 368
 369 sub read_config {
 370         my ($prefix) = @_;
 371
 372         foreach my $setting (keys %config_bool_settings) {
 373                 my $target = $config_bool_settings{$setting}->[0];
 374                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 375         }
 376
 377         foreach my $setting (keys %config_path_settings) {
 378                 my $target = $config_path_settings{$setting};
 379                 if (ref($target) eq "ARRAY") {
 380                         unless (@$target) {
 381                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 382                                 @$target = @values if (@values && defined $values[0]);
 383                         }
 384                 }
 385                 else {
 386                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 387                 }
 388         }
 389
 390         foreach my $setting (keys %config_settings) {
 391                 my $target = $config_settings{$setting};
 392                 next if $setting eq "to" and defined $no_to;
 393                 next if $setting eq "cc" and defined $no_cc;
 394                 next if $setting eq "bcc" and defined $no_bcc;
 395                 if (ref($target) eq "ARRAY") {
 396                         unless (@$target) {
 397                                 my @values = Git::config(@repo, "$prefix.$setting");
 398                                 @$target = @values if (@values && defined $values[0]);
 399                         }
 400                 }
 401                 else {
 402                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 403                 }
 404         }
 405
 406         if (!defined $smtp_encryption) {
 407                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 408                 if (defined $enc) {
 409                         $smtp_encryption = $enc;
 410                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 411                         $smtp_encryption = 'ssl';
 412                 }
 413         }
 414 }
 415
 416 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 417 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 418 read_config("sendemail.$identity") if (defined $identity);
 419 read_config("sendemail");
 420
 421 # fall back on builtin bool defaults
 422 foreach my $setting (values %config_bool_settings) {
 423         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 424 }
 425
 426 # 'default' encryption is none -- this only prevents a warning
 427 $smtp_encryption = '' unless (defined $smtp_encryption);
 428
 429 # Set CC suppressions
 430 my(%suppress_cc);
 431 if (@suppress_cc) {
 432         foreach my $entry (@suppress_cc) {
 433                 die "Unknown --suppress-cc field: '$entry'\n"
 434                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 435                 $suppress_cc{$entry} = 1;
 436         }
 437 }
 438
 439 if ($suppress_cc{'all'}) {
 440         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 441                 $suppress_cc{$entry} = 1;
 442         }
 443         delete $suppress_cc{'all'};
 444 }
 445
 446 # If explicit old-style ones are specified, they trump --suppress-cc.
 447 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 448 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 449
 450 if ($suppress_cc{'body'}) {
 451         foreach my $entry (qw (sob bodycc)) {
 452                 $suppress_cc{$entry} = 1;
 453         }
 454         delete $suppress_cc{'body'};
 455 }
 456
 457 # Set confirm's default value
 458 my $confirm_unconfigured = !defined $confirm;
 459 if ($confirm_unconfigured) {
 460         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 461 };
 462 die "Unknown --confirm setting: '$confirm'\n"
 463         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 464
 465 # Debugging, print out the suppressions.
 466 if (0) {
 467         print "suppressions:\n";
 468         foreach my $entry (keys %suppress_cc) {
 469                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 470         }
 471 }
 472
 473 my ($repoauthor, $repocommitter);
 474 ($repoauthor) = Git::ident_person(@repo, 'author');
 475 ($repocommitter) = Git::ident_person(@repo, 'committer');
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return Git::parse_mailboxes($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/:include:/) {
 496                 print STDERR "warning: `:include:` not supported: $_\n";
 497         } elsif (/[\/|]/) {
 498                 print STDERR "warning: `/file` or `|pipe` redirection not supported: $_\n";
 499         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 500                 my ($alias, $addr) = ($1, $2);
 501                 $aliases{$alias} = [ split_addrs($addr) ];
 502         } else {
 503                 print STDERR "warning: sendmail line is not recognized: $_\n";
 504         }
 505 }
 506
 507 sub parse_sendmail_aliases {
 508         my $fh = shift;
 509         my $s = '';
 510         while (<$fh>) {
 511                 chomp;
 512                 next if /^\s*$/ || /^\s*#/;
 513                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 514                 parse_sendmail_alias($s) if $s;
 515                 $s = $_;
 516         }
 517         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 518         parse_sendmail_alias($s) if $s;
 519 }
 520
 521 my %parse_alias = (
 522         # multiline formats can be supported in the future
 523         mutt => sub { my $fh = shift; while (<$fh>) {
 524                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 525                         my ($alias, $addr) = ($1, $2);
 526                         $addr =~ s/#.*$//; # mutt allows # comments
 527                          # commas delimit multiple addresses
 528                         $aliases{$alias} = [ split_addrs($addr) ];
 529                 }}},
 530         mailrc => sub { my $fh = shift; while (<$fh>) {
 531                 if (/^alias\s+(\S+)\s+(.*)$/) {
 532                         # spaces delimit multiple addresses
 533                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 534                 }}},
 535         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 536                 for (my $x = ''; defined($x); $x = $_) {
 537                         chomp $x;
 538                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 539                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 540                         $aliases{$1} = [ split_addrs($2) ];
 541                 }},
 542         elm => sub  { my $fh = shift;
 543                       while (<$fh>) {
 544                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 545                               my ($alias, $addr) = ($1, $2);
 546                                $aliases{$alias} = [ split_addrs($addr) ];
 547                           }
 548                       } },
 549         sendmail => \&parse_sendmail_aliases,
 550         gnus => sub { my $fh = shift; while (<$fh>) {
 551                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 552                         $aliases{$1} = [ $2 ];
 553                 }}}
 554 );
 555
 556 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 557         foreach my $file (@alias_files) {
 558                 open my $fh, '<', $file or die "opening $file: $!\n";
 559                 $parse_alias{$aliasfiletype}->($fh);
 560                 close $fh;
 561         }
 562 }
 563
 564 if ($dump_aliases) {
 565     print "$_\n" for (sort keys %aliases);
 566     exit(0);
 567 }
 568
 569 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 570 # $f is a revision list specification to be passed to format-patch.
 571 sub is_format_patch_arg {
 572         return unless $repo;
 573         my $f = shift;
 574         try {
 575                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 576                 if (defined($format_patch)) {
 577                         return $format_patch;
 578                 }
 579                 die(<<EOF);
 580 File '$f' exists but it could also be the range of commits
 581 to produce patches for.  Please disambiguate by...
 582
 583     * Saying "./$f" if you mean a file; or
 584     * Giving --format-patch option if you mean a range.
 585 EOF
 586         } catch Git::Error::Command with {
 587                 # Not a valid revision.  Treat it as a filename.
 588                 return 0;
 589         }
 590 }
 591
 592 # Now that all the defaults are set, process the rest of the command line
 593 # arguments and collect up the files that need to be processed.
 594 my @rev_list_opts;
 595 while (defined(my $f = shift @ARGV)) {
 596         if ($f eq "--") {
 597                 push @rev_list_opts, "--", @ARGV;
 598                 @ARGV = ();
 599         } elsif (-d $f and !is_format_patch_arg($f)) {
 600                 opendir my $dh, $f
 601                         or die "Failed to opendir $f: $!";
 602
 603                 push @files, grep { -f $_ } map { catfile($f, $_) }
 604                                 sort readdir $dh;
 605                 closedir $dh;
 606         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 607                 push @files, $f;
 608         } else {
 609                 push @rev_list_opts, $f;
 610         }
 611 }
 612
 613 if (@rev_list_opts) {
 614         die "Cannot run git format-patch from outside a repository\n"
 615                 unless $repo;
 616         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 617 }
 618
 619 if ($validate) {
 620         foreach my $f (@files) {
 621                 unless (-p $f) {
 622                         my $error = validate_patch($f);
 623                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 624                 }
 625         }
 626 }
 627
 628 if (@files) {
 629         unless ($quiet) {
 630                 print $_,"\n" for (@files);
 631         }
 632 } else {
 633         print STDERR "\nNo patch files specified!\n\n";
 634         usage();
 635 }
 636
 637 sub get_patch_subject {
 638         my $fn = shift;
 639         open (my $fh, '<', $fn);
 640         while (my $line = <$fh>) {
 641                 next unless ($line =~ /^Subject: (.*)$/);
 642                 close $fh;
 643                 return "GIT: $1\n";
 644         }
 645         close $fh;
 646         die "No subject line in $fn ?";
 647 }
 648
 649 if ($compose) {
 650         # Note that this does not need to be secure, but we will make a small
 651         # effort to have it be unique
 652         $compose_filename = ($repo ?
 653                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 654                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 655         open my $c, ">", $compose_filename
 656                 or die "Failed to open for writing $compose_filename: $!";
 657
 658
 659         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 660         my $tpl_subject = $initial_subject || '';
 661         my $tpl_reply_to = $initial_reply_to || '';
 662
 663         print $c <<EOT;
 664 From $tpl_sender # This line is ignored.
 665 GIT: Lines beginning in "GIT:" will be removed.
 666 GIT: Consider including an overall diffstat or table of contents
 667 GIT: for the patch you are writing.
 668 GIT:
 669 GIT: Clear the body content if you don't wish to send a summary.
 670 From: $tpl_sender
 671 Subject: $tpl_subject
 672 In-Reply-To: $tpl_reply_to
 673
 674 EOT
 675         for my $f (@files) {
 676                 print $c get_patch_subject($f);
 677         }
 678         close $c;
 679
 680         if ($annotate) {
 681                 do_edit($compose_filename, @files);
 682         } else {
 683                 do_edit($compose_filename);
 684         }
 685
 686         open my $c2, ">", $compose_filename . ".final"
 687                 or die "Failed to open $compose_filename.final : " . $!;
 688
 689         open $c, "<", $compose_filename
 690                 or die "Failed to open $compose_filename : " . $!;
 691
 692         my $need_8bit_cte = file_has_nonascii($compose_filename);
 693         my $in_body = 0;
 694         my $summary_empty = 1;
 695         if (!defined $compose_encoding) {
 696                 $compose_encoding = "UTF-8";
 697         }
 698         while(<$c>) {
 699                 next if m/^GIT:/;
 700                 if ($in_body) {
 701                         $summary_empty = 0 unless (/^\n$/);
 702                 } elsif (/^\n$/) {
 703                         $in_body = 1;
 704                         if ($need_8bit_cte) {
 705                                 print $c2 "MIME-Version: 1.0\n",
 706                                          "Content-Type: text/plain; ",
 707                                            "charset=$compose_encoding\n",
 708                                          "Content-Transfer-Encoding: 8bit\n";
 709                         }
 710                 } elsif (/^MIME-Version:/i) {
 711                         $need_8bit_cte = 0;
 712                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 713                         $initial_subject = $1;
 714                         my $subject = $initial_subject;
 715                         $_ = "Subject: " .
 716                                 quote_subject($subject, $compose_encoding) .
 717                                 "\n";
 718                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 719                         $initial_reply_to = $1;
 720                         next;
 721                 } elsif (/^From:\s*(.+)\s*$/i) {
 722                         $sender = $1;
 723                         next;
 724                 } elsif (/^(?:To|Cc|Bcc):/i) {
 725                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 726                         next;
 727                 }
 728                 print $c2 $_;
 729         }
 730         close $c;
 731         close $c2;
 732
 733         if ($summary_empty) {
 734                 print "Summary email is empty, skipping it\n";
 735                 $compose = -1;
 736         }
 737 } elsif ($annotate) {
 738         do_edit(@files);
 739 }
 740
 741 sub ask {
 742         my ($prompt, %arg) = @_;
 743         my $valid_re = $arg{valid_re};
 744         my $default = $arg{default};
 745         my $confirm_only = $arg{confirm_only};
 746         my $resp;
 747         my $i = 0;
 748         return defined $default ? $default : undef
 749                 unless defined $term->IN and defined fileno($term->IN) and
 750                        defined $term->OUT and defined fileno($term->OUT);
 751         while ($i++ < 10) {
 752                 $resp = $term->readline($prompt);
 753                 if (!defined $resp) { # EOF
 754                         print "\n";
 755                         return defined $default ? $default : undef;
 756                 }
 757                 if ($resp eq '' and defined $default) {
 758                         return $default;
 759                 }
 760                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 761                         return $resp;
 762                 }
 763                 if ($confirm_only) {
 764                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 765                         if (defined $yesno && $yesno =~ /y/i) {
 766                                 return $resp;
 767                         }
 768                 }
 769         }
 770         return;
 771 }
 772
 773 my %broken_encoding;
 774
 775 sub file_declares_8bit_cte {
 776         my $fn = shift;
 777         open (my $fh, '<', $fn);
 778         while (my $line = <$fh>) {
 779                 last if ($line =~ /^$/);
 780                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 781         }
 782         close $fh;
 783         return 0;
 784 }
 785
 786 foreach my $f (@files) {
 787         next unless (body_or_subject_has_nonascii($f)
 788                      && !file_declares_8bit_cte($f));
 789         $broken_encoding{$f} = 1;
 790 }
 791
 792 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 793         print "The following files are 8bit, but do not declare " .
 794                 "a Content-Transfer-Encoding.\n";
 795         foreach my $f (sort keys %broken_encoding) {
 796                 print "    $f\n";
 797         }
 798         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 799                                   valid_re => qr/.{4}/, confirm_only => 1,
 800                                   default => "UTF-8");
 801 }
 802
 803 if (!$force) {
 804         for my $f (@files) {
 805                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 806                         die "Refusing to send because the patch\n\t$f\n"
 807                                 . "has the template subject '*** SUBJECT HERE ***'. "
 808                                 . "Pass --force if you really want to send.\n";
 809                 }
 810         }
 811 }
 812
 813 if (defined $sender) {
 814         $sender =~ s/^\s+|\s+$//g;
 815         ($sender) = expand_aliases($sender);
 816 } else {
 817         $sender = $repoauthor || $repocommitter || '';
 818 }
 819
 820 # $sender could be an already sanitized address
 821 # (e.g. sendemail.from could be manually sanitized by user).
 822 # But it's a no-op to run sanitize_address on an already sanitized address.
 823 $sender = sanitize_address($sender);
 824
 825 my $prompting = 0;
 826 if (!@initial_to && !defined $to_cmd) {
 827         my $to = ask("Who should the emails be sent to (if any)? ",
 828                      default => "",
 829                      valid_re => qr/\@.*\./, confirm_only => 1);
 830         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 831         $prompting++;
 832 }
 833
 834 sub expand_aliases {
 835         return map { expand_one_alias($_) } @_;
 836 }
 837
 838 my %EXPANDED_ALIASES;
 839 sub expand_one_alias {
 840         my $alias = shift;
 841         if ($EXPANDED_ALIASES{$alias}) {
 842                 die "fatal: alias '$alias' expands to itself\n";
 843         }
 844         local $EXPANDED_ALIASES{$alias} = 1;
 845         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 846 }
 847
 848 @initial_to = process_address_list(@initial_to);
 849 @initial_cc = process_address_list(@initial_cc);
 850 @bcclist = process_address_list(@bcclist);
 851
 852 if ($thread && !defined $initial_reply_to && $prompting) {
 853         $initial_reply_to = ask(
 854                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 855                 default => "",
 856                 valid_re => qr/\@.*\./, confirm_only => 1);
 857 }
 858 if (defined $initial_reply_to) {
 859         $initial_reply_to =~ s/^\s*<?//;
 860         $initial_reply_to =~ s/>?\s*$//;
 861         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 862 }
 863
 864 if (!defined $smtp_server) {
 865         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 866                 if (-x $_) {
 867                         $smtp_server = $_;
 868                         last;
 869                 }
 870         }
 871         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 872 }
 873
 874 if ($compose && $compose > 0) {
 875         @files = ($compose_filename . ".final", @files);
 876 }
 877
 878 # Variables we set as part of the loop over files
 879 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 880         $needs_confirm, $message_num, $ask_default);
 881
 882 sub extract_valid_address {
 883         my $address = shift;
 884         my $local_part_regexp = qr/[^<>"\s@]+/;
 885         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 886
 887         # check for a local address:
 888         return $address if ($address =~ /^($local_part_regexp)$/);
 889
 890         $address =~ s/^\s*<(.*)>\s*$/$1/;
 891         if ($have_email_valid) {
 892                 return scalar Email::Valid->address($address);
 893         }
 894
 895         # less robust/correct than the monster regexp in Email::Valid,
 896         # but still does a 99% job, and one less dependency
 897         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 898         return;
 899 }
 900
 901 sub extract_valid_address_or_die {
 902         my $address = shift;
 903         $address = extract_valid_address($address);
 904         die "error: unable to extract a valid address from: $address\n"
 905                 if !$address;
 906         return $address;
 907 }
 908
 909 sub validate_address {
 910         my $address = shift;
 911         while (!extract_valid_address($address)) {
 912                 print STDERR "error: unable to extract a valid address from: $address\n";
 913                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 914                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 915                         default => 'q');
 916                 if (/^d/i) {
 917                         return undef;
 918                 } elsif (/^q/i) {
 919                         cleanup_compose_files();
 920                         exit(0);
 921                 }
 922                 $address = ask("Who should the email be sent to (if any)? ",
 923                         default => "",
 924                         valid_re => qr/\@.*\./, confirm_only => 1);
 925         }
 926         return $address;
 927 }
 928
 929 sub validate_address_list {
 930         return (grep { defined $_ }
 931                 map { validate_address($_) } @_);
 932 }
 933
 934 # Usually don't need to change anything below here.
 935
 936 # we make a "fake" message id by taking the current number
 937 # of seconds since the beginning of Unix time and tacking on
 938 # a random number to the end, in case we are called quicker than
 939 # 1 second since the last time we were called.
 940
 941 # We'll setup a template for the message id, using the "from" address:
 942
 943 my ($message_id_stamp, $message_id_serial);
 944 sub make_message_id {
 945         my $uniq;
 946         if (!defined $message_id_stamp) {
 947                 $message_id_stamp = sprintf("%s-%s", time, $$);
 948                 $message_id_serial = 0;
 949         }
 950         $message_id_serial++;
 951         $uniq = "$message_id_stamp-$message_id_serial";
 952
 953         my $du_part;
 954         for ($sender, $repocommitter, $repoauthor) {
 955                 $du_part = extract_valid_address(sanitize_address($_));
 956                 last if (defined $du_part and $du_part ne '');
 957         }
 958         if (not defined $du_part or $du_part eq '') {
 959                 require Sys::Hostname;
 960                 $du_part = 'user@' . Sys::Hostname::hostname();
 961         }
 962         my $message_id_template = "<%s-git-send-email-%s>";
 963         $message_id = sprintf($message_id_template, $uniq, $du_part);
 964         #print "new message id = $message_id\n"; # Was useful for debugging
 965 }
 966
 967
 968
 969 $time = time - scalar $#files;
 970
 971 sub unquote_rfc2047 {
 972         local ($_) = @_;
 973         my $charset;
 974         my $sep = qr/[ \t]+/;
 975         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 976                 my @words = split $sep, $&;
 977                 foreach (@words) {
 978                         m/$re_encoded_word/;
 979                         $charset = $1;
 980                         my $encoding = $2;
 981                         my $text = $3;
 982                         if ($encoding eq 'q' || $encoding eq 'Q') {
 983                                 $_ = $text;
 984                                 s/_/ /g;
 985                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 986                         } else {
 987                                 # other encodings not supported yet
 988                         }
 989                 }
 990                 join '', @words;
 991         }eg;
 992         return wantarray ? ($_, $charset) : $_;
 993 }
 994
 995 sub quote_rfc2047 {
 996         local $_ = shift;
 997         my $encoding = shift || 'UTF-8';
 998         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 999         s/(.*)/=\?$encoding\?q\?$1\?=/;
1000         return $_;
1001 }
1002
1003 sub is_rfc2047_quoted {
1004         my $s = shift;
1005         length($s) <= 75 &&
1006         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
1007 }
1008
1009 sub subject_needs_rfc2047_quoting {
1010         my $s = shift;
1011
1012         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1013 }
1014
1015 sub quote_subject {
1016         local $subject = shift;
1017         my $encoding = shift || 'UTF-8';
1018
1019         if (subject_needs_rfc2047_quoting($subject)) {
1020                 return quote_rfc2047($subject, $encoding);
1021         }
1022         return $subject;
1023 }
1024
1025 # use the simplest quoting being able to handle the recipient
1026 sub sanitize_address {
1027         my ($recipient) = @_;
1028
1029         # remove garbage after email address
1030         $recipient =~ s/(.*>).*$/$1/;
1031
1032         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1033
1034         if (not $recipient_name) {
1035                 return $recipient;
1036         }
1037
1038         # if recipient_name is already quoted, do nothing
1039         if (is_rfc2047_quoted($recipient_name)) {
1040                 return $recipient;
1041         }
1042
1043         # remove non-escaped quotes
1044         $recipient_name =~ s/(^|[^\\])"/$1/g;
1045
1046         # rfc2047 is needed if a non-ascii char is included
1047         if ($recipient_name =~ /[^[:ascii:]]/) {
1048                 $recipient_name = quote_rfc2047($recipient_name);
1049         }
1050
1051         # double quotes are needed if specials or CTLs are included
1052         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1053                 $recipient_name =~ s/([\\\r])/\\$1/g;
1054                 $recipient_name = qq["$recipient_name"];
1055         }
1056
1057         return "$recipient_name $recipient_addr";
1058
1059 }
1060
1061 sub sanitize_address_list {
1062         return (map { sanitize_address($_) } @_);
1063 }
1064
1065 sub process_address_list {
1066         my @addr_list = map { parse_address_line($_) } @_;
1067         @addr_list = expand_aliases(@addr_list);
1068         @addr_list = sanitize_address_list(@addr_list);
1069         @addr_list = validate_address_list(@addr_list);
1070         return @addr_list;
1071 }
1072
1073 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1074 #
1075 # Tightly configured MTAa require that a caller sends a real DNS
1076 # domain name that corresponds the IP address in the HELO/EHLO
1077 # handshake. This is used to verify the connection and prevent
1078 # spammers from trying to hide their identity. If the DNS and IP don't
1079 # match, the receiveing MTA may deny the connection.
1080 #
1081 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1082 #
1083 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1084 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1085 #
1086 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1087 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1088
1089 sub valid_fqdn {
1090         my $domain = shift;
1091         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1092 }
1093
1094 sub maildomain_net {
1095         my $maildomain;
1096
1097         if (eval { require Net::Domain; 1 }) {
1098                 my $domain = Net::Domain::domainname();
1099                 $maildomain = $domain if valid_fqdn($domain);
1100         }
1101
1102         return $maildomain;
1103 }
1104
1105 sub maildomain_mta {
1106         my $maildomain;
1107
1108         if (eval { require Net::SMTP; 1 }) {
1109                 for my $host (qw(mailhost localhost)) {
1110                         my $smtp = Net::SMTP->new($host);
1111                         if (defined $smtp) {
1112                                 my $domain = $smtp->domain;
1113                                 $smtp->quit;
1114
1115                                 $maildomain = $domain if valid_fqdn($domain);
1116
1117                                 last if $maildomain;
1118                         }
1119                 }
1120         }
1121
1122         return $maildomain;
1123 }
1124
1125 sub maildomain {
1126         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1127 }
1128
1129 sub smtp_host_string {
1130         if (defined $smtp_server_port) {
1131                 return "$smtp_server:$smtp_server_port";
1132         } else {
1133                 return $smtp_server;
1134         }
1135 }
1136
1137 # Returns 1 if authentication succeeded or was not necessary
1138 # (smtp_user was not specified), and 0 otherwise.
1139
1140 sub smtp_auth_maybe {
1141         if (!defined $smtp_authuser || $auth) {
1142                 return 1;
1143         }
1144
1145         # Workaround AUTH PLAIN/LOGIN interaction defect
1146         # with Authen::SASL::Cyrus
1147         eval {
1148                 require Authen::SASL;
1149                 Authen::SASL->import(qw(Perl));
1150         };
1151
1152         # Check mechanism naming as defined in:
1153         # https://tools.ietf.org/html/rfc4422#page-8
1154         if ($smtp_auth && $smtp_auth !~ /^(\b[A-Z0-9-_]{1,20}\s*)*$/) {
1155                 die "invalid smtp auth: '${smtp_auth}'";
1156         }
1157
1158         # TODO: Authentication may fail not because credentials were
1159         # invalid but due to other reasons, in which we should not
1160         # reject credentials.
1161         $auth = Git::credential({
1162                 'protocol' => 'smtp',
1163                 'host' => smtp_host_string(),
1164                 'username' => $smtp_authuser,
1165                 # if there's no password, "git credential fill" will
1166                 # give us one, otherwise it'll just pass this one.
1167                 'password' => $smtp_authpass
1168         }, sub {
1169                 my $cred = shift;
1170
1171                 if ($smtp_auth) {
1172                         my $sasl = Authen::SASL->new(
1173                                 mechanism => $smtp_auth,
1174                                 callback => {
1175                                         user => $cred->{'username'},
1176                                         pass => $cred->{'password'},
1177                                         authname => $cred->{'username'},
1178                                 }
1179                         );
1180
1181                         return !!$smtp->auth($sasl);
1182                 }
1183
1184                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1185         });
1186
1187         return $auth;
1188 }
1189
1190 sub ssl_verify_params {
1191         eval {
1192                 require IO::Socket::SSL;
1193                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1194         };
1195         if ($@) {
1196                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1197                 return;
1198         }
1199
1200         if (!defined $smtp_ssl_cert_path) {
1201                 # use the OpenSSL defaults
1202                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1203         }
1204
1205         if ($smtp_ssl_cert_path eq "") {
1206                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1207         } elsif (-d $smtp_ssl_cert_path) {
1208                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1209                         SSL_ca_path => $smtp_ssl_cert_path);
1210         } elsif (-f $smtp_ssl_cert_path) {
1211                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1212                         SSL_ca_file => $smtp_ssl_cert_path);
1213         } else {
1214                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1215                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1216         }
1217 }
1218
1219 sub file_name_is_absolute {
1220         my ($path) = @_;
1221
1222         # msys does not grok DOS drive-prefixes
1223         if ($^O eq 'msys') {
1224                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1225         }
1226
1227         require File::Spec::Functions;
1228         return File::Spec::Functions::file_name_is_absolute($path);
1229 }
1230
1231 # Returns 1 if the message was sent, and 0 otherwise.
1232 # In actuality, the whole program dies when there
1233 # is an error sending a message.
1234
1235 sub send_message {
1236         my @recipients = unique_email_list(@to);
1237         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1238                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1239                     }
1240                @cc);
1241         my $to = join (",\n\t", @recipients);
1242         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1243         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1244         my $date = format_2822_time($time++);
1245         my $gitversion = '@@GIT_VERSION@@';
1246         if ($gitversion =~ m/..GIT_VERSION../) {
1247             $gitversion = Git::version();
1248         }
1249
1250         my $cc = join(",\n\t", unique_email_list(@cc));
1251         my $ccline = "";
1252         if ($cc ne '') {
1253                 $ccline = "\nCc: $cc";
1254         }
1255         make_message_id() unless defined($message_id);
1256
1257         my $header = "From: $sender
1258 To: $to${ccline}
1259 Subject: $subject
1260 Date: $date
1261 Message-Id: $message_id
1262 ";
1263         if ($use_xmailer) {
1264                 $header .= "X-Mailer: git-send-email $gitversion\n";
1265         }
1266         if ($reply_to) {
1267
1268                 $header .= "In-Reply-To: $reply_to\n";
1269                 $header .= "References: $references\n";
1270         }
1271         if (@xh) {
1272                 $header .= join("\n", @xh) . "\n";
1273         }
1274
1275         my @sendmail_parameters = ('-i', @recipients);
1276         my $raw_from = $sender;
1277         if (defined $envelope_sender && $envelope_sender ne "auto") {
1278                 $raw_from = $envelope_sender;
1279         }
1280         $raw_from = extract_valid_address($raw_from);
1281         unshift (@sendmail_parameters,
1282                         '-f', $raw_from) if(defined $envelope_sender);
1283
1284         if ($needs_confirm && !$dry_run) {
1285                 print "\n$header\n";
1286                 if ($needs_confirm eq "inform") {
1287                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1288                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1289                         print "    The Cc list above has been expanded by additional\n";
1290                         print "    addresses found in the patch commit message. By default\n";
1291                         print "    send-email prompts before sending whenever this occurs.\n";
1292                         print "    This behavior is controlled by the sendemail.confirm\n";
1293                         print "    configuration setting.\n";
1294                         print "\n";
1295                         print "    For additional information, run 'git send-email --help'.\n";
1296                         print "    To retain the current behavior, but squelch this message,\n";
1297                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1298                 }
1299                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1300                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1301                          default => $ask_default);
1302                 die "Send this email reply required" unless defined $_;
1303                 if (/^n/i) {
1304                         return 0;
1305                 } elsif (/^q/i) {
1306                         cleanup_compose_files();
1307                         exit(0);
1308                 } elsif (/^a/i) {
1309                         $confirm = 'never';
1310                 }
1311         }
1312
1313         unshift (@sendmail_parameters, @smtp_server_options);
1314
1315         if ($dry_run) {
1316                 # We don't want to send the email.
1317         } elsif (file_name_is_absolute($smtp_server)) {
1318                 my $pid = open my $sm, '|-';
1319                 defined $pid or die $!;
1320                 if (!$pid) {
1321                         exec($smtp_server, @sendmail_parameters) or die $!;
1322                 }
1323                 print $sm "$header\n$message";
1324                 close $sm or die $!;
1325         } else {
1326
1327                 if (!defined $smtp_server) {
1328                         die "The required SMTP server is not properly defined."
1329                 }
1330
1331                 if ($smtp_encryption eq 'ssl') {
1332                         $smtp_server_port ||= 465; # ssmtp
1333                         require Net::SMTP::SSL;
1334                         $smtp_domain ||= maildomain();
1335                         require IO::Socket::SSL;
1336                         # Net::SMTP::SSL->new() does not forward any SSL options
1337                         IO::Socket::SSL::set_client_defaults(
1338                                 ssl_verify_params());
1339                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1340                                                       Hello => $smtp_domain,
1341                                                       Port => $smtp_server_port,
1342                                                       Debug => $debug_net_smtp);
1343                 }
1344                 else {
1345                         require Net::SMTP;
1346                         $smtp_domain ||= maildomain();
1347                         $smtp_server_port ||= 25;
1348                         $smtp ||= Net::SMTP->new($smtp_server,
1349                                                  Hello => $smtp_domain,
1350                                                  Debug => $debug_net_smtp,
1351                                                  Port => $smtp_server_port);
1352                         if ($smtp_encryption eq 'tls' && $smtp) {
1353                                 require Net::SMTP::SSL;
1354                                 $smtp->command('STARTTLS');
1355                                 $smtp->response();
1356                                 if ($smtp->code == 220) {
1357                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1358                                                                           ssl_verify_params())
1359                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1360                                         $smtp_encryption = '';
1361                                         # Send EHLO again to receive fresh
1362                                         # supported commands
1363                                         $smtp->hello($smtp_domain);
1364                                 } else {
1365                                         die "Server does not support STARTTLS! ".$smtp->message;
1366                                 }
1367                         }
1368                 }
1369
1370                 if (!$smtp) {
1371                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1372                             "VALUES: server=$smtp_server ",
1373                             "encryption=$smtp_encryption ",
1374                             "hello=$smtp_domain",
1375                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1376                 }
1377
1378                 smtp_auth_maybe or die $smtp->message;
1379
1380                 $smtp->mail( $raw_from ) or die $smtp->message;
1381                 $smtp->to( @recipients ) or die $smtp->message;
1382                 $smtp->data or die $smtp->message;
1383                 $smtp->datasend("$header\n") or die $smtp->message;
1384                 my @lines = split /^/, $message;
1385                 foreach my $line (@lines) {
1386                         $smtp->datasend("$line") or die $smtp->message;
1387                 }
1388                 $smtp->dataend() or die $smtp->message;
1389                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1390         }
1391         if ($quiet) {
1392                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1393         } else {
1394                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1395                 if (!file_name_is_absolute($smtp_server)) {
1396                         print "Server: $smtp_server\n";
1397                         print "MAIL FROM:<$raw_from>\n";
1398                         foreach my $entry (@recipients) {
1399                             print "RCPT TO:<$entry>\n";
1400                         }
1401                 } else {
1402                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1403                 }
1404                 print $header, "\n";
1405                 if ($smtp) {
1406                         print "Result: ", $smtp->code, ' ',
1407                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1408                 } else {
1409                         print "Result: OK\n";
1410                 }
1411         }
1412
1413         return 1;
1414 }
1415
1416 $reply_to = $initial_reply_to;
1417 $references = $initial_reply_to || '';
1418 $subject = $initial_subject;
1419 $message_num = 0;
1420
1421 foreach my $t (@files) {
1422         open my $fh, "<", $t or die "can't open file $t";
1423
1424         my $author = undef;
1425         my $sauthor = undef;
1426         my $author_encoding;
1427         my $has_content_type;
1428         my $body_encoding;
1429         my $xfer_encoding;
1430         my $has_mime_version;
1431         @to = ();
1432         @cc = ();
1433         @xh = ();
1434         my $input_format = undef;
1435         my @header = ();
1436         $message = "";
1437         $message_num++;
1438         # First unfold multiline header fields
1439         while(<$fh>) {
1440                 last if /^\s*$/;
1441                 if (/^\s+\S/ and @header) {
1442                         chomp($header[$#header]);
1443                         s/^\s+/ /;
1444                         $header[$#header] .= $_;
1445             } else {
1446                         push(@header, $_);
1447                 }
1448         }
1449         # Now parse the header
1450         foreach(@header) {
1451                 if (/^From /) {
1452                         $input_format = 'mbox';
1453                         next;
1454                 }
1455                 chomp;
1456                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1457                         $input_format = 'mbox';
1458                 }
1459
1460                 if (defined $input_format && $input_format eq 'mbox') {
1461                         if (/^Subject:\s+(.*)$/i) {
1462                                 $subject = $1;
1463                         }
1464                         elsif (/^From:\s+(.*)$/i) {
1465                                 ($author, $author_encoding) = unquote_rfc2047($1);
1466                                 $sauthor = sanitize_address($author);
1467                                 next if $suppress_cc{'author'};
1468                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1469                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1470                                         $1, $_) unless $quiet;
1471                                 push @cc, $1;
1472                         }
1473                         elsif (/^To:\s+(.*)$/i) {
1474                                 foreach my $addr (parse_address_line($1)) {
1475                                         printf("(mbox) Adding to: %s from line '%s'\n",
1476                                                 $addr, $_) unless $quiet;
1477                                         push @to, $addr;
1478                                 }
1479                         }
1480                         elsif (/^Cc:\s+(.*)$/i) {
1481                                 foreach my $addr (parse_address_line($1)) {
1482                                         my $qaddr = unquote_rfc2047($addr);
1483                                         my $saddr = sanitize_address($qaddr);
1484                                         if ($saddr eq $sender) {
1485                                                 next if ($suppress_cc{'self'});
1486                                         } else {
1487                                                 next if ($suppress_cc{'cc'});
1488                                         }
1489                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1490                                                 $addr, $_) unless $quiet;
1491                                         push @cc, $addr;
1492                                 }
1493                         }
1494                         elsif (/^Content-type:/i) {
1495                                 $has_content_type = 1;
1496                                 if (/charset="?([^ "]+)/) {
1497                                         $body_encoding = $1;
1498                                 }
1499                                 push @xh, $_;
1500                         }
1501                         elsif (/^MIME-Version/i) {
1502                                 $has_mime_version = 1;
1503                                 push @xh, $_;
1504                         }
1505                         elsif (/^Message-Id: (.*)/i) {
1506                                 $message_id = $1;
1507                         }
1508                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1509                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1510                         }
1511                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1512                                 push @xh, $_;
1513                         }
1514
1515                 } else {
1516                         # In the traditional
1517                         # "send lots of email" format,
1518                         # line 1 = cc
1519                         # line 2 = subject
1520                         # So let's support that, too.
1521                         $input_format = 'lots';
1522                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1523                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1524                                         $_, $_) unless $quiet;
1525                                 push @cc, $_;
1526                         } elsif (!defined $subject) {
1527                                 $subject = $_;
1528                         }
1529                 }
1530         }
1531         # Now parse the message body
1532         while(<$fh>) {
1533                 $message .=  $_;
1534                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1535                         chomp;
1536                         my ($what, $c) = ($1, $2);
1537                         chomp $c;
1538                         my $sc = sanitize_address($c);
1539                         if ($sc eq $sender) {
1540                                 next if ($suppress_cc{'self'});
1541                         } else {
1542                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1543                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1544                         }
1545                         push @cc, $c;
1546                         printf("(body) Adding cc: %s from line '%s'\n",
1547                                 $c, $_) unless $quiet;
1548                 }
1549         }
1550         close $fh;
1551
1552         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1553                 if defined $to_cmd;
1554         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1555                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1556
1557         if ($broken_encoding{$t} && !$has_content_type) {
1558                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1559                 $has_content_type = 1;
1560                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1561                 $body_encoding = $auto_8bit_encoding;
1562         }
1563
1564         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1565                 $subject = quote_subject($subject, $auto_8bit_encoding);
1566         }
1567
1568         if (defined $sauthor and $sauthor ne $sender) {
1569                 $message = "From: $author\n\n$message";
1570                 if (defined $author_encoding) {
1571                         if ($has_content_type) {
1572                                 if ($body_encoding eq $author_encoding) {
1573                                         # ok, we already have the right encoding
1574                                 }
1575                                 else {
1576                                         # uh oh, we should re-encode
1577                                 }
1578                         }
1579                         else {
1580                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1581                                 $has_content_type = 1;
1582                                 push @xh,
1583                                   "Content-Type: text/plain; charset=$author_encoding";
1584                         }
1585                 }
1586         }
1587         if (defined $target_xfer_encoding) {
1588                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1589                 $message = apply_transfer_encoding(
1590                         $message, $xfer_encoding, $target_xfer_encoding);
1591                 $xfer_encoding = $target_xfer_encoding;
1592         }
1593         if (defined $xfer_encoding) {
1594                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1595         }
1596         if (defined $xfer_encoding or $has_content_type) {
1597                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1598         }
1599
1600         $needs_confirm = (
1601                 $confirm eq "always" or
1602                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1603                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1604         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1605
1606         @to = process_address_list(@to);
1607         @cc = process_address_list(@cc);
1608
1609         @to = (@initial_to, @to);
1610         @cc = (@initial_cc, @cc);
1611
1612         if ($message_num == 1) {
1613                 if (defined $cover_cc and $cover_cc) {
1614                         @initial_cc = @cc;
1615                 }
1616                 if (defined $cover_to and $cover_to) {
1617                         @initial_to = @to;
1618                 }
1619         }
1620
1621         my $message_was_sent = send_message();
1622
1623         # set up for the next message
1624         if ($thread && $message_was_sent &&
1625                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1626                 $message_num == 1)) {
1627                 $reply_to = $message_id;
1628                 if (length $references > 0) {
1629                         $references .= "\n $message_id";
1630                 } else {
1631                         $references = "$message_id";
1632                 }
1633         }
1634         $message_id = undef;
1635 }
1636
1637 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1638 # and return a results array
1639 sub recipients_cmd {
1640         my ($prefix, $what, $cmd, $file) = @_;
1641
1642         my @addresses = ();
1643         open my $fh, "-|", "$cmd \Q$file\E"
1644             or die "($prefix) Could not execute '$cmd'";
1645         while (my $address = <$fh>) {
1646                 $address =~ s/^\s*//g;
1647                 $address =~ s/\s*$//g;
1648                 $address = sanitize_address($address);
1649                 next if ($address eq $sender and $suppress_cc{'self'});
1650                 push @addresses, $address;
1651                 printf("($prefix) Adding %s: %s from: '%s'\n",
1652                        $what, $address, $cmd) unless $quiet;
1653                 }
1654         close $fh
1655             or die "($prefix) failed to close pipe to '$cmd'";
1656         return @addresses;
1657 }
1658
1659 cleanup_compose_files();
1660
1661 sub cleanup_compose_files {
1662         unlink($compose_filename, $compose_filename . ".final") if $compose;
1663 }
1664
1665 $smtp->quit if $smtp;
1666
1667 sub apply_transfer_encoding {
1668         my $message = shift;
1669         my $from = shift;
1670         my $to = shift;
1671
1672         return $message if ($from eq $to and $from ne '7bit');
1673
1674         require MIME::QuotedPrint;
1675         require MIME::Base64;
1676
1677         $message = MIME::QuotedPrint::decode($message)
1678                 if ($from eq 'quoted-printable');
1679         $message = MIME::Base64::decode($message)
1680                 if ($from eq 'base64');
1681
1682         die "cannot send message as 7bit"
1683                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1684         return $message
1685                 if ($to eq '7bit' or $to eq '8bit');
1686         return MIME::QuotedPrint::encode($message, "\n", 0)
1687                 if ($to eq 'quoted-printable');
1688         return MIME::Base64::encode($message, "\n")
1689                 if ($to eq 'base64');
1690         die "invalid transfer encoding";
1691 }
1692
1693 sub unique_email_list {
1694         my %seen;
1695         my @emails;
1696
1697         foreach my $entry (@_) {
1698                 my $clean = extract_valid_address_or_die($entry);
1699                 $seen{$clean} ||= 0;
1700                 next if $seen{$clean}++;
1701                 push @emails, $entry;
1702         }
1703         return @emails;
1704 }
1705
1706 sub validate_patch {
1707         my $fn = shift;
1708         open(my $fh, '<', $fn)
1709                 or die "unable to open $fn: $!\n";
1710         while (my $line = <$fh>) {
1711                 if (length($line) > 998) {
1712                         return "$.: patch contains a line longer than 998 characters";
1713                 }
1714         }
1715         return;
1716 }
1717
1718 sub file_has_nonascii {
1719         my $fn = shift;
1720         open(my $fh, '<', $fn)
1721                 or die "unable to open $fn: $!\n";
1722         while (my $line = <$fh>) {
1723                 return 1 if $line =~ /[^[:ascii:]]/;
1724         }
1725         return 0;
1726 }
1727
1728 sub body_or_subject_has_nonascii {
1729         my $fn = shift;
1730         open(my $fh, '<', $fn)
1731                 or die "unable to open $fn: $!\n";
1732         while (my $line = <$fh>) {
1733                 last if $line =~ /^$/;
1734                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1735         }
1736         while (my $line = <$fh>) {
1737                 return 1 if $line =~ /[^[:ascii:]]/;
1738         }
1739         return 0;
1740 }