cook

   1 #!/usr/bin/perl -w
   2 # Maintain "what's cooking" messages
   3
   4 use strict;
   5
   6 my %reverts = ('next' => {
   7         map { $_ => 1 } qw(
   8             ) });
   9
  10 %reverts = ();
  11
  12 sub phrase_these {
  13         my %uniq = ();
  14         my (@u) = grep { $uniq{$_}++ == 0 } sort @_;
  15         my @d = ();
  16         for (my $i = 0; $i < @u; $i++) {
  17                 push @d, $u[$i];
  18                 if ($i == @u - 2) {
  19                         push @d, " and ";
  20                 } elsif ($i < @u - 2) {
  21                         push @d, ", ";
  22                 }
  23         }
  24         return join('', @d);
  25 }
  26
  27 sub describe_relation {
  28         my ($topic_info) = @_;
  29         my @desc;
  30
  31         if (exists $topic_info->{'used'}) {
  32                 push @desc, ("is used by " .
  33                              phrase_these(@{$topic_info->{'used'}}));
  34         }
  35
  36         if (exists $topic_info->{'uses'}) {
  37                 push @desc, ("uses " .
  38                              phrase_these(@{$topic_info->{'uses'}}));
  39         }
  40
  41         if (exists $topic_info->{'shares'}) {
  42                 push @desc, ("is tangled with " .
  43                              phrase_these(@{$topic_info->{'shares'}}));
  44         }
  45
  46         if (!@desc) {
  47                 return "";
  48         }
  49
  50         return "(this branch " . join("; ", @desc) . ".)";
  51 }
  52
  53 sub forks_from {
  54         my ($topic, $fork, $forkee, @overlap) = @_;
  55         my %ovl = map { $_ => 1 } (@overlap, @{$topic->{$forkee}{'log'}});
  56
  57         push @{$topic->{$fork}{'uses'}}, $forkee;
  58         push @{$topic->{$forkee}{'used'}}, $fork;
  59         @{$topic->{$fork}{'log'}} = (grep { !exists $ovl{$_} }
  60                                      @{$topic->{$fork}{'log'}});
  61 }
  62
  63 sub topic_relation {
  64         my ($topic, $one, $two) = @_;
  65
  66         my $fh;
  67         open($fh, '-|',
  68              qw(git log --abbrev=7), "--format=%m %h",
  69              "$one...$two", "^master")
  70             or die "$!: open log --left-right";
  71         my (@left, @right);
  72         while (<$fh>) {
  73                 my ($sign, $sha1) = /^(.) (.*)/;
  74                 if ($sign eq '<') {
  75                         push @left, $sha1;
  76                 } elsif ($sign eq '>') {
  77                         push @right, $sha1;
  78                 }
  79         }
  80         close($fh) or die "$!: close log --left-right";
  81
  82         if (!@left) {
  83                 if (@right) {
  84                         forks_from($topic, $two, $one);
  85                 }
  86         } elsif (!@right) {
  87                 forks_from($topic, $one, $two);
  88         } else {
  89                 push @{$topic->{$one}{'shares'}}, $two;
  90                 push @{$topic->{$two}{'shares'}}, $one;
  91         }
  92 }
  93
  94 =head1
  95 Inspect the current set of topics
  96
  97 Returns a hash:
  98
  99     $topic = {
 100         $branchname => {
 101             'tipdate' => date of the tip commit,
 102             'desc' => description string,
 103             'log' => [ $commit,... ],
 104         },
 105     }
 106
 107 =cut
 108
 109 sub get_commit {
 110         my (@base) = qw(master next pu);
 111         my $fh;
 112         open($fh, '-|',
 113              qw(git for-each-ref),
 114              "--format=%(refname:short) %(committerdate:iso8601)",
 115              "refs/heads/??/*")
 116             or die "$!: open for-each-ref";
 117         my @topic;
 118         my %topic;
 119
 120         while (<$fh>) {
 121                 chomp;
 122                 my ($branch, $date) = /^(\S+) (.*)$/;
 123                 push @topic, $branch;
 124                 $date =~ s/ .*//;
 125                 $topic{$branch} = +{
 126                         log => [],
 127                         tipdate => $date,
 128                 };
 129         }
 130         close($fh) or die "$!: close for-each-ref";
 131
 132         my %base = map { $_ => undef } @base;
 133         my %commit;
 134         my $show_branch_batch = 20;
 135
 136         while (@topic) {
 137                 my @t = (@base, splice(@topic, 0, $show_branch_batch));
 138                 my $header_delim = '-' x scalar(@t);
 139                 my $contain_pat = '.' x scalar(@t);
 140                 open($fh, '-|', qw(git show-branch --sparse --sha1-name),
 141                      map { "refs/heads/$_" } @t)
 142                     or die "$!: open show-branch";
 143                 while (<$fh>) {
 144                         chomp;
 145                         if ($header_delim) {
 146                                 if (/^$header_delim$/) {
 147                                         $header_delim = undef;
 148                                 }
 149                                 next;
 150                         }
 151                         my ($contain, $sha1, $log) =
 152                             ($_ =~ /^($contain_pat) \[([0-9a-f]+)\] (.*)$/);
 153
 154                         for (my $i = 0; $i < @t; $i++) {
 155                                 my $branch = $t[$i];
 156                                 my $sign = substr($contain, $i, 1);
 157                                 next if ($sign eq ' ');
 158                                 next if (substr($contain, 0, 1) ne ' ');
 159
 160                                 if (!exists $commit{$sha1}) {
 161                                         $commit{$sha1} = +{
 162                                                 branch => {},
 163                                                 log => $log,
 164                                         };
 165                                 }
 166                                 my $co = $commit{$sha1};
 167                                 if (!exists $reverts{$branch}{$sha1}) {
 168                                         $co->{'branch'}{$branch} = 1;
 169                                 }
 170                                 next if (exists $base{$branch});
 171                                 push @{$topic{$branch}{'log'}}, $sha1;
 172                         }
 173                 }
 174                 close($fh) or die "$!: close show-branch";
 175         }
 176
 177         my %shared;
 178         for my $sha1 (keys %commit) {
 179                 my $sign;
 180                 my $co = $commit{$sha1};
 181                 if (exists $co->{'branch'}{'next'}) {
 182                         $sign = '+';
 183                 } elsif (exists $co->{'branch'}{'pu'}) {
 184                         $sign = '-';
 185                 } else {
 186                         $sign = '.';
 187                 }
 188                 $co->{'log'} = $sign . ' ' . $co->{'log'};
 189                 my @t = (sort grep { !exists $base{$_} }
 190                          keys %{$co->{'branch'}});
 191                 next if (@t < 2);
 192                 my $t = "@t";
 193                 $shared{$t} = 1;
 194         }
 195
 196         for my $combo (keys %shared) {
 197                 my @combo = split(' ', $combo);
 198                 for (my $i = 0; $i < @combo - 1; $i++) {
 199                         for (my $j = $i + 1; $j < @combo; $j++) {
 200                                 topic_relation(\%topic, $combo[$i], $combo[$j]);
 201                         }
 202                 }
 203         }
 204
 205         open($fh, '-|',
 206              qw(git log --first-parent --abbrev=7),
 207              "--format=%ci %h %p :%s", "master..next")
 208             or die "$!: open log master..next";
 209         while (<$fh>) {
 210                 my ($date, $commit, $parent, $tips);
 211                 unless (($date, $commit, $parent, $tips) =
 212                         /^([-0-9]+) ..:..:.. .\d{4} (\S+) (\S+) ([^:]*):/) {
 213                         die "Oops: $_";
 214                 }
 215                 for my $tip (split(' ', $tips)) {
 216                         my $co = $commit{$tip};
 217                         next unless ($co->{'branch'}{'next'});
 218                         $co->{'merged'} = " (merged to 'next' on $date at $commit)";
 219                 }
 220         }
 221         close($fh) or die "$!: close log master..next";
 222
 223         for my $branch (keys %topic) {
 224                 my @log = ();
 225                 my $n = scalar(@{$topic{$branch}{'log'}});
 226                 if (!$n) {
 227                         delete $topic{$branch};
 228                         next;
 229                 } elsif ($n == 1) {
 230                         $n = "1 commit";
 231                 } else {
 232                         $n = "$n commits";
 233                 }
 234                 my $d = $topic{$branch}{'tipdate'};
 235                 my $head = "* $branch ($d) $n\n";
 236                 my @desc;
 237                 for (@{$topic{$branch}{'log'}}) {
 238                         my $co = $commit{$_};
 239                         if (exists $co->{'merged'}) {
 240                                 push @desc, $co->{'merged'};
 241                         }
 242                         push @desc, $commit{$_}->{'log'};
 243                 }
 244
 245                 if (80 < @desc) {
 246                         @desc = @desc[0..4];
 247                         push @desc, "- ...";
 248                 }
 249
 250                 my $list = join("\n", map { " " . $_ } @desc);
 251                 my $relation = describe_relation($topic{$branch});
 252                 $topic{$branch}{'desc'} = $head . $list;
 253                 if ($relation) {
 254                         $topic{$branch}{'desc'} .= "\n $relation";
 255                 }
 256         }
 257
 258         return \%topic;
 259 }
 260
 261 sub blurb_text {
 262         my ($mon, $year, $issue, $dow, $date,
 263             $master_at, $next_at, $text) = @_;
 264
 265         my $now_string = localtime;
 266         my ($current_dow, $current_mon, $current_date, $current_year) =
 267             ($now_string =~ /^(\w+) (\w+) (\d+) [\d:]+ (\d+)$/);
 268
 269         $mon ||= $current_mon;
 270         $year ||= $current_year;
 271         $issue ||= "01";
 272         $dow ||= $current_dow;
 273         $date ||= $current_date;
 274         $master_at ||= '0' x 40;
 275         $next_at ||= '0' x 40;
 276         $text ||= <<'EOF';
 277 Here are the topics that have been cooking.  Commits prefixed with '-' are
 278 only in 'pu' (proposed updates) while commits prefixed with '+' are in 'next'.
 279 The ones marked with '.' do not appear in any of the integration branches,
 280 but I am still holding onto them.
 281
 282 You can find the changes described here in the integration branches of the
 283 repositories listed at
 284
 285     http://git-blame.blogspot.com/p/git-public-repositories.html
 286 EOF
 287
 288         $text = <<EOF;
 289 To: git\@vger.kernel.org
 290 Bcc: lwn\@lwn.net
 291 Subject: What's cooking in git.git ($mon $year, #$issue; $dow, $date)
 292 X-master-at: $master_at
 293 X-next-at: $next_at
 294
 295 What's cooking in git.git ($mon $year, #$issue; $dow, $date)
 296 --------------------------------------------------
 297
 298 $text
 299 EOF
 300         $text =~ s/\n+\Z/\n/;
 301         return $text;
 302 }
 303
 304 my $blurb_match = <<'EOF';
 305 (?i:\s*[a-z]+: .*\n)*?Subject: What's cooking in \S+ \((\w+) (\d+), #(\d+); (\w+), (\d+)\)
 306 X-master-at: ([0-9a-f]{40})
 307 X-next-at: ([0-9a-f]{40})
 308
 309 What's cooking in \S+ \(\1 \2, #\3; \4, \5\)
 310 -{30,}
 311 \n*
 312 EOF
 313
 314 my $blurb = "b..l..u..r..b";
 315 sub read_previous {
 316         my ($fn) = @_;
 317         my $fh;
 318         my $section = undef;
 319         my $serial = 1;
 320         my $branch = $blurb;
 321         my $last_empty = undef;
 322         my (@section, %section, @branch, %branch, %description, @leader);
 323         my $in_unedited_olde = 0;
 324
 325         if (!-r $fn) {
 326                 return +{
 327                         'section_list' => [],
 328                         'section_data' => {},
 329                         'topic_description' => {
 330                                 $blurb => {
 331                                         desc => undef,
 332                                         text => blurb_text(),
 333                                 },
 334                         },
 335                 };
 336         }
 337
 338         open ($fh, '<', $fn) or die "$!: open $fn";
 339         while (<$fh>) {
 340                 chomp;
 341                 s/\s+$//;
 342                 if ($in_unedited_olde) {
 343                         if (/^>>$/) {
 344                                 $in_unedited_olde = 0;
 345                                 $_ = " | $_";
 346                         }
 347                 } elsif (/^<<$/) {
 348                         $in_unedited_olde = 1;
 349                 }
 350
 351                 if ($in_unedited_olde) {
 352                         $_ = " | $_";
 353                 }
 354
 355                 if (defined $section && /^-{20,}$/) {
 356                         $_ = "";
 357                 }
 358                 if (/^$/) {
 359                         $last_empty = 1;
 360                         next;
 361                 }
 362                 if (/^\[(.*)\]\s*$/) {
 363                         $section = $1;
 364                         $branch = undef;
 365                         if (!exists $section{$section}) {
 366                                 push @section, $section;
 367                                 $section{$section} = [];
 368                         }
 369                         next;
 370                 }
 371                 if (defined $section && /^\* (\S+) /) {
 372                         $branch = $1;
 373                         $last_empty = 0;
 374                         if (!exists $branch{$branch}) {
 375                                 push @branch, [$branch, $section];
 376                                 $branch{$branch} = 1;
 377                         }
 378                         push @{$section{$section}}, $branch;
 379                 }
 380                 if (defined $branch) {
 381                         my $was_last_empty = $last_empty;
 382                         $last_empty = 0;
 383                         if (!exists $description{$branch}) {
 384                                 $description{$branch} = [];
 385                         }
 386                         if ($was_last_empty) {
 387                                 push @{$description{$branch}}, "";
 388                         }
 389                         push @{$description{$branch}}, $_;
 390                 }
 391         }
 392         close($fh);
 393
 394         my $lead = " ";
 395         for my $branch (keys %description) {
 396                 my $ary = $description{$branch};
 397                 if ($branch eq $blurb) {
 398                         while (@{$ary} && $ary->[-1] =~ /^-{30,}$/) {
 399                                 pop @{$ary};
 400                         }
 401                         $description{$branch} = +{
 402                                 desc => undef,
 403                                 text => join("\n", @{$ary}),
 404                         };
 405                 } else {
 406                         my @desc = ();
 407                         while (@{$ary}) {
 408                                 my $elem = shift @{$ary};
 409                                 last if ($elem eq '');
 410                                 push @desc, $elem;
 411                         }
 412                         my @txt = map {
 413                                 s/^\s+//;
 414                                 $_ = "$lead$_";
 415                                 s/\s+$//;
 416                                 $_;
 417                         } @{$ary};
 418
 419                         $description{$branch} = +{
 420                                 desc => join("\n", @desc),
 421                                 text => join("\n", @txt),
 422                         };
 423                 }
 424         }
 425
 426         return +{
 427                 section_list => \@section,
 428                 section_data => \%section,
 429                 topic_description => \%description,
 430         };
 431 }
 432
 433 sub write_cooking {
 434         my ($fn, $cooking) = @_;
 435         my $fh;
 436
 437         open($fh, '>', $fn) or die "$!: open $fn";
 438         print $fh $cooking->{'topic_description'}{$blurb}{'text'};
 439
 440         for my $section_name (@{$cooking->{'section_list'}}) {
 441                 my $topic_list = $cooking->{'section_data'}{$section_name};
 442                 next if (!@{$topic_list});
 443
 444                 print $fh "\n";
 445                 print $fh '-' x 50, "\n";
 446                 print $fh "[$section_name]\n";
 447                 my $lead = "\n";
 448                 for my $topic (@{$topic_list}) {
 449                         my $d = $cooking->{'topic_description'}{$topic};
 450
 451                         print $fh $lead, $d->{'desc'}, "\n";
 452                         if ($d->{'text'}) {
 453                                 print $fh "\n", $d->{'text'}, "\n";
 454                         }
 455                         $lead = "\n\n";
 456                 }
 457         }
 458         close($fh);
 459 }
 460
 461 my $graduated = 'Graduated to "master"';
 462 my $new_topics = 'New Topics';
 463 my $discarded = 'Discarded';
 464 my $cooking_topics = 'Cooking';
 465
 466 sub update_issue {
 467         my ($cooking) = @_;
 468         my ($fh, $master_at, $next_at, $incremental);
 469
 470         open($fh, '-|',
 471              qw(git for-each-ref),
 472              "--format=%(refname:short) %(objectname)",
 473              "refs/heads/master",
 474              "refs/heads/next") or die "$!: open for-each-ref";
 475         while (<$fh>) {
 476                 my ($branch, $at) = /^(\S+) (\S+)$/;
 477                 if ($branch eq 'master') { $master_at = $at; }
 478                 if ($branch eq 'next') { $next_at = $at; }
 479         }
 480         close($fh) or die "$!: close for-each-ref";
 481
 482         $incremental = ((-r "Meta/whats-cooking.txt") &&
 483                         system("cd Meta && " .
 484                                "git diff --quiet --no-ext-diff HEAD -- " .
 485                                "whats-cooking.txt"));
 486
 487         my $now_string = localtime;
 488         my ($current_dow, $current_mon, $current_date, $current_year) =
 489             ($now_string =~ /^(\w+) (\w+) +(\d+) [\d:]+ (\d+)$/);
 490
 491         my $btext = $cooking->{'topic_description'}{$blurb}{'text'};
 492         if ($btext !~ s/\A$blurb_match//) {
 493                 die "match pattern broken?";
 494         }
 495         my ($mon, $year, $issue, $dow, $date) = ($1, $2, $3, $4, $5);
 496
 497         if ($current_mon ne $mon || $current_year ne $year) {
 498                 $issue = "01";
 499         } elsif (!$incremental) {
 500                 $issue =~ s/^0*//;
 501                 $issue = sprintf "%02d", ($issue + 1);
 502         }
 503         $mon = $current_mon;
 504         $year = $current_year;
 505         $dow = $current_dow;
 506         $date = $current_date;
 507
 508         $cooking->{'topic_description'}{$blurb}{'text'} =
 509             blurb_text($mon, $year, $issue, $dow, $date,
 510                        $master_at, $next_at, $btext);
 511
 512         if (!$incremental) {
 513                 my $sd = $cooking->{'section_data'};
 514                 my $sl = $cooking->{'section_list'};
 515
 516                 if (exists $sd->{$new_topics}) {
 517                         if (!exists $sd->{$cooking_topics}) {
 518                                 $sd->{$cooking_topics} = [];
 519                                 unshift @{$sl}, $cooking_topics;
 520                         }
 521                         unshift @{$sd->{$cooking_topics}}, @{$sd->{$new_topics}};
 522                 }
 523                 $sd->{$new_topics} = [];
 524         }
 525
 526         return $incremental;
 527 }
 528
 529 sub topic_in_pu {
 530         my ($topic_desc) = @_;
 531         for my $line (split(/\n/, $topic_desc)) {
 532                 if ($line =~ /^ [+-] /) {
 533                         return 1;
 534                 }
 535         }
 536         return 0;
 537 }
 538
 539 sub merge_cooking {
 540         my ($cooking, $current) = @_;
 541         my $td = $cooking->{'topic_description'};
 542         my $sd = $cooking->{'section_data'};
 543         my $sl = $cooking->{'section_list'};
 544         my (@new_topic, @gone_topic);
 545
 546         # Make sure "New Topics" and "Graduated" exists
 547         if (!exists $sd->{$new_topics}) {
 548                 $sd->{$new_topics} = [];
 549                 unshift @{$sl}, $new_topics;
 550         }
 551
 552         if (!exists $sd->{$graduated}) {
 553                 $sd->{$graduated} = [];
 554                 unshift @{$sl}, $graduated;
 555         }
 556
 557         my $incremental = update_issue($cooking);
 558
 559         for my $topic (sort keys %{$current}) {
 560                 if (!exists $td->{$topic}) {
 561                         # Ignore new topics without anything merged
 562                         if (topic_in_pu($current->{$topic}{'desc'})) {
 563                                 push @new_topic, $topic;
 564                         }
 565                         next;
 566                 }
 567                 # Annotate if the contents of the topic changed
 568                 my $n = $current->{$topic}{'desc'};
 569                 my $o = $td->{$topic}{'desc'};
 570                 if ($n ne $o) {
 571                         $td->{$topic}{'desc'} = $n . "\n<<\n" . $o ."\n>>";
 572                 }
 573         }
 574
 575         for my $topic (sort keys %{$td}) {
 576                 next if ($topic eq $blurb);
 577                 next if (!$incremental &&
 578                          grep { $topic eq $_ } @{$sd->{$graduated}});
 579                 next if (grep { $topic eq $_ } @{$sd->{$discarded}});
 580                 if (!exists $current->{$topic}) {
 581                         push @gone_topic, $topic;
 582                 }
 583         }
 584
 585         for (@new_topic) {
 586                 push @{$sd->{$new_topics}}, $_;
 587                 $td->{$_}{'desc'} = $current->{$_}{'desc'};
 588         }
 589
 590         if (!$incremental) {
 591                 $sd->{$graduated} = [];
 592         }
 593
 594         if (@gone_topic) {
 595                 for my $topic (@gone_topic) {
 596                         for my $section (@{$sl}) {
 597                                 my $pre = scalar(@{$sd->{$section}});
 598                                 @{$sd->{$section}} = (grep { $_ ne $topic }
 599                                                       @{$sd->{$section}});
 600                                 my $post = scalar(@{$sd->{$section}});
 601                                 next if ($pre == $post);
 602                         }
 603                 }
 604                 for (@gone_topic) {
 605                         push @{$sd->{$graduated}}, $_;
 606                 }
 607         }
 608 }
 609
 610 ################################################################
 611 # WilDo
 612 sub wildo_queue {
 613         my ($what, $action, $topic) = @_;
 614         if (!exists $what->{$action}) {
 615                 $what->{$action} = [];
 616         }
 617         push @{$what->{$action}}, $topic;
 618 }
 619
 620 sub section_action {
 621         my ($section) = @_;
 622         if ($section) {
 623                 for ($section) {
 624                         return if (/^Graduated to/ || /^Discarded$/);
 625                         return $_ if (/^Stalled$/);
 626                 }
 627         }
 628         return "Undecided";
 629 }
 630
 631 sub wildo_flush_topic {
 632         my ($in_section, $what, $topic) = @_;
 633         if (defined $topic) {
 634                 my $action = section_action($in_section);
 635                 if ($action) {
 636                         wildo_queue($what, $action, $topic);
 637                 }
 638         }
 639 }
 640
 641 sub wildo_match {
 642         if (/^Will (?:\S+ ){0,2}(fast-track|hold|keep|merge|drop|discard|cook|kick|defer|be re-?rolled)[,. ]/ ||
 643             /^Not urgent/ || /^Not ready/ || /^Waiting for / || /^Can wait in / ||
 644             /^Needs? / || /^Expecting / || /^May want to /) {
 645                 return 1;
 646         }
 647         if (/^I think this is ready for /) {
 648                 return 1;
 649         }
 650         return 0;
 651 }
 652
 653 sub wildo {
 654         my $fd = shift;
 655         my (%what, $topic, $last_merge_to_next, $in_section, $in_desc);
 656         my $too_recent = '9999-99-99';
 657         while (<$fd>) {
 658                 chomp;
 659
 660                 if (/^\[(.*)\]$/) {
 661                         my $old_section = $in_section;
 662                         $in_section = $1;
 663                         wildo_flush_topic($old_section, \%what, $topic);
 664                         $topic = $in_desc = undef;
 665                         next;
 666                 }
 667
 668                 if (/^\* (\S+) \(([-0-9]+)\) (\d+) commits?$/) {
 669                         wildo_flush_topic($in_section, \%what, $topic);
 670
 671                         # tip-date, next-date, topic, count, pu-count
 672                         $topic = [$2, $too_recent, $1, $3, 0];
 673                         $in_desc = undef;
 674                         next;
 675                 }
 676
 677                 if (defined $topic &&
 678                     ($topic->[1] eq $too_recent) &&
 679                     ($topic->[4] == 0) &&
 680                     (/^  \(merged to 'next' on ([-0-9]+)/)) {
 681                         $topic->[1] = $1;
 682                 }
 683                 if (defined $topic && /^ - /) {
 684                         $topic->[4]++;
 685                 }
 686
 687                 if (defined $topic && /^$/) {
 688                         $in_desc = 1;
 689                         next;
 690                 }
 691
 692                 next unless defined $topic && $in_desc;
 693
 694                 s/^\s+//;
 695                 if (wildo_match($_)) {
 696                         wildo_queue(\%what, $_, $topic);
 697                         $topic = $in_desc = undef;
 698                 }
 699
 700                 if (/Originally merged to 'next' on ([-0-9]+)/) {
 701                         $topic->[1] = $1;
 702                 }
 703         }
 704         wildo_flush_topic($in_section, \%what, $topic);
 705
 706         my $ipbl = "";
 707         for my $what (sort keys %what) {
 708                 print "$ipbl$what\n";
 709                 for $topic (sort { (($a->[1] cmp $b->[1]) ||
 710                                     ($a->[0] cmp $b->[0])) }
 711                             @{$what{$what}}) {
 712                         my ($tip, $next, $name, $count, $pu) = @$topic;
 713                         my ($sign);
 714                         $tip =~ s/^\d{4}-//;
 715                         if (($next eq $too_recent) || (0 < $pu)) {
 716                                 $sign = "-";
 717                                 $next = " " x 6;
 718                         } else {
 719                                 $sign = "+";
 720                                 $next =~ s|^\d{4}-|/|;
 721                         }
 722                         $count = "#$count";
 723                         printf " %s %-60s %s%s %5s\n", $sign, $name, $tip, $next, $count;
 724                 }
 725                 $ipbl = "\n";
 726         }
 727 }
 728
 729 ################################################################
 730 # HavDone
 731 sub havedone_show {
 732         my $topic = shift;
 733         my $str = shift;
 734         my $prefix = " * ";
 735         $str =~ s/\A\n+//;
 736         $str =~ s/\n+\Z//;
 737
 738         print "($topic)\n";
 739         for $str (split(/\n/, $str)) {
 740                 print "$prefix$str\n";
 741                 $prefix = "   ";
 742         }
 743 }
 744
 745 sub havedone_count {
 746         my @range = @_;
 747         my $cnt = `git rev-list --count @range`;
 748         chomp $cnt;
 749         return $cnt;
 750 }
 751
 752 sub havedone {
 753         my $fh;
 754         my %topic = ();
 755         my @topic = ();
 756         my ($topic, $to_maint, %to_maint, %merged, $in_desc);
 757         if (!@ARGV) {
 758                 open($fh, '-|',
 759                      qw(git rev-list --first-parent -1 master Documentation/RelNotes))
 760                     or die "$!: open rev-list";
 761                 my ($rev) = <$fh>;
 762                 close($fh) or die "$!: close rev-list";
 763                 chomp $rev;
 764                 @ARGV = ("$rev..master");
 765         }
 766         open($fh, '-|',
 767              qw(git log --first-parent --oneline --reverse), @ARGV)
 768             or die "$!: open log --first-parent";
 769         while (<$fh>) {
 770                 my ($sha1, $branch) = /^([0-9a-f]+) Merge branch '(.*)'$/;
 771                 next unless $branch;
 772                 $topic{$branch} = "";
 773                 $merged{$branch} = $sha1;
 774                 push @topic, $branch;
 775         }
 776         close($fh) or die "$!: close log --first-parent";
 777         open($fh, "<", "Meta/whats-cooking.txt")
 778             or die "$!: open whats-cooking";
 779         while (<$fh>) {
 780                 chomp;
 781                 if (/^\[(.*)\]$/) {
 782                         # section header
 783                         $in_desc = $topic = undef;
 784                         next;
 785                 }
 786                 if (/^\* (\S+) \([-0-9]+\) \d+ commits?$/) {
 787                         if (exists $topic{$1}) {
 788                                 $topic = $1;
 789                                 $to_maint = 0;
 790                         } else {
 791                                 $in_desc = $topic = undef;
 792                         }
 793                         next;
 794                 }
 795                 if (defined $topic && /^$/) {
 796                         $in_desc = 1;
 797                         next;
 798                 }
 799
 800                 next unless defined $topic && $in_desc;
 801
 802                 s/^\s+//;
 803                 if (wildo_match($_)) {
 804                         next;
 805                 }
 806                 $topic{$topic} .= "$_\n";
 807         }
 808         close($fh) or die "$!: close whats-cooking";
 809
 810         for $topic (@topic) {
 811                 my $merged = $merged{$topic};
 812                 my $in_master = havedone_count("$merged^1..$merged^2");
 813                 my $not_in_maint = havedone_count("maint..$merged^2");
 814                 if ($in_master == $not_in_maint) {
 815                         $to_maint{$topic} = 1;
 816                 }
 817         }
 818
 819         my $shown = 0;
 820         for $topic (@topic) {
 821                 next if (exists $to_maint{$topic});
 822                 havedone_show($topic, $topic{$topic});
 823                 print "\n";
 824                 $shown++;
 825         }
 826
 827         if ($shown) {
 828                 print "-" x 64, "\n";
 829         }
 830
 831         for $topic (@topic) {
 832                 next unless (exists $to_maint{$topic});
 833                 havedone_show($topic, $topic{$topic});
 834                 my $sha1 = `git rev-parse --short $topic`;
 835                 chomp $sha1;
 836                 print "   (merge $sha1 $topic later to maint).\n";
 837                 print "\n";
 838         }
 839 }
 840
 841 ################################################################
 842 # WhatsCooking
 843
 844 sub doit {
 845         my $topic = get_commit();
 846         my $cooking = read_previous('Meta/whats-cooking.txt');
 847         merge_cooking($cooking, $topic);
 848         write_cooking('Meta/whats-cooking.txt', $cooking);
 849 }
 850
 851 ################################################################
 852 # Main
 853
 854 use Getopt::Long;
 855
 856 my ($wildo, $havedone);
 857 if (!GetOptions("wildo" => \$wildo,
 858                 "havedone" => \$havedone)) {
 859         print STDERR "$0 [--wildo|--havedone]\n";
 860         exit 1;
 861 }
 862
 863 if ($wildo) {
 864         my $fd;
 865         if (!@ARGV) {
 866                 open($fd, "<", "Meta/whats-cooking.txt");
 867         } elsif (@ARGV != 1) {
 868                 print STDERR "$0 --wildo [filename|HEAD|-]\n";
 869                 exit 1;
 870         } elsif ($ARGV[0] eq '-') {
 871                 $fd = \*STDIN;
 872         } elsif ($ARGV[0] =~ /^HEAD/) {
 873                 open($fd, "-|",
 874                      qw(git --git-dir=Meta/.git cat-file -p),
 875                      "$ARGV[0]:whats-cooking.txt");
 876         } else {
 877                 open($fd, "<", $ARGV[0]);
 878         }
 879         wildo($fd);
 880 } elsif ($havedone) {
 881         havedone();
 882 } else {
 883         doit();
 884 }