configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specied by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 # This also implies BLK_SHA1.
 245 #
 246 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 247 # /foo/bar/include and /foo/bar/lib directories.
 248 AC_ARG_WITH(openssl,
 249 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 250 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 251 GIT_PARSE_WITH([openssl]))
 252
 253 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 254 # commands such as log and grep offer runtime options to use
 255 # Perl-compatible regular expressions instead of standard or extended
 256 # POSIX regular expressions.
 257 #
 258 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
 259 # /foo/bar/include and /foo/bar/lib directories.
 260 #
 261 AC_ARG_WITH(libpcre,
 262 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
 263 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 264     if test "$withval" = "no"; then
 265         USE_LIBPCRE=
 266     elif test "$withval" = "yes"; then
 267         USE_LIBPCRE=YesPlease
 268     else
 269         USE_LIBPCRE=YesPlease
 270         LIBPCREDIR=$withval
 271         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 272         dnl USE_LIBPCRE can still be modified below, so don't substitute
 273         dnl it yet.
 274         GIT_CONF_SUBST([LIBPCREDIR])
 275     fi)
 276 #
 277 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 278 AC_FUNC_ALLOCA
 279 case $ac_cv_working_alloca_h in
 280     yes)    HAVE_ALLOCA_H=YesPlease;;
 281     *)      HAVE_ALLOCA_H='';;
 282 esac
 283 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 284 #
 285 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 286 # git-http-push are not built, and you cannot use http:// and https://
 287 # transports.
 288 #
 289 # Define CURLDIR=/foo/bar if your curl header and library files are in
 290 # /foo/bar/include and /foo/bar/lib directories.
 291 AC_ARG_WITH(curl,
 292 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 293 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 294 GIT_PARSE_WITH(curl))
 295 #
 296 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 297 # not built, and you cannot push using http:// and https:// transports.
 298 #
 299 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 300 # /foo/bar/include and /foo/bar/lib directories.
 301 AC_ARG_WITH(expat,
 302 AS_HELP_STRING([--with-expat],
 303 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 304 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 305 GIT_PARSE_WITH(expat))
 306 #
 307 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 308 # installed in /sw, but don't want GIT to link against any libraries
 309 # installed there.  If defined you may specify your own (or Fink's)
 310 # include directories and library directories by defining CFLAGS
 311 # and LDFLAGS appropriately.
 312 #
 313 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 314 # have DarwinPorts installed in /opt/local, but don't want GIT to
 315 # link against any libraries installed there.  If defined you may
 316 # specify your own (or DarwinPort's) include directories and
 317 # library directories by defining CFLAGS and LDFLAGS appropriately.
 318 #
 319 # Define NO_MMAP if you want to avoid mmap.
 320 #
 321 # Define NO_ICONV if your libc does not properly support iconv.
 322 AC_ARG_WITH(iconv,
 323 AS_HELP_STRING([--without-iconv],
 324 [if your architecture doesn't properly support iconv])
 325 AS_HELP_STRING([--with-iconv=PATH],
 326 [PATH is prefix for libiconv library and headers])
 327 AS_HELP_STRING([],
 328 [used only if you need linking with libiconv]),
 329 GIT_PARSE_WITH(iconv))
 330
 331 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 332 #
 333 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 334 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 335 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 336 # randomly break unless your underlying filesystem supports those sub-second
 337 # times (my ext3 doesn't).
 338 #
 339 # Define USE_STDEV below if you want git to care about the underlying device
 340 # change being considered an inode change from the update-index perspective.
 341
 342 #
 343 # Allow user to set ETC_GITCONFIG variable
 344 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 345                         Use VALUE instead of /etc/gitconfig as the
 346                         global git configuration file.
 347                         If VALUE is not fully qualified it will be interpreted
 348                         as a path relative to the computed prefix at runtime.)
 349
 350 #
 351 # Allow user to set ETC_GITATTRIBUTES variable
 352 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 353                         Use VALUE instead of /etc/gitattributes as the
 354                         global git attributes file.
 355                         If VALUE is not fully qualified it will be interpreted
 356                         as a path relative to the computed prefix at runtime.)
 357
 358 #
 359 # Allow user to set the default pager
 360 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 361                         Use VALUE as the fall-back pager instead of 'less'.
 362                         This is used by things like 'git log' when the user
 363                         does not specify a pager to use through alternate
 364                         methods. eg: /usr/bin/pager)
 365 #
 366 # Allow user to set the default editor
 367 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 368                         Use VALUE as the fall-back editor instead of 'vi'.
 369                         This is used by things like 'git commit' when the user
 370                         does not specify a preferred editor through other
 371                         methods. eg: /usr/bin/editor)
 372
 373 #
 374 # Define SHELL_PATH to provide path to shell.
 375 GIT_ARG_SET_PATH(shell)
 376 #
 377 # Define PERL_PATH to provide path to Perl.
 378 GIT_ARG_SET_PATH(perl)
 379 #
 380 # Define PYTHON_PATH to provide path to Python.
 381 GIT_ARG_SET_PATH(python, allow-without)
 382 #
 383 # Define ZLIB_PATH to provide path to zlib.
 384 GIT_ARG_SET_PATH(zlib)
 385 #
 386 # Declare the with-tcltk/without-tcltk options.
 387 AC_ARG_WITH(tcltk,
 388 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 389 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 390 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 391 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 392 GIT_PARSE_WITH(tcltk))
 393 #
 394
 395
 396 ## Checks for programs.
 397 AC_MSG_NOTICE([CHECKS for programs])
 398 #
 399 AC_PROG_CC([cc gcc])
 400 AC_C_INLINE
 401 case $ac_cv_c_inline in
 402   inline | yes | no) INLINE='';;
 403   *)                 INLINE=$ac_cv_c_inline ;;
 404 esac
 405 GIT_CONF_SUBST([INLINE])
 406
 407 # which switch to pass runtime path to dynamic libraries to the linker
 408 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 409    SAVE_LDFLAGS="${LDFLAGS}"
 410    LDFLAGS="${SAVE_LDFLAGS} -R /"
 411    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 412    LDFLAGS="${SAVE_LDFLAGS}"
 413 ])
 414 if test "$git_cv_ld_dashr" = "yes"; then
 415    CC_LD_DYNPATH=-R
 416 else
 417    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 418       SAVE_LDFLAGS="${LDFLAGS}"
 419       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 420       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 421       LDFLAGS="${SAVE_LDFLAGS}"
 422    ])
 423    if test "$git_cv_ld_wl_rpath" = "yes"; then
 424       CC_LD_DYNPATH=-Wl,-rpath,
 425    else
 426       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 427          SAVE_LDFLAGS="${LDFLAGS}"
 428          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 429          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 430          LDFLAGS="${SAVE_LDFLAGS}"
 431       ])
 432       if test "$git_cv_ld_rpath" = "yes"; then
 433          CC_LD_DYNPATH=-rpath
 434       else
 435          CC_LD_DYNPATH=
 436          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 437       fi
 438    fi
 439 fi
 440 GIT_CONF_SUBST([CC_LD_DYNPATH])
 441 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 442 AC_CHECK_TOOLS(AR, [gar ar], :)
 443 AC_CHECK_PROGS(TAR, [gtar tar])
 444 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 445 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 446 # or will be empty otherwise.
 447 if test -n "$NO_TCLTK"; then
 448   TCLTK_PATH=
 449 else
 450   if test "$with_tcltk" = ""; then
 451   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 452     TCLTK_PATH=wish
 453   elif test "$with_tcltk" = "yes"; then
 454   # Tcl/Tk check requested.
 455     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 456   else
 457     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 458     TCLTK_PATH="$with_tcltk"
 459   fi
 460 fi
 461 GIT_CONF_SUBST([TCLTK_PATH])
 462 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 463 if test -n "$ASCIIDOC"; then
 464         AC_MSG_CHECKING([for asciidoc version])
 465         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 466         case "${asciidoc_version}" in
 467         asciidoc' '8*)
 468                 AC_MSG_RESULT([${asciidoc_version}])
 469                 ;;
 470         *)
 471                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 472                 ;;
 473         esac
 474 fi
 475
 476 if grep -a ascii configure.ac >/dev/null; then
 477   AC_MSG_RESULT([Using 'grep -a' for sane_grep])
 478   SANE_TEXT_GREP=-a
 479 else
 480   SANE_TEXT_GREP=
 481 fi
 482 GIT_CONF_SUBST([SANE_TEXT_GREP])
 483
 484 ## Checks for libraries.
 485 AC_MSG_NOTICE([CHECKS for libraries])
 486 #
 487 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 488 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 489
 490 GIT_STASH_FLAGS($OPENSSLDIR)
 491
 492 AC_CHECK_LIB([crypto], [SHA1_Init],
 493 [NEEDS_SSL_WITH_CRYPTO=],
 494 [AC_CHECK_LIB([ssl], [SHA1_Init],
 495  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 496  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 497
 498 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 499
 500 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 501 GIT_CONF_SUBST([NO_OPENSSL])
 502
 503 #
 504 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 505 # commands such as log and grep offer runtime options to use
 506 # Perl-compatible regular expressions instead of standard or extended
 507 # POSIX regular expressions.
 508 #
 509
 510 if test -n "$USE_LIBPCRE"; then
 511
 512 GIT_STASH_FLAGS($LIBPCREDIR)
 513
 514 AC_CHECK_LIB([pcre], [pcre_version],
 515 [USE_LIBPCRE=YesPlease],
 516 [USE_LIBPCRE=])
 517
 518 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 519
 520 GIT_CONF_SUBST([USE_LIBPCRE])
 521
 522 fi
 523
 524 #
 525 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 526 # git-http-push are not built, and you cannot use http:// and https://
 527 # transports.
 528
 529 GIT_STASH_FLAGS($CURLDIR)
 530
 531 AC_CHECK_LIB([curl], [curl_global_init],
 532 [NO_CURL=],
 533 [NO_CURL=YesPlease])
 534
 535 GIT_UNSTASH_FLAGS($CURLDIR)
 536
 537 GIT_CONF_SUBST([NO_CURL])
 538
 539 if test -z "$NO_CURL"; then
 540
 541 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 542 [curl-config],
 543 [no])
 544
 545 if test $CURL_CONFIG != no; then
 546     GIT_CONF_SUBST([CURL_CONFIG])
 547     if test -z "${NO_OPENSSL}"; then
 548       AC_MSG_CHECKING([if Curl supports SSL])
 549       if test $(curl-config --features|grep SSL) = SSL; then
 550          NEEDS_SSL_WITH_CURL=YesPlease
 551          AC_MSG_RESULT([yes])
 552       else
 553          NEEDS_SSL_WITH_CURL=
 554          AC_MSG_RESULT([no])
 555       fi
 556       GIT_CONF_SUBST([NEEDS_SSL_WITH_CURL])
 557     fi
 558 fi
 559
 560 fi
 561
 562
 563 #
 564 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 565 # not built, and you cannot push using http:// and https:// transports.
 566
 567 GIT_STASH_FLAGS($EXPATDIR)
 568
 569 AC_CHECK_LIB([expat], [XML_ParserCreate],
 570 [NO_EXPAT=],
 571 [NO_EXPAT=YesPlease])
 572
 573 GIT_UNSTASH_FLAGS($EXPATDIR)
 574
 575 GIT_CONF_SUBST([NO_EXPAT])
 576
 577 #
 578 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 579 # some Solaris installations).
 580 # Define NO_ICONV if neither libc nor libiconv support iconv.
 581
 582 if test -z "$NO_ICONV"; then
 583
 584 GIT_STASH_FLAGS($ICONVDIR)
 585
 586 AC_DEFUN([ICONVTEST_SRC],
 587 [AC_LANG_PROGRAM([#include <iconv.h>],
 588  [iconv_open("", "");])])
 589
 590 if test -n "$ICONVDIR"; then
 591    lib_order="-liconv -lc"
 592 else
 593    lib_order="-lc -liconv"
 594 fi
 595
 596 NO_ICONV=YesPlease
 597
 598 for l in $lib_order; do
 599     if test "$l" = "-liconv"; then
 600        NEEDS_LIBICONV=YesPlease
 601     else
 602        NEEDS_LIBICONV=
 603     fi
 604
 605     old_LIBS="$LIBS"
 606     LIBS="$LIBS $l"
 607     AC_MSG_CHECKING([for iconv in $l])
 608     AC_LINK_IFELSE([ICONVTEST_SRC],
 609         [AC_MSG_RESULT([yes])
 610         NO_ICONV=
 611         break],
 612         [AC_MSG_RESULT([no])])
 613     LIBS="$old_LIBS"
 614 done
 615
 616 #in case of break
 617 LIBS="$old_LIBS"
 618
 619 GIT_UNSTASH_FLAGS($ICONVDIR)
 620
 621 GIT_CONF_SUBST([NEEDS_LIBICONV])
 622 GIT_CONF_SUBST([NO_ICONV])
 623
 624 if test -n "$NO_ICONV"; then
 625     NEEDS_LIBICONV=
 626 fi
 627
 628 fi
 629
 630 #
 631 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 632
 633 GIT_STASH_FLAGS($ZLIB_PATH)
 634
 635 AC_DEFUN([ZLIBTEST_SRC], [
 636 AC_LANG_PROGRAM([#include <zlib.h>],
 637  [deflateBound(0, 0);])])
 638 AC_MSG_CHECKING([for deflateBound in -lz])
 639 old_LIBS="$LIBS"
 640 LIBS="$LIBS -lz"
 641 AC_LINK_IFELSE([ZLIBTEST_SRC],
 642         [AC_MSG_RESULT([yes])],
 643         [AC_MSG_RESULT([no])
 644         NO_DEFLATE_BOUND=yes])
 645 LIBS="$old_LIBS"
 646
 647 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 648
 649 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 650
 651 #
 652 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 653 # Patrick Mauritz).
 654 AC_CHECK_LIB([c], [socket],
 655 [NEEDS_SOCKET=],
 656 [NEEDS_SOCKET=YesPlease])
 657 GIT_CONF_SUBST([NEEDS_SOCKET])
 658 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 659
 660 #
 661 # The next few tests will define NEEDS_RESOLV if linking with
 662 # libresolv provides some of the functions we would normally get
 663 # from libc.
 664 NEEDS_RESOLV=
 665 #
 666 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 667 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 668 NO_INET_NTOP=
 669 AC_CHECK_FUNC([inet_ntop],
 670     [],
 671     [AC_CHECK_LIB([resolv], [inet_ntop],
 672         [NEEDS_RESOLV=YesPlease],
 673         [NO_INET_NTOP=YesPlease])
 674 ])
 675 GIT_CONF_SUBST([NO_INET_NTOP])
 676 #
 677 # Define NO_INET_PTON if linking with -lresolv is not enough.
 678 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 679 NO_INET_PTON=
 680 AC_CHECK_FUNC([inet_pton],
 681     [],
 682     [AC_CHECK_LIB([resolv], [inet_pton],
 683         [NEEDS_RESOLV=YesPlease],
 684         [NO_INET_PTON=YesPlease])
 685 ])
 686 GIT_CONF_SUBST([NO_INET_PTON])
 687 #
 688 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 689 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 690 NO_HSTRERROR=
 691 AC_CHECK_FUNC([hstrerror],
 692     [],
 693     [AC_CHECK_LIB([resolv], [hstrerror],
 694         [NEEDS_RESOLV=YesPlease],
 695         [NO_HSTRERROR=YesPlease])
 696 ])
 697 GIT_CONF_SUBST([NO_HSTRERROR])
 698
 699 dnl This must go after all the possible places for its initialization,
 700 dnl in the AC_CHECK_FUNC invocations above.
 701 GIT_CONF_SUBST([NEEDS_RESOLV])
 702 #
 703 # If any of the above tests determined that -lresolv is needed at
 704 # build-time, also set it here for remaining configure-time checks.
 705 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 706
 707 AC_CHECK_LIB([c], [basename],
 708 [NEEDS_LIBGEN=],
 709 [NEEDS_LIBGEN=YesPlease])
 710 GIT_CONF_SUBST([NEEDS_LIBGEN])
 711 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 712
 713 AC_CHECK_LIB([c], [gettext],
 714 [LIBC_CONTAINS_LIBINTL=YesPlease],
 715 [LIBC_CONTAINS_LIBINTL=])
 716 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 717
 718 #
 719 # Define NO_GETTEXT if you don't want Git output to be translated.
 720 # A translated Git requires GNU libintl or another gettext implementation
 721 AC_CHECK_HEADER([libintl.h],
 722 [NO_GETTEXT=],
 723 [NO_GETTEXT=YesPlease])
 724 GIT_CONF_SUBST([NO_GETTEXT])
 725
 726 if test -z "$NO_GETTEXT"; then
 727     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 728 fi
 729
 730 ## Checks for header files.
 731 AC_MSG_NOTICE([CHECKS for header files])
 732 #
 733 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 734 AC_CHECK_HEADER([sys/select.h],
 735 [NO_SYS_SELECT_H=],
 736 [NO_SYS_SELECT_H=UnfortunatelyYes])
 737 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 738 #
 739 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 740 AC_CHECK_HEADER([sys/poll.h],
 741 [NO_SYS_POLL_H=],
 742 [NO_SYS_POLL_H=UnfortunatelyYes])
 743 GIT_CONF_SUBST([NO_SYS_POLL_H])
 744 #
 745 # Define NO_INTTYPES_H if you don't have inttypes.h
 746 AC_CHECK_HEADER([inttypes.h],
 747 [NO_INTTYPES_H=],
 748 [NO_INTTYPES_H=UnfortunatelyYes])
 749 GIT_CONF_SUBST([NO_INTTYPES_H])
 750 #
 751 # Define OLD_ICONV if your library has an old iconv(), where the second
 752 # (input buffer pointer) parameter is declared with type (const char **).
 753 AC_DEFUN([OLDICONVTEST_SRC], [
 754 AC_LANG_PROGRAM([[
 755 #include <iconv.h>
 756
 757 extern size_t iconv(iconv_t cd,
 758                     char **inbuf, size_t *inbytesleft,
 759                     char **outbuf, size_t *outbytesleft);
 760 ]], [])])
 761
 762 GIT_STASH_FLAGS($ICONVDIR)
 763
 764 AC_MSG_CHECKING([for old iconv()])
 765 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 766         [AC_MSG_RESULT([no])],
 767         [AC_MSG_RESULT([yes])
 768         OLD_ICONV=UnfortunatelyYes])
 769
 770 GIT_UNSTASH_FLAGS($ICONVDIR)
 771
 772 GIT_CONF_SUBST([OLD_ICONV])
 773
 774 ## Checks for typedefs, structures, and compiler characteristics.
 775 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 776 #
 777 TYPE_SOCKLEN_T
 778 case $ac_cv_type_socklen_t in
 779   yes)  SOCKLEN_T='';;
 780   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 781 esac
 782 GIT_CONF_SUBST([SOCKLEN_T])
 783
 784 #
 785 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 786 AC_CHECK_TYPES([struct itimerval],
 787 [NO_STRUCT_ITIMERVAL=],
 788 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 789 [#include <sys/time.h>])
 790 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 791 #
 792 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 793 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 794 # stat.st_mtimespec.tv_nsec exists.
 795 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 796 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 797 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 798         USE_ST_TIMESPEC=YesPlease
 799         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 800 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 801         NO_NSEC=YesPlease
 802         GIT_CONF_SUBST([NO_NSEC])
 803 fi
 804 #
 805 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 806 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 807 AC_CHECK_MEMBER(struct dirent.d_type,
 808 [NO_D_TYPE_IN_DIRENT=],
 809 [NO_D_TYPE_IN_DIRENT=YesPlease],
 810 [#include <dirent.h>])
 811 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 812 #
 813 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 814 # in the C library.
 815 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 816 [NO_GECOS_IN_PWENT=],
 817 [NO_GECOS_IN_PWENT=YesPlease],
 818 [#include <pwd.h>])
 819 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 820 #
 821 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 822 # sockaddr_storage.
 823 AC_CHECK_TYPE(struct sockaddr_storage,
 824 [NO_SOCKADDR_STORAGE=],
 825 [NO_SOCKADDR_STORAGE=YesPlease],[
 826 #include <sys/types.h>
 827 #include <sys/socket.h>
 828 ])
 829 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 830 #
 831 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 832 AC_CHECK_TYPE([struct addrinfo],[
 833  GIT_CHECK_FUNC([getaddrinfo],
 834   [NO_IPV6=],
 835   [NO_IPV6=YesPlease])
 836 ],[NO_IPV6=YesPlease],[
 837 #include <sys/types.h>
 838 #include <sys/socket.h>
 839 #include <netdb.h>
 840 ])
 841 GIT_CONF_SUBST([NO_IPV6])
 842 #
 843 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
 844 # feature.
 845 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
 846  [ac_cv_c_regex_with_reg_startend], [
 847 AC_EGREP_CPP(yippeeyeswehaveit,
 848         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 849 #include <regex.h>
 850 ],
 851 [#ifdef REG_STARTEND
 852 yippeeyeswehaveit
 853 #endif
 854 ]),
 855         [ac_cv_c_regex_with_reg_startend=yes],
 856         [ac_cv_c_regex_with_reg_startend=no])
 857 ])
 858 if test $ac_cv_c_regex_with_reg_startend = yes; then
 859         NO_REGEX=
 860 else
 861         NO_REGEX=YesPlease
 862 fi
 863 GIT_CONF_SUBST([NO_REGEX])
 864 #
 865 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 866 # when attempting to read from an fopen'ed directory.
 867 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 868  [ac_cv_fread_reads_directories],
 869 [
 870 AC_RUN_IFELSE(
 871         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 872                 [[char c;
 873                 FILE *f = fopen(".", "r");
 874                 return f && fread(&c, 1, 1, f)]])],
 875         [ac_cv_fread_reads_directories=no],
 876         [ac_cv_fread_reads_directories=yes])
 877 ])
 878 if test $ac_cv_fread_reads_directories = yes; then
 879         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 880 else
 881         FREAD_READS_DIRECTORIES=
 882 fi
 883 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
 884 #
 885 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 886 # or vsnprintf() return -1 instead of number of characters which would
 887 # have been written to the final string if enough space had been available.
 888 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 889  [ac_cv_snprintf_returns_bogus],
 890 [
 891 AC_RUN_IFELSE(
 892         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 893                 #include "stdarg.h"
 894
 895                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 896                 {
 897                   int ret;
 898                   va_list ap;
 899                   va_start(ap, format);
 900                   ret = vsnprintf(str, maxsize, format, ap);
 901                   va_end(ap);
 902                   return ret;
 903                 }],
 904                 [[char buf[6];
 905                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 906                       || strcmp(buf, "12")) return 1;
 907                   if (snprintf(buf, 3, "%s", "12345") != 5
 908                       || strcmp(buf, "12")) return 1]])],
 909         [ac_cv_snprintf_returns_bogus=no],
 910         [ac_cv_snprintf_returns_bogus=yes])
 911 ])
 912 if test $ac_cv_snprintf_returns_bogus = yes; then
 913         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 914 else
 915         SNPRINTF_RETURNS_BOGUS=
 916 fi
 917 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
 918 #
 919 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
 920 # bits in mode values.
 921 AC_CACHE_CHECK([whether the platform uses typical file type bits],
 922  [ac_cv_sane_mode_bits], [
 923 AC_EGREP_CPP(yippeeyeswehaveit,
 924         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 925 [#if S_IFMT == 0170000 && \
 926         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
 927         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
 928         S_IFIFO == 0010000 && S_IFSOCK == 0140000
 929 yippeeyeswehaveit
 930 #endif
 931 ]),
 932         [ac_cv_sane_mode_bits=yes],
 933         [ac_cv_sane_mode_bits=no])
 934 ])
 935 if test $ac_cv_sane_mode_bits = yes; then
 936         NEEDS_MODE_TRANSLATION=
 937 else
 938         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
 939 fi
 940 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
 941
 942
 943 ## Checks for library functions.
 944 ## (in default C library and libraries checked by AC_CHECK_LIB)
 945 AC_MSG_NOTICE([CHECKS for library functions])
 946 #
 947 # Define NO_LIBGEN_H if you don't have libgen.h.
 948 AC_CHECK_HEADER([libgen.h],
 949 [NO_LIBGEN_H=],
 950 [NO_LIBGEN_H=YesPlease])
 951 GIT_CONF_SUBST([NO_LIBGEN_H])
 952 #
 953 # Define HAVE_PATHS_H if you have paths.h.
 954 AC_CHECK_HEADER([paths.h],
 955 [HAVE_PATHS_H=YesPlease],
 956 [HAVE_PATHS_H=])
 957 GIT_CONF_SUBST([HAVE_PATHS_H])
 958 #
 959 # Define HAVE_LIBCHARSET_H if have libcharset.h
 960 AC_CHECK_HEADER([libcharset.h],
 961 [HAVE_LIBCHARSET_H=YesPlease],
 962 [HAVE_LIBCHARSET_H=])
 963 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
 964 #
 965 # Define HAVE_STRINGS_H if you have strings.h
 966 AC_CHECK_HEADER([strings.h],
 967 [HAVE_STRINGS_H=YesPlease],
 968 [HAVE_STRINGS_H=])
 969 GIT_CONF_SUBST([HAVE_STRINGS_H])
 970 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
 971 # and libcharset does
 972 CHARSET_LIB=
 973 AC_CHECK_LIB([iconv], [locale_charset],
 974        [CHARSET_LIB=-liconv],
 975        [AC_CHECK_LIB([charset], [locale_charset],
 976                      [CHARSET_LIB=-lcharset])])
 977 GIT_CONF_SUBST([CHARSET_LIB])
 978 #
 979 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
 980 GIT_CHECK_FUNC(clock_gettime,
 981         [HAVE_CLOCK_GETTIME=YesPlease],
 982         [HAVE_CLOCK_GETTIME=])
 983 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
 984
 985 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
 986 AC_LANG_PROGRAM([[
 987 #include <time.h>
 988 clockid_t id = CLOCK_MONOTONIC;
 989 ]])])
 990
 991 #
 992 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
 993 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 994 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
 995         [AC_MSG_RESULT([yes])
 996         HAVE_CLOCK_MONOTONIC=YesPlease],
 997         [AC_MSG_RESULT([no])
 998         HAVE_CLOCK_MONOTONIC=])
 999 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1000 #
1001 # Define NO_SETITIMER if you don't have setitimer.
1002 GIT_CHECK_FUNC(setitimer,
1003 [NO_SETITIMER=],
1004 [NO_SETITIMER=YesPlease])
1005 GIT_CONF_SUBST([NO_SETITIMER])
1006 #
1007 # Define NO_STRCASESTR if you don't have strcasestr.
1008 GIT_CHECK_FUNC(strcasestr,
1009 [NO_STRCASESTR=],
1010 [NO_STRCASESTR=YesPlease])
1011 GIT_CONF_SUBST([NO_STRCASESTR])
1012 #
1013 # Define NO_MEMMEM if you don't have memmem.
1014 GIT_CHECK_FUNC(memmem,
1015 [NO_MEMMEM=],
1016 [NO_MEMMEM=YesPlease])
1017 GIT_CONF_SUBST([NO_MEMMEM])
1018 #
1019 # Define NO_STRLCPY if you don't have strlcpy.
1020 GIT_CHECK_FUNC(strlcpy,
1021 [NO_STRLCPY=],
1022 [NO_STRLCPY=YesPlease])
1023 GIT_CONF_SUBST([NO_STRLCPY])
1024 #
1025 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1026 AC_CHECK_TYPE(uintmax_t,
1027 [NO_UINTMAX_T=],
1028 [NO_UINTMAX_T=YesPlease],[
1029 #include <inttypes.h>
1030 ])
1031 GIT_CONF_SUBST([NO_UINTMAX_T])
1032 #
1033 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1034 GIT_CHECK_FUNC(strtoumax,
1035 [NO_STRTOUMAX=],
1036 [NO_STRTOUMAX=YesPlease])
1037 GIT_CONF_SUBST([NO_STRTOUMAX])
1038 #
1039 # Define NO_SETENV if you don't have setenv in the C library.
1040 GIT_CHECK_FUNC(setenv,
1041 [NO_SETENV=],
1042 [NO_SETENV=YesPlease])
1043 GIT_CONF_SUBST([NO_SETENV])
1044 #
1045 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1046 GIT_CHECK_FUNC(unsetenv,
1047 [NO_UNSETENV=],
1048 [NO_UNSETENV=YesPlease])
1049 GIT_CONF_SUBST([NO_UNSETENV])
1050 #
1051 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1052 GIT_CHECK_FUNC(mkdtemp,
1053 [NO_MKDTEMP=],
1054 [NO_MKDTEMP=YesPlease])
1055 GIT_CONF_SUBST([NO_MKDTEMP])
1056 #
1057 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1058 GIT_CHECK_FUNC(initgroups,
1059 [NO_INITGROUPS=],
1060 [NO_INITGROUPS=YesPlease])
1061 GIT_CONF_SUBST([NO_INITGROUPS])
1062 #
1063 # Define HAVE_GETDELIM if you have getdelim in the C library.
1064 GIT_CHECK_FUNC(getdelim,
1065 [HAVE_GETDELIM=YesPlease],
1066 [HAVE_GETDELIM=])
1067 GIT_CONF_SUBST([HAVE_GETDELIM])
1068 #
1069 #
1070 # Define NO_MMAP if you want to avoid mmap.
1071 #
1072 # Define NO_ICONV if your libc does not properly support iconv.
1073
1074 AC_DEFUN([BSD_SYSCTL_SRC], [
1075 AC_LANG_PROGRAM([[
1076 #include <stddef.h>
1077 #include <sys/types.h>
1078 #include <sys/sysctl.h>
1079 ]],[[
1080 int val, mib[2];
1081 size_t len;
1082 mib[0] = CTL_HW;
1083 mib[1] = 1;
1084 len = sizeof(val);
1085 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1086 ]])])
1087
1088 #
1089 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1090 AC_MSG_CHECKING([for BSD sysctl])
1091 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1092         [AC_MSG_RESULT([yes])
1093         HAVE_BSD_SYSCTL=YesPlease],
1094         [AC_MSG_RESULT([no])
1095         HAVE_BSD_SYSCTL=])
1096 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1097
1098 ## Other checks.
1099 # Define USE_PIC if you need the main git objects to be built with -fPIC
1100 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1101 #
1102 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1103 # Enable it on Windows.  By default, symrefs are still used.
1104 #
1105 # Define NO_PTHREADS if we do not have pthreads.
1106 #
1107 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1108 AC_DEFUN([PTHREADTEST_SRC], [
1109 AC_LANG_PROGRAM([[
1110 #include <pthread.h>
1111 static void *noop(void *ignore) { return ignore; }
1112 ]], [[
1113         pthread_mutex_t test_mutex;
1114         pthread_key_t test_key;
1115         pthread_t th;
1116         int retcode = 0;
1117         void *ret = (void *)0;
1118         retcode |= pthread_key_create(&test_key, (void *)0);
1119         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1120         retcode |= pthread_mutex_lock(&test_mutex);
1121         retcode |= pthread_mutex_unlock(&test_mutex);
1122         retcode |= pthread_create(&th, ret, noop, ret);
1123         retcode |= pthread_join(th, &ret);
1124         return retcode;
1125 ]])])
1126
1127 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1128 dnl   [[#include <pthread.h>]],
1129 dnl   [[pthread_mutex_t test_mutex;]]
1130 dnl )])
1131
1132 NO_PTHREADS=UnfortunatelyYes
1133 PTHREAD_LIBS=
1134
1135 if test -n "$USER_NOPTHREAD"; then
1136    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1137 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1138 # -D_REENTRANT' or some such.
1139 elif test -z "$PTHREAD_CFLAGS"; then
1140   threads_found=no
1141   # Attempt to compile and link some code using pthreads to determine
1142   # required linker flags. The order is somewhat important here: We
1143   # first try it without any extra flags, to catch systems where
1144   # pthreads are part of the C library, then go on testing various other
1145   # flags. We do so to avoid false positives. For example, on Mac OS X
1146   # pthreads are part of the C library; moreover, the compiler allows us
1147   # to add "-mt" to the CFLAGS (although it will do nothing except
1148   # trigger a warning about an unused flag). Hence if we checked for
1149   # "-mt" before "" we would end up picking it. But unfortunately this
1150   # would then trigger compiler warnings on every single file we compile.
1151   for opt in "" -mt -pthread -lpthread; do
1152      old_CFLAGS="$CFLAGS"
1153      old_LIBS="$LIBS"
1154      case "$opt" in
1155         -l*)  LIBS="$opt $LIBS" ;;
1156         *)    CFLAGS="$opt $CFLAGS" ;;
1157      esac
1158
1159      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1160      AC_LINK_IFELSE([PTHREADTEST_SRC],
1161         [AC_MSG_RESULT([yes])
1162                 NO_PTHREADS=
1163                 PTHREAD_LIBS="$opt"
1164                 PTHREAD_CFLAGS="$opt"
1165                 threads_found=yes
1166                 break
1167         ],
1168         [AC_MSG_RESULT([no])])
1169       CFLAGS="$old_CFLAGS"
1170       LIBS="$old_LIBS"
1171   done
1172   if test $threads_found != yes; then
1173     AC_CHECK_LIB([pthread], [pthread_create],
1174         [PTHREAD_LIBS="-lpthread"],
1175         [NO_PTHREADS=UnfortunatelyYes])
1176   fi
1177 else
1178   old_CFLAGS="$CFLAGS"
1179   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1180   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1181   AC_LINK_IFELSE([PTHREADTEST_SRC],
1182         [AC_MSG_RESULT([yes])
1183                 NO_PTHREADS=
1184                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1185         ],
1186         [AC_MSG_RESULT([no])])
1187
1188   CFLAGS="$old_CFLAGS"
1189 fi
1190
1191 CFLAGS="$old_CFLAGS"
1192
1193 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1194 GIT_CONF_SUBST([PTHREAD_LIBS])
1195 GIT_CONF_SUBST([NO_PTHREADS])
1196
1197 ## Output files
1198 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1199 AC_OUTPUT