configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specified by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 241 #
 242 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 243 # /foo/bar/include and /foo/bar/lib directories.
 244 AC_ARG_WITH(openssl,
 245 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 246 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 247 GIT_PARSE_WITH([openssl]))
 248
 249 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 250 # commands such as log and grep offer runtime options to use
 251 # Perl-compatible regular expressions instead of standard or extended
 252 # POSIX regular expressions. Only libpcre version 2 is supported.
 253 #
 254 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
 255 # /foo/bar/include and /foo/bar/lib directories.
 256 #
 257
 258 AC_ARG_WITH(libpcre1,
 259 AS_HELP_STRING([--with-libpcre1],[DEPRECATED]),
 260     AC_MSG_ERROR([support for --with-libpcre1 has been removed. Use --with-libpcre2!])
 261     )
 262
 263 AC_ARG_WITH(libpcre,
 264 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
 265     if test "$withval" = "no"; then
 266         USE_LIBPCRE2=
 267     elif test "$withval" = "yes"; then
 268         USE_LIBPCRE2=YesPlease
 269     else
 270         USE_LIBPCRE2=YesPlease
 271         LIBPCREDIR=$withval
 272         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 273         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 274         dnl it yet.
 275         GIT_CONF_SUBST([LIBPCREDIR])
 276     fi)
 277
 278 AC_ARG_WITH(libpcre2,
 279 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
 280 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 281     if test -n "$USE_LIBPCRE2"; then
 282         AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
 283     fi
 284
 285     if test "$withval" = "no"; then
 286         USE_LIBPCRE2=
 287     elif test "$withval" = "yes"; then
 288         USE_LIBPCRE2=YesPlease
 289     else
 290         USE_LIBPCRE2=YesPlease
 291         LIBPCREDIR=$withval
 292         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 293         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 294         dnl it yet.
 295         GIT_CONF_SUBST([LIBPCREDIR])
 296     fi)
 297 #
 298 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 299 AC_FUNC_ALLOCA
 300 case $ac_cv_working_alloca_h in
 301     yes)    HAVE_ALLOCA_H=YesPlease;;
 302     *)      HAVE_ALLOCA_H='';;
 303 esac
 304 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 305 #
 306 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 307 # git-http-push are not built, and you cannot use http:// and https://
 308 # transports.
 309 #
 310 # Define CURLDIR=/foo/bar if your curl header and library files are in
 311 # /foo/bar/include and /foo/bar/lib directories.
 312 AC_ARG_WITH(curl,
 313 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 314 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 315 GIT_PARSE_WITH(curl))
 316 #
 317 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 318 # not built, and you cannot push using http:// and https:// transports.
 319 #
 320 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 321 # /foo/bar/include and /foo/bar/lib directories.
 322 AC_ARG_WITH(expat,
 323 AS_HELP_STRING([--with-expat],
 324 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 325 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 326 GIT_PARSE_WITH(expat))
 327 #
 328 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 329 # installed in /sw, but don't want GIT to link against any libraries
 330 # installed there.  If defined you may specify your own (or Fink's)
 331 # include directories and library directories by defining CFLAGS
 332 # and LDFLAGS appropriately.
 333 #
 334 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 335 # have DarwinPorts installed in /opt/local, but don't want GIT to
 336 # link against any libraries installed there.  If defined you may
 337 # specify your own (or DarwinPort's) include directories and
 338 # library directories by defining CFLAGS and LDFLAGS appropriately.
 339 #
 340 # Define NO_MMAP if you want to avoid mmap.
 341 #
 342 # Define NO_ICONV if your libc does not properly support iconv.
 343 AC_ARG_WITH(iconv,
 344 AS_HELP_STRING([--without-iconv],
 345 [if your architecture doesn't properly support iconv])
 346 AS_HELP_STRING([--with-iconv=PATH],
 347 [PATH is prefix for libiconv library and headers])
 348 AS_HELP_STRING([],
 349 [used only if you need linking with libiconv]),
 350 GIT_PARSE_WITH(iconv))
 351
 352 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 353 #
 354 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 355 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 356 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 357 # randomly break unless your underlying filesystem supports those sub-second
 358 # times (my ext3 doesn't).
 359 #
 360 # Define USE_STDEV below if you want git to care about the underlying device
 361 # change being considered an inode change from the update-index perspective.
 362
 363 #
 364 # Allow user to set ETC_GITCONFIG variable
 365 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 366                         Use VALUE instead of /etc/gitconfig as the
 367                         global git configuration file.
 368                         If VALUE is not fully qualified it will be interpreted
 369                         as a path relative to the computed prefix at runtime.)
 370
 371 #
 372 # Allow user to set ETC_GITATTRIBUTES variable
 373 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 374                         Use VALUE instead of /etc/gitattributes as the
 375                         global git attributes file.
 376                         If VALUE is not fully qualified it will be interpreted
 377                         as a path relative to the computed prefix at runtime.)
 378
 379 #
 380 # Allow user to set the default pager
 381 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 382                         Use VALUE as the fall-back pager instead of 'less'.
 383                         This is used by things like 'git log' when the user
 384                         does not specify a pager to use through alternate
 385                         methods. eg: /usr/bin/pager)
 386 #
 387 # Allow user to set the default editor
 388 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 389                         Use VALUE as the fall-back editor instead of 'vi'.
 390                         This is used by things like 'git commit' when the user
 391                         does not specify a preferred editor through other
 392                         methods. eg: /usr/bin/editor)
 393
 394 #
 395 # Define SHELL_PATH to provide path to shell.
 396 GIT_ARG_SET_PATH(shell)
 397 #
 398 # Define PERL_PATH to provide path to Perl.
 399 GIT_ARG_SET_PATH(perl)
 400 #
 401 # Define PYTHON_PATH to provide path to Python.
 402 GIT_ARG_SET_PATH(python, allow-without)
 403 #
 404 # Define ZLIB_PATH to provide path to zlib.
 405 GIT_ARG_SET_PATH(zlib)
 406 #
 407 # Declare the with-tcltk/without-tcltk options.
 408 AC_ARG_WITH(tcltk,
 409 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 410 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 411 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 412 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 413 GIT_PARSE_WITH(tcltk))
 414 #
 415
 416
 417 ## Checks for programs.
 418 AC_MSG_NOTICE([CHECKS for programs])
 419 #
 420 AC_PROG_CC([cc gcc])
 421 AC_C_INLINE
 422 case $ac_cv_c_inline in
 423   inline | yes | no) INLINE='';;
 424   *)                 INLINE=$ac_cv_c_inline ;;
 425 esac
 426 GIT_CONF_SUBST([INLINE])
 427
 428 # which switch to pass runtime path to dynamic libraries to the linker
 429 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 430    SAVE_LDFLAGS="${LDFLAGS}"
 431    LDFLAGS="${SAVE_LDFLAGS} -R /"
 432    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 433    LDFLAGS="${SAVE_LDFLAGS}"
 434 ])
 435 if test "$git_cv_ld_dashr" = "yes"; then
 436    CC_LD_DYNPATH=-R
 437 else
 438    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 439       SAVE_LDFLAGS="${LDFLAGS}"
 440       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 441       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 442       LDFLAGS="${SAVE_LDFLAGS}"
 443    ])
 444    if test "$git_cv_ld_wl_rpath" = "yes"; then
 445       CC_LD_DYNPATH=-Wl,-rpath,
 446    else
 447       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 448          SAVE_LDFLAGS="${LDFLAGS}"
 449          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 450          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 451          LDFLAGS="${SAVE_LDFLAGS}"
 452       ])
 453       if test "$git_cv_ld_rpath" = "yes"; then
 454          CC_LD_DYNPATH=-rpath
 455       else
 456          AC_CACHE_CHECK([if linker supports -Wl,+b,], git_cv_ld_wl_b, [
 457             SAVE_LDFLAGS="${LDFLAGS}"
 458             LDFLAGS="${SAVE_LDFLAGS} -Wl,+b,/"
 459             AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_b=yes], [git_cv_ld_wl_b=no])
 460             LDFLAGS="${SAVE_LDFLAGS}"
 461          ])
 462          if test "$git_cv_ld_wl_b" = "yes"; then
 463             CC_LD_DYNPATH=-Wl,+b,
 464           else
 465              CC_LD_DYNPATH=
 466              AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 467           fi
 468       fi
 469    fi
 470 fi
 471 GIT_CONF_SUBST([CC_LD_DYNPATH])
 472 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 473 AC_CHECK_TOOLS(AR, [gar ar], :)
 474 AC_CHECK_PROGS(TAR, [gtar tar])
 475 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 476 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 477 # or will be empty otherwise.
 478 if test -n "$NO_TCLTK"; then
 479   TCLTK_PATH=
 480 else
 481   if test "$with_tcltk" = ""; then
 482   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 483     TCLTK_PATH=wish
 484   elif test "$with_tcltk" = "yes"; then
 485   # Tcl/Tk check requested.
 486     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 487   else
 488     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 489     TCLTK_PATH="$with_tcltk"
 490   fi
 491 fi
 492 GIT_CONF_SUBST([TCLTK_PATH])
 493 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 494 if test -n "$ASCIIDOC"; then
 495         AC_MSG_CHECKING([for asciidoc version])
 496         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 497         case "${asciidoc_version}" in
 498         asciidoc' '8*)
 499                 AC_MSG_RESULT([${asciidoc_version}])
 500                 ;;
 501         *)
 502                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 503                 ;;
 504         esac
 505 fi
 506
 507 ## Checks for libraries.
 508 AC_MSG_NOTICE([CHECKS for libraries])
 509 #
 510 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 511 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 512
 513 GIT_STASH_FLAGS($OPENSSLDIR)
 514
 515 AC_CHECK_LIB([crypto], [SHA1_Init],
 516 [NEEDS_SSL_WITH_CRYPTO=],
 517 [AC_CHECK_LIB([ssl], [SHA1_Init],
 518  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 519  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 520
 521 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 522
 523 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 524 GIT_CONF_SUBST([NO_OPENSSL])
 525
 526 #
 527 # Handle the USE_LIBPCRE options potentially set above.
 528 #
 529
 530 if test -n "$USE_LIBPCRE2"; then
 531
 532 GIT_STASH_FLAGS($LIBPCREDIR)
 533
 534 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
 535 [USE_LIBPCRE2=YesPlease],
 536 [USE_LIBPCRE2=])
 537
 538 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 539
 540 GIT_CONF_SUBST([USE_LIBPCRE2])
 541
 542 fi
 543
 544 #
 545 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 546 # git-http-push are not built, and you cannot use http:// and https://
 547 # transports.
 548
 549 GIT_STASH_FLAGS($CURLDIR)
 550
 551 AC_CHECK_LIB([curl], [curl_global_init],
 552 [NO_CURL=],
 553 [NO_CURL=YesPlease])
 554
 555 GIT_UNSTASH_FLAGS($CURLDIR)
 556
 557 GIT_CONF_SUBST([NO_CURL])
 558
 559 if test -z "$NO_CURL"; then
 560
 561 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 562 [curl-config],
 563 [no])
 564
 565 if test $CURL_CONFIG != no; then
 566     GIT_CONF_SUBST([CURL_CONFIG])
 567
 568     if test -z "$CURL_CONFIG_OPTS"; then
 569         CURL_CONFIG_OPTS="--libs"
 570     fi
 571
 572     CURL_LDFLAGS=$($CURL_CONFIG $CURL_CONFIG_OPTS)
 573     AC_MSG_NOTICE([Setting CURL_LDFLAGS to '$CURL_LDFLAGS'])
 574     GIT_CONF_SUBST([CURL_LDFLAGS], [$CURL_LDFLAGS])
 575 fi
 576
 577 fi
 578
 579
 580 #
 581 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 582 # not built, and you cannot push using http:// and https:// transports.
 583
 584 GIT_STASH_FLAGS($EXPATDIR)
 585
 586 AC_CHECK_LIB([expat], [XML_ParserCreate],
 587 [NO_EXPAT=],
 588 [NO_EXPAT=YesPlease])
 589
 590 GIT_UNSTASH_FLAGS($EXPATDIR)
 591
 592 GIT_CONF_SUBST([NO_EXPAT])
 593
 594 #
 595 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 596 # some Solaris installations).
 597 # Define NO_ICONV if neither libc nor libiconv support iconv.
 598
 599 if test -z "$NO_ICONV"; then
 600
 601 GIT_STASH_FLAGS($ICONVDIR)
 602
 603 AC_DEFUN([ICONVTEST_SRC],
 604 [AC_LANG_PROGRAM([#include <iconv.h>],
 605  [iconv_open("", "");])])
 606
 607 if test -n "$ICONVDIR"; then
 608    lib_order="-liconv -lc"
 609 else
 610    lib_order="-lc -liconv"
 611 fi
 612
 613 NO_ICONV=YesPlease
 614
 615 for l in $lib_order; do
 616     if test "$l" = "-liconv"; then
 617        NEEDS_LIBICONV=YesPlease
 618     else
 619        NEEDS_LIBICONV=
 620     fi
 621
 622     old_LIBS="$LIBS"
 623     LIBS="$LIBS $l"
 624     AC_MSG_CHECKING([for iconv in $l])
 625     AC_LINK_IFELSE([ICONVTEST_SRC],
 626         [AC_MSG_RESULT([yes])
 627         NO_ICONV=
 628         break],
 629         [AC_MSG_RESULT([no])])
 630     LIBS="$old_LIBS"
 631 done
 632
 633 #in case of break
 634 LIBS="$old_LIBS"
 635
 636 GIT_UNSTASH_FLAGS($ICONVDIR)
 637
 638 GIT_CONF_SUBST([NEEDS_LIBICONV])
 639 GIT_CONF_SUBST([NO_ICONV])
 640
 641 if test -n "$NO_ICONV"; then
 642     NEEDS_LIBICONV=
 643 fi
 644
 645 fi
 646
 647 #
 648 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 649
 650 GIT_STASH_FLAGS($ZLIB_PATH)
 651
 652 AC_DEFUN([ZLIBTEST_SRC], [
 653 AC_LANG_PROGRAM([#include <zlib.h>],
 654  [deflateBound(0, 0);])])
 655 AC_MSG_CHECKING([for deflateBound in -lz])
 656 old_LIBS="$LIBS"
 657 LIBS="$LIBS -lz"
 658 AC_LINK_IFELSE([ZLIBTEST_SRC],
 659         [AC_MSG_RESULT([yes])],
 660         [AC_MSG_RESULT([no])
 661         NO_DEFLATE_BOUND=yes])
 662 LIBS="$old_LIBS"
 663
 664 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 665
 666 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 667
 668 #
 669 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 670 # Patrick Mauritz).
 671 AC_CHECK_LIB([c], [socket],
 672 [NEEDS_SOCKET=],
 673 [NEEDS_SOCKET=YesPlease])
 674 GIT_CONF_SUBST([NEEDS_SOCKET])
 675 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 676
 677 #
 678 # The next few tests will define NEEDS_RESOLV if linking with
 679 # libresolv provides some of the functions we would normally get
 680 # from libc.
 681 NEEDS_RESOLV=
 682 #
 683 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 684 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 685 NO_INET_NTOP=
 686 AC_CHECK_FUNC([inet_ntop],
 687     [],
 688     [AC_CHECK_LIB([resolv], [inet_ntop],
 689         [NEEDS_RESOLV=YesPlease],
 690         [NO_INET_NTOP=YesPlease])
 691 ])
 692 GIT_CONF_SUBST([NO_INET_NTOP])
 693 #
 694 # Define NO_INET_PTON if linking with -lresolv is not enough.
 695 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 696 NO_INET_PTON=
 697 AC_CHECK_FUNC([inet_pton],
 698     [],
 699     [AC_CHECK_LIB([resolv], [inet_pton],
 700         [NEEDS_RESOLV=YesPlease],
 701         [NO_INET_PTON=YesPlease])
 702 ])
 703 GIT_CONF_SUBST([NO_INET_PTON])
 704 #
 705 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 706 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 707 NO_HSTRERROR=
 708 AC_CHECK_FUNC([hstrerror],
 709     [],
 710     [AC_CHECK_LIB([resolv], [hstrerror],
 711         [NEEDS_RESOLV=YesPlease],
 712         [NO_HSTRERROR=YesPlease])
 713 ])
 714 GIT_CONF_SUBST([NO_HSTRERROR])
 715
 716 dnl This must go after all the possible places for its initialization,
 717 dnl in the AC_CHECK_FUNC invocations above.
 718 GIT_CONF_SUBST([NEEDS_RESOLV])
 719 #
 720 # If any of the above tests determined that -lresolv is needed at
 721 # build-time, also set it here for remaining configure-time checks.
 722 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 723
 724 AC_CHECK_LIB([c], [basename],
 725 [NEEDS_LIBGEN=],
 726 [NEEDS_LIBGEN=YesPlease])
 727 GIT_CONF_SUBST([NEEDS_LIBGEN])
 728 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 729
 730 AC_DEFUN([LIBINTL_SRC], [
 731 AC_LANG_PROGRAM([[
 732 #include <libintl.h>
 733 ]],[[
 734 char *msg = gettext("test");
 735 ]])])
 736
 737 AC_MSG_CHECKING([if libc contains libintl])
 738 AC_LINK_IFELSE([LIBINTL_SRC],
 739         [AC_MSG_RESULT([yes])
 740         LIBC_CONTAINS_LIBINTL=YesPlease],
 741         [AC_MSG_RESULT([no])
 742         LIBC_CONTAINS_LIBINTL=])
 743 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 744
 745 #
 746 # Define NO_GETTEXT if you don't want Git output to be translated.
 747 # A translated Git requires GNU libintl or another gettext implementation
 748 AC_CHECK_HEADER([libintl.h],
 749 [NO_GETTEXT=],
 750 [NO_GETTEXT=YesPlease])
 751 GIT_CONF_SUBST([NO_GETTEXT])
 752
 753 if test -z "$NO_GETTEXT"; then
 754     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 755 fi
 756
 757 ## Checks for header files.
 758 AC_MSG_NOTICE([CHECKS for header files])
 759 #
 760 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 761 AC_CHECK_HEADER([sys/select.h],
 762 [NO_SYS_SELECT_H=],
 763 [NO_SYS_SELECT_H=UnfortunatelyYes])
 764 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 765 #
 766 # Define NO_POLL_H if you don't have poll.h
 767 AC_CHECK_HEADER([poll.h],
 768 [NO_POLL_H=],
 769 [NO_POLL_H=UnfortunatelyYes])
 770 GIT_CONF_SUBST([NO_POLL_H])
 771 #
 772 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 773 AC_CHECK_HEADER([sys/poll.h],
 774 [NO_SYS_POLL_H=],
 775 [NO_SYS_POLL_H=UnfortunatelyYes])
 776 GIT_CONF_SUBST([NO_SYS_POLL_H])
 777 #
 778 # Define NO_INTTYPES_H if you don't have inttypes.h
 779 AC_CHECK_HEADER([inttypes.h],
 780 [NO_INTTYPES_H=],
 781 [NO_INTTYPES_H=UnfortunatelyYes])
 782 GIT_CONF_SUBST([NO_INTTYPES_H])
 783 #
 784 # Define OLD_ICONV if your library has an old iconv(), where the second
 785 # (input buffer pointer) parameter is declared with type (const char **).
 786 AC_DEFUN([OLDICONVTEST_SRC], [
 787 AC_LANG_PROGRAM([[
 788 #include <iconv.h>
 789
 790 extern size_t iconv(iconv_t cd,
 791                     char **inbuf, size_t *inbytesleft,
 792                     char **outbuf, size_t *outbytesleft);
 793 ]], [])])
 794
 795 GIT_STASH_FLAGS($ICONVDIR)
 796
 797 AC_MSG_CHECKING([for old iconv()])
 798 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 799         [AC_MSG_RESULT([no])],
 800         [AC_MSG_RESULT([yes])
 801         AC_DEFINE(HAVE_OLD_ICONV, 1)
 802         OLD_ICONV=UnfortunatelyYes])
 803
 804 GIT_UNSTASH_FLAGS($ICONVDIR)
 805
 806 GIT_CONF_SUBST([OLD_ICONV])
 807
 808 #
 809 # Define ICONV_OMITS_BOM if you are on a system which
 810 # iconv omits bom for utf-{16,32}
 811 if test -z "$NO_ICONV"; then
 812 AC_CACHE_CHECK([whether iconv omits bom for utf-16 and utf-32],
 813  [ac_cv_iconv_omits_bom],
 814 [
 815 old_LIBS="$LIBS"
 816 if test -n "$NEEDS_LIBICONV"; then
 817         LIBS="$LIBS -liconv"
 818 fi
 819
 820 AC_RUN_IFELSE(
 821         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 822         #include <iconv.h>
 823         #ifdef HAVE_OLD_ICONV
 824         typedef const char *iconv_ibp;
 825         #else
 826         typedef char *iconv_ibp;
 827         #endif
 828         ],
 829         [[
 830         int v;
 831         iconv_t conv;
 832         char in[] = "a"; iconv_ibp pin = in;
 833         char out[20] = ""; char *pout = out;
 834         size_t isz = sizeof in;
 835         size_t osz = sizeof out;
 836
 837         conv = iconv_open("UTF-16", "UTF-8");
 838         iconv(conv, &pin, &isz, &pout, &osz);
 839         iconv_close(conv);
 840         v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
 841         return v != 0xfe + 0xff;
 842         ]])],
 843         [ac_cv_iconv_omits_bom=no],
 844         [ac_cv_iconv_omits_bom=yes])
 845
 846 LIBS="$old_LIBS"
 847 ])
 848 if test "x$ac_cv_iconv_omits_bom" = xyes; then
 849         ICONV_OMITS_BOM=Yes
 850 else
 851         ICONV_OMITS_BOM=
 852 fi
 853 GIT_CONF_SUBST([ICONV_OMITS_BOM])
 854 fi
 855
 856 ## Checks for typedefs, structures, and compiler characteristics.
 857 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 858 #
 859 TYPE_SOCKLEN_T
 860 case $ac_cv_type_socklen_t in
 861   yes)  SOCKLEN_T='';;
 862   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 863 esac
 864 GIT_CONF_SUBST([SOCKLEN_T])
 865
 866 #
 867 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 868 AC_CHECK_TYPES([struct itimerval],
 869 [NO_STRUCT_ITIMERVAL=],
 870 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 871 [#include <sys/time.h>])
 872 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 873 #
 874 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 875 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 876 # stat.st_mtimespec.tv_nsec exists.
 877 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 878 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 879 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 880         USE_ST_TIMESPEC=YesPlease
 881         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 882 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 883         NO_NSEC=YesPlease
 884         GIT_CONF_SUBST([NO_NSEC])
 885 fi
 886 #
 887 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 888 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 889 AC_CHECK_MEMBER(struct dirent.d_type,
 890 [NO_D_TYPE_IN_DIRENT=],
 891 [NO_D_TYPE_IN_DIRENT=YesPlease],
 892 [#include <dirent.h>])
 893 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 894 #
 895 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 896 # in the C library.
 897 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 898 [NO_GECOS_IN_PWENT=],
 899 [NO_GECOS_IN_PWENT=YesPlease],
 900 [#include <pwd.h>])
 901 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 902 #
 903 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 904 # sockaddr_storage.
 905 AC_CHECK_TYPE(struct sockaddr_storage,
 906 [NO_SOCKADDR_STORAGE=],
 907 [NO_SOCKADDR_STORAGE=YesPlease],[
 908 #include <sys/types.h>
 909 #include <sys/socket.h>
 910 ])
 911 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 912 #
 913 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 914 AC_CHECK_TYPE([struct addrinfo],[
 915  GIT_CHECK_FUNC([getaddrinfo],
 916   [NO_IPV6=],
 917   [NO_IPV6=YesPlease])
 918 ],[NO_IPV6=YesPlease],[
 919 #include <sys/types.h>
 920 #include <sys/socket.h>
 921 #include <netdb.h>
 922 ])
 923 GIT_CONF_SUBST([NO_IPV6])
 924 #
 925 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
 926 # feature.
 927 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
 928  [ac_cv_c_regex_with_reg_startend], [
 929 AC_EGREP_CPP(yippeeyeswehaveit,
 930         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 931 #include <regex.h>
 932 ],
 933 [#ifdef REG_STARTEND
 934 yippeeyeswehaveit
 935 #endif
 936 ]),
 937         [ac_cv_c_regex_with_reg_startend=yes],
 938         [ac_cv_c_regex_with_reg_startend=no])
 939 ])
 940 if test $ac_cv_c_regex_with_reg_startend = yes; then
 941         NO_REGEX=
 942 else
 943         NO_REGEX=YesPlease
 944 fi
 945 GIT_CONF_SUBST([NO_REGEX])
 946 #
 947 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 948 # when attempting to read from an fopen'ed directory.
 949 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 950  [ac_cv_fread_reads_directories],
 951 [
 952 AC_RUN_IFELSE(
 953         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 954                 [[
 955                 FILE *f = fopen(".", "r");
 956                 return f != NULL;]])],
 957         [ac_cv_fread_reads_directories=no],
 958         [ac_cv_fread_reads_directories=yes])
 959 ])
 960 if test $ac_cv_fread_reads_directories = yes; then
 961         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 962 else
 963         FREAD_READS_DIRECTORIES=
 964 fi
 965 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
 966 #
 967 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 968 # or vsnprintf() return -1 instead of number of characters which would
 969 # have been written to the final string if enough space had been available.
 970 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 971  [ac_cv_snprintf_returns_bogus],
 972 [
 973 AC_RUN_IFELSE(
 974         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 975                 #include "stdarg.h"
 976
 977                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 978                 {
 979                   int ret;
 980                   va_list ap;
 981                   va_start(ap, format);
 982                   ret = vsnprintf(str, maxsize, format, ap);
 983                   va_end(ap);
 984                   return ret;
 985                 }],
 986                 [[char buf[6];
 987                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 988                       || strcmp(buf, "12")) return 1;
 989                   if (snprintf(buf, 3, "%s", "12345") != 5
 990                       || strcmp(buf, "12")) return 1]])],
 991         [ac_cv_snprintf_returns_bogus=no],
 992         [ac_cv_snprintf_returns_bogus=yes])
 993 ])
 994 if test $ac_cv_snprintf_returns_bogus = yes; then
 995         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 996 else
 997         SNPRINTF_RETURNS_BOGUS=
 998 fi
 999 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
1000 #
1001 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
1002 # bits in mode values.
1003 AC_CACHE_CHECK([whether the platform uses typical file type bits],
1004  [ac_cv_sane_mode_bits], [
1005 AC_EGREP_CPP(yippeeyeswehaveit,
1006         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1007 [#if S_IFMT == 0170000 && \
1008         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
1009         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
1010         S_IFIFO == 0010000 && S_IFSOCK == 0140000
1011 yippeeyeswehaveit
1012 #endif
1013 ]),
1014         [ac_cv_sane_mode_bits=yes],
1015         [ac_cv_sane_mode_bits=no])
1016 ])
1017 if test $ac_cv_sane_mode_bits = yes; then
1018         NEEDS_MODE_TRANSLATION=
1019 else
1020         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
1021 fi
1022 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
1023
1024
1025 ## Checks for library functions.
1026 ## (in default C library and libraries checked by AC_CHECK_LIB)
1027 AC_MSG_NOTICE([CHECKS for library functions])
1028 #
1029 # Define NO_LIBGEN_H if you don't have libgen.h.
1030 AC_CHECK_HEADER([libgen.h],
1031 [NO_LIBGEN_H=],
1032 [NO_LIBGEN_H=YesPlease])
1033 GIT_CONF_SUBST([NO_LIBGEN_H])
1034 #
1035 # Define HAVE_PATHS_H if you have paths.h.
1036 AC_CHECK_HEADER([paths.h],
1037 [HAVE_PATHS_H=YesPlease],
1038 [HAVE_PATHS_H=])
1039 GIT_CONF_SUBST([HAVE_PATHS_H])
1040 #
1041 # Define HAVE_LIBCHARSET_H if have libcharset.h
1042 AC_CHECK_HEADER([libcharset.h],
1043 [HAVE_LIBCHARSET_H=YesPlease],
1044 [HAVE_LIBCHARSET_H=])
1045 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1046 #
1047 # Define HAVE_STRINGS_H if you have strings.h
1048 AC_CHECK_HEADER([strings.h],
1049 [HAVE_STRINGS_H=YesPlease],
1050 [HAVE_STRINGS_H=])
1051 GIT_CONF_SUBST([HAVE_STRINGS_H])
1052 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1053 # and libcharset does
1054 CHARSET_LIB=
1055 AC_CHECK_LIB([iconv], [locale_charset],
1056        [CHARSET_LIB=-liconv],
1057        [AC_CHECK_LIB([charset], [locale_charset],
1058                      [CHARSET_LIB=-lcharset])])
1059 GIT_CONF_SUBST([CHARSET_LIB])
1060 #
1061 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1062 GIT_CHECK_FUNC(clock_gettime,
1063         [HAVE_CLOCK_GETTIME=YesPlease],
1064         [HAVE_CLOCK_GETTIME=])
1065 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1066
1067 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1068 AC_LANG_PROGRAM([[
1069 #include <time.h>
1070 clockid_t id = CLOCK_MONOTONIC;
1071 ]])])
1072
1073 #
1074 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1075 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1076 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1077         [AC_MSG_RESULT([yes])
1078         HAVE_CLOCK_MONOTONIC=YesPlease],
1079         [AC_MSG_RESULT([no])
1080         HAVE_CLOCK_MONOTONIC=])
1081 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1082
1083 #
1084 # Define HAVE_SYNC_FILE_RANGE=YesPlease if sync_file_range is available.
1085 GIT_CHECK_FUNC(sync_file_range,
1086         [HAVE_SYNC_FILE_RANGE=YesPlease],
1087         [HAVE_SYNC_FILE_RANGE=])
1088 GIT_CONF_SUBST([HAVE_SYNC_FILE_RANGE])
1089
1090 #
1091 # Define NO_SETITIMER if you don't have setitimer.
1092 GIT_CHECK_FUNC(setitimer,
1093 [NO_SETITIMER=],
1094 [NO_SETITIMER=YesPlease])
1095 GIT_CONF_SUBST([NO_SETITIMER])
1096 #
1097 # Define NO_STRCASESTR if you don't have strcasestr.
1098 GIT_CHECK_FUNC(strcasestr,
1099 [NO_STRCASESTR=],
1100 [NO_STRCASESTR=YesPlease])
1101 GIT_CONF_SUBST([NO_STRCASESTR])
1102 #
1103 # Define NO_MEMMEM if you don't have memmem.
1104 GIT_CHECK_FUNC(memmem,
1105 [NO_MEMMEM=],
1106 [NO_MEMMEM=YesPlease])
1107 GIT_CONF_SUBST([NO_MEMMEM])
1108 #
1109 # Define NO_STRLCPY if you don't have strlcpy.
1110 GIT_CHECK_FUNC(strlcpy,
1111 [NO_STRLCPY=],
1112 [NO_STRLCPY=YesPlease])
1113 GIT_CONF_SUBST([NO_STRLCPY])
1114 #
1115 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1116 AC_CHECK_TYPE(uintmax_t,
1117 [NO_UINTMAX_T=],
1118 [NO_UINTMAX_T=YesPlease],[
1119 #include <inttypes.h>
1120 ])
1121 GIT_CONF_SUBST([NO_UINTMAX_T])
1122 #
1123 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1124 GIT_CHECK_FUNC(strtoumax,
1125 [NO_STRTOUMAX=],
1126 [NO_STRTOUMAX=YesPlease])
1127 GIT_CONF_SUBST([NO_STRTOUMAX])
1128 #
1129 # Define NO_SETENV if you don't have setenv in the C library.
1130 GIT_CHECK_FUNC(setenv,
1131 [NO_SETENV=],
1132 [NO_SETENV=YesPlease])
1133 GIT_CONF_SUBST([NO_SETENV])
1134 #
1135 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1136 GIT_CHECK_FUNC(unsetenv,
1137 [NO_UNSETENV=],
1138 [NO_UNSETENV=YesPlease])
1139 GIT_CONF_SUBST([NO_UNSETENV])
1140 #
1141 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1142 GIT_CHECK_FUNC(mkdtemp,
1143 [NO_MKDTEMP=],
1144 [NO_MKDTEMP=YesPlease])
1145 GIT_CONF_SUBST([NO_MKDTEMP])
1146 #
1147 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1148 GIT_CHECK_FUNC(initgroups,
1149 [NO_INITGROUPS=],
1150 [NO_INITGROUPS=YesPlease])
1151 GIT_CONF_SUBST([NO_INITGROUPS])
1152 #
1153 # Define HAVE_GETDELIM if you have getdelim in the C library.
1154 GIT_CHECK_FUNC(getdelim,
1155 [HAVE_GETDELIM=YesPlease],
1156 [HAVE_GETDELIM=])
1157 GIT_CONF_SUBST([HAVE_GETDELIM])
1158 #
1159 #
1160 # Define NO_MMAP if you want to avoid mmap.
1161 #
1162 # Define NO_ICONV if your libc does not properly support iconv.
1163
1164 AC_DEFUN([BSD_SYSCTL_SRC], [
1165 AC_LANG_PROGRAM([[
1166 #include <stddef.h>
1167 #include <sys/types.h>
1168 #include <sys/sysctl.h>
1169 ]],[[
1170 int val, mib[2];
1171 size_t len;
1172 mib[0] = CTL_HW;
1173 mib[1] = 1;
1174 len = sizeof(val);
1175 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1176 ]])])
1177
1178 #
1179 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1180 AC_MSG_CHECKING([for BSD sysctl])
1181 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1182         [AC_MSG_RESULT([yes])
1183         HAVE_BSD_SYSCTL=YesPlease],
1184         [AC_MSG_RESULT([no])
1185         HAVE_BSD_SYSCTL=])
1186 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1187
1188 ## Other checks.
1189 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1190 # Enable it on Windows.  By default, symrefs are still used.
1191 #
1192 # Define NO_PTHREADS if we do not have pthreads.
1193 #
1194 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1195 AC_DEFUN([PTHREADTEST_SRC], [
1196 AC_LANG_PROGRAM([[
1197 #include <pthread.h>
1198 static void *noop(void *ignore) { return ignore; }
1199 ]], [[
1200         pthread_mutex_t test_mutex;
1201         pthread_key_t test_key;
1202         pthread_t th;
1203         int retcode = 0;
1204         void *ret = (void *)0;
1205         retcode |= pthread_key_create(&test_key, (void *)0);
1206         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1207         retcode |= pthread_mutex_lock(&test_mutex);
1208         retcode |= pthread_mutex_unlock(&test_mutex);
1209         retcode |= pthread_create(&th, ret, noop, ret);
1210         retcode |= pthread_join(th, &ret);
1211         return retcode;
1212 ]])])
1213
1214 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1215 dnl   [[#include <pthread.h>]],
1216 dnl   [[pthread_mutex_t test_mutex;]]
1217 dnl )])
1218
1219 NO_PTHREADS=UnfortunatelyYes
1220 PTHREAD_LIBS=
1221
1222 if test -n "$USER_NOPTHREAD"; then
1223    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1224 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1225 # -D_REENTRANT' or some such.
1226 elif test -z "$PTHREAD_CFLAGS"; then
1227   threads_found=no
1228   # Attempt to compile and link some code using pthreads to determine
1229   # required linker flags. The order is somewhat important here: We
1230   # first try it without any extra flags, to catch systems where
1231   # pthreads are part of the C library, then go on testing various other
1232   # flags. We do so to avoid false positives. For example, on Mac OS X
1233   # pthreads are part of the C library; moreover, the compiler allows us
1234   # to add "-mt" to the CFLAGS (although it will do nothing except
1235   # trigger a warning about an unused flag). Hence if we checked for
1236   # "-mt" before "" we would end up picking it. But unfortunately this
1237   # would then trigger compiler warnings on every single file we compile.
1238   for opt in "" -mt -pthread -lpthread; do
1239      old_CFLAGS="$CFLAGS"
1240      old_LIBS="$LIBS"
1241      case "$opt" in
1242         -l*)  LIBS="$opt $LIBS" ;;
1243         *)    CFLAGS="$opt $CFLAGS" ;;
1244      esac
1245
1246      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1247      AC_LINK_IFELSE([PTHREADTEST_SRC],
1248         [AC_MSG_RESULT([yes])
1249                 NO_PTHREADS=
1250                 PTHREAD_LIBS="$opt"
1251                 PTHREAD_CFLAGS="$opt"
1252                 threads_found=yes
1253                 break
1254         ],
1255         [AC_MSG_RESULT([no])])
1256       CFLAGS="$old_CFLAGS"
1257       LIBS="$old_LIBS"
1258   done
1259   if test $threads_found != yes; then
1260     AC_CHECK_LIB([pthread], [pthread_create],
1261         [PTHREAD_LIBS="-lpthread"],
1262         [NO_PTHREADS=UnfortunatelyYes])
1263   fi
1264 else
1265   old_CFLAGS="$CFLAGS"
1266   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1267   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1268   AC_LINK_IFELSE([PTHREADTEST_SRC],
1269         [AC_MSG_RESULT([yes])
1270                 NO_PTHREADS=
1271                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1272         ],
1273         [AC_MSG_RESULT([no])])
1274
1275   CFLAGS="$old_CFLAGS"
1276 fi
1277
1278 CFLAGS="$old_CFLAGS"
1279
1280 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1281 GIT_CONF_SUBST([PTHREAD_LIBS])
1282 GIT_CONF_SUBST([NO_PTHREADS])
1283
1284 ## Output files
1285 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1286 AC_OUTPUT