configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specified by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 #
 245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 246 # /foo/bar/include and /foo/bar/lib directories.
 247 AC_ARG_WITH(openssl,
 248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 249 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 250 GIT_PARSE_WITH([openssl]))
 251
 252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 253 # commands such as log and grep offer runtime options to use
 254 # Perl-compatible regular expressions instead of standard or extended
 255 # POSIX regular expressions.
 256 #
 257 # USE_LIBPCRE is a synonym for USE_LIBPCRE2, define USE_LIBPCRE1
 258 # instead if you'd like to use the legacy version 1 of the PCRE
 259 # library. Support for version 1 will likely be removed in some future
 260 # release of Git, as upstream has all but abandoned it.
 261 #
 262 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
 263 # /foo/bar/include and /foo/bar/lib directories.
 264 #
 265 AC_ARG_WITH(libpcre,
 266 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
 267     if test "$withval" = "no"; then
 268         USE_LIBPCRE2=
 269     elif test "$withval" = "yes"; then
 270         USE_LIBPCRE2=YesPlease
 271     else
 272         USE_LIBPCRE2=YesPlease
 273         LIBPCREDIR=$withval
 274         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 275         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 276         dnl it yet.
 277         GIT_CONF_SUBST([LIBPCREDIR])
 278     fi)
 279
 280 AC_ARG_WITH(libpcre1,
 281 AS_HELP_STRING([--with-libpcre1],[support Perl-compatible regexes via libpcre1 (default is NO)])
 282 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 283     if test "$withval" = "no"; then
 284         USE_LIBPCRE1=
 285     elif test "$withval" = "yes"; then
 286         USE_LIBPCRE1=YesPlease
 287     else
 288         USE_LIBPCRE1=YesPlease
 289         LIBPCREDIR=$withval
 290         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 291         dnl USE_LIBPCRE1 can still be modified below, so don't substitute
 292         dnl it yet.
 293         GIT_CONF_SUBST([LIBPCREDIR])
 294     fi)
 295
 296 AC_ARG_WITH(libpcre2,
 297 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
 298 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 299     if test -n "$USE_LIBPCRE2"; then
 300         AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
 301     fi
 302
 303     if test -n "$USE_LIBPCRE1"; then
 304         AC_MSG_ERROR([Only supply one of --with-libpcre1 or --with-libpcre2!])
 305     fi
 306
 307     if test "$withval" = "no"; then
 308         USE_LIBPCRE2=
 309     elif test "$withval" = "yes"; then
 310         USE_LIBPCRE2=YesPlease
 311     else
 312         USE_LIBPCRE2=YesPlease
 313         LIBPCREDIR=$withval
 314         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 315         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 316         dnl it yet.
 317         GIT_CONF_SUBST([LIBPCREDIR])
 318     fi)
 319 #
 320 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 321 AC_FUNC_ALLOCA
 322 case $ac_cv_working_alloca_h in
 323     yes)    HAVE_ALLOCA_H=YesPlease;;
 324     *)      HAVE_ALLOCA_H='';;
 325 esac
 326 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 327 #
 328 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 329 # git-http-push are not built, and you cannot use http:// and https://
 330 # transports.
 331 #
 332 # Define CURLDIR=/foo/bar if your curl header and library files are in
 333 # /foo/bar/include and /foo/bar/lib directories.
 334 AC_ARG_WITH(curl,
 335 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 336 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 337 GIT_PARSE_WITH(curl))
 338 #
 339 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 340 # not built, and you cannot push using http:// and https:// transports.
 341 #
 342 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 343 # /foo/bar/include and /foo/bar/lib directories.
 344 AC_ARG_WITH(expat,
 345 AS_HELP_STRING([--with-expat],
 346 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 347 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 348 GIT_PARSE_WITH(expat))
 349 #
 350 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 351 # installed in /sw, but don't want GIT to link against any libraries
 352 # installed there.  If defined you may specify your own (or Fink's)
 353 # include directories and library directories by defining CFLAGS
 354 # and LDFLAGS appropriately.
 355 #
 356 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 357 # have DarwinPorts installed in /opt/local, but don't want GIT to
 358 # link against any libraries installed there.  If defined you may
 359 # specify your own (or DarwinPort's) include directories and
 360 # library directories by defining CFLAGS and LDFLAGS appropriately.
 361 #
 362 # Define NO_MMAP if you want to avoid mmap.
 363 #
 364 # Define NO_ICONV if your libc does not properly support iconv.
 365 AC_ARG_WITH(iconv,
 366 AS_HELP_STRING([--without-iconv],
 367 [if your architecture doesn't properly support iconv])
 368 AS_HELP_STRING([--with-iconv=PATH],
 369 [PATH is prefix for libiconv library and headers])
 370 AS_HELP_STRING([],
 371 [used only if you need linking with libiconv]),
 372 GIT_PARSE_WITH(iconv))
 373
 374 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 375 #
 376 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 377 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 378 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 379 # randomly break unless your underlying filesystem supports those sub-second
 380 # times (my ext3 doesn't).
 381 #
 382 # Define USE_STDEV below if you want git to care about the underlying device
 383 # change being considered an inode change from the update-index perspective.
 384
 385 #
 386 # Allow user to set ETC_GITCONFIG variable
 387 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 388                         Use VALUE instead of /etc/gitconfig as the
 389                         global git configuration file.
 390                         If VALUE is not fully qualified it will be interpreted
 391                         as a path relative to the computed prefix at runtime.)
 392
 393 #
 394 # Allow user to set ETC_GITATTRIBUTES variable
 395 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 396                         Use VALUE instead of /etc/gitattributes as the
 397                         global git attributes file.
 398                         If VALUE is not fully qualified it will be interpreted
 399                         as a path relative to the computed prefix at runtime.)
 400
 401 #
 402 # Allow user to set the default pager
 403 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 404                         Use VALUE as the fall-back pager instead of 'less'.
 405                         This is used by things like 'git log' when the user
 406                         does not specify a pager to use through alternate
 407                         methods. eg: /usr/bin/pager)
 408 #
 409 # Allow user to set the default editor
 410 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 411                         Use VALUE as the fall-back editor instead of 'vi'.
 412                         This is used by things like 'git commit' when the user
 413                         does not specify a preferred editor through other
 414                         methods. eg: /usr/bin/editor)
 415
 416 #
 417 # Define SHELL_PATH to provide path to shell.
 418 GIT_ARG_SET_PATH(shell)
 419 #
 420 # Define PERL_PATH to provide path to Perl.
 421 GIT_ARG_SET_PATH(perl)
 422 #
 423 # Define PYTHON_PATH to provide path to Python.
 424 GIT_ARG_SET_PATH(python, allow-without)
 425 #
 426 # Define ZLIB_PATH to provide path to zlib.
 427 GIT_ARG_SET_PATH(zlib)
 428 #
 429 # Declare the with-tcltk/without-tcltk options.
 430 AC_ARG_WITH(tcltk,
 431 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 432 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 433 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 434 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 435 GIT_PARSE_WITH(tcltk))
 436 #
 437
 438
 439 ## Checks for programs.
 440 AC_MSG_NOTICE([CHECKS for programs])
 441 #
 442 AC_PROG_CC([cc gcc])
 443 AC_C_INLINE
 444 case $ac_cv_c_inline in
 445   inline | yes | no) INLINE='';;
 446   *)                 INLINE=$ac_cv_c_inline ;;
 447 esac
 448 GIT_CONF_SUBST([INLINE])
 449
 450 # which switch to pass runtime path to dynamic libraries to the linker
 451 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 452    SAVE_LDFLAGS="${LDFLAGS}"
 453    LDFLAGS="${SAVE_LDFLAGS} -R /"
 454    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 455    LDFLAGS="${SAVE_LDFLAGS}"
 456 ])
 457 if test "$git_cv_ld_dashr" = "yes"; then
 458    CC_LD_DYNPATH=-R
 459 else
 460    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 461       SAVE_LDFLAGS="${LDFLAGS}"
 462       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 463       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 464       LDFLAGS="${SAVE_LDFLAGS}"
 465    ])
 466    if test "$git_cv_ld_wl_rpath" = "yes"; then
 467       CC_LD_DYNPATH=-Wl,-rpath,
 468    else
 469       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 470          SAVE_LDFLAGS="${LDFLAGS}"
 471          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 472          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 473          LDFLAGS="${SAVE_LDFLAGS}"
 474       ])
 475       if test "$git_cv_ld_rpath" = "yes"; then
 476          CC_LD_DYNPATH=-rpath
 477       else
 478          AC_CACHE_CHECK([if linker supports -Wl,+b,], git_cv_ld_wl_b, [
 479             SAVE_LDFLAGS="${LDFLAGS}"
 480             LDFLAGS="${SAVE_LDFLAGS} -Wl,+b,/"
 481             AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_b=yes], [git_cv_ld_wl_b=no])
 482             LDFLAGS="${SAVE_LDFLAGS}"
 483          ])
 484          if test "$git_cv_ld_wl_b" = "yes"; then
 485             CC_LD_DYNPATH=-Wl,+b,
 486           else
 487              CC_LD_DYNPATH=
 488              AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 489           fi
 490       fi
 491    fi
 492 fi
 493 GIT_CONF_SUBST([CC_LD_DYNPATH])
 494 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 495 AC_CHECK_TOOLS(AR, [gar ar], :)
 496 AC_CHECK_PROGS(TAR, [gtar tar])
 497 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 498 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 499 # or will be empty otherwise.
 500 if test -n "$NO_TCLTK"; then
 501   TCLTK_PATH=
 502 else
 503   if test "$with_tcltk" = ""; then
 504   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 505     TCLTK_PATH=wish
 506   elif test "$with_tcltk" = "yes"; then
 507   # Tcl/Tk check requested.
 508     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 509   else
 510     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 511     TCLTK_PATH="$with_tcltk"
 512   fi
 513 fi
 514 GIT_CONF_SUBST([TCLTK_PATH])
 515 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 516 if test -n "$ASCIIDOC"; then
 517         AC_MSG_CHECKING([for asciidoc version])
 518         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 519         case "${asciidoc_version}" in
 520         asciidoc' '8*)
 521                 AC_MSG_RESULT([${asciidoc_version}])
 522                 ;;
 523         *)
 524                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 525                 ;;
 526         esac
 527 fi
 528
 529 if grep -a ascii configure.ac >/dev/null; then
 530   AC_MSG_RESULT([Using 'grep -a' for sane_grep])
 531   SANE_TEXT_GREP=-a
 532 else
 533   SANE_TEXT_GREP=
 534 fi
 535 GIT_CONF_SUBST([SANE_TEXT_GREP])
 536
 537 ## Checks for libraries.
 538 AC_MSG_NOTICE([CHECKS for libraries])
 539 #
 540 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 541 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 542
 543 GIT_STASH_FLAGS($OPENSSLDIR)
 544
 545 AC_CHECK_LIB([crypto], [SHA1_Init],
 546 [NEEDS_SSL_WITH_CRYPTO=],
 547 [AC_CHECK_LIB([ssl], [SHA1_Init],
 548  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 549  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 550
 551 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 552
 553 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 554 GIT_CONF_SUBST([NO_OPENSSL])
 555
 556 #
 557 # Handle the USE_LIBPCRE1 and USE_LIBPCRE2 options potentially set
 558 # above.
 559 #
 560
 561 if test -n "$USE_LIBPCRE1"; then
 562
 563 GIT_STASH_FLAGS($LIBPCREDIR)
 564
 565 AC_CHECK_LIB([pcre], [pcre_version],
 566 [USE_LIBPCRE1=YesPlease],
 567 [USE_LIBPCRE1=])
 568
 569 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 570
 571 GIT_CONF_SUBST([USE_LIBPCRE1])
 572
 573 fi
 574
 575
 576 if test -n "$USE_LIBPCRE2"; then
 577
 578 GIT_STASH_FLAGS($LIBPCREDIR)
 579
 580 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
 581 [USE_LIBPCRE2=YesPlease],
 582 [USE_LIBPCRE2=])
 583
 584 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 585
 586 GIT_CONF_SUBST([USE_LIBPCRE2])
 587
 588 fi
 589
 590 #
 591 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 592 # git-http-push are not built, and you cannot use http:// and https://
 593 # transports.
 594
 595 GIT_STASH_FLAGS($CURLDIR)
 596
 597 AC_CHECK_LIB([curl], [curl_global_init],
 598 [NO_CURL=],
 599 [NO_CURL=YesPlease])
 600
 601 GIT_UNSTASH_FLAGS($CURLDIR)
 602
 603 GIT_CONF_SUBST([NO_CURL])
 604
 605 if test -z "$NO_CURL"; then
 606
 607 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 608 [curl-config],
 609 [no])
 610
 611 if test $CURL_CONFIG != no; then
 612     GIT_CONF_SUBST([CURL_CONFIG])
 613
 614     if test -z "$CURL_CONFIG_OPTS"; then
 615         CURL_CONFIG_OPTS="--libs"
 616     fi
 617
 618     CURL_LDFLAGS=$($CURL_CONFIG $CURL_CONFIG_OPTS)
 619     AC_MSG_NOTICE([Setting CURL_LDFLAGS to '$CURL_LDFLAGS'])
 620     GIT_CONF_SUBST([CURL_LDFLAGS], [$CURL_LDFLAGS])
 621 fi
 622
 623 fi
 624
 625
 626 #
 627 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 628 # not built, and you cannot push using http:// and https:// transports.
 629
 630 GIT_STASH_FLAGS($EXPATDIR)
 631
 632 AC_CHECK_LIB([expat], [XML_ParserCreate],
 633 [NO_EXPAT=],
 634 [NO_EXPAT=YesPlease])
 635
 636 GIT_UNSTASH_FLAGS($EXPATDIR)
 637
 638 GIT_CONF_SUBST([NO_EXPAT])
 639
 640 #
 641 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 642 # some Solaris installations).
 643 # Define NO_ICONV if neither libc nor libiconv support iconv.
 644
 645 if test -z "$NO_ICONV"; then
 646
 647 GIT_STASH_FLAGS($ICONVDIR)
 648
 649 AC_DEFUN([ICONVTEST_SRC],
 650 [AC_LANG_PROGRAM([#include <iconv.h>],
 651  [iconv_open("", "");])])
 652
 653 if test -n "$ICONVDIR"; then
 654    lib_order="-liconv -lc"
 655 else
 656    lib_order="-lc -liconv"
 657 fi
 658
 659 NO_ICONV=YesPlease
 660
 661 for l in $lib_order; do
 662     if test "$l" = "-liconv"; then
 663        NEEDS_LIBICONV=YesPlease
 664     else
 665        NEEDS_LIBICONV=
 666     fi
 667
 668     old_LIBS="$LIBS"
 669     LIBS="$LIBS $l"
 670     AC_MSG_CHECKING([for iconv in $l])
 671     AC_LINK_IFELSE([ICONVTEST_SRC],
 672         [AC_MSG_RESULT([yes])
 673         NO_ICONV=
 674         break],
 675         [AC_MSG_RESULT([no])])
 676     LIBS="$old_LIBS"
 677 done
 678
 679 #in case of break
 680 LIBS="$old_LIBS"
 681
 682 GIT_UNSTASH_FLAGS($ICONVDIR)
 683
 684 GIT_CONF_SUBST([NEEDS_LIBICONV])
 685 GIT_CONF_SUBST([NO_ICONV])
 686
 687 if test -n "$NO_ICONV"; then
 688     NEEDS_LIBICONV=
 689 fi
 690
 691 fi
 692
 693 #
 694 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 695
 696 GIT_STASH_FLAGS($ZLIB_PATH)
 697
 698 AC_DEFUN([ZLIBTEST_SRC], [
 699 AC_LANG_PROGRAM([#include <zlib.h>],
 700  [deflateBound(0, 0);])])
 701 AC_MSG_CHECKING([for deflateBound in -lz])
 702 old_LIBS="$LIBS"
 703 LIBS="$LIBS -lz"
 704 AC_LINK_IFELSE([ZLIBTEST_SRC],
 705         [AC_MSG_RESULT([yes])],
 706         [AC_MSG_RESULT([no])
 707         NO_DEFLATE_BOUND=yes])
 708 LIBS="$old_LIBS"
 709
 710 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 711
 712 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 713
 714 #
 715 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 716 # Patrick Mauritz).
 717 AC_CHECK_LIB([c], [socket],
 718 [NEEDS_SOCKET=],
 719 [NEEDS_SOCKET=YesPlease])
 720 GIT_CONF_SUBST([NEEDS_SOCKET])
 721 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 722
 723 #
 724 # The next few tests will define NEEDS_RESOLV if linking with
 725 # libresolv provides some of the functions we would normally get
 726 # from libc.
 727 NEEDS_RESOLV=
 728 #
 729 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 730 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 731 NO_INET_NTOP=
 732 AC_CHECK_FUNC([inet_ntop],
 733     [],
 734     [AC_CHECK_LIB([resolv], [inet_ntop],
 735         [NEEDS_RESOLV=YesPlease],
 736         [NO_INET_NTOP=YesPlease])
 737 ])
 738 GIT_CONF_SUBST([NO_INET_NTOP])
 739 #
 740 # Define NO_INET_PTON if linking with -lresolv is not enough.
 741 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 742 NO_INET_PTON=
 743 AC_CHECK_FUNC([inet_pton],
 744     [],
 745     [AC_CHECK_LIB([resolv], [inet_pton],
 746         [NEEDS_RESOLV=YesPlease],
 747         [NO_INET_PTON=YesPlease])
 748 ])
 749 GIT_CONF_SUBST([NO_INET_PTON])
 750 #
 751 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 752 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 753 NO_HSTRERROR=
 754 AC_CHECK_FUNC([hstrerror],
 755     [],
 756     [AC_CHECK_LIB([resolv], [hstrerror],
 757         [NEEDS_RESOLV=YesPlease],
 758         [NO_HSTRERROR=YesPlease])
 759 ])
 760 GIT_CONF_SUBST([NO_HSTRERROR])
 761
 762 dnl This must go after all the possible places for its initialization,
 763 dnl in the AC_CHECK_FUNC invocations above.
 764 GIT_CONF_SUBST([NEEDS_RESOLV])
 765 #
 766 # If any of the above tests determined that -lresolv is needed at
 767 # build-time, also set it here for remaining configure-time checks.
 768 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 769
 770 AC_CHECK_LIB([c], [basename],
 771 [NEEDS_LIBGEN=],
 772 [NEEDS_LIBGEN=YesPlease])
 773 GIT_CONF_SUBST([NEEDS_LIBGEN])
 774 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 775
 776 AC_DEFUN([LIBINTL_SRC], [
 777 AC_LANG_PROGRAM([[
 778 #include <libintl.h>
 779 ]],[[
 780 char *msg = gettext("test");
 781 ]])])
 782
 783 AC_MSG_CHECKING([if libc contains libintl])
 784 AC_LINK_IFELSE([LIBINTL_SRC],
 785         [AC_MSG_RESULT([yes])
 786         LIBC_CONTAINS_LIBINTL=YesPlease],
 787         [AC_MSG_RESULT([no])
 788         LIBC_CONTAINS_LIBINTL=])
 789 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 790
 791 #
 792 # Define NO_GETTEXT if you don't want Git output to be translated.
 793 # A translated Git requires GNU libintl or another gettext implementation
 794 AC_CHECK_HEADER([libintl.h],
 795 [NO_GETTEXT=],
 796 [NO_GETTEXT=YesPlease])
 797 GIT_CONF_SUBST([NO_GETTEXT])
 798
 799 if test -z "$NO_GETTEXT"; then
 800     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 801 fi
 802
 803 ## Checks for header files.
 804 AC_MSG_NOTICE([CHECKS for header files])
 805 #
 806 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 807 AC_CHECK_HEADER([sys/select.h],
 808 [NO_SYS_SELECT_H=],
 809 [NO_SYS_SELECT_H=UnfortunatelyYes])
 810 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 811 #
 812 # Define NO_POLL_H if you don't have poll.h
 813 AC_CHECK_HEADER([poll.h],
 814 [NO_POLL_H=],
 815 [NO_POLL_H=UnfortunatelyYes])
 816 GIT_CONF_SUBST([NO_POLL_H])
 817 #
 818 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 819 AC_CHECK_HEADER([sys/poll.h],
 820 [NO_SYS_POLL_H=],
 821 [NO_SYS_POLL_H=UnfortunatelyYes])
 822 GIT_CONF_SUBST([NO_SYS_POLL_H])
 823 #
 824 # Define NO_INTTYPES_H if you don't have inttypes.h
 825 AC_CHECK_HEADER([inttypes.h],
 826 [NO_INTTYPES_H=],
 827 [NO_INTTYPES_H=UnfortunatelyYes])
 828 GIT_CONF_SUBST([NO_INTTYPES_H])
 829 #
 830 # Define OLD_ICONV if your library has an old iconv(), where the second
 831 # (input buffer pointer) parameter is declared with type (const char **).
 832 AC_DEFUN([OLDICONVTEST_SRC], [
 833 AC_LANG_PROGRAM([[
 834 #include <iconv.h>
 835
 836 extern size_t iconv(iconv_t cd,
 837                     char **inbuf, size_t *inbytesleft,
 838                     char **outbuf, size_t *outbytesleft);
 839 ]], [])])
 840
 841 GIT_STASH_FLAGS($ICONVDIR)
 842
 843 AC_MSG_CHECKING([for old iconv()])
 844 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 845         [AC_MSG_RESULT([no])],
 846         [AC_MSG_RESULT([yes])
 847         AC_DEFINE(HAVE_OLD_ICONV, 1)
 848         OLD_ICONV=UnfortunatelyYes])
 849
 850 GIT_UNSTASH_FLAGS($ICONVDIR)
 851
 852 GIT_CONF_SUBST([OLD_ICONV])
 853
 854 #
 855 # Define ICONV_OMITS_BOM if you are on a system which
 856 # iconv omits bom for utf-{16,32}
 857 if test -z "$NO_ICONV"; then
 858 AC_CACHE_CHECK([whether iconv omits bom for utf-16 and utf-32],
 859  [ac_cv_iconv_omits_bom],
 860 [
 861 old_LIBS="$LIBS"
 862 if test -n "$NEEDS_LIBICONV"; then
 863         LIBS="$LIBS -liconv"
 864 fi
 865
 866 AC_RUN_IFELSE(
 867         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 868         #include <iconv.h>
 869         #ifdef HAVE_OLD_ICONV
 870         typedef const char *iconv_ibp;
 871         #else
 872         typedef char *iconv_ibp;
 873         #endif
 874         ],
 875         [[
 876         int v;
 877         iconv_t conv;
 878         char in[] = "a"; iconv_ibp pin = in;
 879         char out[20] = ""; char *pout = out;
 880         size_t isz = sizeof in;
 881         size_t osz = sizeof out;
 882
 883         conv = iconv_open("UTF-16", "UTF-8");
 884         iconv(conv, &pin, &isz, &pout, &osz);
 885         iconv_close(conv);
 886         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 887         return v != 0xfe + 0xff;
 888         ]])],
 889         [ac_cv_iconv_omits_bom=no],
 890         [ac_cv_iconv_omits_bom=yes])
 891
 892 LIBS="$old_LIBS"
 893 ])
 894 if test "x$ac_cv_iconv_omits_bom" = xyes; then
 895         ICONV_OMITS_BOM=Yes
 896 else
 897         ICONV_OMITS_BOM=
 898 fi
 899 GIT_CONF_SUBST([ICONV_OMITS_BOM])
 900 fi
 901
 902 ## Checks for typedefs, structures, and compiler characteristics.
 903 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 904 #
 905 TYPE_SOCKLEN_T
 906 case $ac_cv_type_socklen_t in
 907   yes)  SOCKLEN_T='';;
 908   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 909 esac
 910 GIT_CONF_SUBST([SOCKLEN_T])
 911
 912 #
 913 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 914 AC_CHECK_TYPES([struct itimerval],
 915 [NO_STRUCT_ITIMERVAL=],
 916 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 917 [#include <sys/time.h>])
 918 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 919 #
 920 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 921 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 922 # stat.st_mtimespec.tv_nsec exists.
 923 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 924 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 925 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 926         USE_ST_TIMESPEC=YesPlease
 927         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 928 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 929         NO_NSEC=YesPlease
 930         GIT_CONF_SUBST([NO_NSEC])
 931 fi
 932 #
 933 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 934 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 935 AC_CHECK_MEMBER(struct dirent.d_type,
 936 [NO_D_TYPE_IN_DIRENT=],
 937 [NO_D_TYPE_IN_DIRENT=YesPlease],
 938 [#include <dirent.h>])
 939 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 940 #
 941 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 942 # in the C library.
 943 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 944 [NO_GECOS_IN_PWENT=],
 945 [NO_GECOS_IN_PWENT=YesPlease],
 946 [#include <pwd.h>])
 947 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 948 #
 949 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 950 # sockaddr_storage.
 951 AC_CHECK_TYPE(struct sockaddr_storage,
 952 [NO_SOCKADDR_STORAGE=],
 953 [NO_SOCKADDR_STORAGE=YesPlease],[
 954 #include <sys/types.h>
 955 #include <sys/socket.h>
 956 ])
 957 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 958 #
 959 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 960 AC_CHECK_TYPE([struct addrinfo],[
 961  GIT_CHECK_FUNC([getaddrinfo],
 962   [NO_IPV6=],
 963   [NO_IPV6=YesPlease])
 964 ],[NO_IPV6=YesPlease],[
 965 #include <sys/types.h>
 966 #include <sys/socket.h>
 967 #include <netdb.h>
 968 ])
 969 GIT_CONF_SUBST([NO_IPV6])
 970 #
 971 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
 972 # feature.
 973 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
 974  [ac_cv_c_regex_with_reg_startend], [
 975 AC_EGREP_CPP(yippeeyeswehaveit,
 976         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 977 #include <regex.h>
 978 ],
 979 [#ifdef REG_STARTEND
 980 yippeeyeswehaveit
 981 #endif
 982 ]),
 983         [ac_cv_c_regex_with_reg_startend=yes],
 984         [ac_cv_c_regex_with_reg_startend=no])
 985 ])
 986 if test $ac_cv_c_regex_with_reg_startend = yes; then
 987         NO_REGEX=
 988 else
 989         NO_REGEX=YesPlease
 990 fi
 991 GIT_CONF_SUBST([NO_REGEX])
 992 #
 993 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 994 # when attempting to read from an fopen'ed directory.
 995 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 996  [ac_cv_fread_reads_directories],
 997 [
 998 AC_RUN_IFELSE(
 999         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1000                 [[
1001                 FILE *f = fopen(".", "r");
1002                 return f != NULL;]])],
1003         [ac_cv_fread_reads_directories=no],
1004         [ac_cv_fread_reads_directories=yes])
1005 ])
1006 if test $ac_cv_fread_reads_directories = yes; then
1007         FREAD_READS_DIRECTORIES=UnfortunatelyYes
1008 else
1009         FREAD_READS_DIRECTORIES=
1010 fi
1011 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
1012 #
1013 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
1014 # or vsnprintf() return -1 instead of number of characters which would
1015 # have been written to the final string if enough space had been available.
1016 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
1017  [ac_cv_snprintf_returns_bogus],
1018 [
1019 AC_RUN_IFELSE(
1020         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
1021                 #include "stdarg.h"
1022
1023                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
1024                 {
1025                   int ret;
1026                   va_list ap;
1027                   va_start(ap, format);
1028                   ret = vsnprintf(str, maxsize, format, ap);
1029                   va_end(ap);
1030                   return ret;
1031                 }],
1032                 [[char buf[6];
1033                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
1034                       || strcmp(buf, "12")) return 1;
1035                   if (snprintf(buf, 3, "%s", "12345") != 5
1036                       || strcmp(buf, "12")) return 1]])],
1037         [ac_cv_snprintf_returns_bogus=no],
1038         [ac_cv_snprintf_returns_bogus=yes])
1039 ])
1040 if test $ac_cv_snprintf_returns_bogus = yes; then
1041         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
1042 else
1043         SNPRINTF_RETURNS_BOGUS=
1044 fi
1045 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
1046 #
1047 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
1048 # bits in mode values.
1049 AC_CACHE_CHECK([whether the platform uses typical file type bits],
1050  [ac_cv_sane_mode_bits], [
1051 AC_EGREP_CPP(yippeeyeswehaveit,
1052         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1053 [#if S_IFMT == 0170000 && \
1054         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
1055         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
1056         S_IFIFO == 0010000 && S_IFSOCK == 0140000
1057 yippeeyeswehaveit
1058 #endif
1059 ]),
1060         [ac_cv_sane_mode_bits=yes],
1061         [ac_cv_sane_mode_bits=no])
1062 ])
1063 if test $ac_cv_sane_mode_bits = yes; then
1064         NEEDS_MODE_TRANSLATION=
1065 else
1066         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
1067 fi
1068 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
1069
1070
1071 ## Checks for library functions.
1072 ## (in default C library and libraries checked by AC_CHECK_LIB)
1073 AC_MSG_NOTICE([CHECKS for library functions])
1074 #
1075 # Define NO_LIBGEN_H if you don't have libgen.h.
1076 AC_CHECK_HEADER([libgen.h],
1077 [NO_LIBGEN_H=],
1078 [NO_LIBGEN_H=YesPlease])
1079 GIT_CONF_SUBST([NO_LIBGEN_H])
1080 #
1081 # Define HAVE_PATHS_H if you have paths.h.
1082 AC_CHECK_HEADER([paths.h],
1083 [HAVE_PATHS_H=YesPlease],
1084 [HAVE_PATHS_H=])
1085 GIT_CONF_SUBST([HAVE_PATHS_H])
1086 #
1087 # Define HAVE_LIBCHARSET_H if have libcharset.h
1088 AC_CHECK_HEADER([libcharset.h],
1089 [HAVE_LIBCHARSET_H=YesPlease],
1090 [HAVE_LIBCHARSET_H=])
1091 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1092 #
1093 # Define HAVE_STRINGS_H if you have strings.h
1094 AC_CHECK_HEADER([strings.h],
1095 [HAVE_STRINGS_H=YesPlease],
1096 [HAVE_STRINGS_H=])
1097 GIT_CONF_SUBST([HAVE_STRINGS_H])
1098 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1099 # and libcharset does
1100 CHARSET_LIB=
1101 AC_CHECK_LIB([iconv], [locale_charset],
1102        [CHARSET_LIB=-liconv],
1103        [AC_CHECK_LIB([charset], [locale_charset],
1104                      [CHARSET_LIB=-lcharset])])
1105 GIT_CONF_SUBST([CHARSET_LIB])
1106 #
1107 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1108 GIT_CHECK_FUNC(clock_gettime,
1109         [HAVE_CLOCK_GETTIME=YesPlease],
1110         [HAVE_CLOCK_GETTIME=])
1111 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1112
1113 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1114 AC_LANG_PROGRAM([[
1115 #include <time.h>
1116 clockid_t id = CLOCK_MONOTONIC;
1117 ]])])
1118
1119 #
1120 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1121 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1122 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1123         [AC_MSG_RESULT([yes])
1124         HAVE_CLOCK_MONOTONIC=YesPlease],
1125         [AC_MSG_RESULT([no])
1126         HAVE_CLOCK_MONOTONIC=])
1127 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1128 #
1129 # Define NO_SETITIMER if you don't have setitimer.
1130 GIT_CHECK_FUNC(setitimer,
1131 [NO_SETITIMER=],
1132 [NO_SETITIMER=YesPlease])
1133 GIT_CONF_SUBST([NO_SETITIMER])
1134 #
1135 # Define NO_STRCASESTR if you don't have strcasestr.
1136 GIT_CHECK_FUNC(strcasestr,
1137 [NO_STRCASESTR=],
1138 [NO_STRCASESTR=YesPlease])
1139 GIT_CONF_SUBST([NO_STRCASESTR])
1140 #
1141 # Define NO_MEMMEM if you don't have memmem.
1142 GIT_CHECK_FUNC(memmem,
1143 [NO_MEMMEM=],
1144 [NO_MEMMEM=YesPlease])
1145 GIT_CONF_SUBST([NO_MEMMEM])
1146 #
1147 # Define NO_STRLCPY if you don't have strlcpy.
1148 GIT_CHECK_FUNC(strlcpy,
1149 [NO_STRLCPY=],
1150 [NO_STRLCPY=YesPlease])
1151 GIT_CONF_SUBST([NO_STRLCPY])
1152 #
1153 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1154 AC_CHECK_TYPE(uintmax_t,
1155 [NO_UINTMAX_T=],
1156 [NO_UINTMAX_T=YesPlease],[
1157 #include <inttypes.h>
1158 ])
1159 GIT_CONF_SUBST([NO_UINTMAX_T])
1160 #
1161 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1162 GIT_CHECK_FUNC(strtoumax,
1163 [NO_STRTOUMAX=],
1164 [NO_STRTOUMAX=YesPlease])
1165 GIT_CONF_SUBST([NO_STRTOUMAX])
1166 #
1167 # Define NO_SETENV if you don't have setenv in the C library.
1168 GIT_CHECK_FUNC(setenv,
1169 [NO_SETENV=],
1170 [NO_SETENV=YesPlease])
1171 GIT_CONF_SUBST([NO_SETENV])
1172 #
1173 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1174 GIT_CHECK_FUNC(unsetenv,
1175 [NO_UNSETENV=],
1176 [NO_UNSETENV=YesPlease])
1177 GIT_CONF_SUBST([NO_UNSETENV])
1178 #
1179 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1180 GIT_CHECK_FUNC(mkdtemp,
1181 [NO_MKDTEMP=],
1182 [NO_MKDTEMP=YesPlease])
1183 GIT_CONF_SUBST([NO_MKDTEMP])
1184 #
1185 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1186 GIT_CHECK_FUNC(initgroups,
1187 [NO_INITGROUPS=],
1188 [NO_INITGROUPS=YesPlease])
1189 GIT_CONF_SUBST([NO_INITGROUPS])
1190 #
1191 # Define HAVE_GETDELIM if you have getdelim in the C library.
1192 GIT_CHECK_FUNC(getdelim,
1193 [HAVE_GETDELIM=YesPlease],
1194 [HAVE_GETDELIM=])
1195 GIT_CONF_SUBST([HAVE_GETDELIM])
1196 #
1197 #
1198 # Define NO_MMAP if you want to avoid mmap.
1199 #
1200 # Define NO_ICONV if your libc does not properly support iconv.
1201
1202 AC_DEFUN([BSD_SYSCTL_SRC], [
1203 AC_LANG_PROGRAM([[
1204 #include <stddef.h>
1205 #include <sys/types.h>
1206 #include <sys/sysctl.h>
1207 ]],[[
1208 int val, mib[2];
1209 size_t len;
1210 mib[0] = CTL_HW;
1211 mib[1] = 1;
1212 len = sizeof(val);
1213 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1214 ]])])
1215
1216 #
1217 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1218 AC_MSG_CHECKING([for BSD sysctl])
1219 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1220         [AC_MSG_RESULT([yes])
1221         HAVE_BSD_SYSCTL=YesPlease],
1222         [AC_MSG_RESULT([no])
1223         HAVE_BSD_SYSCTL=])
1224 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1225
1226 ## Other checks.
1227 # Define USE_PIC if you need the main git objects to be built with -fPIC
1228 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1229 #
1230 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1231 # Enable it on Windows.  By default, symrefs are still used.
1232 #
1233 # Define NO_PTHREADS if we do not have pthreads.
1234 #
1235 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1236 AC_DEFUN([PTHREADTEST_SRC], [
1237 AC_LANG_PROGRAM([[
1238 #include <pthread.h>
1239 static void *noop(void *ignore) { return ignore; }
1240 ]], [[
1241         pthread_mutex_t test_mutex;
1242         pthread_key_t test_key;
1243         pthread_t th;
1244         int retcode = 0;
1245         void *ret = (void *)0;
1246         retcode |= pthread_key_create(&test_key, (void *)0);
1247         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1248         retcode |= pthread_mutex_lock(&test_mutex);
1249         retcode |= pthread_mutex_unlock(&test_mutex);
1250         retcode |= pthread_create(&th, ret, noop, ret);
1251         retcode |= pthread_join(th, &ret);
1252         return retcode;
1253 ]])])
1254
1255 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1256 dnl   [[#include <pthread.h>]],
1257 dnl   [[pthread_mutex_t test_mutex;]]
1258 dnl )])
1259
1260 NO_PTHREADS=UnfortunatelyYes
1261 PTHREAD_LIBS=
1262
1263 if test -n "$USER_NOPTHREAD"; then
1264    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1265 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1266 # -D_REENTRANT' or some such.
1267 elif test -z "$PTHREAD_CFLAGS"; then
1268   threads_found=no
1269   # Attempt to compile and link some code using pthreads to determine
1270   # required linker flags. The order is somewhat important here: We
1271   # first try it without any extra flags, to catch systems where
1272   # pthreads are part of the C library, then go on testing various other
1273   # flags. We do so to avoid false positives. For example, on Mac OS X
1274   # pthreads are part of the C library; moreover, the compiler allows us
1275   # to add "-mt" to the CFLAGS (although it will do nothing except
1276   # trigger a warning about an unused flag). Hence if we checked for
1277   # "-mt" before "" we would end up picking it. But unfortunately this
1278   # would then trigger compiler warnings on every single file we compile.
1279   for opt in "" -mt -pthread -lpthread; do
1280      old_CFLAGS="$CFLAGS"
1281      old_LIBS="$LIBS"
1282      case "$opt" in
1283         -l*)  LIBS="$opt $LIBS" ;;
1284         *)    CFLAGS="$opt $CFLAGS" ;;
1285      esac
1286
1287      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1288      AC_LINK_IFELSE([PTHREADTEST_SRC],
1289         [AC_MSG_RESULT([yes])
1290                 NO_PTHREADS=
1291                 PTHREAD_LIBS="$opt"
1292                 PTHREAD_CFLAGS="$opt"
1293                 threads_found=yes
1294                 break
1295         ],
1296         [AC_MSG_RESULT([no])])
1297       CFLAGS="$old_CFLAGS"
1298       LIBS="$old_LIBS"
1299   done
1300   if test $threads_found != yes; then
1301     AC_CHECK_LIB([pthread], [pthread_create],
1302         [PTHREAD_LIBS="-lpthread"],
1303         [NO_PTHREADS=UnfortunatelyYes])
1304   fi
1305 else
1306   old_CFLAGS="$CFLAGS"
1307   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1308   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1309   AC_LINK_IFELSE([PTHREADTEST_SRC],
1310         [AC_MSG_RESULT([yes])
1311                 NO_PTHREADS=
1312                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1313         ],
1314         [AC_MSG_RESULT([no])])
1315
1316   CFLAGS="$old_CFLAGS"
1317 fi
1318
1319 CFLAGS="$old_CFLAGS"
1320
1321 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1322 GIT_CONF_SUBST([PTHREAD_LIBS])
1323 GIT_CONF_SUBST([NO_PTHREADS])
1324
1325 ## Output files
1326 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1327 AC_OUTPUT