| blob | 031e8d3fee8f22f1f3a1a751675d923d1e36dc42 |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ## Definitions of private macros.
6 # GIT_CONF_SUBST(VAL, VAR)
7 # ------------------------
8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
9 AC_DEFUN([GIT_CONF_SUBST],
10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
11 config_appended_defs="$config_appended_defs${newline}dnl
12 $1=m4_if([$#],[1],[${$1}],[$2])"])
14 # GIT_CONF_SUBST_INIT
15 # -------------------
16 # Prepare shell variables and autoconf machine required by later calls
17 # to GIT_CONF_SUBST.
18 AC_DEFUN([GIT_CONF_SUBST_INIT],
19 [config_appended_defs=; newline='
20 '
21 AC_CONFIG_COMMANDS([$config_file],
22 [echo "$config_appended_defs" >> "$config_file"],
23 [config_file=$config_file
24 config_appended_defs="$config_appended_defs"])])
26 # GIT_ARG_SET_PATH(PROGRAM)
27 # -------------------------
28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
30 # --without-PROGRAM version used.
31 AC_DEFUN([GIT_ARG_SET_PATH],
32 [AC_ARG_WITH([$1],
33 [AS_HELP_STRING([--with-$1=PATH],
34 [provide PATH to $1])],
35 [GIT_CONF_APPEND_PATH([$1], [$2])],
36 [])])
38 # GIT_CONF_APPEND_PATH(PROGRAM)
39 # -----------------------------
40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
41 # Used by GIT_ARG_SET_PATH(PROGRAM)
42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
43 # --without-PROGRAM is used.
44 AC_DEFUN([GIT_CONF_APPEND_PATH],
45 [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
46 if test "$withval" = "no"; then
47 if test -n "$2"; then
48 GIT_UC_PROGRAM[]_PATH=$withval
49 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
50 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
51 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
52 else
53 AC_MSG_ERROR([You cannot use git without $1])
54 fi
55 else
56 if test "$withval" = "yes"; then
57 AC_MSG_WARN([You should provide path for --with-$1=PATH])
58 else
59 GIT_UC_PROGRAM[]_PATH=$withval
60 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
61 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
62 fi
63 fi
64 m4_popdef([GIT_UC_PROGRAM])])
66 # GIT_PARSE_WITH(PACKAGE)
67 # -----------------------
68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
72 AC_DEFUN([GIT_PARSE_WITH],
73 [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
74 if test "$withval" = "no"; then
75 NO_[]GIT_UC_PACKAGE=YesPlease
76 elif test "$withval" = "yes"; then
77 NO_[]GIT_UC_PACKAGE=
78 else
79 NO_[]GIT_UC_PACKAGE=
80 GIT_UC_PACKAGE[]DIR=$withval
81 AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
82 GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
83 fi
84 m4_popdef([GIT_UC_PACKAGE])])
86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
87 # -----------------------------------------------------
88 # Set VAR to the value specified by --with-WITHNAME.
89 # No verification of arguments is performed, but warnings are issued
90 # if either 'yes' or 'no' is specified.
91 # HELP_TEXT is presented when --help is called.
92 # This is a direct way to allow setting variables in the Makefile.
93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
94 [AC_ARG_WITH([$1],
95 [AS_HELP_STRING([--with-$1=VALUE], $3)],
96 if test -n "$withval"; then
97 if test "$withval" = "yes" -o "$withval" = "no"; then
98 AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
99 [a value for $1 ($2). Maybe you do...?])
100 fi
101 AC_MSG_NOTICE([Setting $2 to $withval])
102 GIT_CONF_SUBST([$2], [$withval])
103 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
105 #
106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
107 # -----------------------------------------
108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
110 # -Wall), it does not work. By looking for function definition in
111 # libraries, this problem can be worked around.
112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
113 AC_SEARCH_LIBS([$1],,
114 [$2],[$3])
115 ],[$3])])
117 #
118 # GIT_STASH_FLAGS(BASEPATH_VAR)
119 # -----------------------------
120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
121 # tests that may want to take user settings into account.
122 AC_DEFUN([GIT_STASH_FLAGS],[
123 if test -n "$1"; then
124 old_CPPFLAGS="$CPPFLAGS"
125 old_LDFLAGS="$LDFLAGS"
126 CPPFLAGS="-I$1/include $CPPFLAGS"
127 LDFLAGS="-L$1/$lib $LDFLAGS"
128 fi
129 ])
131 dnl
132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
133 dnl -----------------------------
134 dnl Restore the stashed *FLAGS values.
135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
136 if test -n "$1"; then
137 CPPFLAGS="$old_CPPFLAGS"
138 LDFLAGS="$old_LDFLAGS"
139 fi
140 ])
142 ## Configure body starts here.
144 AC_PREREQ(2.59)
145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
147 AC_CONFIG_SRCDIR([git.c])
149 config_file=config.mak.autogen
150 config_in=config.mak.in
152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
154 # Directories holding "saner" versions of common or POSIX binaries.
155 AC_ARG_WITH([sane-tool-path],
156 [AS_HELP_STRING(
157 [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
158 [Directories to prepend to PATH in build system and generated scripts])],
159 [if test "$withval" = "no"; then
160 withval=''
161 else
162 AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
163 fi
164 GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
165 [# If the "--with-sane-tool-path" option was not given, don't touch
166 # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
167 # This should minimize spurious differences in the behaviour of the
168 # Git build system when configure is used w.r.t. when it is not.
169 :])
171 ## Site configuration related to programs (before tests)
172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
173 #
174 # Set lib to alternative name of lib directory (e.g. lib64)
175 AC_ARG_WITH([lib],
176 [AS_HELP_STRING([--with-lib=ARG],
177 [ARG specifies alternative name for lib directory])],
178 [if test "$withval" = "no" || test "$withval" = "yes"; then
179 AC_MSG_WARN([You should provide name for --with-lib=ARG])
180 else
181 lib=$withval
182 AC_MSG_NOTICE([Setting lib to '$lib'])
183 GIT_CONF_SUBST([lib])
184 fi])
186 if test -z "$lib"; then
187 AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
188 lib=lib
189 fi
191 AC_ARG_ENABLE([pthreads],
192 [AS_HELP_STRING([--enable-pthreads=FLAGS],
193 [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
194 [The default if FLAGS is not specified is to try first -pthread]
195 [and then -lpthread.]
196 [--disable-pthreads will disable threading.])],
197 [
198 if test "x$enableval" = "xyes"; then
199 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
200 elif test "x$enableval" != "xno"; then
201 PTHREAD_CFLAGS=$enableval
202 AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
203 else
204 AC_MSG_NOTICE([POSIX Threads will be disabled.])
205 NO_PTHREADS=YesPlease
206 USER_NOPTHREAD=1
207 fi],
208 [
209 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
210 ])
212 # Define option to enable JavaScript minification
213 AC_ARG_ENABLE([jsmin],
214 [AS_HELP_STRING([--enable-jsmin=PATH],
215 [PATH is the name of a JavaScript minifier or the absolute path to one.])],
216 [
217 JSMIN=$enableval;
218 AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
219 GIT_CONF_SUBST([JSMIN])
220 ])
222 # Define option to enable CSS minification
223 AC_ARG_ENABLE([cssmin],
224 [AS_HELP_STRING([--enable-cssmin=PATH],
225 [PATH is the name of a CSS minifier or the absolute path to one.])],
226 [
227 CSSMIN=$enableval;
228 AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
229 GIT_CONF_SUBST([CSSMIN])
230 ])
232 ## Site configuration (override autodetection)
233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
234 AC_MSG_NOTICE([CHECKS for site configuration])
235 #
236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
237 # tests. These tests take up a significant amount of the total test time
238 # but are not needed unless you plan to talk to SVN repos.
239 #
240 # Define PPC_SHA1 environment variable when running make to make use of
241 # a bundled SHA1 routine optimized for PowerPC.
242 #
243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
244 #
245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
246 # /foo/bar/include and /foo/bar/lib directories.
247 AC_ARG_WITH(openssl,
248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
249 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),
250 GIT_PARSE_WITH([openssl]))
252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
253 # commands such as log and grep offer runtime options to use
254 # Perl-compatible regular expressions instead of standard or extended
255 # POSIX regular expressions. Only libpcre version 2 is supported.
256 #
257 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
258 # /foo/bar/include and /foo/bar/lib directories.
259 #
261 AC_ARG_WITH(libpcre1,
262 AS_HELP_STRING([--with-libpcre1],[DEPRECATED]),
263 AC_MSG_ERROR([support for --with-libpcre1 has been removed. Use --with-libpcre2!])
264 )
266 AC_ARG_WITH(libpcre,
267 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
268 if test "$withval" = "no"; then
269 USE_LIBPCRE2=
270 elif test "$withval" = "yes"; then
271 USE_LIBPCRE2=YesPlease
272 else
273 USE_LIBPCRE2=YesPlease
274 LIBPCREDIR=$withval
275 AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
276 dnl USE_LIBPCRE2 can still be modified below, so don't substitute
277 dnl it yet.
278 GIT_CONF_SUBST([LIBPCREDIR])
279 fi)
281 AC_ARG_WITH(libpcre2,
282 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
283 AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]),
284 if test -n "$USE_LIBPCRE2"; then
285 AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
286 fi
288 if test "$withval" = "no"; then
289 USE_LIBPCRE2=
290 elif test "$withval" = "yes"; then
291 USE_LIBPCRE2=YesPlease
292 else
293 USE_LIBPCRE2=YesPlease
294 LIBPCREDIR=$withval
295 AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
296 dnl USE_LIBPCRE2 can still be modified below, so don't substitute
297 dnl it yet.
298 GIT_CONF_SUBST([LIBPCREDIR])
299 fi)
300 #
301 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
302 AC_FUNC_ALLOCA
303 case $ac_cv_working_alloca_h in
304 yes) HAVE_ALLOCA_H=YesPlease;;
305 *) HAVE_ALLOCA_H='';;
306 esac
307 GIT_CONF_SUBST([HAVE_ALLOCA_H])
308 #
309 # Define NO_CURL if you do not have curl installed. git-http-pull and
310 # git-http-push are not built, and you cannot use http:// and https://
311 # transports.
312 #
313 # Define CURLDIR=/foo/bar if your curl header and library files are in
314 # /foo/bar/include and /foo/bar/lib directories.
315 AC_ARG_WITH(curl,
316 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
317 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
318 GIT_PARSE_WITH(curl))
319 #
320 # Define NO_EXPAT if you do not have expat installed. git-http-push is
321 # not built, and you cannot push using http:// and https:// transports.
322 #
323 # Define EXPATDIR=/foo/bar if your expat header and library files are in
324 # /foo/bar/include and /foo/bar/lib directories.
325 AC_ARG_WITH(expat,
326 AS_HELP_STRING([--with-expat],
327 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
328 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
329 GIT_PARSE_WITH(expat))
330 #
331 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
332 # installed in /sw, but don't want GIT to link against any libraries
333 # installed there. If defined you may specify your own (or Fink's)
334 # include directories and library directories by defining CFLAGS
335 # and LDFLAGS appropriately.
336 #
337 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
338 # have DarwinPorts installed in /opt/local, but don't want GIT to
339 # link against any libraries installed there. If defined you may
340 # specify your own (or DarwinPort's) include directories and
341 # library directories by defining CFLAGS and LDFLAGS appropriately.
342 #
343 # Define NO_MMAP if you want to avoid mmap.
344 #
345 # Define NO_ICONV if your libc does not properly support iconv.
346 AC_ARG_WITH(iconv,
347 AS_HELP_STRING([--without-iconv],
348 [if your architecture doesn't properly support iconv])
349 AS_HELP_STRING([--with-iconv=PATH],
350 [PATH is prefix for libiconv library and headers])
351 AS_HELP_STRING([],
352 [used only if you need linking with libiconv]),
353 GIT_PARSE_WITH(iconv))
355 ## --enable-FEATURE[=ARG] and --disable-FEATURE
356 #
357 # Define USE_NSEC below if you want git to care about sub-second file mtimes
358 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
359 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
360 # randomly break unless your underlying filesystem supports those sub-second
361 # times (my ext3 doesn't).
362 #
363 # Define USE_STDEV below if you want git to care about the underlying device
364 # change being considered an inode change from the update-index perspective.
366 #
367 # Allow user to set ETC_GITCONFIG variable
368 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
369 Use VALUE instead of /etc/gitconfig as the
370 global git configuration file.
371 If VALUE is not fully qualified it will be interpreted
372 as a path relative to the computed prefix at runtime.)
374 #
375 # Allow user to set ETC_GITATTRIBUTES variable
376 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
377 Use VALUE instead of /etc/gitattributes as the
378 global git attributes file.
379 If VALUE is not fully qualified it will be interpreted
380 as a path relative to the computed prefix at runtime.)
382 #
383 # Allow user to set the default pager
384 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
385 Use VALUE as the fall-back pager instead of 'less'.
386 This is used by things like 'git log' when the user
387 does not specify a pager to use through alternate
388 methods. eg: /usr/bin/pager)
389 #
390 # Allow user to set the default editor
391 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
392 Use VALUE as the fall-back editor instead of 'vi'.
393 This is used by things like 'git commit' when the user
394 does not specify a preferred editor through other
395 methods. eg: /usr/bin/editor)
397 #
398 # Define SHELL_PATH to provide path to shell.
399 GIT_ARG_SET_PATH(shell)
400 #
401 # Define PERL_PATH to provide path to Perl.
402 GIT_ARG_SET_PATH(perl)
403 #
404 # Define PYTHON_PATH to provide path to Python.
405 GIT_ARG_SET_PATH(python, allow-without)
406 #
407 # Define ZLIB_PATH to provide path to zlib.
408 GIT_ARG_SET_PATH(zlib)
409 #
410 # Declare the with-tcltk/without-tcltk options.
411 AC_ARG_WITH(tcltk,
412 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
413 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
414 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
415 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
416 GIT_PARSE_WITH(tcltk))
417 #
420 ## Checks for programs.
421 AC_MSG_NOTICE([CHECKS for programs])
422 #
423 AC_PROG_CC([cc gcc])
424 AC_C_INLINE
425 case $ac_cv_c_inline in
426 inline | yes | no) INLINE='';;
427 *) INLINE=$ac_cv_c_inline ;;
428 esac
429 GIT_CONF_SUBST([INLINE])
431 # which switch to pass runtime path to dynamic libraries to the linker
432 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
433 SAVE_LDFLAGS="${LDFLAGS}"
434 LDFLAGS="${SAVE_LDFLAGS} -R /"
435 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
436 LDFLAGS="${SAVE_LDFLAGS}"
437 ])
438 if test "$git_cv_ld_dashr" = "yes"; then
439 CC_LD_DYNPATH=-R
440 else
441 AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
442 SAVE_LDFLAGS="${LDFLAGS}"
443 LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
444 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
445 LDFLAGS="${SAVE_LDFLAGS}"
446 ])
447 if test "$git_cv_ld_wl_rpath" = "yes"; then
448 CC_LD_DYNPATH=-Wl,-rpath,
449 else
450 AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
451 SAVE_LDFLAGS="${LDFLAGS}"
452 LDFLAGS="${SAVE_LDFLAGS} -rpath /"
453 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
454 LDFLAGS="${SAVE_LDFLAGS}"
455 ])
456 if test "$git_cv_ld_rpath" = "yes"; then
457 CC_LD_DYNPATH=-rpath
458 else
459 AC_CACHE_CHECK([if linker supports -Wl,+b,], git_cv_ld_wl_b, [
460 SAVE_LDFLAGS="${LDFLAGS}"
461 LDFLAGS="${SAVE_LDFLAGS} -Wl,+b,/"
462 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_b=yes], [git_cv_ld_wl_b=no])
463 LDFLAGS="${SAVE_LDFLAGS}"
464 ])
465 if test "$git_cv_ld_wl_b" = "yes"; then
466 CC_LD_DYNPATH=-Wl,+b,
467 else
468 CC_LD_DYNPATH=
469 AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
470 fi
471 fi
472 fi
473 fi
474 GIT_CONF_SUBST([CC_LD_DYNPATH])
475 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
476 AC_CHECK_TOOLS(AR, [gar ar], :)
477 AC_CHECK_PROGS(TAR, [gtar tar])
478 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
479 # TCLTK_PATH will be set to some value if we want Tcl/Tk
480 # or will be empty otherwise.
481 if test -n "$NO_TCLTK"; then
482 TCLTK_PATH=
483 else
484 if test "$with_tcltk" = ""; then
485 # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
486 TCLTK_PATH=wish
487 elif test "$with_tcltk" = "yes"; then
488 # Tcl/Tk check requested.
489 AC_CHECK_PROGS(TCLTK_PATH, [wish], )
490 else
491 AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
492 TCLTK_PATH="$with_tcltk"
493 fi
494 fi
495 GIT_CONF_SUBST([TCLTK_PATH])
496 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
497 if test -n "$ASCIIDOC"; then
498 AC_MSG_CHECKING([for asciidoc version])
499 asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
500 case "${asciidoc_version}" in
501 asciidoc' '8*)
502 AC_MSG_RESULT([${asciidoc_version}])
503 ;;
504 *)
505 AC_MSG_RESULT([${asciidoc_version} (unknown)])
506 ;;
507 esac
508 fi
510 if grep -a ascii configure.ac >/dev/null; then
511 AC_MSG_RESULT([Using 'grep -a' for sane_grep])
512 SANE_TEXT_GREP=-a
513 else
514 SANE_TEXT_GREP=
515 fi
516 GIT_CONF_SUBST([SANE_TEXT_GREP])
518 ## Checks for libraries.
519 AC_MSG_NOTICE([CHECKS for libraries])
520 #
521 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
522 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
524 GIT_STASH_FLAGS($OPENSSLDIR)
526 AC_CHECK_LIB([crypto], [SHA1_Init],
527 [NEEDS_SSL_WITH_CRYPTO=],
528 [AC_CHECK_LIB([ssl], [SHA1_Init],
529 [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
530 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
532 GIT_UNSTASH_FLAGS($OPENSSLDIR)
534 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
535 GIT_CONF_SUBST([NO_OPENSSL])
537 #
538 # Handle the USE_LIBPCRE options potentially set above.
539 #
541 if test -n "$USE_LIBPCRE2"; then
543 GIT_STASH_FLAGS($LIBPCREDIR)
545 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
546 [USE_LIBPCRE2=YesPlease],
547 [USE_LIBPCRE2=])
549 GIT_UNSTASH_FLAGS($LIBPCREDIR)
551 GIT_CONF_SUBST([USE_LIBPCRE2])
553 fi
555 #
556 # Define NO_CURL if you do not have libcurl installed. git-http-pull and
557 # git-http-push are not built, and you cannot use http:// and https://
558 # transports.
560 GIT_STASH_FLAGS($CURLDIR)
562 AC_CHECK_LIB([curl], [curl_global_init],
563 [NO_CURL=],
564 [NO_CURL=YesPlease])
566 GIT_UNSTASH_FLAGS($CURLDIR)
568 GIT_CONF_SUBST([NO_CURL])
570 if test -z "$NO_CURL"; then
572 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
573 [curl-config],
574 [no])
576 if test $CURL_CONFIG != no; then
577 GIT_CONF_SUBST([CURL_CONFIG])
579 if test -z "$CURL_CONFIG_OPTS"; then
580 CURL_CONFIG_OPTS="--libs"
581 fi
583 CURL_LDFLAGS=$($CURL_CONFIG $CURL_CONFIG_OPTS)
584 AC_MSG_NOTICE([Setting CURL_LDFLAGS to '$CURL_LDFLAGS'])
585 GIT_CONF_SUBST([CURL_LDFLAGS], [$CURL_LDFLAGS])
586 fi
588 fi
591 #
592 # Define NO_EXPAT if you do not have expat installed. git-http-push is
593 # not built, and you cannot push using http:// and https:// transports.
595 GIT_STASH_FLAGS($EXPATDIR)
597 AC_CHECK_LIB([expat], [XML_ParserCreate],
598 [NO_EXPAT=],
599 [NO_EXPAT=YesPlease])
601 GIT_UNSTASH_FLAGS($EXPATDIR)
603 GIT_CONF_SUBST([NO_EXPAT])
605 #
606 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
607 # some Solaris installations).
608 # Define NO_ICONV if neither libc nor libiconv support iconv.
610 if test -z "$NO_ICONV"; then
612 GIT_STASH_FLAGS($ICONVDIR)
614 AC_DEFUN([ICONVTEST_SRC],
615 [AC_LANG_PROGRAM([#include <iconv.h>],
616 [iconv_open("", "");])])
618 if test -n "$ICONVDIR"; then
619 lib_order="-liconv -lc"
620 else
621 lib_order="-lc -liconv"
622 fi
624 NO_ICONV=YesPlease
626 for l in $lib_order; do
627 if test "$l" = "-liconv"; then
628 NEEDS_LIBICONV=YesPlease
629 else
630 NEEDS_LIBICONV=
631 fi
633 old_LIBS="$LIBS"
634 LIBS="$LIBS $l"
635 AC_MSG_CHECKING([for iconv in $l])
636 AC_LINK_IFELSE([ICONVTEST_SRC],
637 [AC_MSG_RESULT([yes])
638 NO_ICONV=
639 break],
640 [AC_MSG_RESULT([no])])
641 LIBS="$old_LIBS"
642 done
644 #in case of break
645 LIBS="$old_LIBS"
647 GIT_UNSTASH_FLAGS($ICONVDIR)
649 GIT_CONF_SUBST([NEEDS_LIBICONV])
650 GIT_CONF_SUBST([NO_ICONV])
652 if test -n "$NO_ICONV"; then
653 NEEDS_LIBICONV=
654 fi
656 fi
658 #
659 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
661 GIT_STASH_FLAGS($ZLIB_PATH)
663 AC_DEFUN([ZLIBTEST_SRC], [
664 AC_LANG_PROGRAM([#include <zlib.h>],
665 [deflateBound(0, 0);])])
666 AC_MSG_CHECKING([for deflateBound in -lz])
667 old_LIBS="$LIBS"
668 LIBS="$LIBS -lz"
669 AC_LINK_IFELSE([ZLIBTEST_SRC],
670 [AC_MSG_RESULT([yes])],
671 [AC_MSG_RESULT([no])
672 NO_DEFLATE_BOUND=yes])
673 LIBS="$old_LIBS"
675 GIT_UNSTASH_FLAGS($ZLIB_PATH)
677 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
679 #
680 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
681 # Patrick Mauritz).
682 AC_CHECK_LIB([c], [socket],
683 [NEEDS_SOCKET=],
684 [NEEDS_SOCKET=YesPlease])
685 GIT_CONF_SUBST([NEEDS_SOCKET])
686 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
688 #
689 # The next few tests will define NEEDS_RESOLV if linking with
690 # libresolv provides some of the functions we would normally get
691 # from libc.
692 NEEDS_RESOLV=
693 #
694 # Define NO_INET_NTOP if linking with -lresolv is not enough.
695 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
696 NO_INET_NTOP=
697 AC_CHECK_FUNC([inet_ntop],
698 [],
699 [AC_CHECK_LIB([resolv], [inet_ntop],
700 [NEEDS_RESOLV=YesPlease],
701 [NO_INET_NTOP=YesPlease])
702 ])
703 GIT_CONF_SUBST([NO_INET_NTOP])
704 #
705 # Define NO_INET_PTON if linking with -lresolv is not enough.
706 # Solaris 2.7 in particular hos inet_pton in -lresolv.
707 NO_INET_PTON=
708 AC_CHECK_FUNC([inet_pton],
709 [],
710 [AC_CHECK_LIB([resolv], [inet_pton],
711 [NEEDS_RESOLV=YesPlease],
712 [NO_INET_PTON=YesPlease])
713 ])
714 GIT_CONF_SUBST([NO_INET_PTON])
715 #
716 # Define NO_HSTRERROR if linking with -lresolv is not enough.
717 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
718 NO_HSTRERROR=
719 AC_CHECK_FUNC([hstrerror],
720 [],
721 [AC_CHECK_LIB([resolv], [hstrerror],
722 [NEEDS_RESOLV=YesPlease],
723 [NO_HSTRERROR=YesPlease])
724 ])
725 GIT_CONF_SUBST([NO_HSTRERROR])
727 dnl This must go after all the possible places for its initialization,
728 dnl in the AC_CHECK_FUNC invocations above.
729 GIT_CONF_SUBST([NEEDS_RESOLV])
730 #
731 # If any of the above tests determined that -lresolv is needed at
732 # build-time, also set it here for remaining configure-time checks.
733 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
735 AC_CHECK_LIB([c], [basename],
736 [NEEDS_LIBGEN=],
737 [NEEDS_LIBGEN=YesPlease])
738 GIT_CONF_SUBST([NEEDS_LIBGEN])
739 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
741 AC_DEFUN([LIBINTL_SRC], [
742 AC_LANG_PROGRAM([[
743 #include <libintl.h>
744 ]],[[
745 char *msg = gettext("test");
746 ]])])
748 AC_MSG_CHECKING([if libc contains libintl])
749 AC_LINK_IFELSE([LIBINTL_SRC],
750 [AC_MSG_RESULT([yes])
751 LIBC_CONTAINS_LIBINTL=YesPlease],
752 [AC_MSG_RESULT([no])
753 LIBC_CONTAINS_LIBINTL=])
754 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
756 #
757 # Define NO_GETTEXT if you don't want Git output to be translated.
758 # A translated Git requires GNU libintl or another gettext implementation
759 AC_CHECK_HEADER([libintl.h],
760 [NO_GETTEXT=],
761 [NO_GETTEXT=YesPlease])
762 GIT_CONF_SUBST([NO_GETTEXT])
764 if test -z "$NO_GETTEXT"; then
765 test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
766 fi
768 ## Checks for header files.
769 AC_MSG_NOTICE([CHECKS for header files])
770 #
771 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
772 AC_CHECK_HEADER([sys/select.h],
773 [NO_SYS_SELECT_H=],
774 [NO_SYS_SELECT_H=UnfortunatelyYes])
775 GIT_CONF_SUBST([NO_SYS_SELECT_H])
776 #
777 # Define NO_POLL_H if you don't have poll.h
778 AC_CHECK_HEADER([poll.h],
779 [NO_POLL_H=],
780 [NO_POLL_H=UnfortunatelyYes])
781 GIT_CONF_SUBST([NO_POLL_H])
782 #
783 # Define NO_SYS_POLL_H if you don't have sys/poll.h
784 AC_CHECK_HEADER([sys/poll.h],
785 [NO_SYS_POLL_H=],
786 [NO_SYS_POLL_H=UnfortunatelyYes])
787 GIT_CONF_SUBST([NO_SYS_POLL_H])
788 #
789 # Define NO_INTTYPES_H if you don't have inttypes.h
790 AC_CHECK_HEADER([inttypes.h],
791 [NO_INTTYPES_H=],
792 [NO_INTTYPES_H=UnfortunatelyYes])
793 GIT_CONF_SUBST([NO_INTTYPES_H])
794 #
795 # Define OLD_ICONV if your library has an old iconv(), where the second
796 # (input buffer pointer) parameter is declared with type (const char **).
797 AC_DEFUN([OLDICONVTEST_SRC], [
798 AC_LANG_PROGRAM([[
799 #include <iconv.h>
801 extern size_t iconv(iconv_t cd,
802 char **inbuf, size_t *inbytesleft,
803 char **outbuf, size_t *outbytesleft);
804 ]], [])])
806 GIT_STASH_FLAGS($ICONVDIR)
808 AC_MSG_CHECKING([for old iconv()])
809 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
810 [AC_MSG_RESULT([no])],
811 [AC_MSG_RESULT([yes])
812 AC_DEFINE(HAVE_OLD_ICONV, 1)
813 OLD_ICONV=UnfortunatelyYes])
815 GIT_UNSTASH_FLAGS($ICONVDIR)
817 GIT_CONF_SUBST([OLD_ICONV])
819 #
820 # Define ICONV_OMITS_BOM if you are on a system which
821 # iconv omits bom for utf-{16,32}
822 if test -z "$NO_ICONV"; then
823 AC_CACHE_CHECK([whether iconv omits bom for utf-16 and utf-32],
824 [ac_cv_iconv_omits_bom],
825 [
826 old_LIBS="$LIBS"
827 if test -n "$NEEDS_LIBICONV"; then
828 LIBS="$LIBS -liconv"
829 fi
831 AC_RUN_IFELSE(
832 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
833 #include <iconv.h>
834 #ifdef HAVE_OLD_ICONV
835 typedef const char *iconv_ibp;
836 #else
837 typedef char *iconv_ibp;
838 #endif
839 ],
840 [[
841 int v;
842 iconv_t conv;
843 char in[] = "a"; iconv_ibp pin = in;
844 char out[20] = ""; char *pout = out;
845 size_t isz = sizeof in;
846 size_t osz = sizeof out;
848 conv = iconv_open("UTF-16", "UTF-8");
849 iconv(conv, &pin, &isz, &pout, &osz);
850 iconv_close(conv);
851 v = (unsigned char)(out[0]) + (unsigned char)(out[1]);
852 return v != 0xfe + 0xff;
853 ]])],
854 [ac_cv_iconv_omits_bom=no],
855 [ac_cv_iconv_omits_bom=yes])
857 LIBS="$old_LIBS"
858 ])
859 if test "x$ac_cv_iconv_omits_bom" = xyes; then
860 ICONV_OMITS_BOM=Yes
861 else
862 ICONV_OMITS_BOM=
863 fi
864 GIT_CONF_SUBST([ICONV_OMITS_BOM])
865 fi
867 ## Checks for typedefs, structures, and compiler characteristics.
868 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
869 #
870 TYPE_SOCKLEN_T
871 case $ac_cv_type_socklen_t in
872 yes) SOCKLEN_T='';;
873 *) SOCKLEN_T=$git_cv_socklen_t_equiv;;
874 esac
875 GIT_CONF_SUBST([SOCKLEN_T])
877 #
878 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
879 AC_CHECK_TYPES([struct itimerval],
880 [NO_STRUCT_ITIMERVAL=],
881 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
882 [#include <sys/time.h>])
883 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
884 #
885 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
886 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
887 # stat.st_mtimespec.tv_nsec exists.
888 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
889 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
890 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
891 USE_ST_TIMESPEC=YesPlease
892 GIT_CONF_SUBST([USE_ST_TIMESPEC])
893 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
894 NO_NSEC=YesPlease
895 GIT_CONF_SUBST([NO_NSEC])
896 fi
897 #
898 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
899 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
900 AC_CHECK_MEMBER(struct dirent.d_type,
901 [NO_D_TYPE_IN_DIRENT=],
902 [NO_D_TYPE_IN_DIRENT=YesPlease],
903 [#include <dirent.h>])
904 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
905 #
906 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
907 # in the C library.
908 AC_CHECK_MEMBER(struct passwd.pw_gecos,
909 [NO_GECOS_IN_PWENT=],
910 [NO_GECOS_IN_PWENT=YesPlease],
911 [#include <pwd.h>])
912 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
913 #
914 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
915 # sockaddr_storage.
916 AC_CHECK_TYPE(struct sockaddr_storage,
917 [NO_SOCKADDR_STORAGE=],
918 [NO_SOCKADDR_STORAGE=YesPlease],[
919 #include <sys/types.h>
920 #include <sys/socket.h>
921 ])
922 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
923 #
924 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
925 AC_CHECK_TYPE([struct addrinfo],[
926 GIT_CHECK_FUNC([getaddrinfo],
927 [NO_IPV6=],
928 [NO_IPV6=YesPlease])
929 ],[NO_IPV6=YesPlease],[
930 #include <sys/types.h>
931 #include <sys/socket.h>
932 #include <netdb.h>
933 ])
934 GIT_CONF_SUBST([NO_IPV6])
935 #
936 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
937 # feature.
938 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
939 [ac_cv_c_regex_with_reg_startend], [
940 AC_EGREP_CPP(yippeeyeswehaveit,
941 AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
942 #include <regex.h>
943 ],
944 [#ifdef REG_STARTEND
945 yippeeyeswehaveit
946 #endif
947 ]),
948 [ac_cv_c_regex_with_reg_startend=yes],
949 [ac_cv_c_regex_with_reg_startend=no])
950 ])
951 if test $ac_cv_c_regex_with_reg_startend = yes; then
952 NO_REGEX=
953 else
954 NO_REGEX=YesPlease
955 fi
956 GIT_CONF_SUBST([NO_REGEX])
957 #
958 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
959 # when attempting to read from an fopen'ed directory.
960 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
961 [ac_cv_fread_reads_directories],
962 [
963 AC_RUN_IFELSE(
964 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
965 [[
966 FILE *f = fopen(".", "r");
967 return f != NULL;]])],
968 [ac_cv_fread_reads_directories=no],
969 [ac_cv_fread_reads_directories=yes])
970 ])
971 if test $ac_cv_fread_reads_directories = yes; then
972 FREAD_READS_DIRECTORIES=UnfortunatelyYes
973 else
974 FREAD_READS_DIRECTORIES=
975 fi
976 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
977 #
978 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
979 # or vsnprintf() return -1 instead of number of characters which would
980 # have been written to the final string if enough space had been available.
981 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
982 [ac_cv_snprintf_returns_bogus],
983 [
984 AC_RUN_IFELSE(
985 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
986 #include "stdarg.h"
988 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
989 {
990 int ret;
991 va_list ap;
992 va_start(ap, format);
993 ret = vsnprintf(str, maxsize, format, ap);
994 va_end(ap);
995 return ret;
996 }],
997 [[char buf[6];
998 if (test_vsnprintf(buf, 3, "%s", "12345") != 5
999 || strcmp(buf, "12")) return 1;
1000 if (snprintf(buf, 3, "%s", "12345") != 5
1001 || strcmp(buf, "12")) return 1]])],
1002 [ac_cv_snprintf_returns_bogus=no],
1003 [ac_cv_snprintf_returns_bogus=yes])
1004 ])
1005 if test $ac_cv_snprintf_returns_bogus = yes; then
1006 SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
1007 else
1008 SNPRINTF_RETURNS_BOGUS=
1009 fi
1010 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
1011 #
1012 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
1013 # bits in mode values.
1014 AC_CACHE_CHECK([whether the platform uses typical file type bits],
1015 [ac_cv_sane_mode_bits], [
1016 AC_EGREP_CPP(yippeeyeswehaveit,
1017 AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1018 [#if S_IFMT == 0170000 && \
1019 S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
1020 S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
1021 S_IFIFO == 0010000 && S_IFSOCK == 0140000
1022 yippeeyeswehaveit
1023 #endif
1024 ]),
1025 [ac_cv_sane_mode_bits=yes],
1026 [ac_cv_sane_mode_bits=no])
1027 ])
1028 if test $ac_cv_sane_mode_bits = yes; then
1029 NEEDS_MODE_TRANSLATION=
1030 else
1031 NEEDS_MODE_TRANSLATION=UnfortunatelyYes
1032 fi
1033 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
1036 ## Checks for library functions.
1037 ## (in default C library and libraries checked by AC_CHECK_LIB)
1038 AC_MSG_NOTICE([CHECKS for library functions])
1039 #
1040 # Define NO_LIBGEN_H if you don't have libgen.h.
1041 AC_CHECK_HEADER([libgen.h],
1042 [NO_LIBGEN_H=],
1043 [NO_LIBGEN_H=YesPlease])
1044 GIT_CONF_SUBST([NO_LIBGEN_H])
1045 #
1046 # Define HAVE_PATHS_H if you have paths.h.
1047 AC_CHECK_HEADER([paths.h],
1048 [HAVE_PATHS_H=YesPlease],
1049 [HAVE_PATHS_H=])
1050 GIT_CONF_SUBST([HAVE_PATHS_H])
1051 #
1052 # Define HAVE_LIBCHARSET_H if have libcharset.h
1053 AC_CHECK_HEADER([libcharset.h],
1054 [HAVE_LIBCHARSET_H=YesPlease],
1055 [HAVE_LIBCHARSET_H=])
1056 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1057 #
1058 # Define HAVE_STRINGS_H if you have strings.h
1059 AC_CHECK_HEADER([strings.h],
1060 [HAVE_STRINGS_H=YesPlease],
1061 [HAVE_STRINGS_H=])
1062 GIT_CONF_SUBST([HAVE_STRINGS_H])
1063 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1064 # and libcharset does
1065 CHARSET_LIB=
1066 AC_CHECK_LIB([iconv], [locale_charset],
1067 [CHARSET_LIB=-liconv],
1068 [AC_CHECK_LIB([charset], [locale_charset],
1069 [CHARSET_LIB=-lcharset])])
1070 GIT_CONF_SUBST([CHARSET_LIB])
1071 #
1072 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1073 GIT_CHECK_FUNC(clock_gettime,
1074 [HAVE_CLOCK_GETTIME=YesPlease],
1075 [HAVE_CLOCK_GETTIME=])
1076 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1078 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1079 AC_LANG_PROGRAM([[
1080 #include <time.h>
1081 clockid_t id = CLOCK_MONOTONIC;
1082 ]])])
1084 #
1085 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1086 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1087 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1088 [AC_MSG_RESULT([yes])
1089 HAVE_CLOCK_MONOTONIC=YesPlease],
1090 [AC_MSG_RESULT([no])
1091 HAVE_CLOCK_MONOTONIC=])
1092 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1093 #
1094 # Define NO_SETITIMER if you don't have setitimer.
1095 GIT_CHECK_FUNC(setitimer,
1096 [NO_SETITIMER=],
1097 [NO_SETITIMER=YesPlease])
1098 GIT_CONF_SUBST([NO_SETITIMER])
1099 #
1100 # Define NO_STRCASESTR if you don't have strcasestr.
1101 GIT_CHECK_FUNC(strcasestr,
1102 [NO_STRCASESTR=],
1103 [NO_STRCASESTR=YesPlease])
1104 GIT_CONF_SUBST([NO_STRCASESTR])
1105 #
1106 # Define NO_MEMMEM if you don't have memmem.
1107 GIT_CHECK_FUNC(memmem,
1108 [NO_MEMMEM=],
1109 [NO_MEMMEM=YesPlease])
1110 GIT_CONF_SUBST([NO_MEMMEM])
1111 #
1112 # Define NO_STRLCPY if you don't have strlcpy.
1113 GIT_CHECK_FUNC(strlcpy,
1114 [NO_STRLCPY=],
1115 [NO_STRLCPY=YesPlease])
1116 GIT_CONF_SUBST([NO_STRLCPY])
1117 #
1118 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1119 AC_CHECK_TYPE(uintmax_t,
1120 [NO_UINTMAX_T=],
1121 [NO_UINTMAX_T=YesPlease],[
1122 #include <inttypes.h>
1123 ])
1124 GIT_CONF_SUBST([NO_UINTMAX_T])
1125 #
1126 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1127 GIT_CHECK_FUNC(strtoumax,
1128 [NO_STRTOUMAX=],
1129 [NO_STRTOUMAX=YesPlease])
1130 GIT_CONF_SUBST([NO_STRTOUMAX])
1131 #
1132 # Define NO_SETENV if you don't have setenv in the C library.
1133 GIT_CHECK_FUNC(setenv,
1134 [NO_SETENV=],
1135 [NO_SETENV=YesPlease])
1136 GIT_CONF_SUBST([NO_SETENV])
1137 #
1138 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1139 GIT_CHECK_FUNC(unsetenv,
1140 [NO_UNSETENV=],
1141 [NO_UNSETENV=YesPlease])
1142 GIT_CONF_SUBST([NO_UNSETENV])
1143 #
1144 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1145 GIT_CHECK_FUNC(mkdtemp,
1146 [NO_MKDTEMP=],
1147 [NO_MKDTEMP=YesPlease])
1148 GIT_CONF_SUBST([NO_MKDTEMP])
1149 #
1150 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1151 GIT_CHECK_FUNC(initgroups,
1152 [NO_INITGROUPS=],
1153 [NO_INITGROUPS=YesPlease])
1154 GIT_CONF_SUBST([NO_INITGROUPS])
1155 #
1156 # Define HAVE_GETDELIM if you have getdelim in the C library.
1157 GIT_CHECK_FUNC(getdelim,
1158 [HAVE_GETDELIM=YesPlease],
1159 [HAVE_GETDELIM=])
1160 GIT_CONF_SUBST([HAVE_GETDELIM])
1161 #
1162 #
1163 # Define NO_MMAP if you want to avoid mmap.
1164 #
1165 # Define NO_ICONV if your libc does not properly support iconv.
1167 AC_DEFUN([BSD_SYSCTL_SRC], [
1168 AC_LANG_PROGRAM([[
1169 #include <stddef.h>
1170 #include <sys/types.h>
1171 #include <sys/sysctl.h>
1172 ]],[[
1173 int val, mib[2];
1174 size_t len;
1175 mib[0] = CTL_HW;
1176 mib[1] = 1;
1177 len = sizeof(val);
1178 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1179 ]])])
1181 #
1182 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1183 AC_MSG_CHECKING([for BSD sysctl])
1184 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1185 [AC_MSG_RESULT([yes])
1186 HAVE_BSD_SYSCTL=YesPlease],
1187 [AC_MSG_RESULT([no])
1188 HAVE_BSD_SYSCTL=])
1189 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1191 ## Other checks.
1192 # Define USE_PIC if you need the main git objects to be built with -fPIC
1193 # in order to build and link perl/Git.so. x86-64 seems to need this.
1194 #
1195 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1196 # Enable it on Windows. By default, symrefs are still used.
1197 #
1198 # Define NO_PTHREADS if we do not have pthreads.
1199 #
1200 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1201 AC_DEFUN([PTHREADTEST_SRC], [
1202 AC_LANG_PROGRAM([[
1203 #include <pthread.h>
1204 static void *noop(void *ignore) { return ignore; }
1205 ]], [[
1206 pthread_mutex_t test_mutex;
1207 pthread_key_t test_key;
1208 pthread_t th;
1209 int retcode = 0;
1210 void *ret = (void *)0;
1211 retcode |= pthread_key_create(&test_key, (void *)0);
1212 retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1213 retcode |= pthread_mutex_lock(&test_mutex);
1214 retcode |= pthread_mutex_unlock(&test_mutex);
1215 retcode |= pthread_create(&th, ret, noop, ret);
1216 retcode |= pthread_join(th, &ret);
1217 return retcode;
1218 ]])])
1220 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1221 dnl [[#include <pthread.h>]],
1222 dnl [[pthread_mutex_t test_mutex;]]
1223 dnl )])
1225 NO_PTHREADS=UnfortunatelyYes
1226 PTHREAD_LIBS=
1228 if test -n "$USER_NOPTHREAD"; then
1229 AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1230 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1231 # -D_REENTRANT' or some such.
1232 elif test -z "$PTHREAD_CFLAGS"; then
1233 threads_found=no
1234 # Attempt to compile and link some code using pthreads to determine
1235 # required linker flags. The order is somewhat important here: We
1236 # first try it without any extra flags, to catch systems where
1237 # pthreads are part of the C library, then go on testing various other
1238 # flags. We do so to avoid false positives. For example, on Mac OS X
1239 # pthreads are part of the C library; moreover, the compiler allows us
1240 # to add "-mt" to the CFLAGS (although it will do nothing except
1241 # trigger a warning about an unused flag). Hence if we checked for
1242 # "-mt" before "" we would end up picking it. But unfortunately this
1243 # would then trigger compiler warnings on every single file we compile.
1244 for opt in "" -mt -pthread -lpthread; do
1245 old_CFLAGS="$CFLAGS"
1246 old_LIBS="$LIBS"
1247 case "$opt" in
1248 -l*) LIBS="$opt $LIBS" ;;
1249 *) CFLAGS="$opt $CFLAGS" ;;
1250 esac
1252 AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1253 AC_LINK_IFELSE([PTHREADTEST_SRC],
1254 [AC_MSG_RESULT([yes])
1255 NO_PTHREADS=
1256 PTHREAD_LIBS="$opt"
1257 PTHREAD_CFLAGS="$opt"
1258 threads_found=yes
1259 break
1260 ],
1261 [AC_MSG_RESULT([no])])
1262 CFLAGS="$old_CFLAGS"
1263 LIBS="$old_LIBS"
1264 done
1265 if test $threads_found != yes; then
1266 AC_CHECK_LIB([pthread], [pthread_create],
1267 [PTHREAD_LIBS="-lpthread"],
1268 [NO_PTHREADS=UnfortunatelyYes])
1269 fi
1270 else
1271 old_CFLAGS="$CFLAGS"
1272 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1273 AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1274 AC_LINK_IFELSE([PTHREADTEST_SRC],
1275 [AC_MSG_RESULT([yes])
1276 NO_PTHREADS=
1277 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1278 ],
1279 [AC_MSG_RESULT([no])])
1281 CFLAGS="$old_CFLAGS"
1282 fi
1284 CFLAGS="$old_CFLAGS"
1286 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1287 GIT_CONF_SUBST([PTHREAD_LIBS])
1288 GIT_CONF_SUBST([NO_PTHREADS])
1290 ## Output files
1291 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1292 AC_OUTPUT