gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 # handle ACL in file access tests
  14 use filetest 'access';
  15 use CGI qw(:standard :escapeHTML -nosticky);
  16 use CGI::Util qw(unescape);
  17 use CGI::Carp qw(fatalsToBrowser set_message);
  18 use Encode;
  19 use Fcntl ':mode';
  20 use File::Find qw();
  21 use File::Basename qw(basename);
  22 use Time::HiRes qw(gettimeofday tv_interval);
  23 use Digest::MD5 qw(md5_hex);
  24
  25 binmode STDOUT, ':utf8';
  26
  27 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  28         eval 'sub CGI::multi_param { CGI::param(@_) }'
  29 }
  30
  31 our $t0 = [ gettimeofday() ];
  32 our $number_of_git_cmds = 0;
  33
  34 BEGIN {
  35         CGI->compile() if $ENV{'MOD_PERL'};
  36 }
  37
  38 our $version = "++GIT_VERSION++";
  39
  40 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  41 sub evaluate_uri {
  42         our $cgi;
  43
  44         our $my_url = $cgi->url();
  45         our $my_uri = $cgi->url(-absolute => 1);
  46
  47         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  48         # needed and used only for URLs with nonempty PATH_INFO
  49         our $base_url = $my_url;
  50
  51         # When the script is used as DirectoryIndex, the URL does not contain the name
  52         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  53         # have to do it ourselves. We make $path_info global because it's also used
  54         # later on.
  55         #
  56         # Another issue with the script being the DirectoryIndex is that the resulting
  57         # $my_url data is not the full script URL: this is good, because we want
  58         # generated links to keep implying the script name if it wasn't explicitly
  59         # indicated in the URL we're handling, but it means that $my_url cannot be used
  60         # as base URL.
  61         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  62         # to build the base URL ourselves:
  63         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  64         if ($path_info) {
  65                 # $path_info has already been URL-decoded by the web server, but
  66                 # $my_url and $my_uri have not. URL-decode them so we can properly
  67                 # strip $path_info.
  68                 $my_url = unescape($my_url);
  69                 $my_uri = unescape($my_uri);
  70                 if ($my_url =~ s,\Q$path_info\E$,, &&
  71                     $my_uri =~ s,\Q$path_info\E$,, &&
  72                     defined $ENV{'SCRIPT_NAME'}) {
  73                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  74                 }
  75         }
  76
  77         # target of the home link on top of all pages
  78         our $home_link = $my_uri || "/";
  79 }
  80
  81 # core git executable to use
  82 # this can just be "git" if your webserver has a sensible PATH
  83 our $GIT = "++GIT_BINDIR++/git";
  84
  85 # absolute fs-path which will be prepended to the project path
  86 #our $projectroot = "/pub/scm";
  87 our $projectroot = "++GITWEB_PROJECTROOT++";
  88
  89 # fs traversing limit for getting project list
  90 # the number is relative to the projectroot
  91 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  92
  93 # string of the home link on top of all pages
  94 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  95
  96 # extra breadcrumbs preceding the home link
  97 our @extra_breadcrumbs = ();
  98
  99 # name of your site or organization to appear in page titles
 100 # replace this with something more descriptive for clearer bookmarks
 101 our $site_name = "++GITWEB_SITENAME++"
 102                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
 103
 104 # html snippet to include in the <head> section of each page
 105 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
 106 # filename of html text to include at top of each page
 107 our $site_header = "++GITWEB_SITE_HEADER++";
 108 # html text to include at home page
 109 our $home_text = "++GITWEB_HOMETEXT++";
 110 # filename of html text to include at bottom of each page
 111 our $site_footer = "++GITWEB_SITE_FOOTER++";
 112
 113 # URI of stylesheets
 114 our @stylesheets = ("++GITWEB_CSS++");
 115 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 116 our $stylesheet = undef;
 117 # URI of GIT logo (72x27 size)
 118 our $logo = "++GITWEB_LOGO++";
 119 # URI of GIT favicon, assumed to be image/png type
 120 our $favicon = "++GITWEB_FAVICON++";
 121 # URI of gitweb.js (JavaScript code for gitweb)
 122 our $javascript = "++GITWEB_JS++";
 123
 124 # URI and label (title) of GIT logo link
 125 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 126 #our $logo_label = "git documentation";
 127 our $logo_url = "http://git-scm.com/";
 128 our $logo_label = "git homepage";
 129
 130 # source of projects list
 131 our $projects_list = "++GITWEB_LIST++";
 132
 133 # the width (in characters) of the projects list "Description" column
 134 our $projects_list_description_width = 25;
 135
 136 # group projects by category on the projects list
 137 # (enabled if this variable evaluates to true)
 138 our $projects_list_group_categories = 0;
 139
 140 # default category if none specified
 141 # (leave the empty string for no category)
 142 our $project_list_default_category = "";
 143
 144 # default order of projects list
 145 # valid values are none, project, descr, owner, and age
 146 our $default_projects_order = "project";
 147
 148 # show repository only if this file exists
 149 # (only effective if this variable evaluates to true)
 150 our $export_ok = "++GITWEB_EXPORT_OK++";
 151
 152 # don't generate age column on the projects list page
 153 our $omit_age_column = 0;
 154
 155 # don't generate information about owners of repositories
 156 our $omit_owner=0;
 157
 158 # show repository only if this subroutine returns true
 159 # when given the path to the project, for example:
 160 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 161 our $export_auth_hook = undef;
 162
 163 # only allow viewing of repositories also shown on the overview page
 164 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 165
 166 # list of git base URLs used for URL to where fetch project from,
 167 # i.e. full URL is "$git_base_url/$project"
 168 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 169
 170 # default blob_plain mimetype and default charset for text/plain blob
 171 our $default_blob_plain_mimetype = 'text/plain';
 172 our $default_text_plain_charset  = undef;
 173
 174 # file to use for guessing MIME types before trying /etc/mime.types
 175 # (relative to the current git repository)
 176 our $mimetypes_file = undef;
 177
 178 # assume this charset if line contains non-UTF-8 characters;
 179 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 180 # for which encoding all byte sequences are valid, for example
 181 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 182 # could be even 'utf-8' for the old behavior)
 183 our $fallback_encoding = 'latin1';
 184
 185 # rename detection options for git-diff and git-diff-tree
 186 # - default is '-M', with the cost proportional to
 187 #   (number of removed files) * (number of new files).
 188 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 189 #   (number of changed files + number of removed files) * (number of new files)
 190 # - even more costly is '-C', '--find-copies-harder' with cost
 191 #   (number of files in the original tree) * (number of new files)
 192 # - one might want to include '-B' option, e.g. '-B', '-M'
 193 our @diff_opts = ('-M'); # taken from git_commit
 194
 195 # Disables features that would allow repository owners to inject script into
 196 # the gitweb domain.
 197 our $prevent_xss = 0;
 198
 199 # Path to the highlight executable to use (must be the one from
 200 # http://www.andre-simon.de due to assumptions about parameters and output).
 201 # Useful if highlight is not installed on your webserver's PATH.
 202 # [Default: highlight]
 203 our $highlight_bin = "++HIGHLIGHT_BIN++";
 204
 205 # information about snapshot formats that gitweb is capable of serving
 206 our %known_snapshot_formats = (
 207         # name => {
 208         #       'display' => display name,
 209         #       'type' => mime type,
 210         #       'suffix' => filename suffix,
 211         #       'format' => --format for git-archive,
 212         #       'compressor' => [compressor command and arguments]
 213         #                       (array reference, optional)
 214         #       'disabled' => boolean (optional)}
 215         #
 216         'tgz' => {
 217                 'display' => 'tar.gz',
 218                 'type' => 'application/x-gzip',
 219                 'suffix' => '.tar.gz',
 220                 'format' => 'tar',
 221                 'compressor' => ['gzip', '-n']},
 222
 223         'tbz2' => {
 224                 'display' => 'tar.bz2',
 225                 'type' => 'application/x-bzip2',
 226                 'suffix' => '.tar.bz2',
 227                 'format' => 'tar',
 228                 'compressor' => ['bzip2']},
 229
 230         'txz' => {
 231                 'display' => 'tar.xz',
 232                 'type' => 'application/x-xz',
 233                 'suffix' => '.tar.xz',
 234                 'format' => 'tar',
 235                 'compressor' => ['xz'],
 236                 'disabled' => 1},
 237
 238         'zip' => {
 239                 'display' => 'zip',
 240                 'type' => 'application/x-zip',
 241                 'suffix' => '.zip',
 242                 'format' => 'zip'},
 243 );
 244
 245 # Aliases so we understand old gitweb.snapshot values in repository
 246 # configuration.
 247 our %known_snapshot_format_aliases = (
 248         'gzip'  => 'tgz',
 249         'bzip2' => 'tbz2',
 250         'xz'    => 'txz',
 251
 252         # backward compatibility: legacy gitweb config support
 253         'x-gzip' => undef, 'gz' => undef,
 254         'x-bzip2' => undef, 'bz2' => undef,
 255         'x-zip' => undef, '' => undef,
 256 );
 257
 258 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 259 # are changed, it may be appropriate to change these values too via
 260 # $GITWEB_CONFIG.
 261 our %avatar_size = (
 262         'default' => 16,
 263         'double'  => 32
 264 );
 265
 266 # Used to set the maximum load that we will still respond to gitweb queries.
 267 # If server load exceed this value then return "503 server busy" error.
 268 # If gitweb cannot determined server load, it is taken to be 0.
 269 # Leave it undefined (or set to 'undef') to turn off load checking.
 270 our $maxload = 300;
 271
 272 # configuration for 'highlight' (http://www.andre-simon.de/)
 273 # match by basename
 274 our %highlight_basename = (
 275         #'Program' => 'py',
 276         #'Library' => 'py',
 277         'SConstruct' => 'py', # SCons equivalent of Makefile
 278         'Makefile' => 'make',
 279 );
 280 # match by extension
 281 our %highlight_ext = (
 282         # main extensions, defining name of syntax;
 283         # see files in /usr/share/highlight/langDefs/ directory
 284         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 285         # alternate extensions, see /etc/highlight/filetypes.conf
 286         (map { $_ => 'c'   } qw(c h)),
 287         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 288         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 289         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 290         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 291         (map { $_ => 'make'} qw(make mak mk)),
 292         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 293 );
 294
 295 # You define site-wide feature defaults here; override them with
 296 # $GITWEB_CONFIG as necessary.
 297 our %feature = (
 298         # feature => {
 299         #       'sub' => feature-sub (subroutine),
 300         #       'override' => allow-override (boolean),
 301         #       'default' => [ default options...] (array reference)}
 302         #
 303         # if feature is overridable (it means that allow-override has true value),
 304         # then feature-sub will be called with default options as parameters;
 305         # return value of feature-sub indicates if to enable specified feature
 306         #
 307         # if there is no 'sub' key (no feature-sub), then feature cannot be
 308         # overridden
 309         #
 310         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 311         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 312         # is enabled
 313
 314         # Enable the 'blame' blob view, showing the last commit that modified
 315         # each line in the file. This can be very CPU-intensive.
 316
 317         # To enable system wide have in $GITWEB_CONFIG
 318         # $feature{'blame'}{'default'} = [1];
 319         # To have project specific config enable override in $GITWEB_CONFIG
 320         # $feature{'blame'}{'override'} = 1;
 321         # and in project config gitweb.blame = 0|1;
 322         'blame' => {
 323                 'sub' => sub { feature_bool('blame', @_) },
 324                 'override' => 0,
 325                 'default' => [0]},
 326
 327         # Enable the 'snapshot' link, providing a compressed archive of any
 328         # tree. This can potentially generate high traffic if you have large
 329         # project.
 330
 331         # Value is a list of formats defined in %known_snapshot_formats that
 332         # you wish to offer.
 333         # To disable system wide have in $GITWEB_CONFIG
 334         # $feature{'snapshot'}{'default'} = [];
 335         # To have project specific config enable override in $GITWEB_CONFIG
 336         # $feature{'snapshot'}{'override'} = 1;
 337         # and in project config, a comma-separated list of formats or "none"
 338         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 339         'snapshot' => {
 340                 'sub' => \&feature_snapshot,
 341                 'override' => 0,
 342                 'default' => ['tgz']},
 343
 344         # Enable text search, which will list the commits which match author,
 345         # committer or commit text to a given string.  Enabled by default.
 346         # Project specific override is not supported.
 347         #
 348         # Note that this controls all search features, which means that if
 349         # it is disabled, then 'grep' and 'pickaxe' search would also be
 350         # disabled.
 351         'search' => {
 352                 'override' => 0,
 353                 'default' => [1]},
 354
 355         # Enable grep search, which will list the files in currently selected
 356         # tree containing the given string. Enabled by default. This can be
 357         # potentially CPU-intensive, of course.
 358         # Note that you need to have 'search' feature enabled too.
 359
 360         # To enable system wide have in $GITWEB_CONFIG
 361         # $feature{'grep'}{'default'} = [1];
 362         # To have project specific config enable override in $GITWEB_CONFIG
 363         # $feature{'grep'}{'override'} = 1;
 364         # and in project config gitweb.grep = 0|1;
 365         'grep' => {
 366                 'sub' => sub { feature_bool('grep', @_) },
 367                 'override' => 0,
 368                 'default' => [1]},
 369
 370         # Enable the pickaxe search, which will list the commits that modified
 371         # a given string in a file. This can be practical and quite faster
 372         # alternative to 'blame', but still potentially CPU-intensive.
 373         # Note that you need to have 'search' feature enabled too.
 374
 375         # To enable system wide have in $GITWEB_CONFIG
 376         # $feature{'pickaxe'}{'default'} = [1];
 377         # To have project specific config enable override in $GITWEB_CONFIG
 378         # $feature{'pickaxe'}{'override'} = 1;
 379         # and in project config gitweb.pickaxe = 0|1;
 380         'pickaxe' => {
 381                 'sub' => sub { feature_bool('pickaxe', @_) },
 382                 'override' => 0,
 383                 'default' => [1]},
 384
 385         # Enable showing size of blobs in a 'tree' view, in a separate
 386         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 387
 388         # To disable system wide have in $GITWEB_CONFIG
 389         # $feature{'show-sizes'}{'default'} = [0];
 390         # To have project specific config enable override in $GITWEB_CONFIG
 391         # $feature{'show-sizes'}{'override'} = 1;
 392         # and in project config gitweb.showsizes = 0|1;
 393         'show-sizes' => {
 394                 'sub' => sub { feature_bool('showsizes', @_) },
 395                 'override' => 0,
 396                 'default' => [1]},
 397
 398         # Make gitweb use an alternative format of the URLs which can be
 399         # more readable and natural-looking: project name is embedded
 400         # directly in the path and the query string contains other
 401         # auxiliary information. All gitweb installations recognize
 402         # URL in either format; this configures in which formats gitweb
 403         # generates links.
 404
 405         # To enable system wide have in $GITWEB_CONFIG
 406         # $feature{'pathinfo'}{'default'} = [1];
 407         # Project specific override is not supported.
 408
 409         # Note that you will need to change the default location of CSS,
 410         # favicon, logo and possibly other files to an absolute URL. Also,
 411         # if gitweb.cgi serves as your indexfile, you will need to force
 412         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 413         'pathinfo' => {
 414                 'override' => 0,
 415                 'default' => [0]},
 416
 417         # Make gitweb consider projects in project root subdirectories
 418         # to be forks of existing projects. Given project $projname.git,
 419         # projects matching $projname/*.git will not be shown in the main
 420         # projects list, instead a '+' mark will be added to $projname
 421         # there and a 'forks' view will be enabled for the project, listing
 422         # all the forks. If project list is taken from a file, forks have
 423         # to be listed after the main project.
 424
 425         # To enable system wide have in $GITWEB_CONFIG
 426         # $feature{'forks'}{'default'} = [1];
 427         # Project specific override is not supported.
 428         'forks' => {
 429                 'override' => 0,
 430                 'default' => [0]},
 431
 432         # Insert custom links to the action bar of all project pages.
 433         # This enables you mainly to link to third-party scripts integrating
 434         # into gitweb; e.g. git-browser for graphical history representation
 435         # or custom web-based repository administration interface.
 436
 437         # The 'default' value consists of a list of triplets in the form
 438         # (label, link, position) where position is the label after which
 439         # to insert the link and link is a format string where %n expands
 440         # to the project name, %f to the project path within the filesystem,
 441         # %h to the current hash (h gitweb parameter) and %b to the current
 442         # hash base (hb gitweb parameter); %% expands to %.
 443
 444         # To enable system wide have in $GITWEB_CONFIG e.g.
 445         # $feature{'actions'}{'default'} = [('graphiclog',
 446         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 447         # Project specific override is not supported.
 448         'actions' => {
 449                 'override' => 0,
 450                 'default' => []},
 451
 452         # Allow gitweb scan project content tags of project repository,
 453         # and display the popular Web 2.0-ish "tag cloud" near the projects
 454         # list.  Note that this is something COMPLETELY different from the
 455         # normal Git tags.
 456
 457         # gitweb by itself can show existing tags, but it does not handle
 458         # tagging itself; you need to do it externally, outside gitweb.
 459         # The format is described in git_get_project_ctags() subroutine.
 460         # You may want to install the HTML::TagCloud Perl module to get
 461         # a pretty tag cloud instead of just a list of tags.
 462
 463         # To enable system wide have in $GITWEB_CONFIG
 464         # $feature{'ctags'}{'default'} = [1];
 465         # Project specific override is not supported.
 466
 467         # In the future whether ctags editing is enabled might depend
 468         # on the value, but using 1 should always mean no editing of ctags.
 469         'ctags' => {
 470                 'override' => 0,
 471                 'default' => [0]},
 472
 473         # The maximum number of patches in a patchset generated in patch
 474         # view. Set this to 0 or undef to disable patch view, or to a
 475         # negative number to remove any limit.
 476
 477         # To disable system wide have in $GITWEB_CONFIG
 478         # $feature{'patches'}{'default'} = [0];
 479         # To have project specific config enable override in $GITWEB_CONFIG
 480         # $feature{'patches'}{'override'} = 1;
 481         # and in project config gitweb.patches = 0|n;
 482         # where n is the maximum number of patches allowed in a patchset.
 483         'patches' => {
 484                 'sub' => \&feature_patches,
 485                 'override' => 0,
 486                 'default' => [16]},
 487
 488         # Avatar support. When this feature is enabled, views such as
 489         # shortlog or commit will display an avatar associated with
 490         # the email of the committer(s) and/or author(s).
 491
 492         # Currently available providers are gravatar and picon.
 493         # If an unknown provider is specified, the feature is disabled.
 494
 495         # Picon currently relies on the indiana.edu database.
 496
 497         # To enable system wide have in $GITWEB_CONFIG
 498         # $feature{'avatar'}{'default'} = ['<provider>'];
 499         # where <provider> is either gravatar or picon.
 500         # To have project specific config enable override in $GITWEB_CONFIG
 501         # $feature{'avatar'}{'override'} = 1;
 502         # and in project config gitweb.avatar = <provider>;
 503         'avatar' => {
 504                 'sub' => \&feature_avatar,
 505                 'override' => 0,
 506                 'default' => ['']},
 507
 508         # Enable displaying how much time and how many git commands
 509         # it took to generate and display page.  Disabled by default.
 510         # Project specific override is not supported.
 511         'timed' => {
 512                 'override' => 0,
 513                 'default' => [0]},
 514
 515         # Enable turning some links into links to actions which require
 516         # JavaScript to run (like 'blame_incremental').  Not enabled by
 517         # default.  Project specific override is currently not supported.
 518         'javascript-actions' => {
 519                 'override' => 0,
 520                 'default' => [0]},
 521
 522         # Enable and configure ability to change common timezone for dates
 523         # in gitweb output via JavaScript.  Enabled by default.
 524         # Project specific override is not supported.
 525         'javascript-timezone' => {
 526                 'override' => 0,
 527                 'default' => [
 528                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 529                                      # or undef to turn off this feature
 530                         'gitweb_tz', # name of cookie where to store selected timezone
 531                         'datetime',  # CSS class used to mark up dates for manipulation
 532                 ]},
 533
 534         # Syntax highlighting support. This is based on Daniel Svensson's
 535         # and Sham Chukoury's work in gitweb-xmms2.git.
 536         # It requires the 'highlight' program present in $PATH,
 537         # and therefore is disabled by default.
 538
 539         # To enable system wide have in $GITWEB_CONFIG
 540         # $feature{'highlight'}{'default'} = [1];
 541
 542         'highlight' => {
 543                 'sub' => sub { feature_bool('highlight', @_) },
 544                 'override' => 0,
 545                 'default' => [0]},
 546
 547         # Enable displaying of remote heads in the heads list
 548
 549         # To enable system wide have in $GITWEB_CONFIG
 550         # $feature{'remote_heads'}{'default'} = [1];
 551         # To have project specific config enable override in $GITWEB_CONFIG
 552         # $feature{'remote_heads'}{'override'} = 1;
 553         # and in project config gitweb.remoteheads = 0|1;
 554         'remote_heads' => {
 555                 'sub' => sub { feature_bool('remote_heads', @_) },
 556                 'override' => 0,
 557                 'default' => [0]},
 558
 559         # Enable showing branches under other refs in addition to heads
 560
 561         # To set system wide extra branch refs have in $GITWEB_CONFIG
 562         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 563         # To have project specific config enable override in $GITWEB_CONFIG
 564         # $feature{'extra-branch-refs'}{'override'} = 1;
 565         # and in project config gitweb.extrabranchrefs = dirs of choice
 566         # Every directory is separated with whitespace.
 567
 568         'extra-branch-refs' => {
 569                 'sub' => \&feature_extra_branch_refs,
 570                 'override' => 0,
 571                 'default' => []},
 572 );
 573
 574 sub gitweb_get_feature {
 575         my ($name) = @_;
 576         return unless exists $feature{$name};
 577         my ($sub, $override, @defaults) = (
 578                 $feature{$name}{'sub'},
 579                 $feature{$name}{'override'},
 580                 @{$feature{$name}{'default'}});
 581         # project specific override is possible only if we have project
 582         our $git_dir; # global variable, declared later
 583         if (!$override || !defined $git_dir) {
 584                 return @defaults;
 585         }
 586         if (!defined $sub) {
 587                 warn "feature $name is not overridable";
 588                 return @defaults;
 589         }
 590         return $sub->(@defaults);
 591 }
 592
 593 # A wrapper to check if a given feature is enabled.
 594 # With this, you can say
 595 #
 596 #   my $bool_feat = gitweb_check_feature('bool_feat');
 597 #   gitweb_check_feature('bool_feat') or somecode;
 598 #
 599 # instead of
 600 #
 601 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 602 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 603 #
 604 sub gitweb_check_feature {
 605         return (gitweb_get_feature(@_))[0];
 606 }
 607
 608
 609 sub feature_bool {
 610         my $key = shift;
 611         my ($val) = git_get_project_config($key, '--bool');
 612
 613         if (!defined $val) {
 614                 return ($_[0]);
 615         } elsif ($val eq 'true') {
 616                 return (1);
 617         } elsif ($val eq 'false') {
 618                 return (0);
 619         }
 620 }
 621
 622 sub feature_snapshot {
 623         my (@fmts) = @_;
 624
 625         my ($val) = git_get_project_config('snapshot');
 626
 627         if ($val) {
 628                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 629         }
 630
 631         return @fmts;
 632 }
 633
 634 sub feature_patches {
 635         my @val = (git_get_project_config('patches', '--int'));
 636
 637         if (@val) {
 638                 return @val;
 639         }
 640
 641         return ($_[0]);
 642 }
 643
 644 sub feature_avatar {
 645         my @val = (git_get_project_config('avatar'));
 646
 647         return @val ? @val : @_;
 648 }
 649
 650 sub feature_extra_branch_refs {
 651         my (@branch_refs) = @_;
 652         my $values = git_get_project_config('extrabranchrefs');
 653
 654         if ($values) {
 655                 $values = config_to_multi ($values);
 656                 @branch_refs = ();
 657                 foreach my $value (@{$values}) {
 658                         push @branch_refs, split /\s+/, $value;
 659                 }
 660         }
 661
 662         return @branch_refs;
 663 }
 664
 665 # checking HEAD file with -e is fragile if the repository was
 666 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 667 # and then pruned.
 668 sub check_head_link {
 669         my ($dir) = @_;
 670         my $headfile = "$dir/HEAD";
 671         return ((-e $headfile) ||
 672                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 673 }
 674
 675 sub check_export_ok {
 676         my ($dir) = @_;
 677         return (check_head_link($dir) &&
 678                 (!$export_ok || -e "$dir/$export_ok") &&
 679                 (!$export_auth_hook || $export_auth_hook->($dir)));
 680 }
 681
 682 # process alternate names for backward compatibility
 683 # filter out unsupported (unknown) snapshot formats
 684 sub filter_snapshot_fmts {
 685         my @fmts = @_;
 686
 687         @fmts = map {
 688                 exists $known_snapshot_format_aliases{$_} ?
 689                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 690         @fmts = grep {
 691                 exists $known_snapshot_formats{$_} &&
 692                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 693 }
 694
 695 sub filter_and_validate_refs {
 696         my @refs = @_;
 697         my %unique_refs = ();
 698
 699         foreach my $ref (@refs) {
 700                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 701                 # 'heads' are added implicitly in get_branch_refs().
 702                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 703         }
 704         return sort keys %unique_refs;
 705 }
 706
 707 # If it is set to code reference, it is code that it is to be run once per
 708 # request, allowing updating configurations that change with each request,
 709 # while running other code in config file only once.
 710 #
 711 # Otherwise, if it is false then gitweb would process config file only once;
 712 # if it is true then gitweb config would be run for each request.
 713 our $per_request_config = 1;
 714
 715 # read and parse gitweb config file given by its parameter.
 716 # returns true on success, false on recoverable error, allowing
 717 # to chain this subroutine, using first file that exists.
 718 # dies on errors during parsing config file, as it is unrecoverable.
 719 sub read_config_file {
 720         my $filename = shift;
 721         return unless defined $filename;
 722         # die if there are errors parsing config file
 723         if (-e $filename) {
 724                 do $filename;
 725                 die $@ if $@;
 726                 return 1;
 727         }
 728         return;
 729 }
 730
 731 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 732 sub evaluate_gitweb_config {
 733         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 734         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 735         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 736
 737         # Protect against duplications of file names, to not read config twice.
 738         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 739         # there possibility of duplication of filename there doesn't matter.
 740         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 741         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 742
 743         # Common system-wide settings for convenience.
 744         # Those settings can be overridden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 745         read_config_file($GITWEB_CONFIG_COMMON);
 746
 747         # Use first config file that exists.  This means use the per-instance
 748         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 749         read_config_file($GITWEB_CONFIG) and return;
 750         read_config_file($GITWEB_CONFIG_SYSTEM);
 751 }
 752
 753 # Get loadavg of system, to compare against $maxload.
 754 # Currently it requires '/proc/loadavg' present to get loadavg;
 755 # if it is not present it returns 0, which means no load checking.
 756 sub get_loadavg {
 757         if( -e '/proc/loadavg' ){
 758                 open my $fd, '<', '/proc/loadavg'
 759                         or return 0;
 760                 my @load = split(/\s+/, scalar <$fd>);
 761                 close $fd;
 762
 763                 # The first three columns measure CPU and IO utilization of the last one,
 764                 # five, and 10 minute periods.  The fourth column shows the number of
 765                 # currently running processes and the total number of processes in the m/n
 766                 # format.  The last column displays the last process ID used.
 767                 return $load[0] || 0;
 768         }
 769         # additional checks for load average should go here for things that don't export
 770         # /proc/loadavg
 771
 772         return 0;
 773 }
 774
 775 # version of the core git binary
 776 our $git_version;
 777 sub evaluate_git_version {
 778         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 779         $number_of_git_cmds++;
 780 }
 781
 782 sub check_loadavg {
 783         if (defined $maxload && get_loadavg() > $maxload) {
 784                 die_error(503, "The load average on the server is too high");
 785         }
 786 }
 787
 788 # ======================================================================
 789 # input validation and dispatch
 790
 791 # Various hash size-related values.
 792 my $sha1_len = 40;
 793 my $sha256_extra_len = 24;
 794 my $sha256_len = $sha1_len + $sha256_extra_len;
 795
 796 # A regex matching $len hex characters. $len may be a range (e.g. 7,64).
 797 sub oid_nlen_regex {
 798         my $len = shift;
 799         my $hchr = qr/[0-9a-fA-F]/;
 800         return qr/(?:(?:$hchr){$len})/;
 801 }
 802
 803 # A regex matching two sets of $nlen hex characters, prefixed by the literal
 804 # string $prefix and with the literal string $infix between them.
 805 sub oid_nlen_prefix_infix_regex {
 806         my $nlen = shift;
 807         my $prefix = shift;
 808         my $infix = shift;
 809
 810         my $rx = oid_nlen_regex($nlen);
 811
 812         return qr/^\Q$prefix\E$rx\Q$infix\E$rx$/;
 813 }
 814
 815 # A regex matching a valid object ID.
 816 our $oid_regex;
 817 {
 818         my $x = oid_nlen_regex($sha1_len);
 819         my $y = oid_nlen_regex($sha256_extra_len);
 820         $oid_regex = qr/(?:$x(?:$y)?)/;
 821 }
 822
 823 # input parameters can be collected from a variety of sources (presently, CGI
 824 # and PATH_INFO), so we define an %input_params hash that collects them all
 825 # together during validation: this allows subsequent uses (e.g. href()) to be
 826 # agnostic of the parameter origin
 827
 828 our %input_params = ();
 829
 830 # input parameters are stored with the long parameter name as key. This will
 831 # also be used in the href subroutine to convert parameters to their CGI
 832 # equivalent, and since the href() usage is the most frequent one, we store
 833 # the name -> CGI key mapping here, instead of the reverse.
 834 #
 835 # XXX: Warning: If you touch this, check the search form for updating,
 836 # too.
 837
 838 our @cgi_param_mapping = (
 839         project => "p",
 840         action => "a",
 841         file_name => "f",
 842         file_parent => "fp",
 843         hash => "h",
 844         hash_parent => "hp",
 845         hash_base => "hb",
 846         hash_parent_base => "hpb",
 847         page => "pg",
 848         order => "o",
 849         searchtext => "s",
 850         searchtype => "st",
 851         snapshot_format => "sf",
 852         extra_options => "opt",
 853         search_use_regexp => "sr",
 854         ctag => "by_tag",
 855         diff_style => "ds",
 856         project_filter => "pf",
 857         # this must be last entry (for manipulation from JavaScript)
 858         javascript => "js"
 859 );
 860 our %cgi_param_mapping = @cgi_param_mapping;
 861
 862 # we will also need to know the possible actions, for validation
 863 our %actions = (
 864         "blame" => \&git_blame,
 865         "blame_incremental" => \&git_blame_incremental,
 866         "blame_data" => \&git_blame_data,
 867         "blobdiff" => \&git_blobdiff,
 868         "blobdiff_plain" => \&git_blobdiff_plain,
 869         "blob" => \&git_blob,
 870         "blob_plain" => \&git_blob_plain,
 871         "commitdiff" => \&git_commitdiff,
 872         "commitdiff_plain" => \&git_commitdiff_plain,
 873         "commit" => \&git_commit,
 874         "forks" => \&git_forks,
 875         "heads" => \&git_heads,
 876         "history" => \&git_history,
 877         "log" => \&git_log,
 878         "patch" => \&git_patch,
 879         "patches" => \&git_patches,
 880         "remotes" => \&git_remotes,
 881         "rss" => \&git_rss,
 882         "atom" => \&git_atom,
 883         "search" => \&git_search,
 884         "search_help" => \&git_search_help,
 885         "shortlog" => \&git_shortlog,
 886         "summary" => \&git_summary,
 887         "tag" => \&git_tag,
 888         "tags" => \&git_tags,
 889         "tree" => \&git_tree,
 890         "snapshot" => \&git_snapshot,
 891         "object" => \&git_object,
 892         # those below don't need $project
 893         "opml" => \&git_opml,
 894         "project_list" => \&git_project_list,
 895         "project_index" => \&git_project_index,
 896 );
 897
 898 # finally, we have the hash of allowed extra_options for the commands that
 899 # allow them
 900 our %allowed_options = (
 901         "--no-merges" => [ qw(rss atom log shortlog history) ],
 902 );
 903
 904 # fill %input_params with the CGI parameters. All values except for 'opt'
 905 # should be single values, but opt can be an array. We should probably
 906 # build an array of parameters that can be multi-valued, but since for the time
 907 # being it's only this one, we just single it out
 908 sub evaluate_query_params {
 909         our $cgi;
 910
 911         while (my ($name, $symbol) = each %cgi_param_mapping) {
 912                 if ($symbol eq 'opt') {
 913                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 914                 } else {
 915                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 916                 }
 917         }
 918 }
 919
 920 # now read PATH_INFO and update the parameter list for missing parameters
 921 sub evaluate_path_info {
 922         return if defined $input_params{'project'};
 923         return if !$path_info;
 924         $path_info =~ s,^/+,,;
 925         return if !$path_info;
 926
 927         # find which part of PATH_INFO is project
 928         my $project = $path_info;
 929         $project =~ s,/+$,,;
 930         while ($project && !check_head_link("$projectroot/$project")) {
 931                 $project =~ s,/*[^/]*$,,;
 932         }
 933         return unless $project;
 934         $input_params{'project'} = $project;
 935
 936         # do not change any parameters if an action is given using the query string
 937         return if $input_params{'action'};
 938         $path_info =~ s,^\Q$project\E/*,,;
 939
 940         # next, check if we have an action
 941         my $action = $path_info;
 942         $action =~ s,/.*$,,;
 943         if (exists $actions{$action}) {
 944                 $path_info =~ s,^$action/*,,;
 945                 $input_params{'action'} = $action;
 946         }
 947
 948         # list of actions that want hash_base instead of hash, but can have no
 949         # pathname (f) parameter
 950         my @wants_base = (
 951                 'tree',
 952                 'history',
 953         );
 954
 955         # we want to catch, among others
 956         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 957         my ($parentrefname, $parentpathname, $refname, $pathname) =
 958                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 959
 960         # first, analyze the 'current' part
 961         if (defined $pathname) {
 962                 # we got "branch:filename" or "branch:dir/"
 963                 # we could use git_get_type(branch:pathname), but:
 964                 # - it needs $git_dir
 965                 # - it does a git() call
 966                 # - the convention of terminating directories with a slash
 967                 #   makes it superfluous
 968                 # - embedding the action in the PATH_INFO would make it even
 969                 #   more superfluous
 970                 $pathname =~ s,^/+,,;
 971                 if (!$pathname || substr($pathname, -1) eq "/") {
 972                         $input_params{'action'} ||= "tree";
 973                         $pathname =~ s,/$,,;
 974                 } else {
 975                         # the default action depends on whether we had parent info
 976                         # or not
 977                         if ($parentrefname) {
 978                                 $input_params{'action'} ||= "blobdiff_plain";
 979                         } else {
 980                                 $input_params{'action'} ||= "blob_plain";
 981                         }
 982                 }
 983                 $input_params{'hash_base'} ||= $refname;
 984                 $input_params{'file_name'} ||= $pathname;
 985         } elsif (defined $refname) {
 986                 # we got "branch". In this case we have to choose if we have to
 987                 # set hash or hash_base.
 988                 #
 989                 # Most of the actions without a pathname only want hash to be
 990                 # set, except for the ones specified in @wants_base that want
 991                 # hash_base instead. It should also be noted that hand-crafted
 992                 # links having 'history' as an action and no pathname or hash
 993                 # set will fail, but that happens regardless of PATH_INFO.
 994                 if (defined $parentrefname) {
 995                         # if there is parent let the default be 'shortlog' action
 996                         # (for http://git.example.com/repo.git/A..B links); if there
 997                         # is no parent, dispatch will detect type of object and set
 998                         # action appropriately if required (if action is not set)
 999                         $input_params{'action'} ||= "shortlog";
1000                 }
1001                 if ($input_params{'action'} &&
1002                     grep { $_ eq $input_params{'action'} } @wants_base) {
1003                         $input_params{'hash_base'} ||= $refname;
1004                 } else {
1005                         $input_params{'hash'} ||= $refname;
1006                 }
1007         }
1008
1009         # next, handle the 'parent' part, if present
1010         if (defined $parentrefname) {
1011                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
1012                 # someproject/blobdiff/oldrev..newrev:/filename
1013                 if ($parentpathname) {
1014                         $parentpathname =~ s,^/+,,;
1015                         $parentpathname =~ s,/$,,;
1016                         $input_params{'file_parent'} ||= $parentpathname;
1017                 } else {
1018                         $input_params{'file_parent'} ||= $input_params{'file_name'};
1019                 }
1020                 # we assume that hash_parent_base is wanted if a path was specified,
1021                 # or if the action wants hash_base instead of hash
1022                 if (defined $input_params{'file_parent'} ||
1023                         grep { $_ eq $input_params{'action'} } @wants_base) {
1024                         $input_params{'hash_parent_base'} ||= $parentrefname;
1025                 } else {
1026                         $input_params{'hash_parent'} ||= $parentrefname;
1027                 }
1028         }
1029
1030         # for the snapshot action, we allow URLs in the form
1031         # $project/snapshot/$hash.ext
1032         # where .ext determines the snapshot and gets removed from the
1033         # passed $refname to provide the $hash.
1034         #
1035         # To be able to tell that $refname includes the format extension, we
1036         # require the following two conditions to be satisfied:
1037         # - the hash input parameter MUST have been set from the $refname part
1038         #   of the URL (i.e. they must be equal)
1039         # - the snapshot format MUST NOT have been defined already (e.g. from
1040         #   CGI parameter sf)
1041         # It's also useless to try any matching unless $refname has a dot,
1042         # so we check for that too
1043         if (defined $input_params{'action'} &&
1044                 $input_params{'action'} eq 'snapshot' &&
1045                 defined $refname && index($refname, '.') != -1 &&
1046                 $refname eq $input_params{'hash'} &&
1047                 !defined $input_params{'snapshot_format'}) {
1048                 # We loop over the known snapshot formats, checking for
1049                 # extensions. Allowed extensions are both the defined suffix
1050                 # (which includes the initial dot already) and the snapshot
1051                 # format key itself, with a prepended dot
1052                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1053                         my $hash = $refname;
1054                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1055                                 next;
1056                         }
1057                         my $sfx = $1;
1058                         # a valid suffix was found, so set the snapshot format
1059                         # and reset the hash parameter
1060                         $input_params{'snapshot_format'} = $fmt;
1061                         $input_params{'hash'} = $hash;
1062                         # we also set the format suffix to the one requested
1063                         # in the URL: this way a request for e.g. .tgz returns
1064                         # a .tgz instead of a .tar.gz
1065                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1066                         last;
1067                 }
1068         }
1069 }
1070
1071 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1072      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1073      $searchtext, $search_regexp, $project_filter);
1074 sub evaluate_and_validate_params {
1075         our $action = $input_params{'action'};
1076         if (defined $action) {
1077                 if (!is_valid_action($action)) {
1078                         die_error(400, "Invalid action parameter");
1079                 }
1080         }
1081
1082         # parameters which are pathnames
1083         our $project = $input_params{'project'};
1084         if (defined $project) {
1085                 if (!is_valid_project($project)) {
1086                         undef $project;
1087                         die_error(404, "No such project");
1088                 }
1089         }
1090
1091         our $project_filter = $input_params{'project_filter'};
1092         if (defined $project_filter) {
1093                 if (!is_valid_pathname($project_filter)) {
1094                         die_error(404, "Invalid project_filter parameter");
1095                 }
1096         }
1097
1098         our $file_name = $input_params{'file_name'};
1099         if (defined $file_name) {
1100                 if (!is_valid_pathname($file_name)) {
1101                         die_error(400, "Invalid file parameter");
1102                 }
1103         }
1104
1105         our $file_parent = $input_params{'file_parent'};
1106         if (defined $file_parent) {
1107                 if (!is_valid_pathname($file_parent)) {
1108                         die_error(400, "Invalid file parent parameter");
1109                 }
1110         }
1111
1112         # parameters which are refnames
1113         our $hash = $input_params{'hash'};
1114         if (defined $hash) {
1115                 if (!is_valid_refname($hash)) {
1116                         die_error(400, "Invalid hash parameter");
1117                 }
1118         }
1119
1120         our $hash_parent = $input_params{'hash_parent'};
1121         if (defined $hash_parent) {
1122                 if (!is_valid_refname($hash_parent)) {
1123                         die_error(400, "Invalid hash parent parameter");
1124                 }
1125         }
1126
1127         our $hash_base = $input_params{'hash_base'};
1128         if (defined $hash_base) {
1129                 if (!is_valid_refname($hash_base)) {
1130                         die_error(400, "Invalid hash base parameter");
1131                 }
1132         }
1133
1134         our @extra_options = @{$input_params{'extra_options'}};
1135         # @extra_options is always defined, since it can only be (currently) set from
1136         # CGI, and $cgi->param() returns the empty array in array context if the param
1137         # is not set
1138         foreach my $opt (@extra_options) {
1139                 if (not exists $allowed_options{$opt}) {
1140                         die_error(400, "Invalid option parameter");
1141                 }
1142                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1143                         die_error(400, "Invalid option parameter for this action");
1144                 }
1145         }
1146
1147         our $hash_parent_base = $input_params{'hash_parent_base'};
1148         if (defined $hash_parent_base) {
1149                 if (!is_valid_refname($hash_parent_base)) {
1150                         die_error(400, "Invalid hash parent base parameter");
1151                 }
1152         }
1153
1154         # other parameters
1155         our $page = $input_params{'page'};
1156         if (defined $page) {
1157                 if ($page =~ m/[^0-9]/) {
1158                         die_error(400, "Invalid page parameter");
1159                 }
1160         }
1161
1162         our $searchtype = $input_params{'searchtype'};
1163         if (defined $searchtype) {
1164                 if ($searchtype =~ m/[^a-z]/) {
1165                         die_error(400, "Invalid searchtype parameter");
1166                 }
1167         }
1168
1169         our $search_use_regexp = $input_params{'search_use_regexp'};
1170
1171         our $searchtext = $input_params{'searchtext'};
1172         our $search_regexp = undef;
1173         if (defined $searchtext) {
1174                 if (length($searchtext) < 2) {
1175                         die_error(403, "At least two characters are required for search parameter");
1176                 }
1177                 if ($search_use_regexp) {
1178                         $search_regexp = $searchtext;
1179                         if (!eval { qr/$search_regexp/; 1; }) {
1180                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1181                                 die_error(400, "Invalid search regexp '$search_regexp'",
1182                                           esc_html($error));
1183                         }
1184                 } else {
1185                         $search_regexp = quotemeta $searchtext;
1186                 }
1187         }
1188 }
1189
1190 # path to the current git repository
1191 our $git_dir;
1192 sub evaluate_git_dir {
1193         our $git_dir = "$projectroot/$project" if $project;
1194 }
1195
1196 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1197 sub configure_gitweb_features {
1198         # list of supported snapshot formats
1199         our @snapshot_fmts = gitweb_get_feature('snapshot');
1200         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1201
1202         our ($git_avatar) = gitweb_get_feature('avatar');
1203         $git_avatar = '' unless $git_avatar =~ /^(?:gravatar|picon)$/s;
1204
1205         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1206         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1207 }
1208
1209 sub get_branch_refs {
1210         return ('heads', @extra_branch_refs);
1211 }
1212
1213 # custom error handler: 'die <message>' is Internal Server Error
1214 sub handle_errors_html {
1215         my $msg = shift; # it is already HTML escaped
1216
1217         # to avoid infinite loop where error occurs in die_error,
1218         # change handler to default handler, disabling handle_errors_html
1219         set_message("Error occurred when inside die_error:\n$msg");
1220
1221         # you cannot jump out of die_error when called as error handler;
1222         # the subroutine set via CGI::Carp::set_message is called _after_
1223         # HTTP headers are already written, so it cannot write them itself
1224         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1225 }
1226 set_message(\&handle_errors_html);
1227
1228 # dispatch
1229 sub dispatch {
1230         if (!defined $action) {
1231                 if (defined $hash) {
1232                         $action = git_get_type($hash);
1233                         $action or die_error(404, "Object does not exist");
1234                 } elsif (defined $hash_base && defined $file_name) {
1235                         $action = git_get_type("$hash_base:$file_name");
1236                         $action or die_error(404, "File or directory does not exist");
1237                 } elsif (defined $project) {
1238                         $action = 'summary';
1239                 } else {
1240                         $action = 'project_list';
1241                 }
1242         }
1243         if (!defined($actions{$action})) {
1244                 die_error(400, "Unknown action");
1245         }
1246         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1247             !$project) {
1248                 die_error(400, "Project needed");
1249         }
1250         $actions{$action}->();
1251 }
1252
1253 sub reset_timer {
1254         our $t0 = [ gettimeofday() ]
1255                 if defined $t0;
1256         our $number_of_git_cmds = 0;
1257 }
1258
1259 our $first_request = 1;
1260 sub run_request {
1261         reset_timer();
1262
1263         evaluate_uri();
1264         if ($first_request) {
1265                 evaluate_gitweb_config();
1266                 evaluate_git_version();
1267         }
1268         if ($per_request_config) {
1269                 if (ref($per_request_config) eq 'CODE') {
1270                         $per_request_config->();
1271                 } elsif (!$first_request) {
1272                         evaluate_gitweb_config();
1273                 }
1274         }
1275         check_loadavg();
1276
1277         # $projectroot and $projects_list might be set in gitweb config file
1278         $projects_list ||= $projectroot;
1279
1280         evaluate_query_params();
1281         evaluate_path_info();
1282         evaluate_and_validate_params();
1283         evaluate_git_dir();
1284
1285         configure_gitweb_features();
1286
1287         dispatch();
1288 }
1289
1290 our $is_last_request = sub { 1 };
1291 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1292 our $CGI = 'CGI';
1293 our $cgi;
1294 our $FCGI_Stream_PRINT_raw = \&FCGI::Stream::PRINT;
1295 sub configure_as_fcgi {
1296         require CGI::Fast;
1297         our $CGI = 'CGI::Fast';
1298         # FCGI is not Unicode aware hence the UTF-8 encoding must be done manually.
1299         # However no encoding must be done within git_blob_plain() and git_snapshot()
1300         # which must still output in raw binary mode.
1301         no warnings 'redefine';
1302         my $enc = Encode::find_encoding('UTF-8');
1303         *FCGI::Stream::PRINT = sub {
1304                 my @OUTPUT = @_;
1305                 for (my $i = 1; $i < @_; $i++) {
1306                         $OUTPUT[$i] = $enc->encode($_[$i], Encode::FB_CROAK|Encode::LEAVE_SRC);
1307                 }
1308                 @_ = @OUTPUT;
1309                 goto $FCGI_Stream_PRINT_raw;
1310         };
1311
1312         my $request_number = 0;
1313         # let each child service 100 requests
1314         our $is_last_request = sub { ++$request_number > 100 };
1315 }
1316 sub evaluate_argv {
1317         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1318         configure_as_fcgi()
1319                 if $script_name =~ /\.fcgi$/;
1320
1321         return unless (@ARGV);
1322
1323         require Getopt::Long;
1324         Getopt::Long::GetOptions(
1325                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1326                 'nproc|n=i' => sub {
1327                         my ($arg, $val) = @_;
1328                         return unless eval { require FCGI::ProcManager; 1; };
1329                         my $proc_manager = FCGI::ProcManager->new({
1330                                 n_processes => $val,
1331                         });
1332                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1333                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1334                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1335                 },
1336         );
1337 }
1338
1339 sub run {
1340         evaluate_argv();
1341
1342         $first_request = 1;
1343         $pre_listen_hook->()
1344                 if $pre_listen_hook;
1345
1346  REQUEST:
1347         while ($cgi = $CGI->new()) {
1348                 $pre_dispatch_hook->()
1349                         if $pre_dispatch_hook;
1350
1351                 run_request();
1352
1353                 $post_dispatch_hook->()
1354                         if $post_dispatch_hook;
1355                 $first_request = 0;
1356
1357                 last REQUEST if ($is_last_request->());
1358         }
1359
1360  DONE_GITWEB:
1361         1;
1362 }
1363
1364 run();
1365
1366 if (defined caller) {
1367         # wrapped in a subroutine processing requests,
1368         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1369         return;
1370 } else {
1371         # pure CGI script, serving single request
1372         exit;
1373 }
1374
1375 ## ======================================================================
1376 ## action links
1377
1378 # possible values of extra options
1379 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1380 # -replay => 1      - start from a current view (replay with modifications)
1381 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1382 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1383 sub href {
1384         my %params = @_;
1385         # default is to use -absolute url() i.e. $my_uri
1386         my $href = $params{-full} ? $my_url : $my_uri;
1387
1388         # implicit -replay, must be first of implicit params
1389         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1390
1391         $params{'project'} = $project unless exists $params{'project'};
1392
1393         if ($params{-replay}) {
1394                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1395                         if (!exists $params{$name}) {
1396                                 $params{$name} = $input_params{$name};
1397                         }
1398                 }
1399         }
1400
1401         my $use_pathinfo = gitweb_check_feature('pathinfo');
1402         if (defined $params{'project'} &&
1403             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1404                 # try to put as many parameters as possible in PATH_INFO:
1405                 #   - project name
1406                 #   - action
1407                 #   - hash_parent or hash_parent_base:/file_parent
1408                 #   - hash or hash_base:/filename
1409                 #   - the snapshot_format as an appropriate suffix
1410
1411                 # When the script is the root DirectoryIndex for the domain,
1412                 # $href here would be something like http://gitweb.example.com/
1413                 # Thus, we strip any trailing / from $href, to spare us double
1414                 # slashes in the final URL
1415                 $href =~ s,/$,,;
1416
1417                 # Then add the project name, if present
1418                 $href .= "/".esc_path_info($params{'project'});
1419                 delete $params{'project'};
1420
1421                 # since we destructively absorb parameters, we keep this
1422                 # boolean that remembers if we're handling a snapshot
1423                 my $is_snapshot = $params{'action'} eq 'snapshot';
1424
1425                 # Summary just uses the project path URL, any other action is
1426                 # added to the URL
1427                 if (defined $params{'action'}) {
1428                         $href .= "/".esc_path_info($params{'action'})
1429                                 unless $params{'action'} eq 'summary';
1430                         delete $params{'action'};
1431                 }
1432
1433                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1434                 # stripping nonexistent or useless pieces
1435                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1436                         || $params{'hash_parent'} || $params{'hash'});
1437                 if (defined $params{'hash_base'}) {
1438                         if (defined $params{'hash_parent_base'}) {
1439                                 $href .= esc_path_info($params{'hash_parent_base'});
1440                                 # skip the file_parent if it's the same as the file_name
1441                                 if (defined $params{'file_parent'}) {
1442                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1443                                                 delete $params{'file_parent'};
1444                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1445                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1446                                                 delete $params{'file_parent'};
1447                                         }
1448                                 }
1449                                 $href .= "..";
1450                                 delete $params{'hash_parent'};
1451                                 delete $params{'hash_parent_base'};
1452                         } elsif (defined $params{'hash_parent'}) {
1453                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1454                                 delete $params{'hash_parent'};
1455                         }
1456
1457                         $href .= esc_path_info($params{'hash_base'});
1458                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1459                                 $href .= ":/".esc_path_info($params{'file_name'});
1460                                 delete $params{'file_name'};
1461                         }
1462                         delete $params{'hash'};
1463                         delete $params{'hash_base'};
1464                 } elsif (defined $params{'hash'}) {
1465                         $href .= esc_path_info($params{'hash'});
1466                         delete $params{'hash'};
1467                 }
1468
1469                 # If the action was a snapshot, we can absorb the
1470                 # snapshot_format parameter too
1471                 if ($is_snapshot) {
1472                         my $fmt = $params{'snapshot_format'};
1473                         # snapshot_format should always be defined when href()
1474                         # is called, but just in case some code forgets, we
1475                         # fall back to the default
1476                         $fmt ||= $snapshot_fmts[0];
1477                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1478                         delete $params{'snapshot_format'};
1479                 }
1480         }
1481
1482         # now encode the parameters explicitly
1483         my @result = ();
1484         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1485                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1486                 if (defined $params{$name}) {
1487                         if (ref($params{$name}) eq "ARRAY") {
1488                                 foreach my $par (@{$params{$name}}) {
1489                                         push @result, $symbol . "=" . esc_param($par);
1490                                 }
1491                         } else {
1492                                 push @result, $symbol . "=" . esc_param($params{$name});
1493                         }
1494                 }
1495         }
1496         $href .= "?" . join(';', @result) if scalar @result;
1497
1498         # final transformation: trailing spaces must be escaped (URI-encoded)
1499         $href =~ s/(\s+)$/CGI::escape($1)/e;
1500
1501         if ($params{-anchor}) {
1502                 $href .= "#".esc_param($params{-anchor});
1503         }
1504
1505         return $href;
1506 }
1507
1508
1509 ## ======================================================================
1510 ## validation, quoting/unquoting and escaping
1511
1512 sub is_valid_action {
1513         my $input = shift;
1514         return undef unless exists $actions{$input};
1515         return 1;
1516 }
1517
1518 sub is_valid_project {
1519         my $input = shift;
1520
1521         return unless defined $input;
1522         if (!is_valid_pathname($input) ||
1523                 !(-d "$projectroot/$input") ||
1524                 !check_export_ok("$projectroot/$input") ||
1525                 ($strict_export && !project_in_list($input))) {
1526                 return undef;
1527         } else {
1528                 return 1;
1529         }
1530 }
1531
1532 sub is_valid_pathname {
1533         my $input = shift;
1534
1535         return undef unless defined $input;
1536         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1537         # at the beginning, at the end, and between slashes.
1538         # also this catches doubled slashes
1539         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1540                 return undef;
1541         }
1542         # no null characters
1543         if ($input =~ m!\0!) {
1544                 return undef;
1545         }
1546         return 1;
1547 }
1548
1549 sub is_valid_ref_format {
1550         my $input = shift;
1551
1552         return undef unless defined $input;
1553         # restrictions on ref name according to git-check-ref-format
1554         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1555                 return undef;
1556         }
1557         return 1;
1558 }
1559
1560 sub is_valid_refname {
1561         my $input = shift;
1562
1563         return undef unless defined $input;
1564         # textual hashes are O.K.
1565         if ($input =~ m/^$oid_regex$/) {
1566                 return 1;
1567         }
1568         # it must be correct pathname
1569         is_valid_pathname($input) or return undef;
1570         # check git-check-ref-format restrictions
1571         is_valid_ref_format($input) or return undef;
1572         return 1;
1573 }
1574
1575 # decode sequences of octets in utf8 into Perl's internal form,
1576 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1577 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1578 sub to_utf8 {
1579         my $str = shift;
1580         return undef unless defined $str;
1581
1582         if (utf8::is_utf8($str) || utf8::decode($str)) {
1583                 return $str;
1584         } else {
1585                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1586         }
1587 }
1588
1589 # quote unsafe chars, but keep the slash, even when it's not
1590 # correct, but quoted slashes look too horrible in bookmarks
1591 sub esc_param {
1592         my $str = shift;
1593         return undef unless defined $str;
1594         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1595         $str =~ s/ /\+/g;
1596         return $str;
1597 }
1598
1599 # the quoting rules for path_info fragment are slightly different
1600 sub esc_path_info {
1601         my $str = shift;
1602         return undef unless defined $str;
1603
1604         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1605         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1606
1607         return $str;
1608 }
1609
1610 # quote unsafe chars in whole URL, so some characters cannot be quoted
1611 sub esc_url {
1612         my $str = shift;
1613         return undef unless defined $str;
1614         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1615         $str =~ s/ /\+/g;
1616         return $str;
1617 }
1618
1619 # quote unsafe characters in HTML attributes
1620 sub esc_attr {
1621
1622         # for XHTML conformance escaping '"' to '&quot;' is not enough
1623         return esc_html(@_);
1624 }
1625
1626 # replace invalid utf8 character with SUBSTITUTION sequence
1627 sub esc_html {
1628         my $str = shift;
1629         my %opts = @_;
1630
1631         return undef unless defined $str;
1632
1633         $str = to_utf8($str);
1634         $str = $cgi->escapeHTML($str);
1635         if ($opts{'-nbsp'}) {
1636                 $str =~ s/ /&nbsp;/g;
1637         }
1638         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1639         return $str;
1640 }
1641
1642 # quote control characters and escape filename to HTML
1643 sub esc_path {
1644         my $str = shift;
1645         my %opts = @_;
1646
1647         return undef unless defined $str;
1648
1649         $str = to_utf8($str);
1650         $str = $cgi->escapeHTML($str);
1651         if ($opts{'-nbsp'}) {
1652                 $str =~ s/ /&nbsp;/g;
1653         }
1654         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1655         return $str;
1656 }
1657
1658 # Sanitize for use in XHTML + application/xml+xhtml (valid XML 1.0)
1659 sub sanitize {
1660         my $str = shift;
1661
1662         return undef unless defined $str;
1663
1664         $str = to_utf8($str);
1665         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1666         return $str;
1667 }
1668
1669 # Make control characters "printable", using character escape codes (CEC)
1670 sub quot_cec {
1671         my $cntrl = shift;
1672         my %opts = @_;
1673         my %es = ( # character escape codes, aka escape sequences
1674                 "\t" => '\t',   # tab             (HT)
1675                 "\n" => '\n',   # line feed       (LF)
1676                 "\r" => '\r',   # carriage return (CR)
1677                 "\f" => '\f',   # form feed       (FF)
1678                 "\b" => '\b',   # backspace       (BS)
1679                 "\a" => '\a',   # alarm (bell)    (BEL)
1680                 "\e" => '\e',   # escape          (ESC)
1681                 "\013" => '\v', # vertical tab    (VT)
1682                 "\000" => '\0', # nul character   (NUL)
1683         );
1684         my $chr = ( (exists $es{$cntrl})
1685                     ? $es{$cntrl}
1686                     : sprintf('\%2x', ord($cntrl)) );
1687         if ($opts{-nohtml}) {
1688                 return $chr;
1689         } else {
1690                 return "<span class=\"cntrl\">$chr</span>";
1691         }
1692 }
1693
1694 # Alternatively use unicode control pictures codepoints,
1695 # Unicode "printable representation" (PR)
1696 sub quot_upr {
1697         my $cntrl = shift;
1698         my %opts = @_;
1699
1700         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1701         if ($opts{-nohtml}) {
1702                 return $chr;
1703         } else {
1704                 return "<span class=\"cntrl\">$chr</span>";
1705         }
1706 }
1707
1708 # git may return quoted and escaped filenames
1709 sub unquote {
1710         my $str = shift;
1711
1712         sub unq {
1713                 my $seq = shift;
1714                 my %es = ( # character escape codes, aka escape sequences
1715                         't' => "\t",   # tab            (HT, TAB)
1716                         'n' => "\n",   # newline        (NL)
1717                         'r' => "\r",   # return         (CR)
1718                         'f' => "\f",   # form feed      (FF)
1719                         'b' => "\b",   # backspace      (BS)
1720                         'a' => "\a",   # alarm (bell)   (BEL)
1721                         'e' => "\e",   # escape         (ESC)
1722                         'v' => "\013", # vertical tab   (VT)
1723                 );
1724
1725                 if ($seq =~ m/^[0-7]{1,3}$/) {
1726                         # octal char sequence
1727                         return chr(oct($seq));
1728                 } elsif (exists $es{$seq}) {
1729                         # C escape sequence, aka character escape code
1730                         return $es{$seq};
1731                 }
1732                 # quoted ordinary character
1733                 return $seq;
1734         }
1735
1736         if ($str =~ m/^"(.*)"$/) {
1737                 # needs unquoting
1738                 $str = $1;
1739                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1740         }
1741         return $str;
1742 }
1743
1744 # escape tabs (convert tabs to spaces)
1745 sub untabify {
1746         my $line = shift;
1747
1748         while ((my $pos = index($line, "\t")) != -1) {
1749                 if (my $count = (8 - ($pos % 8))) {
1750                         my $spaces = ' ' x $count;
1751                         $line =~ s/\t/$spaces/;
1752                 }
1753         }
1754
1755         return $line;
1756 }
1757
1758 sub project_in_list {
1759         my $project = shift;
1760         my @list = git_get_projects_list();
1761         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1762 }
1763
1764 ## ----------------------------------------------------------------------
1765 ## HTML aware string manipulation
1766
1767 # Try to chop given string on a word boundary between position
1768 # $len and $len+$add_len. If there is no word boundary there,
1769 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1770 # (marking chopped part) would be longer than given string.
1771 sub chop_str {
1772         my $str = shift;
1773         my $len = shift;
1774         my $add_len = shift || 10;
1775         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1776
1777         # Make sure perl knows it is utf8 encoded so we don't
1778         # cut in the middle of a utf8 multibyte char.
1779         $str = to_utf8($str);
1780
1781         # allow only $len chars, but don't cut a word if it would fit in $add_len
1782         # if it doesn't fit, cut it if it's still longer than the dots we would add
1783         # remove chopped character entities entirely
1784
1785         # when chopping in the middle, distribute $len into left and right part
1786         # return early if chopping wouldn't make string shorter
1787         if ($where eq 'center') {
1788                 return $str if ($len + 5 >= length($str)); # filler is length 5
1789                 $len = int($len/2);
1790         } else {
1791                 return $str if ($len + 4 >= length($str)); # filler is length 4
1792         }
1793
1794         # regexps: ending and beginning with word part up to $add_len
1795         my $endre = qr/.{$len}\w{0,$add_len}/;
1796         my $begre = qr/\w{0,$add_len}.{$len}/;
1797
1798         if ($where eq 'left') {
1799                 $str =~ m/^(.*?)($begre)$/;
1800                 my ($lead, $body) = ($1, $2);
1801                 if (length($lead) > 4) {
1802                         $lead = " ...";
1803                 }
1804                 return "$lead$body";
1805
1806         } elsif ($where eq 'center') {
1807                 $str =~ m/^($endre)(.*)$/;
1808                 my ($left, $str)  = ($1, $2);
1809                 $str =~ m/^(.*?)($begre)$/;
1810                 my ($mid, $right) = ($1, $2);
1811                 if (length($mid) > 5) {
1812                         $mid = " ... ";
1813                 }
1814                 return "$left$mid$right";
1815
1816         } else {
1817                 $str =~ m/^($endre)(.*)$/;
1818                 my $body = $1;
1819                 my $tail = $2;
1820                 if (length($tail) > 4) {
1821                         $tail = "... ";
1822                 }
1823                 return "$body$tail";
1824         }
1825 }
1826
1827 # takes the same arguments as chop_str, but also wraps a <span> around the
1828 # result with a title attribute if it does get chopped. Additionally, the
1829 # string is HTML-escaped.
1830 sub chop_and_escape_str {
1831         my ($str) = @_;
1832
1833         my $chopped = chop_str(@_);
1834         $str = to_utf8($str);
1835         if ($chopped eq $str) {
1836                 return esc_html($chopped);
1837         } else {
1838                 $str =~ s/[[:cntrl:]]/?/g;
1839                 return $cgi->span({-title=>$str}, esc_html($chopped));
1840         }
1841 }
1842
1843 # Highlight selected fragments of string, using given CSS class,
1844 # and escape HTML.  It is assumed that fragments do not overlap.
1845 # Regions are passed as list of pairs (array references).
1846 #
1847 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1848 # '<span class="mark">foo</span>bar'
1849 sub esc_html_hl_regions {
1850         my ($str, $css_class, @sel) = @_;
1851         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1852         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1853         return esc_html($str, %opts) unless @sel;
1854
1855         my $out = '';
1856         my $pos = 0;
1857
1858         for my $s (@sel) {
1859                 my ($begin, $end) = @$s;
1860
1861                 # Don't create empty <span> elements.
1862                 next if $end <= $begin;
1863
1864                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1865                                        %opts);
1866
1867                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1868                         if ($begin - $pos > 0);
1869                 $out .= $cgi->span({-class => $css_class}, $escaped);
1870
1871                 $pos = $end;
1872         }
1873         $out .= esc_html(substr($str, $pos), %opts)
1874                 if ($pos < length($str));
1875
1876         return $out;
1877 }
1878
1879 # return positions of beginning and end of each match
1880 sub matchpos_list {
1881         my ($str, $regexp) = @_;
1882         return unless (defined $str && defined $regexp);
1883
1884         my @matches;
1885         while ($str =~ /$regexp/g) {
1886                 push @matches, [$-[0], $+[0]];
1887         }
1888         return @matches;
1889 }
1890
1891 # highlight match (if any), and escape HTML
1892 sub esc_html_match_hl {
1893         my ($str, $regexp) = @_;
1894         return esc_html($str) unless defined $regexp;
1895
1896         my @matches = matchpos_list($str, $regexp);
1897         return esc_html($str) unless @matches;
1898
1899         return esc_html_hl_regions($str, 'match', @matches);
1900 }
1901
1902
1903 # highlight match (if any) of shortened string, and escape HTML
1904 sub esc_html_match_hl_chopped {
1905         my ($str, $chopped, $regexp) = @_;
1906         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1907
1908         my @matches = matchpos_list($str, $regexp);
1909         return esc_html($chopped) unless @matches;
1910
1911         # filter matches so that we mark chopped string
1912         my $tail = "... "; # see chop_str
1913         unless ($chopped =~ s/\Q$tail\E$//) {
1914                 $tail = '';
1915         }
1916         my $chop_len = length($chopped);
1917         my $tail_len = length($tail);
1918         my @filtered;
1919
1920         for my $m (@matches) {
1921                 if ($m->[0] > $chop_len) {
1922                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1923                         last;
1924                 } elsif ($m->[1] > $chop_len) {
1925                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1926                         last;
1927                 }
1928                 push @filtered, $m;
1929         }
1930
1931         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1932 }
1933
1934 ## ----------------------------------------------------------------------
1935 ## functions returning short strings
1936
1937 # CSS class for given age value (in seconds)
1938 sub age_class {
1939         my $age = shift;
1940
1941         if (!defined $age) {
1942                 return "noage";
1943         } elsif ($age < 60*60*2) {
1944                 return "age0";
1945         } elsif ($age < 60*60*24*2) {
1946                 return "age1";
1947         } else {
1948                 return "age2";
1949         }
1950 }
1951
1952 # convert age in seconds to "nn units ago" string
1953 sub age_string {
1954         my $age = shift;
1955         my $age_str;
1956
1957         if ($age > 60*60*24*365*2) {
1958                 $age_str = (int $age/60/60/24/365);
1959                 $age_str .= " years ago";
1960         } elsif ($age > 60*60*24*(365/12)*2) {
1961                 $age_str = int $age/60/60/24/(365/12);
1962                 $age_str .= " months ago";
1963         } elsif ($age > 60*60*24*7*2) {
1964                 $age_str = int $age/60/60/24/7;
1965                 $age_str .= " weeks ago";
1966         } elsif ($age > 60*60*24*2) {
1967                 $age_str = int $age/60/60/24;
1968                 $age_str .= " days ago";
1969         } elsif ($age > 60*60*2) {
1970                 $age_str = int $age/60/60;
1971                 $age_str .= " hours ago";
1972         } elsif ($age > 60*2) {
1973                 $age_str = int $age/60;
1974                 $age_str .= " min ago";
1975         } elsif ($age > 2) {
1976                 $age_str = int $age;
1977                 $age_str .= " sec ago";
1978         } else {
1979                 $age_str .= " right now";
1980         }
1981         return $age_str;
1982 }
1983
1984 use constant {
1985         S_IFINVALID => 0030000,
1986         S_IFGITLINK => 0160000,
1987 };
1988
1989 # submodule/subproject, a commit object reference
1990 sub S_ISGITLINK {
1991         my $mode = shift;
1992
1993         return (($mode & S_IFMT) == S_IFGITLINK)
1994 }
1995
1996 # convert file mode in octal to symbolic file mode string
1997 sub mode_str {
1998         my $mode = oct shift;
1999
2000         if (S_ISGITLINK($mode)) {
2001                 return 'm---------';
2002         } elsif (S_ISDIR($mode & S_IFMT)) {
2003                 return 'drwxr-xr-x';
2004         } elsif (S_ISLNK($mode)) {
2005                 return 'lrwxrwxrwx';
2006         } elsif (S_ISREG($mode)) {
2007                 # git cares only about the executable bit
2008                 if ($mode & S_IXUSR) {
2009                         return '-rwxr-xr-x';
2010                 } else {
2011                         return '-rw-r--r--';
2012                 };
2013         } else {
2014                 return '----------';
2015         }
2016 }
2017
2018 # convert file mode in octal to file type string
2019 sub file_type {
2020         my $mode = shift;
2021
2022         if ($mode !~ m/^[0-7]+$/) {
2023                 return $mode;
2024         } else {
2025                 $mode = oct $mode;
2026         }
2027
2028         if (S_ISGITLINK($mode)) {
2029                 return "submodule";
2030         } elsif (S_ISDIR($mode & S_IFMT)) {
2031                 return "directory";
2032         } elsif (S_ISLNK($mode)) {
2033                 return "symlink";
2034         } elsif (S_ISREG($mode)) {
2035                 return "file";
2036         } else {
2037                 return "unknown";
2038         }
2039 }
2040
2041 # convert file mode in octal to file type description string
2042 sub file_type_long {
2043         my $mode = shift;
2044
2045         if ($mode !~ m/^[0-7]+$/) {
2046                 return $mode;
2047         } else {
2048                 $mode = oct $mode;
2049         }
2050
2051         if (S_ISGITLINK($mode)) {
2052                 return "submodule";
2053         } elsif (S_ISDIR($mode & S_IFMT)) {
2054                 return "directory";
2055         } elsif (S_ISLNK($mode)) {
2056                 return "symlink";
2057         } elsif (S_ISREG($mode)) {
2058                 if ($mode & S_IXUSR) {
2059                         return "executable";
2060                 } else {
2061                         return "file";
2062                 };
2063         } else {
2064                 return "unknown";
2065         }
2066 }
2067
2068
2069 ## ----------------------------------------------------------------------
2070 ## functions returning short HTML fragments, or transforming HTML fragments
2071 ## which don't belong to other sections
2072
2073 # format line of commit message.
2074 sub format_log_line_html {
2075         my $line = shift;
2076
2077         # Potentially abbreviated OID.
2078         my $regex = oid_nlen_regex("7,64");
2079
2080         $line = esc_html($line, -nbsp=>1);
2081         $line =~ s{
2082         \b
2083         (
2084             # The output of "git describe", e.g. v2.10.0-297-gf6727b0
2085             # or hadoop-20160921-113441-20-g094fb7d
2086             (?<!-) # see strbuf_check_tag_ref(). Tags can't start with -
2087             [A-Za-z0-9.-]+
2088             (?!\.) # refs can't end with ".", see check_refname_format()
2089             -g$regex
2090             |
2091             # Just a normal looking Git SHA1
2092             $regex
2093         )
2094         \b
2095     }{
2096                 $cgi->a({-href => href(action=>"object", hash=>$1),
2097                                         -class => "text"}, $1);
2098         }egx;
2099
2100         return $line;
2101 }
2102
2103 # format marker of refs pointing to given object
2104
2105 # the destination action is chosen based on object type and current context:
2106 # - for annotated tags, we choose the tag view unless it's the current view
2107 #   already, in which case we go to shortlog view
2108 # - for other refs, we keep the current view if we're in history, shortlog or
2109 #   log view, and select shortlog otherwise
2110 sub format_ref_marker {
2111         my ($refs, $id) = @_;
2112         my $markers = '';
2113
2114         if (defined $refs->{$id}) {
2115                 foreach my $ref (@{$refs->{$id}}) {
2116                         # this code exploits the fact that non-lightweight tags are the
2117                         # only indirect objects, and that they are the only objects for which
2118                         # we want to use tag instead of shortlog as action
2119                         my ($type, $name) = qw();
2120                         my $indirect = ($ref =~ s/\^\{\}$//);
2121                         # e.g. tags/v2.6.11 or heads/next
2122                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2123                                 $type = $1;
2124                                 $name = $2;
2125                         } else {
2126                                 $type = "ref";
2127                                 $name = $ref;
2128                         }
2129
2130                         my $class = $type;
2131                         $class .= " indirect" if $indirect;
2132
2133                         my $dest_action = "shortlog";
2134
2135                         if ($indirect) {
2136                                 $dest_action = "tag" unless $action eq "tag";
2137                         } elsif ($action =~ /^(history|(short)?log)$/) {
2138                                 $dest_action = $action;
2139                         }
2140
2141                         my $dest = "";
2142                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2143                         $dest .= $ref;
2144
2145                         my $link = $cgi->a({
2146                                 -href => href(
2147                                         action=>$dest_action,
2148                                         hash=>$dest
2149                                 )}, esc_html($name));
2150
2151                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2152                                 $link . "</span>";
2153                 }
2154         }
2155
2156         if ($markers) {
2157                 return ' <span class="refs">'. $markers . '</span>';
2158         } else {
2159                 return "";
2160         }
2161 }
2162
2163 # format, perhaps shortened and with markers, title line
2164 sub format_subject_html {
2165         my ($long, $short, $href, $extra) = @_;
2166         $extra = '' unless defined($extra);
2167
2168         if (length($short) < length($long)) {
2169                 $long =~ s/[[:cntrl:]]/?/g;
2170                 return $cgi->a({-href => $href, -class => "list subject",
2171                                 -title => to_utf8($long)},
2172                        esc_html($short)) . $extra;
2173         } else {
2174                 return $cgi->a({-href => $href, -class => "list subject"},
2175                        esc_html($long)) . $extra;
2176         }
2177 }
2178
2179 # Rather than recomputing the url for an email multiple times, we cache it
2180 # after the first hit. This gives a visible benefit in views where the avatar
2181 # for the same email is used repeatedly (e.g. shortlog).
2182 # The cache is shared by all avatar engines (currently gravatar only), which
2183 # are free to use it as preferred. Since only one avatar engine is used for any
2184 # given page, there's no risk for cache conflicts.
2185 our %avatar_cache = ();
2186
2187 # Compute the picon url for a given email, by using the picon search service over at
2188 # http://www.cs.indiana.edu/picons/search.html
2189 sub picon_url {
2190         my $email = lc shift;
2191         if (!$avatar_cache{$email}) {
2192                 my ($user, $domain) = split('@', $email);
2193                 $avatar_cache{$email} =
2194                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2195                         "$domain/$user/" .
2196                         "users+domains+unknown/up/single";
2197         }
2198         return $avatar_cache{$email};
2199 }
2200
2201 # Compute the gravatar url for a given email, if it's not in the cache already.
2202 # Gravatar stores only the part of the URL before the size, since that's the
2203 # one computationally more expensive. This also allows reuse of the cache for
2204 # different sizes (for this particular engine).
2205 sub gravatar_url {
2206         my $email = lc shift;
2207         my $size = shift;
2208         $avatar_cache{$email} ||=
2209                 "//www.gravatar.com/avatar/" .
2210                         md5_hex($email) . "?s=";
2211         return $avatar_cache{$email} . $size;
2212 }
2213
2214 # Insert an avatar for the given $email at the given $size if the feature
2215 # is enabled.
2216 sub git_get_avatar {
2217         my ($email, %opts) = @_;
2218         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2219         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2220         $opts{-size} ||= 'default';
2221         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2222         my $url = "";
2223         if ($git_avatar eq 'gravatar') {
2224                 $url = gravatar_url($email, $size);
2225         } elsif ($git_avatar eq 'picon') {
2226                 $url = picon_url($email);
2227         }
2228         # Other providers can be added by extending the if chain, defining $url
2229         # as needed. If no variant puts something in $url, we assume avatars
2230         # are completely disabled/unavailable.
2231         if ($url) {
2232                 return $pre_white .
2233                        "<img width=\"$size\" " .
2234                             "class=\"avatar\" " .
2235                             "src=\"".esc_url($url)."\" " .
2236                             "alt=\"\" " .
2237                        "/>" . $post_white;
2238         } else {
2239                 return "";
2240         }
2241 }
2242
2243 sub format_search_author {
2244         my ($author, $searchtype, $displaytext) = @_;
2245         my $have_search = gitweb_check_feature('search');
2246
2247         if ($have_search) {
2248                 my $performed = "";
2249                 if ($searchtype eq 'author') {
2250                         $performed = "authored";
2251                 } elsif ($searchtype eq 'committer') {
2252                         $performed = "committed";
2253                 }
2254
2255                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2256                                 searchtext=>$author,
2257                                 searchtype=>$searchtype), class=>"list",
2258                                 title=>"Search for commits $performed by $author"},
2259                                 $displaytext);
2260
2261         } else {
2262                 return $displaytext;
2263         }
2264 }
2265
2266 # format the author name of the given commit with the given tag
2267 # the author name is chopped and escaped according to the other
2268 # optional parameters (see chop_str).
2269 sub format_author_html {
2270         my $tag = shift;
2271         my $co = shift;
2272         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2273         return "<$tag class=\"author\">" .
2274                format_search_author($co->{'author_name'}, "author",
2275                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2276                        $author) .
2277                "</$tag>";
2278 }
2279
2280 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2281 sub format_git_diff_header_line {
2282         my $line = shift;
2283         my $diffinfo = shift;
2284         my ($from, $to) = @_;
2285
2286         if ($diffinfo->{'nparents'}) {
2287                 # combined diff
2288                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2289                 if ($to->{'href'}) {
2290                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2291                                          esc_path($to->{'file'}));
2292                 } else { # file was deleted (no href)
2293                         $line .= esc_path($to->{'file'});
2294                 }
2295         } else {
2296                 # "ordinary" diff
2297                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2298                 if ($from->{'href'}) {
2299                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2300                                          'a/' . esc_path($from->{'file'}));
2301                 } else { # file was added (no href)
2302                         $line .= 'a/' . esc_path($from->{'file'});
2303                 }
2304                 $line .= ' ';
2305                 if ($to->{'href'}) {
2306                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2307                                          'b/' . esc_path($to->{'file'}));
2308                 } else { # file was deleted
2309                         $line .= 'b/' . esc_path($to->{'file'});
2310                 }
2311         }
2312
2313         return "<div class=\"diff header\">$line</div>\n";
2314 }
2315
2316 # format extended diff header line, before patch itself
2317 sub format_extended_diff_header_line {
2318         my $line = shift;
2319         my $diffinfo = shift;
2320         my ($from, $to) = @_;
2321
2322         # match <path>
2323         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2324                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2325                                        esc_path($from->{'file'}));
2326         }
2327         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2328                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2329                                  esc_path($to->{'file'}));
2330         }
2331         # match single <mode>
2332         if ($line =~ m/\s(\d{6})$/) {
2333                 $line .= '<span class="info"> (' .
2334                          file_type_long($1) .
2335                          ')</span>';
2336         }
2337         # match <hash>
2338         if ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", ",") |
2339             $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", ",")) {
2340                 # can match only for combined diff
2341                 $line = 'index ';
2342                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2343                         if ($from->{'href'}[$i]) {
2344                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2345                                                   -class=>"hash"},
2346                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2347                         } else {
2348                                 $line .= '0' x 7;
2349                         }
2350                         # separator
2351                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2352                 }
2353                 $line .= '..';
2354                 if ($to->{'href'}) {
2355                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2356                                          substr($diffinfo->{'to_id'},0,7));
2357                 } else {
2358                         $line .= '0' x 7;
2359                 }
2360
2361         } elsif ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", "..") |
2362                  $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", "..")) {
2363                 # can match only for ordinary diff
2364                 my ($from_link, $to_link);
2365                 if ($from->{'href'}) {
2366                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2367                                              substr($diffinfo->{'from_id'},0,7));
2368                 } else {
2369                         $from_link = '0' x 7;
2370                 }
2371                 if ($to->{'href'}) {
2372                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2373                                            substr($diffinfo->{'to_id'},0,7));
2374                 } else {
2375                         $to_link = '0' x 7;
2376                 }
2377                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2378                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2379         }
2380
2381         return $line . "<br/>\n";
2382 }
2383
2384 # format from-file/to-file diff header
2385 sub format_diff_from_to_header {
2386         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2387         my $line;
2388         my $result = '';
2389
2390         $line = $from_line;
2391         #assert($line =~ m/^---/) if DEBUG;
2392         # no extra formatting for "^--- /dev/null"
2393         if (! $diffinfo->{'nparents'}) {
2394                 # ordinary (single parent) diff
2395                 if ($line =~ m!^--- "?a/!) {
2396                         if ($from->{'href'}) {
2397                                 $line = '--- a/' .
2398                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2399                                                 esc_path($from->{'file'}));
2400                         } else {
2401                                 $line = '--- a/' .
2402                                         esc_path($from->{'file'});
2403                         }
2404                 }
2405                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2406
2407         } else {
2408                 # combined diff (merge commit)
2409                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2410                         if ($from->{'href'}[$i]) {
2411                                 $line = '--- ' .
2412                                         $cgi->a({-href=>href(action=>"blobdiff",
2413                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2414                                                              hash_parent_base=>$parents[$i],
2415                                                              file_parent=>$from->{'file'}[$i],
2416                                                              hash=>$diffinfo->{'to_id'},
2417                                                              hash_base=>$hash,
2418                                                              file_name=>$to->{'file'}),
2419                                                  -class=>"path",
2420                                                  -title=>"diff" . ($i+1)},
2421                                                 $i+1) .
2422                                         '/' .
2423                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2424                                                 esc_path($from->{'file'}[$i]));
2425                         } else {
2426                                 $line = '--- /dev/null';
2427                         }
2428                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2429                 }
2430         }
2431
2432         $line = $to_line;
2433         #assert($line =~ m/^\+\+\+/) if DEBUG;
2434         # no extra formatting for "^+++ /dev/null"
2435         if ($line =~ m!^\+\+\+ "?b/!) {
2436                 if ($to->{'href'}) {
2437                         $line = '+++ b/' .
2438                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2439                                         esc_path($to->{'file'}));
2440                 } else {
2441                         $line = '+++ b/' .
2442                                 esc_path($to->{'file'});
2443                 }
2444         }
2445         $result .= qq!<div class="diff to_file">$line</div>\n!;
2446
2447         return $result;
2448 }
2449
2450 # create note for patch simplified by combined diff
2451 sub format_diff_cc_simplified {
2452         my ($diffinfo, @parents) = @_;
2453         my $result = '';
2454
2455         $result .= "<div class=\"diff header\">" .
2456                    "diff --cc ";
2457         if (!is_deleted($diffinfo)) {
2458                 $result .= $cgi->a({-href => href(action=>"blob",
2459                                                   hash_base=>$hash,
2460                                                   hash=>$diffinfo->{'to_id'},
2461                                                   file_name=>$diffinfo->{'to_file'}),
2462                                     -class => "path"},
2463                                    esc_path($diffinfo->{'to_file'}));
2464         } else {
2465                 $result .= esc_path($diffinfo->{'to_file'});
2466         }
2467         $result .= "</div>\n" . # class="diff header"
2468                    "<div class=\"diff nodifferences\">" .
2469                    "Simple merge" .
2470                    "</div>\n"; # class="diff nodifferences"
2471
2472         return $result;
2473 }
2474
2475 sub diff_line_class {
2476         my ($line, $from, $to) = @_;
2477
2478         # ordinary diff
2479         my $num_sign = 1;
2480         # combined diff
2481         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2482                 $num_sign = scalar @{$from->{'href'}};
2483         }
2484
2485         my @diff_line_classifier = (
2486                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2487                 { regexp => qr/^\\/,               class => "incomplete"  },
2488                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2489                 # classifier for context must come before classifier add/rem,
2490                 # or we would have to use more complicated regexp, for example
2491                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2492                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2493                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2494         );
2495         for my $clsfy (@diff_line_classifier) {
2496                 return $clsfy->{'class'}
2497                         if ($line =~ $clsfy->{'regexp'});
2498         }
2499
2500         # fallback
2501         return "";
2502 }
2503
2504 # assumes that $from and $to are defined and correctly filled,
2505 # and that $line holds a line of chunk header for unified diff
2506 sub format_unidiff_chunk_header {
2507         my ($line, $from, $to) = @_;
2508
2509         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2510                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2511
2512         $from_lines = 0 unless defined $from_lines;
2513         $to_lines   = 0 unless defined $to_lines;
2514
2515         if ($from->{'href'}) {
2516                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2517                                      -class=>"list"}, $from_text);
2518         }
2519         if ($to->{'href'}) {
2520                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2521                                      -class=>"list"}, $to_text);
2522         }
2523         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2524                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2525         return $line;
2526 }
2527
2528 # assumes that $from and $to are defined and correctly filled,
2529 # and that $line holds a line of chunk header for combined diff
2530 sub format_cc_diff_chunk_header {
2531         my ($line, $from, $to) = @_;
2532
2533         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2534         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2535
2536         @from_text = split(' ', $ranges);
2537         for (my $i = 0; $i < @from_text; ++$i) {
2538                 ($from_start[$i], $from_nlines[$i]) =
2539                         (split(',', substr($from_text[$i], 1)), 0);
2540         }
2541
2542         $to_text   = pop @from_text;
2543         $to_start  = pop @from_start;
2544         $to_nlines = pop @from_nlines;
2545
2546         $line = "<span class=\"chunk_info\">$prefix ";
2547         for (my $i = 0; $i < @from_text; ++$i) {
2548                 if ($from->{'href'}[$i]) {
2549                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2550                                           -class=>"list"}, $from_text[$i]);
2551                 } else {
2552                         $line .= $from_text[$i];
2553                 }
2554                 $line .= " ";
2555         }
2556         if ($to->{'href'}) {
2557                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2558                                   -class=>"list"}, $to_text);
2559         } else {
2560                 $line .= $to_text;
2561         }
2562         $line .= " $prefix</span>" .
2563                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2564         return $line;
2565 }
2566
2567 # process patch (diff) line (not to be used for diff headers),
2568 # returning HTML-formatted (but not wrapped) line.
2569 # If the line is passed as a reference, it is treated as HTML and not
2570 # esc_html()'ed.
2571 sub format_diff_line {
2572         my ($line, $diff_class, $from, $to) = @_;
2573
2574         if (ref($line)) {
2575                 $line = $$line;
2576         } else {
2577                 chomp $line;
2578                 $line = untabify($line);
2579
2580                 if ($from && $to && $line =~ m/^\@{2} /) {
2581                         $line = format_unidiff_chunk_header($line, $from, $to);
2582                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2583                         $line = format_cc_diff_chunk_header($line, $from, $to);
2584                 } else {
2585                         $line = esc_html($line, -nbsp=>1);
2586                 }
2587         }
2588
2589         my $diff_classes = "diff";
2590         $diff_classes .= " $diff_class" if ($diff_class);
2591         $line = "<div class=\"$diff_classes\">$line</div>\n";
2592
2593         return $line;
2594 }
2595
2596 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2597 # linked.  Pass the hash of the tree/commit to snapshot.
2598 sub format_snapshot_links {
2599         my ($hash) = @_;
2600         my $num_fmts = @snapshot_fmts;
2601         if ($num_fmts > 1) {
2602                 # A parenthesized list of links bearing format names.
2603                 # e.g. "snapshot (_tar.gz_ _zip_)"
2604                 return "snapshot (" . join(' ', map
2605                         $cgi->a({
2606                                 -href => href(
2607                                         action=>"snapshot",
2608                                         hash=>$hash,
2609                                         snapshot_format=>$_
2610                                 )
2611                         }, $known_snapshot_formats{$_}{'display'})
2612                 , @snapshot_fmts) . ")";
2613         } elsif ($num_fmts == 1) {
2614                 # A single "snapshot" link whose tooltip bears the format name.
2615                 # i.e. "_snapshot_"
2616                 my ($fmt) = @snapshot_fmts;
2617                 return
2618                         $cgi->a({
2619                                 -href => href(
2620                                         action=>"snapshot",
2621                                         hash=>$hash,
2622                                         snapshot_format=>$fmt
2623                                 ),
2624                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2625                         }, "snapshot");
2626         } else { # $num_fmts == 0
2627                 return undef;
2628         }
2629 }
2630
2631 ## ......................................................................
2632 ## functions returning values to be passed, perhaps after some
2633 ## transformation, to other functions; e.g. returning arguments to href()
2634
2635 # returns hash to be passed to href to generate gitweb URL
2636 # in -title key it returns description of link
2637 sub get_feed_info {
2638         my $format = shift || 'Atom';
2639         my %res = (action => lc($format));
2640         my $matched_ref = 0;
2641
2642         # feed links are possible only for project views
2643         return unless (defined $project);
2644         # some views should link to OPML, or to generic project feed,
2645         # or don't have specific feed yet (so they should use generic)
2646         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2647
2648         my $branch = undef;
2649         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2650         # (fullname) to differentiate from tag links; this also makes
2651         # possible to detect branch links
2652         for my $ref (get_branch_refs()) {
2653                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2654                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2655                         $branch = $1;
2656                         $matched_ref = $ref;
2657                         last;
2658                 }
2659         }
2660         # find log type for feed description (title)
2661         my $type = 'log';
2662         if (defined $file_name) {
2663                 $type  = "history of $file_name";
2664                 $type .= "/" if ($action eq 'tree');
2665                 $type .= " on '$branch'" if (defined $branch);
2666         } else {
2667                 $type = "log of $branch" if (defined $branch);
2668         }
2669
2670         $res{-title} = $type;
2671         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2672         $res{'file_name'} = $file_name;
2673
2674         return %res;
2675 }
2676
2677 ## ----------------------------------------------------------------------
2678 ## git utility subroutines, invoking git commands
2679
2680 # returns path to the core git executable and the --git-dir parameter as list
2681 sub git_cmd {
2682         $number_of_git_cmds++;
2683         return $GIT, '--git-dir='.$git_dir;
2684 }
2685
2686 # quote the given arguments for passing them to the shell
2687 # quote_command("command", "arg 1", "arg with ' and ! characters")
2688 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2689 # Try to avoid using this function wherever possible.
2690 sub quote_command {
2691         return join(' ',
2692                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2693 }
2694
2695 # get HEAD ref of given project as hash
2696 sub git_get_head_hash {
2697         return git_get_full_hash(shift, 'HEAD');
2698 }
2699
2700 sub git_get_full_hash {
2701         return git_get_hash(@_);
2702 }
2703
2704 sub git_get_short_hash {
2705         return git_get_hash(@_, '--short=7');
2706 }
2707
2708 sub git_get_hash {
2709         my ($project, $hash, @options) = @_;
2710         my $o_git_dir = $git_dir;
2711         my $retval = undef;
2712         $git_dir = "$projectroot/$project";
2713         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2714             '--verify', '-q', @options, $hash) {
2715                 $retval = <$fd>;
2716                 chomp $retval if defined $retval;
2717                 close $fd;
2718         }
2719         if (defined $o_git_dir) {
2720                 $git_dir = $o_git_dir;
2721         }
2722         return $retval;
2723 }
2724
2725 # get type of given object
2726 sub git_get_type {
2727         my $hash = shift;
2728
2729         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2730         my $type = <$fd>;
2731         close $fd or return;
2732         chomp $type;
2733         return $type;
2734 }
2735
2736 # repository configuration
2737 our $config_file = '';
2738 our %config;
2739
2740 # store multiple values for single key as anonymous array reference
2741 # single values stored directly in the hash, not as [ <value> ]
2742 sub hash_set_multi {
2743         my ($hash, $key, $value) = @_;
2744
2745         if (!exists $hash->{$key}) {
2746                 $hash->{$key} = $value;
2747         } elsif (!ref $hash->{$key}) {
2748                 $hash->{$key} = [ $hash->{$key}, $value ];
2749         } else {
2750                 push @{$hash->{$key}}, $value;
2751         }
2752 }
2753
2754 # return hash of git project configuration
2755 # optionally limited to some section, e.g. 'gitweb'
2756 sub git_parse_project_config {
2757         my $section_regexp = shift;
2758         my %config;
2759
2760         local $/ = "\0";
2761
2762         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2763                 or return;
2764
2765         while (my $keyval = <$fh>) {
2766                 chomp $keyval;
2767                 my ($key, $value) = split(/\n/, $keyval, 2);
2768
2769                 hash_set_multi(\%config, $key, $value)
2770                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2771         }
2772         close $fh;
2773
2774         return %config;
2775 }
2776
2777 # convert config value to boolean: 'true' or 'false'
2778 # no value, number > 0, 'true' and 'yes' values are true
2779 # rest of values are treated as false (never as error)
2780 sub config_to_bool {
2781         my $val = shift;
2782
2783         return 1 if !defined $val;             # section.key
2784
2785         # strip leading and trailing whitespace
2786         $val =~ s/^\s+//;
2787         $val =~ s/\s+$//;
2788
2789         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2790                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2791 }
2792
2793 # convert config value to simple decimal number
2794 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2795 # to be multiplied by 1024, 1048576, or 1073741824
2796 sub config_to_int {
2797         my $val = shift;
2798
2799         # strip leading and trailing whitespace
2800         $val =~ s/^\s+//;
2801         $val =~ s/\s+$//;
2802
2803         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2804                 $unit = lc($unit);
2805                 # unknown unit is treated as 1
2806                 return $num * ($unit eq 'g' ? 1073741824 :
2807                                $unit eq 'm' ?    1048576 :
2808                                $unit eq 'k' ?       1024 : 1);
2809         }
2810         return $val;
2811 }
2812
2813 # convert config value to array reference, if needed
2814 sub config_to_multi {
2815         my $val = shift;
2816
2817         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2818 }
2819
2820 sub git_get_project_config {
2821         my ($key, $type) = @_;
2822
2823         return unless defined $git_dir;
2824
2825         # key sanity check
2826         return unless ($key);
2827         # only subsection, if exists, is case sensitive,
2828         # and not lowercased by 'git config -z -l'
2829         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2830                 $lo =~ s/_//g;
2831                 $key = join(".", lc($hi), $mi, lc($lo));
2832                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2833         } else {
2834                 $key = lc($key);
2835                 $key =~ s/_//g;
2836                 return if ($key =~ /\W/);
2837         }
2838         $key =~ s/^gitweb\.//;
2839
2840         # type sanity check
2841         if (defined $type) {
2842                 $type =~ s/^--//;
2843                 $type = undef
2844                         unless ($type eq 'bool' || $type eq 'int');
2845         }
2846
2847         # get config
2848         if (!defined $config_file ||
2849             $config_file ne "$git_dir/config") {
2850                 %config = git_parse_project_config('gitweb');
2851                 $config_file = "$git_dir/config";
2852         }
2853
2854         # check if config variable (key) exists
2855         return unless exists $config{"gitweb.$key"};
2856
2857         # ensure given type
2858         if (!defined $type) {
2859                 return $config{"gitweb.$key"};
2860         } elsif ($type eq 'bool') {
2861                 # backward compatibility: 'git config --bool' returns true/false
2862                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2863         } elsif ($type eq 'int') {
2864                 return config_to_int($config{"gitweb.$key"});
2865         }
2866         return $config{"gitweb.$key"};
2867 }
2868
2869 # get hash of given path at given ref
2870 sub git_get_hash_by_path {
2871         my $base = shift;
2872         my $path = shift || return undef;
2873         my $type = shift;
2874
2875         $path =~ s,/+$,,;
2876
2877         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2878                 or die_error(500, "Open git-ls-tree failed");
2879         my $line = <$fd>;
2880         close $fd or return undef;
2881
2882         if (!defined $line) {
2883                 # there is no tree or hash given by $path at $base
2884                 return undef;
2885         }
2886
2887         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2888         $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/;
2889         if (defined $type && $type ne $2) {
2890                 # type doesn't match
2891                 return undef;
2892         }
2893         return $3;
2894 }
2895
2896 # get path of entry with given hash at given tree-ish (ref)
2897 # used to get 'from' filename for combined diff (merge commit) for renames
2898 sub git_get_path_by_hash {
2899         my $base = shift || return;
2900         my $hash = shift || return;
2901
2902         local $/ = "\0";
2903
2904         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2905                 or return undef;
2906         while (my $line = <$fd>) {
2907                 chomp $line;
2908
2909                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2910                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2911                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2912                         close $fd;
2913                         return $1;
2914                 }
2915         }
2916         close $fd;
2917         return undef;
2918 }
2919
2920 ## ......................................................................
2921 ## git utility functions, directly accessing git repository
2922
2923 # get the value of config variable either from file named as the variable
2924 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2925 # configuration variable in the repository config file.
2926 sub git_get_file_or_project_config {
2927         my ($path, $name) = @_;
2928
2929         $git_dir = "$projectroot/$path";
2930         open my $fd, '<', "$git_dir/$name"
2931                 or return git_get_project_config($name);
2932         my $conf = <$fd>;
2933         close $fd;
2934         if (defined $conf) {
2935                 chomp $conf;
2936         }
2937         return $conf;
2938 }
2939
2940 sub git_get_project_description {
2941         my $path = shift;
2942         return git_get_file_or_project_config($path, 'description');
2943 }
2944
2945 sub git_get_project_category {
2946         my $path = shift;
2947         return git_get_file_or_project_config($path, 'category');
2948 }
2949
2950
2951 # supported formats:
2952 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2953 #   - if its contents is a number, use it as tag weight,
2954 #   - otherwise add a tag with weight 1
2955 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2956 #   the same value multiple times increases tag weight
2957 # * `gitweb.ctag' multi-valued repo config variable
2958 sub git_get_project_ctags {
2959         my $project = shift;
2960         my $ctags = {};
2961
2962         $git_dir = "$projectroot/$project";
2963         if (opendir my $dh, "$git_dir/ctags") {
2964                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2965                 foreach my $tagfile (@files) {
2966                         open my $ct, '<', $tagfile
2967                                 or next;
2968                         my $val = <$ct>;
2969                         chomp $val if $val;
2970                         close $ct;
2971
2972                         (my $ctag = $tagfile) =~ s#.*/##;
2973                         if ($val =~ /^\d+$/) {
2974                                 $ctags->{$ctag} = $val;
2975                         } else {
2976                                 $ctags->{$ctag} = 1;
2977                         }
2978                 }
2979                 closedir $dh;
2980
2981         } elsif (open my $fh, '<', "$git_dir/ctags") {
2982                 while (my $line = <$fh>) {
2983                         chomp $line;
2984                         $ctags->{$line}++ if $line;
2985                 }
2986                 close $fh;
2987
2988         } else {
2989                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2990                 foreach my $tag (@$taglist) {
2991                         $ctags->{$tag}++;
2992                 }
2993         }
2994
2995         return $ctags;
2996 }
2997
2998 # return hash, where keys are content tags ('ctags'),
2999 # and values are sum of weights of given tag in every project
3000 sub git_gather_all_ctags {
3001         my $projects = shift;
3002         my $ctags = {};
3003
3004         foreach my $p (@$projects) {
3005                 foreach my $ct (keys %{$p->{'ctags'}}) {
3006                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
3007                 }
3008         }
3009
3010         return $ctags;
3011 }
3012
3013 sub git_populate_project_tagcloud {
3014         my $ctags = shift;
3015
3016         # First, merge different-cased tags; tags vote on casing
3017         my %ctags_lc;
3018         foreach (keys %$ctags) {
3019                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
3020                 if (not $ctags_lc{lc $_}->{topcount}
3021                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
3022                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
3023                         $ctags_lc{lc $_}->{topname} = $_;
3024                 }
3025         }
3026
3027         my $cloud;
3028         my $matched = $input_params{'ctag'};
3029         if (eval { require HTML::TagCloud; 1; }) {
3030                 $cloud = HTML::TagCloud->new;
3031                 foreach my $ctag (sort keys %ctags_lc) {
3032                         # Pad the title with spaces so that the cloud looks
3033                         # less crammed.
3034                         my $title = esc_html($ctags_lc{$ctag}->{topname});
3035                         $title =~ s/ /&nbsp;/g;
3036                         $title =~ s/^/&nbsp;/g;
3037                         $title =~ s/$/&nbsp;/g;
3038                         if (defined $matched && $matched eq $ctag) {
3039                                 $title = qq(<span class="match">$title</span>);
3040                         }
3041                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
3042                                     $ctags_lc{$ctag}->{count});
3043                 }
3044         } else {
3045                 $cloud = {};
3046                 foreach my $ctag (keys %ctags_lc) {
3047                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3048                         if (defined $matched && $matched eq $ctag) {
3049                                 $title = qq(<span class="match">$title</span>);
3050                         }
3051                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3052                         $cloud->{$ctag}{ctag} =
3053                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3054                 }
3055         }
3056         return $cloud;
3057 }
3058
3059 sub git_show_project_tagcloud {
3060         my ($cloud, $count) = @_;
3061         if (ref $cloud eq 'HTML::TagCloud') {
3062                 return $cloud->html_and_css($count);
3063         } else {
3064                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3065                 return
3066                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3067                         join (', ', map {
3068                                 $cloud->{$_}->{'ctag'}
3069                         } splice(@tags, 0, $count)) .
3070                         '</div>';
3071         }
3072 }
3073
3074 sub git_get_project_url_list {
3075         my $path = shift;
3076
3077         $git_dir = "$projectroot/$path";
3078         open my $fd, '<', "$git_dir/cloneurl"
3079                 or return wantarray ?
3080                 @{ config_to_multi(git_get_project_config('url')) } :
3081                    config_to_multi(git_get_project_config('url'));
3082         my @git_project_url_list = map { chomp; $_ } <$fd>;
3083         close $fd;
3084
3085         return wantarray ? @git_project_url_list : \@git_project_url_list;
3086 }
3087
3088 sub git_get_projects_list {
3089         my $filter = shift || '';
3090         my $paranoid = shift;
3091         my @list;
3092
3093         if (-d $projects_list) {
3094                 # search in directory
3095                 my $dir = $projects_list;
3096                 # remove the trailing "/"
3097                 $dir =~ s!/+$!!;
3098                 my $pfxlen = length("$dir");
3099                 my $pfxdepth = ($dir =~ tr!/!!);
3100                 # when filtering, search only given subdirectory
3101                 if ($filter && !$paranoid) {
3102                         $dir .= "/$filter";
3103                         $dir =~ s!/+$!!;
3104                 }
3105
3106                 File::Find::find({
3107                         follow_fast => 1, # follow symbolic links
3108                         follow_skip => 2, # ignore duplicates
3109                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3110                         wanted => sub {
3111                                 # global variables
3112                                 our $project_maxdepth;
3113                                 our $projectroot;
3114                                 # skip project-list toplevel, if we get it.
3115                                 return if (m!^[/.]$!);
3116                                 # only directories can be git repositories
3117                                 return unless (-d $_);
3118                                 # need search permission
3119                                 return unless (-x $_);
3120                                 # don't traverse too deep (Find is super slow on os x)
3121                                 # $project_maxdepth excludes depth of $projectroot
3122                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3123                                         $File::Find::prune = 1;
3124                                         return;
3125                                 }
3126
3127                                 my $path = substr($File::Find::name, $pfxlen + 1);
3128                                 # paranoidly only filter here
3129                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3130                                         next;
3131                                 }
3132                                 # we check related file in $projectroot
3133                                 if (check_export_ok("$projectroot/$path")) {
3134                                         push @list, { path => $path };
3135                                         $File::Find::prune = 1;
3136                                 }
3137                         },
3138                 }, "$dir");
3139
3140         } elsif (-f $projects_list) {
3141                 # read from file(url-encoded):
3142                 # 'git%2Fgit.git Linus+Torvalds'
3143                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3144                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3145                 open my $fd, '<', $projects_list or return;
3146         PROJECT:
3147                 while (my $line = <$fd>) {
3148                         chomp $line;
3149                         my ($path, $owner) = split ' ', $line;
3150                         $path = unescape($path);
3151                         $owner = unescape($owner);
3152                         if (!defined $path) {
3153                                 next;
3154                         }
3155                         # if $filter is rpovided, check if $path begins with $filter
3156                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3157                                 next;
3158                         }
3159                         if (check_export_ok("$projectroot/$path")) {
3160                                 my $pr = {
3161                                         path => $path
3162                                 };
3163                                 if ($owner) {
3164                                         $pr->{'owner'} = to_utf8($owner);
3165                                 }
3166                                 push @list, $pr;
3167                         }
3168                 }
3169                 close $fd;
3170         }
3171         return @list;
3172 }
3173
3174 # written with help of Tree::Trie module (Perl Artistic License, GPL compatible)
3175 # as side effects it sets 'forks' field to list of forks for forked projects
3176 sub filter_forks_from_projects_list {
3177         my $projects = shift;
3178
3179         my %trie; # prefix tree of directories (path components)
3180         # generate trie out of those directories that might contain forks
3181         foreach my $pr (@$projects) {
3182                 my $path = $pr->{'path'};
3183                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3184                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3185                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3186                 next unless (-d "$projectroot/$path"); # containing directory exists
3187                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3188
3189                 # add to trie
3190                 my @dirs = split('/', $path);
3191                 # walk the trie, until either runs out of components or out of trie
3192                 my $ref = \%trie;
3193                 while (scalar @dirs &&
3194                        exists($ref->{$dirs[0]})) {
3195                         $ref = $ref->{shift @dirs};
3196                 }
3197                 # create rest of trie structure from rest of components
3198                 foreach my $dir (@dirs) {
3199                         $ref = $ref->{$dir} = {};
3200                 }
3201                 # create end marker, store $pr as a data
3202                 $ref->{''} = $pr if (!exists $ref->{''});
3203         }
3204
3205         # filter out forks, by finding shortest prefix match for paths
3206         my @filtered;
3207  PROJECT:
3208         foreach my $pr (@$projects) {
3209                 # trie lookup
3210                 my $ref = \%trie;
3211         DIR:
3212                 foreach my $dir (split('/', $pr->{'path'})) {
3213                         if (exists $ref->{''}) {
3214                                 # found [shortest] prefix, is a fork - skip it
3215                                 push @{$ref->{''}{'forks'}}, $pr;
3216                                 next PROJECT;
3217                         }
3218                         if (!exists $ref->{$dir}) {
3219                                 # not in trie, cannot have prefix, not a fork
3220                                 push @filtered, $pr;
3221                                 next PROJECT;
3222                         }
3223                         # If the dir is there, we just walk one step down the trie.
3224                         $ref = $ref->{$dir};
3225                 }
3226                 # we ran out of trie
3227                 # (shouldn't happen: it's either no match, or end marker)
3228                 push @filtered, $pr;
3229         }
3230
3231         return @filtered;
3232 }
3233
3234 # note: fill_project_list_info must be run first,
3235 # for 'descr_long' and 'ctags' to be filled
3236 sub search_projects_list {
3237         my ($projlist, %opts) = @_;
3238         my $tagfilter  = $opts{'tagfilter'};
3239         my $search_re = $opts{'search_regexp'};
3240
3241         return @$projlist
3242                 unless ($tagfilter || $search_re);
3243
3244         # searching projects require filling to be run before it;
3245         fill_project_list_info($projlist,
3246                                $tagfilter  ? 'ctags' : (),
3247                                $search_re ? ('path', 'descr') : ());
3248         my @projects;
3249  PROJECT:
3250         foreach my $pr (@$projlist) {
3251
3252                 if ($tagfilter) {
3253                         next unless ref($pr->{'ctags'}) eq 'HASH';
3254                         next unless
3255                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3256                 }
3257
3258                 if ($search_re) {
3259                         next unless
3260                                 $pr->{'path'} =~ /$search_re/ ||
3261                                 $pr->{'descr_long'} =~ /$search_re/;
3262                 }
3263
3264                 push @projects, $pr;
3265         }
3266
3267         return @projects;
3268 }
3269
3270 our $gitweb_project_owner = undef;
3271 sub git_get_project_list_from_file {
3272
3273         return if (defined $gitweb_project_owner);
3274
3275         $gitweb_project_owner = {};
3276         # read from file (url-encoded):
3277         # 'git%2Fgit.git Linus+Torvalds'
3278         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3279         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3280         if (-f $projects_list) {
3281                 open(my $fd, '<', $projects_list);
3282                 while (my $line = <$fd>) {
3283                         chomp $line;
3284                         my ($pr, $ow) = split ' ', $line;
3285                         $pr = unescape($pr);
3286                         $ow = unescape($ow);
3287                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3288                 }
3289                 close $fd;
3290         }
3291 }
3292
3293 sub git_get_project_owner {
3294         my $project = shift;
3295         my $owner;
3296
3297         return undef unless $project;
3298         $git_dir = "$projectroot/$project";
3299
3300         if (!defined $gitweb_project_owner) {
3301                 git_get_project_list_from_file();
3302         }
3303
3304         if (exists $gitweb_project_owner->{$project}) {
3305                 $owner = $gitweb_project_owner->{$project};
3306         }
3307         if (!defined $owner){
3308                 $owner = git_get_project_config('owner');
3309         }
3310         if (!defined $owner) {
3311                 $owner = get_file_owner("$git_dir");
3312         }
3313
3314         return $owner;
3315 }
3316
3317 sub git_get_last_activity {
3318         my ($path) = @_;
3319         my $fd;
3320
3321         $git_dir = "$projectroot/$path";
3322         open($fd, "-|", git_cmd(), 'for-each-ref',
3323              '--format=%(committer)',
3324              '--sort=-committerdate',
3325              '--count=1',
3326              map { "refs/$_" } get_branch_refs ()) or return;
3327         my $most_recent = <$fd>;
3328         close $fd or return;
3329         if (defined $most_recent &&
3330             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3331                 my $timestamp = $1;
3332                 my $age = time - $timestamp;
3333                 return ($age, age_string($age));
3334         }
3335         return (undef, undef);
3336 }
3337
3338 # Implementation note: when a single remote is wanted, we cannot use 'git
3339 # remote show -n' because that command always work (assuming it's a remote URL
3340 # if it's not defined), and we cannot use 'git remote show' because that would
3341 # try to make a network roundtrip. So the only way to find if that particular
3342 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3343 # and when we find what we want.
3344 sub git_get_remotes_list {
3345         my $wanted = shift;
3346         my %remotes = ();
3347
3348         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3349         return unless $fd;
3350         while (my $remote = <$fd>) {
3351                 chomp $remote;
3352                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3353                 next if $wanted and not $remote eq $wanted;
3354                 my ($url, $key) = ($1, $2);
3355
3356                 $remotes{$remote} ||= { 'heads' => () };
3357                 $remotes{$remote}{$key} = $url;
3358         }
3359         close $fd or return;
3360         return wantarray ? %remotes : \%remotes;
3361 }
3362
3363 # Takes a hash of remotes as first parameter and fills it by adding the
3364 # available remote heads for each of the indicated remotes.
3365 sub fill_remote_heads {
3366         my $remotes = shift;
3367         my @heads = map { "remotes/$_" } keys %$remotes;
3368         my @remoteheads = git_get_heads_list(undef, @heads);
3369         foreach my $remote (keys %$remotes) {
3370                 $remotes->{$remote}{'heads'} = [ grep {
3371                         $_->{'name'} =~ s!^$remote/!!
3372                         } @remoteheads ];
3373         }
3374 }
3375
3376 sub git_get_references {
3377         my $type = shift || "";
3378         my %refs;
3379         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3380         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3381         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3382                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3383                 or return;
3384
3385         while (my $line = <$fd>) {
3386                 chomp $line;
3387                 if ($line =~ m!^($oid_regex)\srefs/($type.*)$!) {
3388                         if (defined $refs{$1}) {
3389                                 push @{$refs{$1}}, $2;
3390                         } else {
3391                                 $refs{$1} = [ $2 ];
3392                         }
3393                 }
3394         }
3395         close $fd or return;
3396         return \%refs;
3397 }
3398
3399 sub git_get_rev_name_tags {
3400         my $hash = shift || return undef;
3401
3402         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3403                 or return;
3404         my $name_rev = <$fd>;
3405         close $fd;
3406
3407         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3408                 return $1;
3409         } else {
3410                 # catches also '$hash undefined' output
3411                 return undef;
3412         }
3413 }
3414
3415 ## ----------------------------------------------------------------------
3416 ## parse to hash functions
3417
3418 sub parse_date {
3419         my $epoch = shift;
3420         my $tz = shift || "-0000";
3421
3422         my %date;
3423         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3424         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3425         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3426         $date{'hour'} = $hour;
3427         $date{'minute'} = $min;
3428         $date{'mday'} = $mday;
3429         $date{'day'} = $days[$wday];
3430         $date{'month'} = $months[$mon];
3431         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3432                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3433         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3434                              $mday, $months[$mon], $hour ,$min;
3435         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3436                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3437
3438         my ($tz_sign, $tz_hour, $tz_min) =
3439                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3440         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3441         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3442         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3443         $date{'hour_local'} = $hour;
3444         $date{'minute_local'} = $min;
3445         $date{'tz_local'} = $tz;
3446         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3447                                   1900+$year, $mon+1, $mday,
3448                                   $hour, $min, $sec, $tz);
3449         return %date;
3450 }
3451
3452 sub parse_tag {
3453         my $tag_id = shift;
3454         my %tag;
3455         my @comment;
3456
3457         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3458         $tag{'id'} = $tag_id;
3459         while (my $line = <$fd>) {
3460                 chomp $line;
3461                 if ($line =~ m/^object ($oid_regex)$/) {
3462                         $tag{'object'} = $1;
3463                 } elsif ($line =~ m/^type (.+)$/) {
3464                         $tag{'type'} = $1;
3465                 } elsif ($line =~ m/^tag (.+)$/) {
3466                         $tag{'name'} = $1;
3467                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3468                         $tag{'author'} = $1;
3469                         $tag{'author_epoch'} = $2;
3470                         $tag{'author_tz'} = $3;
3471                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3472                                 $tag{'author_name'}  = $1;
3473                                 $tag{'author_email'} = $2;
3474                         } else {
3475                                 $tag{'author_name'} = $tag{'author'};
3476                         }
3477                 } elsif ($line =~ m/--BEGIN/) {
3478                         push @comment, $line;
3479                         last;
3480                 } elsif ($line eq "") {
3481                         last;
3482                 }
3483         }
3484         push @comment, <$fd>;
3485         $tag{'comment'} = \@comment;
3486         close $fd or return;
3487         if (!defined $tag{'name'}) {
3488                 return
3489         };
3490         return %tag
3491 }
3492
3493 sub parse_commit_text {
3494         my ($commit_text, $withparents) = @_;
3495         my @commit_lines = split '\n', $commit_text;
3496         my %co;
3497
3498         pop @commit_lines; # Remove '\0'
3499
3500         if (! @commit_lines) {
3501                 return;
3502         }
3503
3504         my $header = shift @commit_lines;
3505         if ($header !~ m/^$oid_regex/) {
3506                 return;
3507         }
3508         ($co{'id'}, my @parents) = split ' ', $header;
3509         while (my $line = shift @commit_lines) {
3510                 last if $line eq "\n";
3511                 if ($line =~ m/^tree ($oid_regex)$/) {
3512                         $co{'tree'} = $1;
3513                 } elsif ((!defined $withparents) && ($line =~ m/^parent ($oid_regex)$/)) {
3514                         push @parents, $1;
3515                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3516                         $co{'author'} = to_utf8($1);
3517                         $co{'author_epoch'} = $2;
3518                         $co{'author_tz'} = $3;
3519                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3520                                 $co{'author_name'}  = $1;
3521                                 $co{'author_email'} = $2;
3522                         } else {
3523                                 $co{'author_name'} = $co{'author'};
3524                         }
3525                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3526                         $co{'committer'} = to_utf8($1);
3527                         $co{'committer_epoch'} = $2;
3528                         $co{'committer_tz'} = $3;
3529                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3530                                 $co{'committer_name'}  = $1;
3531                                 $co{'committer_email'} = $2;
3532                         } else {
3533                                 $co{'committer_name'} = $co{'committer'};
3534                         }
3535                 }
3536         }
3537         if (!defined $co{'tree'}) {
3538                 return;
3539         };
3540         $co{'parents'} = \@parents;
3541         $co{'parent'} = $parents[0];
3542
3543         foreach my $title (@commit_lines) {
3544                 $title =~ s/^    //;
3545                 if ($title ne "") {
3546                         $co{'title'} = chop_str($title, 80, 5);
3547                         # remove leading stuff of merges to make the interesting part visible
3548                         if (length($title) > 50) {
3549                                 $title =~ s/^Automatic //;
3550                                 $title =~ s/^merge (of|with) /Merge ... /i;
3551                                 if (length($title) > 50) {
3552                                         $title =~ s/(http|rsync):\/\///;
3553                                 }
3554                                 if (length($title) > 50) {
3555                                         $title =~ s/(master|www|rsync)\.//;
3556                                 }
3557                                 if (length($title) > 50) {
3558                                         $title =~ s/kernel.org:?//;
3559                                 }
3560                                 if (length($title) > 50) {
3561                                         $title =~ s/\/pub\/scm//;
3562                                 }
3563                         }
3564                         $co{'title_short'} = chop_str($title, 50, 5);
3565                         last;
3566                 }
3567         }
3568         if (! defined $co{'title'} || $co{'title'} eq "") {
3569                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3570         }
3571         # remove added spaces
3572         foreach my $line (@commit_lines) {
3573                 $line =~ s/^    //;
3574         }
3575         $co{'comment'} = \@commit_lines;
3576
3577         my $age = time - $co{'committer_epoch'};
3578         $co{'age'} = $age;
3579         $co{'age_string'} = age_string($age);
3580         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3581         if ($age > 60*60*24*7*2) {
3582                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3583                 $co{'age_string_age'} = $co{'age_string'};
3584         } else {
3585                 $co{'age_string_date'} = $co{'age_string'};
3586                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3587         }
3588         return %co;
3589 }
3590
3591 sub parse_commit {
3592         my ($commit_id) = @_;
3593         my %co;
3594
3595         local $/ = "\0";
3596
3597         open my $fd, "-|", git_cmd(), "rev-list",
3598                 "--parents",
3599                 "--header",
3600                 "--max-count=1",
3601                 $commit_id,
3602                 "--",
3603                 or die_error(500, "Open git-rev-list failed");
3604         %co = parse_commit_text(<$fd>, 1);
3605         close $fd;
3606
3607         return %co;
3608 }
3609
3610 sub parse_commits {
3611         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3612         my @cos;
3613
3614         $maxcount ||= 1;
3615         $skip ||= 0;
3616
3617         local $/ = "\0";
3618
3619         open my $fd, "-|", git_cmd(), "rev-list",
3620                 "--header",
3621                 @args,
3622                 ("--max-count=" . $maxcount),
3623                 ("--skip=" . $skip),
3624                 @extra_options,
3625                 $commit_id,
3626                 "--",
3627                 ($filename ? ($filename) : ())
3628                 or die_error(500, "Open git-rev-list failed");
3629         while (my $line = <$fd>) {
3630                 my %co = parse_commit_text($line);
3631                 push @cos, \%co;
3632         }
3633         close $fd;
3634
3635         return wantarray ? @cos : \@cos;
3636 }
3637
3638 # parse line of git-diff-tree "raw" output
3639 sub parse_difftree_raw_line {
3640         my $line = shift;
3641         my %res;
3642
3643         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3644         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3645         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ($oid_regex) ($oid_regex) (.)([0-9]{0,3})\t(.*)$/) {
3646                 $res{'from_mode'} = $1;
3647                 $res{'to_mode'} = $2;
3648                 $res{'from_id'} = $3;
3649                 $res{'to_id'} = $4;
3650                 $res{'status'} = $5;
3651                 $res{'similarity'} = $6;
3652                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3653                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3654                 } else {
3655                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3656                 }
3657         }
3658         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3659         # combined diff (for merge commit)
3660         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:$oid_regex )+)([a-zA-Z]+)\t(.*)$//) {
3661                 $res{'nparents'}  = length($1);
3662                 $res{'from_mode'} = [ split(' ', $2) ];
3663                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3664                 $res{'from_id'} = [ split(' ', $3) ];
3665                 $res{'to_id'} = pop @{$res{'from_id'}};
3666                 $res{'status'} = [ split('', $4) ];
3667                 $res{'to_file'} = unquote($5);
3668         }
3669         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3670         elsif ($line =~ m/^($oid_regex)$/) {
3671                 $res{'commit'} = $1;
3672         }
3673
3674         return wantarray ? %res : \%res;
3675 }
3676
3677 # wrapper: return parsed line of git-diff-tree "raw" output
3678 # (the argument might be raw line, or parsed info)
3679 sub parsed_difftree_line {
3680         my $line_or_ref = shift;
3681
3682         if (ref($line_or_ref) eq "HASH") {
3683                 # pre-parsed (or generated by hand)
3684                 return $line_or_ref;
3685         } else {
3686                 return parse_difftree_raw_line($line_or_ref);
3687         }
3688 }
3689
3690 # parse line of git-ls-tree output
3691 sub parse_ls_tree_line {
3692         my $line = shift;
3693         my %opts = @_;
3694         my %res;
3695
3696         if ($opts{'-l'}) {
3697                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3698                 $line =~ m/^([0-9]+) (.+) ($oid_regex) +(-|[0-9]+)\t(.+)$/s;
3699
3700                 $res{'mode'} = $1;
3701                 $res{'type'} = $2;
3702                 $res{'hash'} = $3;
3703                 $res{'size'} = $4;
3704                 if ($opts{'-z'}) {
3705                         $res{'name'} = $5;
3706                 } else {
3707                         $res{'name'} = unquote($5);
3708                 }
3709         } else {
3710                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3711                 $line =~ m/^([0-9]+) (.+) ($oid_regex)\t(.+)$/s;
3712
3713                 $res{'mode'} = $1;
3714                 $res{'type'} = $2;
3715                 $res{'hash'} = $3;
3716                 if ($opts{'-z'}) {
3717                         $res{'name'} = $4;
3718                 } else {
3719                         $res{'name'} = unquote($4);
3720                 }
3721         }
3722
3723         return wantarray ? %res : \%res;
3724 }
3725
3726 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3727 sub parse_from_to_diffinfo {
3728         my ($diffinfo, $from, $to, @parents) = @_;
3729
3730         if ($diffinfo->{'nparents'}) {
3731                 # combined diff
3732                 $from->{'file'} = [];
3733                 $from->{'href'} = [];
3734                 fill_from_file_info($diffinfo, @parents)
3735                         unless exists $diffinfo->{'from_file'};
3736                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3737                         $from->{'file'}[$i] =
3738                                 defined $diffinfo->{'from_file'}[$i] ?
3739                                         $diffinfo->{'from_file'}[$i] :
3740                                         $diffinfo->{'to_file'};
3741                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3742                                 $from->{'href'}[$i] = href(action=>"blob",
3743                                                            hash_base=>$parents[$i],
3744                                                            hash=>$diffinfo->{'from_id'}[$i],
3745                                                            file_name=>$from->{'file'}[$i]);
3746                         } else {
3747                                 $from->{'href'}[$i] = undef;
3748                         }
3749                 }
3750         } else {
3751                 # ordinary (not combined) diff
3752                 $from->{'file'} = $diffinfo->{'from_file'};
3753                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3754                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3755                                                hash=>$diffinfo->{'from_id'},
3756                                                file_name=>$from->{'file'});
3757                 } else {
3758                         delete $from->{'href'};
3759                 }
3760         }
3761
3762         $to->{'file'} = $diffinfo->{'to_file'};
3763         if (!is_deleted($diffinfo)) { # file exists in result
3764                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3765                                      hash=>$diffinfo->{'to_id'},
3766                                      file_name=>$to->{'file'});
3767         } else {
3768                 delete $to->{'href'};
3769         }
3770 }
3771
3772 ## ......................................................................
3773 ## parse to array of hashes functions
3774
3775 sub git_get_heads_list {
3776         my ($limit, @classes) = @_;
3777         @classes = get_branch_refs() unless @classes;
3778         my @patterns = map { "refs/$_" } @classes;
3779         my @headslist;
3780
3781         open my $fd, '-|', git_cmd(), 'for-each-ref',
3782                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3783                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3784                 @patterns
3785                 or return;
3786         while (my $line = <$fd>) {
3787                 my %ref_item;
3788
3789                 chomp $line;
3790                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3791                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3792                 my ($committer, $epoch, $tz) =
3793                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3794                 $ref_item{'fullname'}  = $name;
3795                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3796                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3797                 $ref_item{'name'} = $name;
3798                 # for refs neither in 'heads' nor 'remotes' we want to
3799                 # show their ref dir
3800                 my $ref_dir = (defined $1) ? $1 : '';
3801                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3802                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3803                 }
3804
3805                 $ref_item{'id'}    = $hash;
3806                 $ref_item{'title'} = $title || '(no commit message)';
3807                 $ref_item{'epoch'} = $epoch;
3808                 if ($epoch) {
3809                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3810                 } else {
3811                         $ref_item{'age'} = "unknown";
3812                 }
3813
3814                 push @headslist, \%ref_item;
3815         }
3816         close $fd;
3817
3818         return wantarray ? @headslist : \@headslist;
3819 }
3820
3821 sub git_get_tags_list {
3822         my $limit = shift;
3823         my @tagslist;
3824
3825         open my $fd, '-|', git_cmd(), 'for-each-ref',
3826                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3827                 '--format=%(objectname) %(objecttype) %(refname) '.
3828                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3829                 'refs/tags'
3830                 or return;
3831         while (my $line = <$fd>) {
3832                 my %ref_item;
3833
3834                 chomp $line;
3835                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3836                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3837                 my ($creator, $epoch, $tz) =
3838                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3839                 $ref_item{'fullname'} = $name;
3840                 $name =~ s!^refs/tags/!!;
3841
3842                 $ref_item{'type'} = $type;
3843                 $ref_item{'id'} = $id;
3844                 $ref_item{'name'} = $name;
3845                 if ($type eq "tag") {
3846                         $ref_item{'subject'} = $title;
3847                         $ref_item{'reftype'} = $reftype;
3848                         $ref_item{'refid'}   = $refid;
3849                 } else {
3850                         $ref_item{'reftype'} = $type;
3851                         $ref_item{'refid'}   = $id;
3852                 }
3853
3854                 if ($type eq "tag" || $type eq "commit") {
3855                         $ref_item{'epoch'} = $epoch;
3856                         if ($epoch) {
3857                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3858                         } else {
3859                                 $ref_item{'age'} = "unknown";
3860                         }
3861                 }
3862
3863                 push @tagslist, \%ref_item;
3864         }
3865         close $fd;
3866
3867         return wantarray ? @tagslist : \@tagslist;
3868 }
3869
3870 ## ----------------------------------------------------------------------
3871 ## filesystem-related functions
3872
3873 sub get_file_owner {
3874         my $path = shift;
3875
3876         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3877         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3878         if (!defined $gcos) {
3879                 return undef;
3880         }
3881         my $owner = $gcos;
3882         $owner =~ s/[,;].*$//;
3883         return to_utf8($owner);
3884 }
3885
3886 # assume that file exists
3887 sub insert_file {
3888         my $filename = shift;
3889
3890         open my $fd, '<', $filename;
3891         print map { to_utf8($_) } <$fd>;
3892         close $fd;
3893 }
3894
3895 ## ......................................................................
3896 ## mimetype related functions
3897
3898 sub mimetype_guess_file {
3899         my $filename = shift;
3900         my $mimemap = shift;
3901         -r $mimemap or return undef;
3902
3903         my %mimemap;
3904         open(my $mh, '<', $mimemap) or return undef;
3905         while (<$mh>) {
3906                 next if m/^#/; # skip comments
3907                 my ($mimetype, @exts) = split(/\s+/);
3908                 foreach my $ext (@exts) {
3909                         $mimemap{$ext} = $mimetype;
3910                 }
3911         }
3912         close($mh);
3913
3914         $filename =~ /\.([^.]*)$/;
3915         return $mimemap{$1};
3916 }
3917
3918 sub mimetype_guess {
3919         my $filename = shift;
3920         my $mime;
3921         $filename =~ /\./ or return undef;
3922
3923         if ($mimetypes_file) {
3924                 my $file = $mimetypes_file;
3925                 if ($file !~ m!^/!) { # if it is relative path
3926                         # it is relative to project
3927                         $file = "$projectroot/$project/$file";
3928                 }
3929                 $mime = mimetype_guess_file($filename, $file);
3930         }
3931         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3932         return $mime;
3933 }
3934
3935 sub blob_mimetype {
3936         my $fd = shift;
3937         my $filename = shift;
3938
3939         if ($filename) {
3940                 my $mime = mimetype_guess($filename);
3941                 $mime and return $mime;
3942         }
3943
3944         # just in case
3945         return $default_blob_plain_mimetype unless $fd;
3946
3947         if (-T $fd) {
3948                 return 'text/plain';
3949         } elsif (! $filename) {
3950                 return 'application/octet-stream';
3951         } elsif ($filename =~ m/\.png$/i) {
3952                 return 'image/png';
3953         } elsif ($filename =~ m/\.gif$/i) {
3954                 return 'image/gif';
3955         } elsif ($filename =~ m/\.jpe?g$/i) {
3956                 return 'image/jpeg';
3957         } else {
3958                 return 'application/octet-stream';
3959         }
3960 }
3961
3962 sub blob_contenttype {
3963         my ($fd, $file_name, $type) = @_;
3964
3965         $type ||= blob_mimetype($fd, $file_name);
3966         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3967                 $type .= "; charset=$default_text_plain_charset";
3968         }
3969
3970         return $type;
3971 }
3972
3973 # guess file syntax for syntax highlighting; return undef if no highlighting
3974 # the name of syntax can (in the future) depend on syntax highlighter used
3975 sub guess_file_syntax {
3976         my ($highlight, $file_name) = @_;
3977         return undef unless ($highlight && defined $file_name);
3978         my $basename = basename($file_name, '.in');
3979         return $highlight_basename{$basename}
3980                 if exists $highlight_basename{$basename};
3981
3982         $basename =~ /\.([^.]*)$/;
3983         my $ext = $1 or return undef;
3984         return $highlight_ext{$ext}
3985                 if exists $highlight_ext{$ext};
3986
3987         return undef;
3988 }
3989
3990 # run highlighter and return FD of its output,
3991 # or return original FD if no highlighting
3992 sub run_highlighter {
3993         my ($fd, $highlight, $syntax) = @_;
3994         return $fd unless ($highlight);
3995
3996         close $fd;
3997         my $syntax_arg = (defined $syntax) ? "--syntax $syntax" : "--force";
3998         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3999                   quote_command($^X, '-CO', '-MEncode=decode,FB_DEFAULT', '-pse',
4000                     '$_ = decode($fe, $_, FB_DEFAULT) if !utf8::decode($_);',
4001                     '--', "-fe=$fallback_encoding")." | ".
4002                   quote_command($highlight_bin).
4003                   " --replace-tabs=8 --fragment $syntax_arg |"
4004                 or die_error(500, "Couldn't open file or run syntax highlighter");
4005         return $fd;
4006 }
4007
4008 ## ======================================================================
4009 ## functions printing HTML: header, footer, error page
4010
4011 sub get_page_title {
4012         my $title = to_utf8($site_name);
4013
4014         unless (defined $project) {
4015                 if (defined $project_filter) {
4016                         $title .= " - projects in '" . esc_path($project_filter) . "'";
4017                 }
4018                 return $title;
4019         }
4020         $title .= " - " . to_utf8($project);
4021
4022         return $title unless (defined $action);
4023         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
4024
4025         return $title unless (defined $file_name);
4026         $title .= " - " . esc_path($file_name);
4027         if ($action eq "tree" && $file_name !~ m|/$|) {
4028                 $title .= "/";
4029         }
4030
4031         return $title;
4032 }
4033
4034 sub get_content_type_html {
4035         # require explicit support from the UA if we are to send the page as
4036         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
4037         # we have to do this because MSIE sometimes globs '*/*', pretending to
4038         # support xhtml+xml but choking when it gets what it asked for.
4039         if (defined $cgi->http('HTTP_ACCEPT') &&
4040             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
4041             $cgi->Accept('application/xhtml+xml') != 0) {
4042                 return 'application/xhtml+xml';
4043         } else {
4044                 return 'text/html';
4045         }
4046 }
4047
4048 sub print_feed_meta {
4049         if (defined $project) {
4050                 my %href_params = get_feed_info();
4051                 if (!exists $href_params{'-title'}) {
4052                         $href_params{'-title'} = 'log';
4053                 }
4054
4055                 foreach my $format (qw(RSS Atom)) {
4056                         my $type = lc($format);
4057                         my %link_attr = (
4058                                 '-rel' => 'alternate',
4059                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4060                                 '-type' => "application/$type+xml"
4061                         );
4062
4063                         $href_params{'extra_options'} = undef;
4064                         $href_params{'action'} = $type;
4065                         $link_attr{'-href'} = esc_attr(href(%href_params));
4066                         print "<link ".
4067                               "rel=\"$link_attr{'-rel'}\" ".
4068                               "title=\"$link_attr{'-title'}\" ".
4069                               "href=\"$link_attr{'-href'}\" ".
4070                               "type=\"$link_attr{'-type'}\" ".
4071                               "/>\n";
4072
4073                         $href_params{'extra_options'} = '--no-merges';
4074                         $link_attr{'-href'} = esc_attr(href(%href_params));
4075                         $link_attr{'-title'} .= ' (no merges)';
4076                         print "<link ".
4077                               "rel=\"$link_attr{'-rel'}\" ".
4078                               "title=\"$link_attr{'-title'}\" ".
4079                               "href=\"$link_attr{'-href'}\" ".
4080                               "type=\"$link_attr{'-type'}\" ".
4081                               "/>\n";
4082                 }
4083
4084         } else {
4085                 printf('<link rel="alternate" title="%s projects list" '.
4086                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4087                        esc_attr($site_name),
4088                        esc_attr(href(project=>undef, action=>"project_index")));
4089                 printf('<link rel="alternate" title="%s projects feeds" '.
4090                        'href="%s" type="text/x-opml" />'."\n",
4091                        esc_attr($site_name),
4092                        esc_attr(href(project=>undef, action=>"opml")));
4093         }
4094 }
4095
4096 sub print_header_links {
4097         my $status = shift;
4098
4099         # print out each stylesheet that exist, providing backwards capability
4100         # for those people who defined $stylesheet in a config file
4101         if (defined $stylesheet) {
4102                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4103         } else {
4104                 foreach my $stylesheet (@stylesheets) {
4105                         next unless $stylesheet;
4106                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4107                 }
4108         }
4109         print_feed_meta()
4110                 if ($status eq '200 OK');
4111         if (defined $favicon) {
4112                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4113         }
4114 }
4115
4116 sub print_nav_breadcrumbs_path {
4117         my $dirprefix = undef;
4118         while (my $part = shift) {
4119                 $dirprefix .= "/" if defined $dirprefix;
4120                 $dirprefix .= $part;
4121                 print $cgi->a({-href => href(project => undef,
4122                                              project_filter => $dirprefix,
4123                                              action => "project_list")},
4124                               esc_html($part)) . " / ";
4125         }
4126 }
4127
4128 sub print_nav_breadcrumbs {
4129         my %opts = @_;
4130
4131         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4132                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4133         }
4134         if (defined $project) {
4135                 my @dirname = split '/', $project;
4136                 my $projectbasename = pop @dirname;
4137                 print_nav_breadcrumbs_path(@dirname);
4138                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4139                 if (defined $action) {
4140                         my $action_print = $action ;
4141                         if (defined $opts{-action_extra}) {
4142                                 $action_print = $cgi->a({-href => href(action=>$action)},
4143                                         $action);
4144                         }
4145                         print " / $action_print";
4146                 }
4147                 if (defined $opts{-action_extra}) {
4148                         print " / $opts{-action_extra}";
4149                 }
4150                 print "\n";
4151         } elsif (defined $project_filter) {
4152                 print_nav_breadcrumbs_path(split '/', $project_filter);
4153         }
4154 }
4155
4156 sub print_search_form {
4157         if (!defined $searchtext) {
4158                 $searchtext = "";
4159         }
4160         my $search_hash;
4161         if (defined $hash_base) {
4162                 $search_hash = $hash_base;
4163         } elsif (defined $hash) {
4164                 $search_hash = $hash;
4165         } else {
4166                 $search_hash = "HEAD";
4167         }
4168         my $action = $my_uri;
4169         my $use_pathinfo = gitweb_check_feature('pathinfo');
4170         if ($use_pathinfo) {
4171                 $action .= "/".esc_url($project);
4172         }
4173         print $cgi->start_form(-method => "get", -action => $action) .
4174               "<div class=\"search\">\n" .
4175               (!$use_pathinfo &&
4176               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4177               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4178               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4179               $cgi->popup_menu(-name => 'st', -default => 'commit',
4180                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4181               " " . $cgi->a({-href => href(action=>"search_help"),
4182                              -title => "search help" }, "?") . " search:\n",
4183               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4184               "<span title=\"Extended regular expression\">" .
4185               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4186                              -checked => $search_use_regexp) .
4187               "</span>" .
4188               "</div>" .
4189               $cgi->end_form() . "\n";
4190 }
4191
4192 sub git_header_html {
4193         my $status = shift || "200 OK";
4194         my $expires = shift;
4195         my %opts = @_;
4196
4197         my $title = get_page_title();
4198         my $content_type = get_content_type_html();
4199         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4200                            -status=> $status, -expires => $expires)
4201                 unless ($opts{'-no_http_header'});
4202         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4203         print <<EOF;
4204 <?xml version="1.0" encoding="utf-8"?>
4205 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4206 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4207 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4208 <!-- git core binaries version $git_version -->
4209 <head>
4210 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4211 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4212 <meta name="robots" content="index, nofollow"/>
4213 <title>$title</title>
4214 EOF
4215         # the stylesheet, favicon etc urls won't work correctly with path_info
4216         # unless we set the appropriate base URL
4217         if ($ENV{'PATH_INFO'}) {
4218                 print "<base href=\"".esc_url($base_url)."\" />\n";
4219         }
4220         print_header_links($status);
4221
4222         if (defined $site_html_head_string) {
4223                 print to_utf8($site_html_head_string);
4224         }
4225
4226         print "</head>\n" .
4227               "<body>\n";
4228
4229         if (defined $site_header && -f $site_header) {
4230                 insert_file($site_header);
4231         }
4232
4233         print "<div class=\"page_header\">\n";
4234         if (defined $logo) {
4235                 print $cgi->a({-href => esc_url($logo_url),
4236                                -title => $logo_label},
4237                               $cgi->img({-src => esc_url($logo),
4238                                          -width => 72, -height => 27,
4239                                          -alt => "git",
4240                                          -class => "logo"}));
4241         }
4242         print_nav_breadcrumbs(%opts);
4243         print "</div>\n";
4244
4245         my $have_search = gitweb_check_feature('search');
4246         if (defined $project && $have_search) {
4247                 print_search_form();
4248         }
4249 }
4250
4251 sub git_footer_html {
4252         my $feed_class = 'rss_logo';
4253
4254         print "<div class=\"page_footer\">\n";
4255         if (defined $project) {
4256                 my $descr = git_get_project_description($project);
4257                 if (defined $descr) {
4258                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4259                 }
4260
4261                 my %href_params = get_feed_info();
4262                 if (!%href_params) {
4263                         $feed_class .= ' generic';
4264                 }
4265                 $href_params{'-title'} ||= 'log';
4266
4267                 foreach my $format (qw(RSS Atom)) {
4268                         $href_params{'action'} = lc($format);
4269                         print $cgi->a({-href => href(%href_params),
4270                                       -title => "$href_params{'-title'} $format feed",
4271                                       -class => $feed_class}, $format)."\n";
4272                 }
4273
4274         } else {
4275                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4276                                              project_filter => $project_filter),
4277                               -class => $feed_class}, "OPML") . " ";
4278                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4279                                              project_filter => $project_filter),
4280                               -class => $feed_class}, "TXT") . "\n";
4281         }
4282         print "</div>\n"; # class="page_footer"
4283
4284         if (defined $t0 && gitweb_check_feature('timed')) {
4285                 print "<div id=\"generating_info\">\n";
4286                 print 'This page took '.
4287                       '<span id="generating_time" class="time_span">'.
4288                       tv_interval($t0, [ gettimeofday() ]).
4289                       ' seconds </span>'.
4290                       ' and '.
4291                       '<span id="generating_cmd">'.
4292                       $number_of_git_cmds.
4293                       '</span> git commands '.
4294                       " to generate.\n";
4295                 print "</div>\n"; # class="page_footer"
4296         }
4297
4298         if (defined $site_footer && -f $site_footer) {
4299                 insert_file($site_footer);
4300         }
4301
4302         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4303         if (defined $action &&
4304             $action eq 'blame_incremental') {
4305                 print qq!<script type="text/javascript">\n!.
4306                       qq!startBlame("!. esc_attr(href(action=>"blame_data", -replay=>1)) .qq!",\n!.
4307                       qq!           "!. esc_attr(href()) .qq!");\n!.
4308                       qq!</script>\n!;
4309         } else {
4310                 my ($jstimezone, $tz_cookie, $datetime_class) =
4311                         gitweb_get_feature('javascript-timezone');
4312
4313                 print qq!<script type="text/javascript">\n!.
4314                       qq!window.onload = function () {\n!;
4315                 if (gitweb_check_feature('javascript-actions')) {
4316                         print qq!       fixLinks();\n!;
4317                 }
4318                 if ($jstimezone && $tz_cookie && $datetime_class) {
4319                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4320                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4321                 }
4322                 print qq!};\n!.
4323                       qq!</script>\n!;
4324         }
4325
4326         print "</body>\n" .
4327               "</html>";
4328 }
4329
4330 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4331 # Example: die_error(404, 'Hash not found')
4332 # By convention, use the following status codes (as defined in RFC 2616):
4333 # 400: Invalid or missing CGI parameters, or
4334 #      requested object exists but has wrong type.
4335 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4336 #      this server or project.
4337 # 404: Requested object/revision/project doesn't exist.
4338 # 500: The server isn't configured properly, or
4339 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4340 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4341 # 503: The server is currently unavailable (because it is overloaded,
4342 #      or down for maintenance).  Generally, this is a temporary state.
4343 sub die_error {
4344         my $status = shift || 500;
4345         my $error = esc_html(shift) || "Internal Server Error";
4346         my $extra = shift;
4347         my %opts = @_;
4348
4349         my %http_responses = (
4350                 400 => '400 Bad Request',
4351                 403 => '403 Forbidden',
4352                 404 => '404 Not Found',
4353                 500 => '500 Internal Server Error',
4354                 503 => '503 Service Unavailable',
4355         );
4356         git_header_html($http_responses{$status}, undef, %opts);
4357         print <<EOF;
4358 <div class="page_body">
4359 <br /><br />
4360 $status - $error
4361 <br />
4362 EOF
4363         if (defined $extra) {
4364                 print "<hr />\n" .
4365                       "$extra\n";
4366         }
4367         print "</div>\n";
4368
4369         git_footer_html();
4370         goto DONE_GITWEB
4371                 unless ($opts{'-error_handler'});
4372 }
4373
4374 ## ----------------------------------------------------------------------
4375 ## functions printing or outputting HTML: navigation
4376
4377 sub git_print_page_nav {
4378         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4379         $extra = '' if !defined $extra; # pager or formats
4380
4381         my @navs = qw(summary shortlog log commit commitdiff tree);
4382         if ($suppress) {
4383                 @navs = grep { $_ ne $suppress } @navs;
4384         }
4385
4386         my %arg = map { $_ => {action=>$_} } @navs;
4387         if (defined $head) {
4388                 for (qw(commit commitdiff)) {
4389                         $arg{$_}{'hash'} = $head;
4390                 }
4391                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4392                         for (qw(shortlog log)) {
4393                                 $arg{$_}{'hash'} = $head;
4394                         }
4395                 }
4396         }
4397
4398         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4399         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4400
4401         my @actions = gitweb_get_feature('actions');
4402         my %repl = (
4403                 '%' => '%',
4404                 'n' => $project,         # project name
4405                 'f' => $git_dir,         # project path within filesystem
4406                 'h' => $treehead || '',  # current hash ('h' parameter)
4407                 'b' => $treebase || '',  # hash base ('hb' parameter)
4408         );
4409         while (@actions) {
4410                 my ($label, $link, $pos) = splice(@actions,0,3);
4411                 # insert
4412                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4413                 # munch munch
4414                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4415                 $arg{$label}{'_href'} = $link;
4416         }
4417
4418         print "<div class=\"page_nav\">\n" .
4419                 (join " | ",
4420                  map { $_ eq $current ?
4421                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4422                  } @navs);
4423         print "<br/>\n$extra<br/>\n" .
4424               "</div>\n";
4425 }
4426
4427 # returns a submenu for the navigation of the refs views (tags, heads,
4428 # remotes) with the current view disabled and the remotes view only
4429 # available if the feature is enabled
4430 sub format_ref_views {
4431         my ($current) = @_;
4432         my @ref_views = qw{tags heads};
4433         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4434         return join " | ", map {
4435                 $_ eq $current ? $_ :
4436                 $cgi->a({-href => href(action=>$_)}, $_)
4437         } @ref_views
4438 }
4439
4440 sub format_paging_nav {
4441         my ($action, $page, $has_next_link) = @_;
4442         my $paging_nav;
4443
4444
4445         if ($page > 0) {
4446                 $paging_nav .=
4447                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4448                         " &sdot; " .
4449                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4450                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4451         } else {
4452                 $paging_nav .= "first &sdot; prev";
4453         }
4454
4455         if ($has_next_link) {
4456                 $paging_nav .= " &sdot; " .
4457                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4458                                  -accesskey => "n", -title => "Alt-n"}, "next");
4459         } else {
4460                 $paging_nav .= " &sdot; next";
4461         }
4462
4463         return $paging_nav;
4464 }
4465
4466 ## ......................................................................
4467 ## functions printing or outputting HTML: div
4468
4469 sub git_print_header_div {
4470         my ($action, $title, $hash, $hash_base) = @_;
4471         my %args = ();
4472
4473         $args{'action'} = $action;
4474         $args{'hash'} = $hash if $hash;
4475         $args{'hash_base'} = $hash_base if $hash_base;
4476
4477         print "<div class=\"header\">\n" .
4478               $cgi->a({-href => href(%args), -class => "title"},
4479               $title ? $title : $action) .
4480               "\n</div>\n";
4481 }
4482
4483 sub format_repo_url {
4484         my ($name, $url) = @_;
4485         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4486 }
4487
4488 # Group output by placing it in a DIV element and adding a header.
4489 # Options for start_div() can be provided by passing a hash reference as the
4490 # first parameter to the function.
4491 # Options to git_print_header_div() can be provided by passing an array
4492 # reference. This must follow the options to start_div if they are present.
4493 # The content can be a scalar, which is output as-is, a scalar reference, which
4494 # is output after html escaping, an IO handle passed either as *handle or
4495 # *handle{IO}, or a function reference. In the latter case all following
4496 # parameters will be taken as argument to the content function call.
4497 sub git_print_section {
4498         my ($div_args, $header_args, $content);
4499         my $arg = shift;
4500         if (ref($arg) eq 'HASH') {
4501                 $div_args = $arg;
4502                 $arg = shift;
4503         }
4504         if (ref($arg) eq 'ARRAY') {
4505                 $header_args = $arg;
4506                 $arg = shift;
4507         }
4508         $content = $arg;
4509
4510         print $cgi->start_div($div_args);
4511         git_print_header_div(@$header_args);
4512
4513         if (ref($content) eq 'CODE') {
4514                 $content->(@_);
4515         } elsif (ref($content) eq 'SCALAR') {
4516                 print esc_html($$content);
4517         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4518                 print <$content>;
4519         } elsif (!ref($content) && defined($content)) {
4520                 print $content;
4521         }
4522
4523         print $cgi->end_div;
4524 }
4525
4526 sub format_timestamp_html {
4527         my $date = shift;
4528         my $strtime = $date->{'rfc2822'};
4529
4530         my (undef, undef, $datetime_class) =
4531                 gitweb_get_feature('javascript-timezone');
4532         if ($datetime_class) {
4533                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4534         }
4535
4536         my $localtime_format = '(%02d:%02d %s)';
4537         if ($date->{'hour_local'} < 6) {
4538                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4539         }
4540         $strtime .= ' ' .
4541                     sprintf($localtime_format,
4542                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4543
4544         return $strtime;
4545 }
4546
4547 # Outputs the author name and date in long form
4548 sub git_print_authorship {
4549         my $co = shift;
4550         my %opts = @_;
4551         my $tag = $opts{-tag} || 'div';
4552         my $author = $co->{'author_name'};
4553
4554         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4555         print "<$tag class=\"author_date\">" .
4556               format_search_author($author, "author", esc_html($author)) .
4557               " [".format_timestamp_html(\%ad)."]".
4558               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4559               "</$tag>\n";
4560 }
4561
4562 # Outputs table rows containing the full author or committer information,
4563 # in the format expected for 'commit' view (& similar).
4564 # Parameters are a commit hash reference, followed by the list of people
4565 # to output information for. If the list is empty it defaults to both
4566 # author and committer.
4567 sub git_print_authorship_rows {
4568         my $co = shift;
4569         # too bad we can't use @people = @_ || ('author', 'committer')
4570         my @people = @_;
4571         @people = ('author', 'committer') unless @people;
4572         foreach my $who (@people) {
4573                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4574                 print "<tr><td>$who</td><td>" .
4575                       format_search_author($co->{"${who}_name"}, $who,
4576                                            esc_html($co->{"${who}_name"})) . " " .
4577                       format_search_author($co->{"${who}_email"}, $who,
4578                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4579                       "</td><td rowspan=\"2\">" .
4580                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4581                       "</td></tr>\n" .
4582                       "<tr>" .
4583                       "<td></td><td>" .
4584                       format_timestamp_html(\%wd) .
4585                       "</td>" .
4586                       "</tr>\n";
4587         }
4588 }
4589
4590 sub git_print_page_path {
4591         my $name = shift;
4592         my $type = shift;
4593         my $hb = shift;
4594
4595
4596         print "<div class=\"page_path\">";
4597         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4598                       -title => 'tree root'}, to_utf8("[$project]"));
4599         print " / ";
4600         if (defined $name) {
4601                 my @dirname = split '/', $name;
4602                 my $basename = pop @dirname;
4603                 my $fullname = '';
4604
4605                 foreach my $dir (@dirname) {
4606                         $fullname .= ($fullname ? '/' : '') . $dir;
4607                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4608                                                      hash_base=>$hb),
4609                                       -title => $fullname}, esc_path($dir));
4610                         print " / ";
4611                 }
4612                 if (defined $type && $type eq 'blob') {
4613                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4614                                                      hash_base=>$hb),
4615                                       -title => $name}, esc_path($basename));
4616                 } elsif (defined $type && $type eq 'tree') {
4617                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4618                                                      hash_base=>$hb),
4619                                       -title => $name}, esc_path($basename));
4620                         print " / ";
4621                 } else {
4622                         print esc_path($basename);
4623                 }
4624         }
4625         print "<br/></div>\n";
4626 }
4627
4628 sub git_print_log {
4629         my $log = shift;
4630         my %opts = @_;
4631
4632         if ($opts{'-remove_title'}) {
4633                 # remove title, i.e. first line of log
4634                 shift @$log;
4635         }
4636         # remove leading empty lines
4637         while (defined $log->[0] && $log->[0] eq "") {
4638                 shift @$log;
4639         }
4640
4641         # print log
4642         my $skip_blank_line = 0;
4643         foreach my $line (@$log) {
4644                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-([Bb]y|[Tt]o)|C[Cc]|(Clos|Fix)es): /) {
4645                         if (! $opts{'-remove_signoff'}) {
4646                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4647                                 $skip_blank_line = 1;
4648                         }
4649                         next;
4650                 }
4651
4652                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4653                         if (! $opts{'-remove_signoff'}) {
4654                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4655                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4656                                         "</span><br/>\n";
4657                                 $skip_blank_line = 1;
4658                         }
4659                         next;
4660                 }
4661
4662                 # print only one empty line
4663                 # do not print empty line after signoff
4664                 if ($line eq "") {
4665                         next if ($skip_blank_line);
4666                         $skip_blank_line = 1;
4667                 } else {
4668                         $skip_blank_line = 0;
4669                 }
4670
4671                 print format_log_line_html($line) . "<br/>\n";
4672         }
4673
4674         if ($opts{'-final_empty_line'}) {
4675                 # end with single empty line
4676                 print "<br/>\n" unless $skip_blank_line;
4677         }
4678 }
4679
4680 # return link target (what link points to)
4681 sub git_get_link_target {
4682         my $hash = shift;
4683         my $link_target;
4684
4685         # read link
4686         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4687                 or return;
4688         {
4689                 local $/ = undef;
4690                 $link_target = <$fd>;
4691         }
4692         close $fd
4693                 or return;
4694
4695         return $link_target;
4696 }
4697
4698 # given link target, and the directory (basedir) the link is in,
4699 # return target of link relative to top directory (top tree);
4700 # return undef if it is not possible (including absolute links).
4701 sub normalize_link_target {
4702         my ($link_target, $basedir) = @_;
4703
4704         # absolute symlinks (beginning with '/') cannot be normalized
4705         return if (substr($link_target, 0, 1) eq '/');
4706
4707         # normalize link target to path from top (root) tree (dir)
4708         my $path;
4709         if ($basedir) {
4710                 $path = $basedir . '/' . $link_target;
4711         } else {
4712                 # we are in top (root) tree (dir)
4713                 $path = $link_target;
4714         }
4715
4716         # remove //, /./, and /../
4717         my @path_parts;
4718         foreach my $part (split('/', $path)) {
4719                 # discard '.' and ''
4720                 next if (!$part || $part eq '.');
4721                 # handle '..'
4722                 if ($part eq '..') {
4723                         if (@path_parts) {
4724                                 pop @path_parts;
4725                         } else {
4726                                 # link leads outside repository (outside top dir)
4727                                 return;
4728                         }
4729                 } else {
4730                         push @path_parts, $part;
4731                 }
4732         }
4733         $path = join('/', @path_parts);
4734
4735         return $path;
4736 }
4737
4738 # print tree entry (row of git_tree), but without encompassing <tr> element
4739 sub git_print_tree_entry {
4740         my ($t, $basedir, $hash_base, $have_blame) = @_;
4741
4742         my %base_key = ();
4743         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4744
4745         # The format of a table row is: mode list link.  Where mode is
4746         # the mode of the entry, list is the name of the entry, an href,
4747         # and link is the action links of the entry.
4748
4749         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4750         if (exists $t->{'size'}) {
4751                 print "<td class=\"size\">$t->{'size'}</td>\n";
4752         }
4753         if ($t->{'type'} eq "blob") {
4754                 print "<td class=\"list\">" .
4755                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4756                                                file_name=>"$basedir$t->{'name'}", %base_key),
4757                                 -class => "list"}, esc_path($t->{'name'}));
4758                 if (S_ISLNK(oct $t->{'mode'})) {
4759                         my $link_target = git_get_link_target($t->{'hash'});
4760                         if ($link_target) {
4761                                 my $norm_target = normalize_link_target($link_target, $basedir);
4762                                 if (defined $norm_target) {
4763                                         print " -> " .
4764                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4765                                                                      file_name=>$norm_target),
4766                                                        -title => $norm_target}, esc_path($link_target));
4767                                 } else {
4768                                         print " -> " . esc_path($link_target);
4769                                 }
4770                         }
4771                 }
4772                 print "</td>\n";
4773                 print "<td class=\"link\">";
4774                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4775                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4776                               "blob");
4777                 if ($have_blame) {
4778                         print " | " .
4779                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4780                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4781                                       "blame");
4782                 }
4783                 if (defined $hash_base) {
4784                         print " | " .
4785                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4786                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4787                                       "history");
4788                 }
4789                 print " | " .
4790                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4791                                                file_name=>"$basedir$t->{'name'}")},
4792                                 "raw");
4793                 print "</td>\n";
4794
4795         } elsif ($t->{'type'} eq "tree") {
4796                 print "<td class=\"list\">";
4797                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4798                                              file_name=>"$basedir$t->{'name'}",
4799                                              %base_key)},
4800                               esc_path($t->{'name'}));
4801                 print "</td>\n";
4802                 print "<td class=\"link\">";
4803                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4804                                              file_name=>"$basedir$t->{'name'}",
4805                                              %base_key)},
4806                               "tree");
4807                 if (defined $hash_base) {
4808                         print " | " .
4809                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4810                                                      file_name=>"$basedir$t->{'name'}")},
4811                                       "history");
4812                 }
4813                 print "</td>\n";
4814         } else {
4815                 # unknown object: we can only present history for it
4816                 # (this includes 'commit' object, i.e. submodule support)
4817                 print "<td class=\"list\">" .
4818                       esc_path($t->{'name'}) .
4819                       "</td>\n";
4820                 print "<td class=\"link\">";
4821                 if (defined $hash_base) {
4822                         print $cgi->a({-href => href(action=>"history",
4823                                                      hash_base=>$hash_base,
4824                                                      file_name=>"$basedir$t->{'name'}")},
4825                                       "history");
4826                 }
4827                 print "</td>\n";
4828         }
4829 }
4830
4831 ## ......................................................................
4832 ## functions printing large fragments of HTML
4833
4834 # get pre-image filenames for merge (combined) diff
4835 sub fill_from_file_info {
4836         my ($diff, @parents) = @_;
4837
4838         $diff->{'from_file'} = [ ];
4839         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4840         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4841                 if ($diff->{'status'}[$i] eq 'R' ||
4842                     $diff->{'status'}[$i] eq 'C') {
4843                         $diff->{'from_file'}[$i] =
4844                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4845                 }
4846         }
4847
4848         return $diff;
4849 }
4850
4851 # is current raw difftree line of file deletion
4852 sub is_deleted {
4853         my $diffinfo = shift;
4854
4855         return $diffinfo->{'to_id'} eq ('0' x 40) || $diffinfo->{'to_id'} eq ('0' x 64);
4856 }
4857
4858 # does patch correspond to [previous] difftree raw line
4859 # $diffinfo  - hashref of parsed raw diff format
4860 # $patchinfo - hashref of parsed patch diff format
4861 #              (the same keys as in $diffinfo)
4862 sub is_patch_split {
4863         my ($diffinfo, $patchinfo) = @_;
4864
4865         return defined $diffinfo && defined $patchinfo
4866                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4867 }
4868
4869
4870 sub git_difftree_body {
4871         my ($difftree, $hash, @parents) = @_;
4872         my ($parent) = $parents[0];
4873         my $have_blame = gitweb_check_feature('blame');
4874         print "<div class=\"list_head\">\n";
4875         if ($#{$difftree} > 10) {
4876                 print(($#{$difftree} + 1) . " files changed:\n");
4877         }
4878         print "</div>\n";
4879
4880         print "<table class=\"" .
4881               (@parents > 1 ? "combined " : "") .
4882               "diff_tree\">\n";
4883
4884         # header only for combined diff in 'commitdiff' view
4885         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4886         if ($has_header) {
4887                 # table header
4888                 print "<thead><tr>\n" .
4889                        "<th></th><th></th>\n"; # filename, patchN link
4890                 for (my $i = 0; $i < @parents; $i++) {
4891                         my $par = $parents[$i];
4892                         print "<th>" .
4893                               $cgi->a({-href => href(action=>"commitdiff",
4894                                                      hash=>$hash, hash_parent=>$par),
4895                                        -title => 'commitdiff to parent number ' .
4896                                                   ($i+1) . ': ' . substr($par,0,7)},
4897                                       $i+1) .
4898                               "&nbsp;</th>\n";
4899                 }
4900                 print "</tr></thead>\n<tbody>\n";
4901         }
4902
4903         my $alternate = 1;
4904         my $patchno = 0;
4905         foreach my $line (@{$difftree}) {
4906                 my $diff = parsed_difftree_line($line);
4907
4908                 if ($alternate) {
4909                         print "<tr class=\"dark\">\n";
4910                 } else {
4911                         print "<tr class=\"light\">\n";
4912                 }
4913                 $alternate ^= 1;
4914
4915                 if (exists $diff->{'nparents'}) { # combined diff
4916
4917                         fill_from_file_info($diff, @parents)
4918                                 unless exists $diff->{'from_file'};
4919
4920                         if (!is_deleted($diff)) {
4921                                 # file exists in the result (child) commit
4922                                 print "<td>" .
4923                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4924                                                              file_name=>$diff->{'to_file'},
4925                                                              hash_base=>$hash),
4926                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4927                                       "</td>\n";
4928                         } else {
4929                                 print "<td>" .
4930                                       esc_path($diff->{'to_file'}) .
4931                                       "</td>\n";
4932                         }
4933
4934                         if ($action eq 'commitdiff') {
4935                                 # link to patch
4936                                 $patchno++;
4937                                 print "<td class=\"link\">" .
4938                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4939                                               "patch") .
4940                                       " | " .
4941                                       "</td>\n";
4942                         }
4943
4944                         my $has_history = 0;
4945                         my $not_deleted = 0;
4946                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4947                                 my $hash_parent = $parents[$i];
4948                                 my $from_hash = $diff->{'from_id'}[$i];
4949                                 my $from_path = $diff->{'from_file'}[$i];
4950                                 my $status = $diff->{'status'}[$i];
4951
4952                                 $has_history ||= ($status ne 'A');
4953                                 $not_deleted ||= ($status ne 'D');
4954
4955                                 if ($status eq 'A') {
4956                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4957                                 } elsif ($status eq 'D') {
4958                                         print "<td class=\"link\">" .
4959                                               $cgi->a({-href => href(action=>"blob",
4960                                                                      hash_base=>$hash,
4961                                                                      hash=>$from_hash,
4962                                                                      file_name=>$from_path)},
4963                                                       "blob" . ($i+1)) .
4964                                               " | </td>\n";
4965                                 } else {
4966                                         if ($diff->{'to_id'} eq $from_hash) {
4967                                                 print "<td class=\"link nochange\">";
4968                                         } else {
4969                                                 print "<td class=\"link\">";
4970                                         }
4971                                         print $cgi->a({-href => href(action=>"blobdiff",
4972                                                                      hash=>$diff->{'to_id'},
4973                                                                      hash_parent=>$from_hash,
4974                                                                      hash_base=>$hash,
4975                                                                      hash_parent_base=>$hash_parent,
4976                                                                      file_name=>$diff->{'to_file'},
4977                                                                      file_parent=>$from_path)},
4978                                                       "diff" . ($i+1)) .
4979                                               " | </td>\n";
4980                                 }
4981                         }
4982
4983                         print "<td class=\"link\">";
4984                         if ($not_deleted) {
4985                                 print $cgi->a({-href => href(action=>"blob",
4986                                                              hash=>$diff->{'to_id'},
4987                                                              file_name=>$diff->{'to_file'},
4988                                                              hash_base=>$hash)},
4989                                               "blob");
4990                                 print " | " if ($has_history);
4991                         }
4992                         if ($has_history) {
4993                                 print $cgi->a({-href => href(action=>"history",
4994                                                              file_name=>$diff->{'to_file'},
4995                                                              hash_base=>$hash)},
4996                                               "history");
4997                         }
4998                         print "</td>\n";
4999
5000                         print "</tr>\n";
5001                         next; # instead of 'else' clause, to avoid extra indent
5002                 }
5003                 # else ordinary diff
5004
5005                 my ($to_mode_oct, $to_mode_str, $to_file_type);
5006                 my ($from_mode_oct, $from_mode_str, $from_file_type);
5007                 if ($diff->{'to_mode'} ne ('0' x 6)) {
5008                         $to_mode_oct = oct $diff->{'to_mode'};
5009                         if (S_ISREG($to_mode_oct)) { # only for regular file
5010                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
5011                         }
5012                         $to_file_type = file_type($diff->{'to_mode'});
5013                 }
5014                 if ($diff->{'from_mode'} ne ('0' x 6)) {
5015                         $from_mode_oct = oct $diff->{'from_mode'};
5016                         if (S_ISREG($from_mode_oct)) { # only for regular file
5017                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
5018                         }
5019                         $from_file_type = file_type($diff->{'from_mode'});
5020                 }
5021
5022                 if ($diff->{'status'} eq "A") { # created
5023                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
5024                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
5025                         $mode_chng   .= "]</span>";
5026                         print "<td>";
5027                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5028                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5029                                       -class => "list"}, esc_path($diff->{'file'}));
5030                         print "</td>\n";
5031                         print "<td>$mode_chng</td>\n";
5032                         print "<td class=\"link\">";
5033                         if ($action eq 'commitdiff') {
5034                                 # link to patch
5035                                 $patchno++;
5036                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5037                                               "patch") .
5038                                       " | ";
5039                         }
5040                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5041                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5042                                       "blob");
5043                         print "</td>\n";
5044
5045                 } elsif ($diff->{'status'} eq "D") { # deleted
5046                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
5047                         print "<td>";
5048                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5049                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
5050                                        -class => "list"}, esc_path($diff->{'file'}));
5051                         print "</td>\n";
5052                         print "<td>$mode_chng</td>\n";
5053                         print "<td class=\"link\">";
5054                         if ($action eq 'commitdiff') {
5055                                 # link to patch
5056                                 $patchno++;
5057                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5058                                               "patch") .
5059                                       " | ";
5060                         }
5061                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5062                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5063                                       "blob") . " | ";
5064                         if ($have_blame) {
5065                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5066                                                              file_name=>$diff->{'file'})},
5067                                               "blame") . " | ";
5068                         }
5069                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5070                                                      file_name=>$diff->{'file'})},
5071                                       "history");
5072                         print "</td>\n";
5073
5074                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5075                         my $mode_chnge = "";
5076                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5077                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5078                                 if ($from_file_type ne $to_file_type) {
5079                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5080                                 }
5081                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5082                                         if ($from_mode_str && $to_mode_str) {
5083                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5084                                         } elsif ($to_mode_str) {
5085                                                 $mode_chnge .= " mode: $to_mode_str";
5086                                         }
5087                                 }
5088                                 $mode_chnge .= "]</span>\n";
5089                         }
5090                         print "<td>";
5091                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5092                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5093                                       -class => "list"}, esc_path($diff->{'file'}));
5094                         print "</td>\n";
5095                         print "<td>$mode_chnge</td>\n";
5096                         print "<td class=\"link\">";
5097                         if ($action eq 'commitdiff') {
5098                                 # link to patch
5099                                 $patchno++;
5100                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5101                                               "patch") .
5102                                       " | ";
5103                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5104                                 # "commit" view and modified file (not onlu mode changed)
5105                                 print $cgi->a({-href => href(action=>"blobdiff",
5106                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5107                                                              hash_base=>$hash, hash_parent_base=>$parent,
5108                                                              file_name=>$diff->{'file'})},
5109                                               "diff") .
5110                                       " | ";
5111                         }
5112                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5113                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5114                                        "blob") . " | ";
5115                         if ($have_blame) {
5116                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5117                                                              file_name=>$diff->{'file'})},
5118                                               "blame") . " | ";
5119                         }
5120                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5121                                                      file_name=>$diff->{'file'})},
5122                                       "history");
5123                         print "</td>\n";
5124
5125                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5126                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5127                         my $nstatus = $status_name{$diff->{'status'}};
5128                         my $mode_chng = "";
5129                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5130                                 # mode also for directories, so we cannot use $to_mode_str
5131                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5132                         }
5133                         print "<td>" .
5134                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5135                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5136                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5137                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5138                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5139                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5140                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5141                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5142                               "<td class=\"link\">";
5143                         if ($action eq 'commitdiff') {
5144                                 # link to patch
5145                                 $patchno++;
5146                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5147                                               "patch") .
5148                                       " | ";
5149                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5150                                 # "commit" view and modified file (not only pure rename or copy)
5151                                 print $cgi->a({-href => href(action=>"blobdiff",
5152                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5153                                                              hash_base=>$hash, hash_parent_base=>$parent,
5154                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5155                                               "diff") .
5156                                       " | ";
5157                         }
5158                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5159                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5160                                       "blob") . " | ";
5161                         if ($have_blame) {
5162                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5163                                                              file_name=>$diff->{'to_file'})},
5164                                               "blame") . " | ";
5165                         }
5166                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5167                                                     file_name=>$diff->{'to_file'})},
5168                                       "history");
5169                         print "</td>\n";
5170
5171                 } # we should not encounter Unmerged (U) or Unknown (X) status
5172                 print "</tr>\n";
5173         }
5174         print "</tbody>" if $has_header;
5175         print "</table>\n";
5176 }
5177
5178 # Print context lines and then rem/add lines in a side-by-side manner.
5179 sub print_sidebyside_diff_lines {
5180         my ($ctx, $rem, $add) = @_;
5181
5182         # print context block before add/rem block
5183         if (@$ctx) {
5184                 print join '',
5185                         '<div class="chunk_block ctx">',
5186                                 '<div class="old">',
5187                                 @$ctx,
5188                                 '</div>',
5189                                 '<div class="new">',
5190                                 @$ctx,
5191                                 '</div>',
5192                         '</div>';
5193         }
5194
5195         if (!@$add) {
5196                 # pure removal
5197                 print join '',
5198                         '<div class="chunk_block rem">',
5199                                 '<div class="old">',
5200                                 @$rem,
5201                                 '</div>',
5202                         '</div>';
5203         } elsif (!@$rem) {
5204                 # pure addition
5205                 print join '',
5206                         '<div class="chunk_block add">',
5207                                 '<div class="new">',
5208                                 @$add,
5209                                 '</div>',
5210                         '</div>';
5211         } else {
5212                 print join '',
5213                         '<div class="chunk_block chg">',
5214                                 '<div class="old">',
5215                                 @$rem,
5216                                 '</div>',
5217                                 '<div class="new">',
5218                                 @$add,
5219                                 '</div>',
5220                         '</div>';
5221         }
5222 }
5223
5224 # Print context lines and then rem/add lines in inline manner.
5225 sub print_inline_diff_lines {
5226         my ($ctx, $rem, $add) = @_;
5227
5228         print @$ctx, @$rem, @$add;
5229 }
5230
5231 # Format removed and added line, mark changed part and HTML-format them.
5232 # Implementation is based on contrib/diff-highlight
5233 sub format_rem_add_lines_pair {
5234         my ($rem, $add, $num_parents) = @_;
5235
5236         # We need to untabify lines before split()'ing them;
5237         # otherwise offsets would be invalid.
5238         chomp $rem;
5239         chomp $add;
5240         $rem = untabify($rem);
5241         $add = untabify($add);
5242
5243         my @rem = split(//, $rem);
5244         my @add = split(//, $add);
5245         my ($esc_rem, $esc_add);
5246         # Ignore leading +/- characters for each parent.
5247         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5248         my ($prefix_has_nonspace, $suffix_has_nonspace);
5249
5250         my $shorter = (@rem < @add) ? @rem : @add;
5251         while ($prefix_len < $shorter) {
5252                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5253
5254                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5255                 $prefix_len++;
5256         }
5257
5258         while ($prefix_len + $suffix_len < $shorter) {
5259                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5260
5261                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5262                 $suffix_len++;
5263         }
5264
5265         # Mark lines that are different from each other, but have some common
5266         # part that isn't whitespace.  If lines are completely different, don't
5267         # mark them because that would make output unreadable, especially if
5268         # diff consists of multiple lines.
5269         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5270                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5271                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5272                 $esc_add = esc_html_hl_regions($add, 'marked',
5273                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5274         } else {
5275                 $esc_rem = esc_html($rem, -nbsp=>1);
5276                 $esc_add = esc_html($add, -nbsp=>1);
5277         }
5278
5279         return format_diff_line(\$esc_rem, 'rem'),
5280                format_diff_line(\$esc_add, 'add');
5281 }
5282
5283 # HTML-format diff context, removed and added lines.
5284 sub format_ctx_rem_add_lines {
5285         my ($ctx, $rem, $add, $num_parents) = @_;
5286         my (@new_ctx, @new_rem, @new_add);
5287         my $can_highlight = 0;
5288         my $is_combined = ($num_parents > 1);
5289
5290         # Highlight if every removed line has a corresponding added line.
5291         if (@$add > 0 && @$add == @$rem) {
5292                 $can_highlight = 1;
5293
5294                 # Highlight lines in combined diff only if the chunk contains
5295                 # diff between the same version, e.g.
5296                 #
5297                 #    - a
5298                 #   -  b
5299                 #    + c
5300                 #   +  d
5301                 #
5302                 # Otherwise the highlighting would be confusing.
5303                 if ($is_combined) {
5304                         for (my $i = 0; $i < @$add; $i++) {
5305                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5306                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5307
5308                                 $prefix_rem =~ s/-/+/g;
5309
5310                                 if ($prefix_rem ne $prefix_add) {
5311                                         $can_highlight = 0;
5312                                         last;
5313                                 }
5314                         }
5315                 }
5316         }
5317
5318         if ($can_highlight) {
5319                 for (my $i = 0; $i < @$add; $i++) {
5320                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5321                                 $rem->[$i], $add->[$i], $num_parents);
5322                         push @new_rem, $line_rem;
5323                         push @new_add, $line_add;
5324                 }
5325         } else {
5326                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5327                 @new_add = map { format_diff_line($_, 'add') } @$add;
5328         }
5329
5330         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5331
5332         return (\@new_ctx, \@new_rem, \@new_add);
5333 }
5334
5335 # Print context lines and then rem/add lines.
5336 sub print_diff_lines {
5337         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5338         my $is_combined = $num_parents > 1;
5339
5340         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5341                 $num_parents);
5342
5343         if ($diff_style eq 'sidebyside' && !$is_combined) {
5344                 print_sidebyside_diff_lines($ctx, $rem, $add);
5345         } else {
5346                 # default 'inline' style and unknown styles
5347                 print_inline_diff_lines($ctx, $rem, $add);
5348         }
5349 }
5350
5351 sub print_diff_chunk {
5352         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5353         my (@ctx, @rem, @add);
5354
5355         # The class of the previous line.
5356         my $prev_class = '';
5357
5358         return unless @chunk;
5359
5360         # incomplete last line might be among removed or added lines,
5361         # or both, or among context lines: find which
5362         for (my $i = 1; $i < @chunk; $i++) {
5363                 if ($chunk[$i][0] eq 'incomplete') {
5364                         $chunk[$i][0] = $chunk[$i-1][0];
5365                 }
5366         }
5367
5368         # guardian
5369         push @chunk, ["", ""];
5370
5371         foreach my $line_info (@chunk) {
5372                 my ($class, $line) = @$line_info;
5373
5374                 # print chunk headers
5375                 if ($class && $class eq 'chunk_header') {
5376                         print format_diff_line($line, $class, $from, $to);
5377                         next;
5378                 }
5379
5380                 ## print from accumulator when have some add/rem lines or end
5381                 # of chunk (flush context lines), or when have add and rem
5382                 # lines and new block is reached (otherwise add/rem lines could
5383                 # be reordered)
5384                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5385                     (@rem && @add && $class ne $prev_class)) {
5386                         print_diff_lines(\@ctx, \@rem, \@add,
5387                                          $diff_style, $num_parents);
5388                         @ctx = @rem = @add = ();
5389                 }
5390
5391                 ## adding lines to accumulator
5392                 # guardian value
5393                 last unless $line;
5394                 # rem, add or change
5395                 if ($class eq 'rem') {
5396                         push @rem, $line;
5397                 } elsif ($class eq 'add') {
5398                         push @add, $line;
5399                 }
5400                 # context line
5401                 if ($class eq 'ctx') {
5402                         push @ctx, $line;
5403                 }
5404
5405                 $prev_class = $class;
5406         }
5407 }
5408
5409 sub git_patchset_body {
5410         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5411         my ($hash_parent) = $hash_parents[0];
5412
5413         my $is_combined = (@hash_parents > 1);
5414         my $patch_idx = 0;
5415         my $patch_number = 0;
5416         my $patch_line;
5417         my $diffinfo;
5418         my $to_name;
5419         my (%from, %to);
5420         my @chunk; # for side-by-side diff
5421
5422         print "<div class=\"patchset\">\n";
5423
5424         # skip to first patch
5425         while ($patch_line = <$fd>) {
5426                 chomp $patch_line;
5427
5428                 last if ($patch_line =~ m/^diff /);
5429         }
5430
5431  PATCH:
5432         while ($patch_line) {
5433
5434                 # parse "git diff" header line
5435                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5436                         # $1 is from_name, which we do not use
5437                         $to_name = unquote($2);
5438                         $to_name =~ s!^b/!!;
5439                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5440                         # $1 is 'cc' or 'combined', which we do not use
5441                         $to_name = unquote($2);
5442                 } else {
5443                         $to_name = undef;
5444                 }
5445
5446                 # check if current patch belong to current raw line
5447                 # and parse raw git-diff line if needed
5448                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5449                         # this is continuation of a split patch
5450                         print "<div class=\"patch cont\">\n";
5451                 } else {
5452                         # advance raw git-diff output if needed
5453                         $patch_idx++ if defined $diffinfo;
5454
5455                         # read and prepare patch information
5456                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5457
5458                         # compact combined diff output can have some patches skipped
5459                         # find which patch (using pathname of result) we are at now;
5460                         if ($is_combined) {
5461                                 while ($to_name ne $diffinfo->{'to_file'}) {
5462                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5463                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5464                                               "</div>\n";  # class="patch"
5465
5466                                         $patch_idx++;
5467                                         $patch_number++;
5468
5469                                         last if $patch_idx > $#$difftree;
5470                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5471                                 }
5472                         }
5473
5474                         # modifies %from, %to hashes
5475                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5476
5477                         # this is first patch for raw difftree line with $patch_idx index
5478                         # we index @$difftree array from 0, but number patches from 1
5479                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5480                 }
5481
5482                 # git diff header
5483                 #assert($patch_line =~ m/^diff /) if DEBUG;
5484                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5485                 $patch_number++;
5486                 # print "git diff" header
5487                 print format_git_diff_header_line($patch_line, $diffinfo,
5488                                                   \%from, \%to);
5489
5490                 # print extended diff header
5491                 print "<div class=\"diff extended_header\">\n";
5492         EXTENDED_HEADER:
5493                 while ($patch_line = <$fd>) {
5494                         chomp $patch_line;
5495
5496                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5497
5498                         print format_extended_diff_header_line($patch_line, $diffinfo,
5499                                                                \%from, \%to);
5500                 }
5501                 print "</div>\n"; # class="diff extended_header"
5502
5503                 # from-file/to-file diff header
5504                 if (! $patch_line) {
5505                         print "</div>\n"; # class="patch"
5506                         last PATCH;
5507                 }
5508                 next PATCH if ($patch_line =~ m/^diff /);
5509                 #assert($patch_line =~ m/^---/) if DEBUG;
5510
5511                 my $last_patch_line = $patch_line;
5512                 $patch_line = <$fd>;
5513                 chomp $patch_line;
5514                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5515
5516                 print format_diff_from_to_header($last_patch_line, $patch_line,
5517                                                  $diffinfo, \%from, \%to,
5518                                                  @hash_parents);
5519
5520                 # the patch itself
5521         LINE:
5522                 while ($patch_line = <$fd>) {
5523                         chomp $patch_line;
5524
5525                         next PATCH if ($patch_line =~ m/^diff /);
5526
5527                         my $class = diff_line_class($patch_line, \%from, \%to);
5528
5529                         if ($class eq 'chunk_header') {
5530                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5531                                 @chunk = ();
5532                         }
5533
5534                         push @chunk, [ $class, $patch_line ];
5535                 }
5536
5537         } continue {
5538                 if (@chunk) {
5539                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5540                         @chunk = ();
5541                 }
5542                 print "</div>\n"; # class="patch"
5543         }
5544
5545         # for compact combined (--cc) format, with chunk and patch simplification
5546         # the patchset might be empty, but there might be unprocessed raw lines
5547         for (++$patch_idx if $patch_number > 0;
5548              $patch_idx < @$difftree;
5549              ++$patch_idx) {
5550                 # read and prepare patch information
5551                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5552
5553                 # generate anchor for "patch" links in difftree / whatchanged part
5554                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5555                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5556                       "</div>\n";  # class="patch"
5557
5558                 $patch_number++;
5559         }
5560
5561         if ($patch_number == 0) {
5562                 if (@hash_parents > 1) {
5563                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5564                 } else {
5565                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5566                 }
5567         }
5568
5569         print "</div>\n"; # class="patchset"
5570 }
5571
5572 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5573
5574 sub git_project_search_form {
5575         my ($searchtext, $search_use_regexp) = @_;
5576
5577         my $limit = '';
5578         if ($project_filter) {
5579                 $limit = " in '$project_filter/'";
5580         }
5581
5582         print "<div class=\"projsearch\">\n";
5583         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5584               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5585         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5586                 if (defined $project_filter);
5587         print $cgi->textfield(-name => 's', -value => $searchtext,
5588                               -title => "Search project by name and description$limit",
5589                               -size => 60) . "\n" .
5590               "<span title=\"Extended regular expression\">" .
5591               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5592                              -checked => $search_use_regexp) .
5593               "</span>\n" .
5594               $cgi->submit(-name => 'btnS', -value => 'Search') .
5595               $cgi->end_form() . "\n" .
5596               $cgi->a({-href => href(project => undef, searchtext => undef,
5597                                      project_filter => $project_filter)},
5598                       esc_html("List all projects$limit")) . "<br />\n";
5599         print "</div>\n";
5600 }
5601
5602 # entry for given @keys needs filling if at least one of keys in list
5603 # is not present in %$project_info
5604 sub project_info_needs_filling {
5605         my ($project_info, @keys) = @_;
5606
5607         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5608         foreach my $key (@keys) {
5609                 if (!exists $project_info->{$key}) {
5610                         return 1;
5611                 }
5612         }
5613         return;
5614 }
5615
5616 # fills project list info (age, description, owner, category, forks, etc.)
5617 # for each project in the list, removing invalid projects from
5618 # returned list, or fill only specified info.
5619 #
5620 # Invalid projects are removed from the returned list if and only if you
5621 # ask 'age' or 'age_string' to be filled, because they are the only fields
5622 # that run unconditionally git command that requires repository, and
5623 # therefore do always check if project repository is invalid.
5624 #
5625 # USAGE:
5626 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5627 #   ensures that 'descr_long' and 'ctags' fields are filled
5628 # * @project_list = fill_project_list_info(\@project_list)
5629 #   ensures that all fields are filled (and invalid projects removed)
5630 #
5631 # NOTE: modifies $projlist, but does not remove entries from it
5632 sub fill_project_list_info {
5633         my ($projlist, @wanted_keys) = @_;
5634         my @projects;
5635         my $filter_set = sub { return @_; };
5636         if (@wanted_keys) {
5637                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5638                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5639         }
5640
5641         my $show_ctags = gitweb_check_feature('ctags');
5642  PROJECT:
5643         foreach my $pr (@$projlist) {
5644                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5645                         my (@activity) = git_get_last_activity($pr->{'path'});
5646                         unless (@activity) {
5647                                 next PROJECT;
5648                         }
5649                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5650                 }
5651                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5652                         my $descr = git_get_project_description($pr->{'path'}) || "";
5653                         $descr = to_utf8($descr);
5654                         $pr->{'descr_long'} = $descr;
5655                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5656                 }
5657                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5658                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5659                 }
5660                 if ($show_ctags &&
5661                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5662                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5663                 }
5664                 if ($projects_list_group_categories &&
5665                     project_info_needs_filling($pr, $filter_set->('category'))) {
5666                         my $cat = git_get_project_category($pr->{'path'}) ||
5667                                                            $project_list_default_category;
5668                         $pr->{'category'} = to_utf8($cat);
5669                 }
5670
5671                 push @projects, $pr;
5672         }
5673
5674         return @projects;
5675 }
5676
5677 sub sort_projects_list {
5678         my ($projlist, $order) = @_;
5679
5680         sub order_str {
5681                 my $key = shift;
5682                 return sub { $a->{$key} cmp $b->{$key} };
5683         }
5684
5685         sub order_num_then_undef {
5686                 my $key = shift;
5687                 return sub {
5688                         defined $a->{$key} ?
5689                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5690                                 (defined $b->{$key} ? 1 : 0)
5691                 };
5692         }
5693
5694         my %orderings = (
5695                 project => order_str('path'),
5696                 descr => order_str('descr_long'),
5697                 owner => order_str('owner'),
5698                 age => order_num_then_undef('age'),
5699         );
5700
5701         my $ordering = $orderings{$order};
5702         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5703 }
5704
5705 # returns a hash of categories, containing the list of project
5706 # belonging to each category
5707 sub build_projlist_by_category {
5708         my ($projlist, $from, $to) = @_;
5709         my %categories;
5710
5711         $from = 0 unless defined $from;
5712         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5713
5714         for (my $i = $from; $i <= $to; $i++) {
5715                 my $pr = $projlist->[$i];
5716                 push @{$categories{ $pr->{'category'} }}, $pr;
5717         }
5718
5719         return wantarray ? %categories : \%categories;
5720 }
5721
5722 # print 'sort by' <th> element, generating 'sort by $name' replay link
5723 # if that order is not selected
5724 sub print_sort_th {
5725         print format_sort_th(@_);
5726 }
5727
5728 sub format_sort_th {
5729         my ($name, $order, $header) = @_;
5730         my $sort_th = "";
5731         $header ||= ucfirst($name);
5732
5733         if ($order eq $name) {
5734                 $sort_th .= "<th>$header</th>\n";
5735         } else {
5736                 $sort_th .= "<th>" .
5737                             $cgi->a({-href => href(-replay=>1, order=>$name),
5738                                      -class => "header"}, $header) .
5739                             "</th>\n";
5740         }
5741
5742         return $sort_th;
5743 }
5744
5745 sub git_project_list_rows {
5746         my ($projlist, $from, $to, $check_forks) = @_;
5747
5748         $from = 0 unless defined $from;
5749         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5750
5751         my $alternate = 1;
5752         for (my $i = $from; $i <= $to; $i++) {
5753                 my $pr = $projlist->[$i];
5754
5755                 if ($alternate) {
5756                         print "<tr class=\"dark\">\n";
5757                 } else {
5758                         print "<tr class=\"light\">\n";
5759                 }
5760                 $alternate ^= 1;
5761
5762                 if ($check_forks) {
5763                         print "<td>";
5764                         if ($pr->{'forks'}) {
5765                                 my $nforks = scalar @{$pr->{'forks'}};
5766                                 if ($nforks > 0) {
5767                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5768                                                        -title => "$nforks forks"}, "+");
5769                                 } else {
5770                                         print $cgi->span({-title => "$nforks forks"}, "+");
5771                                 }
5772                         }
5773                         print "</td>\n";
5774                 }
5775                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5776                                         -class => "list"},
5777                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5778                       "</td>\n" .
5779                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5780                                         -class => "list",
5781                                         -title => $pr->{'descr_long'}},
5782                                         $search_regexp
5783                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5784                                                                     $pr->{'descr'}, $search_regexp)
5785                                         : esc_html($pr->{'descr'})) .
5786                       "</td>\n";
5787                 unless ($omit_owner) {
5788                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5789                 }
5790                 unless ($omit_age_column) {
5791                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5792                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5793                 }
5794                 print"<td class=\"link\">" .
5795                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5796                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5797                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5798                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5799                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5800                       "</td>\n" .
5801                       "</tr>\n";
5802         }
5803 }
5804
5805 sub git_project_list_body {
5806         # actually uses global variable $project
5807         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5808         my @projects = @$projlist;
5809
5810         my $check_forks = gitweb_check_feature('forks');
5811         my $show_ctags  = gitweb_check_feature('ctags');
5812         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5813         $check_forks = undef
5814                 if ($tagfilter || $search_regexp);
5815
5816         # filtering out forks before filling info allows to do less work
5817         @projects = filter_forks_from_projects_list(\@projects)
5818                 if ($check_forks);
5819         # search_projects_list pre-fills required info
5820         @projects = search_projects_list(\@projects,
5821                                          'search_regexp' => $search_regexp,
5822                                          'tagfilter'  => $tagfilter)
5823                 if ($tagfilter || $search_regexp);
5824         # fill the rest
5825         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5826         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5827         push @all_fields, 'owner' unless($omit_owner);
5828         @projects = fill_project_list_info(\@projects, @all_fields);
5829
5830         $order ||= $default_projects_order;
5831         $from = 0 unless defined $from;
5832         $to = $#projects if (!defined $to || $#projects < $to);
5833
5834         # short circuit
5835         if ($from > $to) {
5836                 print "<center>\n".
5837                       "<b>No such projects found</b><br />\n".
5838                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5839                       "</center>\n<br />\n";
5840                 return;
5841         }
5842
5843         @projects = sort_projects_list(\@projects, $order);
5844
5845         if ($show_ctags) {
5846                 my $ctags = git_gather_all_ctags(\@projects);
5847                 my $cloud = git_populate_project_tagcloud($ctags);
5848                 print git_show_project_tagcloud($cloud, 64);
5849         }
5850
5851         print "<table class=\"project_list\">\n";
5852         unless ($no_header) {
5853                 print "<tr>\n";
5854                 if ($check_forks) {
5855                         print "<th></th>\n";
5856                 }
5857                 print_sort_th('project', $order, 'Project');
5858                 print_sort_th('descr', $order, 'Description');
5859                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5860                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5861                 print "<th></th>\n" . # for links
5862                       "</tr>\n";
5863         }
5864
5865         if ($projects_list_group_categories) {
5866                 # only display categories with projects in the $from-$to window
5867                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5868                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5869                 foreach my $cat (sort keys %categories) {
5870                         unless ($cat eq "") {
5871                                 print "<tr>\n";
5872                                 if ($check_forks) {
5873                                         print "<td></td>\n";
5874                                 }
5875                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5876                                 print "</tr>\n";
5877                         }
5878
5879                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5880                 }
5881         } else {
5882                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5883         }
5884
5885         if (defined $extra) {
5886                 print "<tr>\n";
5887                 if ($check_forks) {
5888                         print "<td></td>\n";
5889                 }
5890                 print "<td colspan=\"5\">$extra</td>\n" .
5891                       "</tr>\n";
5892         }
5893         print "</table>\n";
5894 }
5895
5896 sub git_log_body {
5897         # uses global variable $project
5898         my ($commitlist, $from, $to, $refs, $extra) = @_;
5899
5900         $from = 0 unless defined $from;
5901         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5902
5903         for (my $i = 0; $i <= $to; $i++) {
5904                 my %co = %{$commitlist->[$i]};
5905                 next if !%co;
5906                 my $commit = $co{'id'};
5907                 my $ref = format_ref_marker($refs, $commit);
5908                 git_print_header_div('commit',
5909                                "<span class=\"age\">$co{'age_string'}</span>" .
5910                                esc_html($co{'title'}) . $ref,
5911                                $commit);
5912                 print "<div class=\"title_text\">\n" .
5913                       "<div class=\"log_link\">\n" .
5914                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5915                       " | " .
5916                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5917                       " | " .
5918                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5919                       "<br/>\n" .
5920                       "</div>\n";
5921                       git_print_authorship(\%co, -tag => 'span');
5922                       print "<br/>\n</div>\n";
5923
5924                 print "<div class=\"log_body\">\n";
5925                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5926                 print "</div>\n";
5927         }
5928         if ($extra) {
5929                 print "<div class=\"page_nav\">\n";
5930                 print "$extra\n";
5931                 print "</div>\n";
5932         }
5933 }
5934
5935 sub git_shortlog_body {
5936         # uses global variable $project
5937         my ($commitlist, $from, $to, $refs, $extra) = @_;
5938
5939         $from = 0 unless defined $from;
5940         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5941
5942         print "<table class=\"shortlog\">\n";
5943         my $alternate = 1;
5944         for (my $i = $from; $i <= $to; $i++) {
5945                 my %co = %{$commitlist->[$i]};
5946                 my $commit = $co{'id'};
5947                 my $ref = format_ref_marker($refs, $commit);
5948                 if ($alternate) {
5949                         print "<tr class=\"dark\">\n";
5950                 } else {
5951                         print "<tr class=\"light\">\n";
5952                 }
5953                 $alternate ^= 1;
5954                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5955                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5956                       format_author_html('td', \%co, 10) . "<td>";
5957                 print format_subject_html($co{'title'}, $co{'title_short'},
5958                                           href(action=>"commit", hash=>$commit), $ref);
5959                 print "</td>\n" .
5960                       "<td class=\"link\">" .
5961                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5962                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5963                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5964                 my $snapshot_links = format_snapshot_links($commit);
5965                 if (defined $snapshot_links) {
5966                         print " | " . $snapshot_links;
5967                 }
5968                 print "</td>\n" .
5969                       "</tr>\n";
5970         }
5971         if (defined $extra) {
5972                 print "<tr>\n" .
5973                       "<td colspan=\"4\">$extra</td>\n" .
5974                       "</tr>\n";
5975         }
5976         print "</table>\n";
5977 }
5978
5979 sub git_history_body {
5980         # Warning: assumes constant type (blob or tree) during history
5981         my ($commitlist, $from, $to, $refs, $extra,
5982             $file_name, $file_hash, $ftype) = @_;
5983
5984         $from = 0 unless defined $from;
5985         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5986
5987         print "<table class=\"history\">\n";
5988         my $alternate = 1;
5989         for (my $i = $from; $i <= $to; $i++) {
5990                 my %co = %{$commitlist->[$i]};
5991                 if (!%co) {
5992                         next;
5993                 }
5994                 my $commit = $co{'id'};
5995
5996                 my $ref = format_ref_marker($refs, $commit);
5997
5998                 if ($alternate) {
5999                         print "<tr class=\"dark\">\n";
6000                 } else {
6001                         print "<tr class=\"light\">\n";
6002                 }
6003                 $alternate ^= 1;
6004                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6005         # shortlog:   format_author_html('td', \%co, 10)
6006                       format_author_html('td', \%co, 15, 3) . "<td>";
6007                 # originally git_history used chop_str($co{'title'}, 50)
6008                 print format_subject_html($co{'title'}, $co{'title_short'},
6009                                           href(action=>"commit", hash=>$commit), $ref);
6010                 print "</td>\n" .
6011                       "<td class=\"link\">" .
6012                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
6013                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
6014
6015                 if ($ftype eq 'blob') {
6016                         print " | " .
6017                               $cgi->a({-href => href(action=>"blob_plain", hash_base=>$commit, file_name=>$file_name)}, "raw");
6018
6019                         my $blob_current = $file_hash;
6020                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
6021                         if (defined $blob_current && defined $blob_parent &&
6022                                         $blob_current ne $blob_parent) {
6023                                 print " | " .
6024                                         $cgi->a({-href => href(action=>"blobdiff",
6025                                                                hash=>$blob_current, hash_parent=>$blob_parent,
6026                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
6027                                                                file_name=>$file_name)},
6028                                                 "diff to current");
6029                         }
6030                 }
6031                 print "</td>\n" .
6032                       "</tr>\n";
6033         }
6034         if (defined $extra) {
6035                 print "<tr>\n" .
6036                       "<td colspan=\"4\">$extra</td>\n" .
6037                       "</tr>\n";
6038         }
6039         print "</table>\n";
6040 }
6041
6042 sub git_tags_body {
6043         # uses global variable $project
6044         my ($taglist, $from, $to, $extra) = @_;
6045         $from = 0 unless defined $from;
6046         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
6047
6048         print "<table class=\"tags\">\n";
6049         my $alternate = 1;
6050         for (my $i = $from; $i <= $to; $i++) {
6051                 my $entry = $taglist->[$i];
6052                 my %tag = %$entry;
6053                 my $comment = $tag{'subject'};
6054                 my $comment_short;
6055                 if (defined $comment) {
6056                         $comment_short = chop_str($comment, 30, 5);
6057                 }
6058                 if ($alternate) {
6059                         print "<tr class=\"dark\">\n";
6060                 } else {
6061                         print "<tr class=\"light\">\n";
6062                 }
6063                 $alternate ^= 1;
6064                 if (defined $tag{'age'}) {
6065                         print "<td><i>$tag{'age'}</i></td>\n";
6066                 } else {
6067                         print "<td></td>\n";
6068                 }
6069                 print "<td>" .
6070                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6071                                -class => "list name"}, esc_html($tag{'name'})) .
6072                       "</td>\n" .
6073                       "<td>";
6074                 if (defined $comment) {
6075                         print format_subject_html($comment, $comment_short,
6076                                                   href(action=>"tag", hash=>$tag{'id'}));
6077                 }
6078                 print "</td>\n" .
6079                       "<td class=\"selflink\">";
6080                 if ($tag{'type'} eq "tag") {
6081                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6082                 } else {
6083                         print "&nbsp;";
6084                 }
6085                 print "</td>\n" .
6086                       "<td class=\"link\">" . " | " .
6087                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6088                 if ($tag{'reftype'} eq "commit") {
6089                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6090                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6091                 } elsif ($tag{'reftype'} eq "blob") {
6092                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6093                 }
6094                 print "</td>\n" .
6095                       "</tr>";
6096         }
6097         if (defined $extra) {
6098                 print "<tr>\n" .
6099                       "<td colspan=\"5\">$extra</td>\n" .
6100                       "</tr>\n";
6101         }
6102         print "</table>\n";
6103 }
6104
6105 sub git_heads_body {
6106         # uses global variable $project
6107         my ($headlist, $head_at, $from, $to, $extra) = @_;
6108         $from = 0 unless defined $from;
6109         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6110
6111         print "<table class=\"heads\">\n";
6112         my $alternate = 1;
6113         for (my $i = $from; $i <= $to; $i++) {
6114                 my $entry = $headlist->[$i];
6115                 my %ref = %$entry;
6116                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6117                 if ($alternate) {
6118                         print "<tr class=\"dark\">\n";
6119                 } else {
6120                         print "<tr class=\"light\">\n";
6121                 }
6122                 $alternate ^= 1;
6123                 print "<td><i>$ref{'age'}</i></td>\n" .
6124                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6125                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6126                                -class => "list name"},esc_html($ref{'name'})) .
6127                       "</td>\n" .
6128                       "<td class=\"link\">" .
6129                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6130                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6131                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6132                       "</td>\n" .
6133                       "</tr>";
6134         }
6135         if (defined $extra) {
6136                 print "<tr>\n" .
6137                       "<td colspan=\"3\">$extra</td>\n" .
6138                       "</tr>\n";
6139         }
6140         print "</table>\n";
6141 }
6142
6143 # Display a single remote block
6144 sub git_remote_block {
6145         my ($remote, $rdata, $limit, $head) = @_;
6146
6147         my $heads = $rdata->{'heads'};
6148         my $fetch = $rdata->{'fetch'};
6149         my $push = $rdata->{'push'};
6150
6151         my $urls_table = "<table class=\"projects_list\">\n" ;
6152
6153         if (defined $fetch) {
6154                 if ($fetch eq $push) {
6155                         $urls_table .= format_repo_url("URL", $fetch);
6156                 } else {
6157                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6158                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6159                 }
6160         } elsif (defined $push) {
6161                 $urls_table .= format_repo_url("Push URL", $push);
6162         } else {
6163                 $urls_table .= format_repo_url("", "No remote URL");
6164         }
6165
6166         $urls_table .= "</table>\n";
6167
6168         my $dots;
6169         if (defined $limit && $limit < @$heads) {
6170                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6171         }
6172
6173         print $urls_table;
6174         git_heads_body($heads, $head, 0, $limit, $dots);
6175 }
6176
6177 # Display a list of remote names with the respective fetch and push URLs
6178 sub git_remotes_list {
6179         my ($remotedata, $limit) = @_;
6180         print "<table class=\"heads\">\n";
6181         my $alternate = 1;
6182         my @remotes = sort keys %$remotedata;
6183
6184         my $limited = $limit && $limit < @remotes;
6185
6186         $#remotes = $limit - 1 if $limited;
6187
6188         while (my $remote = shift @remotes) {
6189                 my $rdata = $remotedata->{$remote};
6190                 my $fetch = $rdata->{'fetch'};
6191                 my $push = $rdata->{'push'};
6192                 if ($alternate) {
6193                         print "<tr class=\"dark\">\n";
6194                 } else {
6195                         print "<tr class=\"light\">\n";
6196                 }
6197                 $alternate ^= 1;
6198                 print "<td>" .
6199                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6200                                -class=> "list name"},esc_html($remote)) .
6201                       "</td>";
6202                 print "<td class=\"link\">" .
6203                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6204                       " | " .
6205                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6206                       "</td>";
6207
6208                 print "</tr>\n";
6209         }
6210
6211         if ($limited) {
6212                 print "<tr>\n" .
6213                       "<td colspan=\"3\">" .
6214                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6215                       "</td>\n" . "</tr>\n";
6216         }
6217
6218         print "</table>";
6219 }
6220
6221 # Display remote heads grouped by remote, unless there are too many
6222 # remotes, in which case we only display the remote names
6223 sub git_remotes_body {
6224         my ($remotedata, $limit, $head) = @_;
6225         if ($limit and $limit < keys %$remotedata) {
6226                 git_remotes_list($remotedata, $limit);
6227         } else {
6228                 fill_remote_heads($remotedata);
6229                 while (my ($remote, $rdata) = each %$remotedata) {
6230                         git_print_section({-class=>"remote", -id=>$remote},
6231                                 ["remotes", $remote, $remote], sub {
6232                                         git_remote_block($remote, $rdata, $limit, $head);
6233                                 });
6234                 }
6235         }
6236 }
6237
6238 sub git_search_message {
6239         my %co = @_;
6240
6241         my $greptype;
6242         if ($searchtype eq 'commit') {
6243                 $greptype = "--grep=";
6244         } elsif ($searchtype eq 'author') {
6245                 $greptype = "--author=";
6246         } elsif ($searchtype eq 'committer') {
6247                 $greptype = "--committer=";
6248         }
6249         $greptype .= $searchtext;
6250         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6251                                        $greptype, '--regexp-ignore-case',
6252                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6253
6254         my $paging_nav = '';
6255         if ($page > 0) {
6256                 $paging_nav .=
6257                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6258                                 "first") .
6259                         " &sdot; " .
6260                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6261                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6262         } else {
6263                 $paging_nav .= "first &sdot; prev";
6264         }
6265         my $next_link = '';
6266         if ($#commitlist >= 100) {
6267                 $next_link =
6268                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6269                                  -accesskey => "n", -title => "Alt-n"}, "next");
6270                 $paging_nav .= " &sdot; $next_link";
6271         } else {
6272                 $paging_nav .= " &sdot; next";
6273         }
6274
6275         git_header_html();
6276
6277         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6278         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6279         if ($page == 0 && !@commitlist) {
6280                 print "<p>No match.</p>\n";
6281         } else {
6282                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6283         }
6284
6285         git_footer_html();
6286 }
6287
6288 sub git_search_changes {
6289         my %co = @_;
6290
6291         local $/ = "\n";
6292         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6293                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6294                 ($search_use_regexp ? '--pickaxe-regex' : ())
6295                         or die_error(500, "Open git-log failed");
6296
6297         git_header_html();
6298
6299         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6300         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6301
6302         print "<table class=\"pickaxe search\">\n";
6303         my $alternate = 1;
6304         undef %co;
6305         my @files;
6306         while (my $line = <$fd>) {
6307                 chomp $line;
6308                 next unless $line;
6309
6310                 my %set = parse_difftree_raw_line($line);
6311                 if (defined $set{'commit'}) {
6312                         # finish previous commit
6313                         if (%co) {
6314                                 print "</td>\n" .
6315                                       "<td class=\"link\">" .
6316                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6317                                               "commit") .
6318                                       " | " .
6319                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6320                                                              hash_base=>$co{'id'})},
6321                                               "tree") .
6322                                       "</td>\n" .
6323                                       "</tr>\n";
6324                         }
6325
6326                         if ($alternate) {
6327                                 print "<tr class=\"dark\">\n";
6328                         } else {
6329                                 print "<tr class=\"light\">\n";
6330                         }
6331                         $alternate ^= 1;
6332                         %co = parse_commit($set{'commit'});
6333                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6334                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6335                               "<td><i>$author</i></td>\n" .
6336                               "<td>" .
6337                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6338                                       -class => "list subject"},
6339                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6340                 } elsif (defined $set{'to_id'}) {
6341                         next if is_deleted(\%set);
6342
6343                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6344                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6345                                       -class => "list"},
6346                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6347                               "<br/>\n";
6348                 }
6349         }
6350         close $fd;
6351
6352         # finish last commit (warning: repetition!)
6353         if (%co) {
6354                 print "</td>\n" .
6355                       "<td class=\"link\">" .
6356                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6357                               "commit") .
6358                       " | " .
6359                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6360                                              hash_base=>$co{'id'})},
6361                               "tree") .
6362                       "</td>\n" .
6363                       "</tr>\n";
6364         }
6365
6366         print "</table>\n";
6367
6368         git_footer_html();
6369 }
6370
6371 sub git_search_files {
6372         my %co = @_;
6373
6374         local $/ = "\n";
6375         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6376                 $search_use_regexp ? ('-E', '-i') : '-F',
6377                 $searchtext, $co{'tree'}
6378                         or die_error(500, "Open git-grep failed");
6379
6380         git_header_html();
6381
6382         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6383         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6384
6385         print "<table class=\"grep_search\">\n";
6386         my $alternate = 1;
6387         my $matches = 0;
6388         my $lastfile = '';
6389         my $file_href;
6390         while (my $line = <$fd>) {
6391                 chomp $line;
6392                 my ($file, $lno, $ltext, $binary);
6393                 last if ($matches++ > 1000);
6394                 if ($line =~ /^Binary file (.+) matches$/) {
6395                         $file = $1;
6396                         $binary = 1;
6397                 } else {
6398                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6399                         $file =~ s/^$co{'tree'}://;
6400                 }
6401                 if ($file ne $lastfile) {
6402                         $lastfile and print "</td></tr>\n";
6403                         if ($alternate++) {
6404                                 print "<tr class=\"dark\">\n";
6405                         } else {
6406                                 print "<tr class=\"light\">\n";
6407                         }
6408                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6409                                           file_name=>$file);
6410                         print "<td class=\"list\">".
6411                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6412                         print "</td><td>\n";
6413                         $lastfile = $file;
6414                 }
6415                 if ($binary) {
6416                         print "<div class=\"binary\">Binary file</div>\n";
6417                 } else {
6418                         $ltext = untabify($ltext);
6419                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6420                                 $ltext = esc_html($1, -nbsp=>1);
6421                                 $ltext .= '<span class="match">';
6422                                 $ltext .= esc_html($2, -nbsp=>1);
6423                                 $ltext .= '</span>';
6424                                 $ltext .= esc_html($3, -nbsp=>1);
6425                         } else {
6426                                 $ltext = esc_html($ltext, -nbsp=>1);
6427                         }
6428                         print "<div class=\"pre\">" .
6429                                 $cgi->a({-href => $file_href.'#l'.$lno,
6430                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6431                                 ' ' .  $ltext . "</div>\n";
6432                 }
6433         }
6434         if ($lastfile) {
6435                 print "</td></tr>\n";
6436                 if ($matches > 1000) {
6437                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6438                 }
6439         } else {
6440                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6441         }
6442         close $fd;
6443
6444         print "</table>\n";
6445
6446         git_footer_html();
6447 }
6448
6449 sub git_search_grep_body {
6450         my ($commitlist, $from, $to, $extra) = @_;
6451         $from = 0 unless defined $from;
6452         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6453
6454         print "<table class=\"commit_search\">\n";
6455         my $alternate = 1;
6456         for (my $i = $from; $i <= $to; $i++) {
6457                 my %co = %{$commitlist->[$i]};
6458                 if (!%co) {
6459                         next;
6460                 }
6461                 my $commit = $co{'id'};
6462                 if ($alternate) {
6463                         print "<tr class=\"dark\">\n";
6464                 } else {
6465                         print "<tr class=\"light\">\n";
6466                 }
6467                 $alternate ^= 1;
6468                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6469                       format_author_html('td', \%co, 15, 5) .
6470                       "<td>" .
6471                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6472                                -class => "list subject"},
6473                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6474                 my $comment = $co{'comment'};
6475                 foreach my $line (@$comment) {
6476                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6477                                 my ($lead, $match, $trail) = ($1, $2, $3);
6478                                 $match = chop_str($match, 70, 5, 'center');
6479                                 my $contextlen = int((80 - length($match))/2);
6480                                 $contextlen = 30 if ($contextlen > 30);
6481                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6482                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6483
6484                                 $lead  = esc_html($lead);
6485                                 $match = esc_html($match);
6486                                 $trail = esc_html($trail);
6487
6488                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6489                         }
6490                 }
6491                 print "</td>\n" .
6492                       "<td class=\"link\">" .
6493                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6494                       " | " .
6495                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6496                       " | " .
6497                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6498                 print "</td>\n" .
6499                       "</tr>\n";
6500         }
6501         if (defined $extra) {
6502                 print "<tr>\n" .
6503                       "<td colspan=\"3\">$extra</td>\n" .
6504                       "</tr>\n";
6505         }
6506         print "</table>\n";
6507 }
6508
6509 ## ======================================================================
6510 ## ======================================================================
6511 ## actions
6512
6513 sub git_project_list {
6514         my $order = $input_params{'order'};
6515         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6516                 die_error(400, "Unknown order parameter");
6517         }
6518
6519         my @list = git_get_projects_list($project_filter, $strict_export);
6520         if (!@list) {
6521                 die_error(404, "No projects found");
6522         }
6523
6524         git_header_html();
6525         if (defined $home_text && -f $home_text) {
6526                 print "<div class=\"index_include\">\n";
6527                 insert_file($home_text);
6528                 print "</div>\n";
6529         }
6530
6531         git_project_search_form($searchtext, $search_use_regexp);
6532         git_project_list_body(\@list, $order);
6533         git_footer_html();
6534 }
6535
6536 sub git_forks {
6537         my $order = $input_params{'order'};
6538         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6539                 die_error(400, "Unknown order parameter");
6540         }
6541
6542         my $filter = $project;
6543         $filter =~ s/\.git$//;
6544         my @list = git_get_projects_list($filter);
6545         if (!@list) {
6546                 die_error(404, "No forks found");
6547         }
6548
6549         git_header_html();
6550         git_print_page_nav('','');
6551         git_print_header_div('summary', "$project forks");
6552         git_project_list_body(\@list, $order);
6553         git_footer_html();
6554 }
6555
6556 sub git_project_index {
6557         my @projects = git_get_projects_list($project_filter, $strict_export);
6558         if (!@projects) {
6559                 die_error(404, "No projects found");
6560         }
6561
6562         print $cgi->header(
6563                 -type => 'text/plain',
6564                 -charset => 'utf-8',
6565                 -content_disposition => 'inline; filename="index.aux"');
6566
6567         foreach my $pr (@projects) {
6568                 if (!exists $pr->{'owner'}) {
6569                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6570                 }
6571
6572                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6573                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6574                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6575                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6576                 $path  =~ s/ /\+/g;
6577                 $owner =~ s/ /\+/g;
6578
6579                 print "$path $owner\n";
6580         }
6581 }
6582
6583 sub git_summary {
6584         my $descr = git_get_project_description($project) || "none";
6585         my %co = parse_commit("HEAD");
6586         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6587         my $head = $co{'id'};
6588         my $remote_heads = gitweb_check_feature('remote_heads');
6589
6590         my $owner = git_get_project_owner($project);
6591
6592         my $refs = git_get_references();
6593         # These get_*_list functions return one more to allow us to see if
6594         # there are more ...
6595         my @taglist  = git_get_tags_list(16);
6596         my @headlist = git_get_heads_list(16);
6597         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6598         my @forklist;
6599         my $check_forks = gitweb_check_feature('forks');
6600
6601         if ($check_forks) {
6602                 # find forks of a project
6603                 my $filter = $project;
6604                 $filter =~ s/\.git$//;
6605                 @forklist = git_get_projects_list($filter);
6606                 # filter out forks of forks
6607                 @forklist = filter_forks_from_projects_list(\@forklist)
6608                         if (@forklist);
6609         }
6610
6611         git_header_html();
6612         git_print_page_nav('summary','', $head);
6613
6614         print "<div class=\"title\">&nbsp;</div>\n";
6615         print "<table class=\"projects_list\">\n" .
6616               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6617         if ($owner and not $omit_owner) {
6618                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6619         }
6620         if (defined $cd{'rfc2822'}) {
6621                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6622                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6623         }
6624
6625         # use per project git URL list in $projectroot/$project/cloneurl
6626         # or make project git URL from git base URL and project name
6627         my $url_tag = "URL";
6628         my @url_list = git_get_project_url_list($project);
6629         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6630         foreach my $git_url (@url_list) {
6631                 next unless $git_url;
6632                 print format_repo_url($url_tag, $git_url);
6633                 $url_tag = "";
6634         }
6635
6636         # Tag cloud
6637         my $show_ctags = gitweb_check_feature('ctags');
6638         if ($show_ctags) {
6639                 my $ctags = git_get_project_ctags($project);
6640                 if (%$ctags) {
6641                         # without ability to add tags, don't show if there are none
6642                         my $cloud = git_populate_project_tagcloud($ctags);
6643                         print "<tr id=\"metadata_ctags\">" .
6644                               "<td>content tags</td>" .
6645                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6646                               "</tr>\n";
6647                 }
6648         }
6649
6650         print "</table>\n";
6651
6652         # If XSS prevention is on, we don't include README.html.
6653         # TODO: Allow a readme in some safe format.
6654         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6655                 print "<div class=\"title\">readme</div>\n" .
6656                       "<div class=\"readme\">\n";
6657                 insert_file("$projectroot/$project/README.html");
6658                 print "\n</div>\n"; # class="readme"
6659         }
6660
6661         # we need to request one more than 16 (0..15) to check if
6662         # those 16 are all
6663         my @commitlist = $head ? parse_commits($head, 17) : ();
6664         if (@commitlist) {
6665                 git_print_header_div('shortlog');
6666                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6667                                   $#commitlist <=  15 ? undef :
6668                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6669         }
6670
6671         if (@taglist) {
6672                 git_print_header_div('tags');
6673                 git_tags_body(\@taglist, 0, 15,
6674                               $#taglist <=  15 ? undef :
6675                               $cgi->a({-href => href(action=>"tags")}, "..."));
6676         }
6677
6678         if (@headlist) {
6679                 git_print_header_div('heads');
6680                 git_heads_body(\@headlist, $head, 0, 15,
6681                                $#headlist <= 15 ? undef :
6682                                $cgi->a({-href => href(action=>"heads")}, "..."));
6683         }
6684
6685         if (%remotedata) {
6686                 git_print_header_div('remotes');
6687                 git_remotes_body(\%remotedata, 15, $head);
6688         }
6689
6690         if (@forklist) {
6691                 git_print_header_div('forks');
6692                 git_project_list_body(\@forklist, 'age', 0, 15,
6693                                       $#forklist <= 15 ? undef :
6694                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6695                                       'no_header');
6696         }
6697
6698         git_footer_html();
6699 }
6700
6701 sub git_tag {
6702         my %tag = parse_tag($hash);
6703
6704         if (! %tag) {
6705                 die_error(404, "Unknown tag object");
6706         }
6707
6708         my $head = git_get_head_hash($project);
6709         git_header_html();
6710         git_print_page_nav('','', $head,undef,$head);
6711         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6712         print "<div class=\"title_text\">\n" .
6713               "<table class=\"object_header\">\n" .
6714               "<tr>\n" .
6715               "<td>object</td>\n" .
6716               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6717                                $tag{'object'}) . "</td>\n" .
6718               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6719                                               $tag{'type'}) . "</td>\n" .
6720               "</tr>\n";
6721         if (defined($tag{'author'})) {
6722                 git_print_authorship_rows(\%tag, 'author');
6723         }
6724         print "</table>\n\n" .
6725               "</div>\n";
6726         print "<div class=\"page_body\">";
6727         my $comment = $tag{'comment'};
6728         foreach my $line (@$comment) {
6729                 chomp $line;
6730                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6731         }
6732         print "</div>\n";
6733         git_footer_html();
6734 }
6735
6736 sub git_blame_common {
6737         my $format = shift || 'porcelain';
6738         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6739                 $format = 'incremental';
6740                 $action = 'blame_incremental'; # for page title etc
6741         }
6742
6743         # permissions
6744         gitweb_check_feature('blame')
6745                 or die_error(403, "Blame view not allowed");
6746
6747         # error checking
6748         die_error(400, "No file name given") unless $file_name;
6749         $hash_base ||= git_get_head_hash($project);
6750         die_error(404, "Couldn't find base commit") unless $hash_base;
6751         my %co = parse_commit($hash_base)
6752                 or die_error(404, "Commit not found");
6753         my $ftype = "blob";
6754         if (!defined $hash) {
6755                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6756                         or die_error(404, "Error looking up file");
6757         } else {
6758                 $ftype = git_get_type($hash);
6759                 if ($ftype !~ "blob") {
6760                         die_error(400, "Object is not a blob");
6761                 }
6762         }
6763
6764         my $fd;
6765         if ($format eq 'incremental') {
6766                 # get file contents (as base)
6767                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6768                         or die_error(500, "Open git-cat-file failed");
6769         } elsif ($format eq 'data') {
6770                 # run git-blame --incremental
6771                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6772                         $hash_base, "--", $file_name
6773                         or die_error(500, "Open git-blame --incremental failed");
6774         } else {
6775                 # run git-blame --porcelain
6776                 open $fd, "-|", git_cmd(), "blame", '-p',
6777                         $hash_base, '--', $file_name
6778                         or die_error(500, "Open git-blame --porcelain failed");
6779         }
6780         binmode $fd, ':utf8';
6781
6782         # incremental blame data returns early
6783         if ($format eq 'data') {
6784                 print $cgi->header(
6785                         -type=>"text/plain", -charset => "utf-8",
6786                         -status=> "200 OK");
6787                 local $| = 1; # output autoflush
6788                 while (my $line = <$fd>) {
6789                         print to_utf8($line);
6790                 }
6791                 close $fd
6792                         or print "ERROR $!\n";
6793
6794                 print 'END';
6795                 if (defined $t0 && gitweb_check_feature('timed')) {
6796                         print ' '.
6797                               tv_interval($t0, [ gettimeofday() ]).
6798                               ' '.$number_of_git_cmds;
6799                 }
6800                 print "\n";
6801
6802                 return;
6803         }
6804
6805         # page header
6806         git_header_html();
6807         my $formats_nav =
6808                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6809                         "blob") .
6810                 " | ";
6811         if ($format eq 'incremental') {
6812                 $formats_nav .=
6813                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6814                                 "blame") . " (non-incremental)";
6815         } else {
6816                 $formats_nav .=
6817                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6818                                 "blame") . " (incremental)";
6819         }
6820         $formats_nav .=
6821                 " | " .
6822                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6823                         "history") .
6824                 " | " .
6825                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6826                         "HEAD");
6827         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6828         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6829         git_print_page_path($file_name, $ftype, $hash_base);
6830
6831         # page body
6832         if ($format eq 'incremental') {
6833                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6834                       "This page requires JavaScript to run.\n Use ".
6835                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6836                               'this page').
6837                       " instead.\n".
6838                       "</b></center></div>\n</noscript>\n";
6839
6840                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6841         }
6842
6843         print qq!<div class="page_body">\n!;
6844         print qq!<div id="progress_info">... / ...</div>\n!
6845                 if ($format eq 'incremental');
6846         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6847               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6848               qq!<thead>\n!.
6849               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6850               qq!</thead>\n!.
6851               qq!<tbody>\n!;
6852
6853         my @rev_color = qw(light dark);
6854         my $num_colors = scalar(@rev_color);
6855         my $current_color = 0;
6856
6857         if ($format eq 'incremental') {
6858                 my $color_class = $rev_color[$current_color];
6859
6860                 #contents of a file
6861                 my $linenr = 0;
6862         LINE:
6863                 while (my $line = <$fd>) {
6864                         chomp $line;
6865                         $linenr++;
6866
6867                         print qq!<tr id="l$linenr" class="$color_class">!.
6868                               qq!<td class="sha1"><a href=""> </a></td>!.
6869                               qq!<td class="linenr">!.
6870                               qq!<a class="linenr" href="">$linenr</a></td>!;
6871                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6872                         print qq!</tr>\n!;
6873                 }
6874
6875         } else { # porcelain, i.e. ordinary blame
6876                 my %metainfo = (); # saves information about commits
6877
6878                 # blame data
6879         LINE:
6880                 while (my $line = <$fd>) {
6881                         chomp $line;
6882                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6883                         # no <lines in group> for subsequent lines in group of lines
6884                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6885                            ($line =~ /^($oid_regex) (\d+) (\d+)(?: (\d+))?$/);
6886                         if (!exists $metainfo{$full_rev}) {
6887                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6888                         }
6889                         my $meta = $metainfo{$full_rev};
6890                         my $data;
6891                         while ($data = <$fd>) {
6892                                 chomp $data;
6893                                 last if ($data =~ s/^\t//); # contents of line
6894                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6895                                         $meta->{$1} = $2 unless exists $meta->{$1};
6896                                 }
6897                                 if ($data =~ /^previous /) {
6898                                         $meta->{'nprevious'}++;
6899                                 }
6900                         }
6901                         my $short_rev = substr($full_rev, 0, 8);
6902                         my $author = $meta->{'author'};
6903                         my %date =
6904                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6905                         my $date = $date{'iso-tz'};
6906                         if ($group_size) {
6907                                 $current_color = ($current_color + 1) % $num_colors;
6908                         }
6909                         my $tr_class = $rev_color[$current_color];
6910                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6911                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6912                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6913                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6914                         if ($group_size) {
6915                                 print "<td class=\"sha1\"";
6916                                 print " title=\"". esc_html($author) . ", $date\"";
6917                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6918                                 print ">";
6919                                 print $cgi->a({-href => href(action=>"commit",
6920                                                              hash=>$full_rev,
6921                                                              file_name=>$file_name)},
6922                                               esc_html($short_rev));
6923                                 if ($group_size >= 2) {
6924                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6925                                         if (@author_initials) {
6926                                                 print "<br />" .
6927                                                       esc_html(join('', @author_initials));
6928                                                 #           or join('.', ...)
6929                                         }
6930                                 }
6931                                 print "</td>\n";
6932                         }
6933                         # 'previous' <sha1 of parent commit> <filename at commit>
6934                         if (exists $meta->{'previous'} &&
6935                             $meta->{'previous'} =~ /^($oid_regex) (.*)$/) {
6936                                 $meta->{'parent'} = $1;
6937                                 $meta->{'file_parent'} = unquote($2);
6938                         }
6939                         my $linenr_commit =
6940                                 exists($meta->{'parent'}) ?
6941                                 $meta->{'parent'} : $full_rev;
6942                         my $linenr_filename =
6943                                 exists($meta->{'file_parent'}) ?
6944                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6945                         my $blamed = href(action => 'blame',
6946                                           file_name => $linenr_filename,
6947                                           hash_base => $linenr_commit);
6948                         print "<td class=\"linenr\">";
6949                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6950                                         -class => "linenr" },
6951                                       esc_html($lineno));
6952                         print "</td>";
6953                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6954                         print "</tr>\n";
6955                 } # end while
6956
6957         }
6958
6959         # footer
6960         print "</tbody>\n".
6961               "</table>\n"; # class="blame"
6962         print "</div>\n";   # class="blame_body"
6963         close $fd
6964                 or print "Reading blob failed\n";
6965
6966         git_footer_html();
6967 }
6968
6969 sub git_blame {
6970         git_blame_common();
6971 }
6972
6973 sub git_blame_incremental {
6974         git_blame_common('incremental');
6975 }
6976
6977 sub git_blame_data {
6978         git_blame_common('data');
6979 }
6980
6981 sub git_tags {
6982         my $head = git_get_head_hash($project);
6983         git_header_html();
6984         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6985         git_print_header_div('summary', $project);
6986
6987         my @tagslist = git_get_tags_list();
6988         if (@tagslist) {
6989                 git_tags_body(\@tagslist);
6990         }
6991         git_footer_html();
6992 }
6993
6994 sub git_heads {
6995         my $head = git_get_head_hash($project);
6996         git_header_html();
6997         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6998         git_print_header_div('summary', $project);
6999
7000         my @headslist = git_get_heads_list();
7001         if (@headslist) {
7002                 git_heads_body(\@headslist, $head);
7003         }
7004         git_footer_html();
7005 }
7006
7007 # used both for single remote view and for list of all the remotes
7008 sub git_remotes {
7009         gitweb_check_feature('remote_heads')
7010                 or die_error(403, "Remote heads view is disabled");
7011
7012         my $head = git_get_head_hash($project);
7013         my $remote = $input_params{'hash'};
7014
7015         my $remotedata = git_get_remotes_list($remote);
7016         die_error(500, "Unable to get remote information") unless defined $remotedata;
7017
7018         unless (%$remotedata) {
7019                 die_error(404, defined $remote ?
7020                         "Remote $remote not found" :
7021                         "No remotes found");
7022         }
7023
7024         git_header_html(undef, undef, -action_extra => $remote);
7025         git_print_page_nav('', '',  $head, undef, $head,
7026                 format_ref_views($remote ? '' : 'remotes'));
7027
7028         fill_remote_heads($remotedata);
7029         if (defined $remote) {
7030                 git_print_header_div('remotes', "$remote remote for $project");
7031                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
7032         } else {
7033                 git_print_header_div('summary', "$project remotes");
7034                 git_remotes_body($remotedata, undef, $head);
7035         }
7036
7037         git_footer_html();
7038 }
7039
7040 sub git_blob_plain {
7041         my $type = shift;
7042         my $expires;
7043
7044         if (!defined $hash) {
7045                 if (defined $file_name) {
7046                         my $base = $hash_base || git_get_head_hash($project);
7047                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7048                                 or die_error(404, "Cannot find file");
7049                 } else {
7050                         die_error(400, "No file name defined");
7051                 }
7052         } elsif ($hash =~ m/^$oid_regex$/) {
7053                 # blobs defined by non-textual hash id's can be cached
7054                 $expires = "+1d";
7055         }
7056
7057         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7058                 or die_error(500, "Open git-cat-file blob '$hash' failed");
7059
7060         # content-type (can include charset)
7061         $type = blob_contenttype($fd, $file_name, $type);
7062
7063         # "save as" filename, even when no $file_name is given
7064         my $save_as = "$hash";
7065         if (defined $file_name) {
7066                 $save_as = $file_name;
7067         } elsif ($type =~ m/^text\//) {
7068                 $save_as .= '.txt';
7069         }
7070
7071         # With XSS prevention on, blobs of all types except a few known safe
7072         # ones are served with "Content-Disposition: attachment" to make sure
7073         # they don't run in our security domain.  For certain image types,
7074         # blob view writes an <img> tag referring to blob_plain view, and we
7075         # want to be sure not to break that by serving the image as an
7076         # attachment (though Firefox 3 doesn't seem to care).
7077         my $sandbox = $prevent_xss &&
7078                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7079
7080         # serve text/* as text/plain
7081         if ($prevent_xss &&
7082             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7083              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7084                 my $rest = $1;
7085                 $rest = defined $rest ? $rest : '';
7086                 $type = "text/plain$rest";
7087         }
7088
7089         print $cgi->header(
7090                 -type => $type,
7091                 -expires => $expires,
7092                 -content_disposition =>
7093                         ($sandbox ? 'attachment' : 'inline')
7094                         . '; filename="' . $save_as . '"');
7095         local $/ = undef;
7096         local *FCGI::Stream::PRINT = $FCGI_Stream_PRINT_raw;
7097         binmode STDOUT, ':raw';
7098         print <$fd>;
7099         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7100         close $fd;
7101 }
7102
7103 sub git_blob {
7104         my $expires;
7105
7106         if (!defined $hash) {
7107                 if (defined $file_name) {
7108                         my $base = $hash_base || git_get_head_hash($project);
7109                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7110                                 or die_error(404, "Cannot find file");
7111                 } else {
7112                         die_error(400, "No file name defined");
7113                 }
7114         } elsif ($hash =~ m/^$oid_regex$/) {
7115                 # blobs defined by non-textual hash id's can be cached
7116                 $expires = "+1d";
7117         }
7118
7119         my $have_blame = gitweb_check_feature('blame');
7120         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7121                 or die_error(500, "Couldn't cat $file_name, $hash");
7122         my $mimetype = blob_mimetype($fd, $file_name);
7123         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7124         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7125                 close $fd;
7126                 return git_blob_plain($mimetype);
7127         }
7128         # we can have blame only for text/* mimetype
7129         $have_blame &&= ($mimetype =~ m!^text/!);
7130
7131         my $highlight = gitweb_check_feature('highlight');
7132         my $syntax = guess_file_syntax($highlight, $file_name);
7133         $fd = run_highlighter($fd, $highlight, $syntax);
7134
7135         git_header_html(undef, $expires);
7136         my $formats_nav = '';
7137         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7138                 if (defined $file_name) {
7139                         if ($have_blame) {
7140                                 $formats_nav .=
7141                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7142                                                 "blame") .
7143                                         " | ";
7144                         }
7145                         $formats_nav .=
7146                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7147                                         "history") .
7148                                 " | " .
7149                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7150                                         "raw") .
7151                                 " | " .
7152                                 $cgi->a({-href => href(action=>"blob",
7153                                                        hash_base=>"HEAD", file_name=>$file_name)},
7154                                         "HEAD");
7155                 } else {
7156                         $formats_nav .=
7157                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7158                                         "raw");
7159                 }
7160                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7161                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7162         } else {
7163                 print "<div class=\"page_nav\">\n" .
7164                       "<br/><br/></div>\n" .
7165                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7166         }
7167         git_print_page_path($file_name, "blob", $hash_base);
7168         print "<div class=\"page_body\">\n";
7169         if ($mimetype =~ m!^image/!) {
7170                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7171                 if ($file_name) {
7172                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7173                 }
7174                 print qq! src="! .
7175                       esc_attr(href(action=>"blob_plain", hash=>$hash,
7176                            hash_base=>$hash_base, file_name=>$file_name)) .
7177                       qq!" />\n!;
7178         } else {
7179                 my $nr;
7180                 while (my $line = <$fd>) {
7181                         chomp $line;
7182                         $nr++;
7183                         $line = untabify($line);
7184                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7185                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7186                                $highlight ? sanitize($line) : esc_html($line, -nbsp=>1);
7187                 }
7188         }
7189         close $fd
7190                 or print "Reading blob failed.\n";
7191         print "</div>";
7192         git_footer_html();
7193 }
7194
7195 sub git_tree {
7196         if (!defined $hash_base) {
7197                 $hash_base = "HEAD";
7198         }
7199         if (!defined $hash) {
7200                 if (defined $file_name) {
7201                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7202                 } else {
7203                         $hash = $hash_base;
7204                 }
7205         }
7206         die_error(404, "No such tree") unless defined($hash);
7207
7208         my $show_sizes = gitweb_check_feature('show-sizes');
7209         my $have_blame = gitweb_check_feature('blame');
7210
7211         my @entries = ();
7212         {
7213                 local $/ = "\0";
7214                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7215                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7216                         or die_error(500, "Open git-ls-tree failed");
7217                 @entries = map { chomp; $_ } <$fd>;
7218                 close $fd
7219                         or die_error(404, "Reading tree failed");
7220         }
7221
7222         my $refs = git_get_references();
7223         my $ref = format_ref_marker($refs, $hash_base);
7224         git_header_html();
7225         my $basedir = '';
7226         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7227                 my @views_nav = ();
7228                 if (defined $file_name) {
7229                         push @views_nav,
7230                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7231                                         "history"),
7232                                 $cgi->a({-href => href(action=>"tree",
7233                                                        hash_base=>"HEAD", file_name=>$file_name)},
7234                                         "HEAD"),
7235                 }
7236                 my $snapshot_links = format_snapshot_links($hash);
7237                 if (defined $snapshot_links) {
7238                         # FIXME: Should be available when we have no hash base as well.
7239                         push @views_nav, $snapshot_links;
7240                 }
7241                 git_print_page_nav('tree','', $hash_base, undef, undef,
7242                                    join(' | ', @views_nav));
7243                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7244         } else {
7245                 undef $hash_base;
7246                 print "<div class=\"page_nav\">\n";
7247                 print "<br/><br/></div>\n";
7248                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7249         }
7250         if (defined $file_name) {
7251                 $basedir = $file_name;
7252                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7253                         $basedir .= '/';
7254                 }
7255                 git_print_page_path($file_name, 'tree', $hash_base);
7256         }
7257         print "<div class=\"page_body\">\n";
7258         print "<table class=\"tree\">\n";
7259         my $alternate = 1;
7260         # '..' (top directory) link if possible
7261         if (defined $hash_base &&
7262             defined $file_name && $file_name =~ m![^/]+$!) {
7263                 if ($alternate) {
7264                         print "<tr class=\"dark\">\n";
7265                 } else {
7266                         print "<tr class=\"light\">\n";
7267                 }
7268                 $alternate ^= 1;
7269
7270                 my $up = $file_name;
7271                 $up =~ s!/?[^/]+$!!;
7272                 undef $up unless $up;
7273                 # based on git_print_tree_entry
7274                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7275                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7276                 print '<td class="list">';
7277                 print $cgi->a({-href => href(action=>"tree",
7278                                              hash_base=>$hash_base,
7279                                              file_name=>$up)},
7280                               "..");
7281                 print "</td>\n";
7282                 print "<td class=\"link\"></td>\n";
7283
7284                 print "</tr>\n";
7285         }
7286         foreach my $line (@entries) {
7287                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7288
7289                 if ($alternate) {
7290                         print "<tr class=\"dark\">\n";
7291                 } else {
7292                         print "<tr class=\"light\">\n";
7293                 }
7294                 $alternate ^= 1;
7295
7296                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7297
7298                 print "</tr>\n";
7299         }
7300         print "</table>\n" .
7301               "</div>";
7302         git_footer_html();
7303 }
7304
7305 sub sanitize_for_filename {
7306     my $name = shift;
7307
7308     $name =~ s!/!-!g;
7309     $name =~ s/[^[:alnum:]_.-]//g;
7310
7311     return $name;
7312 }
7313
7314 sub snapshot_name {
7315         my ($project, $hash) = @_;
7316
7317         # path/to/project.git  -> project
7318         # path/to/project/.git -> project
7319         my $name = to_utf8($project);
7320         $name =~ s,([^/])/*\.git$,$1,;
7321         $name = sanitize_for_filename(basename($name));
7322
7323         my $ver = $hash;
7324         if ($hash =~ /^[0-9a-fA-F]+$/) {
7325                 # shorten SHA-1 hash
7326                 my $full_hash = git_get_full_hash($project, $hash);
7327                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7328                         $ver = git_get_short_hash($project, $hash);
7329                 }
7330         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7331                 # tags don't need shortened SHA-1 hash
7332                 $ver = $1;
7333         } else {
7334                 # branches and other need shortened SHA-1 hash
7335                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7336                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7337                         my $ref_dir = (defined $1) ? $1 : '';
7338                         $ver = $2;
7339
7340                         $ref_dir = sanitize_for_filename($ref_dir);
7341                         # for refs neither in heads nor remotes we want to
7342                         # add a ref dir to archive name
7343                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7344                                 $ver = $ref_dir . '-' . $ver;
7345                         }
7346                 }
7347                 $ver .= '-' . git_get_short_hash($project, $hash);
7348         }
7349         # special case of sanitization for filename - we change
7350         # slashes to dots instead of dashes
7351         # in case of hierarchical branch names
7352         $ver =~ s!/!.!g;
7353         $ver =~ s/[^[:alnum:]_.-]//g;
7354
7355         # name = project-version_string
7356         $name = "$name-$ver";
7357
7358         return wantarray ? ($name, $name) : $name;
7359 }
7360
7361 sub exit_if_unmodified_since {
7362         my ($latest_epoch) = @_;
7363         our $cgi;
7364
7365         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7366         if (defined $if_modified) {
7367                 my $since;
7368                 if (eval { require HTTP::Date; 1; }) {
7369                         $since = HTTP::Date::str2time($if_modified);
7370                 } elsif (eval { require Time::ParseDate; 1; }) {
7371                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7372                 }
7373                 if (defined $since && $latest_epoch <= $since) {
7374                         my %latest_date = parse_date($latest_epoch);
7375                         print $cgi->header(
7376                                 -last_modified => $latest_date{'rfc2822'},
7377                                 -status => '304 Not Modified');
7378                         goto DONE_GITWEB;
7379                 }
7380         }
7381 }
7382
7383 sub git_snapshot {
7384         my $format = $input_params{'snapshot_format'};
7385         if (!@snapshot_fmts) {
7386                 die_error(403, "Snapshots not allowed");
7387         }
7388         # default to first supported snapshot format
7389         $format ||= $snapshot_fmts[0];
7390         if ($format !~ m/^[a-z0-9]+$/) {
7391                 die_error(400, "Invalid snapshot format parameter");
7392         } elsif (!exists($known_snapshot_formats{$format})) {
7393                 die_error(400, "Unknown snapshot format");
7394         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7395                 die_error(403, "Snapshot format not allowed");
7396         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7397                 die_error(403, "Unsupported snapshot format");
7398         }
7399
7400         my $type = git_get_type("$hash^{}");
7401         if (!$type) {
7402                 die_error(404, 'Object does not exist');
7403         }  elsif ($type eq 'blob') {
7404                 die_error(400, 'Object is not a tree-ish');
7405         }
7406
7407         my ($name, $prefix) = snapshot_name($project, $hash);
7408         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7409
7410         my %co = parse_commit($hash);
7411         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7412
7413         my $cmd = quote_command(
7414                 git_cmd(), 'archive',
7415                 "--format=$known_snapshot_formats{$format}{'format'}",
7416                 "--prefix=$prefix/", $hash);
7417         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7418                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7419         }
7420
7421         $filename =~ s/(["\\])/\\$1/g;
7422         my %latest_date;
7423         if (%co) {
7424                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7425         }
7426
7427         print $cgi->header(
7428                 -type => $known_snapshot_formats{$format}{'type'},
7429                 -content_disposition => 'inline; filename="' . $filename . '"',
7430                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7431                 -status => '200 OK');
7432
7433         open my $fd, "-|", $cmd
7434                 or die_error(500, "Execute git-archive failed");
7435         local *FCGI::Stream::PRINT = $FCGI_Stream_PRINT_raw;
7436         binmode STDOUT, ':raw';
7437         print <$fd>;
7438         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7439         close $fd;
7440 }
7441
7442 sub git_log_generic {
7443         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7444
7445         my $head = git_get_head_hash($project);
7446         if (!defined $base) {
7447                 $base = $head;
7448         }
7449         if (!defined $page) {
7450                 $page = 0;
7451         }
7452         my $refs = git_get_references();
7453
7454         my $commit_hash = $base;
7455         if (defined $parent) {
7456                 $commit_hash = "$parent..$base";
7457         }
7458         my @commitlist =
7459                 parse_commits($commit_hash, 101, (100 * $page),
7460                               defined $file_name ? ($file_name, "--full-history") : ());
7461
7462         my $ftype;
7463         if (!defined $file_hash && defined $file_name) {
7464                 # some commits could have deleted file in question,
7465                 # and not have it in tree, but one of them has to have it
7466                 for (my $i = 0; $i < @commitlist; $i++) {
7467                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7468                         last if defined $file_hash;
7469                 }
7470         }
7471         if (defined $file_hash) {
7472                 $ftype = git_get_type($file_hash);
7473         }
7474         if (defined $file_name && !defined $ftype) {
7475                 die_error(500, "Unknown type of object");
7476         }
7477         my %co;
7478         if (defined $file_name) {
7479                 %co = parse_commit($base)
7480                         or die_error(404, "Unknown commit object");
7481         }
7482
7483
7484         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7485         my $next_link = '';
7486         if ($#commitlist >= 100) {
7487                 $next_link =
7488                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7489                                  -accesskey => "n", -title => "Alt-n"}, "next");
7490         }
7491         my $patch_max = gitweb_get_feature('patches');
7492         if ($patch_max && !defined $file_name) {
7493                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7494                         $paging_nav .= " &sdot; " .
7495                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7496                                         "patches");
7497                 }
7498         }
7499
7500         git_header_html();
7501         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7502         if (defined $file_name) {
7503                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7504         } else {
7505                 git_print_header_div('summary', $project)
7506         }
7507         git_print_page_path($file_name, $ftype, $hash_base)
7508                 if (defined $file_name);
7509
7510         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7511                      $file_name, $file_hash, $ftype);
7512
7513         git_footer_html();
7514 }
7515
7516 sub git_log {
7517         git_log_generic('log', \&git_log_body,
7518                         $hash, $hash_parent);
7519 }
7520
7521 sub git_commit {
7522         $hash ||= $hash_base || "HEAD";
7523         my %co = parse_commit($hash)
7524             or die_error(404, "Unknown commit object");
7525
7526         my $parent  = $co{'parent'};
7527         my $parents = $co{'parents'}; # listref
7528
7529         # we need to prepare $formats_nav before any parameter munging
7530         my $formats_nav;
7531         if (!defined $parent) {
7532                 # --root commitdiff
7533                 $formats_nav .= '(initial)';
7534         } elsif (@$parents == 1) {
7535                 # single parent commit
7536                 $formats_nav .=
7537                         '(parent: ' .
7538                         $cgi->a({-href => href(action=>"commit",
7539                                                hash=>$parent)},
7540                                 esc_html(substr($parent, 0, 7))) .
7541                         ')';
7542         } else {
7543                 # merge commit
7544                 $formats_nav .=
7545                         '(merge: ' .
7546                         join(' ', map {
7547                                 $cgi->a({-href => href(action=>"commit",
7548                                                        hash=>$_)},
7549                                         esc_html(substr($_, 0, 7)));
7550                         } @$parents ) .
7551                         ')';
7552         }
7553         if (gitweb_check_feature('patches') && @$parents <= 1) {
7554                 $formats_nav .= " | " .
7555                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7556                                 "patch");
7557         }
7558
7559         if (!defined $parent) {
7560                 $parent = "--root";
7561         }
7562         my @difftree;
7563         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7564                 @diff_opts,
7565                 (@$parents <= 1 ? $parent : '-c'),
7566                 $hash, "--"
7567                 or die_error(500, "Open git-diff-tree failed");
7568         @difftree = map { chomp; $_ } <$fd>;
7569         close $fd or die_error(404, "Reading git-diff-tree failed");
7570
7571         # non-textual hash id's can be cached
7572         my $expires;
7573         if ($hash =~ m/^$oid_regex$/) {
7574                 $expires = "+1d";
7575         }
7576         my $refs = git_get_references();
7577         my $ref = format_ref_marker($refs, $co{'id'});
7578
7579         git_header_html(undef, $expires);
7580         git_print_page_nav('commit', '',
7581                            $hash, $co{'tree'}, $hash,
7582                            $formats_nav);
7583
7584         if (defined $co{'parent'}) {
7585                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7586         } else {
7587                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7588         }
7589         print "<div class=\"title_text\">\n" .
7590               "<table class=\"object_header\">\n";
7591         git_print_authorship_rows(\%co);
7592         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7593         print "<tr>" .
7594               "<td>tree</td>" .
7595               "<td class=\"sha1\">" .
7596               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7597                        class => "list"}, $co{'tree'}) .
7598               "</td>" .
7599               "<td class=\"link\">" .
7600               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7601                       "tree");
7602         my $snapshot_links = format_snapshot_links($hash);
7603         if (defined $snapshot_links) {
7604                 print " | " . $snapshot_links;
7605         }
7606         print "</td>" .
7607               "</tr>\n";
7608
7609         foreach my $par (@$parents) {
7610                 print "<tr>" .
7611                       "<td>parent</td>" .
7612                       "<td class=\"sha1\">" .
7613                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7614                                class => "list"}, $par) .
7615                       "</td>" .
7616                       "<td class=\"link\">" .
7617                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7618                       " | " .
7619                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7620                       "</td>" .
7621                       "</tr>\n";
7622         }
7623         print "</table>".
7624               "</div>\n";
7625
7626         print "<div class=\"page_body\">\n";
7627         git_print_log($co{'comment'});
7628         print "</div>\n";
7629
7630         git_difftree_body(\@difftree, $hash, @$parents);
7631
7632         git_footer_html();
7633 }
7634
7635 sub git_object {
7636         # object is defined by:
7637         # - hash or hash_base alone
7638         # - hash_base and file_name
7639         my $type;
7640
7641         # - hash or hash_base alone
7642         if ($hash || ($hash_base && !defined $file_name)) {
7643                 my $object_id = $hash || $hash_base;
7644
7645                 open my $fd, "-|", quote_command(
7646                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7647                         or die_error(404, "Object does not exist");
7648                 $type = <$fd>;
7649                 defined $type && chomp $type;
7650                 close $fd
7651                         or die_error(404, "Object does not exist");
7652
7653         # - hash_base and file_name
7654         } elsif ($hash_base && defined $file_name) {
7655                 $file_name =~ s,/+$,,;
7656
7657                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7658                         or die_error(404, "Base object does not exist");
7659
7660                 # here errors should not happen
7661                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7662                         or die_error(500, "Open git-ls-tree failed");
7663                 my $line = <$fd>;
7664                 close $fd;
7665
7666                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7667                 unless ($line && $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/) {
7668                         die_error(404, "File or directory for given base does not exist");
7669                 }
7670                 $type = $2;
7671                 $hash = $3;
7672         } else {
7673                 die_error(400, "Not enough information to find object");
7674         }
7675
7676         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7677                                           hash=>$hash, hash_base=>$hash_base,
7678                                           file_name=>$file_name),
7679                              -status => '302 Found');
7680 }
7681
7682 sub git_blobdiff {
7683         my $format = shift || 'html';
7684         my $diff_style = $input_params{'diff_style'} || 'inline';
7685
7686         my $fd;
7687         my @difftree;
7688         my %diffinfo;
7689         my $expires;
7690
7691         # preparing $fd and %diffinfo for git_patchset_body
7692         # new style URI
7693         if (defined $hash_base && defined $hash_parent_base) {
7694                 if (defined $file_name) {
7695                         # read raw output
7696                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7697                                 $hash_parent_base, $hash_base,
7698                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7699                                 or die_error(500, "Open git-diff-tree failed");
7700                         @difftree = map { chomp; $_ } <$fd>;
7701                         close $fd
7702                                 or die_error(404, "Reading git-diff-tree failed");
7703                         @difftree
7704                                 or die_error(404, "Blob diff not found");
7705
7706                 } elsif (defined $hash &&
7707                          $hash =~ $oid_regex) {
7708                         # try to find filename from $hash
7709
7710                         # read filtered raw output
7711                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7712                                 $hash_parent_base, $hash_base, "--"
7713                                 or die_error(500, "Open git-diff-tree failed");
7714                         @difftree =
7715                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7716                                 # $hash == to_id
7717                                 grep { /^:[0-7]{6} [0-7]{6} $oid_regex $hash/ }
7718                                 map { chomp; $_ } <$fd>;
7719                         close $fd
7720                                 or die_error(404, "Reading git-diff-tree failed");
7721                         @difftree
7722                                 or die_error(404, "Blob diff not found");
7723
7724                 } else {
7725                         die_error(400, "Missing one of the blob diff parameters");
7726                 }
7727
7728                 if (@difftree > 1) {
7729                         die_error(400, "Ambiguous blob diff specification");
7730                 }
7731
7732                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7733                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7734                 $file_name   ||= $diffinfo{'to_file'};
7735
7736                 $hash_parent ||= $diffinfo{'from_id'};
7737                 $hash        ||= $diffinfo{'to_id'};
7738
7739                 # non-textual hash id's can be cached
7740                 if ($hash_base =~ m/^$oid_regex$/ &&
7741                     $hash_parent_base =~ m/^$oid_regex$/) {
7742                         $expires = '+1d';
7743                 }
7744
7745                 # open patch output
7746                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7747                         '-p', ($format eq 'html' ? "--full-index" : ()),
7748                         $hash_parent_base, $hash_base,
7749                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7750                         or die_error(500, "Open git-diff-tree failed");
7751         }
7752
7753         # old/legacy style URI -- not generated anymore since 1.4.3.
7754         if (!%diffinfo) {
7755                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7756         }
7757
7758         # header
7759         if ($format eq 'html') {
7760                 my $formats_nav =
7761                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7762                                 "raw");
7763                 $formats_nav .= diff_style_nav($diff_style);
7764                 git_header_html(undef, $expires);
7765                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7766                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7767                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7768                 } else {
7769                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7770                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7771                 }
7772                 if (defined $file_name) {
7773                         git_print_page_path($file_name, "blob", $hash_base);
7774                 } else {
7775                         print "<div class=\"page_path\"></div>\n";
7776                 }
7777
7778         } elsif ($format eq 'plain') {
7779                 print $cgi->header(
7780                         -type => 'text/plain',
7781                         -charset => 'utf-8',
7782                         -expires => $expires,
7783                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7784
7785                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7786
7787         } else {
7788                 die_error(400, "Unknown blobdiff format");
7789         }
7790
7791         # patch
7792         if ($format eq 'html') {
7793                 print "<div class=\"page_body\">\n";
7794
7795                 git_patchset_body($fd, $diff_style,
7796                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7797                 close $fd;
7798
7799                 print "</div>\n"; # class="page_body"
7800                 git_footer_html();
7801
7802         } else {
7803                 while (my $line = <$fd>) {
7804                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7805                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7806
7807                         print $line;
7808
7809                         last if $line =~ m!^\+\+\+!;
7810                 }
7811                 local $/ = undef;
7812                 print <$fd>;
7813                 close $fd;
7814         }
7815 }
7816
7817 sub git_blobdiff_plain {
7818         git_blobdiff('plain');
7819 }
7820
7821 # assumes that it is added as later part of already existing navigation,
7822 # so it returns "| foo | bar" rather than just "foo | bar"
7823 sub diff_style_nav {
7824         my ($diff_style, $is_combined) = @_;
7825         $diff_style ||= 'inline';
7826
7827         return "" if ($is_combined);
7828
7829         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7830         my %styles = @styles;
7831         @styles =
7832                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7833
7834         return join '',
7835                 map { " | ".$_ }
7836                 map {
7837                         $_ eq $diff_style ? $styles{$_} :
7838                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7839                 } @styles;
7840 }
7841
7842 sub git_commitdiff {
7843         my %params = @_;
7844         my $format = $params{-format} || 'html';
7845         my $diff_style = $input_params{'diff_style'} || 'inline';
7846
7847         my ($patch_max) = gitweb_get_feature('patches');
7848         if ($format eq 'patch') {
7849                 die_error(403, "Patch view not allowed") unless $patch_max;
7850         }
7851
7852         $hash ||= $hash_base || "HEAD";
7853         my %co = parse_commit($hash)
7854             or die_error(404, "Unknown commit object");
7855
7856         # choose format for commitdiff for merge
7857         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7858                 $hash_parent = '--cc';
7859         }
7860         # we need to prepare $formats_nav before almost any parameter munging
7861         my $formats_nav;
7862         if ($format eq 'html') {
7863                 $formats_nav =
7864                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7865                                 "raw");
7866                 if ($patch_max && @{$co{'parents'}} <= 1) {
7867                         $formats_nav .= " | " .
7868                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7869                                         "patch");
7870                 }
7871                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7872
7873                 if (defined $hash_parent &&
7874                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7875                         # commitdiff with two commits given
7876                         my $hash_parent_short = $hash_parent;
7877                         if ($hash_parent =~ m/^$oid_regex$/) {
7878                                 $hash_parent_short = substr($hash_parent, 0, 7);
7879                         }
7880                         $formats_nav .=
7881                                 ' (from';
7882                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7883                                 if ($co{'parents'}[$i] eq $hash_parent) {
7884                                         $formats_nav .= ' parent ' . ($i+1);
7885                                         last;
7886                                 }
7887                         }
7888                         $formats_nav .= ': ' .
7889                                 $cgi->a({-href => href(-replay=>1,
7890                                                        hash=>$hash_parent, hash_base=>undef)},
7891                                         esc_html($hash_parent_short)) .
7892                                 ')';
7893                 } elsif (!$co{'parent'}) {
7894                         # --root commitdiff
7895                         $formats_nav .= ' (initial)';
7896                 } elsif (scalar @{$co{'parents'}} == 1) {
7897                         # single parent commit
7898                         $formats_nav .=
7899                                 ' (parent: ' .
7900                                 $cgi->a({-href => href(-replay=>1,
7901                                                        hash=>$co{'parent'}, hash_base=>undef)},
7902                                         esc_html(substr($co{'parent'}, 0, 7))) .
7903                                 ')';
7904                 } else {
7905                         # merge commit
7906                         if ($hash_parent eq '--cc') {
7907                                 $formats_nav .= ' | ' .
7908                                         $cgi->a({-href => href(-replay=>1,
7909                                                                hash=>$hash, hash_parent=>'-c')},
7910                                                 'combined');
7911                         } else { # $hash_parent eq '-c'
7912                                 $formats_nav .= ' | ' .
7913                                         $cgi->a({-href => href(-replay=>1,
7914                                                                hash=>$hash, hash_parent=>'--cc')},
7915                                                 'compact');
7916                         }
7917                         $formats_nav .=
7918                                 ' (merge: ' .
7919                                 join(' ', map {
7920                                         $cgi->a({-href => href(-replay=>1,
7921                                                                hash=>$_, hash_base=>undef)},
7922                                                 esc_html(substr($_, 0, 7)));
7923                                 } @{$co{'parents'}} ) .
7924                                 ')';
7925                 }
7926         }
7927
7928         my $hash_parent_param = $hash_parent;
7929         if (!defined $hash_parent_param) {
7930                 # --cc for multiple parents, --root for parentless
7931                 $hash_parent_param =
7932                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7933         }
7934
7935         # read commitdiff
7936         my $fd;
7937         my @difftree;
7938         if ($format eq 'html') {
7939                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7940                         "--no-commit-id", "--patch-with-raw", "--full-index",
7941                         $hash_parent_param, $hash, "--"
7942                         or die_error(500, "Open git-diff-tree failed");
7943
7944                 while (my $line = <$fd>) {
7945                         chomp $line;
7946                         # empty line ends raw part of diff-tree output
7947                         last unless $line;
7948                         push @difftree, scalar parse_difftree_raw_line($line);
7949                 }
7950
7951         } elsif ($format eq 'plain') {
7952                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7953                         '-p', $hash_parent_param, $hash, "--"
7954                         or die_error(500, "Open git-diff-tree failed");
7955         } elsif ($format eq 'patch') {
7956                 # For commit ranges, we limit the output to the number of
7957                 # patches specified in the 'patches' feature.
7958                 # For single commits, we limit the output to a single patch,
7959                 # diverging from the git-format-patch default.
7960                 my @commit_spec = ();
7961                 if ($hash_parent) {
7962                         if ($patch_max > 0) {
7963                                 push @commit_spec, "-$patch_max";
7964                         }
7965                         push @commit_spec, '-n', "$hash_parent..$hash";
7966                 } else {
7967                         if ($params{-single}) {
7968                                 push @commit_spec, '-1';
7969                         } else {
7970                                 if ($patch_max > 0) {
7971                                         push @commit_spec, "-$patch_max";
7972                                 }
7973                                 push @commit_spec, "-n";
7974                         }
7975                         push @commit_spec, '--root', $hash;
7976                 }
7977                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7978                         '--encoding=utf8', '--stdout', @commit_spec
7979                         or die_error(500, "Open git-format-patch failed");
7980         } else {
7981                 die_error(400, "Unknown commitdiff format");
7982         }
7983
7984         # non-textual hash id's can be cached
7985         my $expires;
7986         if ($hash =~ m/^$oid_regex$/) {
7987                 $expires = "+1d";
7988         }
7989
7990         # write commit message
7991         if ($format eq 'html') {
7992                 my $refs = git_get_references();
7993                 my $ref = format_ref_marker($refs, $co{'id'});
7994
7995                 git_header_html(undef, $expires);
7996                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7997                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7998                 print "<div class=\"title_text\">\n" .
7999                       "<table class=\"object_header\">\n";
8000                 git_print_authorship_rows(\%co);
8001                 print "</table>".
8002                       "</div>\n";
8003                 print "<div class=\"page_body\">\n";
8004                 if (@{$co{'comment'}} > 1) {
8005                         print "<div class=\"log\">\n";
8006                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
8007                         print "</div>\n"; # class="log"
8008                 }
8009
8010         } elsif ($format eq 'plain') {
8011                 my $refs = git_get_references("tags");
8012                 my $tagname = git_get_rev_name_tags($hash);
8013                 my $filename = basename($project) . "-$hash.patch";
8014
8015                 print $cgi->header(
8016                         -type => 'text/plain',
8017                         -charset => 'utf-8',
8018                         -expires => $expires,
8019                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8020                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
8021                 print "From: " . to_utf8($co{'author'}) . "\n";
8022                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
8023                 print "Subject: " . to_utf8($co{'title'}) . "\n";
8024
8025                 print "X-Git-Tag: $tagname\n" if $tagname;
8026                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
8027
8028                 foreach my $line (@{$co{'comment'}}) {
8029                         print to_utf8($line) . "\n";
8030                 }
8031                 print "---\n\n";
8032         } elsif ($format eq 'patch') {
8033                 my $filename = basename($project) . "-$hash.patch";
8034
8035                 print $cgi->header(
8036                         -type => 'text/plain',
8037                         -charset => 'utf-8',
8038                         -expires => $expires,
8039                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8040         }
8041
8042         # write patch
8043         if ($format eq 'html') {
8044                 my $use_parents = !defined $hash_parent ||
8045                         $hash_parent eq '-c' || $hash_parent eq '--cc';
8046                 git_difftree_body(\@difftree, $hash,
8047                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8048                 print "<br/>\n";
8049
8050                 git_patchset_body($fd, $diff_style,
8051                                   \@difftree, $hash,
8052                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8053                 close $fd;
8054                 print "</div>\n"; # class="page_body"
8055                 git_footer_html();
8056
8057         } elsif ($format eq 'plain') {
8058                 local $/ = undef;
8059                 print <$fd>;
8060                 close $fd
8061                         or print "Reading git-diff-tree failed\n";
8062         } elsif ($format eq 'patch') {
8063                 local $/ = undef;
8064                 print <$fd>;
8065                 close $fd
8066                         or print "Reading git-format-patch failed\n";
8067         }
8068 }
8069
8070 sub git_commitdiff_plain {
8071         git_commitdiff(-format => 'plain');
8072 }
8073
8074 # format-patch-style patches
8075 sub git_patch {
8076         git_commitdiff(-format => 'patch', -single => 1);
8077 }
8078
8079 sub git_patches {
8080         git_commitdiff(-format => 'patch');
8081 }
8082
8083 sub git_history {
8084         git_log_generic('history', \&git_history_body,
8085                         $hash_base, $hash_parent_base,
8086                         $file_name, $hash);
8087 }
8088
8089 sub git_search {
8090         $searchtype ||= 'commit';
8091
8092         # check if appropriate features are enabled
8093         gitweb_check_feature('search')
8094                 or die_error(403, "Search is disabled");
8095         if ($searchtype eq 'pickaxe') {
8096                 # pickaxe may take all resources of your box and run for several minutes
8097                 # with every query - so decide by yourself how public you make this feature
8098                 gitweb_check_feature('pickaxe')
8099                         or die_error(403, "Pickaxe search is disabled");
8100         }
8101         if ($searchtype eq 'grep') {
8102                 # grep search might be potentially CPU-intensive, too
8103                 gitweb_check_feature('grep')
8104                         or die_error(403, "Grep search is disabled");
8105         }
8106
8107         if (!defined $searchtext) {
8108                 die_error(400, "Text field is empty");
8109         }
8110         if (!defined $hash) {
8111                 $hash = git_get_head_hash($project);
8112         }
8113         my %co = parse_commit($hash);
8114         if (!%co) {
8115                 die_error(404, "Unknown commit object");
8116         }
8117         if (!defined $page) {
8118                 $page = 0;
8119         }
8120
8121         if ($searchtype eq 'commit' ||
8122             $searchtype eq 'author' ||
8123             $searchtype eq 'committer') {
8124                 git_search_message(%co);
8125         } elsif ($searchtype eq 'pickaxe') {
8126                 git_search_changes(%co);
8127         } elsif ($searchtype eq 'grep') {
8128                 git_search_files(%co);
8129         } else {
8130                 die_error(400, "Unknown search type");
8131         }
8132 }
8133
8134 sub git_search_help {
8135         git_header_html();
8136         git_print_page_nav('','', $hash,$hash,$hash);
8137         print <<EOT;
8138 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8139 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8140 the pattern entered is recognized as the POSIX extended
8141 <a href="https://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8142 insensitive).</p>
8143 <dl>
8144 <dt><b>commit</b></dt>
8145 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8146 EOT
8147         my $have_grep = gitweb_check_feature('grep');
8148         if ($have_grep) {
8149                 print <<EOT;
8150 <dt><b>grep</b></dt>
8151 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8152     a different one) are searched for the given pattern. On large trees, this search can take
8153 a while and put some strain on the server, so please use it with some consideration. Note that
8154 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8155 case-sensitive.</dd>
8156 EOT
8157         }
8158         print <<EOT;
8159 <dt><b>author</b></dt>
8160 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8161 <dt><b>committer</b></dt>
8162 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8163 EOT
8164         my $have_pickaxe = gitweb_check_feature('pickaxe');
8165         if ($have_pickaxe) {
8166                 print <<EOT;
8167 <dt><b>pickaxe</b></dt>
8168 <dd>All commits that caused the string to appear or disappear from any file (changes that
8169 added, removed or "modified" the string) will be listed. This search can take a while and
8170 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8171 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8172 EOT
8173         }
8174         print "</dl>\n";
8175         git_footer_html();
8176 }
8177
8178 sub git_shortlog {
8179         git_log_generic('shortlog', \&git_shortlog_body,
8180                         $hash, $hash_parent);
8181 }
8182
8183 ## ......................................................................
8184 ## feeds (RSS, Atom; OPML)
8185
8186 sub git_feed {
8187         my $format = shift || 'atom';
8188         my $have_blame = gitweb_check_feature('blame');
8189
8190         # Atom: http://www.atomenabled.org/developers/syndication/
8191         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8192         if ($format ne 'rss' && $format ne 'atom') {
8193                 die_error(400, "Unknown web feed format");
8194         }
8195
8196         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8197         my $head = $hash || 'HEAD';
8198         my @commitlist = parse_commits($head, 150, 0, $file_name);
8199
8200         my %latest_commit;
8201         my %latest_date;
8202         my $content_type = "application/$format+xml";
8203         if (defined $cgi->http('HTTP_ACCEPT') &&
8204                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8205                 # browser (feed reader) prefers text/xml
8206                 $content_type = 'text/xml';
8207         }
8208         if (defined($commitlist[0])) {
8209                 %latest_commit = %{$commitlist[0]};
8210                 my $latest_epoch = $latest_commit{'committer_epoch'};
8211                 exit_if_unmodified_since($latest_epoch);
8212                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8213         }
8214         print $cgi->header(
8215                 -type => $content_type,
8216                 -charset => 'utf-8',
8217                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8218                 -status => '200 OK');
8219
8220         # Optimization: skip generating the body if client asks only
8221         # for Last-Modified date.
8222         return if ($cgi->request_method() eq 'HEAD');
8223
8224         # header variables
8225         my $title = "$site_name - $project/$action";
8226         my $feed_type = 'log';
8227         if (defined $hash) {
8228                 $title .= " - '$hash'";
8229                 $feed_type = 'branch log';
8230                 if (defined $file_name) {
8231                         $title .= " :: $file_name";
8232                         $feed_type = 'history';
8233                 }
8234         } elsif (defined $file_name) {
8235                 $title .= " - $file_name";
8236                 $feed_type = 'history';
8237         }
8238         $title .= " $feed_type";
8239         $title = esc_html($title);
8240         my $descr = git_get_project_description($project);
8241         if (defined $descr) {
8242                 $descr = esc_html($descr);
8243         } else {
8244                 $descr = "$project " .
8245                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8246                          " feed";
8247         }
8248         my $owner = git_get_project_owner($project);
8249         $owner = esc_html($owner);
8250
8251         #header
8252         my $alt_url;
8253         if (defined $file_name) {
8254                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8255         } elsif (defined $hash) {
8256                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8257         } else {
8258                 $alt_url = href(-full=>1, action=>"summary");
8259         }
8260         $alt_url = esc_attr($alt_url);
8261         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8262         if ($format eq 'rss') {
8263                 print <<XML;
8264 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8265 <channel>
8266 XML
8267                 print "<title>$title</title>\n" .
8268                       "<link>$alt_url</link>\n" .
8269                       "<description>$descr</description>\n" .
8270                       "<language>en</language>\n" .
8271                       # project owner is responsible for 'editorial' content
8272                       "<managingEditor>$owner</managingEditor>\n";
8273                 if (defined $logo || defined $favicon) {
8274                         # prefer the logo to the favicon, since RSS
8275                         # doesn't allow both
8276                         my $img = esc_url($logo || $favicon);
8277                         print "<image>\n" .
8278                               "<url>$img</url>\n" .
8279                               "<title>$title</title>\n" .
8280                               "<link>$alt_url</link>\n" .
8281                               "</image>\n";
8282                 }
8283                 if (%latest_date) {
8284                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8285                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8286                 }
8287                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8288         } elsif ($format eq 'atom') {
8289                 print <<XML;
8290 <feed xmlns="http://www.w3.org/2005/Atom">
8291 XML
8292                 print "<title>$title</title>\n" .
8293                       "<subtitle>$descr</subtitle>\n" .
8294                       '<link rel="alternate" type="text/html" href="' .
8295                       $alt_url . '" />' . "\n" .
8296                       '<link rel="self" type="' . $content_type . '" href="' .
8297                       $cgi->self_url() . '" />' . "\n" .
8298                       "<id>" . esc_url(href(-full=>1)) . "</id>\n" .
8299                       # use project owner for feed author
8300                       "<author><name>$owner</name></author>\n";
8301                 if (defined $favicon) {
8302                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8303                 }
8304                 if (defined $logo) {
8305                         # not twice as wide as tall: 72 x 27 pixels
8306                         print "<logo>" . esc_url($logo) . "</logo>\n";
8307                 }
8308                 if (! %latest_date) {
8309                         # dummy date to keep the feed valid until commits trickle in:
8310                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8311                 } else {
8312                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8313                 }
8314                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8315         }
8316
8317         # contents
8318         for (my $i = 0; $i <= $#commitlist; $i++) {
8319                 my %co = %{$commitlist[$i]};
8320                 my $commit = $co{'id'};
8321                 # we read 150, we always show 30 and the ones more recent than 48 hours
8322                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8323                         last;
8324                 }
8325                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8326
8327                 # get list of changed files
8328                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8329                         $co{'parent'} || "--root",
8330                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8331                         or next;
8332                 my @difftree = map { chomp; $_ } <$fd>;
8333                 close $fd
8334                         or next;
8335
8336                 # print element (entry, item)
8337                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8338                 if ($format eq 'rss') {
8339                         print "<item>\n" .
8340                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8341                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8342                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8343                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8344                               "<link>" . esc_html($co_url) . "</link>\n" .
8345                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8346                               "<content:encoded>" .
8347                               "<![CDATA[\n";
8348                 } elsif ($format eq 'atom') {
8349                         print "<entry>\n" .
8350                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8351                               "<updated>$cd{'iso-8601'}</updated>\n" .
8352                               "<author>\n" .
8353                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8354                         if ($co{'author_email'}) {
8355                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8356                         }
8357                         print "</author>\n" .
8358                               # use committer for contributor
8359                               "<contributor>\n" .
8360                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8361                         if ($co{'committer_email'}) {
8362                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8363                         }
8364                         print "</contributor>\n" .
8365                               "<published>$cd{'iso-8601'}</published>\n" .
8366                               "<link rel=\"alternate\" type=\"text/html\" href=\"" . esc_attr($co_url) . "\" />\n" .
8367                               "<id>" . esc_html($co_url) . "</id>\n" .
8368                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8369                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8370                 }
8371                 my $comment = $co{'comment'};
8372                 print "<pre>\n";
8373                 foreach my $line (@$comment) {
8374                         $line = esc_html($line);
8375                         print "$line\n";
8376                 }
8377                 print "</pre><ul>\n";
8378                 foreach my $difftree_line (@difftree) {
8379                         my %difftree = parse_difftree_raw_line($difftree_line);
8380                         next if !$difftree{'from_id'};
8381
8382                         my $file = $difftree{'file'} || $difftree{'to_file'};
8383
8384                         print "<li>" .
8385                               "[" .
8386                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8387                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8388                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8389                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8390                                       -title => "diff"}, 'D');
8391                         if ($have_blame) {
8392                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8393                                                              file_name=>$file, hash_base=>$commit),
8394                                               -title => "blame"}, 'B');
8395                         }
8396                         # if this is not a feed of a file history
8397                         if (!defined $file_name || $file_name ne $file) {
8398                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8399                                                              file_name=>$file, hash=>$commit),
8400                                               -title => "history"}, 'H');
8401                         }
8402                         $file = esc_path($file);
8403                         print "] ".
8404                               "$file</li>\n";
8405                 }
8406                 if ($format eq 'rss') {
8407                         print "</ul>]]>\n" .
8408                               "</content:encoded>\n" .
8409                               "</item>\n";
8410                 } elsif ($format eq 'atom') {
8411                         print "</ul>\n</div>\n" .
8412                               "</content>\n" .
8413                               "</entry>\n";
8414                 }
8415         }
8416
8417         # end of feed
8418         if ($format eq 'rss') {
8419                 print "</channel>\n</rss>\n";
8420         } elsif ($format eq 'atom') {
8421                 print "</feed>\n";
8422         }
8423 }
8424
8425 sub git_rss {
8426         git_feed('rss');
8427 }
8428
8429 sub git_atom {
8430         git_feed('atom');
8431 }
8432
8433 sub git_opml {
8434         my @list = git_get_projects_list($project_filter, $strict_export);
8435         if (!@list) {
8436                 die_error(404, "No projects found");
8437         }
8438
8439         print $cgi->header(
8440                 -type => 'text/xml',
8441                 -charset => 'utf-8',
8442                 -content_disposition => 'inline; filename="opml.xml"');
8443
8444         my $title = esc_html($site_name);
8445         my $filter = " within subdirectory ";
8446         if (defined $project_filter) {
8447                 $filter .= esc_html($project_filter);
8448         } else {
8449                 $filter = "";
8450         }
8451         print <<XML;
8452 <?xml version="1.0" encoding="utf-8"?>
8453 <opml version="1.0">
8454 <head>
8455   <title>$title OPML Export$filter</title>
8456 </head>
8457 <body>
8458 <outline text="git RSS feeds">
8459 XML
8460
8461         foreach my $pr (@list) {
8462                 my %proj = %$pr;
8463                 my $head = git_get_head_hash($proj{'path'});
8464                 if (!defined $head) {
8465                         next;
8466                 }
8467                 $git_dir = "$projectroot/$proj{'path'}";
8468                 my %co = parse_commit($head);
8469                 if (!%co) {
8470                         next;
8471                 }
8472
8473                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8474                 my $rss  = esc_attr(href('project' => $proj{'path'}, 'action' => 'rss', -full => 1));
8475                 my $html = esc_attr(href('project' => $proj{'path'}, 'action' => 'summary', -full => 1));
8476                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8477         }
8478         print <<XML;
8479 </outline>
8480 </body>
8481 </opml>
8482 XML
8483 }