git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use File::Basename qw/dirname basename/;
  15 use File::Path qw/mkpath/;
  16 use File::Spec;
  17 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  18 use Memoize;
  19
  20 use Git::SVN;
  21 use Git::SVN::Editor;
  22 use Git::SVN::Fetcher;
  23 use Git::SVN::Ra;
  24 use Git::SVN::Prompt;
  25 use Git::SVN::Log;
  26 use Git::SVN::Migration;
  27
  28 use Git::SVN::Utils qw(
  29         fatal
  30         can_compress
  31         canonicalize_path
  32         canonicalize_url
  33         join_paths
  34         add_path_to_url
  35         join_paths
  36 );
  37
  38 use Git qw(
  39         git_cmd_try
  40         command
  41         command_oneline
  42         command_noisy
  43         command_output_pipe
  44         command_close_pipe
  45         command_bidi_pipe
  46         command_close_bidi_pipe
  47         get_record
  48 );
  49
  50 BEGIN {
  51         Memoize::memoize 'Git::config';
  52         Memoize::memoize 'Git::config_bool';
  53 }
  54
  55
  56 # From which subdir have we been invoked?
  57 my $cmd_dir_prefix = eval {
  58         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  59 } || '';
  60
  61 $Git::SVN::Ra::_log_window_size = 100;
  62
  63 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  64         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  65 }
  66
  67 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  68         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  69         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  70 }
  71
  72 $Git::SVN::Log::TZ = $ENV{TZ};
  73 $ENV{TZ} = 'UTC';
  74 $| = 1; # unbuffer STDOUT
  75
  76 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  77 # repository decides to close the connection which we expect to be kept alive.
  78 $SIG{PIPE} = 'IGNORE';
  79
  80 # Given a dot separated version number, "subtract" it from
  81 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  82 # is at least at the version the caller asked for.
  83 sub compare_svn_version {
  84         my (@ours) = split(/\./, $SVN::Core::VERSION);
  85         my (@theirs) = split(/\./, $_[0]);
  86         my ($i, $diff);
  87
  88         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  89                 $diff = $ours[$i] - $theirs[$i];
  90                 return $diff if ($diff);
  91         }
  92         return 1 if ($i < @ours);
  93         return -1 if ($i < @theirs);
  94         return 0;
  95 }
  96
  97 sub _req_svn {
  98         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  99         require SVN::Ra;
 100         require SVN::Delta;
 101         if (::compare_svn_version('1.1.0') < 0) {
 102                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 103         }
 104 }
 105
 106 $sha1 = qr/[a-f\d]{40}/;
 107 $sha1_short = qr/[a-f\d]{4,40}/;
 108 my ($_stdin, $_help, $_edit,
 109         $_message, $_file, $_branch_dest,
 110         $_template, $_shared,
 111         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 112         $_before, $_after,
 113         $_merge, $_strategy, $_rebase_merges, $_dry_run, $_parents, $_local,
 114         $_prefix, $_no_checkout, $_url, $_verbose,
 115         $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
 116
 117 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 118 sub opt_prefix { return $_prefix || '' }
 119
 120 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 121 $_q ||= 0;
 122 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 123                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 124                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 125                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 126                     'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 127                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 128 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 129                 'authors-file|A=s' => \$_authors,
 130                 'authors-prog=s' => \$_authors_prog,
 131                 'repack:i' => \$Git::SVN::_repack,
 132                 'noMetadata' => \$Git::SVN::_no_metadata,
 133                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 134                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 135                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 136                 'no-checkout' => \$_no_checkout,
 137                 'quiet|q+' => \$_q,
 138                 'repack-flags|repack-args|repack-opts=s' =>
 139                    \$Git::SVN::_repack_flags,
 140                 'use-log-author' => \$Git::SVN::_use_log_author,
 141                 'add-author-from' => \$Git::SVN::_add_author_from,
 142                 'localtime' => \$Git::SVN::_localtime,
 143                 %remote_opts );
 144
 145 my ($_trunk, @_tags, @_branches, $_stdlayout);
 146 my %icv;
 147 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 148                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 149                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 150                   'stdlayout|s' => \$_stdlayout,
 151                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 152                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 153                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 154                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 155                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 156                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 157                   %remote_opts );
 158 my %cmt_opts = ( 'edit|e' => \$_edit,
 159                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 160                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 161                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 162                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 163 );
 164
 165 my %cmd = (
 166         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 167                         { 'revision|r=s' => \$_revision,
 168                           'fetch-all|all' => \$_fetch_all,
 169                           'parent|p' => \$_fetch_parent,
 170                            %fc_opts } ],
 171         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 172                         { 'revision|r=s' => \$_revision,
 173                           'preserve-empty-dirs' =>
 174                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 175                           'placeholder-filename=s' =>
 176                                 \$Git::SVN::Fetcher::_placeholder_filename,
 177                            %fc_opts, %init_opts } ],
 178         init => [ \&cmd_init, "Initialize a repo for tracking" .
 179                           " (requires URL argument)",
 180                           \%init_opts ],
 181         'multi-init' => [ \&cmd_multi_init,
 182                           "Deprecated alias for ".
 183                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 184                           \%init_opts ],
 185         dcommit => [ \&cmd_dcommit,
 186                      'Commit several diffs to merge with upstream',
 187                         { 'merge|m|M' => \$_merge,
 188                           'strategy|s=s' => \$_strategy,
 189                           'verbose|v' => \$_verbose,
 190                           'dry-run|n' => \$_dry_run,
 191                           'fetch-all|all' => \$_fetch_all,
 192                           'commit-url=s' => \$_commit_url,
 193                           'set-svn-props=s' => \$_set_svn_props,
 194                           'revision|r=i' => \$_revision,
 195                           'no-rebase' => \$_no_rebase,
 196                           'mergeinfo=s' => \$_merge_info,
 197                           'interactive|i' => \$_interactive,
 198                         %cmt_opts, %fc_opts } ],
 199         branch => [ \&cmd_branch,
 200                     'Create a branch in the SVN repository',
 201                     { 'message|m=s' => \$_message,
 202                       'destination|d=s' => \$_branch_dest,
 203                       'dry-run|n' => \$_dry_run,
 204                       'parents' => \$_parents,
 205                       'tag|t' => \$_tag,
 206                       'username=s' => \$Git::SVN::Prompt::_username,
 207                       'commit-url=s' => \$_commit_url } ],
 208         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 209                  'Create a tag in the SVN repository',
 210                  { 'message|m=s' => \$_message,
 211                    'destination|d=s' => \$_branch_dest,
 212                    'dry-run|n' => \$_dry_run,
 213                    'parents' => \$_parents,
 214                    'username=s' => \$Git::SVN::Prompt::_username,
 215                    'commit-url=s' => \$_commit_url } ],
 216         'set-tree' => [ \&cmd_set_tree,
 217                         "Set an SVN repository to a git tree-ish",
 218                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 219         'create-ignore' => [ \&cmd_create_ignore,
 220                              'Create a .gitignore per svn:ignore',
 221                              { 'revision|r=i' => \$_revision
 222                              } ],
 223         'mkdirs' => [ \&cmd_mkdirs ,
 224                       "recreate empty directories after a checkout",
 225                       { 'revision|r=i' => \$_revision } ],
 226         'propget' => [ \&cmd_propget,
 227                        'Print the value of a property on a file or directory',
 228                        { 'revision|r=i' => \$_revision } ],
 229         'propset' => [ \&cmd_propset,
 230                        'Set the value of a property on a file or directory - will be set on commit',
 231                        {} ],
 232         'proplist' => [ \&cmd_proplist,
 233                        'List all properties of a file or directory',
 234                        { 'revision|r=i' => \$_revision } ],
 235         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 236                         { 'revision|r=i' => \$_revision
 237                         } ],
 238         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 239                         { 'revision|r=i' => \$_revision
 240                         } ],
 241         'multi-fetch' => [ \&cmd_multi_fetch,
 242                            "Deprecated alias for $0 fetch --all",
 243                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 244         'migrate' => [ sub { },
 245                        # no-op, we automatically run this anyways,
 246                        'Migrate configuration/metadata/layout from
 247                         previous versions of git-svn',
 248                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 249                          %remote_opts } ],
 250         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 251                         { 'limit=i' => \$Git::SVN::Log::limit,
 252                           'revision|r=s' => \$_revision,
 253                           'verbose|v' => \$Git::SVN::Log::verbose,
 254                           'incremental' => \$Git::SVN::Log::incremental,
 255                           'oneline' => \$Git::SVN::Log::oneline,
 256                           'show-commit' => \$Git::SVN::Log::show_commit,
 257                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 258                           'authors-file|A=s' => \$_authors,
 259                           'color' => \$Git::SVN::Log::color,
 260                           'pager=s' => \$Git::SVN::Log::pager
 261                         } ],
 262         'find-rev' => [ \&cmd_find_rev,
 263                         "Translate between SVN revision numbers and tree-ish",
 264                         { 'B|before' => \$_before,
 265                           'A|after' => \$_after } ],
 266         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 267                         { 'merge|m|M' => \$_merge,
 268                           'verbose|v' => \$_verbose,
 269                           'strategy|s=s' => \$_strategy,
 270                           'local|l' => \$_local,
 271                           'fetch-all|all' => \$_fetch_all,
 272                           'dry-run|n' => \$_dry_run,
 273                           'rebase-merges|p' => \$_rebase_merges,
 274                           'preserve-merges|p' => \$_rebase_merges,
 275                           %fc_opts } ],
 276         'commit-diff' => [ \&cmd_commit_diff,
 277                            'Commit a diff between two trees',
 278                         { 'message|m=s' => \$_message,
 279                           'file|F=s' => \$_file,
 280                           'revision|r=s' => \$_revision,
 281                         %cmt_opts } ],
 282         'info' => [ \&cmd_info,
 283                     "Show info about the latest SVN revision
 284                      on the current branch",
 285                     { 'url' => \$_url, } ],
 286         'blame' => [ \&Git::SVN::Log::cmd_blame,
 287                     "Show what revision and author last modified each line of a file",
 288                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 289         'reset' => [ \&cmd_reset,
 290                      "Undo fetches back to the specified SVN revision",
 291                      { 'revision|r=s' => \$_revision,
 292                        'parent|p' => \$_fetch_parent } ],
 293         'gc' => [ \&cmd_gc,
 294                   "Compress unhandled.log files in .git/svn and remove " .
 295                   "index files in .git/svn",
 296                 {} ],
 297 );
 298
 299 package FakeTerm;
 300 sub new {
 301         my ($class, $reason) = @_;
 302         return bless \$reason, shift;
 303 }
 304 sub readline {
 305         my $self = shift;
 306         die "Cannot use readline on FakeTerm: $$self";
 307 }
 308 package main;
 309
 310 my $term;
 311 sub term_init {
 312         $term = eval {
 313                 require Term::ReadLine;
 314                 $ENV{"GIT_SVN_NOTTY"}
 315                         ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 316                         : new Term::ReadLine 'git-svn';
 317         };
 318         if ($@) {
 319                 $term = new FakeTerm "$@: going non-interactive";
 320         }
 321 }
 322
 323 my $cmd;
 324 for (my $i = 0; $i < @ARGV; $i++) {
 325         if (defined $cmd{$ARGV[$i]}) {
 326                 $cmd = $ARGV[$i];
 327                 splice @ARGV, $i, 1;
 328                 last;
 329         } elsif ($ARGV[$i] eq 'help') {
 330                 $cmd = $ARGV[$i+1];
 331                 usage(0);
 332         }
 333 };
 334
 335 # make sure we're always running at the top-level working directory
 336 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 337         $ENV{GIT_DIR} ||= ".git";
 338         # catch the submodule case
 339         if (-f $ENV{GIT_DIR}) {
 340                 open(my $fh, '<', $ENV{GIT_DIR}) or
 341                         die "failed to open $ENV{GIT_DIR}: $!\n";
 342                 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
 343         }
 344 } elsif ($cmd) {
 345         my ($git_dir, $cdup);
 346         git_cmd_try {
 347                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 348         } "Unable to find .git directory\n";
 349         git_cmd_try {
 350                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 351                 chomp $cdup if ($cdup);
 352                 $cdup = "." unless ($cdup && length $cdup);
 353         } "Already at toplevel, but $git_dir not found\n";
 354         $ENV{GIT_DIR} = $git_dir;
 355         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 356         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 357 }
 358
 359 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 360
 361 read_git_config(\%opts) if $ENV{GIT_DIR};
 362 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 363         Getopt::Long::Configure('pass_through');
 364 }
 365 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 366                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 367                     'id|i=s' => \$Git::SVN::default_ref_id,
 368                     'svn-remote|remote|R=s' => sub {
 369                        $Git::SVN::no_reuse_existing = 1;
 370                        $Git::SVN::default_repo_id = $_[1] });
 371 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 372
 373 usage(0) if $_help;
 374 version() if $_version;
 375 usage(1) unless defined $cmd;
 376 load_authors() if $_authors;
 377 if (defined $_authors_prog) {
 378         my $abs_file = File::Spec->rel2abs($_authors_prog);
 379         $_authors_prog = "'" . $abs_file . "'" if -x $abs_file;
 380 }
 381
 382 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 383         Git::SVN::Migration::migration_check();
 384 }
 385 Git::SVN::init_vars();
 386 eval {
 387         Git::SVN::verify_remotes_sanity();
 388         $cmd{$cmd}->[0]->(@ARGV);
 389         post_fetch_checkout();
 390 };
 391 fatal $@ if $@;
 392 exit 0;
 393
 394 ####################### primary functions ######################
 395 sub usage {
 396         my $exit = shift || 0;
 397         my $fd = $exit ? \*STDERR : \*STDOUT;
 398         print $fd <<"";
 399 git-svn - bidirectional operations between a single Subversion tree and git
 400 usage: git svn <command> [options] [arguments]\n
 401
 402         print $fd "Available commands:\n" unless $cmd;
 403
 404         foreach (sort keys %cmd) {
 405                 next if $cmd && $cmd ne $_;
 406                 next if /^multi-/; # don't show deprecated commands
 407                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 408                 foreach (sort keys %{$cmd{$_}->[2]}) {
 409                         # mixed-case options are for .git/config only
 410                         next if /[A-Z]/ && /^[a-z]+$/i;
 411                         # prints out arguments as they should be passed:
 412                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 413                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 414                                                         "--$_" : "-$_" }
 415                                                 split /\|/,$_)," $x\n";
 416                 }
 417         }
 418         print $fd <<"";
 419 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 420 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 421 one git repository and want to keep them separate.  See git-svn(1) for more
 422 information.
 423
 424         exit $exit;
 425 }
 426
 427 sub version {
 428         ::_req_svn();
 429         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 430         exit 0;
 431 }
 432
 433 sub ask {
 434         my ($prompt, %arg) = @_;
 435         my $valid_re = $arg{valid_re};
 436         my $default = $arg{default};
 437         my $resp;
 438         my $i = 0;
 439         term_init() unless $term;
 440
 441         if ( !( defined($term->IN)
 442             && defined( fileno($term->IN) )
 443             && defined( $term->OUT )
 444             && defined( fileno($term->OUT) ) ) ){
 445                 return defined($default) ? $default : undef;
 446         }
 447
 448         while ($i++ < 10) {
 449                 $resp = $term->readline($prompt);
 450                 if (!defined $resp) { # EOF
 451                         print "\n";
 452                         return defined $default ? $default : undef;
 453                 }
 454                 if ($resp eq '' and defined $default) {
 455                         return $default;
 456                 }
 457                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 458                         return $resp;
 459                 }
 460         }
 461         return undef;
 462 }
 463
 464 sub do_git_init_db {
 465         unless (-d $ENV{GIT_DIR}) {
 466                 my @init_db = ('init');
 467                 push @init_db, "--template=$_template" if defined $_template;
 468                 if (defined $_shared) {
 469                         if ($_shared =~ /[a-z]/) {
 470                                 push @init_db, "--shared=$_shared";
 471                         } else {
 472                                 push @init_db, "--shared";
 473                         }
 474                 }
 475                 command_noisy(@init_db);
 476                 $_repository = Git->repository(Repository => ".git");
 477         }
 478         my $set;
 479         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 480         foreach my $i (keys %icv) {
 481                 die "'$set' and '$i' cannot both be set\n" if $set;
 482                 next unless defined $icv{$i};
 483                 command_noisy('config', "$pfx.$i", $icv{$i});
 484                 $set = $i;
 485         }
 486         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 487         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 488                 if defined $$ignore_paths_regex;
 489         my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 490         command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 491                 if defined $$include_paths_regex;
 492         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 493         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 494                 if defined $$ignore_refs_regex;
 495
 496         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 497                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 498                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 499                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 500         }
 501 }
 502
 503 sub init_subdir {
 504         my $repo_path = shift or return;
 505         mkpath([$repo_path]) unless -d $repo_path;
 506         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 507         $ENV{GIT_DIR} = '.git';
 508         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 509 }
 510
 511 sub cmd_clone {
 512         my ($url, $path) = @_;
 513         if (!$url) {
 514                 die "SVN repository location required ",
 515                     "as a command-line argument\n";
 516         } elsif (!defined $path &&
 517             (defined $_trunk || @_branches || @_tags ||
 518              defined $_stdlayout) &&
 519             $url !~ m#^[a-z\+]+://#) {
 520                 $path = $url;
 521         }
 522         $path = basename($url) if !defined $path || !length $path;
 523         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 524         cmd_init($url, $path);
 525         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 526             if $_authors;
 527         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 528 }
 529
 530 sub cmd_init {
 531         if (defined $_stdlayout) {
 532                 $_trunk = 'trunk' if (!defined $_trunk);
 533                 @_tags = 'tags' if (! @_tags);
 534                 @_branches = 'branches' if (! @_branches);
 535         }
 536         if (defined $_trunk || @_branches || @_tags) {
 537                 return cmd_multi_init(@_);
 538         }
 539         my $url = shift or die "SVN repository location required ",
 540                                "as a command-line argument\n";
 541         $url = canonicalize_url($url);
 542         init_subdir(@_);
 543         do_git_init_db();
 544
 545         if ($Git::SVN::_minimize_url eq 'unset') {
 546                 $Git::SVN::_minimize_url = 0;
 547         }
 548
 549         Git::SVN->init($url);
 550 }
 551
 552 sub cmd_fetch {
 553         if (grep /^\d+=./, @_) {
 554                 die "'<rev>=<commit>' fetch arguments are ",
 555                     "no longer supported.\n";
 556         }
 557         my ($remote) = @_;
 558         if (@_ > 1) {
 559                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 560         }
 561         $Git::SVN::no_reuse_existing = undef;
 562         if ($_fetch_parent) {
 563                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 564                 unless ($gs) {
 565                         die "Unable to determine upstream SVN information from ",
 566                             "working tree history\n";
 567                 }
 568                 # just fetch, don't checkout.
 569                 $_no_checkout = 'true';
 570                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 571         } elsif ($_fetch_all) {
 572                 cmd_multi_fetch();
 573         } else {
 574                 $remote ||= $Git::SVN::default_repo_id;
 575                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 576         }
 577 }
 578
 579 sub cmd_set_tree {
 580         my (@commits) = @_;
 581         if ($_stdin || !@commits) {
 582                 print "Reading from stdin...\n";
 583                 @commits = ();
 584                 while (<STDIN>) {
 585                         if (/\b($sha1_short)\b/o) {
 586                                 unshift @commits, $1;
 587                         }
 588                 }
 589         }
 590         my @revs;
 591         foreach my $c (@commits) {
 592                 my @tmp = command('rev-parse',$c);
 593                 if (scalar @tmp == 1) {
 594                         push @revs, $tmp[0];
 595                 } elsif (scalar @tmp > 1) {
 596                         push @revs, reverse(command('rev-list',@tmp));
 597                 } else {
 598                         fatal "Failed to rev-parse $c";
 599                 }
 600         }
 601         my $gs = Git::SVN->new;
 602         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 603         $gs->fetch;
 604         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 605                 fatal "There are new revisions that were fetched ",
 606                       "and need to be merged (or acknowledged) ",
 607                       "before committing.\nlast rev: $r_last\n",
 608                       " current: $gs->{last_rev}";
 609         }
 610         $gs->set_tree($_) foreach @revs;
 611         print "Done committing ",scalar @revs," revisions to SVN\n";
 612         unlink $gs->{index};
 613 }
 614
 615 sub split_merge_info_range {
 616         my ($range) = @_;
 617         if ($range =~ /(\d+)-(\d+)/) {
 618                 return (int($1), int($2));
 619         } else {
 620                 return (int($range), int($range));
 621         }
 622 }
 623
 624 sub combine_ranges {
 625         my ($in) = @_;
 626
 627         my @fnums = ();
 628         my @arr = split(/,/, $in);
 629         for my $element (@arr) {
 630                 my ($start, $end) = split_merge_info_range($element);
 631                 push @fnums, $start;
 632         }
 633
 634         my @sorted = @arr [ sort {
 635                 $fnums[$a] <=> $fnums[$b]
 636         } 0..$#arr ];
 637
 638         my @return = ();
 639         my $last = -1;
 640         my $first = -1;
 641         for my $element (@sorted) {
 642                 my ($start, $end) = split_merge_info_range($element);
 643
 644                 if ($last == -1) {
 645                         $first = $start;
 646                         $last = $end;
 647                         next;
 648                 }
 649                 if ($start <= $last+1) {
 650                         if ($end > $last) {
 651                                 $last = $end;
 652                         }
 653                         next;
 654                 }
 655                 if ($first == $last) {
 656                         push @return, "$first";
 657                 } else {
 658                         push @return, "$first-$last";
 659                 }
 660                 $first = $start;
 661                 $last = $end;
 662         }
 663
 664         if ($first != -1) {
 665                 if ($first == $last) {
 666                         push @return, "$first";
 667                 } else {
 668                         push @return, "$first-$last";
 669                 }
 670         }
 671
 672         return join(',', @return);
 673 }
 674
 675 sub merge_revs_into_hash {
 676         my ($hash, $minfo) = @_;
 677         my @lines = split(' ', $minfo);
 678
 679         for my $line (@lines) {
 680                 my ($branchpath, $revs) = split(/:/, $line);
 681
 682                 if (exists($hash->{$branchpath})) {
 683                         # Merge the two revision sets
 684                         my $combined = "$hash->{$branchpath},$revs";
 685                         $hash->{$branchpath} = combine_ranges($combined);
 686                 } else {
 687                         # Just do range combining for consolidation
 688                         $hash->{$branchpath} = combine_ranges($revs);
 689                 }
 690         }
 691 }
 692
 693 sub merge_merge_info {
 694         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 695         my %result_hash = ();
 696
 697         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 698         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 699
 700         delete $result_hash{$ignore_branch} if $ignore_branch;
 701
 702         my $result = '';
 703         # Sort below is for consistency's sake
 704         for my $branchname (sort keys(%result_hash)) {
 705                 my $revlist = $result_hash{$branchname};
 706                 $result .= "$branchname:$revlist\n"
 707         }
 708         return $result;
 709 }
 710
 711 sub populate_merge_info {
 712         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 713
 714         my %parentshash;
 715         read_commit_parents(\%parentshash, $d);
 716         my @parents = @{$parentshash{$d}};
 717         if ($#parents > 0) {
 718                 # Merge commit
 719                 my $all_parents_ok = 1;
 720                 my $aggregate_mergeinfo = '';
 721                 my $rooturl = $gs->repos_root;
 722                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 723
 724                 if (defined($rewritten_parent)) {
 725                         # Replace first parent with newly-rewritten version
 726                         shift @parents;
 727                         unshift @parents, $rewritten_parent;
 728                 }
 729
 730                 foreach my $parent (@parents) {
 731                         my ($branchurl, $svnrev, $paruuid) =
 732                                 cmt_metadata($parent);
 733
 734                         unless (defined($svnrev)) {
 735                                 # Should have been caught be preflight check
 736                                 fatal "merge commit $d has ancestor $parent, but that change "
 737                      ."does not have git-svn metadata!";
 738                         }
 739                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 740                                 fatal "commit $parent git-svn metadata changed mid-run!";
 741                         }
 742                         my $branchpath = $1;
 743
 744                         my $ra = Git::SVN::Ra->new($branchurl);
 745                         my (undef, undef, $props) =
 746                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 747                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 748                         unless (defined $par_mergeinfo) {
 749                                 $par_mergeinfo = '';
 750                         }
 751                         # Merge previous mergeinfo values
 752                         $aggregate_mergeinfo =
 753                                 merge_merge_info($aggregate_mergeinfo,
 754                                                                 $par_mergeinfo,
 755                                                                 $target_branch);
 756
 757                         next if $parent eq $parents[0]; # Skip first parent
 758                         # Add new changes being placed in tree by merge
 759                         my @cmd = (qw/rev-list --reverse/,
 760                                            $parent, qw/--not/);
 761                         foreach my $par (@parents) {
 762                                 unless ($par eq $parent) {
 763                                         push @cmd, $par;
 764                                 }
 765                         }
 766                         my @revsin = ();
 767                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 768                         while (<$revlist>) {
 769                                 my $irev = $_;
 770                                 chomp $irev;
 771                                 my (undef, $csvnrev, undef) =
 772                                         cmt_metadata($irev);
 773                                 unless (defined $csvnrev) {
 774                                         # A child is missing SVN annotations...
 775                                         # this might be OK, or might not be.
 776                                         warn "W:child $irev is merged into revision "
 777                                                  ."$d but does not have git-svn metadata. "
 778                                                  ."This means git-svn cannot determine the "
 779                                                  ."svn revision numbers to place into the "
 780                                                  ."svn:mergeinfo property. You must ensure "
 781                                                  ."a branch is entirely committed to "
 782                                                  ."SVN before merging it in order for "
 783                                                  ."svn:mergeinfo population to function "
 784                                                  ."properly";
 785                                 }
 786                                 push @revsin, $csvnrev;
 787                         }
 788                         command_close_pipe($revlist, $ctx);
 789
 790                         last unless $all_parents_ok;
 791
 792                         # We now have a list of all SVN revnos which are
 793                         # merged by this particular parent. Integrate them.
 794                         next if $#revsin == -1;
 795                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 796                         $aggregate_mergeinfo =
 797                                 merge_merge_info($aggregate_mergeinfo,
 798                                                                 $newmergeinfo,
 799                                                                 $target_branch);
 800                 }
 801                 if ($all_parents_ok and $aggregate_mergeinfo) {
 802                         return $aggregate_mergeinfo;
 803                 }
 804         }
 805
 806         return undef;
 807 }
 808
 809 sub dcommit_rebase {
 810         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 811         my @diff;
 812
 813         if ($svn_error) {
 814                 print STDERR "\nERROR from SVN:\n",
 815                                 $svn_error->expanded_message, "\n";
 816         }
 817         unless ($_no_rebase) {
 818                 # we always want to rebase against the current HEAD,
 819                 # not any head that was passed to us
 820                 @diff = command('diff-tree', $current,
 821                            $fetched_ref, '--');
 822                 my @finish;
 823                 if (@diff) {
 824                         @finish = rebase_cmd();
 825                         print STDERR "W: $current and ", $fetched_ref,
 826                                      " differ, using @finish:\n",
 827                                      join("\n", @diff), "\n";
 828                 } elsif ($is_last) {
 829                         print "No changes between ", $current, " and ",
 830                               $fetched_ref,
 831                               "\nResetting to the latest ",
 832                               $fetched_ref, "\n";
 833                         @finish = qw/reset --mixed/;
 834                 }
 835                 command_noisy(@finish, $fetched_ref) if @finish;
 836         }
 837         if ($svn_error) {
 838                 die "ERROR: Not all changes have been committed into SVN"
 839                         .($_no_rebase ? ".\n" : ", however the committed\n"
 840                         ."ones (if any) seem to be successfully integrated "
 841                         ."into the working tree.\n")
 842                         ."Please see the above messages for details.\n";
 843         }
 844         return @diff;
 845 }
 846
 847 sub cmd_dcommit {
 848         my $head = shift;
 849         command_noisy(qw/update-index --refresh/);
 850         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 851                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 852                 . "or stash them with `git stash'.\n";
 853         $head ||= 'HEAD';
 854
 855         my $old_head;
 856         if ($head ne 'HEAD') {
 857                 $old_head = eval {
 858                         command_oneline([qw/symbolic-ref -q HEAD/])
 859                 };
 860                 if ($old_head) {
 861                         $old_head =~ s{^refs/heads/}{};
 862                 } else {
 863                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 864                 }
 865                 command(['checkout', $head], STDERR => 0);
 866         }
 867
 868         my @refs;
 869         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 870         unless ($gs) {
 871                 die "Unable to determine upstream SVN information from ",
 872                     "$head history.\nPerhaps the repository is empty.";
 873         }
 874
 875         if (defined $_commit_url) {
 876                 $url = $_commit_url;
 877         } else {
 878                 $url = eval { command_oneline('config', '--get',
 879                               "svn-remote.$gs->{repo_id}.commiturl") };
 880                 if (!$url) {
 881                         $url = $gs->full_pushurl
 882                 }
 883         }
 884
 885         my $last_rev = $_revision if defined $_revision;
 886         if ($url) {
 887                 print "Committing to $url ...\n";
 888         }
 889         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 890         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 891                 warn "Attempting to commit more than one change while ",
 892                      "--no-rebase is enabled.\n",
 893                      "If these changes depend on each other, re-running ",
 894                      "without --no-rebase may be required."
 895         }
 896
 897         if (defined $_interactive){
 898                 my $ask_default = "y";
 899                 foreach my $d (@$linear_refs){
 900                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 901                         while (<$fh>){
 902                                 print $_;
 903                         }
 904                         command_close_pipe($fh, $ctx);
 905                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 906                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 907                                  default => $ask_default);
 908                         die "Commit this patch reply required" unless defined $_;
 909                         if (/^[nq]/i) {
 910                                 exit(0);
 911                         } elsif (/^a/i) {
 912                                 last;
 913                         }
 914                 }
 915         }
 916
 917         my $expect_url = $url;
 918
 919         my $push_merge_info = eval {
 920                 command_oneline(qw/config --get svn.pushmergeinfo/)
 921                 };
 922         if (not defined($push_merge_info)
 923                         or $push_merge_info eq "false"
 924                         or $push_merge_info eq "no"
 925                         or $push_merge_info eq "never") {
 926                 $push_merge_info = 0;
 927         }
 928
 929         unless (defined($_merge_info) || ! $push_merge_info) {
 930                 # Preflight check of changes to ensure no issues with mergeinfo
 931                 # This includes check for uncommitted-to-SVN parents
 932                 # (other than the first parent, which we will handle),
 933                 # information from different SVN repos, and paths
 934                 # which are not underneath this repository root.
 935                 my $rooturl = $gs->repos_root;
 936                 Git::SVN::remove_username($rooturl);
 937                 foreach my $d (@$linear_refs) {
 938                         my %parentshash;
 939                         read_commit_parents(\%parentshash, $d);
 940                         my @realparents = @{$parentshash{$d}};
 941                         if ($#realparents > 0) {
 942                                 # Merge commit
 943                                 shift @realparents; # Remove/ignore first parent
 944                                 foreach my $parent (@realparents) {
 945                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 946                                         unless (defined $paruuid) {
 947                                                 # A parent is missing SVN annotations...
 948                                                 # abort the whole operation.
 949                                                 fatal "$parent is merged into revision $d, "
 950                                                          ."but does not have git-svn metadata. "
 951                                                          ."Either dcommit the branch or use a "
 952                                                          ."local cherry-pick, FF merge, or rebase "
 953                                                          ."instead of an explicit merge commit.";
 954                                         }
 955
 956                                         unless ($paruuid eq $uuid) {
 957                                                 # Parent has SVN metadata from different repository
 958                                                 fatal "merge parent $parent for change $d has "
 959                                                          ."git-svn uuid $paruuid, while current change "
 960                                                          ."has uuid $uuid!";
 961                                         }
 962
 963                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 964                                                 # This branch is very strange indeed.
 965                                                 fatal "merge parent $parent for $d is on branch "
 966                                                          ."$branchurl, which is not under the "
 967                                                          ."git-svn root $rooturl!";
 968                                         }
 969                                 }
 970                         }
 971                 }
 972         }
 973
 974         my $rewritten_parent;
 975         my $current_head = command_oneline(qw/rev-parse HEAD/);
 976         Git::SVN::remove_username($expect_url);
 977         if (defined($_merge_info)) {
 978                 $_merge_info =~ tr{ }{\n};
 979         }
 980         while (1) {
 981                 my $d = shift @$linear_refs or last;
 982                 unless (defined $last_rev) {
 983                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 984                         unless (defined $last_rev) {
 985                                 fatal "Unable to extract revision information ",
 986                                       "from commit $d~1";
 987                         }
 988                 }
 989                 if ($_dry_run) {
 990                         print "diff-tree $d~1 $d\n";
 991                 } else {
 992                         my $cmt_rev;
 993
 994                         unless (defined($_merge_info) || ! $push_merge_info) {
 995                                 $_merge_info = populate_merge_info($d, $gs,
 996                                                              $uuid,
 997                                                              $linear_refs,
 998                                                              $rewritten_parent);
 999                         }
1000
1001                         my %ed_opts = ( r => $last_rev,
1002                                         log => get_commit_entry($d)->{log},
1003                                         ra => Git::SVN::Ra->new($url),
1004                                         config => SVN::Core::config_get_config(
1005                                                 $Git::SVN::Ra::config_dir
1006                                         ),
1007                                         tree_a => "$d~1",
1008                                         tree_b => $d,
1009                                         editor_cb => sub {
1010                                                print "Committed r$_[0]\n";
1011                                                $cmt_rev = $_[0];
1012                                         },
1013                                         mergeinfo => $_merge_info,
1014                                         svn_path => '');
1015
1016                         my $err_handler = $SVN::Error::handler;
1017                         $SVN::Error::handler = sub {
1018                                 my $err = shift;
1019                                 dcommit_rebase(1, $current_head, $gs->refname,
1020                                         $err);
1021                         };
1022
1023                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1024                                 print "No changes\n$d~1 == $d\n";
1025                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1026                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1027                                                                $parents->{$d};
1028                         }
1029                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1030                         $SVN::Error::handler = $err_handler;
1031                         $last_rev = $cmt_rev;
1032                         next if $_no_rebase;
1033
1034                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1035                                                 $gs->refname, undef);
1036
1037                         $rewritten_parent = command_oneline(qw/rev-parse/,
1038                                                         $gs->refname);
1039
1040                         if (@diff) {
1041                                 $current_head = command_oneline(qw/rev-parse
1042                                                                 HEAD/);
1043                                 @refs = ();
1044                                 my ($url_, $rev_, $uuid_, $gs_) =
1045                                               working_head_info('HEAD', \@refs);
1046                                 my ($linear_refs_, $parents_) =
1047                                               linearize_history($gs_, \@refs);
1048                                 if (scalar(@$linear_refs) !=
1049                                     scalar(@$linear_refs_)) {
1050                                         fatal "# of revisions changed ",
1051                                           "\nbefore:\n",
1052                                           join("\n", @$linear_refs),
1053                                           "\n\nafter:\n",
1054                                           join("\n", @$linear_refs_), "\n",
1055                                           'If you are attempting to commit ',
1056                                           "merges, try running:\n\t",
1057                                           'git rebase --interactive',
1058                                           '--rebase-merges ',
1059                                           $gs->refname,
1060                                           "\nBefore dcommitting";
1061                                 }
1062                                 if ($url_ ne $expect_url) {
1063                                         if ($url_ eq $gs->metadata_url) {
1064                                                 print
1065                                                   "Accepting rewritten URL:",
1066                                                   " $url_\n";
1067                                         } else {
1068                                                 fatal
1069                                                   "URL mismatch after rebase:",
1070                                                   " $url_ != $expect_url";
1071                                         }
1072                                 }
1073                                 if ($uuid_ ne $uuid) {
1074                                         fatal "uuid mismatch after rebase: ",
1075                                               "$uuid_ != $uuid";
1076                                 }
1077                                 # remap parents
1078                                 my (%p, @l, $i);
1079                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1080                                         my $new = $linear_refs_->[$i] or next;
1081                                         $p{$new} =
1082                                                 $parents->{$linear_refs->[$i]};
1083                                         push @l, $new;
1084                                 }
1085                                 $parents = \%p;
1086                                 $linear_refs = \@l;
1087                                 undef $last_rev;
1088                         }
1089                 }
1090         }
1091
1092         if ($old_head) {
1093                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1094                 my $new_is_symbolic = eval {
1095                         command_oneline(qw/symbolic-ref -q HEAD/);
1096                 };
1097                 if ($new_is_symbolic) {
1098                         print "dcommitted the branch ", $head, "\n";
1099                 } else {
1100                         print "dcommitted on a detached HEAD because you gave ",
1101                               "a revision argument.\n",
1102                               "The rewritten commit is: ", $new_head, "\n";
1103                 }
1104                 command(['checkout', $old_head], STDERR => 0);
1105         }
1106
1107         unlink $gs->{index};
1108 }
1109
1110 sub cmd_branch {
1111         my ($branch_name, $head) = @_;
1112
1113         unless (defined $branch_name && length $branch_name) {
1114                 die(($_tag ? "tag" : "branch") . " name required\n");
1115         }
1116         $head ||= 'HEAD';
1117
1118         my (undef, $rev, undef, $gs) = working_head_info($head);
1119         my $src = $gs->full_pushurl;
1120
1121         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1122         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1123         my $glob;
1124         if ($#{$allglobs} == 0) {
1125                 $glob = $allglobs->[0];
1126         } else {
1127                 unless(defined $_branch_dest) {
1128                         die "Multiple ",
1129                             $_tag ? "tag" : "branch",
1130                             " paths defined for Subversion repository.\n",
1131                             "You must specify where you want to create the ",
1132                             $_tag ? "tag" : "branch",
1133                             " with the --destination argument.\n";
1134                 }
1135                 foreach my $g (@{$allglobs}) {
1136                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1137                         if ($_branch_dest =~ /$re/) {
1138                                 $glob = $g;
1139                                 last;
1140                         }
1141                 }
1142                 unless (defined $glob) {
1143                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1144                         foreach my $g (@{$allglobs}) {
1145                                 $g->{path}->{left} =~ /$dest_re/ or next;
1146                                 if (defined $glob) {
1147                                         die "Ambiguous destination: ",
1148                                             $_branch_dest, "\nmatches both '",
1149                                             $glob->{path}->{left}, "' and '",
1150                                             $g->{path}->{left}, "'\n";
1151                                 }
1152                                 $glob = $g;
1153                         }
1154                         unless (defined $glob) {
1155                                 die "Unknown ",
1156                                     $_tag ? "tag" : "branch",
1157                                     " destination $_branch_dest\n";
1158                         }
1159                 }
1160         }
1161         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1162         my $url;
1163         if (defined $_commit_url) {
1164                 $url = $_commit_url;
1165         } else {
1166                 $url = eval { command_oneline('config', '--get',
1167                         "svn-remote.$gs->{repo_id}.commiturl") };
1168                 if (!$url) {
1169                         $url = $remote->{pushurl} || $remote->{url};
1170                 }
1171         }
1172         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1173
1174         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1175                 $src=~s/^http:/https:/;
1176         }
1177
1178         ::_req_svn();
1179         require SVN::Client;
1180
1181         my ($config, $baton, undef) = Git::SVN::Ra::prepare_config_once();
1182         my $ctx = SVN::Client->new(
1183                 auth => $baton,
1184                 config => $config,
1185                 log_msg => sub {
1186                         ${ $_[0] } = defined $_message
1187                                 ? $_message
1188                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1189                                 . $branch_name;
1190                 },
1191         );
1192
1193         eval {
1194                 $ctx->ls($dst, 'HEAD', 0);
1195         } and die "branch ${branch_name} already exists\n";
1196
1197         if ($_parents) {
1198                 mk_parent_dirs($ctx, $dst);
1199         }
1200
1201         print "Copying ${src} at r${rev} to ${dst}...\n";
1202         $ctx->copy($src, $rev, $dst)
1203                 unless $_dry_run;
1204
1205         # Release resources held by ctx before creating another SVN::Ra
1206         # so destruction is orderly.  This seems necessary with SVN 1.9.5
1207         # to avoid segfaults.
1208         $ctx = undef;
1209
1210         $gs->fetch_all;
1211 }
1212
1213 sub mk_parent_dirs {
1214         my ($ctx, $parent) = @_;
1215         $parent =~ s{/[^/]*$}{};
1216
1217         if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1218                 mk_parent_dirs($ctx, $parent);
1219                 print "Creating parent folder ${parent} ...\n";
1220                 $ctx->mkdir($parent) unless $_dry_run;
1221         }
1222 }
1223
1224 sub cmd_find_rev {
1225         my $revision_or_hash = shift or die "SVN or git revision required ",
1226                                             "as a command-line argument\n";
1227         my $result;
1228         if ($revision_or_hash =~ /^r\d+$/) {
1229                 my $head = shift;
1230                 $head ||= 'HEAD';
1231                 my @refs;
1232                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1233                 unless ($gs) {
1234                         die "Unable to determine upstream SVN information from ",
1235                             "$head history\n";
1236                 }
1237                 my $desired_revision = substr($revision_or_hash, 1);
1238                 if ($_before) {
1239                         $result = $gs->find_rev_before($desired_revision, 1);
1240                 } elsif ($_after) {
1241                         $result = $gs->find_rev_after($desired_revision, 1);
1242                 } else {
1243                         $result = $gs->rev_map_get($desired_revision, $uuid);
1244                 }
1245         } else {
1246                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1247                 $result = $rev;
1248         }
1249         print "$result\n" if $result;
1250 }
1251
1252 sub auto_create_empty_directories {
1253         my ($gs) = @_;
1254         my $var = eval { command_oneline('config', '--get', '--bool',
1255                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1256         # By default, create empty directories by consulting the unhandled log,
1257         # but allow setting it to 'false' to skip it.
1258         return !($var && $var eq 'false');
1259 }
1260
1261 sub cmd_rebase {
1262         command_noisy(qw/update-index --refresh/);
1263         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1264         unless ($gs) {
1265                 die "Unable to determine upstream SVN information from ",
1266                     "working tree history\n";
1267         }
1268         if ($_dry_run) {
1269                 print "Remote Branch: " . $gs->refname . "\n";
1270                 print "SVN URL: " . $url . "\n";
1271                 return;
1272         }
1273         if (command(qw/diff-index HEAD --/)) {
1274                 print STDERR "Cannot rebase with uncommitted changes:\n";
1275                 command_noisy('status');
1276                 exit 1;
1277         }
1278         unless ($_local) {
1279                 # rebase will checkout for us, so no need to do it explicitly
1280                 $_no_checkout = 'true';
1281                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1282         }
1283         command_noisy(rebase_cmd(), $gs->refname);
1284         if (auto_create_empty_directories($gs)) {
1285                 $gs->mkemptydirs;
1286         }
1287 }
1288
1289 sub cmd_show_ignore {
1290         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1291         $gs ||= Git::SVN->new;
1292         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1293         $gs->prop_walk($gs->path, $r, sub {
1294                 my ($gs, $path, $props) = @_;
1295                 print STDOUT "\n# $path\n";
1296                 my $s = $props->{'svn:ignore'} or return;
1297                 $s =~ s/[\r\n]+/\n/g;
1298                 $s =~ s/^\n+//;
1299                 chomp $s;
1300                 $s =~ s#^#$path#gm;
1301                 print STDOUT "$s\n";
1302         });
1303 }
1304
1305 sub cmd_show_externals {
1306         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1307         $gs ||= Git::SVN->new;
1308         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1309         $gs->prop_walk($gs->path, $r, sub {
1310                 my ($gs, $path, $props) = @_;
1311                 print STDOUT "\n# $path\n";
1312                 my $s = $props->{'svn:externals'} or return;
1313                 $s =~ s/[\r\n]+/\n/g;
1314                 chomp $s;
1315                 $s =~ s#^#$path#gm;
1316                 print STDOUT "$s\n";
1317         });
1318 }
1319
1320 sub cmd_create_ignore {
1321         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1322         $gs ||= Git::SVN->new;
1323         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1324         $gs->prop_walk($gs->path, $r, sub {
1325                 my ($gs, $path, $props) = @_;
1326                 # $path is of the form /path/to/dir/
1327                 $path = '.' . $path;
1328                 # SVN can have attributes on empty directories,
1329                 # which git won't track
1330                 mkpath([$path]) unless -d $path;
1331                 my $ignore = $path . '.gitignore';
1332                 my $s = $props->{'svn:ignore'} or return;
1333                 open(GITIGNORE, '>', $ignore)
1334                   or fatal("Failed to open `$ignore' for writing: $!");
1335                 $s =~ s/[\r\n]+/\n/g;
1336                 $s =~ s/^\n+//;
1337                 chomp $s;
1338                 # Prefix all patterns so that the ignore doesn't apply
1339                 # to sub-directories.
1340                 $s =~ s#^#/#gm;
1341                 print GITIGNORE "$s\n";
1342                 close(GITIGNORE)
1343                   or fatal("Failed to close `$ignore': $!");
1344                 command_noisy('add', '-f', $ignore);
1345         });
1346 }
1347
1348 sub cmd_mkdirs {
1349         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1350         $gs ||= Git::SVN->new;
1351         $gs->mkemptydirs($_revision);
1352 }
1353
1354 # get_svnprops(PATH)
1355 # ------------------
1356 # Helper for cmd_propget and cmd_proplist below.
1357 sub get_svnprops {
1358         my $path = shift;
1359         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1360         $gs ||= Git::SVN->new;
1361
1362         # prefix THE PATH by the sub-directory from which the user
1363         # invoked us.
1364         $path = $cmd_dir_prefix . $path;
1365         fatal("No such file or directory: $path") unless -e $path;
1366         my $is_dir = -d $path ? 1 : 0;
1367         $path = join_paths($gs->path, $path);
1368
1369         # canonicalize the path (otherwise libsvn will abort or fail to
1370         # find the file)
1371         $path = canonicalize_path($path);
1372
1373         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1374         my $props;
1375         if ($is_dir) {
1376                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1377         }
1378         else {
1379                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1380         }
1381         return $props;
1382 }
1383
1384 # cmd_propget (PROP, PATH)
1385 # ------------------------
1386 # Print the SVN property PROP for PATH.
1387 sub cmd_propget {
1388         my ($prop, $path) = @_;
1389         $path = '.' if not defined $path;
1390         usage(1) if not defined $prop;
1391         my $props = get_svnprops($path);
1392         if (not defined $props->{$prop}) {
1393                 fatal("`$path' does not have a `$prop' SVN property.");
1394         }
1395         print $props->{$prop} . "\n";
1396 }
1397
1398 # cmd_propset (PROPNAME, PROPVAL, PATH)
1399 # ------------------------
1400 # Adjust the SVN property PROPNAME to PROPVAL for PATH.
1401 sub cmd_propset {
1402         my ($propname, $propval, $path) = @_;
1403         $path = '.' if not defined $path;
1404         $path = $cmd_dir_prefix . $path;
1405         usage(1) if not defined $propname;
1406         usage(1) if not defined $propval;
1407         my $file = basename($path);
1408         my $dn = dirname($path);
1409         my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1410         my @new_props;
1411         if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1412                 push @new_props, "$propname=$propval";
1413         } else {
1414                 # TODO: handle combining properties better
1415                 my @props = split(/;/, $cur_props);
1416                 my $replaced_prop;
1417                 foreach my $prop (@props) {
1418                         # Parse 'name=value' syntax and set the property.
1419                         if ($prop =~ /([^=]+)=(.*)/) {
1420                                 my ($n,$v) = ($1,$2);
1421                                 if ($n eq $propname) {
1422                                         $v = $propval;
1423                                         $replaced_prop = 1;
1424                                 }
1425                                 push @new_props, "$n=$v";
1426                         }
1427                 }
1428                 if (!$replaced_prop) {
1429                         push @new_props, "$propname=$propval";
1430                 }
1431         }
1432         my $attrfile = "$dn/.gitattributes";
1433         open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1434         # TODO: don't simply append here if $file already has svn-properties
1435         my $new_props = join(';', @new_props);
1436         print $attrfh "$file svn-properties=$new_props\n" or
1437                 die "write to $attrfile: $!\n";
1438         close $attrfh or die "close $attrfile: $!\n";
1439 }
1440
1441 # cmd_proplist (PATH)
1442 # -------------------
1443 # Print the list of SVN properties for PATH.
1444 sub cmd_proplist {
1445         my $path = shift;
1446         $path = '.' if not defined $path;
1447         my $props = get_svnprops($path);
1448         print "Properties on '$path':\n";
1449         foreach (sort keys %{$props}) {
1450                 print "  $_\n";
1451         }
1452 }
1453
1454 sub cmd_multi_init {
1455         my $url = shift;
1456         unless (defined $_trunk || @_branches || @_tags) {
1457                 usage(1);
1458         }
1459
1460         $_prefix = 'origin/' unless defined $_prefix;
1461         if (defined $url) {
1462                 $url = canonicalize_url($url);
1463                 init_subdir(@_);
1464         }
1465         do_git_init_db();
1466         if (defined $_trunk) {
1467                 $_trunk =~ s#^/+##;
1468                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1469                 # try both old-style and new-style lookups:
1470                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1471                 unless ($gs_trunk) {
1472                         my ($trunk_url, $trunk_path) =
1473                                               complete_svn_url($url, $_trunk);
1474                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1475                                                    undef, $trunk_ref);
1476                 }
1477         }
1478         return unless @_branches || @_tags;
1479         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1480         foreach my $path (@_branches) {
1481                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1482         }
1483         foreach my $path (@_tags) {
1484                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1485         }
1486 }
1487
1488 sub cmd_multi_fetch {
1489         $Git::SVN::no_reuse_existing = undef;
1490         my $remotes = Git::SVN::read_all_remotes();
1491         foreach my $repo_id (sort keys %$remotes) {
1492                 if ($remotes->{$repo_id}->{url}) {
1493                         Git::SVN::fetch_all($repo_id, $remotes);
1494                 }
1495         }
1496 }
1497
1498 # this command is special because it requires no metadata
1499 sub cmd_commit_diff {
1500         my ($ta, $tb, $url) = @_;
1501         my $usage = "usage: $0 commit-diff -r<revision> ".
1502                     "<tree-ish> <tree-ish> [<URL>]";
1503         fatal($usage) if (!defined $ta || !defined $tb);
1504         my $svn_path = '';
1505         if (!defined $url) {
1506                 my $gs = eval { Git::SVN->new };
1507                 if (!$gs) {
1508                         fatal("Needed URL or usable git-svn --id in ",
1509                               "the command-line\n", $usage);
1510                 }
1511                 $url = $gs->url;
1512                 $svn_path = $gs->path;
1513         }
1514         unless (defined $_revision) {
1515                 fatal("-r|--revision is a required argument\n", $usage);
1516         }
1517         if (defined $_message && defined $_file) {
1518                 fatal("Both --message/-m and --file/-F specified ",
1519                       "for the commit message.\n",
1520                       "I have no idea what you mean");
1521         }
1522         if (defined $_file) {
1523                 $_message = file_to_s($_file);
1524         } else {
1525                 $_message ||= get_commit_entry($tb)->{log};
1526         }
1527         my $ra ||= Git::SVN::Ra->new($url);
1528         my $r = $_revision;
1529         if ($r eq 'HEAD') {
1530                 $r = $ra->get_latest_revnum;
1531         } elsif ($r !~ /^\d+$/) {
1532                 die "revision argument: $r not understood by git-svn\n";
1533         }
1534         my %ed_opts = ( r => $r,
1535                         log => $_message,
1536                         ra => $ra,
1537                         tree_a => $ta,
1538                         tree_b => $tb,
1539                         editor_cb => sub { print "Committed r$_[0]\n" },
1540                         svn_path => $svn_path );
1541         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1542                 print "No changes\n$ta == $tb\n";
1543         }
1544 }
1545
1546 sub cmd_info {
1547         my $path_arg = defined($_[0]) ? $_[0] : '.';
1548         my $path = $path_arg;
1549         if (File::Spec->file_name_is_absolute($path)) {
1550                 $path = canonicalize_path($path);
1551
1552                 my $toplevel = eval {
1553                         my @cmd = qw/rev-parse --show-toplevel/;
1554                         command_oneline(\@cmd, STDERR => 0);
1555                 };
1556
1557                 # remove $toplevel from the absolute path:
1558                 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1559                 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1560                 my @dirs = File::Spec->splitdir($dirs);
1561                 my @tdirs = File::Spec->splitdir($tdirs);
1562                 pop @dirs if $dirs[-1] eq '';
1563                 pop @tdirs if $tdirs[-1] eq '';
1564                 push @dirs, $file;
1565                 push @tdirs, $tfile;
1566                 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1567                         shift @dirs;
1568                         shift @tdirs;
1569                 }
1570                 $dirs = File::Spec->catdir(@dirs);
1571                 $path = File::Spec->catpath($vol, $dirs);
1572
1573                 $path = canonicalize_path($path);
1574         } else {
1575                 $path = canonicalize_path($cmd_dir_prefix . $path);
1576         }
1577         if (exists $_[1]) {
1578                 die "Too many arguments specified\n";
1579         }
1580
1581         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1582
1583         if (!$file_type && !$diff_status) {
1584                 print STDERR "svn: '$path' is not under version control\n";
1585                 exit 1;
1586         }
1587
1588         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1589         unless ($gs) {
1590                 die "Unable to determine upstream SVN information from ",
1591                     "working tree history\n";
1592         }
1593
1594         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1595         $path = "." if $path eq "";
1596
1597         my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1598
1599         if ($_url) {
1600                 print "$full_url\n";
1601                 return;
1602         }
1603
1604         my $result = "Path: $path_arg\n";
1605         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1606         $result .= "URL: $full_url\n";
1607
1608         eval {
1609                 my $repos_root = $gs->repos_root;
1610                 Git::SVN::remove_username($repos_root);
1611                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1612         };
1613         if ($@) {
1614                 $result .= "Repository Root: (offline)\n";
1615         }
1616         ::_req_svn();
1617         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1618                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1619         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1620
1621         $result .= "Node Kind: " .
1622                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1623
1624         my $schedule = $diff_status eq "A"
1625                        ? "add"
1626                        : ($diff_status eq "D" ? "delete" : "normal");
1627         $result .= "Schedule: $schedule\n";
1628
1629         if ($diff_status eq "A") {
1630                 print $result, "\n";
1631                 return;
1632         }
1633
1634         my ($lc_author, $lc_rev, $lc_date_utc);
1635         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1636         my $log = command_output_pipe(@args);
1637         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1638         while (<$log>) {
1639                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1640                         $lc_author = $1;
1641                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1642                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1643                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1644                 }
1645         }
1646         close $log;
1647
1648         Git::SVN::Log::set_local_timezone();
1649
1650         $result .= "Last Changed Author: $lc_author\n";
1651         $result .= "Last Changed Rev: $lc_rev\n";
1652         $result .= "Last Changed Date: " .
1653                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1654
1655         if ($file_type ne "dir") {
1656                 my $text_last_updated_date =
1657                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1658                 $result .=
1659                     "Text Last Updated: " .
1660                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1661                     "\n";
1662                 my $checksum;
1663                 if ($diff_status eq "D") {
1664                         my ($fh, $ctx) =
1665                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1666                         if ($file_type eq "link") {
1667                                 my $file_name = <$fh>;
1668                                 $checksum = md5sum("link $file_name");
1669                         } else {
1670                                 $checksum = md5sum($fh);
1671                         }
1672                         command_close_pipe($fh, $ctx);
1673                 } elsif ($file_type eq "link") {
1674                         my $file_name =
1675                             command(qw(cat-file blob), "HEAD:$path");
1676                         $checksum =
1677                             md5sum("link " . $file_name);
1678                 } else {
1679                         open FILE, "<", $path or die $!;
1680                         $checksum = md5sum(\*FILE);
1681                         close FILE or die $!;
1682                 }
1683                 $result .= "Checksum: " . $checksum . "\n";
1684         }
1685
1686         print $result, "\n";
1687 }
1688
1689 sub cmd_reset {
1690         my $target = shift || $_revision or die "SVN revision required\n";
1691         $target = $1 if $target =~ /^r(\d+)$/;
1692         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1693         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1694         unless ($gs) {
1695                 die "Unable to determine upstream SVN information from ".
1696                     "history\n";
1697         }
1698         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1699         die "Cannot find SVN revision $target\n" unless defined($c);
1700         $gs->rev_map_set($r, $c, 'reset', $uuid);
1701         print "r$r = $c ($gs->{ref_id})\n";
1702 }
1703
1704 sub cmd_gc {
1705         require File::Find;
1706         if (!can_compress()) {
1707                 warn "Compress::Zlib could not be found; unhandled.log " .
1708                      "files will not be compressed.\n";
1709         }
1710         File::Find::find({ wanted => \&gc_directory, no_chdir => 1},
1711                          Git::SVN::svn_dir());
1712 }
1713
1714 ########################### utility functions #########################
1715
1716 sub rebase_cmd {
1717         my @cmd = qw/rebase/;
1718         push @cmd, '-v' if $_verbose;
1719         push @cmd, qw/--merge/ if $_merge;
1720         push @cmd, "--strategy=$_strategy" if $_strategy;
1721         push @cmd, "--rebase-merges" if $_rebase_merges;
1722         @cmd;
1723 }
1724
1725 sub post_fetch_checkout {
1726         return if $_no_checkout;
1727         return if verify_ref('HEAD^0');
1728         my $gs = $Git::SVN::_head or return;
1729
1730         # look for "trunk" ref if it exists
1731         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1732         my $fetch = $remote->{fetch};
1733         if ($fetch) {
1734                 foreach my $p (keys %$fetch) {
1735                         basename($fetch->{$p}) eq 'trunk' or next;
1736                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1737                         last;
1738                 }
1739         }
1740
1741         command_noisy(qw(update-ref HEAD), $gs->refname);
1742         return unless verify_ref('HEAD^0');
1743
1744         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1745         my $index = command_oneline(qw(rev-parse --git-path index));
1746         return if -f $index;
1747
1748         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1749         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1750         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1751         print STDERR "Checked out HEAD:\n  ",
1752                      $gs->full_url, " r", $gs->last_rev, "\n";
1753         if (auto_create_empty_directories($gs)) {
1754                 $gs->mkemptydirs($gs->last_rev);
1755         }
1756 }
1757
1758 sub complete_svn_url {
1759         my ($url, $path) = @_;
1760
1761         if ($path =~ m#^[a-z\+]+://#i) { # path is a URL
1762                 $path = canonicalize_url($path);
1763         } else {
1764                 $path = canonicalize_path($path);
1765                 if (!defined $url || $url !~ m#^[a-z\+]+://#i) {
1766                         fatal("E: '$path' is not a complete URL ",
1767                               "and a separate URL is not specified");
1768                 }
1769                 return ($url, $path);
1770         }
1771         return ($path, '');
1772 }
1773
1774 sub complete_url_ls_init {
1775         my ($ra, $repo_path, $switch, $pfx) = @_;
1776         unless ($repo_path) {
1777                 print STDERR "W: $switch not specified\n";
1778                 return;
1779         }
1780         if ($repo_path =~ m#^[a-z\+]+://#i) {
1781                 $repo_path = canonicalize_url($repo_path);
1782                 $ra = Git::SVN::Ra->new($repo_path);
1783                 $repo_path = '';
1784         } else {
1785                 $repo_path = canonicalize_path($repo_path);
1786                 $repo_path =~ s#^/+##;
1787                 unless ($ra) {
1788                         fatal("E: '$repo_path' is not a complete URL ",
1789                               "and a separate URL is not specified");
1790                 }
1791         }
1792         my $url = $ra->url;
1793         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1794         my $k = "svn-remote.$gs->{repo_id}.url";
1795         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1796         if ($orig_url && ($orig_url ne $gs->url)) {
1797                 die "$k already set: $orig_url\n",
1798                     "wanted to set to: $gs->url\n";
1799         }
1800         command_oneline('config', $k, $gs->url) unless $orig_url;
1801
1802         my $remote_path = join_paths( $gs->path, $repo_path );
1803         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1804         $remote_path =~ s#^/##g;
1805         $remote_path .= "/*" if $remote_path !~ /\*/;
1806         my ($n) = ($switch =~ /^--(\w+)/);
1807         if (length $pfx && $pfx !~ m#/$#) {
1808                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1809         }
1810         command_noisy('config',
1811                       '--add',
1812                       "svn-remote.$gs->{repo_id}.$n",
1813                       "$remote_path:refs/remotes/$pfx*" .
1814                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1815 }
1816
1817 sub verify_ref {
1818         my ($ref) = @_;
1819         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1820                                { STDERR => 0 }); };
1821 }
1822
1823 sub get_tree_from_treeish {
1824         my ($treeish) = @_;
1825         # $treeish can be a symbolic ref, too:
1826         my $type = command_oneline(qw/cat-file -t/, $treeish);
1827         my $expected;
1828         while ($type eq 'tag') {
1829                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1830         }
1831         if ($type eq 'commit') {
1832                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1833                                                     $treeish))[0];
1834                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1835                 die "Unable to get tree from $treeish\n" unless $expected;
1836         } elsif ($type eq 'tree') {
1837                 $expected = $treeish;
1838         } else {
1839                 die "$treeish is a $type, expected tree, tag or commit\n";
1840         }
1841         return $expected;
1842 }
1843
1844 sub get_commit_entry {
1845         my ($treeish) = shift;
1846         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1847         my @git_path = qw(rev-parse --git-path);
1848         my $commit_editmsg = command_oneline(@git_path, 'COMMIT_EDITMSG');
1849         my $commit_msg = command_oneline(@git_path, 'COMMIT_MSG');
1850         open my $log_fh, '>', $commit_editmsg or croak $!;
1851
1852         my $type = command_oneline(qw/cat-file -t/, $treeish);
1853         if ($type eq 'commit' || $type eq 'tag') {
1854                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1855                                                          $type, $treeish);
1856                 my $in_msg = 0;
1857                 my $author;
1858                 my $saw_from = 0;
1859                 my $msgbuf = "";
1860                 while (<$msg_fh>) {
1861                         if (!$in_msg) {
1862                                 $in_msg = 1 if (/^$/);
1863                                 $author = $1 if (/^author (.*>)/);
1864                         } elsif (/^git-svn-id: /) {
1865                                 # skip this for now, we regenerate the
1866                                 # correct one on re-fetch anyways
1867                                 # TODO: set *:merge properties or like...
1868                         } else {
1869                                 if (/^From:/ || /^Signed-off-by:/) {
1870                                         $saw_from = 1;
1871                                 }
1872                                 $msgbuf .= $_;
1873                         }
1874                 }
1875                 $msgbuf =~ s/\s+$//s;
1876                 $msgbuf =~ s/\r\n/\n/sg; # SVN 1.6+ disallows CRLF
1877                 if ($Git::SVN::_add_author_from && defined($author)
1878                     && !$saw_from) {
1879                         $msgbuf .= "\n\nFrom: $author";
1880                 }
1881                 print $log_fh $msgbuf or croak $!;
1882                 command_close_pipe($msg_fh, $ctx);
1883         }
1884         close $log_fh or croak $!;
1885
1886         if ($_edit || ($type eq 'tree')) {
1887                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1888                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1889         }
1890         rename $commit_editmsg, $commit_msg or croak $!;
1891         {
1892                 require Encode;
1893                 # SVN requires messages to be UTF-8 when entering the repo
1894                 open $log_fh, '<', $commit_msg or croak $!;
1895                 binmode $log_fh;
1896                 chomp($log_entry{log} = get_record($log_fh, undef));
1897
1898                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1899                 my $msg = $log_entry{log};
1900
1901                 eval { $msg = Encode::decode($enc, $msg, 1) };
1902                 if ($@) {
1903                         die "Could not decode as $enc:\n", $msg,
1904                             "\nPerhaps you need to set i18n.commitencoding\n";
1905                 }
1906
1907                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1908                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1909
1910                 $log_entry{log} = $msg;
1911
1912                 close $log_fh or croak $!;
1913         }
1914         unlink $commit_msg;
1915         \%log_entry;
1916 }
1917
1918 sub s_to_file {
1919         my ($str, $file, $mode) = @_;
1920         open my $fd,'>',$file or croak $!;
1921         print $fd $str,"\n" or croak $!;
1922         close $fd or croak $!;
1923         chmod ($mode &~ umask, $file) if (defined $mode);
1924 }
1925
1926 sub file_to_s {
1927         my $file = shift;
1928         open my $fd,'<',$file or croak "$!: file: $file\n";
1929         local $/;
1930         my $ret = <$fd>;
1931         close $fd or croak $!;
1932         $ret =~ s/\s*$//s;
1933         return $ret;
1934 }
1935
1936 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1937 sub load_authors {
1938         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1939         my $log = $cmd eq 'log';
1940         while (<$authors>) {
1941                 chomp;
1942                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.*)>\s*$/;
1943                 my ($user, $name, $email) = ($1, $2, $3);
1944                 if ($log) {
1945                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1946                 } else {
1947                         $users{$user} = [$name, $email];
1948                 }
1949         }
1950         close $authors or croak $!;
1951 }
1952
1953 # convert GetOpt::Long specs for use by git-config
1954 sub read_git_config {
1955         my $opts = shift;
1956         my @config_only;
1957         foreach my $o (keys %$opts) {
1958                 # if we have mixedCase and a long option-only, then
1959                 # it's a config-only variable that we don't need for
1960                 # the command-line.
1961                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1962                 my $v = $opts->{$o};
1963                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1964                 $key =~ s/-//g;
1965                 my $arg = 'git config';
1966                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1967                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1968                 if (ref $v eq 'ARRAY') {
1969                         chomp(my @tmp = `$arg --get-all svn.$key`);
1970                         @$v = @tmp if @tmp;
1971                 } else {
1972                         chomp(my $tmp = `$arg --get svn.$key`);
1973                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1974                                 $$v = $tmp;
1975                         }
1976                 }
1977         }
1978         delete @$opts{@config_only} if @config_only;
1979 }
1980
1981 sub extract_metadata {
1982         my $id = shift or return (undef, undef, undef);
1983         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1984                                                         \s([a-f\d\-]+)$/ix);
1985         if (!defined $rev || !$uuid || !$url) {
1986                 # some of the original repositories I made had
1987                 # identifiers like this:
1988                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1989         }
1990         return ($url, $rev, $uuid);
1991 }
1992
1993 sub cmt_metadata {
1994         return extract_metadata((grep(/^git-svn-id: /,
1995                 command(qw/cat-file commit/, shift)))[-1]);
1996 }
1997
1998 sub cmt_sha2rev_batch {
1999         my %s2r;
2000         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
2001         my $list = shift;
2002
2003         foreach my $sha (@{$list}) {
2004                 my $first = 1;
2005                 my $size = 0;
2006                 print $out $sha, "\n";
2007
2008                 while (my $line = <$in>) {
2009                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
2010                                 last;
2011                         } elsif ($first &&
2012                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
2013                                 $first = 0;
2014                                 $size = $1;
2015                                 next;
2016                         } elsif ($line =~ /^(git-svn-id: )/) {
2017                                 my (undef, $rev, undef) =
2018                                                       extract_metadata($line);
2019                                 $s2r{$sha} = $rev;
2020                         }
2021
2022                         $size -= length($line);
2023                         last if ($size == 0);
2024                 }
2025         }
2026
2027         command_close_bidi_pipe($pid, $in, $out, $ctx);
2028
2029         return \%s2r;
2030 }
2031
2032 sub working_head_info {
2033         my ($head, $refs) = @_;
2034         my @args = qw/rev-list --first-parent --pretty=medium/;
2035         my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2036         my $hash;
2037         my %max;
2038         while (<$fh>) {
2039                 if ( m{^commit ($::sha1)$} ) {
2040                         unshift @$refs, $hash if $hash and $refs;
2041                         $hash = $1;
2042                         next;
2043                 }
2044                 next unless s{^\s*(git-svn-id:)}{$1};
2045                 my ($url, $rev, $uuid) = extract_metadata($_);
2046                 if (defined $url && defined $rev) {
2047                         next if $max{$url} and $max{$url} < $rev;
2048                         if (my $gs = Git::SVN->find_by_url($url)) {
2049                                 my $c = $gs->rev_map_get($rev, $uuid);
2050                                 if ($c && $c eq $hash) {
2051                                         close $fh; # break the pipe
2052                                         return ($url, $rev, $uuid, $gs);
2053                                 } else {
2054                                         $max{$url} ||= $gs->rev_map_max;
2055                                 }
2056                         }
2057                 }
2058         }
2059         command_close_pipe($fh, $ctx);
2060         (undef, undef, undef, undef);
2061 }
2062
2063 sub read_commit_parents {
2064         my ($parents, $c) = @_;
2065         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2066         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2067         @{$parents->{$c}} = split(/ /, $p);
2068 }
2069
2070 sub linearize_history {
2071         my ($gs, $refs) = @_;
2072         my %parents;
2073         foreach my $c (@$refs) {
2074                 read_commit_parents(\%parents, $c);
2075         }
2076
2077         my @linear_refs;
2078         my %skip = ();
2079         my $last_svn_commit = $gs->last_commit;
2080         foreach my $c (reverse @$refs) {
2081                 next if $c eq $last_svn_commit;
2082                 last if $skip{$c};
2083
2084                 unshift @linear_refs, $c;
2085                 $skip{$c} = 1;
2086
2087                 # we only want the first parent to diff against for linear
2088                 # history, we save the rest to inject when we finalize the
2089                 # svn commit
2090                 my $fp_a = verify_ref("$c~1");
2091                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2092                 if (!$fp_a || !$fp_b) {
2093                         die "Commit $c\n",
2094                             "has no parent commit, and therefore ",
2095                             "nothing to diff against.\n",
2096                             "You should be working from a repository ",
2097                             "originally created by git-svn\n";
2098                 }
2099                 if ($fp_a ne $fp_b) {
2100                         die "$c~1 = $fp_a, however parsing commit $c ",
2101                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2102                 }
2103
2104                 foreach my $p (@{$parents{$c}}) {
2105                         $skip{$p} = 1;
2106                 }
2107         }
2108         (\@linear_refs, \%parents);
2109 }
2110
2111 sub find_file_type_and_diff_status {
2112         my ($path) = @_;
2113         return ('dir', '') if $path eq '';
2114
2115         my $diff_output =
2116             command_oneline(qw(diff --cached --name-status --), $path) || "";
2117         my $diff_status = (split(' ', $diff_output))[0] || "";
2118
2119         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2120
2121         return (undef, undef) if !$diff_status && !$ls_tree;
2122
2123         if ($diff_status eq "A") {
2124                 return ("link", $diff_status) if -l $path;
2125                 return ("dir", $diff_status) if -d $path;
2126                 return ("file", $diff_status);
2127         }
2128
2129         my $mode = (split(' ', $ls_tree))[0] || "";
2130
2131         return ("link", $diff_status) if $mode eq "120000";
2132         return ("dir", $diff_status) if $mode eq "040000";
2133         return ("file", $diff_status);
2134 }
2135
2136 sub md5sum {
2137         my $arg = shift;
2138         my $ref = ref $arg;
2139         require Digest::MD5;
2140         my $md5 = Digest::MD5->new();
2141         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2142                 $md5->addfile($arg) or croak $!;
2143         } elsif ($ref eq 'SCALAR') {
2144                 $md5->add($$arg) or croak $!;
2145         } elsif (!$ref) {
2146                 $md5->add($arg) or croak $!;
2147         } else {
2148                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2149         }
2150         return $md5->hexdigest();
2151 }
2152
2153 sub gc_directory {
2154         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2155                 my $out_filename = $_ . ".gz";
2156                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2157                 binmode $in_fh;
2158                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2159                                 die "Unable to open $out_filename: $!\n";
2160
2161                 my $res;
2162                 while ($res = sysread($in_fh, my $str, 1024)) {
2163                         $gz->gzwrite($str) or
2164                                 die "Unable to write: ".$gz->gzerror()."!\n";
2165                 }
2166                 no warnings 'once'; # $File::Find::name would warn
2167                 unlink $_ or die "unlink $File::Find::name: $!\n";
2168         } elsif (-f $_ && basename($_) eq "index") {
2169                 unlink $_ or die "unlink $_: $!\n";
2170         }
2171 }
2172
2173 __END__
2174
2175 Data structures:
2176
2177
2178 $remotes = { # returned by read_all_remotes()
2179         'svn' => {
2180                 # svn-remote.svn.url=https://svn.musicpd.org
2181                 url => 'https://svn.musicpd.org',
2182                 # svn-remote.svn.fetch=mpd/trunk:trunk
2183                 fetch => {
2184                         'mpd/trunk' => 'trunk',
2185                 },
2186                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2187                 tags => {
2188                         path => {
2189                                 left => 'mpd/tags',
2190                                 right => '',
2191                                 regex => qr!mpd/tags/([^/]+)$!,
2192                                 glob => 'tags/*',
2193                         },
2194                         ref => {
2195                                 left => 'tags',
2196                                 right => '',
2197                                 regex => qr!tags/([^/]+)$!,
2198                                 glob => 'tags/*',
2199                         },
2200                 }
2201         }
2202 };
2203
2204 $log_entry hashref as returned by libsvn_log_entry()
2205 {
2206         log => 'whitespace-formatted log entry
2207 ',                                              # trailing newline is preserved
2208         revision => '8',                        # integer
2209         date => '2004-02-24T17:01:44.108345Z',  # commit date
2210         author => 'committer name'
2211 };
2212
2213
2214 # this is generated by generate_diff();
2215 @mods = array of diff-index line hashes, each element represents one line
2216         of diff-index output
2217
2218 diff-index line ($m hash)
2219 {
2220         mode_a => first column of diff-index output, no leading ':',
2221         mode_b => second column of diff-index output,
2222         sha1_b => sha1sum of the final blob,
2223         chg => change type [MCRADT],
2224         file_a => original file name of a file (iff chg is 'C' or 'R')
2225         file_b => new/current file name of a file (any chg)
2226 }
2227 ;
2228
2229 # retval of read_url_paths{,_all}();
2230 $l_map = {
2231         # repository root url
2232         'https://svn.musicpd.org' => {
2233                 # repository path               # GIT_SVN_ID
2234                 'mpd/trunk'             =>      'trunk',
2235                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2236         },
2237 }
2238
2239 Notes:
2240         I don't trust the each() function on unless I created %hash myself
2241         because the internal iterator may not have started at base.