configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specied by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 #
 245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 246 # /foo/bar/include and /foo/bar/lib directories.
 247 AC_ARG_WITH(openssl,
 248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 249 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 250 GIT_PARSE_WITH([openssl]))
 251
 252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 253 # commands such as log and grep offer runtime options to use
 254 # Perl-compatible regular expressions instead of standard or extended
 255 # POSIX regular expressions.
 256 #
 257 # Currently USE_LIBPCRE is a synonym for USE_LIBPCRE1, define
 258 # USE_LIBPCRE2 instead if you'd like to use version 2 of the PCRE
 259 # library. The USE_LIBPCRE flag will likely be changed to mean v2 by
 260 # default in future releases.
 261 #
 262 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
 263 # /foo/bar/include and /foo/bar/lib directories.
 264 #
 265 AC_ARG_WITH(libpcre,
 266 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre1]),
 267     if test "$withval" = "no"; then
 268         USE_LIBPCRE1=
 269     elif test "$withval" = "yes"; then
 270         USE_LIBPCRE1=YesPlease
 271     else
 272         USE_LIBPCRE1=YesPlease
 273         LIBPCREDIR=$withval
 274         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 275         dnl USE_LIBPCRE1 can still be modified below, so don't substitute
 276         dnl it yet.
 277         GIT_CONF_SUBST([LIBPCREDIR])
 278     fi)
 279
 280 AC_ARG_WITH(libpcre1,
 281 AS_HELP_STRING([--with-libpcre1],[support Perl-compatible regexes via libpcre1 (default is NO)])
 282 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 283     if test "$withval" = "no"; then
 284         USE_LIBPCRE1=
 285     elif test "$withval" = "yes"; then
 286         USE_LIBPCRE1=YesPlease
 287     else
 288         USE_LIBPCRE1=YesPlease
 289         LIBPCREDIR=$withval
 290         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 291         dnl USE_LIBPCRE1 can still be modified below, so don't substitute
 292         dnl it yet.
 293         GIT_CONF_SUBST([LIBPCREDIR])
 294     fi)
 295
 296 AC_ARG_WITH(libpcre2,
 297 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
 298 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 299     if test -n "$USE_LIBPCRE1"; then
 300         AC_MSG_ERROR([Only supply one of --with-libpcre1 or --with-libpcre2!])
 301     fi
 302
 303     if test "$withval" = "no"; then
 304         USE_LIBPCRE2=
 305     elif test "$withval" = "yes"; then
 306         USE_LIBPCRE2=YesPlease
 307     else
 308         USE_LIBPCRE2=YesPlease
 309         LIBPCREDIR=$withval
 310         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 311         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 312         dnl it yet.
 313         GIT_CONF_SUBST([LIBPCREDIR])
 314     fi)
 315 #
 316 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 317 AC_FUNC_ALLOCA
 318 case $ac_cv_working_alloca_h in
 319     yes)    HAVE_ALLOCA_H=YesPlease;;
 320     *)      HAVE_ALLOCA_H='';;
 321 esac
 322 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 323 #
 324 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 325 # git-http-push are not built, and you cannot use http:// and https://
 326 # transports.
 327 #
 328 # Define CURLDIR=/foo/bar if your curl header and library files are in
 329 # /foo/bar/include and /foo/bar/lib directories.
 330 AC_ARG_WITH(curl,
 331 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 332 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 333 GIT_PARSE_WITH(curl))
 334 #
 335 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 336 # not built, and you cannot push using http:// and https:// transports.
 337 #
 338 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 339 # /foo/bar/include and /foo/bar/lib directories.
 340 AC_ARG_WITH(expat,
 341 AS_HELP_STRING([--with-expat],
 342 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 343 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 344 GIT_PARSE_WITH(expat))
 345 #
 346 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 347 # installed in /sw, but don't want GIT to link against any libraries
 348 # installed there.  If defined you may specify your own (or Fink's)
 349 # include directories and library directories by defining CFLAGS
 350 # and LDFLAGS appropriately.
 351 #
 352 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 353 # have DarwinPorts installed in /opt/local, but don't want GIT to
 354 # link against any libraries installed there.  If defined you may
 355 # specify your own (or DarwinPort's) include directories and
 356 # library directories by defining CFLAGS and LDFLAGS appropriately.
 357 #
 358 # Define NO_MMAP if you want to avoid mmap.
 359 #
 360 # Define NO_ICONV if your libc does not properly support iconv.
 361 AC_ARG_WITH(iconv,
 362 AS_HELP_STRING([--without-iconv],
 363 [if your architecture doesn't properly support iconv])
 364 AS_HELP_STRING([--with-iconv=PATH],
 365 [PATH is prefix for libiconv library and headers])
 366 AS_HELP_STRING([],
 367 [used only if you need linking with libiconv]),
 368 GIT_PARSE_WITH(iconv))
 369
 370 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 371 #
 372 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 373 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 374 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 375 # randomly break unless your underlying filesystem supports those sub-second
 376 # times (my ext3 doesn't).
 377 #
 378 # Define USE_STDEV below if you want git to care about the underlying device
 379 # change being considered an inode change from the update-index perspective.
 380
 381 #
 382 # Allow user to set ETC_GITCONFIG variable
 383 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 384                         Use VALUE instead of /etc/gitconfig as the
 385                         global git configuration file.
 386                         If VALUE is not fully qualified it will be interpreted
 387                         as a path relative to the computed prefix at runtime.)
 388
 389 #
 390 # Allow user to set ETC_GITATTRIBUTES variable
 391 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 392                         Use VALUE instead of /etc/gitattributes as the
 393                         global git attributes file.
 394                         If VALUE is not fully qualified it will be interpreted
 395                         as a path relative to the computed prefix at runtime.)
 396
 397 #
 398 # Allow user to set the default pager
 399 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 400                         Use VALUE as the fall-back pager instead of 'less'.
 401                         This is used by things like 'git log' when the user
 402                         does not specify a pager to use through alternate
 403                         methods. eg: /usr/bin/pager)
 404 #
 405 # Allow user to set the default editor
 406 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 407                         Use VALUE as the fall-back editor instead of 'vi'.
 408                         This is used by things like 'git commit' when the user
 409                         does not specify a preferred editor through other
 410                         methods. eg: /usr/bin/editor)
 411
 412 #
 413 # Define SHELL_PATH to provide path to shell.
 414 GIT_ARG_SET_PATH(shell)
 415 #
 416 # Define PERL_PATH to provide path to Perl.
 417 GIT_ARG_SET_PATH(perl)
 418 #
 419 # Define PYTHON_PATH to provide path to Python.
 420 GIT_ARG_SET_PATH(python, allow-without)
 421 #
 422 # Define ZLIB_PATH to provide path to zlib.
 423 GIT_ARG_SET_PATH(zlib)
 424 #
 425 # Declare the with-tcltk/without-tcltk options.
 426 AC_ARG_WITH(tcltk,
 427 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 428 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 429 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 430 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 431 GIT_PARSE_WITH(tcltk))
 432 #
 433
 434
 435 ## Checks for programs.
 436 AC_MSG_NOTICE([CHECKS for programs])
 437 #
 438 AC_PROG_CC([cc gcc])
 439 AC_C_INLINE
 440 case $ac_cv_c_inline in
 441   inline | yes | no) INLINE='';;
 442   *)                 INLINE=$ac_cv_c_inline ;;
 443 esac
 444 GIT_CONF_SUBST([INLINE])
 445
 446 # which switch to pass runtime path to dynamic libraries to the linker
 447 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 448    SAVE_LDFLAGS="${LDFLAGS}"
 449    LDFLAGS="${SAVE_LDFLAGS} -R /"
 450    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 451    LDFLAGS="${SAVE_LDFLAGS}"
 452 ])
 453 if test "$git_cv_ld_dashr" = "yes"; then
 454    CC_LD_DYNPATH=-R
 455 else
 456    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 457       SAVE_LDFLAGS="${LDFLAGS}"
 458       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 459       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 460       LDFLAGS="${SAVE_LDFLAGS}"
 461    ])
 462    if test "$git_cv_ld_wl_rpath" = "yes"; then
 463       CC_LD_DYNPATH=-Wl,-rpath,
 464    else
 465       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 466          SAVE_LDFLAGS="${LDFLAGS}"
 467          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 468          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 469          LDFLAGS="${SAVE_LDFLAGS}"
 470       ])
 471       if test "$git_cv_ld_rpath" = "yes"; then
 472          CC_LD_DYNPATH=-rpath
 473       else
 474          CC_LD_DYNPATH=
 475          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 476       fi
 477    fi
 478 fi
 479 GIT_CONF_SUBST([CC_LD_DYNPATH])
 480 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 481 AC_CHECK_TOOLS(AR, [gar ar], :)
 482 AC_CHECK_PROGS(TAR, [gtar tar])
 483 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 484 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 485 # or will be empty otherwise.
 486 if test -n "$NO_TCLTK"; then
 487   TCLTK_PATH=
 488 else
 489   if test "$with_tcltk" = ""; then
 490   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 491     TCLTK_PATH=wish
 492   elif test "$with_tcltk" = "yes"; then
 493   # Tcl/Tk check requested.
 494     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 495   else
 496     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 497     TCLTK_PATH="$with_tcltk"
 498   fi
 499 fi
 500 GIT_CONF_SUBST([TCLTK_PATH])
 501 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 502 if test -n "$ASCIIDOC"; then
 503         AC_MSG_CHECKING([for asciidoc version])
 504         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 505         case "${asciidoc_version}" in
 506         asciidoc' '8*)
 507                 AC_MSG_RESULT([${asciidoc_version}])
 508                 ;;
 509         *)
 510                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 511                 ;;
 512         esac
 513 fi
 514
 515 if grep -a ascii configure.ac >/dev/null; then
 516   AC_MSG_RESULT([Using 'grep -a' for sane_grep])
 517   SANE_TEXT_GREP=-a
 518 else
 519   SANE_TEXT_GREP=
 520 fi
 521 GIT_CONF_SUBST([SANE_TEXT_GREP])
 522
 523 ## Checks for libraries.
 524 AC_MSG_NOTICE([CHECKS for libraries])
 525 #
 526 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 527 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 528
 529 GIT_STASH_FLAGS($OPENSSLDIR)
 530
 531 AC_CHECK_LIB([crypto], [SHA1_Init],
 532 [NEEDS_SSL_WITH_CRYPTO=],
 533 [AC_CHECK_LIB([ssl], [SHA1_Init],
 534  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 535  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 536
 537 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 538
 539 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 540 GIT_CONF_SUBST([NO_OPENSSL])
 541
 542 #
 543 # Handle the USE_LIBPCRE1 and USE_LIBPCRE2 options potentially set
 544 # above.
 545 #
 546
 547 if test -n "$USE_LIBPCRE1"; then
 548
 549 GIT_STASH_FLAGS($LIBPCREDIR)
 550
 551 AC_CHECK_LIB([pcre], [pcre_version],
 552 [USE_LIBPCRE=YesPlease],
 553 [USE_LIBPCRE=])
 554
 555 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 556
 557 GIT_CONF_SUBST([USE_LIBPCRE1])
 558
 559 fi
 560
 561
 562 if test -n "$USE_LIBPCRE2"; then
 563
 564 GIT_STASH_FLAGS($LIBPCREDIR)
 565
 566 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
 567 [USE_LIBPCRE2=YesPlease],
 568 [USE_LIBPCRE2=])
 569
 570 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 571
 572 GIT_CONF_SUBST([USE_LIBPCRE2])
 573
 574 fi
 575
 576 #
 577 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 578 # git-http-push are not built, and you cannot use http:// and https://
 579 # transports.
 580
 581 GIT_STASH_FLAGS($CURLDIR)
 582
 583 AC_CHECK_LIB([curl], [curl_global_init],
 584 [NO_CURL=],
 585 [NO_CURL=YesPlease])
 586
 587 GIT_UNSTASH_FLAGS($CURLDIR)
 588
 589 GIT_CONF_SUBST([NO_CURL])
 590
 591 if test -z "$NO_CURL"; then
 592
 593 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 594 [curl-config],
 595 [no])
 596
 597 if test $CURL_CONFIG != no; then
 598     GIT_CONF_SUBST([CURL_CONFIG])
 599     if test -z "${NO_OPENSSL}"; then
 600       AC_MSG_CHECKING([if Curl supports SSL])
 601       if test $(curl-config --features|grep SSL) = SSL; then
 602          NEEDS_SSL_WITH_CURL=YesPlease
 603          AC_MSG_RESULT([yes])
 604       else
 605          NEEDS_SSL_WITH_CURL=
 606          AC_MSG_RESULT([no])
 607       fi
 608       GIT_CONF_SUBST([NEEDS_SSL_WITH_CURL])
 609     fi
 610 fi
 611
 612 fi
 613
 614
 615 #
 616 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 617 # not built, and you cannot push using http:// and https:// transports.
 618
 619 GIT_STASH_FLAGS($EXPATDIR)
 620
 621 AC_CHECK_LIB([expat], [XML_ParserCreate],
 622 [NO_EXPAT=],
 623 [NO_EXPAT=YesPlease])
 624
 625 GIT_UNSTASH_FLAGS($EXPATDIR)
 626
 627 GIT_CONF_SUBST([NO_EXPAT])
 628
 629 #
 630 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 631 # some Solaris installations).
 632 # Define NO_ICONV if neither libc nor libiconv support iconv.
 633
 634 if test -z "$NO_ICONV"; then
 635
 636 GIT_STASH_FLAGS($ICONVDIR)
 637
 638 AC_DEFUN([ICONVTEST_SRC],
 639 [AC_LANG_PROGRAM([#include <iconv.h>],
 640  [iconv_open("", "");])])
 641
 642 if test -n "$ICONVDIR"; then
 643    lib_order="-liconv -lc"
 644 else
 645    lib_order="-lc -liconv"
 646 fi
 647
 648 NO_ICONV=YesPlease
 649
 650 for l in $lib_order; do
 651     if test "$l" = "-liconv"; then
 652        NEEDS_LIBICONV=YesPlease
 653     else
 654        NEEDS_LIBICONV=
 655     fi
 656
 657     old_LIBS="$LIBS"
 658     LIBS="$LIBS $l"
 659     AC_MSG_CHECKING([for iconv in $l])
 660     AC_LINK_IFELSE([ICONVTEST_SRC],
 661         [AC_MSG_RESULT([yes])
 662         NO_ICONV=
 663         break],
 664         [AC_MSG_RESULT([no])])
 665     LIBS="$old_LIBS"
 666 done
 667
 668 #in case of break
 669 LIBS="$old_LIBS"
 670
 671 GIT_UNSTASH_FLAGS($ICONVDIR)
 672
 673 GIT_CONF_SUBST([NEEDS_LIBICONV])
 674 GIT_CONF_SUBST([NO_ICONV])
 675
 676 if test -n "$NO_ICONV"; then
 677     NEEDS_LIBICONV=
 678 fi
 679
 680 fi
 681
 682 #
 683 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 684
 685 GIT_STASH_FLAGS($ZLIB_PATH)
 686
 687 AC_DEFUN([ZLIBTEST_SRC], [
 688 AC_LANG_PROGRAM([#include <zlib.h>],
 689  [deflateBound(0, 0);])])
 690 AC_MSG_CHECKING([for deflateBound in -lz])
 691 old_LIBS="$LIBS"
 692 LIBS="$LIBS -lz"
 693 AC_LINK_IFELSE([ZLIBTEST_SRC],
 694         [AC_MSG_RESULT([yes])],
 695         [AC_MSG_RESULT([no])
 696         NO_DEFLATE_BOUND=yes])
 697 LIBS="$old_LIBS"
 698
 699 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 700
 701 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 702
 703 #
 704 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 705 # Patrick Mauritz).
 706 AC_CHECK_LIB([c], [socket],
 707 [NEEDS_SOCKET=],
 708 [NEEDS_SOCKET=YesPlease])
 709 GIT_CONF_SUBST([NEEDS_SOCKET])
 710 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 711
 712 #
 713 # The next few tests will define NEEDS_RESOLV if linking with
 714 # libresolv provides some of the functions we would normally get
 715 # from libc.
 716 NEEDS_RESOLV=
 717 #
 718 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 719 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 720 NO_INET_NTOP=
 721 AC_CHECK_FUNC([inet_ntop],
 722     [],
 723     [AC_CHECK_LIB([resolv], [inet_ntop],
 724         [NEEDS_RESOLV=YesPlease],
 725         [NO_INET_NTOP=YesPlease])
 726 ])
 727 GIT_CONF_SUBST([NO_INET_NTOP])
 728 #
 729 # Define NO_INET_PTON if linking with -lresolv is not enough.
 730 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 731 NO_INET_PTON=
 732 AC_CHECK_FUNC([inet_pton],
 733     [],
 734     [AC_CHECK_LIB([resolv], [inet_pton],
 735         [NEEDS_RESOLV=YesPlease],
 736         [NO_INET_PTON=YesPlease])
 737 ])
 738 GIT_CONF_SUBST([NO_INET_PTON])
 739 #
 740 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 741 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 742 NO_HSTRERROR=
 743 AC_CHECK_FUNC([hstrerror],
 744     [],
 745     [AC_CHECK_LIB([resolv], [hstrerror],
 746         [NEEDS_RESOLV=YesPlease],
 747         [NO_HSTRERROR=YesPlease])
 748 ])
 749 GIT_CONF_SUBST([NO_HSTRERROR])
 750
 751 dnl This must go after all the possible places for its initialization,
 752 dnl in the AC_CHECK_FUNC invocations above.
 753 GIT_CONF_SUBST([NEEDS_RESOLV])
 754 #
 755 # If any of the above tests determined that -lresolv is needed at
 756 # build-time, also set it here for remaining configure-time checks.
 757 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 758
 759 AC_CHECK_LIB([c], [basename],
 760 [NEEDS_LIBGEN=],
 761 [NEEDS_LIBGEN=YesPlease])
 762 GIT_CONF_SUBST([NEEDS_LIBGEN])
 763 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 764
 765 AC_CHECK_LIB([c], [gettext],
 766 [LIBC_CONTAINS_LIBINTL=YesPlease],
 767 [LIBC_CONTAINS_LIBINTL=])
 768 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 769
 770 #
 771 # Define NO_GETTEXT if you don't want Git output to be translated.
 772 # A translated Git requires GNU libintl or another gettext implementation
 773 AC_CHECK_HEADER([libintl.h],
 774 [NO_GETTEXT=],
 775 [NO_GETTEXT=YesPlease])
 776 GIT_CONF_SUBST([NO_GETTEXT])
 777
 778 if test -z "$NO_GETTEXT"; then
 779     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 780 fi
 781
 782 ## Checks for header files.
 783 AC_MSG_NOTICE([CHECKS for header files])
 784 #
 785 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 786 AC_CHECK_HEADER([sys/select.h],
 787 [NO_SYS_SELECT_H=],
 788 [NO_SYS_SELECT_H=UnfortunatelyYes])
 789 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 790 #
 791 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 792 AC_CHECK_HEADER([sys/poll.h],
 793 [NO_SYS_POLL_H=],
 794 [NO_SYS_POLL_H=UnfortunatelyYes])
 795 GIT_CONF_SUBST([NO_SYS_POLL_H])
 796 #
 797 # Define NO_INTTYPES_H if you don't have inttypes.h
 798 AC_CHECK_HEADER([inttypes.h],
 799 [NO_INTTYPES_H=],
 800 [NO_INTTYPES_H=UnfortunatelyYes])
 801 GIT_CONF_SUBST([NO_INTTYPES_H])
 802 #
 803 # Define OLD_ICONV if your library has an old iconv(), where the second
 804 # (input buffer pointer) parameter is declared with type (const char **).
 805 AC_DEFUN([OLDICONVTEST_SRC], [
 806 AC_LANG_PROGRAM([[
 807 #include <iconv.h>
 808
 809 extern size_t iconv(iconv_t cd,
 810                     char **inbuf, size_t *inbytesleft,
 811                     char **outbuf, size_t *outbytesleft);
 812 ]], [])])
 813
 814 GIT_STASH_FLAGS($ICONVDIR)
 815
 816 AC_MSG_CHECKING([for old iconv()])
 817 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 818         [AC_MSG_RESULT([no])],
 819         [AC_MSG_RESULT([yes])
 820         OLD_ICONV=UnfortunatelyYes])
 821
 822 GIT_UNSTASH_FLAGS($ICONVDIR)
 823
 824 GIT_CONF_SUBST([OLD_ICONV])
 825
 826 ## Checks for typedefs, structures, and compiler characteristics.
 827 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 828 #
 829 TYPE_SOCKLEN_T
 830 case $ac_cv_type_socklen_t in
 831   yes)  SOCKLEN_T='';;
 832   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 833 esac
 834 GIT_CONF_SUBST([SOCKLEN_T])
 835
 836 #
 837 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 838 AC_CHECK_TYPES([struct itimerval],
 839 [NO_STRUCT_ITIMERVAL=],
 840 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 841 [#include <sys/time.h>])
 842 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 843 #
 844 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 845 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 846 # stat.st_mtimespec.tv_nsec exists.
 847 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 848 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 849 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 850         USE_ST_TIMESPEC=YesPlease
 851         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 852 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 853         NO_NSEC=YesPlease
 854         GIT_CONF_SUBST([NO_NSEC])
 855 fi
 856 #
 857 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 858 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 859 AC_CHECK_MEMBER(struct dirent.d_type,
 860 [NO_D_TYPE_IN_DIRENT=],
 861 [NO_D_TYPE_IN_DIRENT=YesPlease],
 862 [#include <dirent.h>])
 863 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 864 #
 865 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 866 # in the C library.
 867 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 868 [NO_GECOS_IN_PWENT=],
 869 [NO_GECOS_IN_PWENT=YesPlease],
 870 [#include <pwd.h>])
 871 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 872 #
 873 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 874 # sockaddr_storage.
 875 AC_CHECK_TYPE(struct sockaddr_storage,
 876 [NO_SOCKADDR_STORAGE=],
 877 [NO_SOCKADDR_STORAGE=YesPlease],[
 878 #include <sys/types.h>
 879 #include <sys/socket.h>
 880 ])
 881 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 882 #
 883 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 884 AC_CHECK_TYPE([struct addrinfo],[
 885  GIT_CHECK_FUNC([getaddrinfo],
 886   [NO_IPV6=],
 887   [NO_IPV6=YesPlease])
 888 ],[NO_IPV6=YesPlease],[
 889 #include <sys/types.h>
 890 #include <sys/socket.h>
 891 #include <netdb.h>
 892 ])
 893 GIT_CONF_SUBST([NO_IPV6])
 894 #
 895 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
 896 # feature.
 897 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
 898  [ac_cv_c_regex_with_reg_startend], [
 899 AC_EGREP_CPP(yippeeyeswehaveit,
 900         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 901 #include <regex.h>
 902 ],
 903 [#ifdef REG_STARTEND
 904 yippeeyeswehaveit
 905 #endif
 906 ]),
 907         [ac_cv_c_regex_with_reg_startend=yes],
 908         [ac_cv_c_regex_with_reg_startend=no])
 909 ])
 910 if test $ac_cv_c_regex_with_reg_startend = yes; then
 911         NO_REGEX=
 912 else
 913         NO_REGEX=YesPlease
 914 fi
 915 GIT_CONF_SUBST([NO_REGEX])
 916 #
 917 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 918 # when attempting to read from an fopen'ed directory.
 919 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 920  [ac_cv_fread_reads_directories],
 921 [
 922 AC_RUN_IFELSE(
 923         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 924                 [[
 925                 FILE *f = fopen(".", "r");
 926                 return f)]])],
 927         [ac_cv_fread_reads_directories=no],
 928         [ac_cv_fread_reads_directories=yes])
 929 ])
 930 if test $ac_cv_fread_reads_directories = yes; then
 931         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 932 else
 933         FREAD_READS_DIRECTORIES=
 934 fi
 935 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
 936 #
 937 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 938 # or vsnprintf() return -1 instead of number of characters which would
 939 # have been written to the final string if enough space had been available.
 940 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 941  [ac_cv_snprintf_returns_bogus],
 942 [
 943 AC_RUN_IFELSE(
 944         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 945                 #include "stdarg.h"
 946
 947                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 948                 {
 949                   int ret;
 950                   va_list ap;
 951                   va_start(ap, format);
 952                   ret = vsnprintf(str, maxsize, format, ap);
 953                   va_end(ap);
 954                   return ret;
 955                 }],
 956                 [[char buf[6];
 957                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 958                       || strcmp(buf, "12")) return 1;
 959                   if (snprintf(buf, 3, "%s", "12345") != 5
 960                       || strcmp(buf, "12")) return 1]])],
 961         [ac_cv_snprintf_returns_bogus=no],
 962         [ac_cv_snprintf_returns_bogus=yes])
 963 ])
 964 if test $ac_cv_snprintf_returns_bogus = yes; then
 965         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 966 else
 967         SNPRINTF_RETURNS_BOGUS=
 968 fi
 969 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
 970 #
 971 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
 972 # bits in mode values.
 973 AC_CACHE_CHECK([whether the platform uses typical file type bits],
 974  [ac_cv_sane_mode_bits], [
 975 AC_EGREP_CPP(yippeeyeswehaveit,
 976         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 977 [#if S_IFMT == 0170000 && \
 978         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
 979         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
 980         S_IFIFO == 0010000 && S_IFSOCK == 0140000
 981 yippeeyeswehaveit
 982 #endif
 983 ]),
 984         [ac_cv_sane_mode_bits=yes],
 985         [ac_cv_sane_mode_bits=no])
 986 ])
 987 if test $ac_cv_sane_mode_bits = yes; then
 988         NEEDS_MODE_TRANSLATION=
 989 else
 990         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
 991 fi
 992 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
 993
 994
 995 ## Checks for library functions.
 996 ## (in default C library and libraries checked by AC_CHECK_LIB)
 997 AC_MSG_NOTICE([CHECKS for library functions])
 998 #
 999 # Define NO_LIBGEN_H if you don't have libgen.h.
1000 AC_CHECK_HEADER([libgen.h],
1001 [NO_LIBGEN_H=],
1002 [NO_LIBGEN_H=YesPlease])
1003 GIT_CONF_SUBST([NO_LIBGEN_H])
1004 #
1005 # Define HAVE_PATHS_H if you have paths.h.
1006 AC_CHECK_HEADER([paths.h],
1007 [HAVE_PATHS_H=YesPlease],
1008 [HAVE_PATHS_H=])
1009 GIT_CONF_SUBST([HAVE_PATHS_H])
1010 #
1011 # Define HAVE_LIBCHARSET_H if have libcharset.h
1012 AC_CHECK_HEADER([libcharset.h],
1013 [HAVE_LIBCHARSET_H=YesPlease],
1014 [HAVE_LIBCHARSET_H=])
1015 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1016 #
1017 # Define HAVE_STRINGS_H if you have strings.h
1018 AC_CHECK_HEADER([strings.h],
1019 [HAVE_STRINGS_H=YesPlease],
1020 [HAVE_STRINGS_H=])
1021 GIT_CONF_SUBST([HAVE_STRINGS_H])
1022 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1023 # and libcharset does
1024 CHARSET_LIB=
1025 AC_CHECK_LIB([iconv], [locale_charset],
1026        [CHARSET_LIB=-liconv],
1027        [AC_CHECK_LIB([charset], [locale_charset],
1028                      [CHARSET_LIB=-lcharset])])
1029 GIT_CONF_SUBST([CHARSET_LIB])
1030 #
1031 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1032 GIT_CHECK_FUNC(clock_gettime,
1033         [HAVE_CLOCK_GETTIME=YesPlease],
1034         [HAVE_CLOCK_GETTIME=])
1035 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1036
1037 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1038 AC_LANG_PROGRAM([[
1039 #include <time.h>
1040 clockid_t id = CLOCK_MONOTONIC;
1041 ]])])
1042
1043 #
1044 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1045 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1046 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1047         [AC_MSG_RESULT([yes])
1048         HAVE_CLOCK_MONOTONIC=YesPlease],
1049         [AC_MSG_RESULT([no])
1050         HAVE_CLOCK_MONOTONIC=])
1051 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1052 #
1053 # Define NO_SETITIMER if you don't have setitimer.
1054 GIT_CHECK_FUNC(setitimer,
1055 [NO_SETITIMER=],
1056 [NO_SETITIMER=YesPlease])
1057 GIT_CONF_SUBST([NO_SETITIMER])
1058 #
1059 # Define NO_STRCASESTR if you don't have strcasestr.
1060 GIT_CHECK_FUNC(strcasestr,
1061 [NO_STRCASESTR=],
1062 [NO_STRCASESTR=YesPlease])
1063 GIT_CONF_SUBST([NO_STRCASESTR])
1064 #
1065 # Define NO_MEMMEM if you don't have memmem.
1066 GIT_CHECK_FUNC(memmem,
1067 [NO_MEMMEM=],
1068 [NO_MEMMEM=YesPlease])
1069 GIT_CONF_SUBST([NO_MEMMEM])
1070 #
1071 # Define NO_STRLCPY if you don't have strlcpy.
1072 GIT_CHECK_FUNC(strlcpy,
1073 [NO_STRLCPY=],
1074 [NO_STRLCPY=YesPlease])
1075 GIT_CONF_SUBST([NO_STRLCPY])
1076 #
1077 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1078 AC_CHECK_TYPE(uintmax_t,
1079 [NO_UINTMAX_T=],
1080 [NO_UINTMAX_T=YesPlease],[
1081 #include <inttypes.h>
1082 ])
1083 GIT_CONF_SUBST([NO_UINTMAX_T])
1084 #
1085 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1086 GIT_CHECK_FUNC(strtoumax,
1087 [NO_STRTOUMAX=],
1088 [NO_STRTOUMAX=YesPlease])
1089 GIT_CONF_SUBST([NO_STRTOUMAX])
1090 #
1091 # Define NO_SETENV if you don't have setenv in the C library.
1092 GIT_CHECK_FUNC(setenv,
1093 [NO_SETENV=],
1094 [NO_SETENV=YesPlease])
1095 GIT_CONF_SUBST([NO_SETENV])
1096 #
1097 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1098 GIT_CHECK_FUNC(unsetenv,
1099 [NO_UNSETENV=],
1100 [NO_UNSETENV=YesPlease])
1101 GIT_CONF_SUBST([NO_UNSETENV])
1102 #
1103 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1104 GIT_CHECK_FUNC(mkdtemp,
1105 [NO_MKDTEMP=],
1106 [NO_MKDTEMP=YesPlease])
1107 GIT_CONF_SUBST([NO_MKDTEMP])
1108 #
1109 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1110 GIT_CHECK_FUNC(initgroups,
1111 [NO_INITGROUPS=],
1112 [NO_INITGROUPS=YesPlease])
1113 GIT_CONF_SUBST([NO_INITGROUPS])
1114 #
1115 # Define HAVE_GETDELIM if you have getdelim in the C library.
1116 GIT_CHECK_FUNC(getdelim,
1117 [HAVE_GETDELIM=YesPlease],
1118 [HAVE_GETDELIM=])
1119 GIT_CONF_SUBST([HAVE_GETDELIM])
1120 #
1121 #
1122 # Define NO_MMAP if you want to avoid mmap.
1123 #
1124 # Define NO_ICONV if your libc does not properly support iconv.
1125
1126 AC_DEFUN([BSD_SYSCTL_SRC], [
1127 AC_LANG_PROGRAM([[
1128 #include <stddef.h>
1129 #include <sys/types.h>
1130 #include <sys/sysctl.h>
1131 ]],[[
1132 int val, mib[2];
1133 size_t len;
1134 mib[0] = CTL_HW;
1135 mib[1] = 1;
1136 len = sizeof(val);
1137 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1138 ]])])
1139
1140 #
1141 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1142 AC_MSG_CHECKING([for BSD sysctl])
1143 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1144         [AC_MSG_RESULT([yes])
1145         HAVE_BSD_SYSCTL=YesPlease],
1146         [AC_MSG_RESULT([no])
1147         HAVE_BSD_SYSCTL=])
1148 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1149
1150 ## Other checks.
1151 # Define USE_PIC if you need the main git objects to be built with -fPIC
1152 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1153 #
1154 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1155 # Enable it on Windows.  By default, symrefs are still used.
1156 #
1157 # Define NO_PTHREADS if we do not have pthreads.
1158 #
1159 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1160 AC_DEFUN([PTHREADTEST_SRC], [
1161 AC_LANG_PROGRAM([[
1162 #include <pthread.h>
1163 static void *noop(void *ignore) { return ignore; }
1164 ]], [[
1165         pthread_mutex_t test_mutex;
1166         pthread_key_t test_key;
1167         pthread_t th;
1168         int retcode = 0;
1169         void *ret = (void *)0;
1170         retcode |= pthread_key_create(&test_key, (void *)0);
1171         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1172         retcode |= pthread_mutex_lock(&test_mutex);
1173         retcode |= pthread_mutex_unlock(&test_mutex);
1174         retcode |= pthread_create(&th, ret, noop, ret);
1175         retcode |= pthread_join(th, &ret);
1176         return retcode;
1177 ]])])
1178
1179 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1180 dnl   [[#include <pthread.h>]],
1181 dnl   [[pthread_mutex_t test_mutex;]]
1182 dnl )])
1183
1184 NO_PTHREADS=UnfortunatelyYes
1185 PTHREAD_LIBS=
1186
1187 if test -n "$USER_NOPTHREAD"; then
1188    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1189 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1190 # -D_REENTRANT' or some such.
1191 elif test -z "$PTHREAD_CFLAGS"; then
1192   threads_found=no
1193   # Attempt to compile and link some code using pthreads to determine
1194   # required linker flags. The order is somewhat important here: We
1195   # first try it without any extra flags, to catch systems where
1196   # pthreads are part of the C library, then go on testing various other
1197   # flags. We do so to avoid false positives. For example, on Mac OS X
1198   # pthreads are part of the C library; moreover, the compiler allows us
1199   # to add "-mt" to the CFLAGS (although it will do nothing except
1200   # trigger a warning about an unused flag). Hence if we checked for
1201   # "-mt" before "" we would end up picking it. But unfortunately this
1202   # would then trigger compiler warnings on every single file we compile.
1203   for opt in "" -mt -pthread -lpthread; do
1204      old_CFLAGS="$CFLAGS"
1205      old_LIBS="$LIBS"
1206      case "$opt" in
1207         -l*)  LIBS="$opt $LIBS" ;;
1208         *)    CFLAGS="$opt $CFLAGS" ;;
1209      esac
1210
1211      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1212      AC_LINK_IFELSE([PTHREADTEST_SRC],
1213         [AC_MSG_RESULT([yes])
1214                 NO_PTHREADS=
1215                 PTHREAD_LIBS="$opt"
1216                 PTHREAD_CFLAGS="$opt"
1217                 threads_found=yes
1218                 break
1219         ],
1220         [AC_MSG_RESULT([no])])
1221       CFLAGS="$old_CFLAGS"
1222       LIBS="$old_LIBS"
1223   done
1224   if test $threads_found != yes; then
1225     AC_CHECK_LIB([pthread], [pthread_create],
1226         [PTHREAD_LIBS="-lpthread"],
1227         [NO_PTHREADS=UnfortunatelyYes])
1228   fi
1229 else
1230   old_CFLAGS="$CFLAGS"
1231   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1232   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1233   AC_LINK_IFELSE([PTHREADTEST_SRC],
1234         [AC_MSG_RESULT([yes])
1235                 NO_PTHREADS=
1236                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1237         ],
1238         [AC_MSG_RESULT([no])])
1239
1240   CFLAGS="$old_CFLAGS"
1241 fi
1242
1243 CFLAGS="$old_CFLAGS"
1244
1245 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1246 GIT_CONF_SUBST([PTHREAD_LIBS])
1247 GIT_CONF_SUBST([NO_PTHREADS])
1248
1249 ## Output files
1250 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1251 AC_OUTPUT