?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git rebase --abort: always restore the right commit
[git/debian.git] / git-svn.perl
blob29f39c0831227a2a7c7b482cdf8277e95cf63245
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
190
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
199
200 # make sure we're always running at the top-level working directory
201 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
221
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
223
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
233
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
238
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
250
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
258
259 print $fd "Available commands:\n" unless $cmd;
260
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
280
281 exit $exit;
282 }
283
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
288
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
311
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
318
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
331
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
345
346 Git::SVN->init($url);
347 }
348
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
365
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
401
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase may be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 $last_rev = $cmt_rev;
457 next if $_no_rebase;
458
459 # we always want to rebase against the current HEAD,
460 # not any head that was passed to us
461 my @diff = command('diff-tree', $d,
462 $gs->refname, '--');
463 my @finish;
464 if (@diff) {
465 @finish = rebase_cmd();
466 print STDERR "W: $d and ", $gs->refname,
467 " differ, using @finish:\n",
468 join("\n", @diff), "\n";
469 } else {
470 print "No changes between current HEAD and ",
471 $gs->refname,
472 "\nResetting to the latest ",
473 $gs->refname, "\n";
474 @finish = qw/reset --mixed/;
475 }
476 command_noisy(@finish, $gs->refname);
477 if (@diff) {
478 @refs = ();
479 my ($url_, $rev_, $uuid_, $gs_) =
480 working_head_info($head, \@refs);
481 my ($linear_refs_, $parents_) =
482 linearize_history($gs_, \@refs);
483 if (scalar(@$linear_refs) !=
484 scalar(@$linear_refs_)) {
485 fatal "# of revisions changed ",
486 "\nbefore:\n",
487 join("\n", @$linear_refs),
488 "\n\nafter:\n",
489 join("\n", @$linear_refs_), "\n",
490 'If you are attempting to commit ',
491 "merges, try running:\n\t",
492 'git rebase --interactive',
493 '--preserve-merges ',
494 $gs->refname,
495 "\nBefore dcommitting";
496 }
497 if ($url_ ne $url) {
498 fatal "URL mismatch after rebase: ",
499 "$url_ != $url";
500 }
501 if ($uuid_ ne $uuid) {
502 fatal "uuid mismatch after rebase: ",
503 "$uuid_ != $uuid";
504 }
505 # remap parents
506 my (%p, @l, $i);
507 for ($i = 0; $i < scalar @$linear_refs; $i++) {
508 my $new = $linear_refs_->[$i] or next;
509 $p{$new} =
510 $parents->{$linear_refs->[$i]};
511 push @l, $new;
512 }
513 $parents = \%p;
514 $linear_refs = \@l;
515 }
516 }
517 }
518 unlink $gs->{index};
519 }
520
521 sub cmd_find_rev {
522 my $revision_or_hash = shift;
523 my $result;
524 if ($revision_or_hash =~ /^r\d+$/) {
525 my $head = shift;
526 $head ||= 'HEAD';
527 my @refs;
528 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
529 unless ($gs) {
530 die "Unable to determine upstream SVN information from ",
531 "$head history\n";
532 }
533 my $desired_revision = substr($revision_or_hash, 1);
534 $result = $gs->rev_map_get($desired_revision);
535 } else {
536 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
537 $result = $rev;
538 }
539 print "$result\n" if $result;
540 }
541
542 sub cmd_rebase {
543 command_noisy(qw/update-index --refresh/);
544 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
545 unless ($gs) {
546 die "Unable to determine upstream SVN information from ",
547 "working tree history\n";
548 }
549 if (command(qw/diff-index HEAD --/)) {
550 print STDERR "Cannot rebase with uncommited changes:\n";
551 command_noisy('status');
552 exit 1;
553 }
554 unless ($_local) {
555 # rebase will checkout for us, so no need to do it explicitly
556 $_no_checkout = 'true';
557 $_fetch_all ? $gs->fetch_all : $gs->fetch;
558 }
559 command_noisy(rebase_cmd(), $gs->refname);
560 }
561
562 sub cmd_show_ignore {
563 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
564 $gs ||= Git::SVN->new;
565 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
566 $gs->prop_walk($gs->{path}, $r, sub {
567 my ($gs, $path, $props) = @_;
568 print STDOUT "\n# $path\n";
569 my $s = $props->{'svn:ignore'} or return;
570 $s =~ s/[\r\n]+/\n/g;
571 chomp $s;
572 $s =~ s#^#$path#gm;
573 print STDOUT "$s\n";
574 });
575 }
576
577 sub cmd_show_externals {
578 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
579 $gs ||= Git::SVN->new;
580 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
581 $gs->prop_walk($gs->{path}, $r, sub {
582 my ($gs, $path, $props) = @_;
583 print STDOUT "\n# $path\n";
584 my $s = $props->{'svn:externals'} or return;
585 $s =~ s/[\r\n]+/\n/g;
586 chomp $s;
587 $s =~ s#^#$path#gm;
588 print STDOUT "$s\n";
589 });
590 }
591
592 sub cmd_create_ignore {
593 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
594 $gs ||= Git::SVN->new;
595 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
596 $gs->prop_walk($gs->{path}, $r, sub {
597 my ($gs, $path, $props) = @_;
598 # $path is of the form /path/to/dir/
599 my $ignore = '.' . $path . '.gitignore';
600 my $s = $props->{'svn:ignore'} or return;
601 open(GITIGNORE, '>', $ignore)
602 or fatal("Failed to open `$ignore' for writing: $!");
603 $s =~ s/[\r\n]+/\n/g;
604 chomp $s;
605 # Prefix all patterns so that the ignore doesn't apply
606 # to sub-directories.
607 $s =~ s#^#/#gm;
608 print GITIGNORE "$s\n";
609 close(GITIGNORE)
610 or fatal("Failed to close `$ignore': $!");
611 command_noisy('add', $ignore);
612 });
613 }
614
615 sub canonicalize_path {
616 my ($path) = @_;
617 my $dot_slash_added = 0;
618 if (substr($path, 0, 1) ne "/") {
619 $path = "./" . $path;
620 $dot_slash_added = 1;
621 }
622 # File::Spec->canonpath doesn't collapse x/../y into y (for a
623 # good reason), so let's do this manually.
624 $path =~ s#/+#/#g;
625 $path =~ s#/\.(?:/|$)#/#g;
626 $path =~ s#/[^/]+/\.\.##g;
627 $path =~ s#/$##g;
628 $path =~ s#^\./## if $dot_slash_added;
629 return $path;
630 }
631
632 # get_svnprops(PATH)
633 # ------------------
634 # Helper for cmd_propget and cmd_proplist below.
635 sub get_svnprops {
636 my $path = shift;
637 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
638 $gs ||= Git::SVN->new;
639
640 # prefix THE PATH by the sub-directory from which the user
641 # invoked us.
642 $path = $cmd_dir_prefix . $path;
643 fatal("No such file or directory: $path") unless -e $path;
644 my $is_dir = -d $path ? 1 : 0;
645 $path = $gs->{path} . '/' . $path;
646
647 # canonicalize the path (otherwise libsvn will abort or fail to
648 # find the file)
649 $path = canonicalize_path($path);
650
651 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
652 my $props;
653 if ($is_dir) {
654 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
655 }
656 else {
657 (undef, $props) = $gs->ra->get_file($path, $r, undef);
658 }
659 return $props;
660 }
661
662 # cmd_propget (PROP, PATH)
663 # ------------------------
664 # Print the SVN property PROP for PATH.
665 sub cmd_propget {
666 my ($prop, $path) = @_;
667 $path = '.' if not defined $path;
668 usage(1) if not defined $prop;
669 my $props = get_svnprops($path);
670 if (not defined $props->{$prop}) {
671 fatal("`$path' does not have a `$prop' SVN property.");
672 }
673 print $props->{$prop} . "\n";
674 }
675
676 # cmd_proplist (PATH)
677 # -------------------
678 # Print the list of SVN properties for PATH.
679 sub cmd_proplist {
680 my $path = shift;
681 $path = '.' if not defined $path;
682 my $props = get_svnprops($path);
683 print "Properties on '$path':\n";
684 foreach (sort keys %{$props}) {
685 print " $_\n";
686 }
687 }
688
689 sub cmd_multi_init {
690 my $url = shift;
691 unless (defined $_trunk || defined $_branches || defined $_tags) {
692 usage(1);
693 }
694
695 # there are currently some bugs that prevent multi-init/multi-fetch
696 # setups from working well without this.
697 $Git::SVN::_minimize_url = 1;
698
699 $_prefix = '' unless defined $_prefix;
700 if (defined $url) {
701 $url =~ s#/+$##;
702 init_subdir(@_);
703 }
704 do_git_init_db();
705 if (defined $_trunk) {
706 my $trunk_ref = $_prefix . 'trunk';
707 # try both old-style and new-style lookups:
708 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
709 unless ($gs_trunk) {
710 my ($trunk_url, $trunk_path) =
711 complete_svn_url($url, $_trunk);
712 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
713 undef, $trunk_ref);
714 }
715 }
716 return unless defined $_branches || defined $_tags;
717 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
718 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
719 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
720 }
721
722 sub cmd_multi_fetch {
723 my $remotes = Git::SVN::read_all_remotes();
724 foreach my $repo_id (sort keys %$remotes) {
725 if ($remotes->{$repo_id}->{url}) {
726 Git::SVN::fetch_all($repo_id, $remotes);
727 }
728 }
729 }
730
731 # this command is special because it requires no metadata
732 sub cmd_commit_diff {
733 my ($ta, $tb, $url) = @_;
734 my $usage = "Usage: $0 commit-diff -r<revision> ".
735 "<tree-ish> <tree-ish> [<URL>]";
736 fatal($usage) if (!defined $ta || !defined $tb);
737 my $svn_path;
738 if (!defined $url) {
739 my $gs = eval { Git::SVN->new };
740 if (!$gs) {
741 fatal("Needed URL or usable git-svn --id in ",
742 "the command-line\n", $usage);
743 }
744 $url = $gs->{url};
745 $svn_path = $gs->{path};
746 }
747 unless (defined $_revision) {
748 fatal("-r|--revision is a required argument\n", $usage);
749 }
750 if (defined $_message && defined $_file) {
751 fatal("Both --message/-m and --file/-F specified ",
752 "for the commit message.\n",
753 "I have no idea what you mean");
754 }
755 if (defined $_file) {
756 $_message = file_to_s($_file);
757 } else {
758 $_message ||= get_commit_entry($tb)->{log};
759 }
760 my $ra ||= Git::SVN::Ra->new($url);
761 $svn_path ||= $ra->{svn_path};
762 my $r = $_revision;
763 if ($r eq 'HEAD') {
764 $r = $ra->get_latest_revnum;
765 } elsif ($r !~ /^\d+$/) {
766 die "revision argument: $r not understood by git-svn\n";
767 }
768 my %ed_opts = ( r => $r,
769 log => $_message,
770 ra => $ra,
771 tree_a => $ta,
772 tree_b => $tb,
773 editor_cb => sub { print "Committed r$_[0]\n" },
774 svn_path => $svn_path );
775 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
776 print "No changes\n$ta == $tb\n";
777 }
778 }
779
780 sub cmd_info {
781 my $path = canonicalize_path(shift or ".");
782 unless (scalar(@_) == 0) {
783 die "Too many arguments specified\n";
784 }
785
786 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
787
788 if (!$file_type && !$diff_status) {
789 print STDERR "$path: (Not a versioned resource)\n\n";
790 return;
791 }
792
793 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
794 unless ($gs) {
795 die "Unable to determine upstream SVN information from ",
796 "working tree history\n";
797 }
798 my $full_url = $url . ($path eq "." ? "" : "/$path");
799
800 if ($_url) {
801 print $full_url, "\n";
802 return;
803 }
804
805 my $result = "Path: $path\n";
806 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
807 $result .= "URL: " . $full_url . "\n";
808
809 eval {
810 my $repos_root = $gs->repos_root;
811 Git::SVN::remove_username($repos_root);
812 $result .= "Repository Root: $repos_root\n";
813 };
814 if ($@) {
815 $result .= "Repository Root: (offline)\n";
816 }
817 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
818 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
819
820 $result .= "Node Kind: " .
821 ($file_type eq "dir" ? "directory" : "file") . "\n";
822
823 my $schedule = $diff_status eq "A"
824 ? "add"
825 : ($diff_status eq "D" ? "delete" : "normal");
826 $result .= "Schedule: $schedule\n";
827
828 if ($diff_status eq "A") {
829 print $result, "\n";
830 return;
831 }
832
833 my ($lc_author, $lc_rev, $lc_date_utc);
834 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
835 my $log = command_output_pipe(@args);
836 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
837 while (<$log>) {
838 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
839 $lc_author = $1;
840 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
841 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
842 (undef, $lc_rev, undef) = ::extract_metadata($1);
843 }
844 }
845 close $log;
846
847 Git::SVN::Log::set_local_timezone();
848
849 $result .= "Last Changed Author: $lc_author\n";
850 $result .= "Last Changed Rev: $lc_rev\n";
851 $result .= "Last Changed Date: " .
852 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
853
854 if ($file_type ne "dir") {
855 my $text_last_updated_date =
856 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
857 $result .=
858 "Text Last Updated: " .
859 Git::SVN::Log::format_svn_date($text_last_updated_date) .
860 "\n";
861 my $checksum;
862 if ($diff_status eq "D") {
863 my ($fh, $ctx) =
864 command_output_pipe(qw(cat-file blob), "HEAD:$path");
865 if ($file_type eq "link") {
866 my $file_name = <$fh>;
867 $checksum = md5sum("link $file_name");
868 } else {
869 $checksum = md5sum($fh);
870 }
871 command_close_pipe($fh, $ctx);
872 } elsif ($file_type eq "link") {
873 my $file_name =
874 command(qw(cat-file blob), "HEAD:$path");
875 $checksum =
876 md5sum("link " . $file_name);
877 } else {
878 open FILE, "<", $path or die $!;
879 $checksum = md5sum(\*FILE);
880 close FILE or die $!;
881 }
882 $result .= "Checksum: " . $checksum . "\n";
883 }
884
885 print $result, "\n";
886 }
887
888 ########################### utility functions #########################
889
890 sub rebase_cmd {
891 my @cmd = qw/rebase/;
892 push @cmd, '-v' if $_verbose;
893 push @cmd, qw/--merge/ if $_merge;
894 push @cmd, "--strategy=$_strategy" if $_strategy;
895 @cmd;
896 }
897
898 sub post_fetch_checkout {
899 return if $_no_checkout;
900 my $gs = $Git::SVN::_head or return;
901 return if verify_ref('refs/heads/master^0');
902
903 my $valid_head = verify_ref('HEAD^0');
904 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
905 return if ($valid_head || !verify_ref('HEAD^0'));
906
907 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
908 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
909 return if -f $index;
910
911 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
912 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
913 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
914 print STDERR "Checked out HEAD:\n ",
915 $gs->full_url, " r", $gs->last_rev, "\n";
916 }
917
918 sub complete_svn_url {
919 my ($url, $path) = @_;
920 $path =~ s#/+$##;
921 if ($path !~ m#^[a-z\+]+://#) {
922 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
923 fatal("E: '$path' is not a complete URL ",
924 "and a separate URL is not specified");
925 }
926 return ($url, $path);
927 }
928 return ($path, '');
929 }
930
931 sub complete_url_ls_init {
932 my ($ra, $repo_path, $switch, $pfx) = @_;
933 unless ($repo_path) {
934 print STDERR "W: $switch not specified\n";
935 return;
936 }
937 $repo_path =~ s#/+$##;
938 if ($repo_path =~ m#^[a-z\+]+://#) {
939 $ra = Git::SVN::Ra->new($repo_path);
940 $repo_path = '';
941 } else {
942 $repo_path =~ s#^/+##;
943 unless ($ra) {
944 fatal("E: '$repo_path' is not a complete URL ",
945 "and a separate URL is not specified");
946 }
947 }
948 my $url = $ra->{url};
949 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
950 my $k = "svn-remote.$gs->{repo_id}.url";
951 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
952 if ($orig_url && ($orig_url ne $gs->{url})) {
953 die "$k already set: $orig_url\n",
954 "wanted to set to: $gs->{url}\n";
955 }
956 command_oneline('config', $k, $gs->{url}) unless $orig_url;
957 my $remote_path = "$ra->{svn_path}/$repo_path/*";
958 $remote_path =~ s#/+#/#g;
959 $remote_path =~ s#^/##g;
960 my ($n) = ($switch =~ /^--(\w+)/);
961 if (length $pfx && $pfx !~ m#/$#) {
962 die "--prefix='$pfx' must have a trailing slash '/'\n";
963 }
964 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
965 "$remote_path:refs/remotes/$pfx*");
966 }
967
968 sub verify_ref {
969 my ($ref) = @_;
970 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
971 { STDERR => 0 }); };
972 }
973
974 sub get_tree_from_treeish {
975 my ($treeish) = @_;
976 # $treeish can be a symbolic ref, too:
977 my $type = command_oneline(qw/cat-file -t/, $treeish);
978 my $expected;
979 while ($type eq 'tag') {
980 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
981 }
982 if ($type eq 'commit') {
983 $expected = (grep /^tree /, command(qw/cat-file commit/,
984 $treeish))[0];
985 ($expected) = ($expected =~ /^tree ($sha1)$/o);
986 die "Unable to get tree from $treeish\n" unless $expected;
987 } elsif ($type eq 'tree') {
988 $expected = $treeish;
989 } else {
990 die "$treeish is a $type, expected tree, tag or commit\n";
991 }
992 return $expected;
993 }
994
995 sub get_commit_entry {
996 my ($treeish) = shift;
997 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
998 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
999 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1000 open my $log_fh, '>', $commit_editmsg or croak $!;
1001
1002 my $type = command_oneline(qw/cat-file -t/, $treeish);
1003 if ($type eq 'commit' || $type eq 'tag') {
1004 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1005 $type, $treeish);
1006 my $in_msg = 0;
1007 while (<$msg_fh>) {
1008 if (!$in_msg) {
1009 $in_msg = 1 if (/^\s*$/);
1010 } elsif (/^git-svn-id: /) {
1011 # skip this for now, we regenerate the
1012 # correct one on re-fetch anyways
1013 # TODO: set *:merge properties or like...
1014 } else {
1015 print $log_fh $_ or croak $!;
1016 }
1017 }
1018 command_close_pipe($msg_fh, $ctx);
1019 }
1020 close $log_fh or croak $!;
1021
1022 if ($_edit || ($type eq 'tree')) {
1023 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1024 # TODO: strip out spaces, comments, like git-commit.sh
1025 system($editor, $commit_editmsg);
1026 }
1027 rename $commit_editmsg, $commit_msg or croak $!;
1028 open $log_fh, '<', $commit_msg or croak $!;
1029 { local $/; chomp($log_entry{log} = <$log_fh>); }
1030 close $log_fh or croak $!;
1031 unlink $commit_msg;
1032 \%log_entry;
1033 }
1034
1035 sub s_to_file {
1036 my ($str, $file, $mode) = @_;
1037 open my $fd,'>',$file or croak $!;
1038 print $fd $str,"\n" or croak $!;
1039 close $fd or croak $!;
1040 chmod ($mode &~ umask, $file) if (defined $mode);
1041 }
1042
1043 sub file_to_s {
1044 my $file = shift;
1045 open my $fd,'<',$file or croak "$!: file: $file\n";
1046 local $/;
1047 my $ret = <$fd>;
1048 close $fd or croak $!;
1049 $ret =~ s/\s*$//s;
1050 return $ret;
1051 }
1052
1053 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1054 sub load_authors {
1055 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1056 my $log = $cmd eq 'log';
1057 while (<$authors>) {
1058 chomp;
1059 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1060 my ($user, $name, $email) = ($1, $2, $3);
1061 if ($log) {
1062 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1063 } else {
1064 $users{$user} = [$name, $email];
1065 }
1066 }
1067 close $authors or croak $!;
1068 }
1069
1070 # convert GetOpt::Long specs for use by git-config
1071 sub read_repo_config {
1072 return unless -d $ENV{GIT_DIR};
1073 my $opts = shift;
1074 my @config_only;
1075 foreach my $o (keys %$opts) {
1076 # if we have mixedCase and a long option-only, then
1077 # it's a config-only variable that we don't need for
1078 # the command-line.
1079 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1080 my $v = $opts->{$o};
1081 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1082 $key =~ s/-//g;
1083 my $arg = 'git-config';
1084 $arg .= ' --int' if ($o =~ /[:=]i$/);
1085 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1086 if (ref $v eq 'ARRAY') {
1087 chomp(my @tmp = `$arg --get-all svn.$key`);
1088 @$v = @tmp if @tmp;
1089 } else {
1090 chomp(my $tmp = `$arg --get svn.$key`);
1091 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1092 $$v = $tmp;
1093 }
1094 }
1095 }
1096 delete @$opts{@config_only} if @config_only;
1097 }
1098
1099 sub extract_metadata {
1100 my $id = shift or return (undef, undef, undef);
1101 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1102 \s([a-f\d\-]+)$/x);
1103 if (!defined $rev || !$uuid || !$url) {
1104 # some of the original repositories I made had
1105 # identifiers like this:
1106 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1107 }
1108 return ($url, $rev, $uuid);
1109 }
1110
1111 sub cmt_metadata {
1112 return extract_metadata((grep(/^git-svn-id: /,
1113 command(qw/cat-file commit/, shift)))[-1]);
1114 }
1115
1116 sub working_head_info {
1117 my ($head, $refs) = @_;
1118 my @args = ('log', '--no-color', '--first-parent');
1119 my ($fh, $ctx) = command_output_pipe(@args, $head);
1120 my $hash;
1121 my %max;
1122 while (<$fh>) {
1123 if ( m{^commit ($::sha1)$} ) {
1124 unshift @$refs, $hash if $hash and $refs;
1125 $hash = $1;
1126 next;
1127 }
1128 next unless s{^\s*(git-svn-id:)}{$1};
1129 my ($url, $rev, $uuid) = extract_metadata($_);
1130 if (defined $url && defined $rev) {
1131 next if $max{$url} and $max{$url} < $rev;
1132 if (my $gs = Git::SVN->find_by_url($url)) {
1133 my $c = $gs->rev_map_get($rev);
1134 if ($c && $c eq $hash) {
1135 close $fh; # break the pipe
1136 return ($url, $rev, $uuid, $gs);
1137 } else {
1138 $max{$url} ||= $gs->rev_map_max;
1139 }
1140 }
1141 }
1142 }
1143 command_close_pipe($fh, $ctx);
1144 (undef, undef, undef, undef);
1145 }
1146
1147 sub read_commit_parents {
1148 my ($parents, $c) = @_;
1149 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1150 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1151 @{$parents->{$c}} = split(/ /, $p);
1152 }
1153
1154 sub linearize_history {
1155 my ($gs, $refs) = @_;
1156 my %parents;
1157 foreach my $c (@$refs) {
1158 read_commit_parents(\%parents, $c);
1159 }
1160
1161 my @linear_refs;
1162 my %skip = ();
1163 my $last_svn_commit = $gs->last_commit;
1164 foreach my $c (reverse @$refs) {
1165 next if $c eq $last_svn_commit;
1166 last if $skip{$c};
1167
1168 unshift @linear_refs, $c;
1169 $skip{$c} = 1;
1170
1171 # we only want the first parent to diff against for linear
1172 # history, we save the rest to inject when we finalize the
1173 # svn commit
1174 my $fp_a = verify_ref("$c~1");
1175 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1176 if (!$fp_a || !$fp_b) {
1177 die "Commit $c\n",
1178 "has no parent commit, and therefore ",
1179 "nothing to diff against.\n",
1180 "You should be working from a repository ",
1181 "originally created by git-svn\n";
1182 }
1183 if ($fp_a ne $fp_b) {
1184 die "$c~1 = $fp_a, however parsing commit $c ",
1185 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1186 }
1187
1188 foreach my $p (@{$parents{$c}}) {
1189 $skip{$p} = 1;
1190 }
1191 }
1192 (\@linear_refs, \%parents);
1193 }
1194
1195 sub find_file_type_and_diff_status {
1196 my ($path) = @_;
1197 return ('dir', '') if $path eq '.';
1198
1199 my $diff_output =
1200 command_oneline(qw(diff --cached --name-status --), $path) || "";
1201 my $diff_status = (split(' ', $diff_output))[0] || "";
1202
1203 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1204
1205 return (undef, undef) if !$diff_status && !$ls_tree;
1206
1207 if ($diff_status eq "A") {
1208 return ("link", $diff_status) if -l $path;
1209 return ("dir", $diff_status) if -d $path;
1210 return ("file", $diff_status);
1211 }
1212
1213 my $mode = (split(' ', $ls_tree))[0] || "";
1214
1215 return ("link", $diff_status) if $mode eq "120000";
1216 return ("dir", $diff_status) if $mode eq "040000";
1217 return ("file", $diff_status);
1218 }
1219
1220 sub md5sum {
1221 my $arg = shift;
1222 my $ref = ref $arg;
1223 my $md5 = Digest::MD5->new();
1224 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1225 $md5->addfile($arg) or croak $!;
1226 } elsif ($ref eq 'SCALAR') {
1227 $md5->add($$arg) or croak $!;
1228 } elsif (!$ref) {
1229 $md5->add($arg) or croak $!;
1230 } else {
1231 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1232 }
1233 return $md5->hexdigest();
1234 }
1235
1236 package Git::SVN;
1237 use strict;
1238 use warnings;
1239 use Fcntl qw/:DEFAULT :seek/;
1240 use constant rev_map_fmt => 'NH40';
1241 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1242 $_repack $_repack_flags $_use_svm_props $_head
1243 $_use_svnsync_props $no_reuse_existing $_minimize_url
1244 $_use_log_author/;
1245 use Carp qw/croak/;
1246 use File::Path qw/mkpath/;
1247 use File::Copy qw/copy/;
1248 use IPC::Open3;
1249
1250 my $_repack_nr;
1251 # properties that we do not log:
1252 my %SKIP_PROP;
1253 BEGIN {
1254 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1255 svn:special svn:executable
1256 svn:entry:committed-rev
1257 svn:entry:last-author
1258 svn:entry:uuid
1259 svn:entry:committed-date/;
1260
1261 # some options are read globally, but can be overridden locally
1262 # per [svn-remote "..."] section. Command-line options will *NOT*
1263 # override options set in an [svn-remote "..."] section
1264 no strict 'refs';
1265 for my $option (qw/follow_parent no_metadata use_svm_props
1266 use_svnsync_props/) {
1267 my $key = $option;
1268 $key =~ tr/_//d;
1269 my $prop = "-$option";
1270 *$option = sub {
1271 my ($self) = @_;
1272 return $self->{$prop} if exists $self->{$prop};
1273 my $k = "svn-remote.$self->{repo_id}.$key";
1274 eval { command_oneline(qw/config --get/, $k) };
1275 if ($@) {
1276 $self->{$prop} = ${"Git::SVN::_$option"};
1277 } else {
1278 my $v = command_oneline(qw/config --bool/,$k);
1279 $self->{$prop} = $v eq 'false' ? 0 : 1;
1280 }
1281 return $self->{$prop};
1282 }
1283 }
1284 }
1285
1286 my (%LOCKFILES, %INDEX_FILES);
1287 END {
1288 unlink keys %LOCKFILES if %LOCKFILES;
1289 unlink keys %INDEX_FILES if %INDEX_FILES;
1290 }
1291
1292 sub resolve_local_globs {
1293 my ($url, $fetch, $glob_spec) = @_;
1294 return unless defined $glob_spec;
1295 my $ref = $glob_spec->{ref};
1296 my $path = $glob_spec->{path};
1297 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1298 next unless m#^refs/remotes/$ref->{regex}$#;
1299 my $p = $1;
1300 my $pathname = desanitize_refname($path->full_path($p));
1301 my $refname = desanitize_refname($ref->full_path($p));
1302 if (my $existing = $fetch->{$pathname}) {
1303 if ($existing ne $refname) {
1304 die "Refspec conflict:\n",
1305 "existing: refs/remotes/$existing\n",
1306 " globbed: refs/remotes/$refname\n";
1307 }
1308 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1309 $u =~ s!^\Q$url\E(/|$)!! or die
1310 "refs/remotes/$refname: '$url' not found in '$u'\n";
1311 if ($pathname ne $u) {
1312 warn "W: Refspec glob conflict ",
1313 "(ref: refs/remotes/$refname):\n",
1314 "expected path: $pathname\n",
1315 " real path: $u\n",
1316 "Continuing ahead with $u\n";
1317 next;
1318 }
1319 } else {
1320 $fetch->{$pathname} = $refname;
1321 }
1322 }
1323 }
1324
1325 sub parse_revision_argument {
1326 my ($base, $head) = @_;
1327 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1328 return ($base, $head);
1329 }
1330 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1331 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1332 return ($head, $head) if ($::_revision eq 'HEAD');
1333 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1334 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1335 die "revision argument: $::_revision not understood by git-svn\n";
1336 }
1337
1338 sub fetch_all {
1339 my ($repo_id, $remotes) = @_;
1340 if (ref $repo_id) {
1341 my $gs = $repo_id;
1342 $repo_id = undef;
1343 $repo_id = $gs->{repo_id};
1344 }
1345 $remotes ||= read_all_remotes();
1346 my $remote = $remotes->{$repo_id} or
1347 die "[svn-remote \"$repo_id\"] unknown\n";
1348 my $fetch = $remote->{fetch};
1349 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1350 my (@gs, @globs);
1351 my $ra = Git::SVN::Ra->new($url);
1352 my $uuid = $ra->get_uuid;
1353 my $head = $ra->get_latest_revnum;
1354 my $base = defined $fetch ? $head : 0;
1355
1356 # read the max revs for wildcard expansion (branches/*, tags/*)
1357 foreach my $t (qw/branches tags/) {
1358 defined $remote->{$t} or next;
1359 push @globs, $remote->{$t};
1360 my $max_rev = eval { tmp_config(qw/--int --get/,
1361 "svn-remote.$repo_id.${t}-maxRev") };
1362 if (defined $max_rev && ($max_rev < $base)) {
1363 $base = $max_rev;
1364 } elsif (!defined $max_rev) {
1365 $base = 0;
1366 }
1367 }
1368
1369 if ($fetch) {
1370 foreach my $p (sort keys %$fetch) {
1371 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1372 my $lr = $gs->rev_map_max;
1373 if (defined $lr) {
1374 $base = $lr if ($lr < $base);
1375 }
1376 push @gs, $gs;
1377 }
1378 }
1379
1380 ($base, $head) = parse_revision_argument($base, $head);
1381 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1382 }
1383
1384 sub read_all_remotes {
1385 my $r = {};
1386 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1387 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1388 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1389 $local_ref =~ s{^/}{};
1390 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1391 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1392 $r->{$1}->{url} = $2;
1393 } elsif (m!^(.+)\.(branches|tags)=
1394 (.*):refs/remotes/(.+)\s*$/!x) {
1395 my ($p, $g) = ($3, $4);
1396 my $rs = $r->{$1}->{$2} = {
1397 t => $2,
1398 remote => $1,
1399 path => Git::SVN::GlobSpec->new($p),
1400 ref => Git::SVN::GlobSpec->new($g) };
1401 if (length($rs->{ref}->{right}) != 0) {
1402 die "The '*' glob character must be the last ",
1403 "character of '$g'\n";
1404 }
1405 }
1406 }
1407 $r;
1408 }
1409
1410 sub init_vars {
1411 $_repack = 1000 unless (defined $_repack && $_repack > 0);
1412 $_repack_nr = $_repack;
1413 $_repack_flags ||= '-d';
1414 }
1415
1416 sub verify_remotes_sanity {
1417 return unless -d $ENV{GIT_DIR};
1418 my %seen;
1419 foreach (command(qw/config -l/)) {
1420 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1421 if ($seen{$1}) {
1422 die "Remote ref refs/remote/$1 is tracked by",
1423 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1424 "Please resolve this ambiguity in ",
1425 "your git configuration file before ",
1426 "continuing\n";
1427 }
1428 $seen{$1} = $_;
1429 }
1430 }
1431 }
1432
1433 # we allow more chars than remotes2config.sh...
1434 sub sanitize_remote_name {
1435 my ($name) = @_;
1436 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1437 $name;
1438 }
1439
1440 sub find_existing_remote {
1441 my ($url, $remotes) = @_;
1442 return undef if $no_reuse_existing;
1443 my $existing;
1444 foreach my $repo_id (keys %$remotes) {
1445 my $u = $remotes->{$repo_id}->{url} or next;
1446 next if $u ne $url;
1447 $existing = $repo_id;
1448 last;
1449 }
1450 $existing;
1451 }
1452
1453 sub init_remote_config {
1454 my ($self, $url, $no_write) = @_;
1455 $url =~ s!/+$!!; # strip trailing slash
1456 my $r = read_all_remotes();
1457 my $existing = find_existing_remote($url, $r);
1458 if ($existing) {
1459 unless ($no_write) {
1460 print STDERR "Using existing ",
1461 "[svn-remote \"$existing\"]\n";
1462 }
1463 $self->{repo_id} = $existing;
1464 } elsif ($_minimize_url) {
1465 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1466 $existing = find_existing_remote($min_url, $r);
1467 if ($existing) {
1468 unless ($no_write) {
1469 print STDERR "Using existing ",
1470 "[svn-remote \"$existing\"]\n";
1471 }
1472 $self->{repo_id} = $existing;
1473 }
1474 if ($min_url ne $url) {
1475 unless ($no_write) {
1476 print STDERR "Using higher level of URL: ",
1477 "$url => $min_url\n";
1478 }
1479 my $old_path = $self->{path};
1480 $self->{path} = $url;
1481 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1482 if (length $old_path) {
1483 $self->{path} .= "/$old_path";
1484 }
1485 $url = $min_url;
1486 }
1487 }
1488 my $orig_url;
1489 if (!$existing) {
1490 # verify that we aren't overwriting anything:
1491 $orig_url = eval {
1492 command_oneline('config', '--get',
1493 "svn-remote.$self->{repo_id}.url")
1494 };
1495 if ($orig_url && ($orig_url ne $url)) {
1496 die "svn-remote.$self->{repo_id}.url already set: ",
1497 "$orig_url\nwanted to set to: $url\n";
1498 }
1499 }
1500 my ($xrepo_id, $xpath) = find_ref($self->refname);
1501 if (defined $xpath) {
1502 die "svn-remote.$xrepo_id.fetch already set to track ",
1503 "$xpath:refs/remotes/", $self->refname, "\n";
1504 }
1505 unless ($no_write) {
1506 command_noisy('config',
1507 "svn-remote.$self->{repo_id}.url", $url);
1508 $self->{path} =~ s{^/}{};
1509 command_noisy('config', '--add',
1510 "svn-remote.$self->{repo_id}.fetch",
1511 "$self->{path}:".$self->refname);
1512 }
1513 $self->{url} = $url;
1514 }
1515
1516 sub find_by_url { # repos_root and, path are optional
1517 my ($class, $full_url, $repos_root, $path) = @_;
1518
1519 return undef unless defined $full_url;
1520 remove_username($full_url);
1521 remove_username($repos_root) if defined $repos_root;
1522 my $remotes = read_all_remotes();
1523 if (defined $full_url && defined $repos_root && !defined $path) {
1524 $path = $full_url;
1525 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1526 }
1527 foreach my $repo_id (keys %$remotes) {
1528 my $u = $remotes->{$repo_id}->{url} or next;
1529 remove_username($u);
1530 next if defined $repos_root && $repos_root ne $u;
1531
1532 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1533 foreach (qw/branches tags/) {
1534 resolve_local_globs($u, $fetch,
1535 $remotes->{$repo_id}->{$_});
1536 }
1537 my $p = $path;
1538 my $rwr = rewrite_root({repo_id => $repo_id});
1539 unless (defined $p) {
1540 $p = $full_url;
1541 my $z = $u;
1542 if ($rwr) {
1543 $z = $rwr;
1544 }
1545 $p =~ s#^\Q$z\E(?:/|$)## or next;
1546 }
1547 foreach my $f (keys %$fetch) {
1548 next if $f ne $p;
1549 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1550 }
1551 }
1552 undef;
1553 }
1554
1555 sub init {
1556 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1557 my $self = _new($class, $repo_id, $ref_id, $path);
1558 if (defined $url) {
1559 $self->init_remote_config($url, $no_write);
1560 }
1561 $self;
1562 }
1563
1564 sub find_ref {
1565 my ($ref_id) = @_;
1566 foreach (command(qw/config -l/)) {
1567 next unless m!^svn-remote\.(.+)\.fetch=
1568 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1569 my ($repo_id, $path, $ref) = ($1, $2, $3);
1570 if ($ref eq $ref_id) {
1571 $path = '' if ($path =~ m#^\./?#);
1572 return ($repo_id, $path);
1573 }
1574 }
1575 (undef, undef, undef);
1576 }
1577
1578 sub new {
1579 my ($class, $ref_id, $repo_id, $path) = @_;
1580 if (defined $ref_id && !defined $repo_id && !defined $path) {
1581 ($repo_id, $path) = find_ref($ref_id);
1582 if (!defined $repo_id) {
1583 die "Could not find a \"svn-remote.*.fetch\" key ",
1584 "in the repository configuration matching: ",
1585 "refs/remotes/$ref_id\n";
1586 }
1587 }
1588 my $self = _new($class, $repo_id, $ref_id, $path);
1589 if (!defined $self->{path} || !length $self->{path}) {
1590 my $fetch = command_oneline('config', '--get',
1591 "svn-remote.$repo_id.fetch",
1592 ":refs/remotes/$ref_id\$") or
1593 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1594 "\":refs/remotes/$ref_id\$\" in config\n";
1595 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1596 }
1597 $self->{url} = command_oneline('config', '--get',
1598 "svn-remote.$repo_id.url") or
1599 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1600 $self->rebuild;
1601 $self;
1602 }
1603
1604 sub refname {
1605 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1606
1607 # It cannot end with a slash /, we'll throw up on this because
1608 # SVN can't have directories with a slash in their name, either:
1609 if ($refname =~ m{/$}) {
1610 die "ref: '$refname' ends with a trailing slash, this is ",
1611 "not permitted by git nor Subversion\n";
1612 }
1613
1614 # It cannot have ASCII control character space, tilde ~, caret ^,
1615 # colon :, question-mark ?, asterisk *, space, or open bracket [
1616 # anywhere.
1617 #
1618 # Additionally, % must be escaped because it is used for escaping
1619 # and we want our escaped refname to be reversible
1620 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1621
1622 # no slash-separated component can begin with a dot .
1623 # /.* becomes /%2E*
1624 $refname =~ s{/\.}{/%2E}g;
1625
1626 # It cannot have two consecutive dots .. anywhere
1627 # .. becomes %2E%2E
1628 $refname =~ s{\.\.}{%2E%2E}g;
1629
1630 return $refname;
1631 }
1632
1633 sub desanitize_refname {
1634 my ($refname) = @_;
1635 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1636 return $refname;
1637 }
1638
1639 sub svm_uuid {
1640 my ($self) = @_;
1641 return $self->{svm}->{uuid} if $self->svm;
1642 $self->ra;
1643 unless ($self->{svm}) {
1644 die "SVM UUID not cached, and reading remotely failed\n";
1645 }
1646 $self->{svm}->{uuid};
1647 }
1648
1649 sub svm {
1650 my ($self) = @_;
1651 return $self->{svm} if $self->{svm};
1652 my $svm;
1653 # see if we have it in our config, first:
1654 eval {
1655 my $section = "svn-remote.$self->{repo_id}";
1656 $svm = {
1657 source => tmp_config('--get', "$section.svm-source"),
1658 uuid => tmp_config('--get', "$section.svm-uuid"),
1659 replace => tmp_config('--get', "$section.svm-replace"),
1660 }
1661 };
1662 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1663 $self->{svm} = $svm;
1664 }
1665 $self->{svm};
1666 }
1667
1668 sub _set_svm_vars {
1669 my ($self, $ra) = @_;
1670 return $ra if $self->svm;
1671
1672 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1673 "(svm:source, svm:uuid) ",
1674 "from the following URLs:\n" );
1675 sub read_svm_props {
1676 my ($self, $ra, $path, $r) = @_;
1677 my $props = ($ra->get_dir($path, $r))[2];
1678 my $src = $props->{'svm:source'};
1679 my $uuid = $props->{'svm:uuid'};
1680 return undef if (!$src || !$uuid);
1681
1682 chomp($src, $uuid);
1683
1684 $uuid =~ m{^[0-9a-f\-]{30,}$}
1685 or die "doesn't look right - svm:uuid is '$uuid'\n";
1686
1687 # the '!' is used to mark the repos_root!/relative/path
1688 $src =~ s{/?!/?}{/};
1689 $src =~ s{/+$}{}; # no trailing slashes please
1690 # username is of no interest
1691 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1692
1693 my $replace = $ra->{url};
1694 $replace .= "/$path" if length $path;
1695
1696 my $section = "svn-remote.$self->{repo_id}";
1697 tmp_config("$section.svm-source", $src);
1698 tmp_config("$section.svm-replace", $replace);
1699 tmp_config("$section.svm-uuid", $uuid);
1700 $self->{svm} = {
1701 source => $src,
1702 uuid => $uuid,
1703 replace => $replace
1704 };
1705 }
1706
1707 my $r = $ra->get_latest_revnum;
1708 my $path = $self->{path};
1709 my %tried;
1710 while (length $path) {
1711 unless ($tried{"$self->{url}/$path"}) {
1712 return $ra if $self->read_svm_props($ra, $path, $r);
1713 $tried{"$self->{url}/$path"} = 1;
1714 }
1715 $path =~ s#/?[^/]+$##;
1716 }
1717 die "Path: '$path' should be ''\n" if $path ne '';
1718 return $ra if $self->read_svm_props($ra, $path, $r);
1719 $tried{"$self->{url}/$path"} = 1;
1720
1721 if ($ra->{repos_root} eq $self->{url}) {
1722 die @err, (map { " $_\n" } keys %tried), "\n";
1723 }
1724
1725 # nope, make sure we're connected to the repository root:
1726 my $ok;
1727 my @tried_b;
1728 $path = $ra->{svn_path};
1729 $ra = Git::SVN::Ra->new($ra->{repos_root});
1730 while (length $path) {
1731 unless ($tried{"$ra->{url}/$path"}) {
1732 $ok = $self->read_svm_props($ra, $path, $r);
1733 last if $ok;
1734 $tried{"$ra->{url}/$path"} = 1;
1735 }
1736 $path =~ s#/?[^/]+$##;
1737 }
1738 die "Path: '$path' should be ''\n" if $path ne '';
1739 $ok ||= $self->read_svm_props($ra, $path, $r);
1740 $tried{"$ra->{url}/$path"} = 1;
1741 if (!$ok) {
1742 die @err, (map { " $_\n" } keys %tried), "\n";
1743 }
1744 Git::SVN::Ra->new($self->{url});
1745 }
1746
1747 sub svnsync {
1748 my ($self) = @_;
1749 return $self->{svnsync} if $self->{svnsync};
1750
1751 if ($self->no_metadata) {
1752 die "Can't have both 'noMetadata' and ",
1753 "'useSvnsyncProps' options set!\n";
1754 }
1755 if ($self->rewrite_root) {
1756 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1757 "options set!\n";
1758 }
1759
1760 my $svnsync;
1761 # see if we have it in our config, first:
1762 eval {
1763 my $section = "svn-remote.$self->{repo_id}";
1764
1765 my $url = tmp_config('--get', "$section.svnsync-url");
1766 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1767 die "doesn't look right - svn:sync-from-url is '$url'\n";
1768
1769 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1770 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1771 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1772
1773 $svnsync = { url => $url, uuid => $uuid }
1774 };
1775 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1776 return $self->{svnsync} = $svnsync;
1777 }
1778
1779 my $err = "useSvnsyncProps set, but failed to read " .
1780 "svnsync property: svn:sync-from-";
1781 my $rp = $self->ra->rev_proplist(0);
1782
1783 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1784 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1785 die "doesn't look right - svn:sync-from-url is '$url'\n";
1786
1787 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1788 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1789 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1790
1791 my $section = "svn-remote.$self->{repo_id}";
1792 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1793 tmp_config('--add', "$section.svnsync-url", $url);
1794 return $self->{svnsync} = { url => $url, uuid => $uuid };
1795 }
1796
1797 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1798 # remote lookup (useful for 'git svn log').
1799 sub ra_uuid {
1800 my ($self) = @_;
1801 unless ($self->{ra_uuid}) {
1802 my $key = "svn-remote.$self->{repo_id}.uuid";
1803 my $uuid = eval { tmp_config('--get', $key) };
1804 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1805 $self->{ra_uuid} = $uuid;
1806 } else {
1807 die "ra_uuid called without URL\n" unless $self->{url};
1808 $self->{ra_uuid} = $self->ra->get_uuid;
1809 tmp_config('--add', $key, $self->{ra_uuid});
1810 }
1811 }
1812 $self->{ra_uuid};
1813 }
1814
1815 sub _set_repos_root {
1816 my ($self, $repos_root) = @_;
1817 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1818 $repos_root ||= $self->ra->{repos_root};
1819 tmp_config($k, $repos_root);
1820 $repos_root;
1821 }
1822
1823 sub repos_root {
1824 my ($self) = @_;
1825 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1826 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1827 }
1828
1829 sub ra {
1830 my ($self) = shift;
1831 my $ra = Git::SVN::Ra->new($self->{url});
1832 $self->_set_repos_root($ra->{repos_root});
1833 if ($self->use_svm_props && !$self->{svm}) {
1834 if ($self->no_metadata) {
1835 die "Can't have both 'noMetadata' and ",
1836 "'useSvmProps' options set!\n";
1837 } elsif ($self->use_svnsync_props) {
1838 die "Can't have both 'useSvnsyncProps' and ",
1839 "'useSvmProps' options set!\n";
1840 }
1841 $ra = $self->_set_svm_vars($ra);
1842 $self->{-want_revprops} = 1;
1843 }
1844 $ra;
1845 }
1846
1847 sub rel_path {
1848 my ($self) = @_;
1849 my $repos_root = $self->ra->{repos_root};
1850 return $self->{path} if ($self->{url} eq $repos_root);
1851 my $url = $self->{url} .
1852 (length $self->{path} ? "/$self->{path}" : $self->{path});
1853 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1854 $url;
1855 }
1856
1857 # prop_walk(PATH, REV, SUB)
1858 # -------------------------
1859 # Recursively traverse PATH at revision REV and invoke SUB for each
1860 # directory that contains a SVN property. SUB will be invoked as
1861 # follows: &SUB(gs, path, props); where `gs' is this instance of
1862 # Git::SVN, `path' the path to the directory where the properties
1863 # `props' were found. The `path' will be relative to point of checkout,
1864 # that is, if url://repo/trunk is the current Git branch, and that
1865 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1866 # as `path' (note the trailing `/').
1867 sub prop_walk {
1868 my ($self, $path, $rev, $sub) = @_;
1869
1870 $path =~ s#^/##;
1871 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1872 $path =~ s#^/*#/#g;
1873 my $p = $path;
1874 # Strip the irrelevant part of the path.
1875 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1876 # Ensure the path is terminated by a `/'.
1877 $p =~ s#/*$#/#;
1878
1879 # The properties contain all the internal SVN stuff nobody
1880 # (usually) cares about.
1881 my $interesting_props = 0;
1882 foreach (keys %{$props}) {
1883 # If it doesn't start with `svn:', it must be a
1884 # user-defined property.
1885 ++$interesting_props and next if $_ !~ /^svn:/;
1886 # FIXME: Fragile, if SVN adds new public properties,
1887 # this needs to be updated.
1888 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1889 |eol-style|mime-type
1890 |externals|needs-lock)$/x;
1891 }
1892 &$sub($self, $p, $props) if $interesting_props;
1893
1894 foreach (sort keys %$dirent) {
1895 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1896 $self->prop_walk($path . '/' . $_, $rev, $sub);
1897 }
1898 }
1899
1900 sub last_rev { ($_[0]->last_rev_commit)[0] }
1901 sub last_commit { ($_[0]->last_rev_commit)[1] }
1902
1903 # returns the newest SVN revision number and newest commit SHA1
1904 sub last_rev_commit {
1905 my ($self) = @_;
1906 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1907 return ($self->{last_rev}, $self->{last_commit});
1908 }
1909 my $c = ::verify_ref($self->refname.'^0');
1910 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1911 my $rev = (::cmt_metadata($c))[1];
1912 if (defined $rev) {
1913 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1914 return ($rev, $c);
1915 }
1916 }
1917 my $map_path = $self->map_path;
1918 unless (-e $map_path) {
1919 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1920 return (undef, undef);
1921 }
1922 my ($rev, $commit) = $self->rev_map_max(1);
1923 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1924 return ($rev, $commit);
1925 }
1926
1927 sub get_fetch_range {
1928 my ($self, $min, $max) = @_;
1929 $max ||= $self->ra->get_latest_revnum;
1930 $min ||= $self->rev_map_max;
1931 (++$min, $max);
1932 }
1933
1934 sub tmp_config {
1935 my (@args) = @_;
1936 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1937 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1938 if (! -f $config && -f $old_def_config) {
1939 rename $old_def_config, $config or
1940 die "Failed rename $old_def_config => $config: $!\n";
1941 }
1942 my $old_config = $ENV{GIT_CONFIG};
1943 $ENV{GIT_CONFIG} = $config;
1944 $@ = undef;
1945 my @ret = eval {
1946 unless (-f $config) {
1947 mkfile($config);
1948 open my $fh, '>', $config or
1949 die "Can't open $config: $!\n";
1950 print $fh "; This file is used internally by ",
1951 "git-svn\n" or die
1952 "Couldn't write to $config: $!\n";
1953 print $fh "; You should not have to edit it\n" or
1954 die "Couldn't write to $config: $!\n";
1955 close $fh or die "Couldn't close $config: $!\n";
1956 }
1957 command('config', @args);
1958 };
1959 my $err = $@;
1960 if (defined $old_config) {
1961 $ENV{GIT_CONFIG} = $old_config;
1962 } else {
1963 delete $ENV{GIT_CONFIG};
1964 }
1965 die $err if $err;
1966 wantarray ? @ret : $ret[0];
1967 }
1968
1969 sub tmp_index_do {
1970 my ($self, $sub) = @_;
1971 my $old_index = $ENV{GIT_INDEX_FILE};
1972 $ENV{GIT_INDEX_FILE} = $self->{index};
1973 $@ = undef;
1974 my @ret = eval {
1975 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1976 mkpath([$dir]) unless -d $dir;
1977 &$sub;
1978 };
1979 my $err = $@;
1980 if (defined $old_index) {
1981 $ENV{GIT_INDEX_FILE} = $old_index;
1982 } else {
1983 delete $ENV{GIT_INDEX_FILE};
1984 }
1985 die $err if $err;
1986 wantarray ? @ret : $ret[0];
1987 }
1988
1989 sub assert_index_clean {
1990 my ($self, $treeish) = @_;
1991
1992 $self->tmp_index_do(sub {
1993 command_noisy('read-tree', $treeish) unless -e $self->{index};
1994 my $x = command_oneline('write-tree');
1995 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1996 /^tree ($::sha1)/mo);
1997 return if $y eq $x;
1998
1999 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2000 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2001 command_noisy('read-tree', $treeish);
2002 $x = command_oneline('write-tree');
2003 if ($y ne $x) {
2004 ::fatal "trees ($treeish) $y != $x\n",
2005 "Something is seriously wrong...";
2006 }
2007 });
2008 }
2009
2010 sub get_commit_parents {
2011 my ($self, $log_entry) = @_;
2012 my (%seen, @ret, @tmp);
2013 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2014 if (my $ip = $self->{inject_parents}) {
2015 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2016 push @tmp, $commit;
2017 }
2018 }
2019 if (my $cur = ::verify_ref($self->refname.'^0')) {
2020 push @tmp, $cur;
2021 }
2022 if (my $ipd = $self->{inject_parents_dcommit}) {
2023 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2024 push @tmp, @$commit;
2025 }
2026 }
2027 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2028 while (my $p = shift @tmp) {
2029 next if $seen{$p};
2030 $seen{$p} = 1;
2031 push @ret, $p;
2032 # MAXPARENT is defined to 16 in commit-tree.c:
2033 last if @ret >= 16;
2034 }
2035 if (@tmp) {
2036 die "r$log_entry->{revision}: No room for parents:\n\t",
2037 join("\n\t", @tmp), "\n";
2038 }
2039 @ret;
2040 }
2041
2042 sub rewrite_root {
2043 my ($self) = @_;
2044 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2045 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2046 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2047 if ($rwr) {
2048 $rwr =~ s#/+$##;
2049 if ($rwr !~ m#^[a-z\+]+://#) {
2050 die "$rwr is not a valid URL (key: $k)\n";
2051 }
2052 }
2053 $self->{-rewrite_root} = $rwr;
2054 }
2055
2056 sub metadata_url {
2057 my ($self) = @_;
2058 ($self->rewrite_root || $self->{url}) .
2059 (length $self->{path} ? '/' . $self->{path} : '');
2060 }
2061
2062 sub full_url {
2063 my ($self) = @_;
2064 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2065 }
2066
2067
2068 sub set_commit_header_env {
2069 my ($log_entry) = @_;
2070 my %env;
2071 foreach my $ned (qw/NAME EMAIL DATE/) {
2072 foreach my $ac (qw/AUTHOR COMMITTER/) {
2073 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2074 }
2075 }
2076
2077 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2078 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2079 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2080
2081 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2082 ? $log_entry->{commit_name}
2083 : $log_entry->{name};
2084 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2085 ? $log_entry->{commit_email}
2086 : $log_entry->{email};
2087 \%env;
2088 }
2089
2090 sub restore_commit_header_env {
2091 my ($env) = @_;
2092 foreach my $ned (qw/NAME EMAIL DATE/) {
2093 foreach my $ac (qw/AUTHOR COMMITTER/) {
2094 my $k = "GIT_${ac}_${ned}";
2095 if (defined $env->{$k}) {
2096 $ENV{$k} = $env->{$k};
2097 } else {
2098 delete $ENV{$k};
2099 }
2100 }
2101 }
2102 }
2103
2104 sub do_git_commit {
2105 my ($self, $log_entry) = @_;
2106 my $lr = $self->last_rev;
2107 if (defined $lr && $lr >= $log_entry->{revision}) {
2108 die "Last fetched revision of ", $self->refname,
2109 " was r$lr, but we are about to fetch: ",
2110 "r$log_entry->{revision}!\n";
2111 }
2112 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2113 croak "$log_entry->{revision} = $c already exists! ",
2114 "Why are we refetching it?\n";
2115 }
2116 my $old_env = set_commit_header_env($log_entry);
2117 my $tree = $log_entry->{tree};
2118 if (!defined $tree) {
2119 $tree = $self->tmp_index_do(sub {
2120 command_oneline('write-tree') });
2121 }
2122 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2123
2124 my @exec = ('git-commit-tree', $tree);
2125 foreach ($self->get_commit_parents($log_entry)) {
2126 push @exec, '-p', $_;
2127 }
2128 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2129 or croak $!;
2130 print $msg_fh $log_entry->{log} or croak $!;
2131 restore_commit_header_env($old_env);
2132 unless ($self->no_metadata) {
2133 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2134 or croak $!;
2135 }
2136 $msg_fh->flush == 0 or croak $!;
2137 close $msg_fh or croak $!;
2138 chomp(my $commit = do { local $/; <$out_fh> });
2139 close $out_fh or croak $!;
2140 waitpid $pid, 0;
2141 croak $? if $?;
2142 if ($commit !~ /^$::sha1$/o) {
2143 die "Failed to commit, invalid sha1: $commit\n";
2144 }
2145
2146 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2147
2148 $self->{last_rev} = $log_entry->{revision};
2149 $self->{last_commit} = $commit;
2150 print "r$log_entry->{revision}";
2151 if (defined $log_entry->{svm_revision}) {
2152 print " (\@$log_entry->{svm_revision})";
2153 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2154 0, $self->svm_uuid);
2155 }
2156 print " = $commit ($self->{ref_id})\n";
2157 if ($_repack && (--$_repack_nr == 0)) {
2158 $_repack_nr = $_repack;
2159 # repack doesn't use any arguments with spaces in them, does it?
2160 print "Running git repack $_repack_flags ...\n";
2161 command_noisy('repack', split(/\s+/, $_repack_flags));
2162 print "Done repacking\n";
2163 }
2164 return $commit;
2165 }
2166
2167 sub match_paths {
2168 my ($self, $paths, $r) = @_;
2169 return 1 if $self->{path} eq '';
2170 if (my $path = $paths->{"/$self->{path}"}) {
2171 return ($path->{action} eq 'D') ? 0 : 1;
2172 }
2173 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2174 if (grep /$self->{path_regex}/, keys %$paths) {
2175 return 1;
2176 }
2177 my $c = '';
2178 foreach (split m#/#, $self->{path}) {
2179 $c .= "/$_";
2180 next unless ($paths->{$c} &&
2181 ($paths->{$c}->{action} =~ /^[AR]$/));
2182 if ($self->ra->check_path($self->{path}, $r) ==
2183 $SVN::Node::dir) {
2184 return 1;
2185 }
2186 }
2187 return 0;
2188 }
2189
2190 sub find_parent_branch {
2191 my ($self, $paths, $rev) = @_;
2192 return undef unless $self->follow_parent;
2193 unless (defined $paths) {
2194 my $err_handler = $SVN::Error::handler;
2195 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2196 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2197 $paths =
2198 Git::SVN::Ra::dup_changed_paths($_[0]) });
2199 $SVN::Error::handler = $err_handler;
2200 }
2201 return undef unless defined $paths;
2202
2203 # look for a parent from another branch:
2204 my @b_path_components = split m#/#, $self->rel_path;
2205 my @a_path_components;
2206 my $i;
2207 while (@b_path_components) {
2208 $i = $paths->{'/'.join('/', @b_path_components)};
2209 last if $i && defined $i->{copyfrom_path};
2210 unshift(@a_path_components, pop(@b_path_components));
2211 }
2212 return undef unless defined $i && defined $i->{copyfrom_path};
2213 my $branch_from = $i->{copyfrom_path};
2214 if (@a_path_components) {
2215 print STDERR "branch_from: $branch_from => ";
2216 $branch_from .= '/'.join('/', @a_path_components);
2217 print STDERR $branch_from, "\n";
2218 }
2219 my $r = $i->{copyfrom_rev};
2220 my $repos_root = $self->ra->{repos_root};
2221 my $url = $self->ra->{url};
2222 my $new_url = $repos_root . $branch_from;
2223 print STDERR "Found possible branch point: ",
2224 "$new_url => ", $self->full_url, ", $r\n";
2225 $branch_from =~ s#^/##;
2226 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2227 unless ($gs) {
2228 my $ref_id = $self->{ref_id};
2229 $ref_id =~ s/\@\d+$//;
2230 $ref_id .= "\@$r";
2231 # just grow a tail if we're not unique enough :x
2232 $ref_id .= '-' while find_ref($ref_id);
2233 print STDERR "Initializing parent: $ref_id\n";
2234 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2235 }
2236 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2237 if (!defined $r0 || !defined $parent) {
2238 my ($base, $head) = parse_revision_argument(0, $r);
2239 if ($base <= $r) {
2240 $gs->fetch($base, $r);
2241 }
2242 ($r0, $parent) = $gs->last_rev_commit;
2243 }
2244 if (defined $r0 && defined $parent) {
2245 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2246 my $ed;
2247 if ($self->ra->can_do_switch) {
2248 $self->assert_index_clean($parent);
2249 print STDERR "Following parent with do_switch\n";
2250 # do_switch works with svn/trunk >= r22312, but that
2251 # is not included with SVN 1.4.3 (the latest version
2252 # at the moment), so we can't rely on it
2253 $self->{last_commit} = $parent;
2254 $ed = SVN::Git::Fetcher->new($self);
2255 $gs->ra->gs_do_switch($r0, $rev, $gs,
2256 $self->full_url, $ed)
2257 or die "SVN connection failed somewhere...\n";
2258 } elsif ($self->ra->trees_match($new_url, $r0,
2259 $self->full_url, $rev)) {
2260 print STDERR "Trees match:\n",
2261 " $new_url\@$r0\n",
2262 " ${\$self->full_url}\@$rev\n",
2263 "Following parent with no changes\n";
2264 $self->tmp_index_do(sub {
2265 command_noisy('read-tree', $parent);
2266 });
2267 $self->{last_commit} = $parent;
2268 } else {
2269 print STDERR "Following parent with do_update\n";
2270 $ed = SVN::Git::Fetcher->new($self);
2271 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2272 or die "SVN connection failed somewhere...\n";
2273 }
2274 print STDERR "Successfully followed parent\n";
2275 return $self->make_log_entry($rev, [$parent], $ed);
2276 }
2277 return undef;
2278 }
2279
2280 sub do_fetch {
2281 my ($self, $paths, $rev) = @_;
2282 my $ed;
2283 my ($last_rev, @parents);
2284 if (my $lc = $self->last_commit) {
2285 # we can have a branch that was deleted, then re-added
2286 # under the same name but copied from another path, in
2287 # which case we'll have multiple parents (we don't
2288 # want to break the original ref, nor lose copypath info):
2289 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2290 push @{$log_entry->{parents}}, $lc;
2291 return $log_entry;
2292 }
2293 $ed = SVN::Git::Fetcher->new($self);
2294 $last_rev = $self->{last_rev};
2295 $ed->{c} = $lc;
2296 @parents = ($lc);
2297 } else {
2298 $last_rev = $rev;
2299 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2300 return $log_entry;
2301 }
2302 $ed = SVN::Git::Fetcher->new($self);
2303 }
2304 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2305 die "SVN connection failed somewhere...\n";
2306 }
2307 $self->make_log_entry($rev, \@parents, $ed);
2308 }
2309
2310 sub get_untracked {
2311 my ($self, $ed) = @_;
2312 my @out;
2313 my $h = $ed->{empty};
2314 foreach (sort keys %$h) {
2315 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2316 push @out, " $act: " . uri_encode($_);
2317 warn "W: $act: $_\n";
2318 }
2319 foreach my $t (qw/dir_prop file_prop/) {
2320 $h = $ed->{$t} or next;
2321 foreach my $path (sort keys %$h) {
2322 my $ppath = $path eq '' ? '.' : $path;
2323 foreach my $prop (sort keys %{$h->{$path}}) {
2324 next if $SKIP_PROP{$prop};
2325 my $v = $h->{$path}->{$prop};
2326 my $t_ppath_prop = "$t: " .
2327 uri_encode($ppath) . ' ' .
2328 uri_encode($prop);
2329 if (defined $v) {
2330 push @out, " +$t_ppath_prop " .
2331 uri_encode($v);
2332 } else {
2333 push @out, " -$t_ppath_prop";
2334 }
2335 }
2336 }
2337 }
2338 foreach my $t (qw/absent_file absent_directory/) {
2339 $h = $ed->{$t} or next;
2340 foreach my $parent (sort keys %$h) {
2341 foreach my $path (sort @{$h->{$parent}}) {
2342 push @out, " $t: " .
2343 uri_encode("$parent/$path");
2344 warn "W: $t: $parent/$path ",
2345 "Insufficient permissions?\n";
2346 }
2347 }
2348 }
2349 \@out;
2350 }
2351
2352 sub parse_svn_date {
2353 my $date = shift || return '+0000 1970-01-01 00:00:00';
2354 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2355 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2356 croak "Unable to parse date: $date\n";
2357 "+0000 $Y-$m-$d $H:$M:$S";
2358 }
2359
2360 sub check_author {
2361 my ($author) = @_;
2362 if (!defined $author || length $author == 0) {
2363 $author = '(no author)';
2364 }
2365 if (defined $::_authors && ! defined $::users{$author}) {
2366 die "Author: $author not defined in $::_authors file\n";
2367 }
2368 $author;
2369 }
2370
2371 sub make_log_entry {
2372 my ($self, $rev, $parents, $ed) = @_;
2373 my $untracked = $self->get_untracked($ed);
2374
2375 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2376 print $un "r$rev\n" or croak $!;
2377 print $un $_, "\n" foreach @$untracked;
2378 my %log_entry = ( parents => $parents || [], revision => $rev,
2379 log => '');
2380
2381 my $headrev;
2382 my $logged = delete $self->{logged_rev_props};
2383 if (!$logged || $self->{-want_revprops}) {
2384 my $rp = $self->ra->rev_proplist($rev);
2385 foreach (sort keys %$rp) {
2386 my $v = $rp->{$_};
2387 if (/^svn:(author|date|log)$/) {
2388 $log_entry{$1} = $v;
2389 } elsif ($_ eq 'svm:headrev') {
2390 $headrev = $v;
2391 } else {
2392 print $un " rev_prop: ", uri_encode($_), ' ',
2393 uri_encode($v), "\n";
2394 }
2395 }
2396 } else {
2397 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2398 }
2399 close $un or croak $!;
2400
2401 $log_entry{date} = parse_svn_date($log_entry{date});
2402 $log_entry{log} .= "\n";
2403 my $author = $log_entry{author} = check_author($log_entry{author});
2404 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2405 : ($author, undef);
2406
2407 my ($commit_name, $commit_email) = ($name, $email);
2408 if ($_use_log_author) {
2409 my $name_field;
2410 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2411 $name_field = $1;
2412 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2413 $name_field = $1;
2414 }
2415 if (!defined $name_field) {
2416 #
2417 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2418 ($name, $email) = ($1, $2);
2419 } elsif ($name_field =~ /(.*)@/) {
2420 ($name, $email) = ($1, $name_field);
2421 } else {
2422 ($name, $email) = ($name_field, 'unknown');
2423 }
2424 }
2425 if (defined $headrev && $self->use_svm_props) {
2426 if ($self->rewrite_root) {
2427 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2428 "options set!\n";
2429 }
2430 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2431 # we don't want "SVM: initializing mirror for junk" ...
2432 return undef if $r == 0;
2433 my $svm = $self->svm;
2434 if ($uuid ne $svm->{uuid}) {
2435 die "UUID mismatch on SVM path:\n",
2436 "expected: $svm->{uuid}\n",
2437 " got: $uuid\n";
2438 }
2439 my $full_url = $self->full_url;
2440 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2441 die "Failed to replace '$svm->{replace}' with ",
2442 "'$svm->{source}' in $full_url\n";
2443 # throw away username for storing in records
2444 remove_username($full_url);
2445 $log_entry{metadata} = "$full_url\@$r $uuid";
2446 $log_entry{svm_revision} = $r;
2447 $email ||= "$author\@$uuid";
2448 $commit_email ||= "$author\@$uuid";
2449 } elsif ($self->use_svnsync_props) {
2450 my $full_url = $self->svnsync->{url};
2451 $full_url .= "/$self->{path}" if length $self->{path};
2452 remove_username($full_url);
2453 my $uuid = $self->svnsync->{uuid};
2454 $log_entry{metadata} = "$full_url\@$rev $uuid";
2455 $email ||= "$author\@$uuid";
2456 $commit_email ||= "$author\@$uuid";
2457 } else {
2458 my $url = $self->metadata_url;
2459 remove_username($url);
2460 $log_entry{metadata} = "$url\@$rev " .
2461 $self->ra->get_uuid;
2462 $email ||= "$author\@" . $self->ra->get_uuid;
2463 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2464 }
2465 $log_entry{name} = $name;
2466 $log_entry{email} = $email;
2467 $log_entry{commit_name} = $commit_name;
2468 $log_entry{commit_email} = $commit_email;
2469 \%log_entry;
2470 }
2471
2472 sub fetch {
2473 my ($self, $min_rev, $max_rev, @parents) = @_;
2474 my ($last_rev, $last_commit) = $self->last_rev_commit;
2475 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2476 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2477 }
2478
2479 sub set_tree_cb {
2480 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2481 $self->{inject_parents} = { $rev => $tree };
2482 $self->fetch(undef, undef);
2483 }
2484
2485 sub set_tree {
2486 my ($self, $tree) = (shift, shift);
2487 my $log_entry = ::get_commit_entry($tree);
2488 unless ($self->{last_rev}) {
2489 fatal("Must have an existing revision to commit");
2490 }
2491 my %ed_opts = ( r => $self->{last_rev},
2492 log => $log_entry->{log},
2493 ra => $self->ra,
2494 tree_a => $self->{last_commit},
2495 tree_b => $tree,
2496 editor_cb => sub {
2497 $self->set_tree_cb($log_entry, $tree, @_) },
2498 svn_path => $self->{path} );
2499 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2500 print "No changes\nr$self->{last_rev} = $tree\n";
2501 }
2502 }
2503
2504 sub rebuild_from_rev_db {
2505 my ($self, $path) = @_;
2506 my $r = -1;
2507 open my $fh, '<', $path or croak "open: $!";
2508 while (<$fh>) {
2509 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2510 chomp($_);
2511 ++$r;
2512 next if $_ eq ('0' x 40);
2513 $self->rev_map_set($r, $_);
2514 print "r$r = $_\n";
2515 }
2516 close $fh or croak "close: $!";
2517 unlink $path or croak "unlink: $!";
2518 }
2519
2520 sub rebuild {
2521 my ($self) = @_;
2522 my $map_path = $self->map_path;
2523 return if (-e $map_path && ! -z $map_path);
2524 return unless ::verify_ref($self->refname.'^0');
2525 if ($self->use_svm_props || $self->no_metadata) {
2526 my $rev_db = $self->rev_db_path;
2527 $self->rebuild_from_rev_db($rev_db);
2528 if ($self->use_svm_props) {
2529 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2530 $self->rebuild_from_rev_db($svm_rev_db);
2531 }
2532 $self->unlink_rev_db_symlink;
2533 return;
2534 }
2535 print "Rebuilding $map_path ...\n";
2536 my ($log, $ctx) =
2537 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2538 $self->refname, '--');
2539 my $full_url = $self->full_url;
2540 remove_username($full_url);
2541 my $svn_uuid = $self->ra_uuid;
2542 my $c;
2543 while (<$log>) {
2544 if ( m{^commit ($::sha1)$} ) {
2545 $c = $1;
2546 next;
2547 }
2548 next unless s{^\s*(git-svn-id:)}{$1};
2549 my ($url, $rev, $uuid) = ::extract_metadata($_);
2550 remove_username($url);
2551
2552 # ignore merges (from set-tree)
2553 next if (!defined $rev || !$uuid);
2554
2555 # if we merged or otherwise started elsewhere, this is
2556 # how we break out of it
2557 if (($uuid ne $svn_uuid) ||
2558 ($full_url && $url && ($url ne $full_url))) {
2559 next;
2560 }
2561
2562 $self->rev_map_set($rev, $c);
2563 print "r$rev = $c\n";
2564 }
2565 command_close_pipe($log, $ctx);
2566 print "Done rebuilding $map_path\n";
2567 my $rev_db_path = $self->rev_db_path;
2568 if (-f $self->rev_db_path) {
2569 unlink $self->rev_db_path or croak "unlink: $!";
2570 }
2571 $self->unlink_rev_db_symlink;
2572 }
2573
2574 # rev_map:
2575 # Tie::File seems to be prone to offset errors if revisions get sparse,
2576 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2577 # one of my favorite modules is out :< Next up would be one of the DBM
2578 # modules, but I'm not sure which is most portable...
2579 #
2580 # This is the replacement for the rev_db format, which was too big
2581 # and inefficient for large repositories with a lot of sparse history
2582 # (mainly tags)
2583 #
2584 # The format is this:
2585 # - 24 bytes for every record,
2586 # * 4 bytes for the integer representing an SVN revision number
2587 # * 20 bytes representing the sha1 of a git commit
2588 # - No empty padding records like the old format
2589 # (except the last record, which can be overwritten)
2590 # - new records are written append-only since SVN revision numbers
2591 # increase monotonically
2592 # - lookups on SVN revision number are done via a binary search
2593 # - Piping the file to xxd -c24 is a good way of dumping it for
2594 # viewing or editing (piped back through xxd -r), should the need
2595 # ever arise.
2596 # - The last record can be padding revision with an all-zero sha1
2597 # This is used to optimize fetch performance when using multiple
2598 # "fetch" directives in .git/config
2599 #
2600 # These files are disposable unless noMetadata or useSvmProps is set
2601
2602 sub _rev_map_set {
2603 my ($fh, $rev, $commit) = @_;
2604
2605 my $size = (stat($fh))[7];
2606 ($size % 24) == 0 or croak "inconsistent size: $size";
2607
2608 my $wr_offset = 0;
2609 if ($size > 0) {
2610 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2611 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2612 $read == 24 or croak "read only $read bytes (!= 24)";
2613 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2614 if ($last_commit eq ('0' x40)) {
2615 if ($size >= 48) {
2616 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2617 $read = sysread($fh, $buf, 24) or
2618 croak "read: $!";
2619 $read == 24 or
2620 croak "read only $read bytes (!= 24)";
2621 ($last_rev, $last_commit) =
2622 unpack(rev_map_fmt, $buf);
2623 if ($last_commit eq ('0' x40)) {
2624 croak "inconsistent .rev_map\n";
2625 }
2626 }
2627 if ($last_rev >= $rev) {
2628 croak "last_rev is higher!: $last_rev >= $rev";
2629 }
2630 $wr_offset = -24;
2631 }
2632 }
2633 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2634 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2635 croak "write: $!";
2636 }
2637
2638 sub mkfile {
2639 my ($path) = @_;
2640 unless (-e $path) {
2641 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2642 mkpath([$dir]) unless -d $dir;
2643 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2644 close $fh or die "Couldn't close (create) $path: $!\n";
2645 }
2646 }
2647
2648 sub rev_map_set {
2649 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2650 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2651 my $db = $self->map_path($uuid);
2652 my $db_lock = "$db.lock";
2653 my $sig;
2654 if ($update_ref) {
2655 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2656 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2657 }
2658 mkfile($db);
2659
2660 $LOCKFILES{$db_lock} = 1;
2661 my $sync;
2662 # both of these options make our .rev_db file very, very important
2663 # and we can't afford to lose it because rebuild() won't work
2664 if ($self->use_svm_props || $self->no_metadata) {
2665 $sync = 1;
2666 copy($db, $db_lock) or die "rev_map_set(@_): ",
2667 "Failed to copy: ",
2668 "$db => $db_lock ($!)\n";
2669 } else {
2670 rename $db, $db_lock or die "rev_map_set(@_): ",
2671 "Failed to rename: ",
2672 "$db => $db_lock ($!)\n";
2673 }
2674
2675 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2676 or croak "Couldn't open $db_lock: $!\n";
2677 _rev_map_set($fh, $rev, $commit);
2678 if ($sync) {
2679 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2680 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2681 }
2682 close $fh or croak $!;
2683 if ($update_ref) {
2684 $_head = $self;
2685 command_noisy('update-ref', '-m', "r$rev",
2686 $self->refname, $commit);
2687 }
2688 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2689 "$db_lock => $db ($!)\n";
2690 delete $LOCKFILES{$db_lock};
2691 if ($update_ref) {
2692 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2693 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2694 kill $sig, $$ if defined $sig;
2695 }
2696 }
2697
2698 # If want_commit, this will return an array of (rev, commit) where
2699 # commit _must_ be a valid commit in the archive.
2700 # Otherwise, it'll return the max revision (whether or not the
2701 # commit is valid or just a 0x40 placeholder).
2702 sub rev_map_max {
2703 my ($self, $want_commit) = @_;
2704 $self->rebuild;
2705 my $map_path = $self->map_path;
2706 stat $map_path or return $want_commit ? (0, undef) : 0;
2707 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2708 my $size = (stat($fh))[7];
2709 ($size % 24) == 0 or croak "inconsistent size: $size";
2710
2711 if ($size == 0) {
2712 close $fh or croak "close: $!";
2713 return $want_commit ? (0, undef) : 0;
2714 }
2715
2716 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2717 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2718 my ($r, $c) = unpack(rev_map_fmt, $buf);
2719 if ($want_commit && $c eq ('0' x40)) {
2720 if ($size < 48) {
2721 return $want_commit ? (0, undef) : 0;
2722 }
2723 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2724 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2725 ($r, $c) = unpack(rev_map_fmt, $buf);
2726 if ($c eq ('0'x40)) {
2727 croak "Penultimate record is all-zeroes in $map_path";
2728 }
2729 }
2730 close $fh or croak "close: $!";
2731 $want_commit ? ($r, $c) : $r;
2732 }
2733
2734 sub rev_map_get {
2735 my ($self, $rev, $uuid) = @_;
2736 my $map_path = $self->map_path($uuid);
2737 return undef unless -e $map_path;
2738
2739 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2740 my $size = (stat($fh))[7];
2741 ($size % 24) == 0 or croak "inconsistent size: $size";
2742
2743 if ($size == 0) {
2744 close $fh or croak "close: $fh";
2745 return undef;
2746 }
2747
2748 my ($l, $u) = (0, $size - 24);
2749 my ($r, $c, $buf);
2750
2751 while ($l <= $u) {
2752 my $i = int(($l/24 + $u/24) / 2) * 24;
2753 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2754 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2755 my ($r, $c) = unpack('NH40', $buf);
2756
2757 if ($r < $rev) {
2758 $l = $i + 24;
2759 } elsif ($r > $rev) {
2760 $u = $i - 24;
2761 } else { # $r == $rev
2762 close($fh) or croak "close: $!";
2763 return $c eq ('0' x 40) ? undef : $c;
2764 }
2765 }
2766 close($fh) or croak "close: $!";
2767 undef;
2768 }
2769
2770 # Finds the first svn revision that exists on (if $eq_ok is true) or
2771 # before $rev for the current branch. It will not search any lower
2772 # than $min_rev. Returns the git commit hash and svn revision number
2773 # if found, else (undef, undef).
2774 sub find_rev_before {
2775 my ($self, $rev, $eq_ok, $min_rev) = @_;
2776 --$rev unless $eq_ok;
2777 $min_rev ||= 1;
2778 while ($rev >= $min_rev) {
2779 if (my $c = $self->rev_map_get($rev)) {
2780 return ($rev, $c);
2781 }
2782 --$rev;
2783 }
2784 return (undef, undef);
2785 }
2786
2787 # Finds the first svn revision that exists on (if $eq_ok is true) or
2788 # after $rev for the current branch. It will not search any higher
2789 # than $max_rev. Returns the git commit hash and svn revision number
2790 # if found, else (undef, undef).
2791 sub find_rev_after {
2792 my ($self, $rev, $eq_ok, $max_rev) = @_;
2793 ++$rev unless $eq_ok;
2794 $max_rev ||= $self->rev_map_max;
2795 while ($rev <= $max_rev) {
2796 if (my $c = $self->rev_map_get($rev)) {
2797 return ($rev, $c);
2798 }
2799 ++$rev;
2800 }
2801 return (undef, undef);
2802 }
2803
2804 sub _new {
2805 my ($class, $repo_id, $ref_id, $path) = @_;
2806 unless (defined $repo_id && length $repo_id) {
2807 $repo_id = $Git::SVN::default_repo_id;
2808 }
2809 unless (defined $ref_id && length $ref_id) {
2810 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2811 }
2812 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2813 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2814 $_[3] = $path = '' unless (defined $path);
2815 mkpath(["$ENV{GIT_DIR}/svn"]);
2816 bless {
2817 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2818 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2819 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2820 }
2821
2822 # for read-only access of old .rev_db formats
2823 sub unlink_rev_db_symlink {
2824 my ($self) = @_;
2825 my $link = $self->rev_db_path;
2826 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2827 if (-l $link) {
2828 unlink $link or croak "unlink: $link failed!";
2829 }
2830 }
2831
2832 sub rev_db_path {
2833 my ($self, $uuid) = @_;
2834 my $db_path = $self->map_path($uuid);
2835 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2836 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2837 $db_path;
2838 }
2839
2840 # the new replacement for .rev_db
2841 sub map_path {
2842 my ($self, $uuid) = @_;
2843 $uuid ||= $self->ra_uuid;
2844 "$self->{map_root}.$uuid";
2845 }
2846
2847 sub uri_encode {
2848 my ($f) = @_;
2849 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2850 $f
2851 }
2852
2853 sub remove_username {
2854 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2855 }
2856
2857 package Git::SVN::Prompt;
2858 use strict;
2859 use warnings;
2860 require SVN::Core;
2861 use vars qw/$_no_auth_cache $_username/;
2862
2863 sub simple {
2864 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2865 $may_save = undef if $_no_auth_cache;
2866 $default_username = $_username if defined $_username;
2867 if (defined $default_username && length $default_username) {
2868 if (defined $realm && length $realm) {
2869 print STDERR "Authentication realm: $realm\n";
2870 STDERR->flush;
2871 }
2872 $cred->username($default_username);
2873 } else {
2874 username($cred, $realm, $may_save, $pool);
2875 }
2876 $cred->password(_read_password("Password for '" .
2877 $cred->username . "': ", $realm));
2878 $cred->may_save($may_save);
2879 $SVN::_Core::SVN_NO_ERROR;
2880 }
2881
2882 sub ssl_server_trust {
2883 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2884 $may_save = undef if $_no_auth_cache;
2885 print STDERR "Error validating server certificate for '$realm':\n";
2886 {
2887 no warnings 'once';
2888 # All variables SVN::Auth::SSL::* are used only once,
2889 # so we're shutting up Perl warnings about this.
2890 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2891 print STDERR " - The certificate is not issued ",
2892 "by a trusted authority. Use the\n",
2893 " fingerprint to validate ",
2894 "the certificate manually!\n";
2895 }
2896 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2897 print STDERR " - The certificate hostname ",
2898 "does not match.\n";
2899 }
2900 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2901 print STDERR " - The certificate is not yet valid.\n";
2902 }
2903 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2904 print STDERR " - The certificate has expired.\n";
2905 }
2906 if ($failures & $SVN::Auth::SSL::OTHER) {
2907 print STDERR " - The certificate has ",
2908 "an unknown error.\n";
2909 }
2910 } # no warnings 'once'
2911 printf STDERR
2912 "Certificate information:\n".
2913 " - Hostname: %s\n".
2914 " - Valid: from %s until %s\n".
2915 " - Issuer: %s\n".
2916 " - Fingerprint: %s\n",
2917 map $cert_info->$_, qw(hostname valid_from valid_until
2918 issuer_dname fingerprint);
2919 my $choice;
2920 prompt:
2921 print STDERR $may_save ?
2922 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2923 "(R)eject or accept (t)emporarily? ";
2924 STDERR->flush;
2925 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2926 if ($choice =~ /^t$/i) {
2927 $cred->may_save(undef);
2928 } elsif ($choice =~ /^r$/i) {
2929 return -1;
2930 } elsif ($may_save && $choice =~ /^p$/i) {
2931 $cred->may_save($may_save);
2932 } else {
2933 goto prompt;
2934 }
2935 $cred->accepted_failures($failures);
2936 $SVN::_Core::SVN_NO_ERROR;
2937 }
2938
2939 sub ssl_client_cert {
2940 my ($cred, $realm, $may_save, $pool) = @_;
2941 $may_save = undef if $_no_auth_cache;
2942 print STDERR "Client certificate filename: ";
2943 STDERR->flush;
2944 chomp(my $filename = <STDIN>);
2945 $cred->cert_file($filename);
2946 $cred->may_save($may_save);
2947 $SVN::_Core::SVN_NO_ERROR;
2948 }
2949
2950 sub ssl_client_cert_pw {
2951 my ($cred, $realm, $may_save, $pool) = @_;
2952 $may_save = undef if $_no_auth_cache;
2953 $cred->password(_read_password("Password: ", $realm));
2954 $cred->may_save($may_save);
2955 $SVN::_Core::SVN_NO_ERROR;
2956 }
2957
2958 sub username {
2959 my ($cred, $realm, $may_save, $pool) = @_;
2960 $may_save = undef if $_no_auth_cache;
2961 if (defined $realm && length $realm) {
2962 print STDERR "Authentication realm: $realm\n";
2963 }
2964 my $username;
2965 if (defined $_username) {
2966 $username = $_username;
2967 } else {
2968 print STDERR "Username: ";
2969 STDERR->flush;
2970 chomp($username = <STDIN>);
2971 }
2972 $cred->username($username);
2973 $cred->may_save($may_save);
2974 $SVN::_Core::SVN_NO_ERROR;
2975 }
2976
2977 sub _read_password {
2978 my ($prompt, $realm) = @_;
2979 print STDERR $prompt;
2980 STDERR->flush;
2981 require Term::ReadKey;
2982 Term::ReadKey::ReadMode('noecho');
2983 my $password = '';
2984 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2985 last if $key =~ /[\012\015]/; # \n\r
2986 $password .= $key;
2987 }
2988 Term::ReadKey::ReadMode('restore');
2989 print STDERR "\n";
2990 STDERR->flush;
2991 $password;
2992 }
2993
2994 package SVN::Git::Fetcher;
2995 use vars qw/@ISA/;
2996 use strict;
2997 use warnings;
2998 use Carp qw/croak/;
2999 use IO::File qw//;
3000
3001 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3002 sub new {
3003 my ($class, $git_svn) = @_;
3004 my $self = SVN::Delta::Editor->new;
3005 bless $self, $class;
3006 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3007 $self->{empty} = {};
3008 $self->{dir_prop} = {};
3009 $self->{file_prop} = {};
3010 $self->{absent_dir} = {};
3011 $self->{absent_file} = {};
3012 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3013 $self;
3014 }
3015
3016 sub set_path_strip {
3017 my ($self, $path) = @_;
3018 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3019 }
3020
3021 sub open_root {
3022 { path => '' };
3023 }
3024
3025 sub open_directory {
3026 my ($self, $path, $pb, $rev) = @_;
3027 { path => $path };
3028 }
3029
3030 sub git_path {
3031 my ($self, $path) = @_;
3032 if ($self->{path_strip}) {
3033 $path =~ s!$self->{path_strip}!! or
3034 die "Failed to strip path '$path' ($self->{path_strip})\n";
3035 }
3036 $path;
3037 }
3038
3039 sub delete_entry {
3040 my ($self, $path, $rev, $pb) = @_;
3041
3042 my $gpath = $self->git_path($path);
3043 return undef if ($gpath eq '');
3044
3045 # remove entire directories.
3046 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3047 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3048 -r --name-only -z/,
3049 $self->{c}, '--', $gpath);
3050 local $/ = "\0";
3051 while (<$ls>) {
3052 chomp;
3053 $self->{gii}->remove($_);
3054 print "\tD\t$_\n" unless $::_q;
3055 }
3056 print "\tD\t$gpath/\n" unless $::_q;
3057 command_close_pipe($ls, $ctx);
3058 $self->{empty}->{$path} = 0
3059 } else {
3060 $self->{gii}->remove($gpath);
3061 print "\tD\t$gpath\n" unless $::_q;
3062 }
3063 undef;
3064 }
3065
3066 sub open_file {
3067 my ($self, $path, $pb, $rev) = @_;
3068 my $gpath = $self->git_path($path);
3069 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3070 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3071 unless (defined $mode && defined $blob) {
3072 die "$path was not found in commit $self->{c} (r$rev)\n";
3073 }
3074 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3075 pool => SVN::Pool->new, action => 'M' };
3076 }
3077
3078 sub add_file {
3079 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3080 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3081 delete $self->{empty}->{$dir};
3082 { path => $path, mode_a => 100644, mode_b => 100644,
3083 pool => SVN::Pool->new, action => 'A' };
3084 }
3085
3086 sub add_directory {
3087 my ($self, $path, $cp_path, $cp_rev) = @_;
3088 my $gpath = $self->git_path($path);
3089 if ($gpath eq '') {
3090 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3091 -r --name-only -z/,
3092 $self->{c});
3093 local $/ = "\0";
3094 while (<$ls>) {
3095 chomp;
3096 $self->{gii}->remove($_);
3097 print "\tD\t$_\n" unless $::_q;
3098 }
3099 command_close_pipe($ls, $ctx);
3100 $self->{empty}->{$path} = 0;
3101 }
3102 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3103 delete $self->{empty}->{$dir};
3104 $self->{empty}->{$path} = 1;
3105 { path => $path };
3106 }
3107
3108 sub change_dir_prop {
3109 my ($self, $db, $prop, $value) = @_;
3110 $self->{dir_prop}->{$db->{path}} ||= {};
3111 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3112 undef;
3113 }
3114
3115 sub absent_directory {
3116 my ($self, $path, $pb) = @_;
3117 $self->{absent_dir}->{$pb->{path}} ||= [];
3118 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3119 undef;
3120 }
3121
3122 sub absent_file {
3123 my ($self, $path, $pb) = @_;
3124 $self->{absent_file}->{$pb->{path}} ||= [];
3125 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3126 undef;
3127 }
3128
3129 sub change_file_prop {
3130 my ($self, $fb, $prop, $value) = @_;
3131 if ($prop eq 'svn:executable') {
3132 if ($fb->{mode_b} != 120000) {
3133 $fb->{mode_b} = defined $value ? 100755 : 100644;
3134 }
3135 } elsif ($prop eq 'svn:special') {
3136 $fb->{mode_b} = defined $value ? 120000 : 100644;
3137 } else {
3138 $self->{file_prop}->{$fb->{path}} ||= {};
3139 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3140 }
3141 undef;
3142 }
3143
3144 sub apply_textdelta {
3145 my ($self, $fb, $exp) = @_;
3146 my $fh = IO::File->new_tmpfile;
3147 $fh->autoflush(1);
3148 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3149 # (but $base does not,) so dup() it for reading in close_file
3150 open my $dup, '<&', $fh or croak $!;
3151 my $base = IO::File->new_tmpfile;
3152 $base->autoflush(1);
3153 if ($fb->{blob}) {
3154 defined (my $pid = fork) or croak $!;
3155 if (!$pid) {
3156 open STDOUT, '>&', $base or croak $!;
3157 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3158 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3159 }
3160 waitpid $pid, 0;
3161 croak $? if $?;
3162
3163 if (defined $exp) {
3164 seek $base, 0, 0 or croak $!;
3165 my $got = ::md5sum($base);
3166 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3167 "expected: $exp\n",
3168 " got: $got\n" if ($got ne $exp);
3169 }
3170 }
3171 seek $base, 0, 0 or croak $!;
3172 $fb->{fh} = $dup;
3173 $fb->{base} = $base;
3174 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3175 }
3176
3177 sub close_file {
3178 my ($self, $fb, $exp) = @_;
3179 my $hash;
3180 my $path = $self->git_path($fb->{path});
3181 if (my $fh = $fb->{fh}) {
3182 if (defined $exp) {
3183 seek($fh, 0, 0) or croak $!;
3184 my $got = ::md5sum($fh);
3185 if ($got ne $exp) {
3186 die "Checksum mismatch: $path\n",
3187 "expected: $exp\n got: $got\n";
3188 }
3189 }
3190 sysseek($fh, 0, 0) or croak $!;
3191 if ($fb->{mode_b} == 120000) {
3192 eval {
3193 sysread($fh, my $buf, 5) == 5 or croak $!;
3194 $buf eq 'link ' or die "$path has mode 120000",
3195 " but is not a link";
3196 };
3197 if ($@) {
3198 warn "$@\n";
3199 sysseek($fh, 0, 0) or croak $!;
3200 }
3201 }
3202 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3203 if (!$pid) {
3204 open STDIN, '<&', $fh or croak $!;
3205 exec qw/git-hash-object -w --stdin/ or croak $!;
3206 }
3207 chomp($hash = do { local $/; <$out> });
3208 close $out or croak $!;
3209 close $fh or croak $!;
3210 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3211 close $fb->{base} or croak $!;
3212 } else {
3213 $hash = $fb->{blob} or die "no blob information\n";
3214 }
3215 $fb->{pool}->clear;
3216 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3217 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3218 undef;
3219 }
3220
3221 sub abort_edit {
3222 my $self = shift;
3223 $self->{nr} = $self->{gii}->{nr};
3224 delete $self->{gii};
3225 $self->SUPER::abort_edit(@_);
3226 }
3227
3228 sub close_edit {
3229 my $self = shift;
3230 $self->{git_commit_ok} = 1;
3231 $self->{nr} = $self->{gii}->{nr};
3232 delete $self->{gii};
3233 $self->SUPER::close_edit(@_);
3234 }
3235
3236 package SVN::Git::Editor;
3237 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3238 use strict;
3239 use warnings;
3240 use Carp qw/croak/;
3241 use IO::File;
3242
3243 sub new {
3244 my ($class, $opts) = @_;
3245 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3246 die "$_ required!\n" unless (defined $opts->{$_});
3247 }
3248
3249 my $pool = SVN::Pool->new;
3250 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3251 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3252 $opts->{r}, $mods);
3253
3254 # $opts->{ra} functions should not be used after this:
3255 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3256 $opts->{editor_cb}, $pool);
3257 my $self = SVN::Delta::Editor->new(@ce, $pool);
3258 bless $self, $class;
3259 foreach (qw/svn_path r tree_a tree_b/) {
3260 $self->{$_} = $opts->{$_};
3261 }
3262 $self->{url} = $opts->{ra}->{url};
3263 $self->{mods} = $mods;
3264 $self->{types} = $types;
3265 $self->{pool} = $pool;
3266 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3267 $self->{rm} = { };
3268 $self->{path_prefix} = length $self->{svn_path} ?
3269 "$self->{svn_path}/" : '';
3270 return $self;
3271 }
3272
3273 sub generate_diff {
3274 my ($tree_a, $tree_b) = @_;
3275 my @diff_tree = qw(diff-tree -z -r);
3276 if ($_cp_similarity) {
3277 push @diff_tree, "-C$_cp_similarity";
3278 } else {
3279 push @diff_tree, '-C';
3280 }
3281 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3282 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3283 push @diff_tree, $tree_a, $tree_b;
3284 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3285 local $/ = "\0";
3286 my $state = 'meta';
3287 my @mods;
3288 while (<$diff_fh>) {
3289 chomp $_; # this gets rid of the trailing "\0"
3290 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3291 $::sha1\s($::sha1)\s
3292 ([MTCRAD])\d*$/xo) {
3293 push @mods, { mode_a => $1, mode_b => $2,
3294 sha1_b => $3, chg => $4 };
3295 if ($4 =~ /^(?:C|R)$/) {
3296 $state = 'file_a';
3297 } else {
3298 $state = 'file_b';
3299 }
3300 } elsif ($state eq 'file_a') {
3301 my $x = $mods[$#mods] or croak "Empty array\n";
3302 if ($x->{chg} !~ /^(?:C|R)$/) {
3303 croak "Error parsing $_, $x->{chg}\n";
3304 }
3305 $x->{file_a} = $_;
3306 $state = 'file_b';
3307 } elsif ($state eq 'file_b') {
3308 my $x = $mods[$#mods] or croak "Empty array\n";
3309 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3310 croak "Error parsing $_, $x->{chg}\n";
3311 }
3312 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3313 croak "Error parsing $_, $x->{chg}\n";
3314 }
3315 $x->{file_b} = $_;
3316 $state = 'meta';
3317 } else {
3318 croak "Error parsing $_\n";
3319 }
3320 }
3321 command_close_pipe($diff_fh, $ctx);
3322 \@mods;
3323 }
3324
3325 sub check_diff_paths {
3326 my ($ra, $pfx, $rev, $mods) = @_;
3327 my %types;
3328 $pfx .= '/' if length $pfx;
3329
3330 sub type_diff_paths {
3331 my ($ra, $types, $path, $rev) = @_;
3332 my @p = split m#/+#, $path;
3333 my $c = shift @p;
3334 unless (defined $types->{$c}) {
3335 $types->{$c} = $ra->check_path($c, $rev);
3336 }
3337 while (@p) {
3338 $c .= '/' . shift @p;
3339 next if defined $types->{$c};
3340 $types->{$c} = $ra->check_path($c, $rev);
3341 }
3342 }
3343
3344 foreach my $m (@$mods) {
3345 foreach my $f (qw/file_a file_b/) {
3346 next unless defined $m->{$f};
3347 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3348 if (length $pfx.$dir && ! defined $types{$dir}) {
3349 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3350 }
3351 }
3352 }
3353 \%types;
3354 }
3355
3356 sub split_path {
3357 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3358 }
3359
3360 sub repo_path {
3361 my ($self, $path) = @_;
3362 $self->{path_prefix}.(defined $path ? $path : '');
3363 }
3364
3365 sub url_path {
3366 my ($self, $path) = @_;
3367 if ($self->{url} =~ m#^https?://#) {
3368 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3369 }
3370 $self->{url} . '/' . $self->repo_path($path);
3371 }
3372
3373 sub rmdirs {
3374 my ($self) = @_;
3375 my $rm = $self->{rm};
3376 delete $rm->{''}; # we never delete the url we're tracking
3377 return unless %$rm;
3378
3379 foreach (keys %$rm) {
3380 my @d = split m#/#, $_;
3381 my $c = shift @d;
3382 $rm->{$c} = 1;
3383 while (@d) {
3384 $c .= '/' . shift @d;
3385 $rm->{$c} = 1;
3386 }
3387 }
3388 delete $rm->{$self->{svn_path}};
3389 delete $rm->{''}; # we never delete the url we're tracking
3390 return unless %$rm;
3391
3392 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3393 $self->{tree_b});
3394 local $/ = "\0";
3395 while (<$fh>) {
3396 chomp;
3397 my @dn = split m#/#, $_;
3398 while (pop @dn) {
3399 delete $rm->{join '/', @dn};
3400 }
3401 unless (%$rm) {
3402 close $fh;
3403 return;
3404 }
3405 }
3406 command_close_pipe($fh, $ctx);
3407
3408 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3409 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3410 $self->close_directory($bat->{$d}, $p);
3411 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3412 print "\tD+\t$d/\n" unless $::_q;
3413 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3414 delete $bat->{$d};
3415 }
3416 }
3417
3418 sub open_or_add_dir {
3419 my ($self, $full_path, $baton) = @_;
3420 my $t = $self->{types}->{$full_path};
3421 if (!defined $t) {
3422 die "$full_path not known in r$self->{r} or we have a bug!\n";
3423 }
3424 {
3425 no warnings 'once';
3426 # SVN::Node::none and SVN::Node::file are used only once,
3427 # so we're shutting up Perl's warnings about them.
3428 if ($t == $SVN::Node::none) {
3429 return $self->add_directory($full_path, $baton,
3430 undef, -1, $self->{pool});
3431 } elsif ($t == $SVN::Node::dir) {
3432 return $self->open_directory($full_path, $baton,
3433 $self->{r}, $self->{pool});
3434 } # no warnings 'once'
3435 print STDERR "$full_path already exists in repository at ",
3436 "r$self->{r} and it is not a directory (",
3437 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3438 } # no warnings 'once'
3439 exit 1;
3440 }
3441
3442 sub ensure_path {
3443 my ($self, $path) = @_;
3444 my $bat = $self->{bat};
3445 my $repo_path = $self->repo_path($path);
3446 return $bat->{''} unless (length $repo_path);
3447 my @p = split m#/+#, $repo_path;
3448 my $c = shift @p;
3449 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3450 while (@p) {
3451 my $c0 = $c;
3452 $c .= '/' . shift @p;
3453 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3454 }
3455 return $bat->{$c};
3456 }
3457
3458 sub A {
3459 my ($self, $m) = @_;
3460 my ($dir, $file) = split_path($m->{file_b});
3461 my $pbat = $self->ensure_path($dir);
3462 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3463 undef, -1);
3464 print "\tA\t$m->{file_b}\n" unless $::_q;
3465 $self->chg_file($fbat, $m);
3466 $self->close_file($fbat,undef,$self->{pool});
3467 }
3468
3469 sub C {
3470 my ($self, $m) = @_;
3471 my ($dir, $file) = split_path($m->{file_b});
3472 my $pbat = $self->ensure_path($dir);
3473 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3474 $self->url_path($m->{file_a}), $self->{r});
3475 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3476 $self->chg_file($fbat, $m);
3477 $self->close_file($fbat,undef,$self->{pool});
3478 }
3479
3480 sub delete_entry {
3481 my ($self, $path, $pbat) = @_;
3482 my $rpath = $self->repo_path($path);
3483 my ($dir, $file) = split_path($rpath);
3484 $self->{rm}->{$dir} = 1;
3485 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3486 }
3487
3488 sub R {
3489 my ($self, $m) = @_;
3490 my ($dir, $file) = split_path($m->{file_b});
3491 my $pbat = $self->ensure_path($dir);
3492 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3493 $self->url_path($m->{file_a}), $self->{r});
3494 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3495 $self->chg_file($fbat, $m);
3496 $self->close_file($fbat,undef,$self->{pool});
3497
3498 ($dir, $file) = split_path($m->{file_a});
3499 $pbat = $self->ensure_path($dir);
3500 $self->delete_entry($m->{file_a}, $pbat);
3501 }
3502
3503 sub M {
3504 my ($self, $m) = @_;
3505 my ($dir, $file) = split_path($m->{file_b});
3506 my $pbat = $self->ensure_path($dir);
3507 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3508 $pbat,$self->{r},$self->{pool});
3509 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3510 $self->chg_file($fbat, $m);
3511 $self->close_file($fbat,undef,$self->{pool});
3512 }
3513
3514 sub T { shift->M(@_) }
3515
3516 sub change_file_prop {
3517 my ($self, $fbat, $pname, $pval) = @_;
3518 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3519 }
3520
3521 sub chg_file {
3522 my ($self, $fbat, $m) = @_;
3523 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3524 $self->change_file_prop($fbat,'svn:executable','*');
3525 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3526 $self->change_file_prop($fbat,'svn:executable',undef);
3527 }
3528 my $fh = IO::File->new_tmpfile or croak $!;
3529 if ($m->{mode_b} =~ /^120/) {
3530 print $fh 'link ' or croak $!;
3531 $self->change_file_prop($fbat,'svn:special','*');
3532 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3533 $self->change_file_prop($fbat,'svn:special',undef);
3534 }
3535 defined(my $pid = fork) or croak $!;
3536 if (!$pid) {
3537 open STDOUT, '>&', $fh or croak $!;
3538 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3539 }
3540 waitpid $pid, 0;
3541 croak $? if $?;
3542 $fh->flush == 0 or croak $!;
3543 seek $fh, 0, 0 or croak $!;
3544
3545 my $exp = ::md5sum($fh);
3546 seek $fh, 0, 0 or croak $!;
3547
3548 my $pool = SVN::Pool->new;
3549 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3550 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3551 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3552 $pool->clear;
3553
3554 close $fh or croak $!;
3555 }
3556
3557 sub D {
3558 my ($self, $m) = @_;
3559 my ($dir, $file) = split_path($m->{file_b});
3560 my $pbat = $self->ensure_path($dir);
3561 print "\tD\t$m->{file_b}\n" unless $::_q;
3562 $self->delete_entry($m->{file_b}, $pbat);
3563 }
3564
3565 sub close_edit {
3566 my ($self) = @_;
3567 my ($p,$bat) = ($self->{pool}, $self->{bat});
3568 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3569 next if $_ eq '';
3570 $self->close_directory($bat->{$_}, $p);
3571 }
3572 $self->close_directory($bat->{''}, $p);
3573 $self->SUPER::close_edit($p);
3574 $p->clear;
3575 }
3576
3577 sub abort_edit {
3578 my ($self) = @_;
3579 $self->SUPER::abort_edit($self->{pool});
3580 }
3581
3582 sub DESTROY {
3583 my $self = shift;
3584 $self->SUPER::DESTROY(@_);
3585 $self->{pool}->clear;
3586 }
3587
3588 # this drives the editor
3589 sub apply_diff {
3590 my ($self) = @_;
3591 my $mods = $self->{mods};
3592 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3593 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3594 my $f = $m->{chg};
3595 if (defined $o{$f}) {
3596 $self->$f($m);
3597 } else {
3598 fatal("Invalid change type: $f");
3599 }
3600 }
3601 $self->rmdirs if $_rmdir;
3602 if (@$mods == 0) {
3603 $self->abort_edit;
3604 } else {
3605 $self->close_edit;
3606 }
3607 return scalar @$mods;
3608 }
3609
3610 package Git::SVN::Ra;
3611 use vars qw/@ISA $config_dir $_log_window_size/;
3612 use strict;
3613 use warnings;
3614 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3615
3616 BEGIN {
3617 # enforce temporary pool usage for some simple functions
3618 no strict 'refs';
3619 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3620 my $SUPER = "SUPER::$f";
3621 *$f = sub {
3622 my $self = shift;
3623 my $pool = SVN::Pool->new;
3624 my @ret = $self->$SUPER(@_,$pool);
3625 $pool->clear;
3626 wantarray ? @ret : $ret[0];
3627 };
3628 }
3629 }
3630
3631 sub _auth_providers () {
3632 [
3633 SVN::Client::get_simple_provider(),
3634 SVN::Client::get_ssl_server_trust_file_provider(),
3635 SVN::Client::get_simple_prompt_provider(
3636 \&Git::SVN::Prompt::simple, 2),
3637 SVN::Client::get_ssl_client_cert_file_provider(),
3638 SVN::Client::get_ssl_client_cert_prompt_provider(
3639 \&Git::SVN::Prompt::ssl_client_cert, 2),
3640 SVN::Client::get_ssl_client_cert_pw_file_provider(),
3641 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3642 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3643 SVN::Client::get_username_provider(),
3644 SVN::Client::get_ssl_server_trust_prompt_provider(
3645 \&Git::SVN::Prompt::ssl_server_trust),
3646 SVN::Client::get_username_prompt_provider(
3647 \&Git::SVN::Prompt::username, 2)
3648 ]
3649 }
3650
3651 sub escape_uri_only {
3652 my ($uri) = @_;
3653 my @tmp;
3654 foreach (split m{/}, $uri) {
3655 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3656 push @tmp, $_;
3657 }
3658 join('/', @tmp);
3659 }
3660
3661 sub escape_url {
3662 my ($url) = @_;
3663 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3664 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3665 $url = "$scheme://$domain$uri";
3666 }
3667 $url;
3668 }
3669
3670 sub new {
3671 my ($class, $url) = @_;
3672 $url =~ s!/+$!!;
3673 return $RA if ($RA && $RA->{url} eq $url);
3674
3675 SVN::_Core::svn_config_ensure($config_dir, undef);
3676 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3677 my $config = SVN::Core::config_get_config($config_dir);
3678 $RA = undef;
3679 my $dont_store_passwords = 1;
3680 my $conf_t = ${$config}{'config'};
3681 {
3682 no warnings 'once';
3683 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3684 # produces warnings that variables are used only once.
3685 # I had not found the better way to shut them up, so
3686 # the warnings of type 'once' are disabled in this block.
3687 if (SVN::_Core::svn_config_get_bool($conf_t,
3688 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3689 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3690 1) == 0) {
3691 SVN::_Core::svn_auth_set_parameter($baton,
3692 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3693 bless (\$dont_store_passwords, "_p_void"));
3694 }
3695 if (SVN::_Core::svn_config_get_bool($conf_t,
3696 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3697 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3698 1) == 0) {
3699 $Git::SVN::Prompt::_no_auth_cache = 1;
3700 }
3701 } # no warnings 'once'
3702 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3703 config => $config,
3704 pool => SVN::Pool->new,
3705 auth_provider_callbacks => $callbacks);
3706 $self->{url} = $url;
3707 $self->{svn_path} = $url;
3708 $self->{repos_root} = $self->get_repos_root;
3709 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3710 $self->{cache} = { check_path => { r => 0, data => {} },
3711 get_dir => { r => 0, data => {} } };
3712 $RA = bless $self, $class;
3713 }
3714
3715 sub check_path {
3716 my ($self, $path, $r) = @_;
3717 my $cache = $self->{cache}->{check_path};
3718 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3719 return $cache->{data}->{$path};
3720 }
3721 my $pool = SVN::Pool->new;
3722 my $t = $self->SUPER::check_path($path, $r, $pool);
3723 $pool->clear;
3724 if ($r != $cache->{r}) {
3725 %{$cache->{data}} = ();
3726 $cache->{r} = $r;
3727 }
3728 $cache->{data}->{$path} = $t;
3729 }
3730
3731 sub get_dir {
3732 my ($self, $dir, $r) = @_;
3733 my $cache = $self->{cache}->{get_dir};
3734 if ($r == $cache->{r}) {
3735 if (my $x = $cache->{data}->{$dir}) {
3736 return wantarray ? @$x : $x->[0];
3737 }
3738 }
3739 my $pool = SVN::Pool->new;
3740 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3741 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3742 $pool->clear;
3743 if ($r != $cache->{r}) {
3744 %{$cache->{data}} = ();
3745 $cache->{r} = $r;
3746 }
3747 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3748 wantarray ? (\%dirents, $r, $props) : \%dirents;
3749 }
3750
3751 sub DESTROY {
3752 # do not call the real DESTROY since we store ourselves in $RA
3753 }
3754
3755 sub get_log {
3756 my ($self, @args) = @_;
3757 my $pool = SVN::Pool->new;
3758 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3759 my $ret = $self->SUPER::get_log(@args, $pool);
3760 $pool->clear;
3761 $ret;
3762 }
3763
3764 sub trees_match {
3765 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3766 my $ctx = SVN::Client->new(auth => _auth_providers);
3767 my $out = IO::File->new_tmpfile;
3768
3769 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3770 # $ctx->diff(), so we'll create a default one
3771 my $pool = SVN::Pool->new_default_sub;
3772
3773 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3774 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3775 $out->flush;
3776 my $ret = (($out->stat)[7] == 0);
3777 close $out or croak $!;
3778
3779 $ret;
3780 }
3781
3782 sub get_commit_editor {
3783 my ($self, $log, $cb, $pool) = @_;
3784 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3785 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3786 }
3787
3788 sub gs_do_update {
3789 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3790 my $new = ($rev_a == $rev_b);
3791 my $path = $gs->{path};
3792
3793 if ($new && -e $gs->{index}) {
3794 unlink $gs->{index} or die
3795 "Couldn't unlink index: $gs->{index}: $!\n";
3796 }
3797 my $pool = SVN::Pool->new;
3798 $editor->set_path_strip($path);
3799 my (@pc) = split m#/#, $path;
3800 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3801 1, $editor, $pool);
3802 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3803
3804 # Since we can't rely on svn_ra_reparent being available, we'll
3805 # just have to do some magic with set_path to make it so
3806 # we only want a partial path.
3807 my $sp = '';
3808 my $final = join('/', @pc);
3809 while (@pc) {
3810 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3811 $sp .= '/' if length $sp;
3812 $sp .= shift @pc;
3813 }
3814 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3815
3816 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3817
3818 $reporter->finish_report($pool);
3819 $pool->clear;
3820 $editor->{git_commit_ok};
3821 }
3822
3823 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3824 # svn_ra_reparent didn't work before 1.4)
3825 sub gs_do_switch {
3826 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3827 my $path = $gs->{path};
3828 my $pool = SVN::Pool->new;
3829
3830 my $full_url = $self->{url};
3831 my $old_url = $full_url;
3832 $full_url .= '/' . escape_uri_only($path) if length $path;
3833 my ($ra, $reparented);
3834 if ($old_url ne $full_url) {
3835 if ($old_url !~ m#^svn(\+ssh)?://#) {
3836 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3837 $pool);
3838 $self->{url} = $full_url;
3839 $reparented = 1;
3840 } else {
3841 $_[0] = undef;
3842 $self = undef;
3843 $RA = undef;
3844 $ra = Git::SVN::Ra->new($full_url);
3845 $ra_invalid = 1;
3846 }
3847 }
3848 $ra ||= $self;
3849 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3850 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3851 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3852 $reporter->finish_report($pool);
3853
3854 if ($reparented) {
3855 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3856 $self->{url} = $old_url;
3857 }
3858
3859 $pool->clear;
3860 $editor->{git_commit_ok};
3861 }
3862
3863 sub longest_common_path {
3864 my ($gsv, $globs) = @_;
3865 my %common;
3866 my $common_max = scalar @$gsv;
3867
3868 foreach my $gs (@$gsv) {
3869 my @tmp = split m#/#, $gs->{path};
3870 my $p = '';
3871 foreach (@tmp) {
3872 $p .= length($p) ? "/$_" : $_;
3873 $common{$p} ||= 0;
3874 $common{$p}++;
3875 }
3876 }
3877 $globs ||= [];
3878 $common_max += scalar @$globs;
3879 foreach my $glob (@$globs) {
3880 my @tmp = split m#/#, $glob->{path}->{left};
3881 my $p = '';
3882 foreach (@tmp) {
3883 $p .= length($p) ? "/$_" : $_;
3884 $common{$p} ||= 0;
3885 $common{$p}++;
3886 }
3887 }
3888
3889 my $longest_path = '';
3890 foreach (sort {length $b <=> length $a} keys %common) {
3891 if ($common{$_} == $common_max) {
3892 $longest_path = $_;
3893 last;
3894 }
3895 }
3896 $longest_path;
3897 }
3898
3899 sub gs_fetch_loop_common {
3900 my ($self, $base, $head, $gsv, $globs) = @_;
3901 return if ($base > $head);
3902 my $inc = $_log_window_size;
3903 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3904 my $longest_path = longest_common_path($gsv, $globs);
3905 my $ra_url = $self->{url};
3906 while (1) {
3907 my %revs;
3908 my $err;
3909 my $err_handler = $SVN::Error::handler;
3910 $SVN::Error::handler = sub {
3911 ($err) = @_;
3912 skip_unknown_revs($err);
3913 };
3914 sub _cb {
3915 my ($paths, $r, $author, $date, $log) = @_;
3916 [ dup_changed_paths($paths),
3917 { author => $author, date => $date, log => $log } ];
3918 }
3919 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3920 sub { $revs{$_[1]} = _cb(@_) });
3921 if ($err && $max >= $head) {
3922 print STDERR "Path '$longest_path' ",
3923 "was probably deleted:\n",
3924 $err->expanded_message,
3925 "\nWill attempt to follow ",
3926 "revisions r$min .. r$max ",
3927 "committed before the deletion\n";
3928 my $hi = $max;
3929 while (--$hi >= $min) {
3930 my $ok;
3931 $self->get_log([$longest_path], $min, $hi,
3932 0, 1, 1, sub {
3933 $ok ||= $_[1];
3934 $revs{$_[1]} = _cb(@_) });
3935 if ($ok) {
3936 print STDERR "r$min .. r$ok OK\n";
3937 last;
3938 }
3939 }
3940 }
3941 $SVN::Error::handler = $err_handler;
3942
3943 my %exists = map { $_->{path} => $_ } @$gsv;
3944 foreach my $r (sort {$a <=> $b} keys %revs) {
3945 my ($paths, $logged) = @{$revs{$r}};
3946
3947 foreach my $gs ($self->match_globs(\%exists, $paths,
3948 $globs, $r)) {
3949 if ($gs->rev_map_max >= $r) {
3950 next;
3951 }
3952 next unless $gs->match_paths($paths, $r);
3953 $gs->{logged_rev_props} = $logged;
3954 if (my $last_commit = $gs->last_commit) {
3955 $gs->assert_index_clean($last_commit);
3956 }
3957 my $log_entry = $gs->do_fetch($paths, $r);
3958 if ($log_entry) {
3959 $gs->do_git_commit($log_entry);
3960 }
3961 $INDEX_FILES{$gs->{index}} = 1;
3962 }
3963 foreach my $g (@$globs) {
3964 my $k = "svn-remote.$g->{remote}." .
3965 "$g->{t}-maxRev";
3966 Git::SVN::tmp_config($k, $r);
3967 }
3968 if ($ra_invalid) {
3969 $_[0] = undef;
3970 $self = undef;
3971 $RA = undef;
3972 $self = Git::SVN::Ra->new($ra_url);
3973 $ra_invalid = undef;
3974 }
3975 }
3976 # pre-fill the .rev_db since it'll eventually get filled in
3977 # with '0' x40 if something new gets committed
3978 foreach my $gs (@$gsv) {
3979 next if $gs->rev_map_max >= $max;
3980 next if defined $gs->rev_map_get($max);
3981 $gs->rev_map_set($max, 0 x40);
3982 }
3983 foreach my $g (@$globs) {
3984 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3985 Git::SVN::tmp_config($k, $max);
3986 }
3987 last if $max >= $head;
3988 $min = $max + 1;
3989 $max += $inc;
3990 $max = $head if ($max > $head);
3991 }
3992 }
3993
3994 sub match_globs {
3995 my ($self, $exists, $paths, $globs, $r) = @_;
3996
3997 sub get_dir_check {
3998 my ($self, $exists, $g, $r) = @_;
3999 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4000 return unless scalar @x == 3;
4001 my $dirents = $x[0];
4002 foreach my $de (keys %$dirents) {
4003 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4004 my $p = $g->{path}->full_path($de);
4005 next if $exists->{$p};
4006 next if (length $g->{path}->{right} &&
4007 ($self->check_path($p, $r) !=
4008 $SVN::Node::dir));
4009 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4010 $g->{ref}->full_path($de), 1);
4011 }
4012 }
4013 foreach my $g (@$globs) {
4014 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4015 if ($path->{action} =~ /^[AR]$/) {
4016 get_dir_check($self, $exists, $g, $r);
4017 }
4018 }
4019 foreach (keys %$paths) {
4020 if (/$g->{path}->{left_regex}/ &&
4021 !/$g->{path}->{regex}/) {
4022 next if $paths->{$_}->{action} !~ /^[AR]$/;
4023 get_dir_check($self, $exists, $g, $r);
4024 }
4025 next unless /$g->{path}->{regex}/;
4026 my $p = $1;
4027 my $pathname = $g->{path}->full_path($p);
4028 next if $exists->{$pathname};
4029 next if ($self->check_path($pathname, $r) !=
4030 $SVN::Node::dir);
4031 $exists->{$pathname} = Git::SVN->init(
4032 $self->{url}, $pathname, undef,
4033 $g->{ref}->full_path($p), 1);
4034 }
4035 my $c = '';
4036 foreach (split m#/#, $g->{path}->{left}) {
4037 $c .= "/$_";
4038 next unless ($paths->{$c} &&
4039 ($paths->{$c}->{action} =~ /^[AR]$/));
4040 get_dir_check($self, $exists, $g, $r);
4041 }
4042 }
4043 values %$exists;
4044 }
4045
4046 sub minimize_url {
4047 my ($self) = @_;
4048 return $self->{url} if ($self->{url} eq $self->{repos_root});
4049 my $url = $self->{repos_root};
4050 my @components = split(m!/!, $self->{svn_path});
4051 my $c = '';
4052 do {
4053 $url .= "/$c" if length $c;
4054 eval { (ref $self)->new($url)->get_latest_revnum };
4055 } while ($@ && ($c = shift @components));
4056 $url;
4057 }
4058
4059 sub can_do_switch {
4060 my $self = shift;
4061 unless (defined $can_do_switch) {
4062 my $pool = SVN::Pool->new;
4063 my $rep = eval {
4064 $self->do_switch(1, '', 0, $self->{url},
4065 SVN::Delta::Editor->new, $pool);
4066 };
4067 if ($@) {
4068 $can_do_switch = 0;
4069 } else {
4070 $rep->abort_report($pool);
4071 $can_do_switch = 1;
4072 }
4073 $pool->clear;
4074 }
4075 $can_do_switch;
4076 }
4077
4078 sub skip_unknown_revs {
4079 my ($err) = @_;
4080 my $errno = $err->apr_err();
4081 # Maybe the branch we're tracking didn't
4082 # exist when the repo started, so it's
4083 # not an error if it doesn't, just continue
4084 #
4085 # Wonderfully consistent library, eh?
4086 # 160013 - svn:// and file://
4087 # 175002 - http(s)://
4088 # 175007 - http(s):// (this repo required authorization, too...)
4089 # More codes may be discovered later...
4090 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4091 my $err_key = $err->expanded_message;
4092 # revision numbers change every time, filter them out
4093 $err_key =~ s/\d+/\0/g;
4094 $err_key = "$errno\0$err_key";
4095 unless ($ignored_err{$err_key}) {
4096 warn "W: Ignoring error from SVN, path probably ",
4097 "does not exist: ($errno): ",
4098 $err->expanded_message,"\n";
4099 warn "W: Do not be alarmed at the above message ",
4100 "git-svn is just searching aggressively for ",
4101 "old history.\n",
4102 "This may take a while on large repositories\n";
4103 $ignored_err{$err_key} = 1;
4104 }
4105 return;
4106 }
4107 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4108 }
4109
4110 # svn_log_changed_path_t objects passed to get_log are likely to be
4111 # overwritten even if only the refs are copied to an external variable,
4112 # so we should dup the structures in their entirety. Using an externally
4113 # passed pool (instead of our temporary and quickly cleared pool in
4114 # Git::SVN::Ra) does not help matters at all...
4115 sub dup_changed_paths {
4116 my ($paths) = @_;
4117 return undef unless $paths;
4118 my %ret;
4119 foreach my $p (keys %$paths) {
4120 my $i = $paths->{$p};
4121 my %s = map { $_ => $i->$_ }
4122 qw/copyfrom_path copyfrom_rev action/;
4123 $ret{$p} = \%s;
4124 }
4125 \%ret;
4126 }
4127
4128 package Git::SVN::Log;
4129 use strict;
4130 use warnings;
4131 use POSIX qw/strftime/;
4132 use constant commit_log_separator => ('-' x 72) . "\n";
4133 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4134 %rusers $show_commit $incremental/;
4135 my $l_fmt;
4136
4137 sub cmt_showable {
4138 my ($c) = @_;
4139 return 1 if defined $c->{r};
4140
4141 # big commit message got truncated by the 16k pretty buffer in rev-list
4142 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4143 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4144 @{$c->{l}} = ();
4145 my @log = command(qw/cat-file commit/, $c->{c});
4146
4147 # shift off the headers
4148 shift @log while ($log[0] ne '');
4149 shift @log;
4150
4151 # TODO: make $c->{l} not have a trailing newline in the future
4152 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4153
4154 (undef, $c->{r}, undef) = ::extract_metadata(
4155 (grep(/^git-svn-id: /, @log))[-1]);
4156 }
4157 return defined $c->{r};
4158 }
4159
4160 sub log_use_color {
4161 return $color || Git->repository->get_colorbool('color.diff');
4162 }
4163
4164 sub git_svn_log_cmd {
4165 my ($r_min, $r_max, @args) = @_;
4166 my $head = 'HEAD';
4167 my (@files, @log_opts);
4168 foreach my $x (@args) {
4169 if ($x eq '--' || @files) {
4170 push @files, $x;
4171 } else {
4172 if (::verify_ref("$x^0")) {
4173 $head = $x;
4174 } else {
4175 push @log_opts, $x;
4176 }
4177 }
4178 }
4179
4180 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4181 $gs ||= Git::SVN->_new;
4182 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4183 $gs->refname);
4184 push @cmd, '-r' unless $non_recursive;
4185 push @cmd, qw/--raw --name-status/ if $verbose;
4186 push @cmd, '--color' if log_use_color();
4187 push @cmd, @log_opts;
4188 if (defined $r_max && $r_max == $r_min) {
4189 push @cmd, '--max-count=1';
4190 if (my $c = $gs->rev_map_get($r_max)) {
4191 push @cmd, $c;
4192 }
4193 } elsif (defined $r_max) {
4194 if ($r_max < $r_min) {
4195 ($r_min, $r_max) = ($r_max, $r_min);
4196 }
4197 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4198 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4199 # If there are no commits in the range, both $c_max and $c_min
4200 # will be undefined. If there is at least 1 commit in the
4201 # range, both will be defined.
4202 return () if !defined $c_min || !defined $c_max;
4203 if ($c_min eq $c_max) {
4204 push @cmd, '--max-count=1', $c_min;
4205 } else {
4206 push @cmd, '--boundary', "$c_min..$c_max";
4207 }
4208 }
4209 return (@cmd, @files);
4210 }
4211
4212 # adapted from pager.c
4213 sub config_pager {
4214 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4215 if (!defined $pager) {
4216 $pager = 'less';
4217 } elsif (length $pager == 0 || $pager eq 'cat') {
4218 $pager = undef;
4219 }
4220 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4221 }
4222
4223 sub run_pager {
4224 return unless -t *STDOUT && defined $pager;
4225 pipe my $rfd, my $wfd or return;
4226 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4227 if (!$pid) {
4228 open STDOUT, '>&', $wfd or
4229 ::fatal "Can't redirect to stdout: $!";
4230 return;
4231 }
4232 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4233 $ENV{LESS} ||= 'FRSX';
4234 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4235 }
4236
4237 sub format_svn_date {
4238 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4239 }
4240
4241 sub parse_git_date {
4242 my ($t, $tz) = @_;
4243 # Date::Parse isn't in the standard Perl distro :(
4244 if ($tz =~ s/^\+//) {
4245 $t += tz_to_s_offset($tz);
4246 } elsif ($tz =~ s/^\-//) {
4247 $t -= tz_to_s_offset($tz);
4248 }
4249 return $t;
4250 }
4251
4252 sub set_local_timezone {
4253 if (defined $TZ) {
4254 $ENV{TZ} = $TZ;
4255 } else {
4256 delete $ENV{TZ};
4257 }
4258 }
4259
4260 sub tz_to_s_offset {
4261 my ($tz) = @_;
4262 $tz =~ s/(\d\d)$//;
4263 return ($1 * 60) + ($tz * 3600);
4264 }
4265
4266 sub get_author_info {
4267 my ($dest, $author, $t, $tz) = @_;
4268 $author =~ s/(?:^\s*|\s*$)//g;
4269 $dest->{a_raw} = $author;
4270 my $au;
4271 if ($::_authors) {
4272 $au = $rusers{$author} || undef;
4273 }
4274 if (!$au) {
4275 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4276 }
4277 $dest->{t} = $t;
4278 $dest->{tz} = $tz;
4279 $dest->{a} = $au;
4280 $dest->{t_utc} = parse_git_date($t, $tz);
4281 }
4282
4283 sub process_commit {
4284 my ($c, $r_min, $r_max, $defer) = @_;
4285 if (defined $r_min && defined $r_max) {
4286 if ($r_min == $c->{r} && $r_min == $r_max) {
4287 show_commit($c);
4288 return 0;
4289 }
4290 return 1 if $r_min == $r_max;
4291 if ($r_min < $r_max) {
4292 # we need to reverse the print order
4293 return 0 if (defined $limit && --$limit < 0);
4294 push @$defer, $c;
4295 return 1;
4296 }
4297 if ($r_min != $r_max) {
4298 return 1 if ($r_min < $c->{r});
4299 return 1 if ($r_max > $c->{r});
4300 }
4301 }
4302 return 0 if (defined $limit && --$limit < 0);
4303 show_commit($c);
4304 return 1;
4305 }
4306
4307 sub show_commit {
4308 my $c = shift;
4309 if ($oneline) {
4310 my $x = "\n";
4311 if (my $l = $c->{l}) {
4312 while ($l->[0] =~ /^\s*$/) { shift @$l }
4313 $x = $l->[0];
4314 }
4315 $l_fmt ||= 'A' . length($c->{r});
4316 print 'r',pack($l_fmt, $c->{r}),' | ';
4317 print "$c->{c} | " if $show_commit;
4318 print $x;
4319 } else {
4320 show_commit_normal($c);
4321 }
4322 }
4323
4324 sub show_commit_changed_paths {
4325 my ($c) = @_;
4326 return unless $c->{changed};
4327 print "Changed paths:\n", @{$c->{changed}};
4328 }
4329
4330 sub show_commit_normal {
4331 my ($c) = @_;
4332 print commit_log_separator, "r$c->{r} | ";
4333 print "$c->{c} | " if $show_commit;
4334 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4335 my $nr_line = 0;
4336
4337 if (my $l = $c->{l}) {
4338 while ($l->[$#$l] eq "\n" && $#$l > 0
4339 && $l->[($#$l - 1)] eq "\n") {
4340 pop @$l;
4341 }
4342 $nr_line = scalar @$l;
4343 if (!$nr_line) {
4344 print "1 line\n\n\n";
4345 } else {
4346 if ($nr_line == 1) {
4347 $nr_line = '1 line';
4348 } else {
4349 $nr_line .= ' lines';
4350 }
4351 print $nr_line, "\n";
4352 show_commit_changed_paths($c);
4353 print "\n";
4354 print $_ foreach @$l;
4355 }
4356 } else {
4357 print "1 line\n";
4358 show_commit_changed_paths($c);
4359 print "\n";
4360
4361 }
4362 foreach my $x (qw/raw stat diff/) {
4363 if ($c->{$x}) {
4364 print "\n";
4365 print $_ foreach @{$c->{$x}}
4366 }
4367 }
4368 }
4369
4370 sub cmd_show_log {
4371 my (@args) = @_;
4372 my ($r_min, $r_max);
4373 my $r_last = -1; # prevent dupes
4374 set_local_timezone();
4375 if (defined $::_revision) {
4376 if ($::_revision =~ /^(\d+):(\d+)$/) {
4377 ($r_min, $r_max) = ($1, $2);
4378 } elsif ($::_revision =~ /^\d+$/) {
4379 $r_min = $r_max = $::_revision;
4380 } else {
4381 ::fatal "-r$::_revision is not supported, use ",
4382 "standard 'git log' arguments instead";
4383 }
4384 }
4385
4386 config_pager();
4387 @args = git_svn_log_cmd($r_min, $r_max, @args);
4388 if (!@args) {
4389 print commit_log_separator unless $incremental || $oneline;
4390 return;
4391 }
4392 my $log = command_output_pipe(@args);
4393 run_pager();
4394 my (@k, $c, $d, $stat);
4395 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4396 while (<$log>) {
4397 if (/^${esc_color}commit -?($::sha1_short)/o) {
4398 my $cmt = $1;
4399 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4400 $r_last = $c->{r};
4401 process_commit($c, $r_min, $r_max, \@k) or
4402 goto out;
4403 }
4404 $d = undef;
4405 $c = { c => $cmt };
4406 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4407 get_author_info($c, $1, $2, $3);
4408 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4409 # ignore
4410 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4411 push @{$c->{raw}}, $_;
4412 } elsif (/^${esc_color}[ACRMDT]\t/) {
4413 # we could add $SVN->{svn_path} here, but that requires
4414 # remote access at the moment (repo_path_split)...
4415 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4416 push @{$c->{changed}}, $_;
4417 } elsif (/^${esc_color}diff /o) {
4418 $d = 1;
4419 push @{$c->{diff}}, $_;
4420 } elsif ($d) {
4421 push @{$c->{diff}}, $_;
4422 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4423 $esc_color*[\+\-]*$esc_color$/x) {
4424 $stat = 1;
4425 push @{$c->{stat}}, $_;
4426 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4427 push @{$c->{stat}}, $_;
4428 $stat = undef;
4429 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4430 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4431 } elsif (s/^${esc_color} //o) {
4432 push @{$c->{l}}, $_;
4433 }
4434 }
4435 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4436 $r_last = $c->{r};
4437 process_commit($c, $r_min, $r_max, \@k);
4438 }
4439 if (@k) {
4440 ($r_min, $r_max) = ($r_max, $r_min);
4441 process_commit($_, $r_min, $r_max) foreach reverse @k;
4442 }
4443 out:
4444 close $log;
4445 print commit_log_separator unless $incremental || $oneline;
4446 }
4447
4448 package Git::SVN::Migration;
4449 # these version numbers do NOT correspond to actual version numbers
4450 # of git nor git-svn. They are just relative.
4451 #
4452 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4453 #
4454 # v1 layout: .git/$id/info/url, refs/remotes/$id
4455 #
4456 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4457 #
4458 # v3 layout: .git/svn/$id, refs/remotes/$id
4459 # - info/url may remain for backwards compatibility
4460 # - this is what we migrate up to this layout automatically,
4461 # - this will be used by git svn init on single branches
4462 # v3.1 layout (auto migrated):
4463 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4464 # for backwards compatibility
4465 #
4466 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4467 # - this is only created for newly multi-init-ed
4468 # repositories. Similar in spirit to the
4469 # --use-separate-remotes option in git-clone (now default)
4470 # - we do not automatically migrate to this (following
4471 # the example set by core git)
4472 #
4473 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4474 # - newer, more-efficient format that uses 24-bytes per record
4475 # with no filler space.
4476 # - use xxd -c24 < .rev_map.$UUID to view and debug
4477 # - This is a one-way migration, repositories updated to the
4478 # new format will not be able to use old git-svn without
4479 # rebuilding the .rev_db. Rebuilding the rev_db is not
4480 # possible if noMetadata or useSvmProps are set; but should
4481 # be no problem for users that use the (sensible) defaults.
4482 use strict;
4483 use warnings;
4484 use Carp qw/croak/;
4485 use File::Path qw/mkpath/;
4486 use File::Basename qw/dirname basename/;
4487 use vars qw/$_minimize/;
4488
4489 sub migrate_from_v0 {
4490 my $git_dir = $ENV{GIT_DIR};
4491 return undef unless -d $git_dir;
4492 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4493 my $migrated = 0;
4494 while (<$fh>) {
4495 chomp;
4496 my ($id, $orig_ref) = ($_, $_);
4497 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4498 next unless -f "$git_dir/$id/info/url";
4499 my $new_ref = "refs/remotes/$id";
4500 if (::verify_ref("$new_ref^0")) {
4501 print STDERR "W: $orig_ref is probably an old ",
4502 "branch used by an ancient version of ",
4503 "git-svn.\n",
4504 "However, $new_ref also exists.\n",
4505 "We will not be able ",
4506 "to use this branch until this ",
4507 "ambiguity is resolved.\n";
4508 next;
4509 }
4510 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4511 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4512 command_noisy('update-ref', $new_ref, $orig_ref);
4513 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4514 $migrated++;
4515 }
4516 command_close_pipe($fh, $ctx);
4517 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4518 $migrated;
4519 }
4520
4521 sub migrate_from_v1 {
4522 my $git_dir = $ENV{GIT_DIR};
4523 my $migrated = 0;
4524 return $migrated unless -d $git_dir;
4525 my $svn_dir = "$git_dir/svn";
4526
4527 # just in case somebody used 'svn' as their $id at some point...
4528 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4529
4530 print STDERR "Migrating from a git-svn v1 layout...\n";
4531 mkpath([$svn_dir]);
4532 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4533 "$svn_dir\n\t(required for this version ",
4534 "($::VERSION) of git-svn) does not. exist\n";
4535 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4536 while (<$fh>) {
4537 my $x = $_;
4538 next unless $x =~ s#^refs/remotes/##;
4539 chomp $x;
4540 next unless -f "$git_dir/$x/info/url";
4541 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4542 next unless $u;
4543 my $dn = dirname("$git_dir/svn/$x");
4544 mkpath([$dn]) unless -d $dn;
4545 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4546 mkpath(["$git_dir/svn/svn"]);
4547 print STDERR " - $git_dir/$x/info => ",
4548 "$git_dir/svn/$x/info\n";
4549 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4550 croak "$!: $x";
4551 # don't worry too much about these, they probably
4552 # don't exist with repos this old (save for index,
4553 # and we can easily regenerate that)
4554 foreach my $f (qw/unhandled.log index .rev_db/) {
4555 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4556 }
4557 } else {
4558 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4559 rename "$git_dir/$x", "$git_dir/svn/$x" or
4560 croak "$!: $x";
4561 }
4562 $migrated++;
4563 }
4564 command_close_pipe($fh, $ctx);
4565 print STDERR "Done migrating from a git-svn v1 layout\n";
4566 $migrated;
4567 }
4568
4569 sub read_old_urls {
4570 my ($l_map, $pfx, $path) = @_;
4571 my @dir;
4572 foreach (<$path/*>) {
4573 if (-r "$_/info/url") {
4574 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4575 my $ref_id = $pfx . basename $_;
4576 my $url = ::file_to_s("$_/info/url");
4577 $l_map->{$ref_id} = $url;
4578 } elsif (-d $_) {
4579 push @dir, $_;
4580 }
4581 }
4582 foreach (@dir) {
4583 my $x = $_;
4584 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4585 read_old_urls($l_map, $x, $_);
4586 }
4587 }
4588
4589 sub migrate_from_v2 {
4590 my @cfg = command(qw/config -l/);
4591 return if grep /^svn-remote\..+\.url=/, @cfg;
4592 my %l_map;
4593 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4594 my $migrated = 0;
4595
4596 foreach my $ref_id (sort keys %l_map) {
4597 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4598 if ($@) {
4599 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4600 }
4601 $migrated++;
4602 }
4603 $migrated;
4604 }
4605
4606 sub minimize_connections {
4607 my $r = Git::SVN::read_all_remotes();
4608 my $new_urls = {};
4609 my $root_repos = {};
4610 foreach my $repo_id (keys %$r) {
4611 my $url = $r->{$repo_id}->{url} or next;
4612 my $fetch = $r->{$repo_id}->{fetch} or next;
4613 my $ra = Git::SVN::Ra->new($url);
4614
4615 # skip existing cases where we already connect to the root
4616 if (($ra->{url} eq $ra->{repos_root}) ||
4617 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4618 $repo_id)) {
4619 $root_repos->{$ra->{url}} = $repo_id;
4620 next;
4621 }
4622
4623 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4624 my $root_path = $ra->{url};
4625 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4626 foreach my $path (keys %$fetch) {
4627 my $ref_id = $fetch->{$path};
4628 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4629
4630 # make sure we can read when connecting to
4631 # a higher level of a repository
4632 my ($last_rev, undef) = $gs->last_rev_commit;
4633 if (!defined $last_rev) {
4634 $last_rev = eval {
4635 $root_ra->get_latest_revnum;
4636 };
4637 next if $@;
4638 }
4639 my $new = $root_path;
4640 $new .= length $path ? "/$path" : '';
4641 eval {
4642 $root_ra->get_log([$new], $last_rev, $last_rev,
4643 0, 0, 1, sub { });
4644 };
4645 next if $@;
4646 $new_urls->{$ra->{repos_root}}->{$new} =
4647 { ref_id => $ref_id,
4648 old_repo_id => $repo_id,
4649 old_path => $path };
4650 }
4651 }
4652
4653 my @emptied;
4654 foreach my $url (keys %$new_urls) {
4655 # see if we can re-use an existing [svn-remote "repo_id"]
4656 # instead of creating a(n ugly) new section:
4657 my $repo_id = $root_repos->{$url} ||
4658 Git::SVN::sanitize_remote_name($url);
4659
4660 my $fetch = $new_urls->{$url};
4661 foreach my $path (keys %$fetch) {
4662 my $x = $fetch->{$path};
4663 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4664 my $pfx = "svn-remote.$x->{old_repo_id}";
4665
4666 my $old_fetch = quotemeta("$x->{old_path}:".
4667 "refs/remotes/$x->{ref_id}");
4668 command_noisy(qw/config --unset/,
4669 "$pfx.fetch", '^'. $old_fetch . '$');
4670 delete $r->{$x->{old_repo_id}}->
4671 {fetch}->{$x->{old_path}};
4672 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4673 command_noisy(qw/config --unset/,
4674 "$pfx.url");
4675 push @emptied, $x->{old_repo_id}
4676 }
4677 }
4678 }
4679 if (@emptied) {
4680 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4681 "$ENV{GIT_DIR}/config";
4682 print STDERR <<EOF;
4683 The following [svn-remote] sections in your config file ($file) are empty
4684 and can be safely removed:
4685 EOF
4686 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4687 }
4688 }
4689
4690 sub migration_check {
4691 migrate_from_v0();
4692 migrate_from_v1();
4693 migrate_from_v2();
4694 minimize_connections() if $_minimize;
4695 }
4696
4697 package Git::IndexInfo;
4698 use strict;
4699 use warnings;
4700 use Git qw/command_input_pipe command_close_pipe/;
4701
4702 sub new {
4703 my ($class) = @_;
4704 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4705 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4706 }
4707
4708 sub remove {
4709 my ($self, $path) = @_;
4710 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4711 return ++$self->{nr};
4712 }
4713 undef;
4714 }
4715
4716 sub update {
4717 my ($self, $mode, $hash, $path) = @_;
4718 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4719 return ++$self->{nr};
4720 }
4721 undef;
4722 }
4723
4724 sub DESTROY {
4725 my ($self) = @_;
4726 command_close_pipe($self->{gui}, $self->{ctx});
4727 }
4728
4729 package Git::SVN::GlobSpec;
4730 use strict;
4731 use warnings;
4732
4733 sub new {
4734 my ($class, $glob) = @_;
4735 my $re = $glob;
4736 $re =~ s!/+$!!g; # no need for trailing slashes
4737 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4738 my ($left, $right) = ($1, $2);
4739 if ($nr > 1) {
4740 die "Only one '*' wildcard expansion ",
4741 "is supported (got $nr): '$glob'\n";
4742 } elsif ($nr == 0) {
4743 die "One '*' is needed for glob: '$glob'\n";
4744 }
4745 $re = quotemeta($left) . $re . quotemeta($right);
4746 if (length $left && !($left =~ s!/+$!!g)) {
4747 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4748 }
4749 if (length $right && !($right =~ s!^/+!!g)) {
4750 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4751 }
4752 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4753 bless { left => $left, right => $right, left_regex => $left_re,
4754 regex => qr/$re/, glob => $glob }, $class;
4755 }
4756
4757 sub full_path {
4758 my ($self, $path) = @_;
4759 return (length $self->{left} ? "$self->{left}/" : '') .
4760 $path . (length $self->{right} ? "/$self->{right}" : '');
4761 }
4762
4763 __END__
4764
4765 Data structures:
4766
4767
4768 $remotes = { # returned by read_all_remotes()
4769 'svn' => {
4770 # svn-remote.svn.url=https://svn.musicpd.org
4771 url => 'https://svn.musicpd.org',
4772 # svn-remote.svn.fetch=mpd/trunk:trunk
4773 fetch => {
4774 'mpd/trunk' => 'trunk',
4775 },
4776 # svn-remote.svn.tags=mpd/tags/*:tags/*
4777 tags => {
4778 path => {
4779 left => 'mpd/tags',
4780 right => '',
4781 regex => qr!mpd/tags/([^/]+)$!,
4782 glob => 'tags/*',
4783 },
4784 ref => {
4785 left => 'tags',
4786 right => '',
4787 regex => qr!tags/([^/]+)$!,
4788 glob => 'tags/*',
4789 },
4790 }
4791 }
4792 };
4793
4794 $log_entry hashref as returned by libsvn_log_entry()
4795 {
4796 log => 'whitespace-formatted log entry
4797 ', # trailing newline is preserved
4798 revision => '8', # integer
4799 date => '2004-02-24T17:01:44.108345Z', # commit date
4800 author => 'committer name'
4801 };
4802
4803
4804 # this is generated by generate_diff();
4805 @mods = array of diff-index line hashes, each element represents one line
4806 of diff-index output
4807
4808 diff-index line ($m hash)
4809 {
4810 mode_a => first column of diff-index output, no leading ':',
4811 mode_b => second column of diff-index output,
4812 sha1_b => sha1sum of the final blob,
4813 chg => change type [MCRADT],
4814 file_a => original file name of a file (iff chg is 'C' or 'R')
4815 file_b => new/current file name of a file (any chg)
4816 }
4817 ;
4818
4819 # retval of read_url_paths{,_all}();
4820 $l_map = {
4821 # repository root url
4822 'https://svn.musicpd.org' => {
4823 # repository path # GIT_SVN_ID
4824 'mpd/trunk' => 'trunk',
4825 'mpd/tags/0.11.5' => 'tags/0.11.5',
4826 },
4827 }
4828
4829 Notes:
4830 I don't trust the each() function on unless I created %hash myself
4831 because the internal iterator may not have started at base.
git for Debian