| blob | 2af1a687f839b729d1c44225adfb8ad8fb97938a |
1 #------------------------------------------------------------------------------
2 # Detect broken &&-chains in tests.
3 #
4 # At present, only &&-chains in subshells are examined by this linter;
5 # top-level &&-chains are instead checked directly by the test framework. Like
6 # the top-level &&-chain linter, the subshell linter (intentionally) does not
7 # check &&-chains within {...} blocks.
8 #
9 # Checking for &&-chain breakage is done line-by-line by pure textual
10 # inspection.
11 #
12 # Incomplete lines (those ending with "\") are stitched together with following
13 # lines to simplify processing, particularly of "one-liner" statements.
14 # Top-level here-docs are swallowed to avoid false positives within the
15 # here-doc body, although the statement to which the here-doc is attached is
16 # retained.
17 #
18 # Heuristics are used to detect end-of-subshell when the closing ")" is cuddled
19 # with the final subshell statement on the same line:
20 #
21 # (cd foo &&
22 # bar)
23 #
24 # in order to avoid misinterpreting the ")" in constructs such as "x=$(...)"
25 # and "case $x in *)" as ending the subshell.
26 #
27 # Lines missing a final "&&" are flagged with "?!AMP?!", and lines which chain
28 # commands with ";" internally rather than "&&" are flagged "?!SEMI?!". A line
29 # may be flagged for both violations.
30 #
31 # Detection of a missing &&-link in a multi-line subshell is complicated by the
32 # fact that the last statement before the closing ")" must not end with "&&".
33 # Since processing is line-by-line, it is not known whether a missing "&&" is
34 # legitimate or not until the _next_ line is seen. To accommodate this, within
35 # multi-line subshells, each line is stored in sed's "hold" area until after
36 # the next line is seen and processed. If the next line is a stand-alone ")",
37 # then a missing "&&" on the previous line is legitimate; otherwise a missing
38 # "&&" is a break in the &&-chain.
39 #
40 # (
41 # cd foo &&
42 # bar
43 # )
44 #
45 # In practical terms, when "bar" is encountered, it is flagged with "?!AMP?!",
46 # but when the stand-alone ")" line is seen which closes the subshell, the
47 # "?!AMP?!" violation is removed from the "bar" line (retrieved from the "hold"
48 # area) since the final statement of a subshell must not end with "&&". The
49 # final line of a subshell may still break the &&-chain by using ";" internally
50 # to chain commands together rather than "&&", so "?!SEMI?!" is never removed
51 # from a line (even though "?!AMP?!" might be).
52 #
53 # Care is taken to recognize the last _statement_ of a multi-line subshell, not
54 # necessarily the last textual _line_ within the subshell, since &&-chaining
55 # applies to statements, not to lines. Consequently, blank lines, comment
56 # lines, and here-docs are swallowed (but not the command to which the here-doc
57 # is attached), leaving the last statement in the "hold" area, not the last
58 # line, thus simplifying &&-link checking.
59 #
60 # The final statement before "done" in for- and while-loops, and before "elif",
61 # "else", and "fi" in if-then-else likewise must not end with "&&", thus
62 # receives similar treatment.
63 #
64 # Swallowing here-docs with arbitrary tags requires a bit of finesse. When a
65 # line such as "cat <<EOF >out" is seen, the here-doc tag is moved to the front
66 # of the line enclosed in angle brackets as a sentinel, giving "<EOF>cat >out".
67 # As each subsequent line is read, it is appended to the target line and a
68 # (whitespace-loose) back-reference match /^<(.*)>\n\1$/ is attempted to see if
69 # the content inside "<...>" matches the entirety of the newly-read line. For
70 # instance, if the next line read is "some data", when concatenated with the
71 # target line, it becomes "<EOF>cat >out\nsome data", and a match is attempted
72 # to see if "EOF" matches "some data". Since it doesn't, the next line is
73 # attempted. When a line consisting of only "EOF" (and possible whitespace) is
74 # encountered, it is appended to the target line giving "<EOF>cat >out\nEOF",
75 # in which case the "EOF" inside "<...>" does match the text following the
76 # newline, thus the closing here-doc tag has been found. The closing tag line
77 # and the "<...>" prefix on the target line are then discarded, leaving just
78 # the target line "cat >out".
79 #
80 # To facilitate regression testing (and manual debugging), a ">" annotation is
81 # applied to the line containing ")" which closes a subshell, ">>" to a line
82 # closing a nested subshell, and ">>>" to a line closing both at once. This
83 # makes it easy to detect whether the heuristics correctly identify
84 # end-of-subshell.
85 #------------------------------------------------------------------------------
87 # incomplete line -- slurp up next line
88 :squash
89 /\\$/ {
90 N
91 s/\\\n//
92 bsquash
93 }
95 # here-doc -- swallow it to avoid false hits within its body (but keep the
96 # command to which it was attached)
97 /<<[ ]*[-\\]*[A-Za-z0-9_]/ {
98 s/^\(.*\)<<[ ]*[-\\]*\([A-Za-z0-9_][A-Za-z0-9_]*\)/<\2>\1<</
99 s/[ ]*<<//
100 :hereslurp
101 N
102 /^<\([^>]*\)>.*\n[ ]*\1[ ]*$/!{
103 s/\n.*$//
104 bhereslurp
105 }
106 s/^<[^>]*>//
107 s/\n.*$//
108 }
110 # one-liner "(...) &&"
111 /^[ ]*!*[ ]*(..*)[ ]*&&[ ]*$/boneline
113 # same as above but without trailing "&&"
114 /^[ ]*!*[ ]*(..*)[ ]*$/boneline
116 # one-liner "(...) >x" (or "2>x" or "<x" or "|x" or "&"
117 /^[ ]*!*[ ]*(..*)[ ]*[0-9]*[<>|&]/boneline
119 # multi-line "(...\n...)"
120 /^[ ]*(/bsubshell
122 # innocuous line -- print it and advance to next line
123 b
125 # found one-liner "(...)" -- mark suspect if it uses ";" internally rather than
126 # "&&" (but not ";" in a string)
127 :oneline
128 /;/{
129 /"[^"]*;[^"]*"/!s/^/?!SEMI?!/
130 }
131 b
133 :subshell
134 # bare "(" line?
135 /^[ ]*([ ]*$/ {
136 # stash for later printing
137 h
138 bnextline
139 }
140 # "(..." line -- split off and stash "(", then process "..." as its own line
141 x
142 s/.*/(/
143 x
144 s/(//
145 bslurp
147 :nextline
148 N
149 s/.*\n//
151 :slurp
152 # incomplete line "...\"
153 /\\$/bincomplete
154 # multi-line quoted string "...\n..."
155 /^[^"]*"[^"]*$/bdqstring
156 # multi-line quoted string '...\n...' (but not contraction in string "it's so")
157 /^[^']*'[^']*$/{
158 /"[^'"]*'[^'"]*"/!bsqstring
159 }
160 # here-doc -- swallow it
161 /<<[ ]*[-\\]*[A-Za-z0-9_]/bheredoc
162 # comment or empty line -- discard since final non-comment, non-empty line
163 # before closing ")", "done", "elsif", "else", or "fi" will need to be
164 # re-visited to drop "suspect" marking since final line of those constructs
165 # legitimately lacks "&&", so "suspect" mark must be removed
166 /^[ ]*#/bnextline
167 /^[ ]*$/bnextline
168 # in-line comment -- strip it (but not "#" in a string, Bash ${#...} array
169 # length, or Perforce "//depot/path#42" revision in filespec)
170 /[ ]#/{
171 /"[^"]*#[^"]*"/!s/[ ]#.*$//
172 }
173 # one-liner "case ... esac"
174 /^[ ]*case[ ]*..*esac/bcheckchain
175 # multi-line "case ... esac"
176 /^[ ]*case[ ]..*[ ]in/bcase
177 # multi-line "for ... done" or "while ... done"
178 /^[ ]*for[ ]..*[ ]in/bcontinue
179 /^[ ]*while[ ]/bcontinue
180 /^[ ]*do[ ]/bcontinue
181 /^[ ]*do[ ]*$/bcontinue
182 /;[ ]*do/bcontinue
183 /^[ ]*done[ ]*&&[ ]*$/bdone
184 /^[ ]*done[ ]*$/bdone
185 /^[ ]*done[ ]*[<>|]/bdone
186 /^[ ]*done[ ]*)/bdone
187 /||[ ]*exit[ ]/bcontinue
188 /||[ ]*exit[ ]*$/bcontinue
189 # multi-line "if...elsif...else...fi"
190 /^[ ]*if[ ]/bcontinue
191 /^[ ]*then[ ]/bcontinue
192 /^[ ]*then[ ]*$/bcontinue
193 /;[ ]*then/bcontinue
194 /^[ ]*elif[ ]/belse
195 /^[ ]*elif[ ]*$/belse
196 /^[ ]*else[ ]/belse
197 /^[ ]*else[ ]*$/belse
198 /^[ ]*fi[ ]*&&[ ]*$/bdone
199 /^[ ]*fi[ ]*$/bdone
200 /^[ ]*fi[ ]*[<>|]/bdone
201 /^[ ]*fi[ ]*)/bdone
202 # nested one-liner "(...) &&"
203 /^[ ]*(.*)[ ]*&&[ ]*$/bcheckchain
204 # nested one-liner "(...)"
205 /^[ ]*(.*)[ ]*$/bcheckchain
206 # nested one-liner "(...) >x" (or "2>x" or "<x" or "|x")
207 /^[ ]*(.*)[ ]*[0-9]*[<>|]/bcheckchain
208 # nested multi-line "(...\n...)"
209 /^[ ]*(/bnest
210 # multi-line "{...\n...}"
211 /^[ ]*{/bblock
212 # closing ")" on own line -- exit subshell
213 /^[ ]*)/bclosesolo
214 # "$((...))" -- arithmetic expansion; not closing ")"
215 /\$(([^)][^)]*))[^)]*$/bcheckchain
216 # "$(...)" -- command substitution; not closing ")"
217 /\$([^)][^)]*)[^)]*$/bcheckchain
218 # multi-line "$(...\n...)" -- command substitution; treat as nested subshell
219 /\$([ ]*$/bnest
220 # "=(...)" -- Bash array assignment; not closing ")"
221 /=(/bcheckchain
222 # closing "...) &&"
223 /)[ ]*&&[ ]*$/bclose
224 # closing "...)"
225 /)[ ]*$/bclose
226 # closing "...) >x" (or "2>x" or "<x" or "|x")
227 /)[ ]*[<>|]/bclose
228 :checkchain
229 # mark suspect if line uses ";" internally rather than "&&" (but not ";" in a
230 # string and not ";;" in one-liner "case...esac")
231 /;/{
232 /;;/!{
233 /"[^"]*;[^"]*"/!s/^/?!SEMI?!/
234 }
235 }
236 # line ends with pipe "...|" -- valid; not missing "&&"
237 /|[ ]*$/bcontinue
238 # missing end-of-line "&&" -- mark suspect
239 /&&[ ]*$/!s/^/?!AMP?!/
240 :continue
241 # retrieve and print previous line
242 x
243 n
244 bslurp
246 # found incomplete line "...\" -- slurp up next line
247 :incomplete
248 N
249 s/\\\n//
250 bslurp
252 # found multi-line double-quoted string "...\n..." -- slurp until end of string
253 :dqstring
254 s/"//g
255 N
256 s/\n//
257 /"/!bdqstring
258 bcheckchain
260 # found multi-line single-quoted string '...\n...' -- slurp until end of string
261 :sqstring
262 s/'//g
263 N
264 s/\n//
265 /'/!bsqstring
266 bcheckchain
268 # found here-doc -- swallow it to avoid false hits within its body (but keep
269 # the command to which it was attached)
270 :heredoc
271 s/^\(.*\)<<[ ]*[-\\]*\([A-Za-z0-9_][A-Za-z0-9_]*\)/<\2>\1<</
272 s/[ ]*<<//
273 :hereslurpsub
274 N
275 /^<\([^>]*\)>.*\n[ ]*\1[ ]*$/!{
276 s/\n.*$//
277 bhereslurpsub
278 }
279 s/^<[^>]*>//
280 s/\n.*$//
281 bcheckchain
283 # found "case ... in" -- pass through untouched
284 :case
285 x
286 n
287 /^[ ]*esac/bslurp
288 bcase
290 # found "else" or "elif" -- drop "suspect" from final line before "else" since
291 # that line legitimately lacks "&&"
292 :else
293 x
294 s/?!AMP?!//
295 x
296 bcontinue
298 # found "done" closing for-loop or while-loop, or "fi" closing if-then -- drop
299 # "suspect" from final contained line since that line legitimately lacks "&&"
300 :done
301 x
302 s/?!AMP?!//
303 x
304 # is 'done' or 'fi' cuddled with ")" to close subshell?
305 /done.*)/bclose
306 /fi.*)/bclose
307 bcheckchain
309 # found nested multi-line "(...\n...)" -- pass through untouched
310 :nest
311 x
312 :nestslurp
313 n
314 # closing ")" on own line -- stop nested slurp
315 /^[ ]*)/bnestclose
316 # comment -- not closing ")" if in comment
317 /^[ ]*#/bnestcontinue
318 # "$((...))" -- arithmetic expansion; not closing ")"
319 /\$(([^)][^)]*))[^)]*$/bnestcontinue
320 # "$(...)" -- command substitution; not closing ")"
321 /\$([^)][^)]*)[^)]*$/bnestcontinue
322 # closing "...)" -- stop nested slurp
323 /)/bnestclose
324 :nestcontinue
325 x
326 bnestslurp
327 :nestclose
328 s/^/>>/
329 # is it "))" which closes nested and parent subshells?
330 /)[ ]*)/bslurp
331 bcheckchain
333 # found multi-line "{...\n...}" block -- pass through untouched
334 :block
335 x
336 n
337 # closing "}" -- stop block slurp
338 /}/bcheckchain
339 bblock
341 # found closing ")" on own line -- drop "suspect" from final line of subshell
342 # since that line legitimately lacks "&&" and exit subshell loop
343 :closesolo
344 x
345 s/?!AMP?!//
346 p
347 x
348 s/^/>/
349 b
351 # found closing "...)" -- exit subshell loop
352 :close
353 x
354 p
355 x
356 s/^/>/
357 b