git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Long;
  19 use File::Spec;
  20 use File::Temp qw(tempfile tmpnam);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,@opt_M,$opt_A,$opt_S,$opt_L, $opt_a, $opt_r);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage(;$) {
  36         my $msg = shift;
  37         print(STDERR "Error: $msg\n") if $msg;
  38         print STDERR <<END;
  39 Usage: ${\basename $0}     # fetch/update GIT from CVS
  40        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  41        [-p opts-for-cvsps] [-P file] [-C GIT_repository] [-z fuzz] [-i] [-k]
  42        [-u] [-s subst] [-a] [-m] [-M regex] [-S regex] [-L commitlimit]
  43        [-r remote] [CVS_module]
  44 END
  45         exit(1);
  46 }
  47
  48 sub read_author_info($) {
  49         my ($file) = @_;
  50         my $user;
  51         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  52
  53         while (<$f>) {
  54                 # Expected format is this:
  55                 #   exon=Andreas Ericsson <ae@op5.se>
  56                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  57                         $user = $1;
  58                         $conv_author_name{$user} = $2;
  59                         $conv_author_email{$user} = $3;
  60                 }
  61                 # However, we also read from CVSROOT/users format
  62                 # to ease migration.
  63                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  64                         my $mapped;
  65                         ($user, $mapped) = ($1, $3);
  66                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  67                                 $conv_author_name{$user} = $1;
  68                                 $conv_author_email{$user} = $2;
  69                         }
  70                         elsif ($mapped =~ /^<?(.*)>?$/) {
  71                                 $conv_author_name{$user} = $user;
  72                                 $conv_author_email{$user} = $1;
  73                         }
  74                 }
  75                 # NEEDSWORK: Maybe warn on unrecognized lines?
  76         }
  77         close ($f);
  78 }
  79
  80 sub write_author_info($) {
  81         my ($file) = @_;
  82         open my $f, '>', $file or
  83           die("Failed to open $file for writing: $!");
  84
  85         foreach (keys %conv_author_name) {
  86                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  87         }
  88         close ($f);
  89 }
  90
  91 # convert getopts specs for use by git config
  92 sub read_repo_config {
  93     # Split the string between characters, unless there is a ':'
  94     # So "abc:de" becomes ["a", "b", "c:", "d", "e"]
  95         my @opts = split(/ *(?!:)/, shift);
  96         foreach my $o (@opts) {
  97                 my $key = $o;
  98                 $key =~ s/://g;
  99                 my $arg = 'git config';
 100                 $arg .= ' --bool' if ($o !~ /:$/);
 101
 102         chomp(my $tmp = `$arg --get cvsimport.$key`);
 103                 if ($tmp && !($arg =~ /--bool/ && $tmp eq 'false')) {
 104             no strict 'refs';
 105             my $opt_name = "opt_" . $key;
 106             if (!$$opt_name) {
 107                 $$opt_name = $tmp;
 108             }
 109                 }
 110         }
 111 }
 112
 113 my $opts = "haivmkuo:d:p:r:C:z:s:M:P:A:S:L:";
 114 read_repo_config($opts);
 115 Getopt::Long::Configure( 'no_ignore_case', 'bundling' );
 116
 117 # turn the Getopt::Std specification in a Getopt::Long one,
 118 # with support for multiple -M options
 119 GetOptions( map { s/:/=s/; /M/ ? "$_\@" : $_ } split( /(?!:)/, $opts ) )
 120     or usage();
 121 usage if $opt_h;
 122
 123 if (@ARGV == 0) {
 124                 chomp(my $module = `git config --get cvsimport.module`);
 125                 push(@ARGV, $module) if $? == 0;
 126 }
 127 @ARGV <= 1 or usage("You can't specify more than one CVS module");
 128
 129 if ($opt_d) {
 130         $ENV{"CVSROOT"} = $opt_d;
 131 } elsif (-f 'CVS/Root') {
 132         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
 133         $opt_d = <$f>;
 134         chomp $opt_d;
 135         close $f;
 136         $ENV{"CVSROOT"} = $opt_d;
 137 } elsif ($ENV{"CVSROOT"}) {
 138         $opt_d = $ENV{"CVSROOT"};
 139 } else {
 140         usage("CVSROOT needs to be set");
 141 }
 142 $opt_s ||= "-";
 143 $opt_a ||= 0;
 144
 145 my $git_tree = $opt_C;
 146 $git_tree ||= ".";
 147
 148 my $remote;
 149 if (defined $opt_r) {
 150         $remote = 'refs/remotes/' . $opt_r;
 151         $opt_o ||= "master";
 152 } else {
 153         $opt_o ||= "origin";
 154         $remote = 'refs/heads';
 155 }
 156
 157 my $cvs_tree;
 158 if ($#ARGV == 0) {
 159         $cvs_tree = $ARGV[0];
 160 } elsif (-f 'CVS/Repository') {
 161         open my $f, '<', 'CVS/Repository' or
 162             die 'Failed to open CVS/Repository';
 163         $cvs_tree = <$f>;
 164         chomp $cvs_tree;
 165         close $f;
 166 } else {
 167         usage("CVS module has to be specified");
 168 }
 169
 170 our @mergerx = ();
 171 if ($opt_m) {
 172         @mergerx = ( qr/\b(?:from|of|merge|merging|merged) ([-\w]+)/i );
 173 }
 174 if (@opt_M) {
 175         push (@mergerx, map { qr/$_/ } @opt_M);
 176 }
 177
 178 # Remember UTC of our starting time
 179 # we'll want to avoid importing commits
 180 # that are too recent
 181 our $starttime = time();
 182
 183 select(STDERR); $|=1; select(STDOUT);
 184
 185
 186 package CVSconn;
 187 # Basic CVS dialog.
 188 # We're only interested in connecting and downloading, so ...
 189
 190 use File::Spec;
 191 use File::Temp qw(tempfile);
 192 use POSIX qw(strftime dup2);
 193
 194 sub new {
 195         my ($what,$repo,$subdir) = @_;
 196         $what=ref($what) if ref($what);
 197
 198         my $self = {};
 199         $self->{'buffer'} = "";
 200         bless($self,$what);
 201
 202         $repo =~ s#/+$##;
 203         $self->{'fullrep'} = $repo;
 204         $self->conn();
 205
 206         $self->{'subdir'} = $subdir;
 207         $self->{'lines'} = undef;
 208
 209         return $self;
 210 }
 211
 212 sub conn {
 213         my $self = shift;
 214         my $repo = $self->{'fullrep'};
 215         if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 216                 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
 217
 218                 my ($proxyhost,$proxyport);
 219                 if ($param && ($param =~ m/proxy=([^;]+)/)) {
 220                         $proxyhost = $1;
 221                         # Default proxyport, if not specified, is 8080.
 222                         $proxyport = 8080;
 223                         if ($ENV{"CVS_PROXY_PORT"}) {
 224                                 $proxyport = $ENV{"CVS_PROXY_PORT"};
 225                         }
 226                         if ($param =~ m/proxyport=([^;]+)/) {
 227                                 $proxyport = $1;
 228                         }
 229                 }
 230
 231                 # if username is not explicit in CVSROOT, then use current user, as cvs would
 232                 $user=(getlogin() || $ENV{'LOGNAME'} || $ENV{'USER'} || "anonymous") unless $user;
 233                 my $rr2 = "-";
 234                 unless ($port) {
 235                         $rr2 = ":pserver:$user\@$serv:$repo";
 236                         $port=2401;
 237                 }
 238                 my $rr = ":pserver:$user\@$serv:$port$repo";
 239
 240                 unless ($pass) {
 241                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 242                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 243                                 while (<H>) {
 244                                         chomp;
 245                                         s/^\/\d+\s+//;
 246                                         my ($w,$p) = split(/\s/,$_,2);
 247                                         if ($w eq $rr or $w eq $rr2) {
 248                                                 $pass = $p;
 249                                                 last;
 250                                         }
 251                                 }
 252                         };
 253                 }
 254                 $pass="A" unless $pass;
 255
 256                 my ($s, $rep);
 257                 if ($proxyhost) {
 258
 259                         # Use a HTTP Proxy. Only works for HTTP proxies that
 260                         # don't require user authentication
 261                         #
 262                         # See: http://www.ietf.org/rfc/rfc2817.txt
 263
 264                         $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
 265                         die "Socket to $proxyhost: $!\n" unless defined $s;
 266                         $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
 267                                 or die "Write to $proxyhost: $!\n";
 268                         $s->flush();
 269
 270                         $rep = <$s>;
 271
 272                         # The answer should look like 'HTTP/1.x 2yy ....'
 273                         if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
 274                                 die "Proxy connect: $rep\n";
 275                         }
 276                         # Skip up to the empty line of the proxy server output
 277                         # including the response headers.
 278                         while ($rep = <$s>) {
 279                                 last if (!defined $rep ||
 280                                          $rep eq "\n" ||
 281                                          $rep eq "\r\n");
 282                         }
 283                 } else {
 284                         $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 285                         die "Socket to $serv: $!\n" unless defined $s;
 286                 }
 287
 288                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 289                         or die "Write to $serv: $!\n";
 290                 $s->flush();
 291
 292                 $rep = <$s>;
 293
 294                 if ($rep ne "I LOVE YOU\n") {
 295                         $rep="<unknown>" unless $rep;
 296                         die "AuthReply: $rep\n";
 297                 }
 298                 $self->{'socketo'} = $s;
 299                 $self->{'socketi'} = $s;
 300         } else { # local or ext: Fork off our own cvs server.
 301                 my $pr = IO::Pipe->new();
 302                 my $pw = IO::Pipe->new();
 303                 my $pid = fork();
 304                 die "Fork: $!\n" unless defined $pid;
 305                 my $cvs = 'cvs';
 306                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 307                 my $rsh = 'rsh';
 308                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 309
 310                 my @cvs = ($cvs, 'server');
 311                 my ($local, $user, $host);
 312                 $local = $repo =~ s/:local://;
 313                 if (!$local) {
 314                     $repo =~ s/:ext://;
 315                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 316                     ($user, $host) = ($1, $2);
 317                 }
 318                 if (!$local) {
 319                     if ($user) {
 320                         unshift @cvs, $rsh, '-l', $user, $host;
 321                     } else {
 322                         unshift @cvs, $rsh, $host;
 323                     }
 324                 }
 325
 326                 unless ($pid) {
 327                         $pr->writer();
 328                         $pw->reader();
 329                         dup2($pw->fileno(),0);
 330                         dup2($pr->fileno(),1);
 331                         $pr->close();
 332                         $pw->close();
 333                         exec(@cvs);
 334                 }
 335                 $pw->writer();
 336                 $pr->reader();
 337                 $self->{'socketo'} = $pw;
 338                 $self->{'socketi'} = $pr;
 339         }
 340         $self->{'socketo'}->write("Root $repo\n");
 341
 342         # Trial and error says that this probably is the minimum set
 343         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 344
 345         $self->{'socketo'}->write("valid-requests\n");
 346         $self->{'socketo'}->flush();
 347
 348         chomp(my $rep=$self->readline());
 349         if ($rep !~ s/^Valid-requests\s*//) {
 350                 $rep="<unknown>" unless $rep;
 351                 die "Expected Valid-requests from server, but got: $rep\n";
 352         }
 353         chomp(my $res=$self->readline());
 354         die "validReply: $res\n" if $res ne "ok";
 355
 356         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 357         $self->{'repo'} = $repo;
 358 }
 359
 360 sub readline {
 361         my ($self) = @_;
 362         return $self->{'socketi'}->getline();
 363 }
 364
 365 sub _file {
 366         # Request a file with a given revision.
 367         # Trial and error says this is a good way to do it. :-/
 368         my ($self,$fn,$rev) = @_;
 369         $self->{'socketo'}->write("Argument -N\n") or return undef;
 370         $self->{'socketo'}->write("Argument -P\n") or return undef;
 371         # -kk: Linus' version doesn't use it - defaults to off
 372         if ($opt_k) {
 373             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 374         }
 375         $self->{'socketo'}->write("Argument -r\n") or return undef;
 376         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 377         $self->{'socketo'}->write("Argument --\n") or return undef;
 378         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 379         $self->{'socketo'}->write("Directory .\n") or return undef;
 380         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 381         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 382         $self->{'socketo'}->write("co\n") or return undef;
 383         $self->{'socketo'}->flush() or return undef;
 384         $self->{'lines'} = 0;
 385         return 1;
 386 }
 387 sub _line {
 388         # Read a line from the server.
 389         # ... except that 'line' may be an entire file. ;-)
 390         my ($self, $fh) = @_;
 391         die "Not in lines" unless defined $self->{'lines'};
 392
 393         my $line;
 394         my $res=0;
 395         while (defined($line = $self->readline())) {
 396                 # M U gnupg-cvs-rep/AUTHORS
 397                 # Updated gnupg-cvs-rep/
 398                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 399                 # /AUTHORS/1.1///T1.1
 400                 # u=rw,g=rw,o=rw
 401                 # 0
 402                 # ok
 403
 404                 if ($line =~ s/^(?:Created|Updated) //) {
 405                         $line = $self->readline(); # path
 406                         $line = $self->readline(); # Entries line
 407                         my $mode = $self->readline(); chomp $mode;
 408                         $self->{'mode'} = $mode;
 409                         defined (my $cnt = $self->readline())
 410                                 or die "EOF from server after 'Changed'\n";
 411                         chomp $cnt;
 412                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 413                         $line="";
 414                         $res = $self->_fetchfile($fh, $cnt);
 415                 } elsif ($line =~ s/^ //) {
 416                         print $fh $line;
 417                         $res += length($line);
 418                 } elsif ($line =~ /^M\b/) {
 419                         # output, do nothing
 420                 } elsif ($line =~ /^Mbinary\b/) {
 421                         my $cnt;
 422                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 423                         chomp $cnt;
 424                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 425                         $line="";
 426                         $res += $self->_fetchfile($fh, $cnt);
 427                 } else {
 428                         chomp $line;
 429                         if ($line eq "ok") {
 430                                 # print STDERR "S: ok (".length($res).")\n";
 431                                 return $res;
 432                         } elsif ($line =~ s/^E //) {
 433                                 # print STDERR "S: $line\n";
 434                         } elsif ($line =~ /^(Remove-entry|Removed) /i) {
 435                                 $line = $self->readline(); # filename
 436                                 $line = $self->readline(); # OK
 437                                 chomp $line;
 438                                 die "Unknown: $line" if $line ne "ok";
 439                                 return -1;
 440                         } else {
 441                                 die "Unknown: $line\n";
 442                         }
 443                 }
 444         }
 445         return undef;
 446 }
 447 sub file {
 448         my ($self,$fn,$rev) = @_;
 449         my $res;
 450
 451         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 452                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 453
 454         $self->_file($fn,$rev) and $res = $self->_line($fh);
 455
 456         if (!defined $res) {
 457             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 458             truncate $fh, 0;
 459             $self->conn();
 460             $self->_file($fn,$rev) or die "No file command send";
 461             $res = $self->_line($fh);
 462             die "Retry failed" unless defined $res;
 463         }
 464         close ($fh);
 465
 466         return ($name, $res);
 467 }
 468 sub _fetchfile {
 469         my ($self, $fh, $cnt) = @_;
 470         my $res = 0;
 471         my $bufsize = 1024 * 1024;
 472         while ($cnt) {
 473             if ($bufsize > $cnt) {
 474                 $bufsize = $cnt;
 475             }
 476             my $buf;
 477             my $num = $self->{'socketi'}->read($buf,$bufsize);
 478             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 479             print $fh $buf;
 480             $res += $num;
 481             $cnt -= $num;
 482         }
 483         return $res;
 484 }
 485
 486
 487 package main;
 488
 489 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 490
 491
 492 sub pdate($) {
 493         my ($d) = @_;
 494         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 495                 or die "Unparseable date: $d\n";
 496         my $y=$1; $y-=1900 if $y>1900;
 497         return timegm($6||0,$5,$4,$3,$2-1,$y);
 498 }
 499
 500 sub pmode($) {
 501         my ($mode) = @_;
 502         my $m = 0;
 503         my $mm = 0;
 504         my $um = 0;
 505         for my $x(split(//,$mode)) {
 506                 if ($x eq ",") {
 507                         $m |= $mm&$um;
 508                         $mm = 0;
 509                         $um = 0;
 510                 } elsif ($x eq "u") { $um |= 0700;
 511                 } elsif ($x eq "g") { $um |= 0070;
 512                 } elsif ($x eq "o") { $um |= 0007;
 513                 } elsif ($x eq "r") { $mm |= 0444;
 514                 } elsif ($x eq "w") { $mm |= 0222;
 515                 } elsif ($x eq "x") { $mm |= 0111;
 516                 } elsif ($x eq "=") { # do nothing
 517                 } else { die "Unknown mode: $mode\n";
 518                 }
 519         }
 520         $m |= $mm&$um;
 521         return $m;
 522 }
 523
 524 sub getwd() {
 525         my $pwd = `pwd`;
 526         chomp $pwd;
 527         return $pwd;
 528 }
 529
 530 sub is_sha1 {
 531         my $s = shift;
 532         return $s =~ /^[a-f0-9]{40}$/;
 533 }
 534
 535 sub get_headref ($) {
 536         my $name = shift;
 537         my $r = `git rev-parse --verify '$name' 2>/dev/null`;
 538         return undef unless $? == 0;
 539         chomp $r;
 540         return $r;
 541 }
 542
 543 -d $git_tree
 544         or mkdir($git_tree,0777)
 545         or die "Could not create $git_tree: $!";
 546 chdir($git_tree);
 547
 548 my $last_branch = "";
 549 my $orig_branch = "";
 550 my %branch_date;
 551 my $tip_at_start = undef;
 552
 553 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 554 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 555 $ENV{"GIT_DIR"} = $git_dir;
 556 my $orig_git_index;
 557 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 558
 559 my %index; # holds filenames of one index per branch
 560
 561 unless (-d $git_dir) {
 562         system("git-init");
 563         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 564         system("git-read-tree");
 565         die "Cannot init an empty tree: $?\n" if $?;
 566
 567         $last_branch = $opt_o;
 568         $orig_branch = "";
 569 } else {
 570         open(F, "git-symbolic-ref HEAD |") or
 571                 die "Cannot run git-symbolic-ref: $!\n";
 572         chomp ($last_branch = <F>);
 573         $last_branch = basename($last_branch);
 574         close(F);
 575         unless ($last_branch) {
 576                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 577                 $last_branch = "master";
 578         }
 579         $orig_branch = $last_branch;
 580         $tip_at_start = `git-rev-parse --verify HEAD`;
 581
 582         # Get the last import timestamps
 583         my $fmt = '($ref, $author) = (%(refname), %(author));';
 584         open(H, "git-for-each-ref --perl --format='$fmt' $remote |") or
 585                 die "Cannot run git-for-each-ref: $!\n";
 586         while (defined(my $entry = <H>)) {
 587                 my ($ref, $author);
 588                 eval($entry) || die "cannot eval refs list: $@";
 589                 my ($head) = ($ref =~ m|^$remote/(.*)|);
 590                 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
 591                 $branch_date{$head} = $1;
 592         }
 593         close(H);
 594         if (!exists $branch_date{$opt_o}) {
 595                 die "Branch '$opt_o' does not exist.\n".
 596                        "Either use the correct '-o branch' option,\n".
 597                        "or import to a new repository.\n";
 598         }
 599 }
 600
 601 -d $git_dir
 602         or die "Could not create git subdir ($git_dir).\n";
 603
 604 # now we read (and possibly save) author-info as well
 605 -f "$git_dir/cvs-authors" and
 606   read_author_info("$git_dir/cvs-authors");
 607 if ($opt_A) {
 608         read_author_info($opt_A);
 609         write_author_info("$git_dir/cvs-authors");
 610 }
 611
 612
 613 #
 614 # run cvsps into a file unless we are getting
 615 # it passed as a file via $opt_P
 616 #
 617 my $cvspsfile;
 618 unless ($opt_P) {
 619         print "Running cvsps...\n" if $opt_v;
 620         my $pid = open(CVSPS,"-|");
 621         my $cvspsfh;
 622         die "Cannot fork: $!\n" unless defined $pid;
 623         unless ($pid) {
 624                 my @opt;
 625                 @opt = split(/,/,$opt_p) if defined $opt_p;
 626                 unshift @opt, '-z', $opt_z if defined $opt_z;
 627                 unshift @opt, '-q'         unless defined $opt_v;
 628                 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 629                         push @opt, '--cvs-direct';
 630                 }
 631                 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 632                 die "Could not start cvsps: $!\n";
 633         }
 634         ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
 635                                           DIR => File::Spec->tmpdir());
 636         while (<CVSPS>) {
 637             print $cvspsfh $_;
 638         }
 639         close CVSPS;
 640         $? == 0 or die "git-cvsimport: fatal: cvsps reported error\n";
 641         close $cvspsfh;
 642 } else {
 643         $cvspsfile = $opt_P;
 644 }
 645
 646 open(CVS, "<$cvspsfile") or die $!;
 647
 648 ## cvsps output:
 649 #---------------------
 650 #PatchSet 314
 651 #Date: 1999/09/18 13:03:59
 652 #Author: wkoch
 653 #Branch: STABLE-BRANCH-1-0
 654 #Ancestor branch: HEAD
 655 #Tag: (none)
 656 #Log:
 657 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 658 #Members:
 659 #       README:1.57->1.57.2.1
 660 #       VERSION:1.96->1.96.2.1
 661 #
 662 #---------------------
 663
 664 my $state = 0;
 665
 666 sub update_index (\@\@) {
 667         my $old = shift;
 668         my $new = shift;
 669         open(my $fh, '|-', qw(git-update-index -z --index-info))
 670                 or die "unable to open git-update-index: $!";
 671         print $fh
 672                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 673                         @$old),
 674                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 675                         @$new)
 676                 or die "unable to write to git-update-index: $!";
 677         close $fh
 678                 or die "unable to write to git-update-index: $!";
 679         $? and die "git-update-index reported error: $?";
 680 }
 681
 682 sub write_tree () {
 683         open(my $fh, '-|', qw(git-write-tree))
 684                 or die "unable to open git-write-tree: $!";
 685         chomp(my $tree = <$fh>);
 686         is_sha1($tree)
 687                 or die "Cannot get tree id ($tree): $!";
 688         close($fh)
 689                 or die "Error running git-write-tree: $?\n";
 690         print "Tree ID $tree\n" if $opt_v;
 691         return $tree;
 692 }
 693
 694 my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 695 my (@old,@new,@skipped,%ignorebranch);
 696
 697 # commits that cvsps cannot place anywhere...
 698 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 699
 700 sub commit {
 701         if ($branch eq $opt_o && !$index{branch} &&
 702                 !get_headref("$remote/$branch")) {
 703             # looks like an initial commit
 704             # use the index primed by git-init
 705             $ENV{GIT_INDEX_FILE} = "$git_dir/index";
 706             $index{$branch} = "$git_dir/index";
 707         } else {
 708             # use an index per branch to speed up
 709             # imports of projects with many branches
 710             unless ($index{$branch}) {
 711                 $index{$branch} = tmpnam();
 712                 $ENV{GIT_INDEX_FILE} = $index{$branch};
 713                 if ($ancestor) {
 714                     system("git-read-tree", "$remote/$ancestor");
 715                 } else {
 716                     system("git-read-tree", "$remote/$branch");
 717                 }
 718                 die "read-tree failed: $?\n" if $?;
 719             }
 720         }
 721         $ENV{GIT_INDEX_FILE} = $index{$branch};
 722
 723         update_index(@old, @new);
 724         @old = @new = ();
 725         my $tree = write_tree();
 726         my $parent = get_headref("$remote/$last_branch");
 727         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 728
 729         my @commit_args;
 730         push @commit_args, ("-p", $parent) if $parent;
 731
 732         # loose detection of merges
 733         # based on the commit msg
 734         foreach my $rx (@mergerx) {
 735                 next unless $logmsg =~ $rx && $1;
 736                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 737                 if (my $sha1 = get_headref("$remote/$mparent")) {
 738                         push @commit_args, '-p', "$remote/$mparent";
 739                         print "Merge parent branch: $mparent\n" if $opt_v;
 740                 }
 741         }
 742
 743         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 744         $ENV{GIT_AUTHOR_NAME} = $author_name;
 745         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 746         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 747         $ENV{GIT_COMMITTER_NAME} = $author_name;
 748         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 749         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 750         my $pid = open2(my $commit_read, my $commit_write,
 751                 'git-commit-tree', $tree, @commit_args);
 752
 753         # compatibility with git2cvs
 754         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 755         $logmsg =~ s/[\s\n]+\z//;
 756
 757         if (@skipped) {
 758             $logmsg .= "\n\n\nSKIPPED:\n\t";
 759             $logmsg .= join("\n\t", @skipped) . "\n";
 760             @skipped = ();
 761         }
 762
 763         print($commit_write "$logmsg\n") && close($commit_write)
 764                 or die "Error writing to git-commit-tree: $!\n";
 765
 766         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 767         chomp(my $cid = <$commit_read>);
 768         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 769         print "Commit ID $cid\n" if $opt_v;
 770         close($commit_read);
 771
 772         waitpid($pid,0);
 773         die "Error running git-commit-tree: $?\n" if $?;
 774
 775         system('git-update-ref', "$remote/$branch", $cid) == 0
 776                 or die "Cannot write branch $branch for update: $!\n";
 777
 778         if ($tag) {
 779                 my ($xtag) = $tag;
 780                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 781                 $xtag =~ tr/_/\./ if ( $opt_u );
 782                 $xtag =~ s/[\/]/$opt_s/g;
 783                 $xtag =~ s/\[//g;
 784
 785                 system('git-tag', '-f', $xtag, $cid) == 0
 786                         or die "Cannot create tag $xtag: $!\n";
 787
 788                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 789         }
 790 };
 791
 792 my $commitcount = 1;
 793 while (<CVS>) {
 794         chomp;
 795         if ($state == 0 and /^-+$/) {
 796                 $state = 1;
 797         } elsif ($state == 0) {
 798                 $state = 1;
 799                 redo;
 800         } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
 801                 $patchset = 0+$_;
 802                 $state=2;
 803         } elsif ($state == 2 and s/^Date:\s+//) {
 804                 $date = pdate($_);
 805                 unless ($date) {
 806                         print STDERR "Could not parse date: $_\n";
 807                         $state=0;
 808                         next;
 809                 }
 810                 $state=3;
 811         } elsif ($state == 3 and s/^Author:\s+//) {
 812                 s/\s+$//;
 813                 if (/^(.*?)\s+<(.*)>/) {
 814                     ($author_name, $author_email) = ($1, $2);
 815                 } elsif ($conv_author_name{$_}) {
 816                         $author_name = $conv_author_name{$_};
 817                         $author_email = $conv_author_email{$_};
 818                 } else {
 819                     $author_name = $author_email = $_;
 820                 }
 821                 $state = 4;
 822         } elsif ($state == 4 and s/^Branch:\s+//) {
 823                 s/\s+$//;
 824                 tr/_/\./ if ( $opt_u );
 825                 s/[\/]/$opt_s/g;
 826                 $branch = $_;
 827                 $state = 5;
 828         } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
 829                 s/\s+$//;
 830                 $ancestor = $_;
 831                 $ancestor = $opt_o if $ancestor eq "HEAD";
 832                 $state = 6;
 833         } elsif ($state == 5) {
 834                 $ancestor = undef;
 835                 $state = 6;
 836                 redo;
 837         } elsif ($state == 6 and s/^Tag:\s+//) {
 838                 s/\s+$//;
 839                 if ($_ eq "(none)") {
 840                         $tag = undef;
 841                 } else {
 842                         $tag = $_;
 843                 }
 844                 $state = 7;
 845         } elsif ($state == 7 and /^Log:/) {
 846                 $logmsg = "";
 847                 $state = 8;
 848         } elsif ($state == 8 and /^Members:/) {
 849                 $branch = $opt_o if $branch eq "HEAD";
 850                 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 851                         # skip
 852                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 853                         $state = 11;
 854                         next;
 855                 }
 856                 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
 857                         # skip if the commit is too recent
 858                         # given that the cvsps default fuzz is 300s, we give ourselves another
 859                         # 300s just in case -- this also prevents skipping commits
 860                         # due to server clock drift
 861                         print "skip patchset $patchset: $date too recent\n" if $opt_v;
 862                         $state = 11;
 863                         next;
 864                 }
 865                 if (exists $ignorebranch{$branch}) {
 866                         print STDERR "Skipping $branch\n";
 867                         $state = 11;
 868                         next;
 869                 }
 870                 if ($ancestor) {
 871                         if ($ancestor eq $branch) {
 872                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 873                                 $ancestor = $opt_o;
 874                         }
 875                         if (defined get_headref("$remote/$branch")) {
 876                                 print STDERR "Branch $branch already exists!\n";
 877                                 $state=11;
 878                                 next;
 879                         }
 880                         my $id = get_headref("$remote/$ancestor");
 881                         if (!$id) {
 882                                 print STDERR "Branch $ancestor does not exist!\n";
 883                                 $ignorebranch{$branch} = 1;
 884                                 $state=11;
 885                                 next;
 886                         }
 887
 888                         system(qw(git update-ref -m cvsimport),
 889                                 "$remote/$branch", $id);
 890                         if($? != 0) {
 891                                 print STDERR "Could not create branch $branch\n";
 892                                 $ignorebranch{$branch} = 1;
 893                                 $state=11;
 894                                 next;
 895                         }
 896                 }
 897                 $last_branch = $branch if $branch ne $last_branch;
 898                 $state = 9;
 899         } elsif ($state == 8) {
 900                 $logmsg .= "$_\n";
 901         } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 902 #       VERSION:1.96->1.96.2.1
 903                 my $init = ($2 eq "INITIAL");
 904                 my $fn = $1;
 905                 my $rev = $3;
 906                 $fn =~ s#^/+##;
 907                 if ($opt_S && $fn =~ m/$opt_S/) {
 908                     print "SKIPPING $fn v $rev\n";
 909                     push(@skipped, $fn);
 910                     next;
 911                 }
 912                 print "Fetching $fn   v $rev\n" if $opt_v;
 913                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 914                 if ($size == -1) {
 915                         push(@old,$fn);
 916                         print "Drop $fn\n" if $opt_v;
 917                 } else {
 918                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 919                         my $pid = open(my $F, '-|');
 920                         die $! unless defined $pid;
 921                         if (!$pid) {
 922                             exec("git-hash-object", "-w", $tmpname)
 923                                 or die "Cannot create object: $!\n";
 924                         }
 925                         my $sha = <$F>;
 926                         chomp $sha;
 927                         close $F;
 928                         my $mode = pmode($cvs->{'mode'});
 929                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 930                 }
 931                 unlink($tmpname);
 932         } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 933                 my $fn = $1;
 934                 $fn =~ s#^/+##;
 935                 push(@old,$fn);
 936                 print "Delete $fn\n" if $opt_v;
 937         } elsif ($state == 9 and /^\s*$/) {
 938                 $state = 10;
 939         } elsif (($state == 9 or $state == 10) and /^-+$/) {
 940                 $commitcount++;
 941                 if ($opt_L && $commitcount > $opt_L) {
 942                         last;
 943                 }
 944                 commit();
 945                 if (($commitcount & 1023) == 0) {
 946                         system("git repack -a -d");
 947                 }
 948                 $state = 1;
 949         } elsif ($state == 11 and /^-+$/) {
 950                 $state = 1;
 951         } elsif (/^-+$/) { # end of unknown-line processing
 952                 $state = 1;
 953         } elsif ($state != 11) { # ignore stuff when skipping
 954                 print "* UNKNOWN LINE * $_\n";
 955         }
 956 }
 957 commit() if $branch and $state != 11;
 958
 959 unless ($opt_P) {
 960         unlink($cvspsfile);
 961 }
 962
 963 # The heuristic of repacking every 1024 commits can leave a
 964 # lot of unpacked data.  If there is more than 1MB worth of
 965 # not-packed objects, repack once more.
 966 my $line = `git-count-objects`;
 967 if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
 968   my ($n_objects, $kb) = ($1, $2);
 969   1024 < $kb
 970     and system("git repack -a -d");
 971 }
 972
 973 foreach my $git_index (values %index) {
 974     if ($git_index ne "$git_dir/index") {
 975         unlink($git_index);
 976     }
 977 }
 978
 979 if (defined $orig_git_index) {
 980         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 981 } else {
 982         delete $ENV{GIT_INDEX_FILE};
 983 }
 984
 985 # Now switch back to the branch we were in before all of this happened
 986 if ($orig_branch) {
 987         print "DONE.\n" if $opt_v;
 988         if ($opt_i) {
 989                 exit 0;
 990         }
 991         my $tip_at_end = `git-rev-parse --verify HEAD`;
 992         if ($tip_at_start ne $tip_at_end) {
 993                 for ($tip_at_start, $tip_at_end) { chomp; }
 994                 print "Fetched into the current branch.\n" if $opt_v;
 995                 system(qw(git-read-tree -u -m),
 996                        $tip_at_start, $tip_at_end);
 997                 die "Fast-forward update failed: $?\n" if $?;
 998         }
 999         else {
1000                 system(qw(git-merge cvsimport HEAD), "$remote/$opt_o");
1001                 die "Could not merge $opt_o into the current branch.\n" if $?;
1002         }
1003 } else {
1004         $orig_branch = "master";
1005         print "DONE; creating $orig_branch branch\n" if $opt_v;
1006         system("git-update-ref", "refs/heads/master", "$remote/$opt_o")
1007                 unless defined get_headref('refs/heads/master');
1008         system("git-symbolic-ref", "$remote/HEAD", "$remote/$opt_o")
1009                 if ($opt_r && $opt_o ne 'HEAD');
1010         system('git-update-ref', 'HEAD', "$orig_branch");
1011         unless ($opt_i) {
1012                 system('git checkout -f');
1013                 die "checkout failed: $?\n" if $?;
1014         }
1015 }