contrib/emacs/git.el

   1 ;;; git.el --- A user interface for git
   2
   3 ;; Copyright (C) 2005, 2006, 2007 Alexandre Julliard <julliard@winehq.org>
   4
   5 ;; Version: 1.0
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation; either version 2 of
  10 ;; the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be
  13 ;; useful, but WITHOUT ANY WARRANTY; without even the implied
  14 ;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15 ;; PURPOSE.  See the GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public
  18 ;; License along with this program; if not, write to the Free
  19 ;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20 ;; MA 02111-1307 USA
  21
  22 ;;; Commentary:
  23
  24 ;; This file contains an interface for the git version control
  25 ;; system. It provides easy access to the most frequently used git
  26 ;; commands. The user interface is as far as possible identical to
  27 ;; that of the PCL-CVS mode.
  28 ;;
  29 ;; To install: put this file on the load-path and place the following
  30 ;; in your .emacs file:
  31 ;;
  32 ;;    (require 'git)
  33 ;;
  34 ;; To start: `M-x git-status'
  35 ;;
  36 ;; TODO
  37 ;;  - portability to XEmacs
  38 ;;  - better handling of subprocess errors
  39 ;;  - hook into file save (after-save-hook)
  40 ;;  - diff against other branch
  41 ;;  - renaming files from the status buffer
  42 ;;  - creating tags
  43 ;;  - fetch/pull
  44 ;;  - switching branches
  45 ;;  - revlist browser
  46 ;;  - git-show-branch browser
  47 ;;  - menus
  48 ;;
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'ewoc)
  52 (require 'log-edit)
  53
  54
  55 ;;;; Customizations
  56 ;;;; ------------------------------------------------------------
  57
  58 (defgroup git nil
  59   "A user interface for the git versioning system."
  60   :group 'tools)
  61
  62 (defcustom git-committer-name nil
  63   "User name to use for commits.
  64 The default is to fall back to the repository config,
  65 then to `add-log-full-name' and then to `user-full-name'."
  66   :group 'git
  67   :type '(choice (const :tag "Default" nil)
  68                  (string :tag "Name")))
  69
  70 (defcustom git-committer-email nil
  71   "Email address to use for commits.
  72 The default is to fall back to the git repository config,
  73 then to `add-log-mailing-address' and then to `user-mail-address'."
  74   :group 'git
  75   :type '(choice (const :tag "Default" nil)
  76                  (string :tag "Email")))
  77
  78 (defcustom git-commits-coding-system nil
  79   "Default coding system for the log message of git commits."
  80   :group 'git
  81   :type '(choice (const :tag "From repository config" nil)
  82                  (coding-system)))
  83
  84 (defcustom git-append-signed-off-by nil
  85   "Whether to append a Signed-off-by line to the commit message before editing."
  86   :group 'git
  87   :type 'boolean)
  88
  89 (defcustom git-reuse-status-buffer t
  90   "Whether `git-status' should try to reuse an existing buffer
  91 if there is already one that displays the same directory."
  92   :group 'git
  93   :type 'boolean)
  94
  95 (defcustom git-per-dir-ignore-file ".gitignore"
  96   "Name of the per-directory ignore file."
  97   :group 'git
  98   :type 'string)
  99
 100 (defcustom git-show-uptodate nil
 101   "Whether to display up-to-date files."
 102   :group 'git
 103   :type 'boolean)
 104
 105 (defcustom git-show-ignored nil
 106   "Whether to display ignored files."
 107   :group 'git
 108   :type 'boolean)
 109
 110 (defcustom git-show-unknown t
 111   "Whether to display unknown files."
 112   :group 'git
 113   :type 'boolean)
 114
 115
 116 (defface git-status-face
 117   '((((class color) (background light)) (:foreground "purple"))
 118     (((class color) (background dark)) (:foreground "salmon")))
 119   "Git mode face used to highlight added and modified files."
 120   :group 'git)
 121
 122 (defface git-unmerged-face
 123   '((((class color) (background light)) (:foreground "red" :bold t))
 124     (((class color) (background dark)) (:foreground "red" :bold t)))
 125   "Git mode face used to highlight unmerged files."
 126   :group 'git)
 127
 128 (defface git-unknown-face
 129   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 130     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 131   "Git mode face used to highlight unknown files."
 132   :group 'git)
 133
 134 (defface git-uptodate-face
 135   '((((class color) (background light)) (:foreground "grey60"))
 136     (((class color) (background dark)) (:foreground "grey40")))
 137   "Git mode face used to highlight up-to-date files."
 138   :group 'git)
 139
 140 (defface git-ignored-face
 141   '((((class color) (background light)) (:foreground "grey60"))
 142     (((class color) (background dark)) (:foreground "grey40")))
 143   "Git mode face used to highlight ignored files."
 144   :group 'git)
 145
 146 (defface git-mark-face
 147   '((((class color) (background light)) (:foreground "red" :bold t))
 148     (((class color) (background dark)) (:foreground "tomato" :bold t)))
 149   "Git mode face used for the file marks."
 150   :group 'git)
 151
 152 (defface git-header-face
 153   '((((class color) (background light)) (:foreground "blue"))
 154     (((class color) (background dark)) (:foreground "blue")))
 155   "Git mode face used for commit headers."
 156   :group 'git)
 157
 158 (defface git-separator-face
 159   '((((class color) (background light)) (:foreground "brown"))
 160     (((class color) (background dark)) (:foreground "brown")))
 161   "Git mode face used for commit separator."
 162   :group 'git)
 163
 164 (defface git-permission-face
 165   '((((class color) (background light)) (:foreground "green" :bold t))
 166     (((class color) (background dark)) (:foreground "green" :bold t)))
 167   "Git mode face used for permission changes."
 168   :group 'git)
 169
 170
 171 ;;;; Utilities
 172 ;;;; ------------------------------------------------------------
 173
 174 (defconst git-log-msg-separator "--- log message follows this line ---")
 175
 176 (defvar git-log-edit-font-lock-keywords
 177   `(("^\\(Author:\\|Date:\\|Parent:\\|Signed-off-by:\\)\\(.*\\)$"
 178      (1 font-lock-keyword-face)
 179      (2 font-lock-function-name-face))
 180     (,(concat "^\\(" (regexp-quote git-log-msg-separator) "\\)$")
 181      (1 font-lock-comment-face))))
 182
 183 (defun git-get-env-strings (env)
 184   "Build a list of NAME=VALUE strings from a list of environment strings."
 185   (mapcar (lambda (entry) (concat (car entry) "=" (cdr entry))) env))
 186
 187 (defun git-call-process-env (buffer env &rest args)
 188   "Wrapper for call-process that sets environment strings."
 189   (if env
 190       (apply #'call-process "env" nil buffer nil
 191              (append (git-get-env-strings env) (list "git") args))
 192     (apply #'call-process "git" nil buffer nil args)))
 193
 194 (defun git-call-process-env-string (env &rest args)
 195   "Wrapper for call-process that sets environment strings,
 196 and returns the process output as a string."
 197   (with-temp-buffer
 198     (and (eq 0 (apply #' git-call-process-env t env args))
 199          (buffer-string))))
 200
 201 (defun git-run-process-region (buffer start end program args)
 202   "Run a git process with a buffer region as input."
 203   (let ((output-buffer (current-buffer))
 204         (dir default-directory))
 205     (with-current-buffer buffer
 206       (cd dir)
 207       (apply #'call-process-region start end program
 208              nil (list output-buffer nil) nil args))))
 209
 210 (defun git-run-command-buffer (buffer-name &rest args)
 211   "Run a git command, sending the output to a buffer named BUFFER-NAME."
 212   (let ((dir default-directory)
 213         (buffer (get-buffer-create buffer-name)))
 214     (message "Running git %s..." (car args))
 215     (with-current-buffer buffer
 216       (let ((default-directory dir)
 217             (buffer-read-only nil))
 218         (erase-buffer)
 219         (apply #'git-call-process-env buffer nil args)))
 220     (message "Running git %s...done" (car args))
 221     buffer))
 222
 223 (defun git-run-command-region (buffer start end env &rest args)
 224   "Run a git command with specified buffer region as input."
 225   (unless (eq 0 (if env
 226                     (git-run-process-region
 227                      buffer start end "env"
 228                      (append (git-get-env-strings env) (list "git") args))
 229                   (git-run-process-region
 230                    buffer start end "git" args)))
 231     (error "Failed to run \"git %s\":\n%s" (mapconcat (lambda (x) x) args " ") (buffer-string))))
 232
 233 (defun git-run-hook (hook env &rest args)
 234   "Run a git hook and display its output if any."
 235   (let ((dir default-directory)
 236         (hook-name (expand-file-name (concat ".git/hooks/" hook))))
 237     (or (not (file-executable-p hook-name))
 238         (let (status (buffer (get-buffer-create "*Git Hook Output*")))
 239           (with-current-buffer buffer
 240             (erase-buffer)
 241             (cd dir)
 242             (setq status
 243                   (if env
 244                       (apply #'call-process "env" nil (list buffer t) nil
 245                              (append (git-get-env-strings env) (list hook-name) args))
 246                     (apply #'call-process hook-name nil (list buffer t) nil args))))
 247           (display-message-or-buffer buffer)
 248           (eq 0 status)))))
 249
 250 (defun git-get-string-sha1 (string)
 251   "Read a SHA1 from the specified string."
 252   (and string
 253        (string-match "[0-9a-f]\\{40\\}" string)
 254        (match-string 0 string)))
 255
 256 (defun git-get-committer-name ()
 257   "Return the name to use as GIT_COMMITTER_NAME."
 258   ; copied from log-edit
 259   (or git-committer-name
 260       (git-config "user.name")
 261       (and (boundp 'add-log-full-name) add-log-full-name)
 262       (and (fboundp 'user-full-name) (user-full-name))
 263       (and (boundp 'user-full-name) user-full-name)))
 264
 265 (defun git-get-committer-email ()
 266   "Return the email address to use as GIT_COMMITTER_EMAIL."
 267   ; copied from log-edit
 268   (or git-committer-email
 269       (git-config "user.email")
 270       (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 271       (and (fboundp 'user-mail-address) (user-mail-address))
 272       (and (boundp 'user-mail-address) user-mail-address)))
 273
 274 (defun git-get-commits-coding-system ()
 275   "Return the coding system to use for commits."
 276   (let ((repo-config (git-config "i18n.commitencoding")))
 277     (or git-commits-coding-system
 278         (and repo-config
 279              (fboundp 'locale-charset-to-coding-system)
 280              (locale-charset-to-coding-system repo-config))
 281       'utf-8)))
 282
 283 (defun git-get-logoutput-coding-system ()
 284   "Return the coding system used for git-log output."
 285   (let ((repo-config (or (git-config "i18n.logoutputencoding")
 286                          (git-config "i18n.commitencoding"))))
 287     (or git-commits-coding-system
 288         (and repo-config
 289              (fboundp 'locale-charset-to-coding-system)
 290              (locale-charset-to-coding-system repo-config))
 291       'utf-8)))
 292
 293 (defun git-escape-file-name (name)
 294   "Escape a file name if necessary."
 295   (if (string-match "[\n\t\"\\]" name)
 296       (concat "\""
 297               (mapconcat (lambda (c)
 298                    (case c
 299                      (?\n "\\n")
 300                      (?\t "\\t")
 301                      (?\\ "\\\\")
 302                      (?\" "\\\"")
 303                      (t (char-to-string c))))
 304                  name "")
 305               "\"")
 306     name))
 307
 308 (defun git-success-message (text files)
 309   "Print a success message after having handled FILES."
 310   (let ((n (length files)))
 311     (if (equal n 1)
 312         (message "%s %s" text (car files))
 313       (message "%s %d files" text n))))
 314
 315 (defun git-get-top-dir (dir)
 316   "Retrieve the top-level directory of a git tree."
 317   (let ((cdup (with-output-to-string
 318                 (with-current-buffer standard-output
 319                   (cd dir)
 320                   (unless (eq 0 (call-process "git" nil t nil "rev-parse" "--show-cdup"))
 321                     (error "cannot find top-level git tree for %s." dir))))))
 322     (expand-file-name (concat (file-name-as-directory dir)
 323                               (car (split-string cdup "\n"))))))
 324
 325 ;stolen from pcl-cvs
 326 (defun git-append-to-ignore (file)
 327   "Add a file name to the ignore file in its directory."
 328   (let* ((fullname (expand-file-name file))
 329          (dir (file-name-directory fullname))
 330          (name (file-name-nondirectory fullname))
 331          (ignore-name (expand-file-name git-per-dir-ignore-file dir))
 332          (created (not (file-exists-p ignore-name))))
 333   (save-window-excursion
 334     (set-buffer (find-file-noselect ignore-name))
 335     (goto-char (point-max))
 336     (unless (zerop (current-column)) (insert "\n"))
 337     (insert "/" name "\n")
 338     (sort-lines nil (point-min) (point-max))
 339     (save-buffer))
 340   (when created
 341     (git-call-process-env nil nil "update-index" "--add" "--" (file-relative-name ignore-name)))
 342   (git-update-status-files (list (file-relative-name ignore-name)) 'unknown)))
 343
 344 ; propertize definition for XEmacs, stolen from erc-compat
 345 (eval-when-compile
 346   (unless (fboundp 'propertize)
 347     (defun propertize (string &rest props)
 348       (let ((string (copy-sequence string)))
 349         (while props
 350           (put-text-property 0 (length string) (nth 0 props) (nth 1 props) string)
 351           (setq props (cddr props)))
 352         string))))
 353
 354 ;;;; Wrappers for basic git commands
 355 ;;;; ------------------------------------------------------------
 356
 357 (defun git-rev-parse (rev)
 358   "Parse a revision name and return its SHA1."
 359   (git-get-string-sha1
 360    (git-call-process-env-string nil "rev-parse" rev)))
 361
 362 (defun git-config (key)
 363   "Retrieve the value associated to KEY in the git repository config file."
 364   (let ((str (git-call-process-env-string nil "config" key)))
 365     (and str (car (split-string str "\n")))))
 366
 367 (defun git-symbolic-ref (ref)
 368   "Wrapper for the git-symbolic-ref command."
 369   (let ((str (git-call-process-env-string nil "symbolic-ref" ref)))
 370     (and str (car (split-string str "\n")))))
 371
 372 (defun git-update-ref (ref newval &optional oldval reason)
 373   "Update a reference by calling git-update-ref."
 374   (let ((args (and oldval (list oldval))))
 375     (push newval args)
 376     (push ref args)
 377     (when reason
 378      (push reason args)
 379      (push "-m" args))
 380     (eq 0 (apply #'git-call-process-env nil nil "update-ref" args))))
 381
 382 (defun git-read-tree (tree &optional index-file)
 383   "Read a tree into the index file."
 384   (apply #'git-call-process-env nil
 385          (if index-file `(("GIT_INDEX_FILE" . ,index-file)) nil)
 386          "read-tree" (if tree (list tree))))
 387
 388 (defun git-write-tree (&optional index-file)
 389   "Call git-write-tree and return the resulting tree SHA1 as a string."
 390   (git-get-string-sha1
 391    (git-call-process-env-string (and index-file `(("GIT_INDEX_FILE" . ,index-file))) "write-tree")))
 392
 393 (defun git-commit-tree (buffer tree head)
 394   "Call git-commit-tree with buffer as input and return the resulting commit SHA1."
 395   (let ((author-name (git-get-committer-name))
 396         (author-email (git-get-committer-email))
 397         (subject "commit (initial): ")
 398         author-date log-start log-end args coding-system-for-write)
 399     (when head
 400       (setq subject "commit: ")
 401       (push "-p" args)
 402       (push head args))
 403     (with-current-buffer buffer
 404       (goto-char (point-min))
 405       (if
 406           (setq log-start (re-search-forward (concat "^" (regexp-quote git-log-msg-separator) "\n") nil t))
 407           (save-restriction
 408             (narrow-to-region (point-min) log-start)
 409             (goto-char (point-min))
 410             (when (re-search-forward "^Author: +\\(.*?\\) *<\\(.*\\)> *$" nil t)
 411               (setq author-name (match-string 1)
 412                     author-email (match-string 2)))
 413             (goto-char (point-min))
 414             (when (re-search-forward "^Date: +\\(.*\\)$" nil t)
 415               (setq author-date (match-string 1)))
 416             (goto-char (point-min))
 417             (while (re-search-forward "^Parent: +\\([0-9a-f]+\\)" nil t)
 418               (unless (string-equal head (match-string 1))
 419                 (setq subject "commit (merge): ")
 420                 (push "-p" args)
 421                 (push (match-string 1) args))))
 422         (setq log-start (point-min)))
 423       (setq log-end (point-max))
 424       (goto-char log-start)
 425       (when (re-search-forward ".*$" nil t)
 426         (setq subject (concat subject (match-string 0))))
 427       (setq coding-system-for-write buffer-file-coding-system))
 428     (let ((commit
 429            (git-get-string-sha1
 430             (with-output-to-string
 431               (with-current-buffer standard-output
 432                 (let ((env `(("GIT_AUTHOR_NAME" . ,author-name)
 433                              ("GIT_AUTHOR_EMAIL" . ,author-email)
 434                              ("GIT_COMMITTER_NAME" . ,(git-get-committer-name))
 435                              ("GIT_COMMITTER_EMAIL" . ,(git-get-committer-email)))))
 436                   (when author-date (push `("GIT_AUTHOR_DATE" . ,author-date) env))
 437                   (apply #'git-run-command-region
 438                          buffer log-start log-end env
 439                          "commit-tree" tree (nreverse args))))))))
 440       (and (git-update-ref "HEAD" commit head subject)
 441            commit))))
 442
 443 (defun git-empty-db-p ()
 444   "Check if the git db is empty (no commit done yet)."
 445   (not (eq 0 (call-process "git" nil nil nil "rev-parse" "--verify" "HEAD"))))
 446
 447 (defun git-get-merge-heads ()
 448   "Retrieve the merge heads from the MERGE_HEAD file if present."
 449   (let (heads)
 450     (when (file-readable-p ".git/MERGE_HEAD")
 451       (with-temp-buffer
 452         (insert-file-contents ".git/MERGE_HEAD" nil nil nil t)
 453         (goto-char (point-min))
 454         (while (re-search-forward "[0-9a-f]\\{40\\}" nil t)
 455           (push (match-string 0) heads))))
 456     (nreverse heads)))
 457
 458 (defun git-get-commit-description (commit)
 459   "Get a one-line description of COMMIT."
 460   (let ((coding-system-for-read (git-get-logoutput-coding-system)))
 461     (let ((descr (git-call-process-env-string nil "log" "--max-count=1" "--pretty=oneline" commit)))
 462       (if (and descr (string-match "\\`\\([0-9a-f]\\{40\\}\\) *\\(.*\\)$" descr))
 463           (concat (substring (match-string 1 descr) 0 10) " - " (match-string 2 descr))
 464         descr))))
 465
 466 ;;;; File info structure
 467 ;;;; ------------------------------------------------------------
 468
 469 ; fileinfo structure stolen from pcl-cvs
 470 (defstruct (git-fileinfo
 471             (:copier nil)
 472             (:constructor git-create-fileinfo (state name &optional old-perm new-perm rename-state orig-name marked))
 473             (:conc-name git-fileinfo->))
 474   marked              ;; t/nil
 475   state               ;; current state
 476   name                ;; file name
 477   old-perm new-perm   ;; permission flags
 478   rename-state        ;; rename or copy state
 479   orig-name           ;; original name for renames or copies
 480   needs-refresh)      ;; whether file needs to be refreshed
 481
 482 (defvar git-status nil)
 483
 484 (defun git-clear-status (status)
 485   "Remove everything from the status list."
 486   (ewoc-filter status (lambda (info) nil)))
 487
 488 (defun git-set-files-state (files state)
 489   "Set the state of a list of files."
 490   (dolist (info files)
 491     (unless (eq (git-fileinfo->state info) state)
 492       (setf (git-fileinfo->state info) state)
 493       (setf (git-fileinfo->rename-state info) nil)
 494       (setf (git-fileinfo->orig-name info) nil)
 495       (setf (git-fileinfo->needs-refresh info) t))))
 496
 497 (defun git-status-filenames-map (status func files &rest args)
 498   "Apply FUNC to the status files names in the FILES list."
 499   (when files
 500     (setq files (sort files #'string-lessp))
 501     (let ((file (pop files))
 502           (node (ewoc-nth status 0)))
 503       (while (and file node)
 504         (let ((info (ewoc-data node)))
 505           (if (string-lessp (git-fileinfo->name info) file)
 506               (setq node (ewoc-next status node))
 507             (if (string-equal (git-fileinfo->name info) file)
 508                 (apply func info args))
 509             (setq file (pop files))))))))
 510
 511 (defun git-set-filenames-state (status files state)
 512   "Set the state of a list of named files."
 513   (when files
 514     (git-status-filenames-map status
 515                               (lambda (info state)
 516                                 (unless (eq (git-fileinfo->state info) state)
 517                                   (setf (git-fileinfo->state info) state)
 518                                   (setf (git-fileinfo->rename-state info) nil)
 519                                   (setf (git-fileinfo->orig-name info) nil)
 520                                   (setf (git-fileinfo->needs-refresh info) t)))
 521                               files state)
 522     (unless state  ;; delete files whose state has been set to nil
 523       (ewoc-filter status (lambda (info) (git-fileinfo->state info))))))
 524
 525 (defun git-state-code (code)
 526   "Convert from a string to a added/deleted/modified state."
 527   (case (string-to-char code)
 528     (?M 'modified)
 529     (?? 'unknown)
 530     (?A 'added)
 531     (?D 'deleted)
 532     (?U 'unmerged)
 533     (t nil)))
 534
 535 (defun git-status-code-as-string (code)
 536   "Format a git status code as string."
 537   (case code
 538     ('modified (propertize "Modified" 'face 'git-status-face))
 539     ('unknown  (propertize "Unknown " 'face 'git-unknown-face))
 540     ('added    (propertize "Added   " 'face 'git-status-face))
 541     ('deleted  (propertize "Deleted " 'face 'git-status-face))
 542     ('unmerged (propertize "Unmerged" 'face 'git-unmerged-face))
 543     ('uptodate (propertize "Uptodate" 'face 'git-uptodate-face))
 544     ('ignored  (propertize "Ignored " 'face 'git-ignored-face))
 545     (t "?       ")))
 546
 547 (defun git-rename-as-string (info)
 548   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 549   (let ((state (git-fileinfo->rename-state info)))
 550     (if state
 551         (propertize
 552          (concat "   ("
 553                  (if (eq state 'copy) "copied from "
 554                    (if (eq (git-fileinfo->state info) 'added) "renamed from "
 555                      "renamed to "))
 556                  (git-escape-file-name (git-fileinfo->orig-name info))
 557                  ")") 'face 'git-status-face)
 558       "")))
 559
 560 (defun git-permissions-as-string (old-perm new-perm)
 561   "Format a permission change as string."
 562   (propertize
 563    (if (or (not old-perm)
 564            (not new-perm)
 565            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 566        "  "
 567      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 568   'face 'git-permission-face))
 569
 570 (defun git-fileinfo-prettyprint (info)
 571   "Pretty-printer for the git-fileinfo structure."
 572   (insert (concat "   " (if (git-fileinfo->marked info) (propertize "*" 'face 'git-mark-face) " ")
 573                   " " (git-status-code-as-string (git-fileinfo->state info))
 574                   " " (git-permissions-as-string (git-fileinfo->old-perm info) (git-fileinfo->new-perm info))
 575                   "  " (git-escape-file-name (git-fileinfo->name info))
 576                   (git-rename-as-string info))))
 577
 578 (defun git-insert-info-list (status infolist)
 579   "Insert a list of file infos in the status buffer, replacing existing ones if any."
 580   (setq infolist (sort infolist
 581                        (lambda (info1 info2)
 582                          (string-lessp (git-fileinfo->name info1)
 583                                        (git-fileinfo->name info2)))))
 584   (let ((info (pop infolist))
 585         (node (ewoc-nth status 0)))
 586     (while info
 587       (setf (git-fileinfo->needs-refresh info) t)
 588       (cond ((not node)
 589              (ewoc-enter-last status info)
 590              (setq info (pop infolist)))
 591             ((string-lessp (git-fileinfo->name (ewoc-data node))
 592                            (git-fileinfo->name info))
 593              (setq node (ewoc-next status node)))
 594             ((string-equal (git-fileinfo->name (ewoc-data node))
 595                            (git-fileinfo->name info))
 596               ;; preserve the marked flag
 597               (setf (git-fileinfo->marked info) (git-fileinfo->marked (ewoc-data node)))
 598               (setf (ewoc-data node) info)
 599               (setq info (pop infolist)))
 600             (t
 601              (ewoc-enter-before status node info)
 602              (setq info (pop infolist)))))))
 603
 604 (defun git-run-diff-index (status files)
 605   "Run git-diff-index on FILES and parse the results into STATUS.
 606 Return the list of files that haven't been handled."
 607   (let (infolist)
 608     (with-temp-buffer
 609       (apply #'git-call-process-env t nil "diff-index" "-z" "-M" "HEAD" "--" files)
 610       (goto-char (point-min))
 611       (while (re-search-forward
 612               ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMU]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 613               nil t 1)
 614         (let ((old-perm (string-to-number (match-string 1) 8))
 615               (new-perm (string-to-number (match-string 2) 8))
 616               (state (or (match-string 4) (match-string 6)))
 617               (name (or (match-string 5) (match-string 7)))
 618               (new-name (match-string 8)))
 619           (if new-name  ; copy or rename
 620               (if (eq ?C (string-to-char state))
 621                   (push (git-create-fileinfo 'added new-name old-perm new-perm 'copy name) infolist)
 622                 (push (git-create-fileinfo 'deleted name 0 0 'rename new-name) infolist)
 623                 (push (git-create-fileinfo 'added new-name old-perm new-perm 'rename name) infolist))
 624             (push (git-create-fileinfo (git-state-code state) name old-perm new-perm) infolist))
 625           (setq files (delete name files))
 626           (when new-name (setq files (delete new-name files))))))
 627     (git-insert-info-list status infolist)
 628     files))
 629
 630 (defun git-find-status-file (status file)
 631   "Find a given file in the status ewoc and return its node."
 632   (let ((node (ewoc-nth status 0)))
 633     (while (and node (not (string= file (git-fileinfo->name (ewoc-data node)))))
 634       (setq node (ewoc-next status node)))
 635     node))
 636
 637 (defun git-run-ls-files (status files default-state &rest options)
 638   "Run git-ls-files on FILES and parse the results into STATUS.
 639 Return the list of files that haven't been handled."
 640   (let (infolist)
 641     (with-temp-buffer
 642       (apply #'git-call-process-env t nil "ls-files" "-z" (append options (list "--") files))
 643       (goto-char (point-min))
 644       (while (re-search-forward "\\([^\0]*\\)\0" nil t 1)
 645         (let ((name (match-string 1)))
 646           (push (git-create-fileinfo default-state name) infolist)
 647           (setq files (delete name files)))))
 648     (git-insert-info-list status infolist)
 649     files))
 650
 651 (defun git-run-ls-unmerged (status files)
 652   "Run git-ls-files -u on FILES and parse the results into STATUS."
 653   (with-temp-buffer
 654     (apply #'git-call-process-env t nil "ls-files" "-z" "-u" "--" files)
 655     (goto-char (point-min))
 656     (let (unmerged-files)
 657       (while (re-search-forward "[0-7]\\{6\\} [0-9a-f]\\{40\\} [123]\t\\([^\0]+\\)\0" nil t)
 658         (push (match-string 1) unmerged-files))
 659       (git-set-filenames-state status unmerged-files 'unmerged))))
 660
 661 (defun git-get-exclude-files ()
 662   "Get the list of exclude files to pass to git-ls-files."
 663   (let (files
 664         (config (git-config "core.excludesfile")))
 665     (when (file-readable-p ".git/info/exclude")
 666       (push ".git/info/exclude" files))
 667     (when (and config (file-readable-p config))
 668       (push config files))
 669     files))
 670
 671 (defun git-run-ls-files-with-excludes (status files default-state &rest options)
 672   "Run git-ls-files on FILES with appropriate --exclude-from options."
 673   (let ((exclude-files (git-get-exclude-files)))
 674     (apply #'git-run-ls-files status files default-state
 675            (concat "--exclude-per-directory=" git-per-dir-ignore-file)
 676            (append options (mapcar (lambda (f) (concat "--exclude-from=" f)) exclude-files)))))
 677
 678 (defun git-update-status-files (files &optional default-state)
 679   "Update the status of FILES from the index."
 680   (unless git-status (error "Not in git-status buffer."))
 681   (unless files
 682     (when git-show-uptodate (git-run-ls-files git-status nil 'uptodate "-c")))
 683   (let* ((remaining-files
 684           (if (git-empty-db-p) ; we need some special handling for an empty db
 685               (git-run-ls-files git-status files 'added "-c")
 686             (git-run-diff-index git-status files))))
 687     (git-run-ls-unmerged git-status files)
 688     (when (or remaining-files (and git-show-unknown (not files)))
 689       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'unknown "-o")))
 690     (when (or remaining-files (and git-show-ignored (not files)))
 691       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'ignored "-o" "-i")))
 692     (git-set-filenames-state git-status remaining-files default-state)
 693     (git-refresh-files)
 694     (git-refresh-ewoc-hf git-status)))
 695
 696 (defun git-marked-files ()
 697   "Return a list of all marked files, or if none a list containing just the file at cursor position."
 698   (unless git-status (error "Not in git-status buffer."))
 699   (or (ewoc-collect git-status (lambda (info) (git-fileinfo->marked info)))
 700       (list (ewoc-data (ewoc-locate git-status)))))
 701
 702 (defun git-marked-files-state (&rest states)
 703   "Return marked files that are in the specified states."
 704   (let ((files (git-marked-files))
 705         result)
 706     (dolist (info files)
 707       (when (memq (git-fileinfo->state info) states)
 708         (push info result)))
 709     result))
 710
 711 (defun git-refresh-files ()
 712   "Refresh all files that need it and clear the needs-refresh flag."
 713   (unless git-status (error "Not in git-status buffer."))
 714   (ewoc-map
 715    (lambda (info)
 716      (let ((refresh (git-fileinfo->needs-refresh info)))
 717        (setf (git-fileinfo->needs-refresh info) nil)
 718        refresh))
 719    git-status)
 720   ; move back to goal column
 721   (when goal-column (move-to-column goal-column)))
 722
 723 (defun git-refresh-ewoc-hf (status)
 724   "Refresh the ewoc header and footer."
 725   (let ((branch (git-symbolic-ref "HEAD"))
 726         (head (if (git-empty-db-p) "Nothing committed yet"
 727                 (git-get-commit-description "HEAD")))
 728         (merge-heads (git-get-merge-heads)))
 729     (ewoc-set-hf status
 730                  (format "Directory:  %s\nBranch:     %s\nHead:       %s%s\n"
 731                          default-directory
 732                          (if branch
 733                              (if (string-match "^refs/heads/" branch)
 734                                  (substring branch (match-end 0))
 735                                branch)
 736                            "none (detached HEAD)")
 737                          head
 738                          (if merge-heads
 739                              (concat "\nMerging:    "
 740                                      (mapconcat (lambda (str) (git-get-commit-description str)) merge-heads "\n            "))
 741                            ""))
 742                  (if (ewoc-nth status 0) "" "    No changes."))))
 743
 744 (defun git-get-filenames (files)
 745   (mapcar (lambda (info) (git-fileinfo->name info)) files))
 746
 747 (defun git-update-index (index-file files)
 748   "Run git-update-index on a list of files."
 749   (let ((env (and index-file `(("GIT_INDEX_FILE" . ,index-file))))
 750         added deleted modified)
 751     (dolist (info files)
 752       (case (git-fileinfo->state info)
 753         ('added (push info added))
 754         ('deleted (push info deleted))
 755         ('modified (push info modified))))
 756     (when added
 757       (apply #'git-call-process-env nil env "update-index" "--add" "--" (git-get-filenames added)))
 758     (when deleted
 759       (apply #'git-call-process-env nil env "update-index" "--remove" "--" (git-get-filenames deleted)))
 760     (when modified
 761       (apply #'git-call-process-env nil env "update-index" "--" (git-get-filenames modified)))))
 762
 763 (defun git-run-pre-commit-hook ()
 764   "Run the pre-commit hook if any."
 765   (unless git-status (error "Not in git-status buffer."))
 766   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
 767     (or (not files)
 768         (not (file-executable-p ".git/hooks/pre-commit"))
 769         (let ((index-file (make-temp-file "gitidx")))
 770           (unwind-protect
 771             (let ((head-tree (unless (git-empty-db-p) (git-rev-parse "HEAD^{tree}"))))
 772               (git-read-tree head-tree index-file)
 773               (git-update-index index-file files)
 774               (git-run-hook "pre-commit" `(("GIT_INDEX_FILE" . ,index-file))))
 775           (delete-file index-file))))))
 776
 777 (defun git-do-commit ()
 778   "Perform the actual commit using the current buffer as log message."
 779   (interactive)
 780   (let ((buffer (current-buffer))
 781         (index-file (make-temp-file "gitidx")))
 782     (with-current-buffer log-edit-parent-buffer
 783       (if (git-marked-files-state 'unmerged)
 784           (message "You cannot commit unmerged files, resolve them first.")
 785         (unwind-protect
 786             (let ((files (git-marked-files-state 'added 'deleted 'modified))
 787                   head head-tree)
 788               (unless (git-empty-db-p)
 789                 (setq head (git-rev-parse "HEAD")
 790                       head-tree (git-rev-parse "HEAD^{tree}")))
 791               (if files
 792                   (progn
 793                     (message "Running git commit...")
 794                     (git-read-tree head-tree index-file)
 795                     (git-update-index nil files)         ;update both the default index
 796                     (git-update-index index-file files)  ;and the temporary one
 797                     (let ((tree (git-write-tree index-file)))
 798                       (if (or (not (string-equal tree head-tree))
 799                               (yes-or-no-p "The tree was not modified, do you really want to perform an empty commit? "))
 800                           (let ((commit (git-commit-tree buffer tree head)))
 801                             (condition-case nil (delete-file ".git/MERGE_HEAD") (error nil))
 802                             (condition-case nil (delete-file ".git/MERGE_MSG") (error nil))
 803                             (with-current-buffer buffer (erase-buffer))
 804                             (git-set-files-state files 'uptodate)
 805                             (git-call-process-env nil nil "rerere")
 806                             (git-refresh-files)
 807                             (git-refresh-ewoc-hf git-status)
 808                             (message "Committed %s." commit)
 809                             (git-run-hook "post-commit" nil))
 810                         (message "Commit aborted."))))
 811                 (message "No files to commit.")))
 812           (delete-file index-file))))))
 813
 814
 815 ;;;; Interactive functions
 816 ;;;; ------------------------------------------------------------
 817
 818 (defun git-mark-file ()
 819   "Mark the file that the cursor is on and move to the next one."
 820   (interactive)
 821   (unless git-status (error "Not in git-status buffer."))
 822   (let* ((pos (ewoc-locate git-status))
 823          (info (ewoc-data pos)))
 824     (setf (git-fileinfo->marked info) t)
 825     (ewoc-invalidate git-status pos)
 826     (ewoc-goto-next git-status 1)))
 827
 828 (defun git-unmark-file ()
 829   "Unmark the file that the cursor is on and move to the next one."
 830   (interactive)
 831   (unless git-status (error "Not in git-status buffer."))
 832   (let* ((pos (ewoc-locate git-status))
 833          (info (ewoc-data pos)))
 834     (setf (git-fileinfo->marked info) nil)
 835     (ewoc-invalidate git-status pos)
 836     (ewoc-goto-next git-status 1)))
 837
 838 (defun git-unmark-file-up ()
 839   "Unmark the file that the cursor is on and move to the previous one."
 840   (interactive)
 841   (unless git-status (error "Not in git-status buffer."))
 842   (let* ((pos (ewoc-locate git-status))
 843          (info (ewoc-data pos)))
 844     (setf (git-fileinfo->marked info) nil)
 845     (ewoc-invalidate git-status pos)
 846     (ewoc-goto-prev git-status 1)))
 847
 848 (defun git-mark-all ()
 849   "Mark all files."
 850   (interactive)
 851   (unless git-status (error "Not in git-status buffer."))
 852   (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) t) t) git-status)
 853   ; move back to goal column after invalidate
 854   (when goal-column (move-to-column goal-column)))
 855
 856 (defun git-unmark-all ()
 857   "Unmark all files."
 858   (interactive)
 859   (unless git-status (error "Not in git-status buffer."))
 860   (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) nil) t) git-status)
 861   ; move back to goal column after invalidate
 862   (when goal-column (move-to-column goal-column)))
 863
 864 (defun git-toggle-all-marks ()
 865   "Toggle all file marks."
 866   (interactive)
 867   (unless git-status (error "Not in git-status buffer."))
 868   (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) (not (git-fileinfo->marked info))) t) git-status)
 869   ; move back to goal column after invalidate
 870   (when goal-column (move-to-column goal-column)))
 871
 872 (defun git-next-file (&optional n)
 873   "Move the selection down N files."
 874   (interactive "p")
 875   (unless git-status (error "Not in git-status buffer."))
 876   (ewoc-goto-next git-status n))
 877
 878 (defun git-prev-file (&optional n)
 879   "Move the selection up N files."
 880   (interactive "p")
 881   (unless git-status (error "Not in git-status buffer."))
 882   (ewoc-goto-prev git-status n))
 883
 884 (defun git-next-unmerged-file (&optional n)
 885   "Move the selection down N unmerged files."
 886   (interactive "p")
 887   (unless git-status (error "Not in git-status buffer."))
 888   (let* ((last (ewoc-locate git-status))
 889          (node (ewoc-next git-status last)))
 890     (while (and node (> n 0))
 891       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 892         (setq n (1- n))
 893         (setq last node))
 894       (setq node (ewoc-next git-status node)))
 895     (ewoc-goto-node git-status last)))
 896
 897 (defun git-prev-unmerged-file (&optional n)
 898   "Move the selection up N unmerged files."
 899   (interactive "p")
 900   (unless git-status (error "Not in git-status buffer."))
 901   (let* ((last (ewoc-locate git-status))
 902          (node (ewoc-prev git-status last)))
 903     (while (and node (> n 0))
 904       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 905         (setq n (1- n))
 906         (setq last node))
 907       (setq node (ewoc-prev git-status node)))
 908     (ewoc-goto-node git-status last)))
 909
 910 (defun git-add-file ()
 911   "Add marked file(s) to the index cache."
 912   (interactive)
 913   (let ((files (git-get-filenames (git-marked-files-state 'unknown 'ignored))))
 914     (unless files
 915       (push (file-relative-name (read-file-name "File to add: " nil nil t)) files))
 916     (apply #'git-call-process-env nil nil "update-index" "--add" "--" files)
 917     (git-update-status-files files 'uptodate)
 918     (git-success-message "Added" files)))
 919
 920 (defun git-ignore-file ()
 921   "Add marked file(s) to the ignore list."
 922   (interactive)
 923   (let ((files (git-get-filenames (git-marked-files-state 'unknown))))
 924     (unless files
 925       (push (file-relative-name (read-file-name "File to ignore: " nil nil t)) files))
 926     (dolist (f files) (git-append-to-ignore f))
 927     (git-update-status-files files 'ignored)
 928     (git-success-message "Ignored" files)))
 929
 930 (defun git-remove-file ()
 931   "Remove the marked file(s)."
 932   (interactive)
 933   (let ((files (git-get-filenames (git-marked-files-state 'added 'modified 'unknown 'uptodate 'ignored))))
 934     (unless files
 935       (push (file-relative-name (read-file-name "File to remove: " nil nil t)) files))
 936     (if (yes-or-no-p
 937          (format "Remove %d file%s? " (length files) (if (> (length files) 1) "s" "")))
 938         (progn
 939           (dolist (name files)
 940             (when (file-exists-p name) (delete-file name)))
 941           (apply #'git-call-process-env nil nil "update-index" "--remove" "--" files)
 942           (git-update-status-files files nil)
 943           (git-success-message "Removed" files))
 944       (message "Aborting"))))
 945
 946 (defun git-revert-file ()
 947   "Revert changes to the marked file(s)."
 948   (interactive)
 949   (let ((files (git-marked-files))
 950         added modified)
 951     (when (and files
 952                (yes-or-no-p
 953                 (format "Revert %d file%s? " (length files) (if (> (length files) 1) "s" ""))))
 954       (dolist (info files)
 955         (case (git-fileinfo->state info)
 956           ('added (push (git-fileinfo->name info) added))
 957           ('deleted (push (git-fileinfo->name info) modified))
 958           ('unmerged (push (git-fileinfo->name info) modified))
 959           ('modified (push (git-fileinfo->name info) modified))))
 960       (when added
 961         (apply #'git-call-process-env nil nil "update-index" "--force-remove" "--" added))
 962       (when modified
 963         (apply #'git-call-process-env nil nil "checkout" "HEAD" modified))
 964       (git-update-status-files (append added modified) 'uptodate)
 965       (git-success-message "Reverted" files))))
 966
 967 (defun git-resolve-file ()
 968   "Resolve conflicts in marked file(s)."
 969   (interactive)
 970   (let ((files (git-get-filenames (git-marked-files-state 'unmerged))))
 971     (when files
 972       (apply #'git-call-process-env nil nil "update-index" "--" files)
 973       (git-update-status-files files 'uptodate)
 974       (git-success-message "Resolved" files))))
 975
 976 (defun git-remove-handled ()
 977   "Remove handled files from the status list."
 978   (interactive)
 979   (ewoc-filter git-status
 980                (lambda (info)
 981                  (case (git-fileinfo->state info)
 982                    ('ignored git-show-ignored)
 983                    ('uptodate git-show-uptodate)
 984                    ('unknown git-show-unknown)
 985                    (t t))))
 986   (unless (ewoc-nth git-status 0)  ; refresh header if list is empty
 987     (git-refresh-ewoc-hf git-status)))
 988
 989 (defun git-toggle-show-uptodate ()
 990   "Toogle the option for showing up-to-date files."
 991   (interactive)
 992   (if (setq git-show-uptodate (not git-show-uptodate))
 993       (git-refresh-status)
 994     (git-remove-handled)))
 995
 996 (defun git-toggle-show-ignored ()
 997   "Toogle the option for showing ignored files."
 998   (interactive)
 999   (if (setq git-show-ignored (not git-show-ignored))
1000       (progn
1001         (message "Inserting ignored files...")
1002         (git-run-ls-files-with-excludes git-status nil 'ignored "-o" "-i")
1003         (git-refresh-files)
1004         (git-refresh-ewoc-hf git-status)
1005         (message "Inserting ignored files...done"))
1006     (git-remove-handled)))
1007
1008 (defun git-toggle-show-unknown ()
1009   "Toogle the option for showing unknown files."
1010   (interactive)
1011   (if (setq git-show-unknown (not git-show-unknown))
1012       (progn
1013         (message "Inserting unknown files...")
1014         (git-run-ls-files-with-excludes git-status nil 'unknown "-o")
1015         (git-refresh-files)
1016         (git-refresh-ewoc-hf git-status)
1017         (message "Inserting unknown files...done"))
1018     (git-remove-handled)))
1019
1020 (defun git-setup-diff-buffer (buffer)
1021   "Setup a buffer for displaying a diff."
1022   (let ((dir default-directory))
1023     (with-current-buffer buffer
1024       (diff-mode)
1025       (goto-char (point-min))
1026       (setq default-directory dir)
1027       (setq buffer-read-only t)))
1028   (display-buffer buffer)
1029   (shrink-window-if-larger-than-buffer))
1030
1031 (defun git-diff-file ()
1032   "Diff the marked file(s) against HEAD."
1033   (interactive)
1034   (let ((files (git-marked-files)))
1035     (git-setup-diff-buffer
1036      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M" "HEAD" "--" (git-get-filenames files)))))
1037
1038 (defun git-diff-file-merge-head (arg)
1039   "Diff the marked file(s) against the first merge head (or the nth one with a numeric prefix)."
1040   (interactive "p")
1041   (let ((files (git-marked-files))
1042         (merge-heads (git-get-merge-heads)))
1043     (unless merge-heads (error "No merge in progress"))
1044     (git-setup-diff-buffer
1045      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M"
1046             (or (nth (1- arg) merge-heads) "HEAD") "--" (git-get-filenames files)))))
1047
1048 (defun git-diff-unmerged-file (stage)
1049   "Diff the marked unmerged file(s) against the specified stage."
1050   (let ((files (git-marked-files)))
1051     (git-setup-diff-buffer
1052      (apply #'git-run-command-buffer "*git-diff*" "diff-files" "-p" stage "--" (git-get-filenames files)))))
1053
1054 (defun git-diff-file-base ()
1055   "Diff the marked unmerged file(s) against the common base file."
1056   (interactive)
1057   (git-diff-unmerged-file "-1"))
1058
1059 (defun git-diff-file-mine ()
1060   "Diff the marked unmerged file(s) against my pre-merge version."
1061   (interactive)
1062   (git-diff-unmerged-file "-2"))
1063
1064 (defun git-diff-file-other ()
1065   "Diff the marked unmerged file(s) against the other's pre-merge version."
1066   (interactive)
1067   (git-diff-unmerged-file "-3"))
1068
1069 (defun git-diff-file-combined ()
1070   "Do a combined diff of the marked unmerged file(s)."
1071   (interactive)
1072   (git-diff-unmerged-file "-c"))
1073
1074 (defun git-diff-file-idiff ()
1075   "Perform an interactive diff on the current file."
1076   (interactive)
1077   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
1078     (unless (eq 1 (length files))
1079       (error "Cannot perform an interactive diff on multiple files."))
1080     (let* ((filename (car (git-get-filenames files)))
1081            (buff1 (find-file-noselect filename))
1082            (buff2 (git-run-command-buffer (concat filename ".~HEAD~") "cat-file" "blob" (concat "HEAD:" filename))))
1083       (ediff-buffers buff1 buff2))))
1084
1085 (defun git-log-file ()
1086   "Display a log of changes to the marked file(s)."
1087   (interactive)
1088   (let* ((files (git-marked-files))
1089          (coding-system-for-read git-commits-coding-system)
1090          (buffer (apply #'git-run-command-buffer "*git-log*" "rev-list" "--pretty" "HEAD" "--" (git-get-filenames files))))
1091     (with-current-buffer buffer
1092       ; (git-log-mode)  FIXME: implement log mode
1093       (goto-char (point-min))
1094       (setq buffer-read-only t))
1095     (display-buffer buffer)))
1096
1097 (defun git-log-edit-files ()
1098   "Return a list of marked files for use in the log-edit buffer."
1099   (with-current-buffer log-edit-parent-buffer
1100     (git-get-filenames (git-marked-files-state 'added 'deleted 'modified))))
1101
1102 (defun git-append-sign-off (name email)
1103   "Append a Signed-off-by entry to the current buffer, avoiding duplicates."
1104   (let ((sign-off (format "Signed-off-by: %s <%s>" name email))
1105         (case-fold-search t))
1106     (goto-char (point-min))
1107     (unless (re-search-forward (concat "^" (regexp-quote sign-off)) nil t)
1108       (goto-char (point-min))
1109       (unless (re-search-forward "^Signed-off-by: " nil t)
1110         (setq sign-off (concat "\n" sign-off)))
1111       (goto-char (point-max))
1112       (insert sign-off "\n"))))
1113
1114 (defun git-setup-log-buffer (buffer &optional author-name author-email subject date msg)
1115   "Setup the log buffer for a commit."
1116   (unless git-status (error "Not in git-status buffer."))
1117   (let ((merge-heads (git-get-merge-heads))
1118         (dir default-directory)
1119         (committer-name (git-get-committer-name))
1120         (committer-email (git-get-committer-email))
1121         (sign-off git-append-signed-off-by))
1122     (with-current-buffer buffer
1123       (cd dir)
1124       (erase-buffer)
1125       (insert
1126        (propertize
1127         (format "Author: %s <%s>\n%s%s"
1128                 (or author-name committer-name)
1129                 (or author-email committer-email)
1130                 (if date (format "Date: %s\n" date) "")
1131                 (if merge-heads
1132                     (format "Parent: %s\n%s\n"
1133                             (git-rev-parse "HEAD")
1134                             (mapconcat (lambda (str) (concat "Parent: " str)) merge-heads "\n"))
1135                   ""))
1136         'face 'git-header-face)
1137        (propertize git-log-msg-separator 'face 'git-separator-face)
1138        "\n")
1139       (when subject (insert subject "\n\n"))
1140       (cond (msg (insert msg "\n"))
1141             ((file-readable-p ".dotest/msg")
1142              (insert-file-contents ".dotest/msg"))
1143             ((file-readable-p ".git/MERGE_MSG")
1144              (insert-file-contents ".git/MERGE_MSG")))
1145       ; delete empty lines at end
1146       (goto-char (point-min))
1147       (when (re-search-forward "\n+\\'" nil t)
1148         (replace-match "\n" t t))
1149       (when sign-off (git-append-sign-off committer-name committer-email)))))
1150
1151 (defun git-commit-file ()
1152   "Commit the marked file(s), asking for a commit message."
1153   (interactive)
1154   (unless git-status (error "Not in git-status buffer."))
1155   (when (git-run-pre-commit-hook)
1156     (let ((buffer (get-buffer-create "*git-commit*"))
1157           (coding-system (git-get-commits-coding-system))
1158           author-name author-email subject date)
1159       (when (eq 0 (buffer-size buffer))
1160         (when (file-readable-p ".dotest/info")
1161           (with-temp-buffer
1162             (insert-file-contents ".dotest/info")
1163             (goto-char (point-min))
1164             (when (re-search-forward "^Author: \\(.*\\)\nEmail: \\(.*\\)$" nil t)
1165               (setq author-name (match-string 1))
1166               (setq author-email (match-string 2)))
1167             (goto-char (point-min))
1168             (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
1169               (setq subject (match-string 1)))
1170             (goto-char (point-min))
1171             (when (re-search-forward "^Date: \\(.*\\)$" nil t)
1172               (setq date (match-string 1)))))
1173         (git-setup-log-buffer buffer author-name author-email subject date))
1174       (log-edit #'git-do-commit nil #'git-log-edit-files buffer)
1175       (setq font-lock-keywords (font-lock-compile-keywords git-log-edit-font-lock-keywords))
1176       (setq buffer-file-coding-system coding-system)
1177       (re-search-forward (regexp-quote (concat git-log-msg-separator "\n")) nil t))))
1178
1179 (defun git-find-file ()
1180   "Visit the current file in its own buffer."
1181   (interactive)
1182   (unless git-status (error "Not in git-status buffer."))
1183   (let ((info (ewoc-data (ewoc-locate git-status))))
1184     (find-file (git-fileinfo->name info))
1185     (when (eq 'unmerged (git-fileinfo->state info))
1186       (smerge-mode 1))))
1187
1188 (defun git-find-file-other-window ()
1189   "Visit the current file in its own buffer in another window."
1190   (interactive)
1191   (unless git-status (error "Not in git-status buffer."))
1192   (let ((info (ewoc-data (ewoc-locate git-status))))
1193     (find-file-other-window (git-fileinfo->name info))
1194     (when (eq 'unmerged (git-fileinfo->state info))
1195       (smerge-mode))))
1196
1197 (defun git-find-file-imerge ()
1198   "Visit the current file in interactive merge mode."
1199   (interactive)
1200   (unless git-status (error "Not in git-status buffer."))
1201   (let ((info (ewoc-data (ewoc-locate git-status))))
1202     (find-file (git-fileinfo->name info))
1203     (smerge-ediff)))
1204
1205 (defun git-view-file ()
1206   "View the current file in its own buffer."
1207   (interactive)
1208   (unless git-status (error "Not in git-status buffer."))
1209   (let ((info (ewoc-data (ewoc-locate git-status))))
1210     (view-file (git-fileinfo->name info))))
1211
1212 (defun git-refresh-status ()
1213   "Refresh the git status buffer."
1214   (interactive)
1215   (let* ((status git-status)
1216          (pos (ewoc-locate status))
1217          (marked-files (git-get-filenames (ewoc-collect status (lambda (info) (git-fileinfo->marked info)))))
1218          (cur-name (and pos (git-fileinfo->name (ewoc-data pos)))))
1219     (unless status (error "Not in git-status buffer."))
1220     (message "Refreshing git status...")
1221     (git-call-process-env nil nil "update-index" "--refresh")
1222     (git-clear-status status)
1223     (git-update-status-files nil)
1224     ; restore file marks
1225     (when marked-files
1226       (git-status-filenames-map status
1227                                 (lambda (info)
1228                                         (setf (git-fileinfo->marked info) t)
1229                                         (setf (git-fileinfo->needs-refresh info) t))
1230                                 marked-files)
1231       (git-refresh-files))
1232     ; move point to the current file name if any
1233     (message "Refreshing git status...done")
1234     (let ((node (and cur-name (git-find-status-file status cur-name))))
1235       (when node (ewoc-goto-node status node)))))
1236
1237 (defun git-status-quit ()
1238   "Quit git-status mode."
1239   (interactive)
1240   (bury-buffer))
1241
1242 ;;;; Major Mode
1243 ;;;; ------------------------------------------------------------
1244
1245 (defvar git-status-mode-hook nil
1246   "Run after `git-status-mode' is setup.")
1247
1248 (defvar git-status-mode-map nil
1249   "Keymap for git major mode.")
1250
1251 (defvar git-status nil
1252   "List of all files managed by the git-status mode.")
1253
1254 (unless git-status-mode-map
1255   (let ((map (make-keymap))
1256         (diff-map (make-sparse-keymap))
1257         (toggle-map (make-sparse-keymap)))
1258     (suppress-keymap map)
1259     (define-key map "?"   'git-help)
1260     (define-key map "h"   'git-help)
1261     (define-key map " "   'git-next-file)
1262     (define-key map "a"   'git-add-file)
1263     (define-key map "c"   'git-commit-file)
1264     (define-key map "d"    diff-map)
1265     (define-key map "="   'git-diff-file)
1266     (define-key map "f"   'git-find-file)
1267     (define-key map "\r"  'git-find-file)
1268     (define-key map "g"   'git-refresh-status)
1269     (define-key map "i"   'git-ignore-file)
1270     (define-key map "l"   'git-log-file)
1271     (define-key map "m"   'git-mark-file)
1272     (define-key map "M"   'git-mark-all)
1273     (define-key map "n"   'git-next-file)
1274     (define-key map "N"   'git-next-unmerged-file)
1275     (define-key map "o"   'git-find-file-other-window)
1276     (define-key map "p"   'git-prev-file)
1277     (define-key map "P"   'git-prev-unmerged-file)
1278     (define-key map "q"   'git-status-quit)
1279     (define-key map "r"   'git-remove-file)
1280     (define-key map "R"   'git-resolve-file)
1281     (define-key map "t"    toggle-map)
1282     (define-key map "T"   'git-toggle-all-marks)
1283     (define-key map "u"   'git-unmark-file)
1284     (define-key map "U"   'git-revert-file)
1285     (define-key map "v"   'git-view-file)
1286     (define-key map "x"   'git-remove-handled)
1287     (define-key map "\C-?" 'git-unmark-file-up)
1288     (define-key map "\M-\C-?" 'git-unmark-all)
1289     ; the diff submap
1290     (define-key diff-map "b" 'git-diff-file-base)
1291     (define-key diff-map "c" 'git-diff-file-combined)
1292     (define-key diff-map "=" 'git-diff-file)
1293     (define-key diff-map "e" 'git-diff-file-idiff)
1294     (define-key diff-map "E" 'git-find-file-imerge)
1295     (define-key diff-map "h" 'git-diff-file-merge-head)
1296     (define-key diff-map "m" 'git-diff-file-mine)
1297     (define-key diff-map "o" 'git-diff-file-other)
1298     ; the toggle submap
1299     (define-key toggle-map "u" 'git-toggle-show-uptodate)
1300     (define-key toggle-map "i" 'git-toggle-show-ignored)
1301     (define-key toggle-map "k" 'git-toggle-show-unknown)
1302     (define-key toggle-map "m" 'git-toggle-all-marks)
1303     (setq git-status-mode-map map)))
1304
1305 ;; git mode should only run in the *git status* buffer
1306 (put 'git-status-mode 'mode-class 'special)
1307
1308 (defun git-status-mode ()
1309   "Major mode for interacting with Git.
1310 Commands:
1311 \\{git-status-mode-map}"
1312   (kill-all-local-variables)
1313   (buffer-disable-undo)
1314   (setq mode-name "git status"
1315         major-mode 'git-status-mode
1316         goal-column 17
1317         buffer-read-only t)
1318   (use-local-map git-status-mode-map)
1319   (let ((buffer-read-only nil))
1320     (erase-buffer)
1321   (let ((status (ewoc-create 'git-fileinfo-prettyprint "" "")))
1322     (set (make-local-variable 'git-status) status))
1323   (set (make-local-variable 'list-buffers-directory) default-directory)
1324   (make-local-variable 'git-show-uptodate)
1325   (make-local-variable 'git-show-ignored)
1326   (make-local-variable 'git-show-unknown)
1327   (run-hooks 'git-status-mode-hook)))
1328
1329 (defun git-find-status-buffer (dir)
1330   "Find the git status buffer handling a specified directory."
1331   (let ((list (buffer-list))
1332         (fulldir (expand-file-name dir))
1333         found)
1334     (while (and list (not found))
1335       (let ((buffer (car list)))
1336         (with-current-buffer buffer
1337           (when (and list-buffers-directory
1338                      (string-equal fulldir (expand-file-name list-buffers-directory))
1339                      (string-match "\\*git-status\\*$" (buffer-name buffer)))
1340             (setq found buffer))))
1341       (setq list (cdr list)))
1342     found))
1343
1344 (defun git-status (dir)
1345   "Entry point into git-status mode."
1346   (interactive "DSelect directory: ")
1347   (setq dir (git-get-top-dir dir))
1348   (if (file-directory-p (concat (file-name-as-directory dir) ".git"))
1349       (let ((buffer (or (and git-reuse-status-buffer (git-find-status-buffer dir))
1350                         (create-file-buffer (expand-file-name "*git-status*" dir)))))
1351         (switch-to-buffer buffer)
1352         (cd dir)
1353         (git-status-mode)
1354         (git-refresh-status)
1355         (goto-char (point-min)))
1356     (message "%s is not a git working tree." dir)))
1357
1358 (defun git-help ()
1359   "Display help for Git mode."
1360   (interactive)
1361   (describe-function 'git-status-mode))
1362
1363 (provide 'git)
1364 ;;; git.el ends here