contrib/buildsystems/CMakeLists.txt

   1 #
   2 #       Copyright (c) 2020 Sibi Siddharthan
   3 #
   4
   5 #[[
   6
   7 Instructions how to use this in Visual Studio:
   8
   9 Open the worktree as a folder. Visual Studio 2019 and later will detect
  10 the CMake configuration automatically and set everything up for you,
  11 ready to build. You can then run the tests in `t/` via a regular Git Bash.
  12
  13 Note: Visual Studio also has the option of opening `CMakeLists.txt`
  14 directly; Using this option, Visual Studio will not find the source code,
  15 though, therefore the `File>Open>Folder...` option is preferred.
  16
  17 Instructions to run CMake manually:
  18
  19     mkdir -p contrib/buildsystems/out
  20     cd contrib/buildsystems/out
  21     cmake ../ -DCMAKE_BUILD_TYPE=Release
  22
  23 This will build the git binaries in contrib/buildsystems/out
  24 directory (our top-level .gitignore file knows to ignore contents of
  25 this directory).
  26
  27 Possible build configurations(-DCMAKE_BUILD_TYPE) with corresponding
  28 compiler flags
  29 Debug : -g
  30 Release: -O3
  31 RelWithDebInfo : -O2 -g
  32 MinSizeRel : -Os
  33 empty(default) :
  34
  35 NOTE: -DCMAKE_BUILD_TYPE is optional. For multi-config generators like Visual Studio
  36 this option is ignored
  37
  38 This process generates a Makefile(Linux/*BSD/MacOS) , Visual Studio solution(Windows) by default.
  39 Run `make` to build Git on Linux/*BSD/MacOS.
  40 Open git.sln on Windows and build Git.
  41
  42 NOTE: By default CMake uses Makefile as the build tool on Linux and Visual Studio in Windows,
  43 to use another tool say `ninja` add this to the command line when configuring.
  44 `-G Ninja`
  45
  46 NOTE: By default CMake will install vcpkg locally to your source tree on configuration,
  47 to avoid this, add `-DNO_VCPKG=TRUE` to the command line when configuring.
  48
  49 ]]
  50 cmake_minimum_required(VERSION 3.14)
  51
  52 #set the source directory to root of git
  53 set(CMAKE_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/../..)
  54
  55 option(USE_VCPKG "Whether or not to use vcpkg for obtaining dependencies.  Only applicable to Windows platforms" ON)
  56 if(NOT WIN32)
  57         set(USE_VCPKG OFF CACHE BOOL FORCE)
  58 endif()
  59
  60 if(NOT DEFINED CMAKE_EXPORT_COMPILE_COMMANDS)
  61         set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
  62 endif()
  63
  64 if(USE_VCPKG)
  65         set(VCPKG_DIR "${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg")
  66         if(NOT EXISTS ${VCPKG_DIR})
  67                 message("Initializing vcpkg and building the Git's dependencies (this will take a while...)")
  68                 execute_process(COMMAND ${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg_install.bat)
  69         endif()
  70         list(APPEND CMAKE_PREFIX_PATH "${VCPKG_DIR}/installed/x64-windows")
  71
  72         # In the vcpkg edition, we need this to be able to link to libcurl
  73         set(CURL_NO_CURL_CMAKE ON)
  74
  75         # Copy the necessary vcpkg DLLs (like iconv) to the install dir
  76         set(X_VCPKG_APPLOCAL_DEPS_INSTALL ON)
  77         set(CMAKE_TOOLCHAIN_FILE ${VCPKG_DIR}/scripts/buildsystems/vcpkg.cmake CACHE STRING "Vcpkg toolchain file")
  78 endif()
  79
  80 find_program(SH_EXE sh PATHS "C:/Program Files/Git/bin")
  81 if(NOT SH_EXE)
  82         message(FATAL_ERROR "sh: shell interpreter was not found in your path, please install one."
  83                         "On Windows, you can get it as part of 'Git for Windows' install at https://gitforwindows.org/")
  84 endif()
  85
  86 #Create GIT-VERSION-FILE using GIT-VERSION-GEN
  87 if(NOT EXISTS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE)
  88         message("Generating GIT-VERSION-FILE")
  89         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/GIT-VERSION-GEN
  90                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
  91 endif()
  92
  93 #Parse GIT-VERSION-FILE to get the version
  94 file(STRINGS ${CMAKE_SOURCE_DIR}/GIT-VERSION-FILE git_version REGEX "GIT_VERSION = (.*)")
  95 string(REPLACE "GIT_VERSION = " "" git_version ${git_version})
  96 string(FIND ${git_version} "GIT" location)
  97 if(location EQUAL -1)
  98         string(REGEX MATCH "[0-9]*\\.[0-9]*\\.[0-9]*" git_version ${git_version})
  99 else()
 100         string(REGEX MATCH "[0-9]*\\.[0-9]*" git_version ${git_version})
 101         string(APPEND git_version ".0") #for building from a snapshot
 102 endif()
 103
 104 project(git
 105         VERSION ${git_version}
 106         LANGUAGES C)
 107
 108
 109 #TODO gitk git-gui gitweb
 110 #TODO Enable NLS on windows natively
 111 #TODO Add pcre support
 112
 113 #macros for parsing the Makefile for sources and scripts
 114 macro(parse_makefile_for_sources list_var regex)
 115         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
 116         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 117         string(REPLACE "$(COMPAT_OBJS)" "" ${list_var} ${${list_var}}) #remove "$(COMPAT_OBJS)" This is only for libgit.
 118         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 119         string(REPLACE ".o" ".c;" ${list_var} ${${list_var}}) #change .o to .c, ; is for converting the string into a list
 120         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
 121         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
 122 endmacro()
 123
 124 macro(parse_makefile_for_scripts list_var regex lang)
 125         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+=(.*)")
 126         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 127         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 128         string(REPLACE " " ";" ${list_var} ${${list_var}}) #convert string to a list
 129         if(NOT ${lang}) #exclude for SCRIPT_LIB
 130                 list(TRANSFORM ${list_var} REPLACE "${lang}" "") #do the replacement
 131         endif()
 132 endmacro()
 133
 134 macro(parse_makefile_for_executables list_var regex)
 135         file(STRINGS ${CMAKE_SOURCE_DIR}/Makefile ${list_var} REGEX "^${regex} \\+= git-(.*)")
 136         string(REPLACE "${regex} +=" "" ${list_var} ${${list_var}})
 137         string(STRIP ${${list_var}} ${list_var}) #remove trailing/leading whitespaces
 138         string(REPLACE "git-" "" ${list_var} ${${list_var}}) #strip `git-` prefix
 139         string(REPLACE "\$X" ";" ${list_var} ${${list_var}}) #strip $X, ; is for converting the string into a list
 140         list(TRANSFORM ${list_var} STRIP) #remove trailing/leading whitespaces for each element in list
 141         list(REMOVE_ITEM ${list_var} "") #remove empty list elements
 142 endmacro()
 143
 144 include(CheckTypeSize)
 145 include(CheckCSourceRuns)
 146 include(CheckCSourceCompiles)
 147 include(CheckIncludeFile)
 148 include(CheckFunctionExists)
 149 include(CheckSymbolExists)
 150 include(CheckStructHasMember)
 151 include(CTest)
 152
 153 find_package(ZLIB REQUIRED)
 154 find_package(CURL)
 155 find_package(EXPAT)
 156 find_package(Iconv)
 157
 158 #Don't use libintl on Windows Visual Studio and Clang builds
 159 if(NOT (WIN32 AND (CMAKE_C_COMPILER_ID STREQUAL "MSVC" OR CMAKE_C_COMPILER_ID STREQUAL "Clang")))
 160         find_package(Intl)
 161 endif()
 162
 163 if(NOT Intl_FOUND)
 164         add_compile_definitions(NO_GETTEXT)
 165         if(NOT Iconv_FOUND)
 166                 add_compile_definitions(NO_ICONV)
 167         endif()
 168 endif()
 169
 170 include_directories(SYSTEM ${ZLIB_INCLUDE_DIRS})
 171 if(CURL_FOUND)
 172         include_directories(SYSTEM ${CURL_INCLUDE_DIRS})
 173 endif()
 174 if(EXPAT_FOUND)
 175         include_directories(SYSTEM ${EXPAT_INCLUDE_DIRS})
 176 endif()
 177 if(Iconv_FOUND)
 178         include_directories(SYSTEM ${Iconv_INCLUDE_DIRS})
 179 endif()
 180 if(Intl_FOUND)
 181         include_directories(SYSTEM ${Intl_INCLUDE_DIRS})
 182 endif()
 183
 184
 185 if(WIN32 AND NOT MSVC)#not required for visual studio builds
 186         find_program(WINDRES_EXE windres)
 187         if(NOT WINDRES_EXE)
 188                 message(FATAL_ERROR "Install windres on Windows for resource files")
 189         endif()
 190 endif()
 191
 192 if(NO_GETTEXT)
 193         message(STATUS "msgfmt not used under NO_GETTEXT")
 194 else()
 195         find_program(MSGFMT_EXE msgfmt)
 196         if(NOT MSGFMT_EXE)
 197                 if(USE_VCPKG)
 198                         set(MSGFMT_EXE ${CMAKE_SOURCE_DIR}/compat/vcbuild/vcpkg/downloads/tools/msys2/msys64/usr/bin/msgfmt.exe)
 199                 endif()
 200                 if(NOT EXISTS ${MSGFMT_EXE})
 201                         message(WARNING "Text Translations won't be built")
 202                         unset(MSGFMT_EXE)
 203                 endif()
 204         endif()
 205 endif()
 206
 207 #Force all visual studio outputs to CMAKE_BINARY_DIR
 208 if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
 209         set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR})
 210         set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR})
 211         add_compile_options(/MP)
 212 endif()
 213
 214 #default behaviour
 215 include_directories(${CMAKE_SOURCE_DIR})
 216 add_compile_definitions(GIT_HOST_CPU="${CMAKE_SYSTEM_PROCESSOR}")
 217 add_compile_definitions(SHA256_BLK INTERNAL_QSORT RUNTIME_PREFIX)
 218 add_compile_definitions(NO_OPENSSL SHA1_DC SHA1DC_NO_STANDARD_INCLUDES
 219                         SHA1DC_INIT_SAFE_HASH_DEFAULT=0
 220                         SHA1DC_CUSTOM_INCLUDE_SHA1_C="cache.h"
 221                         SHA1DC_CUSTOM_INCLUDE_UBC_CHECK_C="git-compat-util.h" )
 222 list(APPEND compat_SOURCES sha1dc_git.c sha1dc/sha1.c sha1dc/ubc_check.c block-sha1/sha1.c sha256/block/sha256.c compat/qsort_s.c)
 223
 224
 225 add_compile_definitions(PAGER_ENV="LESS=FRX LV=-c"
 226                         GIT_EXEC_PATH="libexec/git-core"
 227                         GIT_LOCALE_PATH="share/locale"
 228                         GIT_MAN_PATH="share/man"
 229                         GIT_INFO_PATH="share/info"
 230                         GIT_HTML_PATH="share/doc/git-doc"
 231                         DEFAULT_HELP_FORMAT="html"
 232                         DEFAULT_GIT_TEMPLATE_DIR="share/git-core/templates"
 233                         GIT_VERSION="${PROJECT_VERSION}.GIT"
 234                         GIT_USER_AGENT="git/${PROJECT_VERSION}.GIT"
 235                         BINDIR="bin"
 236                         GIT_BUILT_FROM_COMMIT="")
 237
 238 if(WIN32)
 239         set(FALLBACK_RUNTIME_PREFIX /mingw64)
 240         # Move system config into top-level /etc/
 241         add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}"
 242                 ETC_GITATTRIBUTES="../etc/gitattributes"
 243                 ETC_GITCONFIG="../etc/gitconfig")
 244 else()
 245         set(FALLBACK_RUNTIME_PREFIX /home/$ENV{USER})
 246         add_compile_definitions(FALLBACK_RUNTIME_PREFIX="${FALLBACK_RUNTIME_PREFIX}"
 247                 ETC_GITATTRIBUTES="etc/gitattributes"
 248                 ETC_GITCONFIG="etc/gitconfig")
 249 endif()
 250
 251
 252 #Platform Specific
 253 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 254         if(CMAKE_C_COMPILER_ID STREQUAL "MSVC" OR CMAKE_C_COMPILER_ID STREQUAL "Clang")
 255                 include_directories(${CMAKE_SOURCE_DIR}/compat/vcbuild/include)
 256                 add_compile_definitions(_CRT_SECURE_NO_WARNINGS _CRT_NONSTDC_NO_DEPRECATE)
 257         endif()
 258         include_directories(${CMAKE_SOURCE_DIR}/compat/win32)
 259         add_compile_definitions(HAVE_ALLOCA_H NO_POSIX_GOODIES NATIVE_CRLF NO_UNIX_SOCKETS WIN32
 260                                 _CONSOLE DETECT_MSYS_TTY STRIP_EXTENSION=".exe"  NO_SYMLINK_HEAD UNRELIABLE_FSTAT
 261                                 NOGDI OBJECT_CREATION_MODE=1 __USE_MINGW_ANSI_STDIO=0
 262                                 USE_NED_ALLOCATOR OVERRIDE_STRDUP MMAP_PREVENTS_DELETE USE_WIN32_MMAP
 263                                 UNICODE _UNICODE HAVE_WPGMPTR ENSURE_MSYSTEM_IS_SET)
 264         list(APPEND compat_SOURCES compat/mingw.c compat/winansi.c compat/win32/path-utils.c
 265                 compat/win32/pthread.c compat/win32mmap.c compat/win32/syslog.c
 266                 compat/win32/trace2_win32_process_info.c compat/win32/dirent.c
 267                 compat/nedmalloc/nedmalloc.c compat/strdup.c)
 268         set(NO_UNIX_SOCKETS 1)
 269
 270 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 271         add_compile_definitions(PROCFS_EXECUTABLE_PATH="/proc/self/exe" HAVE_DEV_TTY )
 272         list(APPEND compat_SOURCES unix-socket.c unix-stream-server.c)
 273 endif()
 274
 275 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 276         list(APPEND compat_SOURCES compat/simple-ipc/ipc-shared.c compat/simple-ipc/ipc-win32.c)
 277         add_compile_definitions(SUPPORTS_SIMPLE_IPC)
 278         set(SUPPORTS_SIMPLE_IPC 1)
 279 else()
 280         # Simple IPC requires both Unix sockets and pthreads on Unix-based systems.
 281         if(NOT NO_UNIX_SOCKETS AND NOT NO_PTHREADS)
 282                 list(APPEND compat_SOURCES compat/simple-ipc/ipc-shared.c compat/simple-ipc/ipc-unix-socket.c)
 283                 add_compile_definitions(SUPPORTS_SIMPLE_IPC)
 284                 set(SUPPORTS_SIMPLE_IPC 1)
 285         endif()
 286 endif()
 287
 288 set(EXE_EXTENSION ${CMAKE_EXECUTABLE_SUFFIX})
 289
 290 #header checks
 291 check_include_file(libgen.h HAVE_LIBGEN_H)
 292 if(NOT HAVE_LIBGEN_H)
 293         add_compile_definitions(NO_LIBGEN_H)
 294         list(APPEND compat_SOURCES compat/basename.c)
 295 endif()
 296
 297 check_include_file(sys/sysinfo.h HAVE_SYSINFO)
 298 if(HAVE_SYSINFO)
 299         add_compile_definitions(HAVE_SYSINFO)
 300 endif()
 301
 302 check_c_source_compiles("
 303 #include <alloca.h>
 304
 305 int main(void)
 306 {
 307         char *p = (char *) alloca(2 * sizeof(int));
 308
 309         if (p)
 310                 return 0;
 311         return 0;
 312 }"
 313 HAVE_ALLOCA_H)
 314 if(HAVE_ALLOCA_H)
 315         add_compile_definitions(HAVE_ALLOCA_H)
 316 endif()
 317
 318 check_include_file(strings.h HAVE_STRINGS_H)
 319 if(HAVE_STRINGS_H)
 320         add_compile_definitions(HAVE_STRINGS_H)
 321 endif()
 322
 323 check_include_file(sys/select.h HAVE_SYS_SELECT_H)
 324 if(NOT HAVE_SYS_SELECT_H)
 325         add_compile_definitions(NO_SYS_SELECT_H)
 326 endif()
 327
 328 check_include_file(sys/poll.h HAVE_SYS_POLL_H)
 329 if(NOT HAVE_SYS_POLL_H)
 330         add_compile_definitions(NO_SYS_POLL_H)
 331 endif()
 332
 333 check_include_file(poll.h HAVE_POLL_H)
 334 if(NOT HAVE_POLL_H)
 335         add_compile_definitions(NO_POLL_H)
 336 endif()
 337
 338 check_include_file(inttypes.h HAVE_INTTYPES_H)
 339 if(NOT HAVE_INTTYPES_H)
 340         add_compile_definitions(NO_INTTYPES_H)
 341 endif()
 342
 343 check_include_file(paths.h HAVE_PATHS_H)
 344 if(HAVE_PATHS_H)
 345         add_compile_definitions(HAVE_PATHS_H)
 346 endif()
 347
 348 #function checks
 349 set(function_checks
 350         strcasestr memmem strlcpy strtoimax strtoumax strtoull
 351         setenv mkdtemp poll pread memmem)
 352
 353 #unsetenv,hstrerror are incompatible with windows build
 354 if(NOT WIN32)
 355         list(APPEND function_checks unsetenv hstrerror)
 356 endif()
 357
 358 foreach(f ${function_checks})
 359         string(TOUPPER ${f} uf)
 360         check_function_exists(${f} HAVE_${uf})
 361         if(NOT HAVE_${uf})
 362                 add_compile_definitions(NO_${uf})
 363         endif()
 364 endforeach()
 365
 366 if(NOT HAVE_POLL_H OR NOT HAVE_SYS_POLL_H OR NOT HAVE_POLL)
 367         include_directories(${CMAKE_SOURCE_DIR}/compat/poll)
 368         add_compile_definitions(NO_POLL)
 369         list(APPEND compat_SOURCES compat/poll/poll.c)
 370 endif()
 371
 372 if(NOT HAVE_STRCASESTR)
 373         list(APPEND compat_SOURCES compat/strcasestr.c)
 374 endif()
 375
 376 if(NOT HAVE_STRLCPY)
 377         list(APPEND compat_SOURCES compat/strlcpy.c)
 378 endif()
 379
 380 if(NOT HAVE_STRTOUMAX)
 381         list(APPEND compat_SOURCES compat/strtoumax.c compat/strtoimax.c)
 382 endif()
 383
 384 if(NOT HAVE_SETENV)
 385         list(APPEND compat_SOURCES compat/setenv.c)
 386 endif()
 387
 388 if(NOT HAVE_MKDTEMP)
 389         list(APPEND compat_SOURCES compat/mkdtemp.c)
 390 endif()
 391
 392 if(NOT HAVE_PREAD)
 393         list(APPEND compat_SOURCES compat/pread.c)
 394 endif()
 395
 396 if(NOT HAVE_MEMMEM)
 397         list(APPEND compat_SOURCES compat/memmem.c)
 398 endif()
 399
 400 if(NOT WIN32)
 401         if(NOT HAVE_UNSETENV)
 402                 list(APPEND compat_SOURCES compat/unsetenv.c)
 403         endif()
 404
 405         if(NOT HAVE_HSTRERROR)
 406                 list(APPEND compat_SOURCES compat/hstrerror.c)
 407         endif()
 408 endif()
 409
 410 check_function_exists(getdelim HAVE_GETDELIM)
 411 if(HAVE_GETDELIM)
 412         add_compile_definitions(HAVE_GETDELIM)
 413 endif()
 414
 415 check_function_exists(clock_gettime HAVE_CLOCK_GETTIME)
 416 check_symbol_exists(CLOCK_MONOTONIC "time.h" HAVE_CLOCK_MONOTONIC)
 417 if(HAVE_CLOCK_GETTIME)
 418         add_compile_definitions(HAVE_CLOCK_GETTIME)
 419 endif()
 420 if(HAVE_CLOCK_MONOTONIC)
 421         add_compile_definitions(HAVE_CLOCK_MONOTONIC)
 422 endif()
 423
 424 #check for st_blocks in struct stat
 425 check_struct_has_member("struct stat" st_blocks "sys/stat.h" STRUCT_STAT_HAS_ST_BLOCKS)
 426 if(NOT STRUCT_STAT_HAS_ST_BLOCKS)
 427         add_compile_definitions(NO_ST_BLOCKS_IN_STRUCT_STAT)
 428 endif()
 429
 430 #compile checks
 431 check_c_source_runs("
 432 #include<stdio.h>
 433 #include<stdarg.h>
 434 #include<string.h>
 435 #include<stdlib.h>
 436
 437 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 438 {
 439         int ret;
 440         va_list ap;
 441
 442         va_start(ap, format);
 443         ret = vsnprintf(str, maxsize, format, ap);
 444         va_end(ap);
 445         return ret;
 446 }
 447
 448 int main(void)
 449 {
 450         char buf[6];
 451
 452         if (test_vsnprintf(buf, 3, \"%s\", \"12345\") != 5
 453                 || strcmp(buf, \"12\"))
 454                         return 1;
 455         if (snprintf(buf, 3, \"%s\", \"12345\") != 5
 456                 || strcmp(buf, \"12\"))
 457                         return 1;
 458         return 0;
 459 }"
 460 SNPRINTF_OK)
 461 if(NOT SNPRINTF_OK)
 462         add_compile_definitions(SNPRINTF_RETURNS_BOGUS)
 463         list(APPEND compat_SOURCES compat/snprintf.c)
 464 endif()
 465
 466 check_c_source_runs("
 467 #include<stdio.h>
 468
 469 int main(void)
 470 {
 471         FILE *f = fopen(\".\", \"r\");
 472
 473         return f != NULL;
 474 }"
 475 FREAD_READS_DIRECTORIES_NO)
 476 if(NOT FREAD_READS_DIRECTORIES_NO)
 477         add_compile_definitions(FREAD_READS_DIRECTORIES)
 478         list(APPEND compat_SOURCES compat/fopen.c)
 479 endif()
 480
 481 check_c_source_compiles("
 482 #include <regex.h>
 483 #ifndef REG_STARTEND
 484 #error oops we dont have it
 485 #endif
 486
 487 int main(void)
 488 {
 489         return 0;
 490 }"
 491 HAVE_REGEX)
 492 if(NOT HAVE_REGEX)
 493         include_directories(${CMAKE_SOURCE_DIR}/compat/regex)
 494         list(APPEND compat_SOURCES compat/regex/regex.c )
 495         add_compile_definitions(NO_REGEX NO_MBSUPPORT GAWK)
 496 endif()
 497
 498
 499 check_c_source_compiles("
 500 #include <stddef.h>
 501 #include <sys/types.h>
 502 #include <sys/sysctl.h>
 503
 504 int main(void)
 505 {
 506         int val, mib[2];
 507         size_t len;
 508
 509         mib[0] = CTL_HW;
 510         mib[1] = 1;
 511         len = sizeof(val);
 512         return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
 513 }"
 514 HAVE_BSD_SYSCTL)
 515 if(HAVE_BSD_SYSCTL)
 516         add_compile_definitions(HAVE_BSD_SYSCTL)
 517 endif()
 518
 519 set(CMAKE_REQUIRED_LIBRARIES ${Iconv_LIBRARIES})
 520 set(CMAKE_REQUIRED_INCLUDES ${Iconv_INCLUDE_DIRS})
 521
 522 check_c_source_compiles("
 523 #include <iconv.h>
 524
 525 extern size_t iconv(iconv_t cd,
 526                 char **inbuf, size_t *inbytesleft,
 527                 char **outbuf, size_t *outbytesleft);
 528
 529 int main(void)
 530 {
 531         return 0;
 532 }"
 533 HAVE_NEW_ICONV)
 534 if(HAVE_NEW_ICONV)
 535         set(HAVE_OLD_ICONV 0)
 536 else()
 537         set(HAVE_OLD_ICONV 1)
 538 endif()
 539
 540 check_c_source_runs("
 541 #include <iconv.h>
 542 #if ${HAVE_OLD_ICONV}
 543 typedef const char *iconv_ibp;
 544 #else
 545 typedef char *iconv_ibp;
 546 #endif
 547
 548 int main(void)
 549 {
 550         int v;
 551         iconv_t conv;
 552         char in[] = \"a\";
 553         iconv_ibp pin = in;
 554         char out[20] = \"\";
 555         char *pout = out;
 556         size_t isz = sizeof(in);
 557         size_t osz = sizeof(out);
 558
 559         conv = iconv_open(\"UTF-16\", \"UTF-8\");
 560         iconv(conv, &pin, &isz, &pout, &osz);
 561         iconv_close(conv);
 562         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 563         return v != 0xfe + 0xff;
 564 }"
 565 ICONV_DOESNOT_OMIT_BOM)
 566 if(NOT ICONV_DOESNOT_OMIT_BOM)
 567         add_compile_definitions(ICONV_OMITS_BOM)
 568 endif()
 569
 570 unset(CMAKE_REQUIRED_LIBRARIES)
 571 unset(CMAKE_REQUIRED_INCLUDES)
 572
 573
 574 #programs
 575 set(PROGRAMS_BUILT
 576         git git-daemon git-http-backend git-sh-i18n--envsubst
 577         git-shell)
 578
 579 if(NOT CURL_FOUND)
 580         list(APPEND excluded_progs git-http-fetch git-http-push)
 581         add_compile_definitions(NO_CURL)
 582         message(WARNING "git-http-push and git-http-fetch will not be built")
 583 else()
 584         list(APPEND PROGRAMS_BUILT git-http-fetch git-http-push git-imap-send git-remote-http)
 585         if(CURL_VERSION_STRING VERSION_GREATER_EQUAL 7.34.0)
 586                 add_compile_definitions(USE_CURL_FOR_IMAP_SEND)
 587         endif()
 588 endif()
 589
 590 if(NOT EXPAT_FOUND)
 591         list(APPEND excluded_progs git-http-push)
 592         add_compile_definitions(NO_EXPAT)
 593 else()
 594         list(APPEND PROGRAMS_BUILT git-http-push)
 595         if(EXPAT_VERSION_STRING VERSION_LESS_EQUAL 1.2)
 596                 add_compile_definitions(EXPAT_NEEDS_XMLPARSE_H)
 597         endif()
 598 endif()
 599
 600 list(REMOVE_DUPLICATES excluded_progs)
 601 list(REMOVE_DUPLICATES PROGRAMS_BUILT)
 602
 603
 604 foreach(p ${excluded_progs})
 605         list(APPEND EXCLUSION_PROGS --exclude-program ${p} )
 606 endforeach()
 607
 608 #for comparing null values
 609 list(APPEND EXCLUSION_PROGS empty)
 610 set(EXCLUSION_PROGS_CACHE ${EXCLUSION_PROGS} CACHE STRING "Programs not built" FORCE)
 611
 612 if(NOT EXISTS ${CMAKE_BINARY_DIR}/command-list.h OR NOT EXCLUSION_PROGS_CACHE STREQUAL EXCLUSION_PROGS)
 613         list(REMOVE_ITEM EXCLUSION_PROGS empty)
 614         message("Generating command-list.h")
 615         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-cmdlist.sh ${EXCLUSION_PROGS} command-list.txt
 616                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 617                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/command-list.h)
 618 endif()
 619
 620 if(NOT EXISTS ${CMAKE_BINARY_DIR}/config-list.h)
 621         message("Generating config-list.h")
 622         execute_process(COMMAND ${SH_EXE} ${CMAKE_SOURCE_DIR}/generate-configlist.sh
 623                         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 624                         OUTPUT_FILE ${CMAKE_BINARY_DIR}/config-list.h)
 625 endif()
 626
 627 include_directories(${CMAKE_BINARY_DIR})
 628
 629 #build
 630 #libgit
 631 parse_makefile_for_sources(libgit_SOURCES "LIB_OBJS")
 632
 633 list(TRANSFORM libgit_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 634 list(TRANSFORM compat_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 635 add_library(libgit ${libgit_SOURCES} ${compat_SOURCES})
 636
 637 #libxdiff
 638 parse_makefile_for_sources(libxdiff_SOURCES "XDIFF_OBJS")
 639
 640 list(TRANSFORM libxdiff_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 641 add_library(xdiff STATIC ${libxdiff_SOURCES})
 642
 643 if(WIN32)
 644         if(NOT MSVC)#use windres when compiling with gcc and clang
 645                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/git.res
 646                                 COMMAND ${WINDRES_EXE} -O coff -DMAJOR=${PROJECT_VERSION_MAJOR} -DMINOR=${PROJECT_VERSION_MINOR}
 647                                         -DMICRO=${PROJECT_VERSION_PATCH} -DPATCHLEVEL=0 -DGIT_VERSION="\\\"${PROJECT_VERSION}.GIT\\\""
 648                                         -i ${CMAKE_SOURCE_DIR}/git.rc -o ${CMAKE_BINARY_DIR}/git.res
 649                                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 650                                 VERBATIM)
 651         else()#MSVC use rc
 652                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/git.res
 653                                 COMMAND ${CMAKE_RC_COMPILER} /d MAJOR=${PROJECT_VERSION_MAJOR} /d MINOR=${PROJECT_VERSION_MINOR}
 654                                         /d MICRO=${PROJECT_VERSION_PATCH} /d PATCHLEVEL=0 /d GIT_VERSION="${PROJECT_VERSION}.GIT"
 655                                         /fo ${CMAKE_BINARY_DIR}/git.res ${CMAKE_SOURCE_DIR}/git.rc
 656                                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 657                                 VERBATIM)
 658         endif()
 659         add_custom_target(git-rc DEPENDS ${CMAKE_BINARY_DIR}/git.res)
 660 endif()
 661
 662 #link all required libraries to common-main
 663 add_library(common-main OBJECT ${CMAKE_SOURCE_DIR}/common-main.c)
 664
 665 target_link_libraries(common-main libgit xdiff ${ZLIB_LIBRARIES})
 666 if(Intl_FOUND)
 667         target_link_libraries(common-main ${Intl_LIBRARIES})
 668 endif()
 669 if(Iconv_FOUND)
 670         target_link_libraries(common-main ${Iconv_LIBRARIES})
 671 endif()
 672 if(WIN32)
 673         target_link_libraries(common-main ws2_32 ntdll ${CMAKE_BINARY_DIR}/git.res)
 674         add_dependencies(common-main git-rc)
 675         if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 676                 target_link_options(common-main PUBLIC -municode -Wl,--nxcompat -Wl,--dynamicbase -Wl,--pic-executable,-e,mainCRTStartup)
 677         elseif(CMAKE_C_COMPILER_ID STREQUAL "Clang")
 678                 target_link_options(common-main PUBLIC -municode -Wl,-nxcompat -Wl,-dynamicbase -Wl,-entry:wmainCRTStartup -Wl,invalidcontinue.obj)
 679         elseif(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
 680                 target_link_options(common-main PUBLIC /IGNORE:4217 /IGNORE:4049 /NOLOGO /ENTRY:wmainCRTStartup /SUBSYSTEM:CONSOLE invalidcontinue.obj)
 681         else()
 682                 message(FATAL_ERROR "Unhandled compiler: ${CMAKE_C_COMPILER_ID}")
 683         endif()
 684 elseif(UNIX)
 685         target_link_libraries(common-main pthread rt)
 686 endif()
 687
 688 #git
 689 parse_makefile_for_sources(git_SOURCES "BUILTIN_OBJS")
 690
 691 list(TRANSFORM git_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/")
 692 add_executable(git ${CMAKE_SOURCE_DIR}/git.c ${git_SOURCES})
 693 target_link_libraries(git common-main)
 694
 695 add_executable(git-daemon ${CMAKE_SOURCE_DIR}/daemon.c)
 696 target_link_libraries(git-daemon common-main)
 697
 698 add_executable(git-http-backend ${CMAKE_SOURCE_DIR}/http-backend.c)
 699 target_link_libraries(git-http-backend common-main)
 700
 701 add_executable(git-sh-i18n--envsubst ${CMAKE_SOURCE_DIR}/sh-i18n--envsubst.c)
 702 target_link_libraries(git-sh-i18n--envsubst common-main)
 703
 704 add_executable(git-shell ${CMAKE_SOURCE_DIR}/shell.c)
 705 target_link_libraries(git-shell common-main)
 706
 707 if(CURL_FOUND)
 708         add_library(http_obj OBJECT ${CMAKE_SOURCE_DIR}/http.c)
 709
 710         add_executable(git-imap-send ${CMAKE_SOURCE_DIR}/imap-send.c)
 711         target_link_libraries(git-imap-send http_obj common-main ${CURL_LIBRARIES})
 712
 713         add_executable(git-http-fetch ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/http-fetch.c)
 714         target_link_libraries(git-http-fetch http_obj common-main ${CURL_LIBRARIES})
 715
 716         add_executable(git-remote-http ${CMAKE_SOURCE_DIR}/http-walker.c ${CMAKE_SOURCE_DIR}/remote-curl.c)
 717         target_link_libraries(git-remote-http http_obj common-main ${CURL_LIBRARIES} )
 718
 719         if(EXPAT_FOUND)
 720                 add_executable(git-http-push ${CMAKE_SOURCE_DIR}/http-push.c)
 721                 target_link_libraries(git-http-push http_obj common-main ${CURL_LIBRARIES} ${EXPAT_LIBRARIES})
 722         endif()
 723 endif()
 724
 725 parse_makefile_for_executables(git_builtin_extra "BUILT_INS")
 726
 727 option(SKIP_DASHED_BUILT_INS "Skip hardlinking the dashed versions of the built-ins")
 728
 729 #Creating hardlinks
 730 if(NOT SKIP_DASHED_BUILT_INS)
 731 foreach(s ${git_SOURCES} ${git_builtin_extra})
 732         string(REPLACE "${CMAKE_SOURCE_DIR}/builtin/" "" s ${s})
 733         string(REPLACE ".c" "" s ${s})
 734         file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git${EXE_EXTENSION} git-${s}${EXE_EXTENSION})\n")
 735         list(APPEND git_links ${CMAKE_BINARY_DIR}/git-${s}${EXE_EXTENSION})
 736 endforeach()
 737 endif()
 738
 739 if(CURL_FOUND)
 740         set(remote_exes
 741                 git-remote-https git-remote-ftp git-remote-ftps)
 742         foreach(s ${remote_exes})
 743                 file(APPEND ${CMAKE_BINARY_DIR}/CreateLinks.cmake "file(CREATE_LINK git-remote-http${EXE_EXTENSION} ${s}${EXE_EXTENSION})\n")
 744                 list(APPEND git_http_links ${CMAKE_BINARY_DIR}/${s}${EXE_EXTENSION})
 745         endforeach()
 746 endif()
 747
 748 add_custom_command(OUTPUT ${git_links} ${git_http_links}
 749                 COMMAND ${CMAKE_COMMAND} -P ${CMAKE_BINARY_DIR}/CreateLinks.cmake
 750                 DEPENDS git git-remote-http)
 751 add_custom_target(git-links ALL DEPENDS ${git_links} ${git_http_links})
 752
 753
 754 #creating required scripts
 755 set(SHELL_PATH /bin/sh)
 756 set(PERL_PATH /usr/bin/perl)
 757 set(LOCALEDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 758 set(GITWEBDIR ${FALLBACK_RUNTIME_PREFIX}/share/locale)
 759 set(INSTLIBDIR ${FALLBACK_RUNTIME_PREFIX}/share/perl5)
 760
 761 #shell scripts
 762 parse_makefile_for_scripts(git_sh_scripts "SCRIPT_SH" ".sh")
 763 parse_makefile_for_scripts(git_shlib_scripts "SCRIPT_LIB" "")
 764 set(git_shell_scripts
 765         ${git_sh_scripts} ${git_shlib_scripts} git-instaweb)
 766
 767 foreach(script ${git_shell_scripts})
 768         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.sh content NEWLINE_CONSUME)
 769         string(REPLACE "@SHELL_PATH@" "${SHELL_PATH}" content "${content}")
 770         string(REPLACE "@@DIFF@@" "diff" content "${content}")
 771         string(REPLACE "@LOCALEDIR@" "${LOCALEDIR}" content "${content}")
 772         string(REPLACE "@GITWEBDIR@" "${GITWEBDIR}" content "${content}")
 773         string(REPLACE "@@NO_CURL@@" "" content "${content}")
 774         string(REPLACE "@@USE_GETTEXT_SCHEME@@" "" content "${content}")
 775         string(REPLACE "# @@BROKEN_PATH_FIX@@" "" content "${content}")
 776         string(REPLACE "@@PERL@@" "${PERL_PATH}" content "${content}")
 777         string(REPLACE "@@SANE_TEXT_GREP@@" "-a" content "${content}")
 778         string(REPLACE "@@PAGER_ENV@@" "LESS=FRX LV=-c" content "${content}")
 779         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 780 endforeach()
 781
 782 #perl scripts
 783 parse_makefile_for_scripts(git_perl_scripts "SCRIPT_PERL" ".perl")
 784
 785 #create perl header
 786 file(STRINGS ${CMAKE_SOURCE_DIR}/perl/header_templates/fixed_prefix.template.pl perl_header )
 787 string(REPLACE "@@PATHSEP@@" ":" perl_header "${perl_header}")
 788 string(REPLACE "@@INSTLIBDIR@@" "${INSTLIBDIR}" perl_header "${perl_header}")
 789
 790 foreach(script ${git_perl_scripts})
 791         file(STRINGS ${CMAKE_SOURCE_DIR}/${script}.perl content NEWLINE_CONSUME)
 792         string(REPLACE "#!/usr/bin/perl" "#!/usr/bin/perl\n${perl_header}\n" content "${content}")
 793         string(REPLACE "@@GIT_VERSION@@" "${PROJECT_VERSION}" content "${content}")
 794         file(WRITE ${CMAKE_BINARY_DIR}/${script} ${content})
 795 endforeach()
 796
 797 #python script
 798 file(STRINGS ${CMAKE_SOURCE_DIR}/git-p4.py content NEWLINE_CONSUME)
 799 string(REPLACE "#!/usr/bin/env python" "#!/usr/bin/python" content "${content}")
 800 file(WRITE ${CMAKE_BINARY_DIR}/git-p4 ${content})
 801
 802 #perl modules
 803 file(GLOB_RECURSE perl_modules "${CMAKE_SOURCE_DIR}/perl/*.pm")
 804
 805 foreach(pm ${perl_modules})
 806         string(REPLACE "${CMAKE_SOURCE_DIR}/perl/" "" file_path ${pm})
 807         file(STRINGS ${pm} content NEWLINE_CONSUME)
 808         string(REPLACE "@@LOCALEDIR@@" "${LOCALEDIR}" content "${content}")
 809         string(REPLACE "@@NO_PERL_CPAN_FALLBACKS@@" "" content "${content}")
 810         file(WRITE ${CMAKE_BINARY_DIR}/perl/build/lib/${file_path} ${content})
 811 #test-lib.sh requires perl/build/lib to be the build directory of perl modules
 812 endforeach()
 813
 814
 815 #templates
 816 file(GLOB templates "${CMAKE_SOURCE_DIR}/templates/*")
 817 list(TRANSFORM templates REPLACE "${CMAKE_SOURCE_DIR}/templates/" "")
 818 list(REMOVE_ITEM templates ".gitignore")
 819 list(REMOVE_ITEM templates "Makefile")
 820 list(REMOVE_ITEM templates "blt")# Prevents an error when reconfiguring for in source builds
 821
 822 list(REMOVE_ITEM templates "branches--")
 823 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/branches) #create branches
 824
 825 #templates have @.*@ replacement so use configure_file instead
 826 foreach(tm ${templates})
 827         string(REPLACE "--" "/" blt_tm ${tm})
 828         string(REPLACE "this" "" blt_tm ${blt_tm})# for this--
 829         configure_file(${CMAKE_SOURCE_DIR}/templates/${tm} ${CMAKE_BINARY_DIR}/templates/blt/${blt_tm} @ONLY)
 830 endforeach()
 831
 832
 833 #translations
 834 if(MSGFMT_EXE)
 835         file(GLOB po_files "${CMAKE_SOURCE_DIR}/po/*.po")
 836         list(TRANSFORM po_files REPLACE "${CMAKE_SOURCE_DIR}/po/" "")
 837         list(TRANSFORM po_files REPLACE ".po" "")
 838         foreach(po ${po_files})
 839                 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES)
 840                 add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo
 841                                 COMMAND ${MSGFMT_EXE} --check --statistics -o ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo ${CMAKE_SOURCE_DIR}/po/${po}.po)
 842                 list(APPEND po_gen ${CMAKE_BINARY_DIR}/po/build/locale/${po}/LC_MESSAGES/git.mo)
 843         endforeach()
 844         add_custom_target(po-gen ALL DEPENDS ${po_gen})
 845 endif()
 846
 847
 848 #to help with the install
 849 list(TRANSFORM git_shell_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 850 list(TRANSFORM git_perl_scripts PREPEND "${CMAKE_BINARY_DIR}/")
 851
 852 #install
 853 foreach(program ${PROGRAMS_BUILT})
 854 if(program STREQUAL "git" OR program STREQUAL "git-shell")
 855 install(TARGETS ${program}
 856         RUNTIME DESTINATION bin)
 857 else()
 858 install(TARGETS ${program}
 859         RUNTIME DESTINATION libexec/git-core)
 860 endif()
 861 endforeach()
 862
 863 install(PROGRAMS ${CMAKE_BINARY_DIR}/git-cvsserver
 864         DESTINATION bin)
 865
 866 set(bin_links
 867         git-receive-pack git-upload-archive git-upload-pack)
 868
 869 foreach(b ${bin_links})
 870 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/bin/${b}${EXE_EXTENSION})")
 871 endforeach()
 872
 873 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git${EXE_EXTENSION})")
 874 install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git-shell${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-shell${EXE_EXTENSION})")
 875
 876 foreach(b ${git_links})
 877         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 878         install(CODE "file(CREATE_LINK ${CMAKE_INSTALL_PREFIX}/bin/git${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 879 endforeach()
 880
 881 foreach(b ${git_http_links})
 882         string(REPLACE "${CMAKE_BINARY_DIR}" "" b ${b})
 883         install(CODE "file(CREATE_LINK  ${CMAKE_INSTALL_PREFIX}/libexec/git-core/git-remote-http${EXE_EXTENSION} ${CMAKE_INSTALL_PREFIX}/libexec/git-core/${b})")
 884 endforeach()
 885
 886 install(PROGRAMS ${git_shell_scripts} ${git_perl_scripts} ${CMAKE_BINARY_DIR}/git-p4
 887         DESTINATION libexec/git-core)
 888
 889 install(DIRECTORY ${CMAKE_SOURCE_DIR}/mergetools DESTINATION libexec/git-core)
 890 install(DIRECTORY ${CMAKE_BINARY_DIR}/perl/build/lib/ DESTINATION share/perl5
 891         FILES_MATCHING PATTERN "*.pm")
 892 install(DIRECTORY ${CMAKE_BINARY_DIR}/templates/blt/ DESTINATION share/git-core/templates)
 893
 894 if(MSGFMT_EXE)
 895         install(DIRECTORY ${CMAKE_BINARY_DIR}/po/build/locale DESTINATION share)
 896 endif()
 897
 898
 899 if(BUILD_TESTING)
 900
 901 #tests-helpers
 902 add_executable(test-fake-ssh ${CMAKE_SOURCE_DIR}/t/helper/test-fake-ssh.c)
 903 target_link_libraries(test-fake-ssh common-main)
 904
 905 #test-tool
 906 parse_makefile_for_sources(test-tool_SOURCES "TEST_BUILTINS_OBJS")
 907
 908 list(TRANSFORM test-tool_SOURCES PREPEND "${CMAKE_SOURCE_DIR}/t/helper/")
 909 add_executable(test-tool ${CMAKE_SOURCE_DIR}/t/helper/test-tool.c ${test-tool_SOURCES})
 910 target_link_libraries(test-tool common-main)
 911
 912 set_target_properties(test-fake-ssh test-tool
 913                         PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/t/helper)
 914
 915 if(MSVC)
 916         set_target_properties(test-fake-ssh test-tool
 917                                 PROPERTIES RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR}/t/helper)
 918         set_target_properties(test-fake-ssh test-tool
 919                                 PROPERTIES RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR}/t/helper)
 920 endif()
 921
 922 #wrapper scripts
 923 set(wrapper_scripts
 924         git git-upload-pack git-receive-pack git-upload-archive git-shell git-remote-ext)
 925
 926 set(wrapper_test_scripts
 927         test-fake-ssh test-tool)
 928
 929
 930 foreach(script ${wrapper_scripts})
 931         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 932         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 933         string(REPLACE "@@PROG@@" "${script}${EXE_EXTENSION}" content "${content}")
 934         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 935 endforeach()
 936
 937 foreach(script ${wrapper_test_scripts})
 938         file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 939         string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 940         string(REPLACE "@@PROG@@" "t/helper/${script}${EXE_EXTENSION}" content "${content}")
 941         file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/${script} ${content})
 942 endforeach()
 943
 944 file(STRINGS ${CMAKE_SOURCE_DIR}/wrap-for-bin.sh content NEWLINE_CONSUME)
 945 string(REPLACE "@@BUILD_DIR@@" "${CMAKE_BINARY_DIR}" content "${content}")
 946 string(REPLACE "@@PROG@@" "git-cvsserver" content "${content}")
 947 file(WRITE ${CMAKE_BINARY_DIR}/bin-wrappers/git-cvsserver ${content})
 948
 949 #options for configuring test options
 950 option(PERL_TESTS "Perform tests that use perl" ON)
 951 option(PYTHON_TESTS "Perform tests that use python" ON)
 952
 953 #GIT-BUILD-OPTIONS
 954 set(TEST_SHELL_PATH ${SHELL_PATH})
 955 set(DIFF diff)
 956 set(PYTHON_PATH /usr/bin/python)
 957 set(TAR tar)
 958 set(NO_CURL )
 959 set(NO_EXPAT )
 960 set(USE_LIBPCRE2 )
 961 set(NO_PERL )
 962 set(NO_PTHREADS )
 963 set(NO_PYTHON )
 964 set(PAGER_ENV "LESS=FRX LV=-c")
 965 set(DC_SHA1 YesPlease)
 966 set(RUNTIME_PREFIX true)
 967 set(NO_GETTEXT )
 968
 969 if(NOT CURL_FOUND)
 970         set(NO_CURL 1)
 971 endif()
 972
 973 if(NOT EXPAT_FOUND)
 974         set(NO_EXPAT 1)
 975 endif()
 976
 977 if(NOT Intl_FOUND)
 978         set(NO_GETTEXT 1)
 979 endif()
 980
 981 if(NOT PERL_TESTS)
 982         set(NO_PERL 1)
 983 endif()
 984
 985 if(NOT PYTHON_TESTS)
 986         set(NO_PYTHON 1)
 987 endif()
 988
 989 file(WRITE ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SHELL_PATH='${SHELL_PATH}'\n")
 990 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TEST_SHELL_PATH='${TEST_SHELL_PATH}'\n")
 991 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PERL_PATH='${PERL_PATH}'\n")
 992 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DIFF='${DIFF}'\n")
 993 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PYTHON_PATH='${PYTHON_PATH}'\n")
 994 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "TAR='${TAR}'\n")
 995 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_CURL='${NO_CURL}'\n")
 996 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_EXPAT='${NO_EXPAT}'\n")
 997 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PERL='${NO_PERL}'\n")
 998 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PTHREADS='${NO_PTHREADS}'\n")
 999 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_UNIX_SOCKETS='${NO_UNIX_SOCKETS}'\n")
1000 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PAGER_ENV='${PAGER_ENV}'\n")
1001 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "DC_SHA1='${DC_SHA1}'\n")
1002 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "X='${EXE_EXTENSION}'\n")
1003 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_GETTEXT='${NO_GETTEXT}'\n")
1004 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "RUNTIME_PREFIX='${RUNTIME_PREFIX}'\n")
1005 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "NO_PYTHON='${NO_PYTHON}'\n")
1006 file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "SUPPORTS_SIMPLE_IPC='${SUPPORTS_SIMPLE_IPC}'\n")
1007 if(USE_VCPKG)
1008         file(APPEND ${CMAKE_BINARY_DIR}/GIT-BUILD-OPTIONS "PATH=\"$PATH:$TEST_DIRECTORY/../compat/vcbuild/vcpkg/installed/x64-windows/bin\"\n")
1009 endif()
1010
1011 #Make the tests work when building out of the source tree
1012 get_filename_component(CACHE_PATH ${CMAKE_CURRENT_LIST_DIR}/../../CMakeCache.txt ABSOLUTE)
1013 if(NOT ${CMAKE_BINARY_DIR}/CMakeCache.txt STREQUAL ${CACHE_PATH})
1014         file(RELATIVE_PATH BUILD_DIR_RELATIVE ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR}/CMakeCache.txt)
1015         string(REPLACE "/CMakeCache.txt" "" BUILD_DIR_RELATIVE ${BUILD_DIR_RELATIVE})
1016         #Setting the build directory in test-lib.sh before running tests
1017         file(WRITE ${CMAKE_BINARY_DIR}/CTestCustom.cmake
1018                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh GIT_BUILD_DIR_REPL REGEX \"GIT_BUILD_DIR=(.*)\")\n"
1019                 "file(STRINGS ${CMAKE_SOURCE_DIR}/t/test-lib.sh content NEWLINE_CONSUME)\n"
1020                 "string(REPLACE \"\${GIT_BUILD_DIR_REPL}\" \"GIT_BUILD_DIR=\\\"$TEST_DIRECTORY/../${BUILD_DIR_RELATIVE}\\\"\" content \"\${content}\")\n"
1021                 "file(WRITE ${CMAKE_SOURCE_DIR}/t/test-lib.sh \${content})")
1022         #misc copies
1023         file(COPY ${CMAKE_SOURCE_DIR}/t/chainlint.sed DESTINATION ${CMAKE_BINARY_DIR}/t/)
1024         file(COPY ${CMAKE_SOURCE_DIR}/po/is.po DESTINATION ${CMAKE_BINARY_DIR}/po/)
1025         file(COPY ${CMAKE_SOURCE_DIR}/mergetools/tkdiff DESTINATION ${CMAKE_BINARY_DIR}/mergetools/)
1026         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-prompt.sh DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
1027         file(COPY ${CMAKE_SOURCE_DIR}/contrib/completion/git-completion.bash DESTINATION ${CMAKE_BINARY_DIR}/contrib/completion/)
1028 endif()
1029
1030 file(GLOB test_scipts "${CMAKE_SOURCE_DIR}/t/t[0-9]*.sh")
1031
1032 #test
1033 foreach(tsh ${test_scipts})
1034         add_test(NAME ${tsh}
1035                 COMMAND ${SH_EXE} ${tsh}
1036                 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/t)
1037 endforeach()
1038
1039 endif()#BUILD_TESTING