git-add--interactive.perl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Git;
   5
   6 binmode(STDOUT, ":raw");
   7
   8 my $repo = Git->repository();
   9
  10 my $menu_use_color = $repo->get_colorbool('color.interactive');
  11 my ($prompt_color, $header_color, $help_color) =
  12         $menu_use_color ? (
  13                 $repo->get_color('color.interactive.prompt', 'bold blue'),
  14                 $repo->get_color('color.interactive.header', 'bold'),
  15                 $repo->get_color('color.interactive.help', 'red bold'),
  16         ) : ();
  17 my $error_color = ();
  18 if ($menu_use_color) {
  19         my $help_color_spec = ($repo->config('color.interactive.help') or
  20                                 'red bold');
  21         $error_color = $repo->get_color('color.interactive.error',
  22                                         $help_color_spec);
  23 }
  24
  25 my $diff_use_color = $repo->get_colorbool('color.diff');
  26 my ($fraginfo_color) =
  27         $diff_use_color ? (
  28                 $repo->get_color('color.diff.frag', 'cyan'),
  29         ) : ();
  30 my ($diff_plain_color) =
  31         $diff_use_color ? (
  32                 $repo->get_color('color.diff.plain', ''),
  33         ) : ();
  34 my ($diff_old_color) =
  35         $diff_use_color ? (
  36                 $repo->get_color('color.diff.old', 'red'),
  37         ) : ();
  38 my ($diff_new_color) =
  39         $diff_use_color ? (
  40                 $repo->get_color('color.diff.new', 'green'),
  41         ) : ();
  42
  43 my $normal_color = $repo->get_color("", "reset");
  44
  45 my $use_readkey = 0;
  46 sub ReadMode;
  47 sub ReadKey;
  48 if ($repo->config_bool("interactive.singlekey")) {
  49         eval {
  50                 require Term::ReadKey;
  51                 Term::ReadKey->import;
  52                 $use_readkey = 1;
  53         };
  54 }
  55
  56 sub colored {
  57         my $color = shift;
  58         my $string = join("", @_);
  59
  60         if (defined $color) {
  61                 # Put a color code at the beginning of each line, a reset at the end
  62                 # color after newlines that are not at the end of the string
  63                 $string =~ s/(\n+)(.)/$1$color$2/g;
  64                 # reset before newlines
  65                 $string =~ s/(\n+)/$normal_color$1/g;
  66                 # codes at beginning and end (if necessary):
  67                 $string =~ s/^/$color/;
  68                 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
  69         }
  70         return $string;
  71 }
  72
  73 # command line options
  74 my $patch_mode;
  75
  76 sub run_cmd_pipe {
  77         if ($^O eq 'MSWin32' || $^O eq 'msys') {
  78                 my @invalid = grep {m/[":*]/} @_;
  79                 die "$^O does not support: @invalid\n" if @invalid;
  80                 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
  81                 return qx{@args};
  82         } else {
  83                 my $fh = undef;
  84                 open($fh, '-|', @_) or die;
  85                 return <$fh>;
  86         }
  87 }
  88
  89 my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
  90
  91 if (!defined $GIT_DIR) {
  92         exit(1); # rev-parse would have already said "not a git repo"
  93 }
  94 chomp($GIT_DIR);
  95
  96 my %cquote_map = (
  97  "b" => chr(8),
  98  "t" => chr(9),
  99  "n" => chr(10),
 100  "v" => chr(11),
 101  "f" => chr(12),
 102  "r" => chr(13),
 103  "\\" => "\\",
 104  "\042" => "\042",
 105 );
 106
 107 sub unquote_path {
 108         local ($_) = @_;
 109         my ($retval, $remainder);
 110         if (!/^\042(.*)\042$/) {
 111                 return $_;
 112         }
 113         ($_, $retval) = ($1, "");
 114         while (/^([^\\]*)\\(.*)$/) {
 115                 $remainder = $2;
 116                 $retval .= $1;
 117                 for ($remainder) {
 118                         if (/^([0-3][0-7][0-7])(.*)$/) {
 119                                 $retval .= chr(oct($1));
 120                                 $_ = $2;
 121                                 last;
 122                         }
 123                         if (/^([\\\042btnvfr])(.*)$/) {
 124                                 $retval .= $cquote_map{$1};
 125                                 $_ = $2;
 126                                 last;
 127                         }
 128                         # This is malformed -- just return it as-is for now.
 129                         return $_[0];
 130                 }
 131                 $_ = $remainder;
 132         }
 133         $retval .= $_;
 134         return $retval;
 135 }
 136
 137 sub refresh {
 138         my $fh;
 139         open $fh, 'git update-index --refresh |'
 140             or die;
 141         while (<$fh>) {
 142                 ;# ignore 'needs update'
 143         }
 144         close $fh;
 145 }
 146
 147 sub list_untracked {
 148         map {
 149                 chomp $_;
 150                 unquote_path($_);
 151         }
 152         run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
 153 }
 154
 155 my $status_fmt = '%12s %12s %s';
 156 my $status_head = sprintf($status_fmt, 'staged', 'unstaged', 'path');
 157
 158 {
 159         my $initial;
 160         sub is_initial_commit {
 161                 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
 162                         unless defined $initial;
 163                 return $initial;
 164         }
 165 }
 166
 167 sub get_empty_tree {
 168         return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
 169 }
 170
 171 # Returns list of hashes, contents of each of which are:
 172 # VALUE:        pathname
 173 # BINARY:       is a binary path
 174 # INDEX:        is index different from HEAD?
 175 # FILE:         is file different from index?
 176 # INDEX_ADDDEL: is it add/delete between HEAD and index?
 177 # FILE_ADDDEL:  is it add/delete between index and file?
 178
 179 sub list_modified {
 180         my ($only) = @_;
 181         my (%data, @return);
 182         my ($add, $del, $adddel, $file);
 183         my @tracked = ();
 184
 185         if (@ARGV) {
 186                 @tracked = map {
 187                         chomp $_;
 188                         unquote_path($_);
 189                 } run_cmd_pipe(qw(git ls-files --exclude-standard --), @ARGV);
 190                 return if (!@tracked);
 191         }
 192
 193         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
 194         for (run_cmd_pipe(qw(git diff-index --cached
 195                              --numstat --summary), $reference,
 196                              '--', @tracked)) {
 197                 if (($add, $del, $file) =
 198                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 199                         my ($change, $bin);
 200                         $file = unquote_path($file);
 201                         if ($add eq '-' && $del eq '-') {
 202                                 $change = 'binary';
 203                                 $bin = 1;
 204                         }
 205                         else {
 206                                 $change = "+$add/-$del";
 207                         }
 208                         $data{$file} = {
 209                                 INDEX => $change,
 210                                 BINARY => $bin,
 211                                 FILE => 'nothing',
 212                         }
 213                 }
 214                 elsif (($adddel, $file) =
 215                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 216                         $file = unquote_path($file);
 217                         $data{$file}{INDEX_ADDDEL} = $adddel;
 218                 }
 219         }
 220
 221         for (run_cmd_pipe(qw(git diff-files --numstat --summary --), @tracked)) {
 222                 if (($add, $del, $file) =
 223                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 224                         $file = unquote_path($file);
 225                         if (!exists $data{$file}) {
 226                                 $data{$file} = +{
 227                                         INDEX => 'unchanged',
 228                                         BINARY => 0,
 229                                 };
 230                         }
 231                         my ($change, $bin);
 232                         if ($add eq '-' && $del eq '-') {
 233                                 $change = 'binary';
 234                                 $bin = 1;
 235                         }
 236                         else {
 237                                 $change = "+$add/-$del";
 238                         }
 239                         $data{$file}{FILE} = $change;
 240                         if ($bin) {
 241                                 $data{$file}{BINARY} = 1;
 242                         }
 243                 }
 244                 elsif (($adddel, $file) =
 245                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 246                         $file = unquote_path($file);
 247                         $data{$file}{FILE_ADDDEL} = $adddel;
 248                 }
 249         }
 250
 251         for (sort keys %data) {
 252                 my $it = $data{$_};
 253
 254                 if ($only) {
 255                         if ($only eq 'index-only') {
 256                                 next if ($it->{INDEX} eq 'unchanged');
 257                         }
 258                         if ($only eq 'file-only') {
 259                                 next if ($it->{FILE} eq 'nothing');
 260                         }
 261                 }
 262                 push @return, +{
 263                         VALUE => $_,
 264                         %$it,
 265                 };
 266         }
 267         return @return;
 268 }
 269
 270 sub find_unique {
 271         my ($string, @stuff) = @_;
 272         my $found = undef;
 273         for (my $i = 0; $i < @stuff; $i++) {
 274                 my $it = $stuff[$i];
 275                 my $hit = undef;
 276                 if (ref $it) {
 277                         if ((ref $it) eq 'ARRAY') {
 278                                 $it = $it->[0];
 279                         }
 280                         else {
 281                                 $it = $it->{VALUE};
 282                         }
 283                 }
 284                 eval {
 285                         if ($it =~ /^$string/) {
 286                                 $hit = 1;
 287                         };
 288                 };
 289                 if (defined $hit && defined $found) {
 290                         return undef;
 291                 }
 292                 if ($hit) {
 293                         $found = $i + 1;
 294                 }
 295         }
 296         return $found;
 297 }
 298
 299 # inserts string into trie and updates count for each character
 300 sub update_trie {
 301         my ($trie, $string) = @_;
 302         foreach (split //, $string) {
 303                 $trie = $trie->{$_} ||= {COUNT => 0};
 304                 $trie->{COUNT}++;
 305         }
 306 }
 307
 308 # returns an array of tuples (prefix, remainder)
 309 sub find_unique_prefixes {
 310         my @stuff = @_;
 311         my @return = ();
 312
 313         # any single prefix exceeding the soft limit is omitted
 314         # if any prefix exceeds the hard limit all are omitted
 315         # 0 indicates no limit
 316         my $soft_limit = 0;
 317         my $hard_limit = 3;
 318
 319         # build a trie modelling all possible options
 320         my %trie;
 321         foreach my $print (@stuff) {
 322                 if ((ref $print) eq 'ARRAY') {
 323                         $print = $print->[0];
 324                 }
 325                 elsif ((ref $print) eq 'HASH') {
 326                         $print = $print->{VALUE};
 327                 }
 328                 update_trie(\%trie, $print);
 329                 push @return, $print;
 330         }
 331
 332         # use the trie to find the unique prefixes
 333         for (my $i = 0; $i < @return; $i++) {
 334                 my $ret = $return[$i];
 335                 my @letters = split //, $ret;
 336                 my %search = %trie;
 337                 my ($prefix, $remainder);
 338                 my $j;
 339                 for ($j = 0; $j < @letters; $j++) {
 340                         my $letter = $letters[$j];
 341                         if ($search{$letter}{COUNT} == 1) {
 342                                 $prefix = substr $ret, 0, $j + 1;
 343                                 $remainder = substr $ret, $j + 1;
 344                                 last;
 345                         }
 346                         else {
 347                                 my $prefix = substr $ret, 0, $j;
 348                                 return ()
 349                                     if ($hard_limit && $j + 1 > $hard_limit);
 350                         }
 351                         %search = %{$search{$letter}};
 352                 }
 353                 if (ord($letters[0]) > 127 ||
 354                     ($soft_limit && $j + 1 > $soft_limit)) {
 355                         $prefix = undef;
 356                         $remainder = $ret;
 357                 }
 358                 $return[$i] = [$prefix, $remainder];
 359         }
 360         return @return;
 361 }
 362
 363 # filters out prefixes which have special meaning to list_and_choose()
 364 sub is_valid_prefix {
 365         my $prefix = shift;
 366         return (defined $prefix) &&
 367             !($prefix =~ /[\s,]/) && # separators
 368             !($prefix =~ /^-/) &&    # deselection
 369             !($prefix =~ /^\d+/) &&  # selection
 370             ($prefix ne '*') &&      # "all" wildcard
 371             ($prefix ne '?');        # prompt help
 372 }
 373
 374 # given a prefix/remainder tuple return a string with the prefix highlighted
 375 # for now use square brackets; later might use ANSI colors (underline, bold)
 376 sub highlight_prefix {
 377         my $prefix = shift;
 378         my $remainder = shift;
 379
 380         if (!defined $prefix) {
 381                 return $remainder;
 382         }
 383
 384         if (!is_valid_prefix($prefix)) {
 385                 return "$prefix$remainder";
 386         }
 387
 388         if (!$menu_use_color) {
 389                 return "[$prefix]$remainder";
 390         }
 391
 392         return "$prompt_color$prefix$normal_color$remainder";
 393 }
 394
 395 sub error_msg {
 396         print STDERR colored $error_color, @_;
 397 }
 398
 399 sub list_and_choose {
 400         my ($opts, @stuff) = @_;
 401         my (@chosen, @return);
 402         my $i;
 403         my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
 404
 405       TOPLOOP:
 406         while (1) {
 407                 my $last_lf = 0;
 408
 409                 if ($opts->{HEADER}) {
 410                         if (!$opts->{LIST_FLAT}) {
 411                                 print "     ";
 412                         }
 413                         print colored $header_color, "$opts->{HEADER}\n";
 414                 }
 415                 for ($i = 0; $i < @stuff; $i++) {
 416                         my $chosen = $chosen[$i] ? '*' : ' ';
 417                         my $print = $stuff[$i];
 418                         my $ref = ref $print;
 419                         my $highlighted = highlight_prefix(@{$prefixes[$i]})
 420                             if @prefixes;
 421                         if ($ref eq 'ARRAY') {
 422                                 $print = $highlighted || $print->[0];
 423                         }
 424                         elsif ($ref eq 'HASH') {
 425                                 my $value = $highlighted || $print->{VALUE};
 426                                 $print = sprintf($status_fmt,
 427                                     $print->{INDEX},
 428                                     $print->{FILE},
 429                                     $value);
 430                         }
 431                         else {
 432                                 $print = $highlighted || $print;
 433                         }
 434                         printf("%s%2d: %s", $chosen, $i+1, $print);
 435                         if (($opts->{LIST_FLAT}) &&
 436                             (($i + 1) % ($opts->{LIST_FLAT}))) {
 437                                 print "\t";
 438                                 $last_lf = 0;
 439                         }
 440                         else {
 441                                 print "\n";
 442                                 $last_lf = 1;
 443                         }
 444                 }
 445                 if (!$last_lf) {
 446                         print "\n";
 447                 }
 448
 449                 return if ($opts->{LIST_ONLY});
 450
 451                 print colored $prompt_color, $opts->{PROMPT};
 452                 if ($opts->{SINGLETON}) {
 453                         print "> ";
 454                 }
 455                 else {
 456                         print ">> ";
 457                 }
 458                 my $line = <STDIN>;
 459                 if (!$line) {
 460                         print "\n";
 461                         $opts->{ON_EOF}->() if $opts->{ON_EOF};
 462                         last;
 463                 }
 464                 chomp $line;
 465                 last if $line eq '';
 466                 if ($line eq '?') {
 467                         $opts->{SINGLETON} ?
 468                             singleton_prompt_help_cmd() :
 469                             prompt_help_cmd();
 470                         next TOPLOOP;
 471                 }
 472                 for my $choice (split(/[\s,]+/, $line)) {
 473                         my $choose = 1;
 474                         my ($bottom, $top);
 475
 476                         # Input that begins with '-'; unchoose
 477                         if ($choice =~ s/^-//) {
 478                                 $choose = 0;
 479                         }
 480                         # A range can be specified like 5-7 or 5-.
 481                         if ($choice =~ /^(\d+)-(\d*)$/) {
 482                                 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
 483                         }
 484                         elsif ($choice =~ /^\d+$/) {
 485                                 $bottom = $top = $choice;
 486                         }
 487                         elsif ($choice eq '*') {
 488                                 $bottom = 1;
 489                                 $top = 1 + @stuff;
 490                         }
 491                         else {
 492                                 $bottom = $top = find_unique($choice, @stuff);
 493                                 if (!defined $bottom) {
 494                                         error_msg "Huh ($choice)?\n";
 495                                         next TOPLOOP;
 496                                 }
 497                         }
 498                         if ($opts->{SINGLETON} && $bottom != $top) {
 499                                 error_msg "Huh ($choice)?\n";
 500                                 next TOPLOOP;
 501                         }
 502                         for ($i = $bottom-1; $i <= $top-1; $i++) {
 503                                 next if (@stuff <= $i || $i < 0);
 504                                 $chosen[$i] = $choose;
 505                         }
 506                 }
 507                 last if ($opts->{IMMEDIATE} || $line eq '*');
 508         }
 509         for ($i = 0; $i < @stuff; $i++) {
 510                 if ($chosen[$i]) {
 511                         push @return, $stuff[$i];
 512                 }
 513         }
 514         return @return;
 515 }
 516
 517 sub singleton_prompt_help_cmd {
 518         print colored $help_color, <<\EOF ;
 519 Prompt help:
 520 1          - select a numbered item
 521 foo        - select item based on unique prefix
 522            - (empty) select nothing
 523 EOF
 524 }
 525
 526 sub prompt_help_cmd {
 527         print colored $help_color, <<\EOF ;
 528 Prompt help:
 529 1          - select a single item
 530 3-5        - select a range of items
 531 2-3,6-9    - select multiple ranges
 532 foo        - select item based on unique prefix
 533 -...       - unselect specified items
 534 *          - choose all items
 535            - (empty) finish selecting
 536 EOF
 537 }
 538
 539 sub status_cmd {
 540         list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
 541                         list_modified());
 542         print "\n";
 543 }
 544
 545 sub say_n_paths {
 546         my $did = shift @_;
 547         my $cnt = scalar @_;
 548         print "$did ";
 549         if (1 < $cnt) {
 550                 print "$cnt paths\n";
 551         }
 552         else {
 553                 print "one path\n";
 554         }
 555 }
 556
 557 sub update_cmd {
 558         my @mods = list_modified('file-only');
 559         return if (!@mods);
 560
 561         my @update = list_and_choose({ PROMPT => 'Update',
 562                                        HEADER => $status_head, },
 563                                      @mods);
 564         if (@update) {
 565                 system(qw(git update-index --add --remove --),
 566                        map { $_->{VALUE} } @update);
 567                 say_n_paths('updated', @update);
 568         }
 569         print "\n";
 570 }
 571
 572 sub revert_cmd {
 573         my @update = list_and_choose({ PROMPT => 'Revert',
 574                                        HEADER => $status_head, },
 575                                      list_modified());
 576         if (@update) {
 577                 if (is_initial_commit()) {
 578                         system(qw(git rm --cached),
 579                                 map { $_->{VALUE} } @update);
 580                 }
 581                 else {
 582                         my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
 583                                                  map { $_->{VALUE} } @update);
 584                         my $fh;
 585                         open $fh, '| git update-index --index-info'
 586                             or die;
 587                         for (@lines) {
 588                                 print $fh $_;
 589                         }
 590                         close($fh);
 591                         for (@update) {
 592                                 if ($_->{INDEX_ADDDEL} &&
 593                                     $_->{INDEX_ADDDEL} eq 'create') {
 594                                         system(qw(git update-index --force-remove --),
 595                                                $_->{VALUE});
 596                                         print "note: $_->{VALUE} is untracked now.\n";
 597                                 }
 598                         }
 599                 }
 600                 refresh();
 601                 say_n_paths('reverted', @update);
 602         }
 603         print "\n";
 604 }
 605
 606 sub add_untracked_cmd {
 607         my @add = list_and_choose({ PROMPT => 'Add untracked' },
 608                                   list_untracked());
 609         if (@add) {
 610                 system(qw(git update-index --add --), @add);
 611                 say_n_paths('added', @add);
 612         }
 613         print "\n";
 614 }
 615
 616 sub parse_diff {
 617         my ($path) = @_;
 618         my @diff = run_cmd_pipe(qw(git diff-files -p --), $path);
 619         my @colored = ();
 620         if ($diff_use_color) {
 621                 @colored = run_cmd_pipe(qw(git diff-files -p --color --), $path);
 622         }
 623         my (@hunk) = { TEXT => [], DISPLAY => [] };
 624
 625         for (my $i = 0; $i < @diff; $i++) {
 626                 if ($diff[$i] =~ /^@@ /) {
 627                         push @hunk, { TEXT => [], DISPLAY => [] };
 628                 }
 629                 push @{$hunk[-1]{TEXT}}, $diff[$i];
 630                 push @{$hunk[-1]{DISPLAY}},
 631                         ($diff_use_color ? $colored[$i] : $diff[$i]);
 632         }
 633         return @hunk;
 634 }
 635
 636 sub parse_diff_header {
 637         my $src = shift;
 638
 639         my $head = { TEXT => [], DISPLAY => [] };
 640         my $mode = { TEXT => [], DISPLAY => [] };
 641
 642         for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
 643                 my $dest = $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ?
 644                         $mode : $head;
 645                 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
 646                 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
 647         }
 648         return ($head, $mode);
 649 }
 650
 651 sub hunk_splittable {
 652         my ($text) = @_;
 653
 654         my @s = split_hunk($text);
 655         return (1 < @s);
 656 }
 657
 658 sub parse_hunk_header {
 659         my ($line) = @_;
 660         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
 661             $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@/;
 662         $o_cnt = 1 unless defined $o_cnt;
 663         $n_cnt = 1 unless defined $n_cnt;
 664         return ($o_ofs, $o_cnt, $n_ofs, $n_cnt);
 665 }
 666
 667 sub split_hunk {
 668         my ($text, $display) = @_;
 669         my @split = ();
 670         if (!defined $display) {
 671                 $display = $text;
 672         }
 673         # If there are context lines in the middle of a hunk,
 674         # it can be split, but we would need to take care of
 675         # overlaps later.
 676
 677         my ($o_ofs, undef, $n_ofs) = parse_hunk_header($text->[0]);
 678         my $hunk_start = 1;
 679
 680       OUTER:
 681         while (1) {
 682                 my $next_hunk_start = undef;
 683                 my $i = $hunk_start - 1;
 684                 my $this = +{
 685                         TEXT => [],
 686                         DISPLAY => [],
 687                         OLD => $o_ofs,
 688                         NEW => $n_ofs,
 689                         OCNT => 0,
 690                         NCNT => 0,
 691                         ADDDEL => 0,
 692                         POSTCTX => 0,
 693                         USE => undef,
 694                 };
 695
 696                 while (++$i < @$text) {
 697                         my $line = $text->[$i];
 698                         my $display = $display->[$i];
 699                         if ($line =~ /^ /) {
 700                                 if ($this->{ADDDEL} &&
 701                                     !defined $next_hunk_start) {
 702                                         # We have seen leading context and
 703                                         # adds/dels and then here is another
 704                                         # context, which is trailing for this
 705                                         # split hunk and leading for the next
 706                                         # one.
 707                                         $next_hunk_start = $i;
 708                                 }
 709                                 push @{$this->{TEXT}}, $line;
 710                                 push @{$this->{DISPLAY}}, $display;
 711                                 $this->{OCNT}++;
 712                                 $this->{NCNT}++;
 713                                 if (defined $next_hunk_start) {
 714                                         $this->{POSTCTX}++;
 715                                 }
 716                                 next;
 717                         }
 718
 719                         # add/del
 720                         if (defined $next_hunk_start) {
 721                                 # We are done with the current hunk and
 722                                 # this is the first real change for the
 723                                 # next split one.
 724                                 $hunk_start = $next_hunk_start;
 725                                 $o_ofs = $this->{OLD} + $this->{OCNT};
 726                                 $n_ofs = $this->{NEW} + $this->{NCNT};
 727                                 $o_ofs -= $this->{POSTCTX};
 728                                 $n_ofs -= $this->{POSTCTX};
 729                                 push @split, $this;
 730                                 redo OUTER;
 731                         }
 732                         push @{$this->{TEXT}}, $line;
 733                         push @{$this->{DISPLAY}}, $display;
 734                         $this->{ADDDEL}++;
 735                         if ($line =~ /^-/) {
 736                                 $this->{OCNT}++;
 737                         }
 738                         else {
 739                                 $this->{NCNT}++;
 740                         }
 741                 }
 742
 743                 push @split, $this;
 744                 last;
 745         }
 746
 747         for my $hunk (@split) {
 748                 $o_ofs = $hunk->{OLD};
 749                 $n_ofs = $hunk->{NEW};
 750                 my $o_cnt = $hunk->{OCNT};
 751                 my $n_cnt = $hunk->{NCNT};
 752
 753                 my $head = ("@@ -$o_ofs" .
 754                             (($o_cnt != 1) ? ",$o_cnt" : '') .
 755                             " +$n_ofs" .
 756                             (($n_cnt != 1) ? ",$n_cnt" : '') .
 757                             " @@\n");
 758                 my $display_head = $head;
 759                 unshift @{$hunk->{TEXT}}, $head;
 760                 if ($diff_use_color) {
 761                         $display_head = colored($fraginfo_color, $head);
 762                 }
 763                 unshift @{$hunk->{DISPLAY}}, $display_head;
 764         }
 765         return @split;
 766 }
 767
 768
 769 sub color_diff {
 770         return map {
 771                 colored((/^@/  ? $fraginfo_color :
 772                          /^\+/ ? $diff_new_color :
 773                          /^-/  ? $diff_old_color :
 774                          $diff_plain_color),
 775                         $_);
 776         } @_;
 777 }
 778
 779 sub edit_hunk_manually {
 780         my ($oldtext) = @_;
 781
 782         my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
 783         my $fh;
 784         open $fh, '>', $hunkfile
 785                 or die "failed to open hunk edit file for writing: " . $!;
 786         print $fh "# Manual hunk edit mode -- see bottom for a quick guide\n";
 787         print $fh @$oldtext;
 788         print $fh <<EOF;
 789 # ---
 790 # To remove '-' lines, make them ' ' lines (context).
 791 # To remove '+' lines, delete them.
 792 # Lines starting with # will be removed.
 793 #
 794 # If the patch applies cleanly, the edited hunk will immediately be
 795 # marked for staging. If it does not apply cleanly, you will be given
 796 # an opportunity to edit again. If all lines of the hunk are removed,
 797 # then the edit is aborted and the hunk is left unchanged.
 798 EOF
 799         close $fh;
 800
 801         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor")
 802                 || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 803         system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
 804
 805         open $fh, '<', $hunkfile
 806                 or die "failed to open hunk edit file for reading: " . $!;
 807         my @newtext = grep { !/^#/ } <$fh>;
 808         close $fh;
 809         unlink $hunkfile;
 810
 811         # Abort if nothing remains
 812         if (!grep { /\S/ } @newtext) {
 813                 return undef;
 814         }
 815
 816         # Reinsert the first hunk header if the user accidentally deleted it
 817         if ($newtext[0] !~ /^@/) {
 818                 unshift @newtext, $oldtext->[0];
 819         }
 820         return \@newtext;
 821 }
 822
 823 sub diff_applies {
 824         my $fh;
 825         open $fh, '| git apply --recount --cached --check';
 826         for my $h (@_) {
 827                 print $fh @{$h->{TEXT}};
 828         }
 829         return close $fh;
 830 }
 831
 832 sub _restore_terminal_and_die {
 833         ReadMode 'restore';
 834         print "\n";
 835         exit 1;
 836 }
 837
 838 sub prompt_single_character {
 839         if ($use_readkey) {
 840                 local $SIG{TERM} = \&_restore_terminal_and_die;
 841                 local $SIG{INT} = \&_restore_terminal_and_die;
 842                 ReadMode 'cbreak';
 843                 my $key = ReadKey 0;
 844                 ReadMode 'restore';
 845                 print "$key" if defined $key;
 846                 print "\n";
 847                 return $key;
 848         } else {
 849                 return <STDIN>;
 850         }
 851 }
 852
 853 sub prompt_yesno {
 854         my ($prompt) = @_;
 855         while (1) {
 856                 print colored $prompt_color, $prompt;
 857                 my $line = prompt_single_character;
 858                 return 0 if $line =~ /^n/i;
 859                 return 1 if $line =~ /^y/i;
 860         }
 861 }
 862
 863 sub edit_hunk_loop {
 864         my ($head, $hunk, $ix) = @_;
 865         my $text = $hunk->[$ix]->{TEXT};
 866
 867         while (1) {
 868                 $text = edit_hunk_manually($text);
 869                 if (!defined $text) {
 870                         return undef;
 871                 }
 872                 my $newhunk = { TEXT => $text, USE => 1 };
 873                 if (diff_applies($head,
 874                                  @{$hunk}[0..$ix-1],
 875                                  $newhunk,
 876                                  @{$hunk}[$ix+1..$#{$hunk}])) {
 877                         $newhunk->{DISPLAY} = [color_diff(@{$text})];
 878                         return $newhunk;
 879                 }
 880                 else {
 881                         prompt_yesno(
 882                                 'Your edited hunk does not apply. Edit again '
 883                                 . '(saying "no" discards!) [y/n]? '
 884                                 ) or return undef;
 885                 }
 886         }
 887 }
 888
 889 sub help_patch_cmd {
 890         print colored $help_color, <<\EOF ;
 891 y - stage this hunk
 892 n - do not stage this hunk
 893 a - stage this and all the remaining hunks in the file
 894 d - do not stage this hunk nor any of the remaining hunks in the file
 895 g - select a hunk to go to
 896 / - search for a hunk matching the given regex
 897 j - leave this hunk undecided, see next undecided hunk
 898 J - leave this hunk undecided, see next hunk
 899 k - leave this hunk undecided, see previous undecided hunk
 900 K - leave this hunk undecided, see previous hunk
 901 s - split the current hunk into smaller hunks
 902 e - manually edit the current hunk
 903 ? - print help
 904 EOF
 905 }
 906
 907 sub patch_update_cmd {
 908         my @all_mods = list_modified('file-only');
 909         my @mods = grep { !($_->{BINARY}) } @all_mods;
 910         my @them;
 911
 912         if (!@mods) {
 913                 if (@all_mods) {
 914                         print STDERR "Only binary files changed.\n";
 915                 } else {
 916                         print STDERR "No changes.\n";
 917                 }
 918                 return 0;
 919         }
 920         if ($patch_mode) {
 921                 @them = @mods;
 922         }
 923         else {
 924                 @them = list_and_choose({ PROMPT => 'Patch update',
 925                                           HEADER => $status_head, },
 926                                         @mods);
 927         }
 928         for (@them) {
 929                 patch_update_file($_->{VALUE});
 930         }
 931 }
 932
 933 # Generate a one line summary of a hunk.
 934 sub summarize_hunk {
 935         my $rhunk = shift;
 936         my $summary = $rhunk->{TEXT}[0];
 937
 938         # Keep the line numbers, discard extra context.
 939         $summary =~ s/@@(.*?)@@.*/$1 /s;
 940         $summary .= " " x (20 - length $summary);
 941
 942         # Add some user context.
 943         for my $line (@{$rhunk->{TEXT}}) {
 944                 if ($line =~ m/^[+-].*\w/) {
 945                         $summary .= $line;
 946                         last;
 947                 }
 948         }
 949
 950         chomp $summary;
 951         return substr($summary, 0, 80) . "\n";
 952 }
 953
 954
 955 # Print a one-line summary of each hunk in the array ref in
 956 # the first argument, starting wih the index in the 2nd.
 957 sub display_hunks {
 958         my ($hunks, $i) = @_;
 959         my $ctr = 0;
 960         $i ||= 0;
 961         for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
 962                 my $status = " ";
 963                 if (defined $hunks->[$i]{USE}) {
 964                         $status = $hunks->[$i]{USE} ? "+" : "-";
 965                 }
 966                 printf "%s%2d: %s",
 967                         $status,
 968                         $i + 1,
 969                         summarize_hunk($hunks->[$i]);
 970         }
 971         return $i;
 972 }
 973
 974 sub patch_update_file {
 975         my ($ix, $num);
 976         my $path = shift;
 977         my ($head, @hunk) = parse_diff($path);
 978         ($head, my $mode) = parse_diff_header($head);
 979         for (@{$head->{DISPLAY}}) {
 980                 print;
 981         }
 982
 983         if (@{$mode->{TEXT}}) {
 984                 while (1) {
 985                         print @{$mode->{DISPLAY}};
 986                         print colored $prompt_color,
 987                                 "Stage mode change [y/n/a/d/?]? ";
 988                         my $line = prompt_single_character;
 989                         if ($line =~ /^y/i) {
 990                                 $mode->{USE} = 1;
 991                                 last;
 992                         }
 993                         elsif ($line =~ /^n/i) {
 994                                 $mode->{USE} = 0;
 995                                 last;
 996                         }
 997                         elsif ($line =~ /^a/i) {
 998                                 $_->{USE} = 1 foreach ($mode, @hunk);
 999                                 last;
1000                         }
1001                         elsif ($line =~ /^d/i) {
1002                                 $_->{USE} = 0 foreach ($mode, @hunk);
1003                                 last;
1004                         }
1005                         else {
1006                                 help_patch_cmd('');
1007                                 next;
1008                         }
1009                 }
1010         }
1011
1012         $num = scalar @hunk;
1013         $ix = 0;
1014
1015         while (1) {
1016                 my ($prev, $next, $other, $undecided, $i);
1017                 $other = '';
1018
1019                 if ($num <= $ix) {
1020                         $ix = 0;
1021                 }
1022                 for ($i = 0; $i < $ix; $i++) {
1023                         if (!defined $hunk[$i]{USE}) {
1024                                 $prev = 1;
1025                                 $other .= ',k';
1026                                 last;
1027                         }
1028                 }
1029                 if ($ix) {
1030                         $other .= ',K';
1031                 }
1032                 for ($i = $ix + 1; $i < $num; $i++) {
1033                         if (!defined $hunk[$i]{USE}) {
1034                                 $next = 1;
1035                                 $other .= ',j';
1036                                 last;
1037                         }
1038                 }
1039                 if ($ix < $num - 1) {
1040                         $other .= ',J';
1041                 }
1042                 if ($num > 1) {
1043                         $other .= ',g';
1044                 }
1045                 for ($i = 0; $i < $num; $i++) {
1046                         if (!defined $hunk[$i]{USE}) {
1047                                 $undecided = 1;
1048                                 last;
1049                         }
1050                 }
1051                 last if (!$undecided);
1052
1053                 if (hunk_splittable($hunk[$ix]{TEXT})) {
1054                         $other .= ',s';
1055                 }
1056                 $other .= ',e';
1057                 for (@{$hunk[$ix]{DISPLAY}}) {
1058                         print;
1059                 }
1060                 print colored $prompt_color, "Stage this hunk [y,n,a,d,/$other,?]? ";
1061                 my $line = prompt_single_character;
1062                 if ($line) {
1063                         if ($line =~ /^y/i) {
1064                                 $hunk[$ix]{USE} = 1;
1065                         }
1066                         elsif ($line =~ /^n/i) {
1067                                 $hunk[$ix]{USE} = 0;
1068                         }
1069                         elsif ($line =~ /^a/i) {
1070                                 while ($ix < $num) {
1071                                         if (!defined $hunk[$ix]{USE}) {
1072                                                 $hunk[$ix]{USE} = 1;
1073                                         }
1074                                         $ix++;
1075                                 }
1076                                 next;
1077                         }
1078                         elsif ($other =~ /g/ && $line =~ /^g(.*)/) {
1079                                 my $response = $1;
1080                                 my $no = $ix > 10 ? $ix - 10 : 0;
1081                                 while ($response eq '') {
1082                                         my $extra = "";
1083                                         $no = display_hunks(\@hunk, $no);
1084                                         if ($no < $num) {
1085                                                 $extra = " (<ret> to see more)";
1086                                         }
1087                                         print "go to which hunk$extra? ";
1088                                         $response = <STDIN>;
1089                                         if (!defined $response) {
1090                                                 $response = '';
1091                                         }
1092                                         chomp $response;
1093                                 }
1094                                 if ($response !~ /^\s*\d+\s*$/) {
1095                                         error_msg "Invalid number: '$response'\n";
1096                                 } elsif (0 < $response && $response <= $num) {
1097                                         $ix = $response - 1;
1098                                 } else {
1099                                         error_msg "Sorry, only $num hunks available.\n";
1100                                 }
1101                                 next;
1102                         }
1103                         elsif ($line =~ /^d/i) {
1104                                 while ($ix < $num) {
1105                                         if (!defined $hunk[$ix]{USE}) {
1106                                                 $hunk[$ix]{USE} = 0;
1107                                         }
1108                                         $ix++;
1109                                 }
1110                                 next;
1111                         }
1112                         elsif ($line =~ m|^/(.*)|) {
1113                                 my $regex = $1;
1114                                 if ($1 eq "") {
1115                                         print colored $prompt_color, "search for regex? ";
1116                                         $regex = <STDIN>;
1117                                         if (defined $regex) {
1118                                                 chomp $regex;
1119                                         }
1120                                 }
1121                                 my $search_string;
1122                                 eval {
1123                                         $search_string = qr{$regex}m;
1124                                 };
1125                                 if ($@) {
1126                                         my ($err,$exp) = ($@, $1);
1127                                         $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1128                                         error_msg "Malformed search regexp $exp: $err\n";
1129                                         next;
1130                                 }
1131                                 my $iy = $ix;
1132                                 while (1) {
1133                                         my $text = join ("", @{$hunk[$iy]{TEXT}});
1134                                         last if ($text =~ $search_string);
1135                                         $iy++;
1136                                         $iy = 0 if ($iy >= $num);
1137                                         if ($ix == $iy) {
1138                                                 error_msg "No hunk matches the given pattern\n";
1139                                                 last;
1140                                         }
1141                                 }
1142                                 $ix = $iy;
1143                                 next;
1144                         }
1145                         elsif ($line =~ /^K/) {
1146                                 if ($other =~ /K/) {
1147                                         $ix--;
1148                                 }
1149                                 else {
1150                                         error_msg "No previous hunk\n";
1151                                 }
1152                                 next;
1153                         }
1154                         elsif ($line =~ /^J/) {
1155                                 if ($other =~ /J/) {
1156                                         $ix++;
1157                                 }
1158                                 else {
1159                                         error_msg "No next hunk\n";
1160                                 }
1161                                 next;
1162                         }
1163                         elsif ($line =~ /^k/) {
1164                                 if ($other =~ /k/) {
1165                                         while (1) {
1166                                                 $ix--;
1167                                                 last if (!$ix ||
1168                                                          !defined $hunk[$ix]{USE});
1169                                         }
1170                                 }
1171                                 else {
1172                                         error_msg "No previous hunk\n";
1173                                 }
1174                                 next;
1175                         }
1176                         elsif ($line =~ /^j/) {
1177                                 if ($other !~ /j/) {
1178                                         error_msg "No next hunk\n";
1179                                         next;
1180                                 }
1181                         }
1182                         elsif ($other =~ /s/ && $line =~ /^s/) {
1183                                 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1184                                 if (1 < @split) {
1185                                         print colored $header_color, "Split into ",
1186                                         scalar(@split), " hunks.\n";
1187                                 }
1188                                 splice (@hunk, $ix, 1, @split);
1189                                 $num = scalar @hunk;
1190                                 next;
1191                         }
1192                         elsif ($line =~ /^e/) {
1193                                 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1194                                 if (defined $newhunk) {
1195                                         splice @hunk, $ix, 1, $newhunk;
1196                                 }
1197                         }
1198                         else {
1199                                 help_patch_cmd($other);
1200                                 next;
1201                         }
1202                         # soft increment
1203                         while (1) {
1204                                 $ix++;
1205                                 last if ($ix >= $num ||
1206                                          !defined $hunk[$ix]{USE});
1207                         }
1208                 }
1209         }
1210
1211         my $n_lofs = 0;
1212         my @result = ();
1213         if ($mode->{USE}) {
1214                 push @result, @{$mode->{TEXT}};
1215         }
1216         for (@hunk) {
1217                 if ($_->{USE}) {
1218                         push @result, @{$_->{TEXT}};
1219                 }
1220         }
1221
1222         if (@result) {
1223                 my $fh;
1224
1225                 open $fh, '| git apply --cached --recount';
1226                 for (@{$head->{TEXT}}, @result) {
1227                         print $fh $_;
1228                 }
1229                 if (!close $fh) {
1230                         for (@{$head->{TEXT}}, @result) {
1231                                 print STDERR $_;
1232                         }
1233                 }
1234                 refresh();
1235         }
1236
1237         print "\n";
1238 }
1239
1240 sub diff_cmd {
1241         my @mods = list_modified('index-only');
1242         @mods = grep { !($_->{BINARY}) } @mods;
1243         return if (!@mods);
1244         my (@them) = list_and_choose({ PROMPT => 'Review diff',
1245                                      IMMEDIATE => 1,
1246                                      HEADER => $status_head, },
1247                                    @mods);
1248         return if (!@them);
1249         my $reference = is_initial_commit() ? get_empty_tree() : 'HEAD';
1250         system(qw(git diff -p --cached), $reference, '--',
1251                 map { $_->{VALUE} } @them);
1252 }
1253
1254 sub quit_cmd {
1255         print "Bye.\n";
1256         exit(0);
1257 }
1258
1259 sub help_cmd {
1260         print colored $help_color, <<\EOF ;
1261 status        - show paths with changes
1262 update        - add working tree state to the staged set of changes
1263 revert        - revert staged set of changes back to the HEAD version
1264 patch         - pick hunks and update selectively
1265 diff          - view diff between HEAD and index
1266 add untracked - add contents of untracked files to the staged set of changes
1267 EOF
1268 }
1269
1270 sub process_args {
1271         return unless @ARGV;
1272         my $arg = shift @ARGV;
1273         if ($arg eq "--patch") {
1274                 $patch_mode = 1;
1275                 $arg = shift @ARGV or die "missing --";
1276                 die "invalid argument $arg, expecting --"
1277                     unless $arg eq "--";
1278         }
1279         elsif ($arg ne "--") {
1280                 die "invalid argument $arg, expecting --";
1281         }
1282 }
1283
1284 sub main_loop {
1285         my @cmd = ([ 'status', \&status_cmd, ],
1286                    [ 'update', \&update_cmd, ],
1287                    [ 'revert', \&revert_cmd, ],
1288                    [ 'add untracked', \&add_untracked_cmd, ],
1289                    [ 'patch', \&patch_update_cmd, ],
1290                    [ 'diff', \&diff_cmd, ],
1291                    [ 'quit', \&quit_cmd, ],
1292                    [ 'help', \&help_cmd, ],
1293         );
1294         while (1) {
1295                 my ($it) = list_and_choose({ PROMPT => 'What now',
1296                                              SINGLETON => 1,
1297                                              LIST_FLAT => 4,
1298                                              HEADER => '*** Commands ***',
1299                                              ON_EOF => \&quit_cmd,
1300                                              IMMEDIATE => 1 }, @cmd);
1301                 if ($it) {
1302                         eval {
1303                                 $it->[1]->();
1304                         };
1305                         if ($@) {
1306                                 print "$@";
1307                         }
1308                 }
1309         }
1310 }
1311
1312 process_args();
1313 refresh();
1314 if ($patch_mode) {
1315         patch_update_cmd();
1316 }
1317 else {
1318         status_cmd();
1319         main_loop();
1320 }