| blob | d60d494ee4c81b7ccbe3a1e36285a41125e56107 |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ## Definitions of private macros.
6 # GIT_CONF_SUBST(VAL, VAR)
7 # ------------------------
8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
9 AC_DEFUN([GIT_CONF_SUBST],
10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
11 config_appended_defs="$config_appended_defs${newline}dnl
12 $1=m4_if([$#],[1],[${$1}],[$2])"])
14 # GIT_CONF_SUBST_INIT
15 # -------------------
16 # Prepare shell variables and autoconf machine required by later calls
17 # to GIT_CONF_SUBST.
18 AC_DEFUN([GIT_CONF_SUBST_INIT],
19 [config_appended_defs=; newline='
20 '
21 AC_CONFIG_COMMANDS([$config_file],
22 [echo "$config_appended_defs" >> "$config_file"],
23 [config_file=$config_file
24 config_appended_defs="$config_appended_defs"])])
26 # GIT_ARG_SET_PATH(PROGRAM)
27 # -------------------------
28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
30 # --without-PROGRAM version used.
31 AC_DEFUN([GIT_ARG_SET_PATH],
32 [AC_ARG_WITH([$1],
33 [AS_HELP_STRING([--with-$1=PATH],
34 [provide PATH to $1])],
35 [GIT_CONF_APPEND_PATH([$1], [$2])],
36 [])])
38 # GIT_CONF_APPEND_PATH(PROGRAM)
39 # -----------------------------
40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
41 # Used by GIT_ARG_SET_PATH(PROGRAM)
42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
43 # --without-PROGRAM is used.
44 AC_DEFUN([GIT_CONF_APPEND_PATH],
45 [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
46 if test "$withval" = "no"; then
47 if test -n "$2"; then
48 GIT_UC_PROGRAM[]_PATH=$withval
49 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
50 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
51 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
52 else
53 AC_MSG_ERROR([You cannot use git without $1])
54 fi
55 else
56 if test "$withval" = "yes"; then
57 AC_MSG_WARN([You should provide path for --with-$1=PATH])
58 else
59 GIT_UC_PROGRAM[]_PATH=$withval
60 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
61 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
62 fi
63 fi
64 m4_popdef([GIT_UC_PROGRAM])])
66 # GIT_PARSE_WITH(PACKAGE)
67 # -----------------------
68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
72 AC_DEFUN([GIT_PARSE_WITH],
73 [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
74 if test "$withval" = "no"; then
75 NO_[]GIT_UC_PACKAGE=YesPlease
76 elif test "$withval" = "yes"; then
77 NO_[]GIT_UC_PACKAGE=
78 else
79 NO_[]GIT_UC_PACKAGE=
80 GIT_UC_PACKAGE[]DIR=$withval
81 AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
82 GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
83 fi
84 m4_popdef([GIT_UC_PACKAGE])])
86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
87 # -----------------------------------------------------
88 # Set VAR to the value specified by --with-WITHNAME.
89 # No verification of arguments is performed, but warnings are issued
90 # if either 'yes' or 'no' is specified.
91 # HELP_TEXT is presented when --help is called.
92 # This is a direct way to allow setting variables in the Makefile.
93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
94 [AC_ARG_WITH([$1],
95 [AS_HELP_STRING([--with-$1=VALUE], $3)],
96 if test -n "$withval"; then
97 if test "$withval" = "yes" -o "$withval" = "no"; then
98 AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
99 [a value for $1 ($2). Maybe you do...?])
100 fi
101 AC_MSG_NOTICE([Setting $2 to $withval])
102 GIT_CONF_SUBST([$2], [$withval])
103 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
105 #
106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
107 # -----------------------------------------
108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
110 # -Wall), it does not work. By looking for function definition in
111 # libraries, this problem can be worked around.
112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
113 AC_SEARCH_LIBS([$1],,
114 [$2],[$3])
115 ],[$3])])
117 #
118 # GIT_STASH_FLAGS(BASEPATH_VAR)
119 # -----------------------------
120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
121 # tests that may want to take user settings into account.
122 AC_DEFUN([GIT_STASH_FLAGS],[
123 if test -n "$1"; then
124 old_CPPFLAGS="$CPPFLAGS"
125 old_LDFLAGS="$LDFLAGS"
126 CPPFLAGS="-I$1/include $CPPFLAGS"
127 LDFLAGS="-L$1/$lib $LDFLAGS"
128 fi
129 ])
131 dnl
132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
133 dnl -----------------------------
134 dnl Restore the stashed *FLAGS values.
135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
136 if test -n "$1"; then
137 CPPFLAGS="$old_CPPFLAGS"
138 LDFLAGS="$old_LDFLAGS"
139 fi
140 ])
142 ## Configure body starts here.
144 AC_PREREQ(2.59)
145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
147 AC_CONFIG_SRCDIR([git.c])
149 config_file=config.mak.autogen
150 config_in=config.mak.in
152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
154 # Directories holding "saner" versions of common or POSIX binaries.
155 AC_ARG_WITH([sane-tool-path],
156 [AS_HELP_STRING(
157 [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
158 [Directories to prepend to PATH in build system and generated scripts])],
159 [if test "$withval" = "no"; then
160 withval=''
161 else
162 AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
163 fi
164 GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
165 [# If the "--with-sane-tool-path" option was not given, don't touch
166 # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
167 # This should minimize spurious differences in the behaviour of the
168 # Git build system when configure is used w.r.t. when it is not.
169 :])
171 ## Site configuration related to programs (before tests)
172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
173 #
174 # Set lib to alternative name of lib directory (e.g. lib64)
175 AC_ARG_WITH([lib],
176 [AS_HELP_STRING([--with-lib=ARG],
177 [ARG specifies alternative name for lib directory])],
178 [if test "$withval" = "no" || test "$withval" = "yes"; then
179 AC_MSG_WARN([You should provide name for --with-lib=ARG])
180 else
181 lib=$withval
182 AC_MSG_NOTICE([Setting lib to '$lib'])
183 GIT_CONF_SUBST([lib])
184 fi])
186 if test -z "$lib"; then
187 AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
188 lib=lib
189 fi
191 AC_ARG_ENABLE([pthreads],
192 [AS_HELP_STRING([--enable-pthreads=FLAGS],
193 [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
194 [The default if FLAGS is not specified is to try first -pthread]
195 [and then -lpthread.]
196 [--disable-pthreads will disable threading.])],
197 [
198 if test "x$enableval" = "xyes"; then
199 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
200 elif test "x$enableval" != "xno"; then
201 PTHREAD_CFLAGS=$enableval
202 AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
203 else
204 AC_MSG_NOTICE([POSIX Threads will be disabled.])
205 NO_PTHREADS=YesPlease
206 USER_NOPTHREAD=1
207 fi],
208 [
209 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
210 ])
212 # Define option to enable JavaScript minification
213 AC_ARG_ENABLE([jsmin],
214 [AS_HELP_STRING([--enable-jsmin=PATH],
215 [PATH is the name of a JavaScript minifier or the absolute path to one.])],
216 [
217 JSMIN=$enableval;
218 AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
219 GIT_CONF_SUBST([JSMIN])
220 ])
222 # Define option to enable CSS minification
223 AC_ARG_ENABLE([cssmin],
224 [AS_HELP_STRING([--enable-cssmin=PATH],
225 [PATH is the name of a CSS minifier or the absolute path to one.])],
226 [
227 CSSMIN=$enableval;
228 AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
229 GIT_CONF_SUBST([CSSMIN])
230 ])
232 ## Site configuration (override autodetection)
233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
234 AC_MSG_NOTICE([CHECKS for site configuration])
235 #
236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
237 # tests. These tests take up a significant amount of the total test time
238 # but are not needed unless you plan to talk to SVN repos.
239 #
240 # Define PPC_SHA1 environment variable when running make to make use of
241 # a bundled SHA1 routine optimized for PowerPC.
242 #
243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
244 #
245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
246 # /foo/bar/include and /foo/bar/lib directories.
247 AC_ARG_WITH(openssl,
248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
249 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),
250 GIT_PARSE_WITH([openssl]))
252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
253 # commands such as log and grep offer runtime options to use
254 # Perl-compatible regular expressions instead of standard or extended
255 # POSIX regular expressions. Only libpcre version 2 is supported.
256 #
257 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
258 # /foo/bar/include and /foo/bar/lib directories.
259 #
261 AC_ARG_WITH(libpcre1,
262 AS_HELP_STRING([--with-libpcre1],[DEPRECATED]),
263 AC_MSG_ERROR([support for --with-libpcre1 has been removed. Use --with-libpcre2!])
264 )
266 AC_ARG_WITH(libpcre,
267 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
268 if test "$withval" = "no"; then
269 USE_LIBPCRE2=
270 elif test "$withval" = "yes"; then
271 USE_LIBPCRE2=YesPlease
272 else
273 USE_LIBPCRE2=YesPlease
274 LIBPCREDIR=$withval
275 AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
276 dnl USE_LIBPCRE2 can still be modified below, so don't substitute
277 dnl it yet.
278 GIT_CONF_SUBST([LIBPCREDIR])
279 fi)
281 AC_ARG_WITH(libpcre2,
282 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
283 AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]),
284 if test -n "$USE_LIBPCRE2"; then
285 AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
286 fi
288 if test "$withval" = "no"; then
289 USE_LIBPCRE2=
290 elif test "$withval" = "yes"; then
291 USE_LIBPCRE2=YesPlease
292 else
293 USE_LIBPCRE2=YesPlease
294 LIBPCREDIR=$withval
295 AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
296 dnl USE_LIBPCRE2 can still be modified below, so don't substitute
297 dnl it yet.
298 GIT_CONF_SUBST([LIBPCREDIR])
299 fi)
300 #
301 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
302 AC_FUNC_ALLOCA
303 case $ac_cv_working_alloca_h in
304 yes) HAVE_ALLOCA_H=YesPlease;;
305 *) HAVE_ALLOCA_H='';;
306 esac
307 GIT_CONF_SUBST([HAVE_ALLOCA_H])
308 #
309 # Define NO_CURL if you do not have curl installed. git-http-pull and
310 # git-http-push are not built, and you cannot use http:// and https://
311 # transports.
312 #
313 # Define CURLDIR=/foo/bar if your curl header and library files are in
314 # /foo/bar/include and /foo/bar/lib directories.
315 AC_ARG_WITH(curl,
316 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
317 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
318 GIT_PARSE_WITH(curl))
319 #
320 # Define NO_EXPAT if you do not have expat installed. git-http-push is
321 # not built, and you cannot push using http:// and https:// transports.
322 #
323 # Define EXPATDIR=/foo/bar if your expat header and library files are in
324 # /foo/bar/include and /foo/bar/lib directories.
325 AC_ARG_WITH(expat,
326 AS_HELP_STRING([--with-expat],
327 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
328 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
329 GIT_PARSE_WITH(expat))
330 #
331 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
332 # installed in /sw, but don't want GIT to link against any libraries
333 # installed there. If defined you may specify your own (or Fink's)
334 # include directories and library directories by defining CFLAGS
335 # and LDFLAGS appropriately.
336 #
337 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
338 # have DarwinPorts installed in /opt/local, but don't want GIT to
339 # link against any libraries installed there. If defined you may
340 # specify your own (or DarwinPort's) include directories and
341 # library directories by defining CFLAGS and LDFLAGS appropriately.
342 #
343 # Define NO_MMAP if you want to avoid mmap.
344 #
345 # Define NO_ICONV if your libc does not properly support iconv.
346 AC_ARG_WITH(iconv,
347 AS_HELP_STRING([--without-iconv],
348 [if your architecture doesn't properly support iconv])
349 AS_HELP_STRING([--with-iconv=PATH],
350 [PATH is prefix for libiconv library and headers])
351 AS_HELP_STRING([],
352 [used only if you need linking with libiconv]),
353 GIT_PARSE_WITH(iconv))
355 ## --enable-FEATURE[=ARG] and --disable-FEATURE
356 #
357 # Define USE_NSEC below if you want git to care about sub-second file mtimes
358 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
359 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
360 # randomly break unless your underlying filesystem supports those sub-second
361 # times (my ext3 doesn't).
362 #
363 # Define USE_STDEV below if you want git to care about the underlying device
364 # change being considered an inode change from the update-index perspective.
366 #
367 # Allow user to set ETC_GITCONFIG variable
368 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
369 Use VALUE instead of /etc/gitconfig as the
370 global git configuration file.
371 If VALUE is not fully qualified it will be interpreted
372 as a path relative to the computed prefix at runtime.)
374 #
375 # Allow user to set ETC_GITATTRIBUTES variable
376 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
377 Use VALUE instead of /etc/gitattributes as the
378 global git attributes file.
379 If VALUE is not fully qualified it will be interpreted
380 as a path relative to the computed prefix at runtime.)
382 #
383 # Allow user to set the default pager
384 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
385 Use VALUE as the fall-back pager instead of 'less'.
386 This is used by things like 'git log' when the user
387 does not specify a pager to use through alternate
388 methods. eg: /usr/bin/pager)
389 #
390 # Allow user to set the default editor
391 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
392 Use VALUE as the fall-back editor instead of 'vi'.
393 This is used by things like 'git commit' when the user
394 does not specify a preferred editor through other
395 methods. eg: /usr/bin/editor)
397 #
398 # Define SHELL_PATH to provide path to shell.
399 GIT_ARG_SET_PATH(shell)
400 #
401 # Define PERL_PATH to provide path to Perl.
402 GIT_ARG_SET_PATH(perl)
403 #
404 # Define PYTHON_PATH to provide path to Python.
405 GIT_ARG_SET_PATH(python, allow-without)
406 #
407 # Define ZLIB_PATH to provide path to zlib.
408 GIT_ARG_SET_PATH(zlib)
409 #
410 # Declare the with-tcltk/without-tcltk options.
411 AC_ARG_WITH(tcltk,
412 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
413 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
414 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
415 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
416 GIT_PARSE_WITH(tcltk))
417 #
420 ## Checks for programs.
421 AC_MSG_NOTICE([CHECKS for programs])
422 #
423 AC_PROG_CC([cc gcc])
424 AC_C_INLINE
425 case $ac_cv_c_inline in
426 inline | yes | no) INLINE='';;
427 *) INLINE=$ac_cv_c_inline ;;
428 esac
429 GIT_CONF_SUBST([INLINE])
431 # which switch to pass runtime path to dynamic libraries to the linker
432 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
433 SAVE_LDFLAGS="${LDFLAGS}"
434 LDFLAGS="${SAVE_LDFLAGS} -R /"
435 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
436 LDFLAGS="${SAVE_LDFLAGS}"
437 ])
438 if test "$git_cv_ld_dashr" = "yes"; then
439 CC_LD_DYNPATH=-R
440 else
441 AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
442 SAVE_LDFLAGS="${LDFLAGS}"
443 LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
444 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
445 LDFLAGS="${SAVE_LDFLAGS}"
446 ])
447 if test "$git_cv_ld_wl_rpath" = "yes"; then
448 CC_LD_DYNPATH=-Wl,-rpath,
449 else
450 AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
451 SAVE_LDFLAGS="${LDFLAGS}"
452 LDFLAGS="${SAVE_LDFLAGS} -rpath /"
453 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
454 LDFLAGS="${SAVE_LDFLAGS}"
455 ])
456 if test "$git_cv_ld_rpath" = "yes"; then
457 CC_LD_DYNPATH=-rpath
458 else
459 AC_CACHE_CHECK([if linker supports -Wl,+b,], git_cv_ld_wl_b, [
460 SAVE_LDFLAGS="${LDFLAGS}"
461 LDFLAGS="${SAVE_LDFLAGS} -Wl,+b,/"
462 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_b=yes], [git_cv_ld_wl_b=no])
463 LDFLAGS="${SAVE_LDFLAGS}"
464 ])
465 if test "$git_cv_ld_wl_b" = "yes"; then
466 CC_LD_DYNPATH=-Wl,+b,
467 else
468 CC_LD_DYNPATH=
469 AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
470 fi
471 fi
472 fi
473 fi
474 GIT_CONF_SUBST([CC_LD_DYNPATH])
475 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
476 AC_CHECK_TOOLS(AR, [gar ar], :)
477 AC_CHECK_PROGS(TAR, [gtar tar])
478 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
479 # TCLTK_PATH will be set to some value if we want Tcl/Tk
480 # or will be empty otherwise.
481 if test -n "$NO_TCLTK"; then
482 TCLTK_PATH=
483 else
484 if test "$with_tcltk" = ""; then
485 # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
486 TCLTK_PATH=wish
487 elif test "$with_tcltk" = "yes"; then
488 # Tcl/Tk check requested.
489 AC_CHECK_PROGS(TCLTK_PATH, [wish], )
490 else
491 AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
492 TCLTK_PATH="$with_tcltk"
493 fi
494 fi
495 GIT_CONF_SUBST([TCLTK_PATH])
496 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
497 if test -n "$ASCIIDOC"; then
498 AC_MSG_CHECKING([for asciidoc version])
499 asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
500 case "${asciidoc_version}" in
501 asciidoc' '8*)
502 AC_MSG_RESULT([${asciidoc_version}])
503 ;;
504 *)
505 AC_MSG_RESULT([${asciidoc_version} (unknown)])
506 ;;
507 esac
508 fi
510 ## Checks for libraries.
511 AC_MSG_NOTICE([CHECKS for libraries])
512 #
513 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
514 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
516 GIT_STASH_FLAGS($OPENSSLDIR)
518 AC_CHECK_LIB([crypto], [SHA1_Init],
519 [NEEDS_SSL_WITH_CRYPTO=],
520 [AC_CHECK_LIB([ssl], [SHA1_Init],
521 [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
522 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
524 GIT_UNSTASH_FLAGS($OPENSSLDIR)
526 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
527 GIT_CONF_SUBST([NO_OPENSSL])
529 #
530 # Handle the USE_LIBPCRE options potentially set above.
531 #
533 if test -n "$USE_LIBPCRE2"; then
535 GIT_STASH_FLAGS($LIBPCREDIR)
537 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
538 [USE_LIBPCRE2=YesPlease],
539 [USE_LIBPCRE2=])
541 GIT_UNSTASH_FLAGS($LIBPCREDIR)
543 GIT_CONF_SUBST([USE_LIBPCRE2])
545 fi
547 #
548 # Define NO_CURL if you do not have libcurl installed. git-http-pull and
549 # git-http-push are not built, and you cannot use http:// and https://
550 # transports.
552 GIT_STASH_FLAGS($CURLDIR)
554 AC_CHECK_LIB([curl], [curl_global_init],
555 [NO_CURL=],
556 [NO_CURL=YesPlease])
558 GIT_UNSTASH_FLAGS($CURLDIR)
560 GIT_CONF_SUBST([NO_CURL])
562 if test -z "$NO_CURL"; then
564 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
565 [curl-config],
566 [no])
568 if test $CURL_CONFIG != no; then
569 GIT_CONF_SUBST([CURL_CONFIG])
571 if test -z "$CURL_CONFIG_OPTS"; then
572 CURL_CONFIG_OPTS="--libs"
573 fi
575 CURL_LDFLAGS=$($CURL_CONFIG $CURL_CONFIG_OPTS)
576 AC_MSG_NOTICE([Setting CURL_LDFLAGS to '$CURL_LDFLAGS'])
577 GIT_CONF_SUBST([CURL_LDFLAGS], [$CURL_LDFLAGS])
578 fi
580 fi
583 #
584 # Define NO_EXPAT if you do not have expat installed. git-http-push is
585 # not built, and you cannot push using http:// and https:// transports.
587 GIT_STASH_FLAGS($EXPATDIR)
589 AC_CHECK_LIB([expat], [XML_ParserCreate],
590 [NO_EXPAT=],
591 [NO_EXPAT=YesPlease])
593 GIT_UNSTASH_FLAGS($EXPATDIR)
595 GIT_CONF_SUBST([NO_EXPAT])
597 #
598 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
599 # some Solaris installations).
600 # Define NO_ICONV if neither libc nor libiconv support iconv.
602 if test -z "$NO_ICONV"; then
604 GIT_STASH_FLAGS($ICONVDIR)
606 AC_DEFUN([ICONVTEST_SRC],
607 [AC_LANG_PROGRAM([#include <iconv.h>],
608 [iconv_open("", "");])])
610 if test -n "$ICONVDIR"; then
611 lib_order="-liconv -lc"
612 else
613 lib_order="-lc -liconv"
614 fi
616 NO_ICONV=YesPlease
618 for l in $lib_order; do
619 if test "$l" = "-liconv"; then
620 NEEDS_LIBICONV=YesPlease
621 else
622 NEEDS_LIBICONV=
623 fi
625 old_LIBS="$LIBS"
626 LIBS="$LIBS $l"
627 AC_MSG_CHECKING([for iconv in $l])
628 AC_LINK_IFELSE([ICONVTEST_SRC],
629 [AC_MSG_RESULT([yes])
630 NO_ICONV=
631 break],
632 [AC_MSG_RESULT([no])])
633 LIBS="$old_LIBS"
634 done
636 #in case of break
637 LIBS="$old_LIBS"
639 GIT_UNSTASH_FLAGS($ICONVDIR)
641 GIT_CONF_SUBST([NEEDS_LIBICONV])
642 GIT_CONF_SUBST([NO_ICONV])
644 if test -n "$NO_ICONV"; then
645 NEEDS_LIBICONV=
646 fi
648 fi
650 #
651 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
653 GIT_STASH_FLAGS($ZLIB_PATH)
655 AC_DEFUN([ZLIBTEST_SRC], [
656 AC_LANG_PROGRAM([#include <zlib.h>],
657 [deflateBound(0, 0);])])
658 AC_MSG_CHECKING([for deflateBound in -lz])
659 old_LIBS="$LIBS"
660 LIBS="$LIBS -lz"
661 AC_LINK_IFELSE([ZLIBTEST_SRC],
662 [AC_MSG_RESULT([yes])],
663 [AC_MSG_RESULT([no])
664 NO_DEFLATE_BOUND=yes])
665 LIBS="$old_LIBS"
667 AC_DEFUN([ZLIBTEST_UNCOMPRESS2_SRC], [
668 AC_LANG_PROGRAM([#include <zlib.h>],
669 [uncompress2(NULL,NULL,NULL,NULL);])])
670 AC_MSG_CHECKING([for uncompress2 in -lz])
671 old_LIBS="$LIBS"
672 LIBS="$LIBS -lz"
673 AC_LINK_IFELSE([ZLIBTEST_UNCOMPRESS2_SRC],
674 [AC_MSG_RESULT([yes])],
675 [AC_MSG_RESULT([no])
676 NO_UNCOMPRESS2=yes])
677 LIBS="$old_LIBS"
679 GIT_UNSTASH_FLAGS($ZLIB_PATH)
681 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
682 GIT_CONF_SUBST([NO_UNCOMPRESS2])
684 #
685 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
686 # Patrick Mauritz).
687 AC_CHECK_LIB([c], [socket],
688 [NEEDS_SOCKET=],
689 [NEEDS_SOCKET=YesPlease])
690 GIT_CONF_SUBST([NEEDS_SOCKET])
691 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
693 #
694 # The next few tests will define NEEDS_RESOLV if linking with
695 # libresolv provides some of the functions we would normally get
696 # from libc.
697 NEEDS_RESOLV=
698 #
699 # Define NO_INET_NTOP if linking with -lresolv is not enough.
700 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
701 NO_INET_NTOP=
702 AC_CHECK_FUNC([inet_ntop],
703 [],
704 [AC_CHECK_LIB([resolv], [inet_ntop],
705 [NEEDS_RESOLV=YesPlease],
706 [NO_INET_NTOP=YesPlease])
707 ])
708 GIT_CONF_SUBST([NO_INET_NTOP])
709 #
710 # Define NO_INET_PTON if linking with -lresolv is not enough.
711 # Solaris 2.7 in particular hos inet_pton in -lresolv.
712 NO_INET_PTON=
713 AC_CHECK_FUNC([inet_pton],
714 [],
715 [AC_CHECK_LIB([resolv], [inet_pton],
716 [NEEDS_RESOLV=YesPlease],
717 [NO_INET_PTON=YesPlease])
718 ])
719 GIT_CONF_SUBST([NO_INET_PTON])
720 #
721 # Define NO_HSTRERROR if linking with -lresolv is not enough.
722 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
723 NO_HSTRERROR=
724 AC_CHECK_FUNC([hstrerror],
725 [],
726 [AC_CHECK_LIB([resolv], [hstrerror],
727 [NEEDS_RESOLV=YesPlease],
728 [NO_HSTRERROR=YesPlease])
729 ])
730 GIT_CONF_SUBST([NO_HSTRERROR])
732 dnl This must go after all the possible places for its initialization,
733 dnl in the AC_CHECK_FUNC invocations above.
734 GIT_CONF_SUBST([NEEDS_RESOLV])
735 #
736 # If any of the above tests determined that -lresolv is needed at
737 # build-time, also set it here for remaining configure-time checks.
738 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
740 AC_CHECK_LIB([c], [basename],
741 [NEEDS_LIBGEN=],
742 [NEEDS_LIBGEN=YesPlease])
743 GIT_CONF_SUBST([NEEDS_LIBGEN])
744 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
746 AC_DEFUN([LIBINTL_SRC], [
747 AC_LANG_PROGRAM([[
748 #include <libintl.h>
749 ]],[[
750 char *msg = gettext("test");
751 ]])])
753 AC_MSG_CHECKING([if libc contains libintl])
754 AC_LINK_IFELSE([LIBINTL_SRC],
755 [AC_MSG_RESULT([yes])
756 LIBC_CONTAINS_LIBINTL=YesPlease],
757 [AC_MSG_RESULT([no])
758 LIBC_CONTAINS_LIBINTL=])
759 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
761 #
762 # Define NO_GETTEXT if you don't want Git output to be translated.
763 # A translated Git requires GNU libintl or another gettext implementation
764 AC_CHECK_HEADER([libintl.h],
765 [NO_GETTEXT=],
766 [NO_GETTEXT=YesPlease])
767 GIT_CONF_SUBST([NO_GETTEXT])
769 if test -z "$NO_GETTEXT"; then
770 test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
771 fi
773 ## Checks for header files.
774 AC_MSG_NOTICE([CHECKS for header files])
775 #
776 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
777 AC_CHECK_HEADER([sys/select.h],
778 [NO_SYS_SELECT_H=],
779 [NO_SYS_SELECT_H=UnfortunatelyYes])
780 GIT_CONF_SUBST([NO_SYS_SELECT_H])
781 #
782 # Define NO_POLL_H if you don't have poll.h
783 AC_CHECK_HEADER([poll.h],
784 [NO_POLL_H=],
785 [NO_POLL_H=UnfortunatelyYes])
786 GIT_CONF_SUBST([NO_POLL_H])
787 #
788 # Define NO_SYS_POLL_H if you don't have sys/poll.h
789 AC_CHECK_HEADER([sys/poll.h],
790 [NO_SYS_POLL_H=],
791 [NO_SYS_POLL_H=UnfortunatelyYes])
792 GIT_CONF_SUBST([NO_SYS_POLL_H])
793 #
794 # Define NO_INTTYPES_H if you don't have inttypes.h
795 AC_CHECK_HEADER([inttypes.h],
796 [NO_INTTYPES_H=],
797 [NO_INTTYPES_H=UnfortunatelyYes])
798 GIT_CONF_SUBST([NO_INTTYPES_H])
799 #
800 # Define OLD_ICONV if your library has an old iconv(), where the second
801 # (input buffer pointer) parameter is declared with type (const char **).
802 AC_DEFUN([OLDICONVTEST_SRC], [
803 AC_LANG_PROGRAM([[
804 #include <iconv.h>
806 extern size_t iconv(iconv_t cd,
807 char **inbuf, size_t *inbytesleft,
808 char **outbuf, size_t *outbytesleft);
809 ]], [])])
811 GIT_STASH_FLAGS($ICONVDIR)
813 AC_MSG_CHECKING([for old iconv()])
814 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
815 [AC_MSG_RESULT([no])],
816 [AC_MSG_RESULT([yes])
817 AC_DEFINE(HAVE_OLD_ICONV, 1)
818 OLD_ICONV=UnfortunatelyYes])
820 GIT_UNSTASH_FLAGS($ICONVDIR)
822 GIT_CONF_SUBST([OLD_ICONV])
824 #
825 # Define ICONV_OMITS_BOM if you are on a system which
826 # iconv omits bom for utf-{16,32}
827 if test -z "$NO_ICONV"; then
828 AC_CACHE_CHECK([whether iconv omits bom for utf-16 and utf-32],
829 [ac_cv_iconv_omits_bom],
830 [
831 old_LIBS="$LIBS"
832 if test -n "$NEEDS_LIBICONV"; then
833 LIBS="$LIBS -liconv"
834 fi
836 AC_RUN_IFELSE(
837 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
838 #include <iconv.h>
839 #ifdef HAVE_OLD_ICONV
840 typedef const char *iconv_ibp;
841 #else
842 typedef char *iconv_ibp;
843 #endif
844 ],
845 [[
846 int v;
847 iconv_t conv;
848 char in[] = "a"; iconv_ibp pin = in;
849 char out[20] = ""; char *pout = out;
850 size_t isz = sizeof in;
851 size_t osz = sizeof out;
853 conv = iconv_open("UTF-16", "UTF-8");
854 iconv(conv, &pin, &isz, &pout, &osz);
855 iconv_close(conv);
856 v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
857 return v != 0xfe + 0xff;
858 ]])],
859 [ac_cv_iconv_omits_bom=no],
860 [ac_cv_iconv_omits_bom=yes])
862 LIBS="$old_LIBS"
863 ])
864 if test "x$ac_cv_iconv_omits_bom" = xyes; then
865 ICONV_OMITS_BOM=Yes
866 else
867 ICONV_OMITS_BOM=
868 fi
869 GIT_CONF_SUBST([ICONV_OMITS_BOM])
870 fi
872 ## Checks for typedefs, structures, and compiler characteristics.
873 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
874 #
875 TYPE_SOCKLEN_T
876 case $ac_cv_type_socklen_t in
877 yes) SOCKLEN_T='';;
878 *) SOCKLEN_T=$git_cv_socklen_t_equiv;;
879 esac
880 GIT_CONF_SUBST([SOCKLEN_T])
882 #
883 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
884 AC_CHECK_TYPES([struct itimerval],
885 [NO_STRUCT_ITIMERVAL=],
886 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
887 [#include <sys/time.h>])
888 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
889 #
890 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
891 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
892 # stat.st_mtimespec.tv_nsec exists.
893 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
894 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
895 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
896 USE_ST_TIMESPEC=YesPlease
897 GIT_CONF_SUBST([USE_ST_TIMESPEC])
898 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
899 NO_NSEC=YesPlease
900 GIT_CONF_SUBST([NO_NSEC])
901 fi
902 #
903 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
904 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
905 AC_CHECK_MEMBER(struct dirent.d_type,
906 [NO_D_TYPE_IN_DIRENT=],
907 [NO_D_TYPE_IN_DIRENT=YesPlease],
908 [#include <dirent.h>])
909 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
910 #
911 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
912 # in the C library.
913 AC_CHECK_MEMBER(struct passwd.pw_gecos,
914 [NO_GECOS_IN_PWENT=],
915 [NO_GECOS_IN_PWENT=YesPlease],
916 [#include <pwd.h>])
917 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
918 #
919 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
920 # sockaddr_storage.
921 AC_CHECK_TYPE(struct sockaddr_storage,
922 [NO_SOCKADDR_STORAGE=],
923 [NO_SOCKADDR_STORAGE=YesPlease],[
924 #include <sys/types.h>
925 #include <sys/socket.h>
926 ])
927 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
928 #
929 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
930 AC_CHECK_TYPE([struct addrinfo],[
931 GIT_CHECK_FUNC([getaddrinfo],
932 [NO_IPV6=],
933 [NO_IPV6=YesPlease])
934 ],[NO_IPV6=YesPlease],[
935 #include <sys/types.h>
936 #include <sys/socket.h>
937 #include <netdb.h>
938 ])
939 GIT_CONF_SUBST([NO_IPV6])
940 #
941 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
942 # feature.
943 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
944 [ac_cv_c_regex_with_reg_startend], [
945 AC_EGREP_CPP(yippeeyeswehaveit,
946 AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
947 #include <regex.h>
948 ],
949 [#ifdef REG_STARTEND
950 yippeeyeswehaveit
951 #endif
952 ]),
953 [ac_cv_c_regex_with_reg_startend=yes],
954 [ac_cv_c_regex_with_reg_startend=no])
955 ])
956 if test $ac_cv_c_regex_with_reg_startend = yes; then
957 NO_REGEX=
958 else
959 NO_REGEX=YesPlease
960 fi
961 GIT_CONF_SUBST([NO_REGEX])
962 #
963 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
964 # when attempting to read from an fopen'ed directory.
965 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
966 [ac_cv_fread_reads_directories],
967 [
968 AC_RUN_IFELSE(
969 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
970 [[
971 FILE *f = fopen(".", "r");
972 return f != NULL;]])],
973 [ac_cv_fread_reads_directories=no],
974 [ac_cv_fread_reads_directories=yes])
975 ])
976 if test $ac_cv_fread_reads_directories = yes; then
977 FREAD_READS_DIRECTORIES=UnfortunatelyYes
978 else
979 FREAD_READS_DIRECTORIES=
980 fi
981 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
982 #
983 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
984 # or vsnprintf() return -1 instead of number of characters which would
985 # have been written to the final string if enough space had been available.
986 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
987 [ac_cv_snprintf_returns_bogus],
988 [
989 AC_RUN_IFELSE(
990 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
991 #include "stdarg.h"
993 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
994 {
995 int ret;
996 va_list ap;
997 va_start(ap, format);
998 ret = vsnprintf(str, maxsize, format, ap);
999 va_end(ap);
1000 return ret;
1001 }],
1002 [[char buf[6];
1003 if (test_vsnprintf(buf, 3, "%s", "12345") != 5
1004 || strcmp(buf, "12")) return 1;
1005 if (snprintf(buf, 3, "%s", "12345") != 5
1006 || strcmp(buf, "12")) return 1]])],
1007 [ac_cv_snprintf_returns_bogus=no],
1008 [ac_cv_snprintf_returns_bogus=yes])
1009 ])
1010 if test $ac_cv_snprintf_returns_bogus = yes; then
1011 SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
1012 else
1013 SNPRINTF_RETURNS_BOGUS=
1014 fi
1015 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
1016 #
1017 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
1018 # bits in mode values.
1019 AC_CACHE_CHECK([whether the platform uses typical file type bits],
1020 [ac_cv_sane_mode_bits], [
1021 AC_EGREP_CPP(yippeeyeswehaveit,
1022 AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1023 [#if S_IFMT == 0170000 && \
1024 S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
1025 S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
1026 S_IFIFO == 0010000 && S_IFSOCK == 0140000
1027 yippeeyeswehaveit
1028 #endif
1029 ]),
1030 [ac_cv_sane_mode_bits=yes],
1031 [ac_cv_sane_mode_bits=no])
1032 ])
1033 if test $ac_cv_sane_mode_bits = yes; then
1034 NEEDS_MODE_TRANSLATION=
1035 else
1036 NEEDS_MODE_TRANSLATION=UnfortunatelyYes
1037 fi
1038 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
1041 ## Checks for library functions.
1042 ## (in default C library and libraries checked by AC_CHECK_LIB)
1043 AC_MSG_NOTICE([CHECKS for library functions])
1044 #
1045 # Define NO_LIBGEN_H if you don't have libgen.h.
1046 AC_CHECK_HEADER([libgen.h],
1047 [NO_LIBGEN_H=],
1048 [NO_LIBGEN_H=YesPlease])
1049 GIT_CONF_SUBST([NO_LIBGEN_H])
1050 #
1051 # Define HAVE_PATHS_H if you have paths.h.
1052 AC_CHECK_HEADER([paths.h],
1053 [HAVE_PATHS_H=YesPlease],
1054 [HAVE_PATHS_H=])
1055 GIT_CONF_SUBST([HAVE_PATHS_H])
1056 #
1057 # Define HAVE_LIBCHARSET_H if have libcharset.h
1058 AC_CHECK_HEADER([libcharset.h],
1059 [HAVE_LIBCHARSET_H=YesPlease],
1060 [HAVE_LIBCHARSET_H=])
1061 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1062 #
1063 # Define HAVE_STRINGS_H if you have strings.h
1064 AC_CHECK_HEADER([strings.h],
1065 [HAVE_STRINGS_H=YesPlease],
1066 [HAVE_STRINGS_H=])
1067 GIT_CONF_SUBST([HAVE_STRINGS_H])
1068 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1069 # and libcharset does
1070 CHARSET_LIB=
1071 AC_CHECK_LIB([iconv], [locale_charset],
1072 [CHARSET_LIB=-liconv],
1073 [AC_CHECK_LIB([charset], [locale_charset],
1074 [CHARSET_LIB=-lcharset])])
1075 GIT_CONF_SUBST([CHARSET_LIB])
1076 #
1077 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1078 GIT_CHECK_FUNC(clock_gettime,
1079 [HAVE_CLOCK_GETTIME=YesPlease],
1080 [HAVE_CLOCK_GETTIME=])
1081 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1083 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1084 AC_LANG_PROGRAM([[
1085 #include <time.h>
1086 clockid_t id = CLOCK_MONOTONIC;
1087 ]])])
1089 #
1090 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1091 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1092 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1093 [AC_MSG_RESULT([yes])
1094 HAVE_CLOCK_MONOTONIC=YesPlease],
1095 [AC_MSG_RESULT([no])
1096 HAVE_CLOCK_MONOTONIC=])
1097 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1098 #
1099 # Define NO_SETITIMER if you don't have setitimer.
1100 GIT_CHECK_FUNC(setitimer,
1101 [NO_SETITIMER=],
1102 [NO_SETITIMER=YesPlease])
1103 GIT_CONF_SUBST([NO_SETITIMER])
1104 #
1105 # Define NO_STRCASESTR if you don't have strcasestr.
1106 GIT_CHECK_FUNC(strcasestr,
1107 [NO_STRCASESTR=],
1108 [NO_STRCASESTR=YesPlease])
1109 GIT_CONF_SUBST([NO_STRCASESTR])
1110 #
1111 # Define NO_MEMMEM if you don't have memmem.
1112 GIT_CHECK_FUNC(memmem,
1113 [NO_MEMMEM=],
1114 [NO_MEMMEM=YesPlease])
1115 GIT_CONF_SUBST([NO_MEMMEM])
1116 #
1117 # Define NO_STRLCPY if you don't have strlcpy.
1118 GIT_CHECK_FUNC(strlcpy,
1119 [NO_STRLCPY=],
1120 [NO_STRLCPY=YesPlease])
1121 GIT_CONF_SUBST([NO_STRLCPY])
1122 #
1123 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1124 AC_CHECK_TYPE(uintmax_t,
1125 [NO_UINTMAX_T=],
1126 [NO_UINTMAX_T=YesPlease],[
1127 #include <inttypes.h>
1128 ])
1129 GIT_CONF_SUBST([NO_UINTMAX_T])
1130 #
1131 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1132 GIT_CHECK_FUNC(strtoumax,
1133 [NO_STRTOUMAX=],
1134 [NO_STRTOUMAX=YesPlease])
1135 GIT_CONF_SUBST([NO_STRTOUMAX])
1136 #
1137 # Define NO_SETENV if you don't have setenv in the C library.
1138 GIT_CHECK_FUNC(setenv,
1139 [NO_SETENV=],
1140 [NO_SETENV=YesPlease])
1141 GIT_CONF_SUBST([NO_SETENV])
1142 #
1143 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1144 GIT_CHECK_FUNC(unsetenv,
1145 [NO_UNSETENV=],
1146 [NO_UNSETENV=YesPlease])
1147 GIT_CONF_SUBST([NO_UNSETENV])
1148 #
1149 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1150 GIT_CHECK_FUNC(mkdtemp,
1151 [NO_MKDTEMP=],
1152 [NO_MKDTEMP=YesPlease])
1153 GIT_CONF_SUBST([NO_MKDTEMP])
1154 #
1155 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1156 GIT_CHECK_FUNC(initgroups,
1157 [NO_INITGROUPS=],
1158 [NO_INITGROUPS=YesPlease])
1159 GIT_CONF_SUBST([NO_INITGROUPS])
1160 #
1161 # Define HAVE_GETDELIM if you have getdelim in the C library.
1162 GIT_CHECK_FUNC(getdelim,
1163 [HAVE_GETDELIM=YesPlease],
1164 [HAVE_GETDELIM=])
1165 GIT_CONF_SUBST([HAVE_GETDELIM])
1166 #
1167 #
1168 # Define NO_MMAP if you want to avoid mmap.
1169 #
1170 # Define NO_ICONV if your libc does not properly support iconv.
1172 AC_DEFUN([BSD_SYSCTL_SRC], [
1173 AC_LANG_PROGRAM([[
1174 #include <stddef.h>
1175 #include <sys/types.h>
1176 #include <sys/sysctl.h>
1177 ]],[[
1178 int val, mib[2];
1179 size_t len;
1180 mib[0] = CTL_HW;
1181 mib[1] = 1;
1182 len = sizeof(val);
1183 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1184 ]])])
1186 #
1187 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1188 AC_MSG_CHECKING([for BSD sysctl])
1189 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1190 [AC_MSG_RESULT([yes])
1191 HAVE_BSD_SYSCTL=YesPlease],
1192 [AC_MSG_RESULT([no])
1193 HAVE_BSD_SYSCTL=])
1194 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1196 ## Other checks.
1197 # Define USE_PIC if you need the main git objects to be built with -fPIC
1198 # in order to build and link perl/Git.so. x86-64 seems to need this.
1199 #
1200 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1201 # Enable it on Windows. By default, symrefs are still used.
1202 #
1203 # Define NO_PTHREADS if we do not have pthreads.
1204 #
1205 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1206 AC_DEFUN([PTHREADTEST_SRC], [
1207 AC_LANG_PROGRAM([[
1208 #include <pthread.h>
1209 static void *noop(void *ignore) { return ignore; }
1210 ]], [[
1211 pthread_mutex_t test_mutex;
1212 pthread_key_t test_key;
1213 pthread_t th;
1214 int retcode = 0;
1215 void *ret = (void *)0;
1216 retcode |= pthread_key_create(&test_key, (void *)0);
1217 retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1218 retcode |= pthread_mutex_lock(&test_mutex);
1219 retcode |= pthread_mutex_unlock(&test_mutex);
1220 retcode |= pthread_create(&th, ret, noop, ret);
1221 retcode |= pthread_join(th, &ret);
1222 return retcode;
1223 ]])])
1225 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1226 dnl [[#include <pthread.h>]],
1227 dnl [[pthread_mutex_t test_mutex;]]
1228 dnl )])
1230 NO_PTHREADS=UnfortunatelyYes
1231 PTHREAD_LIBS=
1233 if test -n "$USER_NOPTHREAD"; then
1234 AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1235 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1236 # -D_REENTRANT' or some such.
1237 elif test -z "$PTHREAD_CFLAGS"; then
1238 threads_found=no
1239 # Attempt to compile and link some code using pthreads to determine
1240 # required linker flags. The order is somewhat important here: We
1241 # first try it without any extra flags, to catch systems where
1242 # pthreads are part of the C library, then go on testing various other
1243 # flags. We do so to avoid false positives. For example, on Mac OS X
1244 # pthreads are part of the C library; moreover, the compiler allows us
1245 # to add "-mt" to the CFLAGS (although it will do nothing except
1246 # trigger a warning about an unused flag). Hence if we checked for
1247 # "-mt" before "" we would end up picking it. But unfortunately this
1248 # would then trigger compiler warnings on every single file we compile.
1249 for opt in "" -mt -pthread -lpthread; do
1250 old_CFLAGS="$CFLAGS"
1251 old_LIBS="$LIBS"
1252 case "$opt" in
1253 -l*) LIBS="$opt $LIBS" ;;
1254 *) CFLAGS="$opt $CFLAGS" ;;
1255 esac
1257 AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1258 AC_LINK_IFELSE([PTHREADTEST_SRC],
1259 [AC_MSG_RESULT([yes])
1260 NO_PTHREADS=
1261 PTHREAD_LIBS="$opt"
1262 PTHREAD_CFLAGS="$opt"
1263 threads_found=yes
1264 break
1265 ],
1266 [AC_MSG_RESULT([no])])
1267 CFLAGS="$old_CFLAGS"
1268 LIBS="$old_LIBS"
1269 done
1270 if test $threads_found != yes; then
1271 AC_CHECK_LIB([pthread], [pthread_create],
1272 [PTHREAD_LIBS="-lpthread"],
1273 [NO_PTHREADS=UnfortunatelyYes])
1274 fi
1275 else
1276 old_CFLAGS="$CFLAGS"
1277 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1278 AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1279 AC_LINK_IFELSE([PTHREADTEST_SRC],
1280 [AC_MSG_RESULT([yes])
1281 NO_PTHREADS=
1282 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1283 ],
1284 [AC_MSG_RESULT([no])])
1286 CFLAGS="$old_CFLAGS"
1287 fi
1289 CFLAGS="$old_CFLAGS"
1291 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1292 GIT_CONF_SUBST([PTHREAD_LIBS])
1293 GIT_CONF_SUBST([NO_PTHREADS])
1295 ## Output files
1296 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1297 AC_OUTPUT