git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use POSIX qw/strftime/;
  23 use Term::ReadLine;
  24 use Getopt::Long;
  25 use Text::ParseWords;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49 git send-email --dump-aliases
  50
  51   Composing:
  52     --from                  <str>  * Email From:
  53     --[no-]to               <str>  * Email To:
  54     --[no-]cc               <str>  * Email Cc:
  55     --[no-]bcc              <str>  * Email Bcc:
  56     --subject               <str>  * Email "Subject:"
  57     --in-reply-to           <str>  * Email "In-Reply-To:"
  58     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  59     --[no-]annotate                * Review each patch that will be sent in an editor.
  60     --compose                      * Open an editor for introduction.
  61     --compose-encoding      <str>  * Encoding to assume for introduction.
  62     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  63     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  64
  65   Sending:
  66     --envelope-sender       <str>  * Email envelope sender.
  67     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  68                                      is optional. Default 'localhost'.
  69     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  70     --smtp-server-port      <int>  * Outgoing SMTP server port.
  71     --smtp-user             <str>  * Username for SMTP-AUTH.
  72     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  73     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  74     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  75     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  76                                      Pass an empty string to disable certificate
  77                                      verification.
  78     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  79     --smtp-auth             <str>  * Space-separated list of allowed AUTH mechanisms.
  80                                      This setting forces to use one of the listed mechanisms.
  81     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  82
  83   Automating:
  84     --identity              <str>  * Use the sendemail.<id> options.
  85     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  86     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  87     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  88     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  89     --[no-]to-cover                * Email To: addresses in the cover letter.
  90     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  91     --[no-]suppress-from           * Send to self. Default off.
  92     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  93     --[no-]thread                  * Use In-Reply-To: field. Default on.
  94
  95   Administering:
  96     --confirm               <str>  * Confirm recipients before sending;
  97                                      auto, cc, compose, always, or never.
  98     --quiet                        * Output one line of info per email.
  99     --dry-run                      * Don't actually send the emails.
 100     --[no-]validate                * Perform patch sanity checks. Default on.
 101     --[no-]format-patch            * understand any non optional arguments as
 102                                      `git format-patch` ones.
 103     --force                        * Send even if safety checks would prevent it.
 104
 105   Information:
 106     --dump-aliases                 * Dump configured aliases and exit.
 107
 108 EOT
 109         exit(1);
 110 }
 111
 112 # most mail servers generate the Date: header, but not all...
 113 sub format_2822_time {
 114         my ($time) = @_;
 115         my @localtm = localtime($time);
 116         my @gmttm = gmtime($time);
 117         my $localmin = $localtm[1] + $localtm[2] * 60;
 118         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 119         if ($localtm[0] != $gmttm[0]) {
 120                 die "local zone differs from GMT by a non-minute interval\n";
 121         }
 122         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 123                 $localmin += 1440;
 124         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 125                 $localmin -= 1440;
 126         } elsif ($gmttm[6] != $localtm[6]) {
 127                 die "local time offset greater than or equal to 24 hours\n";
 128         }
 129         my $offset = $localmin - $gmtmin;
 130         my $offhour = $offset / 60;
 131         my $offmin = abs($offset % 60);
 132         if (abs($offhour) >= 24) {
 133                 die ("local time offset greater than or equal to 24 hours\n");
 134         }
 135
 136         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 137                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 138                        $localtm[3],
 139                        qw(Jan Feb Mar Apr May Jun
 140                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 141                        $localtm[5]+1900,
 142                        $localtm[2],
 143                        $localtm[1],
 144                        $localtm[0],
 145                        ($offset >= 0) ? '+' : '-',
 146                        abs($offhour),
 147                        $offmin,
 148                        );
 149 }
 150
 151 my $have_email_valid = eval { require Email::Valid; 1 };
 152 my $have_mail_address = eval { require Mail::Address; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 # Regexes for RFC 2047 productions.
 157 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 158 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 159 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 160
 161 # Variables we fill in automatically, or via prompting:
 162 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 163         $initial_reply_to,$initial_subject,@files,
 164         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184 my $format_patch;
 185 my $compose_filename;
 186 my $force = 0;
 187 my $dump_aliases = 0;
 188
 189 # Handle interactive edition of files.
 190 my $multiedit;
 191 my $editor;
 192
 193 sub do_edit {
 194         if (!defined($editor)) {
 195                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 196         }
 197         if (defined($multiedit) && !$multiedit) {
 198                 map {
 199                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 200                         if (($? & 127) || ($? >> 8)) {
 201                                 die("the editor exited uncleanly, aborting everything");
 202                         }
 203                 } @_;
 204         } else {
 205                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 206                 if (($? & 127) || ($? >> 8)) {
 207                         die("the editor exited uncleanly, aborting everything");
 208                 }
 209         }
 210 }
 211
 212 # Variables with corresponding config settings
 213 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 214 my ($cover_cc, $cover_to);
 215 my ($to_cmd, $cc_cmd);
 216 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 217 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 218 my ($identity, $aliasfiletype, @alias_files, $smtp_domain, $smtp_auth);
 219 my ($validate, $confirm);
 220 my (@suppress_cc);
 221 my ($auto_8bit_encoding);
 222 my ($compose_encoding);
 223 my ($target_xfer_encoding);
 224
 225 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 226
 227 my %config_bool_settings = (
 228     "thread" => [\$thread, 1],
 229     "chainreplyto" => [\$chain_reply_to, 0],
 230     "suppressfrom" => [\$suppress_from, undef],
 231     "signedoffbycc" => [\$signed_off_by_cc, undef],
 232     "cccover" => [\$cover_cc, undef],
 233     "tocover" => [\$cover_to, undef],
 234     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 235     "validate" => [\$validate, 1],
 236     "multiedit" => [\$multiedit, undef],
 237     "annotate" => [\$annotate, undef],
 238     "xmailer" => [\$use_xmailer, 1]
 239 );
 240
 241 my %config_settings = (
 242     "smtpserver" => \$smtp_server,
 243     "smtpserverport" => \$smtp_server_port,
 244     "smtpserveroption" => \@smtp_server_options,
 245     "smtpuser" => \$smtp_authuser,
 246     "smtppass" => \$smtp_authpass,
 247     "smtpdomain" => \$smtp_domain,
 248     "smtpauth" => \$smtp_auth,
 249     "to" => \@initial_to,
 250     "tocmd" => \$to_cmd,
 251     "cc" => \@initial_cc,
 252     "cccmd" => \$cc_cmd,
 253     "aliasfiletype" => \$aliasfiletype,
 254     "bcc" => \@bcclist,
 255     "suppresscc" => \@suppress_cc,
 256     "envelopesender" => \$envelope_sender,
 257     "confirm"   => \$confirm,
 258     "from" => \$sender,
 259     "assume8bitencoding" => \$auto_8bit_encoding,
 260     "composeencoding" => \$compose_encoding,
 261     "transferencoding" => \$target_xfer_encoding,
 262 );
 263
 264 my %config_path_settings = (
 265     "aliasesfile" => \@alias_files,
 266     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 267 );
 268
 269 # Handle Uncouth Termination
 270 sub signal_handler {
 271
 272         # Make text normal
 273         print color("reset"), "\n";
 274
 275         # SMTP password masked
 276         system "stty echo";
 277
 278         # tmp files from --compose
 279         if (defined $compose_filename) {
 280                 if (-e $compose_filename) {
 281                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 282                 }
 283                 if (-e ($compose_filename . ".final")) {
 284                         print "'$compose_filename.final' contains the composed email.\n"
 285                 }
 286         }
 287
 288         exit;
 289 };
 290
 291 $SIG{TERM} = \&signal_handler;
 292 $SIG{INT}  = \&signal_handler;
 293
 294 # Begin by accumulating all the variables (defined above), that we will end up
 295 # needing, first, from the command line:
 296
 297 my $help;
 298 my $rc = GetOptions("h" => \$help,
 299                     "dump-aliases" => \$dump_aliases);
 300 usage() unless $rc;
 301 die "--dump-aliases incompatible with other options\n"
 302     if !$help and $dump_aliases and @ARGV;
 303 $rc = GetOptions(
 304                     "sender|from=s" => \$sender,
 305                     "in-reply-to=s" => \$initial_reply_to,
 306                     "subject=s" => \$initial_subject,
 307                     "to=s" => \@initial_to,
 308                     "to-cmd=s" => \$to_cmd,
 309                     "no-to" => \$no_to,
 310                     "cc=s" => \@initial_cc,
 311                     "no-cc" => \$no_cc,
 312                     "bcc=s" => \@bcclist,
 313                     "no-bcc" => \$no_bcc,
 314                     "chain-reply-to!" => \$chain_reply_to,
 315                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 316                     "smtp-server=s" => \$smtp_server,
 317                     "smtp-server-option=s" => \@smtp_server_options,
 318                     "smtp-server-port=s" => \$smtp_server_port,
 319                     "smtp-user=s" => \$smtp_authuser,
 320                     "smtp-pass:s" => \$smtp_authpass,
 321                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 322                     "smtp-encryption=s" => \$smtp_encryption,
 323                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 324                     "smtp-debug:i" => \$debug_net_smtp,
 325                     "smtp-domain:s" => \$smtp_domain,
 326                     "smtp-auth=s" => \$smtp_auth,
 327                     "identity=s" => \$identity,
 328                     "annotate!" => \$annotate,
 329                     "no-annotate" => sub {$annotate = 0},
 330                     "compose" => \$compose,
 331                     "quiet" => \$quiet,
 332                     "cc-cmd=s" => \$cc_cmd,
 333                     "suppress-from!" => \$suppress_from,
 334                     "no-suppress-from" => sub {$suppress_from = 0},
 335                     "suppress-cc=s" => \@suppress_cc,
 336                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 337                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 338                     "cc-cover|cc-cover!" => \$cover_cc,
 339                     "no-cc-cover" => sub {$cover_cc = 0},
 340                     "to-cover|to-cover!" => \$cover_to,
 341                     "no-to-cover" => sub {$cover_to = 0},
 342                     "confirm=s" => \$confirm,
 343                     "dry-run" => \$dry_run,
 344                     "envelope-sender=s" => \$envelope_sender,
 345                     "thread!" => \$thread,
 346                     "no-thread" => sub {$thread = 0},
 347                     "validate!" => \$validate,
 348                     "no-validate" => sub {$validate = 0},
 349                     "transfer-encoding=s" => \$target_xfer_encoding,
 350                     "format-patch!" => \$format_patch,
 351                     "no-format-patch" => sub {$format_patch = 0},
 352                     "8bit-encoding=s" => \$auto_8bit_encoding,
 353                     "compose-encoding=s" => \$compose_encoding,
 354                     "force" => \$force,
 355                     "xmailer!" => \$use_xmailer,
 356                     "no-xmailer" => sub {$use_xmailer = 0},
 357          );
 358
 359 usage() if $help;
 360 unless ($rc) {
 361     usage();
 362 }
 363
 364 die "Cannot run git format-patch from outside a repository\n"
 365         if $format_patch and not $repo;
 366
 367 # Now, let's fill any that aren't set in with defaults:
 368
 369 sub read_config {
 370         my ($prefix) = @_;
 371
 372         foreach my $setting (keys %config_bool_settings) {
 373                 my $target = $config_bool_settings{$setting}->[0];
 374                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 375         }
 376
 377         foreach my $setting (keys %config_path_settings) {
 378                 my $target = $config_path_settings{$setting};
 379                 if (ref($target) eq "ARRAY") {
 380                         unless (@$target) {
 381                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 382                                 @$target = @values if (@values && defined $values[0]);
 383                         }
 384                 }
 385                 else {
 386                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 387                 }
 388         }
 389
 390         foreach my $setting (keys %config_settings) {
 391                 my $target = $config_settings{$setting};
 392                 next if $setting eq "to" and defined $no_to;
 393                 next if $setting eq "cc" and defined $no_cc;
 394                 next if $setting eq "bcc" and defined $no_bcc;
 395                 if (ref($target) eq "ARRAY") {
 396                         unless (@$target) {
 397                                 my @values = Git::config(@repo, "$prefix.$setting");
 398                                 @$target = @values if (@values && defined $values[0]);
 399                         }
 400                 }
 401                 else {
 402                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 403                 }
 404         }
 405
 406         if (!defined $smtp_encryption) {
 407                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 408                 if (defined $enc) {
 409                         $smtp_encryption = $enc;
 410                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 411                         $smtp_encryption = 'ssl';
 412                 }
 413         }
 414 }
 415
 416 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 417 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 418 read_config("sendemail.$identity") if (defined $identity);
 419 read_config("sendemail");
 420
 421 # fall back on builtin bool defaults
 422 foreach my $setting (values %config_bool_settings) {
 423         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 424 }
 425
 426 # 'default' encryption is none -- this only prevents a warning
 427 $smtp_encryption = '' unless (defined $smtp_encryption);
 428
 429 # Set CC suppressions
 430 my(%suppress_cc);
 431 if (@suppress_cc) {
 432         foreach my $entry (@suppress_cc) {
 433                 die "Unknown --suppress-cc field: '$entry'\n"
 434                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 435                 $suppress_cc{$entry} = 1;
 436         }
 437 }
 438
 439 if ($suppress_cc{'all'}) {
 440         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 441                 $suppress_cc{$entry} = 1;
 442         }
 443         delete $suppress_cc{'all'};
 444 }
 445
 446 # If explicit old-style ones are specified, they trump --suppress-cc.
 447 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 448 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 449
 450 if ($suppress_cc{'body'}) {
 451         foreach my $entry (qw (sob bodycc)) {
 452                 $suppress_cc{$entry} = 1;
 453         }
 454         delete $suppress_cc{'body'};
 455 }
 456
 457 # Set confirm's default value
 458 my $confirm_unconfigured = !defined $confirm;
 459 if ($confirm_unconfigured) {
 460         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 461 };
 462 die "Unknown --confirm setting: '$confirm'\n"
 463         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 464
 465 # Debugging, print out the suppressions.
 466 if (0) {
 467         print "suppressions:\n";
 468         foreach my $entry (keys %suppress_cc) {
 469                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 470         }
 471 }
 472
 473 my ($repoauthor, $repocommitter);
 474 ($repoauthor) = Git::ident_person(@repo, 'author');
 475 ($repocommitter) = Git::ident_person(@repo, 'committer');
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return Git::parse_mailboxes($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/:include:/) {
 496                 print STDERR "warning: `:include:` not supported: $_\n";
 497         } elsif (/[\/|]/) {
 498                 print STDERR "warning: `/file` or `|pipe` redirection not supported: $_\n";
 499         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 500                 my ($alias, $addr) = ($1, $2);
 501                 $aliases{$alias} = [ split_addrs($addr) ];
 502         } else {
 503                 print STDERR "warning: sendmail line is not recognized: $_\n";
 504         }
 505 }
 506
 507 sub parse_sendmail_aliases {
 508         my $fh = shift;
 509         my $s = '';
 510         while (<$fh>) {
 511                 chomp;
 512                 next if /^\s*$/ || /^\s*#/;
 513                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 514                 parse_sendmail_alias($s) if $s;
 515                 $s = $_;
 516         }
 517         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 518         parse_sendmail_alias($s) if $s;
 519 }
 520
 521 my %parse_alias = (
 522         # multiline formats can be supported in the future
 523         mutt => sub { my $fh = shift; while (<$fh>) {
 524                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 525                         my ($alias, $addr) = ($1, $2);
 526                         $addr =~ s/#.*$//; # mutt allows # comments
 527                         # commas delimit multiple addresses
 528                         my @addr = split_addrs($addr);
 529
 530                         # quotes may be escaped in the file,
 531                         # unescape them so we do not double-escape them later.
 532                         s/\\"/"/g foreach @addr;
 533                         $aliases{$alias} = \@addr
 534                 }}},
 535         mailrc => sub { my $fh = shift; while (<$fh>) {
 536                 if (/^alias\s+(\S+)\s+(.*?)\s*$/) {
 537                         # spaces delimit multiple addresses
 538                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 539                 }}},
 540         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 541                 for (my $x = ''; defined($x); $x = $_) {
 542                         chomp $x;
 543                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 544                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 545                         $aliases{$1} = [ split_addrs($2) ];
 546                 }},
 547         elm => sub  { my $fh = shift;
 548                       while (<$fh>) {
 549                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 550                               my ($alias, $addr) = ($1, $2);
 551                                $aliases{$alias} = [ split_addrs($addr) ];
 552                           }
 553                       } },
 554         sendmail => \&parse_sendmail_aliases,
 555         gnus => sub { my $fh = shift; while (<$fh>) {
 556                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 557                         $aliases{$1} = [ $2 ];
 558                 }}}
 559 );
 560
 561 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 562         foreach my $file (@alias_files) {
 563                 open my $fh, '<', $file or die "opening $file: $!\n";
 564                 $parse_alias{$aliasfiletype}->($fh);
 565                 close $fh;
 566         }
 567 }
 568
 569 if ($dump_aliases) {
 570     print "$_\n" for (sort keys %aliases);
 571     exit(0);
 572 }
 573
 574 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 575 # $f is a revision list specification to be passed to format-patch.
 576 sub is_format_patch_arg {
 577         return unless $repo;
 578         my $f = shift;
 579         try {
 580                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 581                 if (defined($format_patch)) {
 582                         return $format_patch;
 583                 }
 584                 die(<<EOF);
 585 File '$f' exists but it could also be the range of commits
 586 to produce patches for.  Please disambiguate by...
 587
 588     * Saying "./$f" if you mean a file; or
 589     * Giving --format-patch option if you mean a range.
 590 EOF
 591         } catch Git::Error::Command with {
 592                 # Not a valid revision.  Treat it as a filename.
 593                 return 0;
 594         }
 595 }
 596
 597 # Now that all the defaults are set, process the rest of the command line
 598 # arguments and collect up the files that need to be processed.
 599 my @rev_list_opts;
 600 while (defined(my $f = shift @ARGV)) {
 601         if ($f eq "--") {
 602                 push @rev_list_opts, "--", @ARGV;
 603                 @ARGV = ();
 604         } elsif (-d $f and !is_format_patch_arg($f)) {
 605                 opendir my $dh, $f
 606                         or die "Failed to opendir $f: $!";
 607
 608                 push @files, grep { -f $_ } map { catfile($f, $_) }
 609                                 sort readdir $dh;
 610                 closedir $dh;
 611         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 612                 push @files, $f;
 613         } else {
 614                 push @rev_list_opts, $f;
 615         }
 616 }
 617
 618 if (@rev_list_opts) {
 619         die "Cannot run git format-patch from outside a repository\n"
 620                 unless $repo;
 621         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 622 }
 623
 624 if ($validate) {
 625         foreach my $f (@files) {
 626                 unless (-p $f) {
 627                         my $error = validate_patch($f);
 628                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 629                 }
 630         }
 631 }
 632
 633 if (@files) {
 634         unless ($quiet) {
 635                 print $_,"\n" for (@files);
 636         }
 637 } else {
 638         print STDERR "\nNo patch files specified!\n\n";
 639         usage();
 640 }
 641
 642 sub get_patch_subject {
 643         my $fn = shift;
 644         open (my $fh, '<', $fn);
 645         while (my $line = <$fh>) {
 646                 next unless ($line =~ /^Subject: (.*)$/);
 647                 close $fh;
 648                 return "GIT: $1\n";
 649         }
 650         close $fh;
 651         die "No subject line in $fn ?";
 652 }
 653
 654 if ($compose) {
 655         # Note that this does not need to be secure, but we will make a small
 656         # effort to have it be unique
 657         $compose_filename = ($repo ?
 658                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 659                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 660         open my $c, ">", $compose_filename
 661                 or die "Failed to open for writing $compose_filename: $!";
 662
 663
 664         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 665         my $tpl_subject = $initial_subject || '';
 666         my $tpl_reply_to = $initial_reply_to || '';
 667
 668         print $c <<EOT;
 669 From $tpl_sender # This line is ignored.
 670 GIT: Lines beginning in "GIT:" will be removed.
 671 GIT: Consider including an overall diffstat or table of contents
 672 GIT: for the patch you are writing.
 673 GIT:
 674 GIT: Clear the body content if you don't wish to send a summary.
 675 From: $tpl_sender
 676 Subject: $tpl_subject
 677 In-Reply-To: $tpl_reply_to
 678
 679 EOT
 680         for my $f (@files) {
 681                 print $c get_patch_subject($f);
 682         }
 683         close $c;
 684
 685         if ($annotate) {
 686                 do_edit($compose_filename, @files);
 687         } else {
 688                 do_edit($compose_filename);
 689         }
 690
 691         open my $c2, ">", $compose_filename . ".final"
 692                 or die "Failed to open $compose_filename.final : " . $!;
 693
 694         open $c, "<", $compose_filename
 695                 or die "Failed to open $compose_filename : " . $!;
 696
 697         my $need_8bit_cte = file_has_nonascii($compose_filename);
 698         my $in_body = 0;
 699         my $summary_empty = 1;
 700         if (!defined $compose_encoding) {
 701                 $compose_encoding = "UTF-8";
 702         }
 703         while(<$c>) {
 704                 next if m/^GIT:/;
 705                 if ($in_body) {
 706                         $summary_empty = 0 unless (/^\n$/);
 707                 } elsif (/^\n$/) {
 708                         $in_body = 1;
 709                         if ($need_8bit_cte) {
 710                                 print $c2 "MIME-Version: 1.0\n",
 711                                          "Content-Type: text/plain; ",
 712                                            "charset=$compose_encoding\n",
 713                                          "Content-Transfer-Encoding: 8bit\n";
 714                         }
 715                 } elsif (/^MIME-Version:/i) {
 716                         $need_8bit_cte = 0;
 717                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 718                         $initial_subject = $1;
 719                         my $subject = $initial_subject;
 720                         $_ = "Subject: " .
 721                                 quote_subject($subject, $compose_encoding) .
 722                                 "\n";
 723                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 724                         $initial_reply_to = $1;
 725                         next;
 726                 } elsif (/^From:\s*(.+)\s*$/i) {
 727                         $sender = $1;
 728                         next;
 729                 } elsif (/^(?:To|Cc|Bcc):/i) {
 730                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 731                         next;
 732                 }
 733                 print $c2 $_;
 734         }
 735         close $c;
 736         close $c2;
 737
 738         if ($summary_empty) {
 739                 print "Summary email is empty, skipping it\n";
 740                 $compose = -1;
 741         }
 742 } elsif ($annotate) {
 743         do_edit(@files);
 744 }
 745
 746 sub ask {
 747         my ($prompt, %arg) = @_;
 748         my $valid_re = $arg{valid_re};
 749         my $default = $arg{default};
 750         my $confirm_only = $arg{confirm_only};
 751         my $resp;
 752         my $i = 0;
 753         return defined $default ? $default : undef
 754                 unless defined $term->IN and defined fileno($term->IN) and
 755                        defined $term->OUT and defined fileno($term->OUT);
 756         while ($i++ < 10) {
 757                 $resp = $term->readline($prompt);
 758                 if (!defined $resp) { # EOF
 759                         print "\n";
 760                         return defined $default ? $default : undef;
 761                 }
 762                 if ($resp eq '' and defined $default) {
 763                         return $default;
 764                 }
 765                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 766                         return $resp;
 767                 }
 768                 if ($confirm_only) {
 769                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 770                         if (defined $yesno && $yesno =~ /y/i) {
 771                                 return $resp;
 772                         }
 773                 }
 774         }
 775         return;
 776 }
 777
 778 my %broken_encoding;
 779
 780 sub file_declares_8bit_cte {
 781         my $fn = shift;
 782         open (my $fh, '<', $fn);
 783         while (my $line = <$fh>) {
 784                 last if ($line =~ /^$/);
 785                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 786         }
 787         close $fh;
 788         return 0;
 789 }
 790
 791 foreach my $f (@files) {
 792         next unless (body_or_subject_has_nonascii($f)
 793                      && !file_declares_8bit_cte($f));
 794         $broken_encoding{$f} = 1;
 795 }
 796
 797 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 798         print "The following files are 8bit, but do not declare " .
 799                 "a Content-Transfer-Encoding.\n";
 800         foreach my $f (sort keys %broken_encoding) {
 801                 print "    $f\n";
 802         }
 803         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 804                                   valid_re => qr/.{4}/, confirm_only => 1,
 805                                   default => "UTF-8");
 806 }
 807
 808 if (!$force) {
 809         for my $f (@files) {
 810                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 811                         die "Refusing to send because the patch\n\t$f\n"
 812                                 . "has the template subject '*** SUBJECT HERE ***'. "
 813                                 . "Pass --force if you really want to send.\n";
 814                 }
 815         }
 816 }
 817
 818 if (defined $sender) {
 819         $sender =~ s/^\s+|\s+$//g;
 820         ($sender) = expand_aliases($sender);
 821 } else {
 822         $sender = $repoauthor || $repocommitter || '';
 823 }
 824
 825 # $sender could be an already sanitized address
 826 # (e.g. sendemail.from could be manually sanitized by user).
 827 # But it's a no-op to run sanitize_address on an already sanitized address.
 828 $sender = sanitize_address($sender);
 829
 830 my $to_whom = "To whom should the emails be sent (if anyone)?";
 831 my $prompting = 0;
 832 if (!@initial_to && !defined $to_cmd) {
 833         my $to = ask("$to_whom ",
 834                      default => "",
 835                      valid_re => qr/\@.*\./, confirm_only => 1);
 836         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 837         $prompting++;
 838 }
 839
 840 sub expand_aliases {
 841         return map { expand_one_alias($_) } @_;
 842 }
 843
 844 my %EXPANDED_ALIASES;
 845 sub expand_one_alias {
 846         my $alias = shift;
 847         if ($EXPANDED_ALIASES{$alias}) {
 848                 die "fatal: alias '$alias' expands to itself\n";
 849         }
 850         local $EXPANDED_ALIASES{$alias} = 1;
 851         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 852 }
 853
 854 @initial_to = process_address_list(@initial_to);
 855 @initial_cc = process_address_list(@initial_cc);
 856 @bcclist = process_address_list(@bcclist);
 857
 858 if ($thread && !defined $initial_reply_to && $prompting) {
 859         $initial_reply_to = ask(
 860                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 861                 default => "",
 862                 valid_re => qr/\@.*\./, confirm_only => 1);
 863 }
 864 if (defined $initial_reply_to) {
 865         $initial_reply_to =~ s/^\s*<?//;
 866         $initial_reply_to =~ s/>?\s*$//;
 867         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 868 }
 869
 870 if (!defined $smtp_server) {
 871         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 872                 if (-x $_) {
 873                         $smtp_server = $_;
 874                         last;
 875                 }
 876         }
 877         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 878 }
 879
 880 if ($compose && $compose > 0) {
 881         @files = ($compose_filename . ".final", @files);
 882 }
 883
 884 # Variables we set as part of the loop over files
 885 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 886         $needs_confirm, $message_num, $ask_default);
 887
 888 sub extract_valid_address {
 889         my $address = shift;
 890         my $local_part_regexp = qr/[^<>"\s@]+/;
 891         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 892
 893         # check for a local address:
 894         return $address if ($address =~ /^($local_part_regexp)$/);
 895
 896         $address =~ s/^\s*<(.*)>\s*$/$1/;
 897         if ($have_email_valid) {
 898                 return scalar Email::Valid->address($address);
 899         }
 900
 901         # less robust/correct than the monster regexp in Email::Valid,
 902         # but still does a 99% job, and one less dependency
 903         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 904         return;
 905 }
 906
 907 sub extract_valid_address_or_die {
 908         my $address = shift;
 909         $address = extract_valid_address($address);
 910         die "error: unable to extract a valid address from: $address\n"
 911                 if !$address;
 912         return $address;
 913 }
 914
 915 sub validate_address {
 916         my $address = shift;
 917         while (!extract_valid_address($address)) {
 918                 print STDERR "error: unable to extract a valid address from: $address\n";
 919                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 920                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 921                         default => 'q');
 922                 if (/^d/i) {
 923                         return undef;
 924                 } elsif (/^q/i) {
 925                         cleanup_compose_files();
 926                         exit(0);
 927                 }
 928                 $address = ask("$to_whom ",
 929                         default => "",
 930                         valid_re => qr/\@.*\./, confirm_only => 1);
 931         }
 932         return $address;
 933 }
 934
 935 sub validate_address_list {
 936         return (grep { defined $_ }
 937                 map { validate_address($_) } @_);
 938 }
 939
 940 # Usually don't need to change anything below here.
 941
 942 # we make a "fake" message id by taking the current number
 943 # of seconds since the beginning of Unix time and tacking on
 944 # a random number to the end, in case we are called quicker than
 945 # 1 second since the last time we were called.
 946
 947 # We'll setup a template for the message id, using the "from" address:
 948
 949 my ($message_id_stamp, $message_id_serial);
 950 sub make_message_id {
 951         my $uniq;
 952         if (!defined $message_id_stamp) {
 953                 $message_id_stamp = strftime("%Y%m%d%H%M%S.$$", gmtime(time));
 954                 $message_id_serial = 0;
 955         }
 956         $message_id_serial++;
 957         $uniq = "$message_id_stamp-$message_id_serial";
 958
 959         my $du_part;
 960         for ($sender, $repocommitter, $repoauthor) {
 961                 $du_part = extract_valid_address(sanitize_address($_));
 962                 last if (defined $du_part and $du_part ne '');
 963         }
 964         if (not defined $du_part or $du_part eq '') {
 965                 require Sys::Hostname;
 966                 $du_part = 'user@' . Sys::Hostname::hostname();
 967         }
 968         my $message_id_template = "<%s-%s>";
 969         $message_id = sprintf($message_id_template, $uniq, $du_part);
 970         #print "new message id = $message_id\n"; # Was useful for debugging
 971 }
 972
 973
 974
 975 $time = time - scalar $#files;
 976
 977 sub unquote_rfc2047 {
 978         local ($_) = @_;
 979         my $charset;
 980         my $sep = qr/[ \t]+/;
 981         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 982                 my @words = split $sep, $&;
 983                 foreach (@words) {
 984                         m/$re_encoded_word/;
 985                         $charset = $1;
 986                         my $encoding = $2;
 987                         my $text = $3;
 988                         if ($encoding eq 'q' || $encoding eq 'Q') {
 989                                 $_ = $text;
 990                                 s/_/ /g;
 991                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 992                         } else {
 993                                 # other encodings not supported yet
 994                         }
 995                 }
 996                 join '', @words;
 997         }eg;
 998         return wantarray ? ($_, $charset) : $_;
 999 }
1000
1001 sub quote_rfc2047 {
1002         local $_ = shift;
1003         my $encoding = shift || 'UTF-8';
1004         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
1005         s/(.*)/=\?$encoding\?q\?$1\?=/;
1006         return $_;
1007 }
1008
1009 sub is_rfc2047_quoted {
1010         my $s = shift;
1011         length($s) <= 75 &&
1012         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
1013 }
1014
1015 sub subject_needs_rfc2047_quoting {
1016         my $s = shift;
1017
1018         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1019 }
1020
1021 sub quote_subject {
1022         local $subject = shift;
1023         my $encoding = shift || 'UTF-8';
1024
1025         if (subject_needs_rfc2047_quoting($subject)) {
1026                 return quote_rfc2047($subject, $encoding);
1027         }
1028         return $subject;
1029 }
1030
1031 # use the simplest quoting being able to handle the recipient
1032 sub sanitize_address {
1033         my ($recipient) = @_;
1034
1035         # remove garbage after email address
1036         $recipient =~ s/(.*>).*$/$1/;
1037
1038         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1039
1040         if (not $recipient_name) {
1041                 return $recipient;
1042         }
1043
1044         # if recipient_name is already quoted, do nothing
1045         if (is_rfc2047_quoted($recipient_name)) {
1046                 return $recipient;
1047         }
1048
1049         # remove non-escaped quotes
1050         $recipient_name =~ s/(^|[^\\])"/$1/g;
1051
1052         # rfc2047 is needed if a non-ascii char is included
1053         if ($recipient_name =~ /[^[:ascii:]]/) {
1054                 $recipient_name = quote_rfc2047($recipient_name);
1055         }
1056
1057         # double quotes are needed if specials or CTLs are included
1058         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1059                 $recipient_name =~ s/([\\\r])/\\$1/g;
1060                 $recipient_name = qq["$recipient_name"];
1061         }
1062
1063         return "$recipient_name $recipient_addr";
1064
1065 }
1066
1067 sub sanitize_address_list {
1068         return (map { sanitize_address($_) } @_);
1069 }
1070
1071 sub process_address_list {
1072         my @addr_list = map { parse_address_line($_) } @_;
1073         @addr_list = expand_aliases(@addr_list);
1074         @addr_list = sanitize_address_list(@addr_list);
1075         @addr_list = validate_address_list(@addr_list);
1076         return @addr_list;
1077 }
1078
1079 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1080 #
1081 # Tightly configured MTAa require that a caller sends a real DNS
1082 # domain name that corresponds the IP address in the HELO/EHLO
1083 # handshake. This is used to verify the connection and prevent
1084 # spammers from trying to hide their identity. If the DNS and IP don't
1085 # match, the receiveing MTA may deny the connection.
1086 #
1087 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1088 #
1089 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1090 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1091 #
1092 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1093 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1094
1095 sub valid_fqdn {
1096         my $domain = shift;
1097         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1098 }
1099
1100 sub maildomain_net {
1101         my $maildomain;
1102
1103         if (eval { require Net::Domain; 1 }) {
1104                 my $domain = Net::Domain::domainname();
1105                 $maildomain = $domain if valid_fqdn($domain);
1106         }
1107
1108         return $maildomain;
1109 }
1110
1111 sub maildomain_mta {
1112         my $maildomain;
1113
1114         if (eval { require Net::SMTP; 1 }) {
1115                 for my $host (qw(mailhost localhost)) {
1116                         my $smtp = Net::SMTP->new($host);
1117                         if (defined $smtp) {
1118                                 my $domain = $smtp->domain;
1119                                 $smtp->quit;
1120
1121                                 $maildomain = $domain if valid_fqdn($domain);
1122
1123                                 last if $maildomain;
1124                         }
1125                 }
1126         }
1127
1128         return $maildomain;
1129 }
1130
1131 sub maildomain {
1132         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1133 }
1134
1135 sub smtp_host_string {
1136         if (defined $smtp_server_port) {
1137                 return "$smtp_server:$smtp_server_port";
1138         } else {
1139                 return $smtp_server;
1140         }
1141 }
1142
1143 # Returns 1 if authentication succeeded or was not necessary
1144 # (smtp_user was not specified), and 0 otherwise.
1145
1146 sub smtp_auth_maybe {
1147         if (!defined $smtp_authuser || $auth) {
1148                 return 1;
1149         }
1150
1151         # Workaround AUTH PLAIN/LOGIN interaction defect
1152         # with Authen::SASL::Cyrus
1153         eval {
1154                 require Authen::SASL;
1155                 Authen::SASL->import(qw(Perl));
1156         };
1157
1158         # Check mechanism naming as defined in:
1159         # https://tools.ietf.org/html/rfc4422#page-8
1160         if ($smtp_auth && $smtp_auth !~ /^(\b[A-Z0-9-_]{1,20}\s*)*$/) {
1161                 die "invalid smtp auth: '${smtp_auth}'";
1162         }
1163
1164         # TODO: Authentication may fail not because credentials were
1165         # invalid but due to other reasons, in which we should not
1166         # reject credentials.
1167         $auth = Git::credential({
1168                 'protocol' => 'smtp',
1169                 'host' => smtp_host_string(),
1170                 'username' => $smtp_authuser,
1171                 # if there's no password, "git credential fill" will
1172                 # give us one, otherwise it'll just pass this one.
1173                 'password' => $smtp_authpass
1174         }, sub {
1175                 my $cred = shift;
1176
1177                 if ($smtp_auth) {
1178                         my $sasl = Authen::SASL->new(
1179                                 mechanism => $smtp_auth,
1180                                 callback => {
1181                                         user => $cred->{'username'},
1182                                         pass => $cred->{'password'},
1183                                         authname => $cred->{'username'},
1184                                 }
1185                         );
1186
1187                         return !!$smtp->auth($sasl);
1188                 }
1189
1190                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1191         });
1192
1193         return $auth;
1194 }
1195
1196 sub ssl_verify_params {
1197         eval {
1198                 require IO::Socket::SSL;
1199                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1200         };
1201         if ($@) {
1202                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1203                 return;
1204         }
1205
1206         if (!defined $smtp_ssl_cert_path) {
1207                 # use the OpenSSL defaults
1208                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1209         }
1210
1211         if ($smtp_ssl_cert_path eq "") {
1212                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1213         } elsif (-d $smtp_ssl_cert_path) {
1214                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1215                         SSL_ca_path => $smtp_ssl_cert_path);
1216         } elsif (-f $smtp_ssl_cert_path) {
1217                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1218                         SSL_ca_file => $smtp_ssl_cert_path);
1219         } else {
1220                 die "CA path \"$smtp_ssl_cert_path\" does not exist";
1221         }
1222 }
1223
1224 sub file_name_is_absolute {
1225         my ($path) = @_;
1226
1227         # msys does not grok DOS drive-prefixes
1228         if ($^O eq 'msys') {
1229                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1230         }
1231
1232         require File::Spec::Functions;
1233         return File::Spec::Functions::file_name_is_absolute($path);
1234 }
1235
1236 # Returns 1 if the message was sent, and 0 otherwise.
1237 # In actuality, the whole program dies when there
1238 # is an error sending a message.
1239
1240 sub send_message {
1241         my @recipients = unique_email_list(@to);
1242         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1243                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1244                     }
1245                @cc);
1246         my $to = join (",\n\t", @recipients);
1247         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1248         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1249         my $date = format_2822_time($time++);
1250         my $gitversion = '@@GIT_VERSION@@';
1251         if ($gitversion =~ m/..GIT_VERSION../) {
1252             $gitversion = Git::version();
1253         }
1254
1255         my $cc = join(",\n\t", unique_email_list(@cc));
1256         my $ccline = "";
1257         if ($cc ne '') {
1258                 $ccline = "\nCc: $cc";
1259         }
1260         make_message_id() unless defined($message_id);
1261
1262         my $header = "From: $sender
1263 To: $to${ccline}
1264 Subject: $subject
1265 Date: $date
1266 Message-Id: $message_id
1267 ";
1268         if ($use_xmailer) {
1269                 $header .= "X-Mailer: git-send-email $gitversion\n";
1270         }
1271         if ($reply_to) {
1272
1273                 $header .= "In-Reply-To: $reply_to\n";
1274                 $header .= "References: $references\n";
1275         }
1276         if (@xh) {
1277                 $header .= join("\n", @xh) . "\n";
1278         }
1279
1280         my @sendmail_parameters = ('-i', @recipients);
1281         my $raw_from = $sender;
1282         if (defined $envelope_sender && $envelope_sender ne "auto") {
1283                 $raw_from = $envelope_sender;
1284         }
1285         $raw_from = extract_valid_address($raw_from);
1286         unshift (@sendmail_parameters,
1287                         '-f', $raw_from) if(defined $envelope_sender);
1288
1289         if ($needs_confirm && !$dry_run) {
1290                 print "\n$header\n";
1291                 if ($needs_confirm eq "inform") {
1292                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1293                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1294                         print "    The Cc list above has been expanded by additional\n";
1295                         print "    addresses found in the patch commit message. By default\n";
1296                         print "    send-email prompts before sending whenever this occurs.\n";
1297                         print "    This behavior is controlled by the sendemail.confirm\n";
1298                         print "    configuration setting.\n";
1299                         print "\n";
1300                         print "    For additional information, run 'git send-email --help'.\n";
1301                         print "    To retain the current behavior, but squelch this message,\n";
1302                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1303                 }
1304                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1305                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1306                          default => $ask_default);
1307                 die "Send this email reply required" unless defined $_;
1308                 if (/^n/i) {
1309                         return 0;
1310                 } elsif (/^q/i) {
1311                         cleanup_compose_files();
1312                         exit(0);
1313                 } elsif (/^a/i) {
1314                         $confirm = 'never';
1315                 }
1316         }
1317
1318         unshift (@sendmail_parameters, @smtp_server_options);
1319
1320         if ($dry_run) {
1321                 # We don't want to send the email.
1322         } elsif (file_name_is_absolute($smtp_server)) {
1323                 my $pid = open my $sm, '|-';
1324                 defined $pid or die $!;
1325                 if (!$pid) {
1326                         exec($smtp_server, @sendmail_parameters) or die $!;
1327                 }
1328                 print $sm "$header\n$message";
1329                 close $sm or die $!;
1330         } else {
1331
1332                 if (!defined $smtp_server) {
1333                         die "The required SMTP server is not properly defined."
1334                 }
1335
1336                 if ($smtp_encryption eq 'ssl') {
1337                         $smtp_server_port ||= 465; # ssmtp
1338                         require Net::SMTP::SSL;
1339                         $smtp_domain ||= maildomain();
1340                         require IO::Socket::SSL;
1341
1342                         # Suppress "variable accessed once" warning.
1343                         {
1344                                 no warnings 'once';
1345                                 $IO::Socket::SSL::DEBUG = 1;
1346                         }
1347
1348                         # Net::SMTP::SSL->new() does not forward any SSL options
1349                         IO::Socket::SSL::set_client_defaults(
1350                                 ssl_verify_params());
1351                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1352                                                       Hello => $smtp_domain,
1353                                                       Port => $smtp_server_port,
1354                                                       Debug => $debug_net_smtp);
1355                 }
1356                 else {
1357                         require Net::SMTP;
1358                         $smtp_domain ||= maildomain();
1359                         $smtp_server_port ||= 25;
1360                         $smtp ||= Net::SMTP->new($smtp_server,
1361                                                  Hello => $smtp_domain,
1362                                                  Debug => $debug_net_smtp,
1363                                                  Port => $smtp_server_port);
1364                         if ($smtp_encryption eq 'tls' && $smtp) {
1365                                 require Net::SMTP::SSL;
1366                                 $smtp->command('STARTTLS');
1367                                 $smtp->response();
1368                                 if ($smtp->code == 220) {
1369                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1370                                                                           ssl_verify_params())
1371                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1372                                         $smtp_encryption = '';
1373                                         # Send EHLO again to receive fresh
1374                                         # supported commands
1375                                         $smtp->hello($smtp_domain);
1376                                 } else {
1377                                         die "Server does not support STARTTLS! ".$smtp->message;
1378                                 }
1379                         }
1380                 }
1381
1382                 if (!$smtp) {
1383                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1384                             "VALUES: server=$smtp_server ",
1385                             "encryption=$smtp_encryption ",
1386                             "hello=$smtp_domain",
1387                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1388                 }
1389
1390                 smtp_auth_maybe or die $smtp->message;
1391
1392                 $smtp->mail( $raw_from ) or die $smtp->message;
1393                 $smtp->to( @recipients ) or die $smtp->message;
1394                 $smtp->data or die $smtp->message;
1395                 $smtp->datasend("$header\n") or die $smtp->message;
1396                 my @lines = split /^/, $message;
1397                 foreach my $line (@lines) {
1398                         $smtp->datasend("$line") or die $smtp->message;
1399                 }
1400                 $smtp->dataend() or die $smtp->message;
1401                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1402         }
1403         if ($quiet) {
1404                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1405         } else {
1406                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1407                 if (!file_name_is_absolute($smtp_server)) {
1408                         print "Server: $smtp_server\n";
1409                         print "MAIL FROM:<$raw_from>\n";
1410                         foreach my $entry (@recipients) {
1411                             print "RCPT TO:<$entry>\n";
1412                         }
1413                 } else {
1414                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1415                 }
1416                 print $header, "\n";
1417                 if ($smtp) {
1418                         print "Result: ", $smtp->code, ' ',
1419                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1420                 } else {
1421                         print "Result: OK\n";
1422                 }
1423         }
1424
1425         return 1;
1426 }
1427
1428 $reply_to = $initial_reply_to;
1429 $references = $initial_reply_to || '';
1430 $subject = $initial_subject;
1431 $message_num = 0;
1432
1433 foreach my $t (@files) {
1434         open my $fh, "<", $t or die "can't open file $t";
1435
1436         my $author = undef;
1437         my $sauthor = undef;
1438         my $author_encoding;
1439         my $has_content_type;
1440         my $body_encoding;
1441         my $xfer_encoding;
1442         my $has_mime_version;
1443         @to = ();
1444         @cc = ();
1445         @xh = ();
1446         my $input_format = undef;
1447         my @header = ();
1448         $message = "";
1449         $message_num++;
1450         # First unfold multiline header fields
1451         while(<$fh>) {
1452                 last if /^\s*$/;
1453                 if (/^\s+\S/ and @header) {
1454                         chomp($header[$#header]);
1455                         s/^\s+/ /;
1456                         $header[$#header] .= $_;
1457             } else {
1458                         push(@header, $_);
1459                 }
1460         }
1461         # Now parse the header
1462         foreach(@header) {
1463                 if (/^From /) {
1464                         $input_format = 'mbox';
1465                         next;
1466                 }
1467                 chomp;
1468                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1469                         $input_format = 'mbox';
1470                 }
1471
1472                 if (defined $input_format && $input_format eq 'mbox') {
1473                         if (/^Subject:\s+(.*)$/i) {
1474                                 $subject = $1;
1475                         }
1476                         elsif (/^From:\s+(.*)$/i) {
1477                                 ($author, $author_encoding) = unquote_rfc2047($1);
1478                                 $sauthor = sanitize_address($author);
1479                                 next if $suppress_cc{'author'};
1480                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1481                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1482                                         $1, $_) unless $quiet;
1483                                 push @cc, $1;
1484                         }
1485                         elsif (/^To:\s+(.*)$/i) {
1486                                 foreach my $addr (parse_address_line($1)) {
1487                                         printf("(mbox) Adding to: %s from line '%s'\n",
1488                                                 $addr, $_) unless $quiet;
1489                                         push @to, $addr;
1490                                 }
1491                         }
1492                         elsif (/^Cc:\s+(.*)$/i) {
1493                                 foreach my $addr (parse_address_line($1)) {
1494                                         my $qaddr = unquote_rfc2047($addr);
1495                                         my $saddr = sanitize_address($qaddr);
1496                                         if ($saddr eq $sender) {
1497                                                 next if ($suppress_cc{'self'});
1498                                         } else {
1499                                                 next if ($suppress_cc{'cc'});
1500                                         }
1501                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1502                                                 $addr, $_) unless $quiet;
1503                                         push @cc, $addr;
1504                                 }
1505                         }
1506                         elsif (/^Content-type:/i) {
1507                                 $has_content_type = 1;
1508                                 if (/charset="?([^ "]+)/) {
1509                                         $body_encoding = $1;
1510                                 }
1511                                 push @xh, $_;
1512                         }
1513                         elsif (/^MIME-Version/i) {
1514                                 $has_mime_version = 1;
1515                                 push @xh, $_;
1516                         }
1517                         elsif (/^Message-Id: (.*)/i) {
1518                                 $message_id = $1;
1519                         }
1520                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1521                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1522                         }
1523                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1524                                 push @xh, $_;
1525                         }
1526
1527                 } else {
1528                         # In the traditional
1529                         # "send lots of email" format,
1530                         # line 1 = cc
1531                         # line 2 = subject
1532                         # So let's support that, too.
1533                         $input_format = 'lots';
1534                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1535                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1536                                         $_, $_) unless $quiet;
1537                                 push @cc, $_;
1538                         } elsif (!defined $subject) {
1539                                 $subject = $_;
1540                         }
1541                 }
1542         }
1543         # Now parse the message body
1544         while(<$fh>) {
1545                 $message .=  $_;
1546                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1547                         chomp;
1548                         my ($what, $c) = ($1, $2);
1549                         chomp $c;
1550                         my $sc = sanitize_address($c);
1551                         if ($sc eq $sender) {
1552                                 next if ($suppress_cc{'self'});
1553                         } else {
1554                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1555                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1556                         }
1557                         push @cc, $c;
1558                         printf("(body) Adding cc: %s from line '%s'\n",
1559                                 $c, $_) unless $quiet;
1560                 }
1561         }
1562         close $fh;
1563
1564         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1565                 if defined $to_cmd;
1566         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1567                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1568
1569         if ($broken_encoding{$t} && !$has_content_type) {
1570                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1571                 $has_content_type = 1;
1572                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1573                 $body_encoding = $auto_8bit_encoding;
1574         }
1575
1576         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1577                 $subject = quote_subject($subject, $auto_8bit_encoding);
1578         }
1579
1580         if (defined $sauthor and $sauthor ne $sender) {
1581                 $message = "From: $author\n\n$message";
1582                 if (defined $author_encoding) {
1583                         if ($has_content_type) {
1584                                 if ($body_encoding eq $author_encoding) {
1585                                         # ok, we already have the right encoding
1586                                 }
1587                                 else {
1588                                         # uh oh, we should re-encode
1589                                 }
1590                         }
1591                         else {
1592                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1593                                 $has_content_type = 1;
1594                                 push @xh,
1595                                   "Content-Type: text/plain; charset=$author_encoding";
1596                         }
1597                 }
1598         }
1599         if (defined $target_xfer_encoding) {
1600                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1601                 $message = apply_transfer_encoding(
1602                         $message, $xfer_encoding, $target_xfer_encoding);
1603                 $xfer_encoding = $target_xfer_encoding;
1604         }
1605         if (defined $xfer_encoding) {
1606                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1607         }
1608         if (defined $xfer_encoding or $has_content_type) {
1609                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1610         }
1611
1612         $needs_confirm = (
1613                 $confirm eq "always" or
1614                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1615                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1616         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1617
1618         @to = process_address_list(@to);
1619         @cc = process_address_list(@cc);
1620
1621         @to = (@initial_to, @to);
1622         @cc = (@initial_cc, @cc);
1623
1624         if ($message_num == 1) {
1625                 if (defined $cover_cc and $cover_cc) {
1626                         @initial_cc = @cc;
1627                 }
1628                 if (defined $cover_to and $cover_to) {
1629                         @initial_to = @to;
1630                 }
1631         }
1632
1633         my $message_was_sent = send_message();
1634
1635         # set up for the next message
1636         if ($thread && $message_was_sent &&
1637                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1638                 $message_num == 1)) {
1639                 $reply_to = $message_id;
1640                 if (length $references > 0) {
1641                         $references .= "\n $message_id";
1642                 } else {
1643                         $references = "$message_id";
1644                 }
1645         }
1646         $message_id = undef;
1647 }
1648
1649 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1650 # and return a results array
1651 sub recipients_cmd {
1652         my ($prefix, $what, $cmd, $file) = @_;
1653
1654         my @addresses = ();
1655         open my $fh, "-|", "$cmd \Q$file\E"
1656             or die "($prefix) Could not execute '$cmd'";
1657         while (my $address = <$fh>) {
1658                 $address =~ s/^\s*//g;
1659                 $address =~ s/\s*$//g;
1660                 $address = sanitize_address($address);
1661                 next if ($address eq $sender and $suppress_cc{'self'});
1662                 push @addresses, $address;
1663                 printf("($prefix) Adding %s: %s from: '%s'\n",
1664                        $what, $address, $cmd) unless $quiet;
1665                 }
1666         close $fh
1667             or die "($prefix) failed to close pipe to '$cmd'";
1668         return @addresses;
1669 }
1670
1671 cleanup_compose_files();
1672
1673 sub cleanup_compose_files {
1674         unlink($compose_filename, $compose_filename . ".final") if $compose;
1675 }
1676
1677 $smtp->quit if $smtp;
1678
1679 sub apply_transfer_encoding {
1680         my $message = shift;
1681         my $from = shift;
1682         my $to = shift;
1683
1684         return $message if ($from eq $to and $from ne '7bit');
1685
1686         require MIME::QuotedPrint;
1687         require MIME::Base64;
1688
1689         $message = MIME::QuotedPrint::decode($message)
1690                 if ($from eq 'quoted-printable');
1691         $message = MIME::Base64::decode($message)
1692                 if ($from eq 'base64');
1693
1694         die "cannot send message as 7bit"
1695                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1696         return $message
1697                 if ($to eq '7bit' or $to eq '8bit');
1698         return MIME::QuotedPrint::encode($message, "\n", 0)
1699                 if ($to eq 'quoted-printable');
1700         return MIME::Base64::encode($message, "\n")
1701                 if ($to eq 'base64');
1702         die "invalid transfer encoding";
1703 }
1704
1705 sub unique_email_list {
1706         my %seen;
1707         my @emails;
1708
1709         foreach my $entry (@_) {
1710                 my $clean = extract_valid_address_or_die($entry);
1711                 $seen{$clean} ||= 0;
1712                 next if $seen{$clean}++;
1713                 push @emails, $entry;
1714         }
1715         return @emails;
1716 }
1717
1718 sub validate_patch {
1719         my $fn = shift;
1720         open(my $fh, '<', $fn)
1721                 or die "unable to open $fn: $!\n";
1722         while (my $line = <$fh>) {
1723                 if (length($line) > 998) {
1724                         return "$.: patch contains a line longer than 998 characters";
1725                 }
1726         }
1727         return;
1728 }
1729
1730 sub file_has_nonascii {
1731         my $fn = shift;
1732         open(my $fh, '<', $fn)
1733                 or die "unable to open $fn: $!\n";
1734         while (my $line = <$fh>) {
1735                 return 1 if $line =~ /[^[:ascii:]]/;
1736         }
1737         return 0;
1738 }
1739
1740 sub body_or_subject_has_nonascii {
1741         my $fn = shift;
1742         open(my $fh, '<', $fn)
1743                 or die "unable to open $fn: $!\n";
1744         while (my $line = <$fh>) {
1745                 last if $line =~ /^$/;
1746                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1747         }
1748         while (my $line = <$fh>) {
1749                 return 1 if $line =~ /[^[:ascii:]]/;
1750         }
1751         return 0;
1752 }