?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
fast-import: fix unalinged allocation and access
[git.git] / git-svn.perl
blobd411a343170cf8dce9d968b84f123855b03e53d3
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
11
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
16
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
45
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
58
59 my ($SVN);
60
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
86
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
105
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
190
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
199
200 # make sure we're always running
201 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
221
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
223
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
233
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
238
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
250
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
258
259 print $fd "Available commands:\n" unless $cmd;
260
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
280
281 exit $exit;
282 }
283
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
288
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
311
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
318
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
331
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
345
346 Git::SVN->init($url);
347 }
348
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
365
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
401
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase will be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 next if $_no_rebase;
457
458 # we always want to rebase against the current HEAD,
459 # not any head that was passed to us
460 my @diff = command('diff-tree', $d,
461 $gs->refname, '--');
462 my @finish;
463 if (@diff) {
464 @finish = rebase_cmd();
465 print STDERR "W: $d and ", $gs->refname,
466 " differ, using @finish:\n",
467 join("\n", @diff), "\n";
468 } else {
469 print "No changes between current HEAD and ",
470 $gs->refname,
471 "\nResetting to the latest ",
472 $gs->refname, "\n";
473 @finish = qw/reset --mixed/;
474 }
475 command_noisy(@finish, $gs->refname);
476 if (@diff) {
477 @refs = ();
478 my ($url_, $rev_, $uuid_, $gs_) =
479 working_head_info($head, \@refs);
480 my ($linear_refs_, $parents_) =
481 linearize_history($gs_, \@refs);
482 if (scalar(@$linear_refs) !=
483 scalar(@$linear_refs_)) {
484 fatal "# of revisions changed ",
485 "\nbefore:\n",
486 join("\n", @$linear_refs),
487 "\n\nafter:\n",
488 join("\n", @$linear_refs_), "\n",
489 'If you are attempting to commit ',
490 "merges, try running:\n\t",
491 'git rebase --interactive',
492 '--preserve-merges ',
493 $gs->refname,
494 "\nBefore dcommitting";
495 }
496 if ($url_ ne $url) {
497 fatal "URL mismatch after rebase: ",
498 "$url_ != $url";
499 }
500 if ($uuid_ ne $uuid) {
501 fatal "uuid mismatch after rebase: ",
502 "$uuid_ != $uuid";
503 }
504 # remap parents
505 my (%p, @l, $i);
506 for ($i = 0; $i < scalar @$linear_refs; $i++) {
507 my $new = $linear_refs_->[$i] or next;
508 $p{$new} =
509 $parents->{$linear_refs->[$i]};
510 push @l, $new;
511 }
512 $parents = \%p;
513 $linear_refs = \@l;
514 }
515 $last_rev = $cmt_rev;
516 }
517 }
518 unlink $gs->{index};
519 }
520
521 sub cmd_find_rev {
522 my $revision_or_hash = shift;
523 my $result;
524 if ($revision_or_hash =~ /^r\d+$/) {
525 my $head = shift;
526 $head ||= 'HEAD';
527 my @refs;
528 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
529 unless ($gs) {
530 die "Unable to determine upstream SVN information from ",
531 "$head history\n";
532 }
533 my $desired_revision = substr($revision_or_hash, 1);
534 $result = $gs->rev_map_get($desired_revision);
535 } else {
536 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
537 $result = $rev;
538 }
539 print "$result\n" if $result;
540 }
541
542 sub cmd_rebase {
543 command_noisy(qw/update-index --refresh/);
544 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
545 unless ($gs) {
546 die "Unable to determine upstream SVN information from ",
547 "working tree history\n";
548 }
549 if (command(qw/diff-index HEAD --/)) {
550 print STDERR "Cannot rebase with uncommited changes:\n";
551 command_noisy('status');
552 exit 1;
553 }
554 unless ($_local) {
555 # rebase will checkout for us, so no need to do it explicitly
556 $_no_checkout = 'true';
557 $_fetch_all ? $gs->fetch_all : $gs->fetch;
558 }
559 command_noisy(rebase_cmd(), $gs->refname);
560 }
561
562 sub cmd_show_ignore {
563 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
564 $gs ||= Git::SVN->new;
565 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
566 $gs->prop_walk($gs->{path}, $r, sub {
567 my ($gs, $path, $props) = @_;
568 print STDOUT "\n# $path\n";
569 my $s = $props->{'svn:ignore'} or return;
570 $s =~ s/[\r\n]+/\n/g;
571 chomp $s;
572 $s =~ s#^#$path#gm;
573 print STDOUT "$s\n";
574 });
575 }
576
577 sub cmd_show_externals {
578 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
579 $gs ||= Git::SVN->new;
580 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
581 $gs->prop_walk($gs->{path}, $r, sub {
582 my ($gs, $path, $props) = @_;
583 print STDOUT "\n# $path\n";
584 my $s = $props->{'svn:externals'} or return;
585 $s =~ s/[\r\n]+/\n/g;
586 chomp $s;
587 $s =~ s#^#$path#gm;
588 print STDOUT "$s\n";
589 });
590 }
591
592 sub cmd_create_ignore {
593 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
594 $gs ||= Git::SVN->new;
595 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
596 $gs->prop_walk($gs->{path}, $r, sub {
597 my ($gs, $path, $props) = @_;
598 # $path is of the form /path/to/dir/
599 my $ignore = '.' . $path . '.gitignore';
600 my $s = $props->{'svn:ignore'} or return;
601 open(GITIGNORE, '>', $ignore)
602 or fatal("Failed to open `$ignore' for writing: $!");
603 $s =~ s/[\r\n]+/\n/g;
604 chomp $s;
605 # Prefix all patterns so that the ignore doesn't apply
606 # to sub-directories.
607 $s =~ s#^#/#gm;
608 print GITIGNORE "$s\n";
609 close(GITIGNORE)
610 or fatal("Failed to close `$ignore': $!");
611 command_noisy('add', $ignore);
612 });
613 }
614
615 sub canonicalize_path {
616 my ($path) = @_;
617 my $dot_slash_added = 0;
618 if (substr($path, 0, 1) ne "/") {
619 $path = "./" . $path;
620 $dot_slash_added = 1;
621 }
622 # File::Spec->canonpath doesn't collapse x/../y into y (for a
623 # good reason), so let's do this manually.
624 $path =~ s#/+#/#g;
625 $path =~ s#/\.(?:/|$)#/#g;
626 $path =~ s#/[^/]+/\.\.##g;
627 $path =~ s#/$##g;
628 $path =~ s#^\./## if $dot_slash_added;
629 return $path;
630 }
631
632 # get_svnprops(PATH)
633 # ------------------
634 # Helper for cmd_propget and cmd_proplist below.
635 sub get_svnprops {
636 my $path = shift;
637 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
638 $gs ||= Git::SVN->new;
639
640 # prefix THE PATH by the sub-directory from which the user
641 # invoked us.
642 $path = $cmd_dir_prefix . $path;
643 fatal("No such file or directory: $path") unless -e $path;
644 my $is_dir = -d $path ? 1 : 0;
645 $path = $gs->{path} . '/' . $path;
646
647 # canonicalize the path (otherwise libsvn will abort or fail to
648 # find the file)
649 $path = canonicalize_path($path);
650
651 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
652 my $props;
653 if ($is_dir) {
654 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
655 }
656 else {
657 (undef, $props) = $gs->ra->get_file($path, $r, undef);
658 }
659 return $props;
660 }
661
662 # cmd_propget (PROP, PATH)
663 # ------------------------
664 # Print the SVN property PROP for PATH.
665 sub cmd_propget {
666 my ($prop, $path) = @_;
667 $path = '.' if not defined $path;
668 usage(1) if not defined $prop;
669 my $props = get_svnprops($path);
670 if (not defined $props->{$prop}) {
671 fatal("`$path' does not have a `$prop' SVN property.");
672 }
673 print $props->{$prop} . "\n";
674 }
675
676 # cmd_proplist (PATH)
677 # -------------------
678 # Print the list of SVN properties for PATH.
679 sub cmd_proplist {
680 my $path = shift;
681 $path = '.' if not defined $path;
682 my $props = get_svnprops($path);
683 print "Properties on '$path':\n";
684 foreach (sort keys %{$props}) {
685 print " $_\n";
686 }
687 }
688
689 sub cmd_multi_init {
690 my $url = shift;
691 unless (defined $_trunk || defined $_branches || defined $_tags) {
692 usage(1);
693 }
694
695 # there are currently some bugs that prevent multi-init/multi-fetch
696 # setups from working well without this.
697 $Git::SVN::_minimize_url = 1;
698
699 $_prefix = '' unless defined $_prefix;
700 if (defined $url) {
701 $url =~ s#/+$##;
702 init_subdir(@_);
703 }
704 do_git_init_db();
705 if (defined $_trunk) {
706 my $trunk_ref = $_prefix . 'trunk';
707 # try both old-style and new-style lookups:
708 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
709 unless ($gs_trunk) {
710 my ($trunk_url, $trunk_path) =
711 complete_svn_url($url, $_trunk);
712 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
713 undef, $trunk_ref);
714 }
715 }
716 return unless defined $_branches || defined $_tags;
717 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
718 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
719 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
720 }
721
722 sub cmd_multi_fetch {
723 my $remotes = Git::SVN::read_all_remotes();
724 foreach my $repo_id (sort keys %$remotes) {
725 if ($remotes->{$repo_id}->{url}) {
726 Git::SVN::fetch_all($repo_id, $remotes);
727 }
728 }
729 }
730
731 # this command is special because it requires no metadata
732 sub cmd_commit_diff {
733 my ($ta, $tb, $url) = @_;
734 my $usage = "Usage: $0 commit-diff -r<revision> ".
735 "<tree-ish> <tree-ish> [<URL>]";
736 fatal($usage) if (!defined $ta || !defined $tb);
737 my $svn_path;
738 if (!defined $url) {
739 my $gs = eval { Git::SVN->new };
740 if (!$gs) {
741 fatal("Needed URL or usable git-svn --id in ",
742 "the command-line\n", $usage);
743 }
744 $url = $gs->{url};
745 $svn_path = $gs->{path};
746 }
747 unless (defined $_revision) {
748 fatal("-r|--revision is a required argument\n", $usage);
749 }
750 if (defined $_message && defined $_file) {
751 fatal("Both --message/-m and --file/-F specified ",
752 "for the commit message.\n",
753 "I have no idea what you mean");
754 }
755 if (defined $_file) {
756 $_message = file_to_s($_file);
757 } else {
758 $_message ||= get_commit_entry($tb)->{log};
759 }
760 my $ra ||= Git::SVN::Ra->new($url);
761 $svn_path ||= $ra->{svn_path};
762 my $r = $_revision;
763 if ($r eq 'HEAD') {
764 $r = $ra->get_latest_revnum;
765 } elsif ($r !~ /^\d+$/) {
766 die "revision argument: $r not understood by git-svn\n";
767 }
768 my %ed_opts = ( r => $r,
769 log => $_message,
770 ra => $ra,
771 tree_a => $ta,
772 tree_b => $tb,
773 editor_cb => sub { print "Committed r$_[0]\n" },
774 svn_path => $svn_path );
775 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
776 print "No changes\n$ta == $tb\n";
777 }
778 }
779
780 sub cmd_info {
781 my $path = canonicalize_path(shift or ".");
782 unless (scalar(@_) == 0) {
783 die "Too many arguments specified\n";
784 }
785
786 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
787
788 if (!$file_type && !$diff_status) {
789 print STDERR "$path: (Not a versioned resource)\n\n";
790 return;
791 }
792
793 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
794 unless ($gs) {
795 die "Unable to determine upstream SVN information from ",
796 "working tree history\n";
797 }
798 my $full_url = $url . ($path eq "." ? "" : "/$path");
799
800 if ($_url) {
801 print $full_url, "\n";
802 return;
803 }
804
805 my $result = "Path: $path\n";
806 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
807 $result .= "URL: " . $full_url . "\n";
808
809 eval {
810 my $repos_root = $gs->repos_root;
811 Git::SVN::remove_username($repos_root);
812 $result .= "Repository Root: $repos_root\n";
813 };
814 if ($@) {
815 $result .= "Repository Root: (offline)\n";
816 }
817 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
818 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
819
820 $result .= "Node Kind: " .
821 ($file_type eq "dir" ? "directory" : "file") . "\n";
822
823 my $schedule = $diff_status eq "A"
824 ? "add"
825 : ($diff_status eq "D" ? "delete" : "normal");
826 $result .= "Schedule: $schedule\n";
827
828 if ($diff_status eq "A") {
829 print $result, "\n";
830 return;
831 }
832
833 my ($lc_author, $lc_rev, $lc_date_utc);
834 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
835 my $log = command_output_pipe(@args);
836 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
837 while (<$log>) {
838 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
839 $lc_author = $1;
840 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
841 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
842 (undef, $lc_rev, undef) = ::extract_metadata($1);
843 }
844 }
845 close $log;
846
847 Git::SVN::Log::set_local_timezone();
848
849 $result .= "Last Changed Author: $lc_author\n";
850 $result .= "Last Changed Rev: $lc_rev\n";
851 $result .= "Last Changed Date: " .
852 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
853
854 if ($file_type ne "dir") {
855 my $text_last_updated_date =
856 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
857 $result .=
858 "Text Last Updated: " .
859 Git::SVN::Log::format_svn_date($text_last_updated_date) .
860 "\n";
861 my $checksum;
862 if ($diff_status eq "D") {
863 my ($fh, $ctx) =
864 command_output_pipe(qw(cat-file blob), "HEAD:$path");
865 if ($file_type eq "link") {
866 my $file_name = <$fh>;
867 $checksum = md5sum("link $file_name");
868 } else {
869 $checksum = md5sum($fh);
870 }
871 command_close_pipe($fh, $ctx);
872 } elsif ($file_type eq "link") {
873 my $file_name =
874 command(qw(cat-file blob), "HEAD:$path");
875 $checksum =
876 md5sum("link " . $file_name);
877 } else {
878 open FILE, "<", $path or die $!;
879 $checksum = md5sum(\*FILE);
880 close FILE or die $!;
881 }
882 $result .= "Checksum: " . $checksum . "\n";
883 }
884
885 print $result, "\n";
886 }
887
888 ########################### utility functions #########################
889
890 sub rebase_cmd {
891 my @cmd = qw/rebase/;
892 push @cmd, '-v' if $_verbose;
893 push @cmd, qw/--merge/ if $_merge;
894 push @cmd, "--strategy=$_strategy" if $_strategy;
895 @cmd;
896 }
897
898 sub post_fetch_checkout {
899 return if $_no_checkout;
900 my $gs = $Git::SVN::_head or return;
901 return if verify_ref('refs/heads/master^0');
902
903 my $valid_head = verify_ref('HEAD^0');
904 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
905 return if ($valid_head || !verify_ref('HEAD^0'));
906
907 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
908 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
909 return if -f $index;
910
911 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
912 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
913 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
914 print STDERR "Checked out HEAD:\n ",
915 $gs->full_url, " r", $gs->last_rev, "\n";
916 }
917
918 sub complete_svn_url {
919 my ($url, $path) = @_;
920 $path =~ s#/+$##;
921 if ($path !~ m#^[a-z\+]+://#) {
922 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
923 fatal("E: '$path' is not a complete URL ",
924 "and a separate URL is not specified");
925 }
926 return ($url, $path);
927 }
928 return ($path, '');
929 }
930
931 sub complete_url_ls_init {
932 my ($ra, $repo_path, $switch, $pfx) = @_;
933 unless ($repo_path) {
934 print STDERR "W: $switch not specified\n";
935 return;
936 }
937 $repo_path =~ s#/+$##;
938 if ($repo_path =~ m#^[a-z\+]+://#) {
939 $ra = Git::SVN::Ra->new($repo_path);
940 $repo_path = '';
941 } else {
942 $repo_path =~ s#^/+##;
943 unless ($ra) {
944 fatal("E: '$repo_path' is not a complete URL ",
945 "and a separate URL is not specified");
946 }
947 }
948 my $url = $ra->{url};
949 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
950 my $k = "svn-remote.$gs->{repo_id}.url";
951 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
952 if ($orig_url && ($orig_url ne $gs->{url})) {
953 die "$k already set: $orig_url\n",
954 "wanted to set to: $gs->{url}\n";
955 }
956 command_oneline('config', $k, $gs->{url}) unless $orig_url;
957 my $remote_path = "$ra->{svn_path}/$repo_path/*";
958 $remote_path =~ s#/+#/#g;
959 $remote_path =~ s#^/##g;
960 my ($n) = ($switch =~ /^--(\w+)/);
961 if (length $pfx && $pfx !~ m#/$#) {
962 die "--prefix='$pfx' must have a trailing slash '/'\n";
963 }
964 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
965 "$remote_path:refs/remotes/$pfx*");
966 }
967
968 sub verify_ref {
969 my ($ref) = @_;
970 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
971 { STDERR => 0 }); };
972 }
973
974 sub get_tree_from_treeish {
975 my ($treeish) = @_;
976 # $treeish can be a symbolic ref, too:
977 my $type = command_oneline(qw/cat-file -t/, $treeish);
978 my $expected;
979 while ($type eq 'tag') {
980 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
981 }
982 if ($type eq 'commit') {
983 $expected = (grep /^tree /, command(qw/cat-file commit/,
984 $treeish))[0];
985 ($expected) = ($expected =~ /^tree ($sha1)$/o);
986 die "Unable to get tree from $treeish\n" unless $expected;
987 } elsif ($type eq 'tree') {
988 $expected = $treeish;
989 } else {
990 die "$treeish is a $type, expected tree, tag or commit\n";
991 }
992 return $expected;
993 }
994
995 sub get_commit_entry {
996 my ($treeish) = shift;
997 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
998 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
999 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1000 open my $log_fh, '>', $commit_editmsg or croak $!;
1001
1002 my $type = command_oneline(qw/cat-file -t/, $treeish);
1003 if ($type eq 'commit' || $type eq 'tag') {
1004 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1005 $type, $treeish);
1006 my $in_msg = 0;
1007 while (<$msg_fh>) {
1008 if (!$in_msg) {
1009 $in_msg = 1 if (/^\s*$/);
1010 } elsif (/^git-svn-id: /) {
1011 # skip this for now, we regenerate the
1012 # correct one on re-fetch anyways
1013 # TODO: set *:merge properties or like...
1014 } else {
1015 print $log_fh $_ or croak $!;
1016 }
1017 }
1018 command_close_pipe($msg_fh, $ctx);
1019 }
1020 close $log_fh or croak $!;
1021
1022 if ($_edit || ($type eq 'tree')) {
1023 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1024 # TODO: strip out spaces, comments, like git-commit.sh
1025 system($editor, $commit_editmsg);
1026 }
1027 rename $commit_editmsg, $commit_msg or croak $!;
1028 open $log_fh, '<', $commit_msg or croak $!;
1029 { local $/; chomp($log_entry{log} = <$log_fh>); }
1030 close $log_fh or croak $!;
1031 unlink $commit_msg;
1032 \%log_entry;
1033 }
1034
1035 sub s_to_file {
1036 my ($str, $file, $mode) = @_;
1037 open my $fd,'>',$file or croak $!;
1038 print $fd $str,"\n" or croak $!;
1039 close $fd or croak $!;
1040 chmod ($mode &~ umask, $file) if (defined $mode);
1041 }
1042
1043 sub file_to_s {
1044 my $file = shift;
1045 open my $fd,'<',$file or croak "$!: file: $file\n";
1046 local $/;
1047 my $ret = <$fd>;
1048 close $fd or croak $!;
1049 $ret =~ s/\s*$//s;
1050 return $ret;
1051 }
1052
1053 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1054 sub load_authors {
1055 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1056 my $log = $cmd eq 'log';
1057 while (<$authors>) {
1058 chomp;
1059 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1060 my ($user, $name, $email) = ($1, $2, $3);
1061 if ($log) {
1062 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1063 } else {
1064 $users{$user} = [$name, $email];
1065 }
1066 }
1067 close $authors or croak $!;
1068 }
1069
1070 # convert GetOpt::Long specs for use by git-config
1071 sub read_repo_config {
1072 return unless -d $ENV{GIT_DIR};
1073 my $opts = shift;
1074 my @config_only;
1075 foreach my $o (keys %$opts) {
1076 # if we have mixedCase and a long option-only, then
1077 # it's a config-only variable that we don't need for
1078 # the command-line.
1079 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1080 my $v = $opts->{$o};
1081 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1082 $key =~ s/-//g;
1083 my $arg = 'git-config';
1084 $arg .= ' --int' if ($o =~ /[:=]i$/);
1085 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1086 if (ref $v eq 'ARRAY') {
1087 chomp(my @tmp = `$arg --get-all svn.$key`);
1088 @$v = @tmp if @tmp;
1089 } else {
1090 chomp(my $tmp = `$arg --get svn.$key`);
1091 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1092 $$v = $tmp;
1093 }
1094 }
1095 }
1096 delete @$opts{@config_only} if @config_only;
1097 }
1098
1099 sub extract_metadata {
1100 my $id = shift or return (undef, undef, undef);
1101 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1102 \s([a-f\d\-]+)$/x);
1103 if (!defined $rev || !$uuid || !$url) {
1104 # some of the original repositories I made had
1105 # identifiers like this:
1106 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1107 }
1108 return ($url, $rev, $uuid);
1109 }
1110
1111 sub cmt_metadata {
1112 return extract_metadata((grep(/^git-svn-id: /,
1113 command(qw/cat-file commit/, shift)))[-1]);
1114 }
1115
1116 sub working_head_info {
1117 my ($head, $refs) = @_;
1118 my @args = ('log', '--no-color', '--first-parent');
1119 my ($fh, $ctx) = command_output_pipe(@args, $head);
1120 my $hash;
1121 my %max;
1122 while (<$fh>) {
1123 if ( m{^commit ($::sha1)$} ) {
1124 unshift @$refs, $hash if $hash and $refs;
1125 $hash = $1;
1126 next;
1127 }
1128 next unless s{^\s*(git-svn-id:)}{$1};
1129 my ($url, $rev, $uuid) = extract_metadata($_);
1130 if (defined $url && defined $rev) {
1131 next if $max{$url} and $max{$url} < $rev;
1132 if (my $gs = Git::SVN->find_by_url($url)) {
1133 my $c = $gs->rev_map_get($rev);
1134 if ($c && $c eq $hash) {
1135 close $fh; # break the pipe
1136 return ($url, $rev, $uuid, $gs);
1137 } else {
1138 $max{$url} ||= $gs->rev_map_max;
1139 }
1140 }
1141 }
1142 }
1143 command_close_pipe($fh, $ctx);
1144 (undef, undef, undef, undef);
1145 }
1146
1147 sub read_commit_parents {
1148 my ($parents, $c) = @_;
1149 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1150 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1151 @{$parents->{$c}} = split(/ /, $p);
1152 }
1153
1154 sub linearize_history {
1155 my ($gs, $refs) = @_;
1156 my %parents;
1157 foreach my $c (@$refs) {
1158 read_commit_parents(\%parents, $c);
1159 }
1160
1161 my @linear_refs;
1162 my %skip = ();
1163 my $last_svn_commit = $gs->last_commit;
1164 foreach my $c (reverse @$refs) {
1165 next if $c eq $last_svn_commit;
1166 last if $skip{$c};
1167
1168 unshift @linear_refs, $c;
1169 $skip{$c} = 1;
1170
1171 # we only want the first parent to diff against for linear
1172 # history, we save the rest to inject when we finalize the
1173 # svn commit
1174 my $fp_a = verify_ref("$c~1");
1175 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1176 if (!$fp_a || !$fp_b) {
1177 die "Commit $c\n",
1178 "has no parent commit, and therefore ",
1179 "nothing to diff against.\n",
1180 "You should be working from a repository ",
1181 "originally created by git-svn\n";
1182 }
1183 if ($fp_a ne $fp_b) {
1184 die "$c~1 = $fp_a, however parsing commit $c ",
1185 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1186 }
1187
1188 foreach my $p (@{$parents{$c}}) {
1189 $skip{$p} = 1;
1190 }
1191 }
1192 (\@linear_refs, \%parents);
1193 }
1194
1195 sub find_file_type_and_diff_status {
1196 my ($path) = @_;
1197 return ('dir', '') if $path eq '.';
1198
1199 my $diff_output =
1200 command_oneline(qw(diff --cached --name-status --), $path) || "";
1201 my $diff_status = (split(' ', $diff_output))[0] || "";
1202
1203 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1204
1205 return (undef, undef) if !$diff_status && !$ls_tree;
1206
1207 if ($diff_status eq "A") {
1208 return ("link", $diff_status) if -l $path;
1209 return ("dir", $diff_status) if -d $path;
1210 return ("file", $diff_status);
1211 }
1212
1213 my $mode = (split(' ', $ls_tree))[0] || "";
1214
1215 return ("link", $diff_status) if $mode eq "120000";
1216 return ("dir", $diff_status) if $mode eq "040000";
1217 return ("file", $diff_status);
1218 }
1219
1220 sub md5sum {
1221 my $arg = shift;
1222 my $ref = ref $arg;
1223 my $md5 = Digest::MD5->new();
1224 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1225 $md5->addfile($arg) or croak $!;
1226 } elsif ($ref eq 'SCALAR') {
1227 $md5->add($$arg) or croak $!;
1228 } elsif (!$ref) {
1229 $md5->add($arg) or croak $!;
1230 } else {
1231 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1232 }
1233 return $md5->hexdigest();
1234 }
1235
1236 package Git::SVN;
1237 use strict;
1238 use warnings;
1239 use Fcntl qw/:DEFAULT :seek/;
1240 use constant rev_map_fmt => 'NH40';
1241 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1242 $_repack $_repack_flags $_use_svm_props $_head
1243 $_use_svnsync_props $no_reuse_existing $_minimize_url
1244 $_use_log_author/;
1245 use Carp qw/croak/;
1246 use File::Path qw/mkpath/;
1247 use File::Copy qw/copy/;
1248 use IPC::Open3;
1249
1250 my $_repack_nr;
1251 # properties that we do not log:
1252 my %SKIP_PROP;
1253 BEGIN {
1254 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1255 svn:special svn:executable
1256 svn:entry:committed-rev
1257 svn:entry:last-author
1258 svn:entry:uuid
1259 svn:entry:committed-date/;
1260
1261 # some options are read globally, but can be overridden locally
1262 # per [svn-remote "..."] section. Command-line options will *NOT*
1263 # override options set in an [svn-remote "..."] section
1264 no strict 'refs';
1265 for my $option (qw/follow_parent no_metadata use_svm_props
1266 use_svnsync_props/) {
1267 my $key = $option;
1268 $key =~ tr/_//d;
1269 my $prop = "-$option";
1270 *$option = sub {
1271 my ($self) = @_;
1272 return $self->{$prop} if exists $self->{$prop};
1273 my $k = "svn-remote.$self->{repo_id}.$key";
1274 eval { command_oneline(qw/config --get/, $k) };
1275 if ($@) {
1276 $self->{$prop} = ${"Git::SVN::_$option"};
1277 } else {
1278 my $v = command_oneline(qw/config --bool/,$k);
1279 $self->{$prop} = $v eq 'false' ? 0 : 1;
1280 }
1281 return $self->{$prop};
1282 }
1283 }
1284 }
1285
1286 my %LOCKFILES;
1287 END { unlink keys %LOCKFILES if %LOCKFILES }
1288
1289 sub resolve_local_globs {
1290 my ($url, $fetch, $glob_spec) = @_;
1291 return unless defined $glob_spec;
1292 my $ref = $glob_spec->{ref};
1293 my $path = $glob_spec->{path};
1294 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1295 next unless m#^refs/remotes/$ref->{regex}$#;
1296 my $p = $1;
1297 my $pathname = desanitize_refname($path->full_path($p));
1298 my $refname = desanitize_refname($ref->full_path($p));
1299 if (my $existing = $fetch->{$pathname}) {
1300 if ($existing ne $refname) {
1301 die "Refspec conflict:\n",
1302 "existing: refs/remotes/$existing\n",
1303 " globbed: refs/remotes/$refname\n";
1304 }
1305 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1306 $u =~ s!^\Q$url\E(/|$)!! or die
1307 "refs/remotes/$refname: '$url' not found in '$u'\n";
1308 if ($pathname ne $u) {
1309 warn "W: Refspec glob conflict ",
1310 "(ref: refs/remotes/$refname):\n",
1311 "expected path: $pathname\n",
1312 " real path: $u\n",
1313 "Continuing ahead with $u\n";
1314 next;
1315 }
1316 } else {
1317 $fetch->{$pathname} = $refname;
1318 }
1319 }
1320 }
1321
1322 sub parse_revision_argument {
1323 my ($base, $head) = @_;
1324 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1325 return ($base, $head);
1326 }
1327 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1328 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1329 return ($head, $head) if ($::_revision eq 'HEAD');
1330 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1331 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1332 die "revision argument: $::_revision not understood by git-svn\n";
1333 }
1334
1335 sub fetch_all {
1336 my ($repo_id, $remotes) = @_;
1337 if (ref $repo_id) {
1338 my $gs = $repo_id;
1339 $repo_id = undef;
1340 $repo_id = $gs->{repo_id};
1341 }
1342 $remotes ||= read_all_remotes();
1343 my $remote = $remotes->{$repo_id} or
1344 die "[svn-remote \"$repo_id\"] unknown\n";
1345 my $fetch = $remote->{fetch};
1346 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1347 my (@gs, @globs);
1348 my $ra = Git::SVN::Ra->new($url);
1349 my $uuid = $ra->get_uuid;
1350 my $head = $ra->get_latest_revnum;
1351 my $base = defined $fetch ? $head : 0;
1352
1353 # read the max revs for wildcard expansion (branches/*, tags/*)
1354 foreach my $t (qw/branches tags/) {
1355 defined $remote->{$t} or next;
1356 push @globs, $remote->{$t};
1357 my $max_rev = eval { tmp_config(qw/--int --get/,
1358 "svn-remote.$repo_id.${t}-maxRev") };
1359 if (defined $max_rev && ($max_rev < $base)) {
1360 $base = $max_rev;
1361 } elsif (!defined $max_rev) {
1362 $base = 0;
1363 }
1364 }
1365
1366 if ($fetch) {
1367 foreach my $p (sort keys %$fetch) {
1368 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1369 my $lr = $gs->rev_map_max;
1370 if (defined $lr) {
1371 $base = $lr if ($lr < $base);
1372 }
1373 push @gs, $gs;
1374 }
1375 }
1376
1377 ($base, $head) = parse_revision_argument($base, $head);
1378 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1379 unlink $_->{index} foreach @gs;
1380 }
1381
1382 sub read_all_remotes {
1383 my $r = {};
1384 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1385 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1386 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1387 $local_ref =~ s{^/}{};
1388 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1389 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1390 $r->{$1}->{url} = $2;
1391 } elsif (m!^(.+)\.(branches|tags)=
1392 (.*):refs/remotes/(.+)\s*$/!x) {
1393 my ($p, $g) = ($3, $4);
1394 my $rs = $r->{$1}->{$2} = {
1395 t => $2,
1396 remote => $1,
1397 path => Git::SVN::GlobSpec->new($p),
1398 ref => Git::SVN::GlobSpec->new($g) };
1399 if (length($rs->{ref}->{right}) != 0) {
1400 die "The '*' glob character must be the last ",
1401 "character of '$g'\n";
1402 }
1403 }
1404 }
1405 $r;
1406 }
1407
1408 sub init_vars {
1409 if (defined $_repack) {
1410 $_repack = 1000 if ($_repack <= 0);
1411 $_repack_nr = $_repack;
1412 $_repack_flags ||= '-d';
1413 }
1414 }
1415
1416 sub verify_remotes_sanity {
1417 return unless -d $ENV{GIT_DIR};
1418 my %seen;
1419 foreach (command(qw/config -l/)) {
1420 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1421 if ($seen{$1}) {
1422 die "Remote ref refs/remote/$1 is tracked by",
1423 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1424 "Please resolve this ambiguity in ",
1425 "your git configuration file before ",
1426 "continuing\n";
1427 }
1428 $seen{$1} = $_;
1429 }
1430 }
1431 }
1432
1433 # we allow more chars than remotes2config.sh...
1434 sub sanitize_remote_name {
1435 my ($name) = @_;
1436 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1437 $name;
1438 }
1439
1440 sub find_existing_remote {
1441 my ($url, $remotes) = @_;
1442 return undef if $no_reuse_existing;
1443 my $existing;
1444 foreach my $repo_id (keys %$remotes) {
1445 my $u = $remotes->{$repo_id}->{url} or next;
1446 next if $u ne $url;
1447 $existing = $repo_id;
1448 last;
1449 }
1450 $existing;
1451 }
1452
1453 sub init_remote_config {
1454 my ($self, $url, $no_write) = @_;
1455 $url =~ s!/+$!!; # strip trailing slash
1456 my $r = read_all_remotes();
1457 my $existing = find_existing_remote($url, $r);
1458 if ($existing) {
1459 unless ($no_write) {
1460 print STDERR "Using existing ",
1461 "[svn-remote \"$existing\"]\n";
1462 }
1463 $self->{repo_id} = $existing;
1464 } elsif ($_minimize_url) {
1465 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1466 $existing = find_existing_remote($min_url, $r);
1467 if ($existing) {
1468 unless ($no_write) {
1469 print STDERR "Using existing ",
1470 "[svn-remote \"$existing\"]\n";
1471 }
1472 $self->{repo_id} = $existing;
1473 }
1474 if ($min_url ne $url) {
1475 unless ($no_write) {
1476 print STDERR "Using higher level of URL: ",
1477 "$url => $min_url\n";
1478 }
1479 my $old_path = $self->{path};
1480 $self->{path} = $url;
1481 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1482 if (length $old_path) {
1483 $self->{path} .= "/$old_path";
1484 }
1485 $url = $min_url;
1486 }
1487 }
1488 my $orig_url;
1489 if (!$existing) {
1490 # verify that we aren't overwriting anything:
1491 $orig_url = eval {
1492 command_oneline('config', '--get',
1493 "svn-remote.$self->{repo_id}.url")
1494 };
1495 if ($orig_url && ($orig_url ne $url)) {
1496 die "svn-remote.$self->{repo_id}.url already set: ",
1497 "$orig_url\nwanted to set to: $url\n";
1498 }
1499 }
1500 my ($xrepo_id, $xpath) = find_ref($self->refname);
1501 if (defined $xpath) {
1502 die "svn-remote.$xrepo_id.fetch already set to track ",
1503 "$xpath:refs/remotes/", $self->refname, "\n";
1504 }
1505 unless ($no_write) {
1506 command_noisy('config',
1507 "svn-remote.$self->{repo_id}.url", $url);
1508 $self->{path} =~ s{^/}{};
1509 command_noisy('config', '--add',
1510 "svn-remote.$self->{repo_id}.fetch",
1511 "$self->{path}:".$self->refname);
1512 }
1513 $self->{url} = $url;
1514 }
1515
1516 sub find_by_url { # repos_root and, path are optional
1517 my ($class, $full_url, $repos_root, $path) = @_;
1518
1519 return undef unless defined $full_url;
1520 remove_username($full_url);
1521 remove_username($repos_root) if defined $repos_root;
1522 my $remotes = read_all_remotes();
1523 if (defined $full_url && defined $repos_root && !defined $path) {
1524 $path = $full_url;
1525 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1526 }
1527 foreach my $repo_id (keys %$remotes) {
1528 my $u = $remotes->{$repo_id}->{url} or next;
1529 remove_username($u);
1530 next if defined $repos_root && $repos_root ne $u;
1531
1532 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1533 foreach (qw/branches tags/) {
1534 resolve_local_globs($u, $fetch,
1535 $remotes->{$repo_id}->{$_});
1536 }
1537 my $p = $path;
1538 unless (defined $p) {
1539 $p = $full_url;
1540 $p =~ s#^\Q$u\E(?:/|$)## or next;
1541 }
1542 foreach my $f (keys %$fetch) {
1543 next if $f ne $p;
1544 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1545 }
1546 }
1547 undef;
1548 }
1549
1550 sub init {
1551 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1552 my $self = _new($class, $repo_id, $ref_id, $path);
1553 if (defined $url) {
1554 $self->init_remote_config($url, $no_write);
1555 }
1556 $self;
1557 }
1558
1559 sub find_ref {
1560 my ($ref_id) = @_;
1561 foreach (command(qw/config -l/)) {
1562 next unless m!^svn-remote\.(.+)\.fetch=
1563 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1564 my ($repo_id, $path, $ref) = ($1, $2, $3);
1565 if ($ref eq $ref_id) {
1566 $path = '' if ($path =~ m#^\./?#);
1567 return ($repo_id, $path);
1568 }
1569 }
1570 (undef, undef, undef);
1571 }
1572
1573 sub new {
1574 my ($class, $ref_id, $repo_id, $path) = @_;
1575 if (defined $ref_id && !defined $repo_id && !defined $path) {
1576 ($repo_id, $path) = find_ref($ref_id);
1577 if (!defined $repo_id) {
1578 die "Could not find a \"svn-remote.*.fetch\" key ",
1579 "in the repository configuration matching: ",
1580 "refs/remotes/$ref_id\n";
1581 }
1582 }
1583 my $self = _new($class, $repo_id, $ref_id, $path);
1584 if (!defined $self->{path} || !length $self->{path}) {
1585 my $fetch = command_oneline('config', '--get',
1586 "svn-remote.$repo_id.fetch",
1587 ":refs/remotes/$ref_id\$") or
1588 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1589 "\":refs/remotes/$ref_id\$\" in config\n";
1590 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1591 }
1592 $self->{url} = command_oneline('config', '--get',
1593 "svn-remote.$repo_id.url") or
1594 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1595 $self->rebuild;
1596 $self;
1597 }
1598
1599 sub refname {
1600 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1601
1602 # It cannot end with a slash /, we'll throw up on this because
1603 # SVN can't have directories with a slash in their name, either:
1604 if ($refname =~ m{/$}) {
1605 die "ref: '$refname' ends with a trailing slash, this is ",
1606 "not permitted by git nor Subversion\n";
1607 }
1608
1609 # It cannot have ASCII control character space, tilde ~, caret ^,
1610 # colon :, question-mark ?, asterisk *, space, or open bracket [
1611 # anywhere.
1612 #
1613 # Additionally, % must be escaped because it is used for escaping
1614 # and we want our escaped refname to be reversible
1615 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1616
1617 # no slash-separated component can begin with a dot .
1618 # /.* becomes /%2E*
1619 $refname =~ s{/\.}{/%2E}g;
1620
1621 # It cannot have two consecutive dots .. anywhere
1622 # .. becomes %2E%2E
1623 $refname =~ s{\.\.}{%2E%2E}g;
1624
1625 return $refname;
1626 }
1627
1628 sub desanitize_refname {
1629 my ($refname) = @_;
1630 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1631 return $refname;
1632 }
1633
1634 sub svm_uuid {
1635 my ($self) = @_;
1636 return $self->{svm}->{uuid} if $self->svm;
1637 $self->ra;
1638 unless ($self->{svm}) {
1639 die "SVM UUID not cached, and reading remotely failed\n";
1640 }
1641 $self->{svm}->{uuid};
1642 }
1643
1644 sub svm {
1645 my ($self) = @_;
1646 return $self->{svm} if $self->{svm};
1647 my $svm;
1648 # see if we have it in our config, first:
1649 eval {
1650 my $section = "svn-remote.$self->{repo_id}";
1651 $svm = {
1652 source => tmp_config('--get', "$section.svm-source"),
1653 uuid => tmp_config('--get', "$section.svm-uuid"),
1654 replace => tmp_config('--get', "$section.svm-replace"),
1655 }
1656 };
1657 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1658 $self->{svm} = $svm;
1659 }
1660 $self->{svm};
1661 }
1662
1663 sub _set_svm_vars {
1664 my ($self, $ra) = @_;
1665 return $ra if $self->svm;
1666
1667 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1668 "(svm:source, svm:uuid) ",
1669 "from the following URLs:\n" );
1670 sub read_svm_props {
1671 my ($self, $ra, $path, $r) = @_;
1672 my $props = ($ra->get_dir($path, $r))[2];
1673 my $src = $props->{'svm:source'};
1674 my $uuid = $props->{'svm:uuid'};
1675 return undef if (!$src || !$uuid);
1676
1677 chomp($src, $uuid);
1678
1679 $uuid =~ m{^[0-9a-f\-]{30,}$}
1680 or die "doesn't look right - svm:uuid is '$uuid'\n";
1681
1682 # the '!' is used to mark the repos_root!/relative/path
1683 $src =~ s{/?!/?}{/};
1684 $src =~ s{/+$}{}; # no trailing slashes please
1685 # username is of no interest
1686 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1687
1688 my $replace = $ra->{url};
1689 $replace .= "/$path" if length $path;
1690
1691 my $section = "svn-remote.$self->{repo_id}";
1692 tmp_config("$section.svm-source", $src);
1693 tmp_config("$section.svm-replace", $replace);
1694 tmp_config("$section.svm-uuid", $uuid);
1695 $self->{svm} = {
1696 source => $src,
1697 uuid => $uuid,
1698 replace => $replace
1699 };
1700 }
1701
1702 my $r = $ra->get_latest_revnum;
1703 my $path = $self->{path};
1704 my %tried;
1705 while (length $path) {
1706 unless ($tried{"$self->{url}/$path"}) {
1707 return $ra if $self->read_svm_props($ra, $path, $r);
1708 $tried{"$self->{url}/$path"} = 1;
1709 }
1710 $path =~ s#/?[^/]+$##;
1711 }
1712 die "Path: '$path' should be ''\n" if $path ne '';
1713 return $ra if $self->read_svm_props($ra, $path, $r);
1714 $tried{"$self->{url}/$path"} = 1;
1715
1716 if ($ra->{repos_root} eq $self->{url}) {
1717 die @err, (map { " $_\n" } keys %tried), "\n";
1718 }
1719
1720 # nope, make sure we're connected to the repository root:
1721 my $ok;
1722 my @tried_b;
1723 $path = $ra->{svn_path};
1724 $ra = Git::SVN::Ra->new($ra->{repos_root});
1725 while (length $path) {
1726 unless ($tried{"$ra->{url}/$path"}) {
1727 $ok = $self->read_svm_props($ra, $path, $r);
1728 last if $ok;
1729 $tried{"$ra->{url}/$path"} = 1;
1730 }
1731 $path =~ s#/?[^/]+$##;
1732 }
1733 die "Path: '$path' should be ''\n" if $path ne '';
1734 $ok ||= $self->read_svm_props($ra, $path, $r);
1735 $tried{"$ra->{url}/$path"} = 1;
1736 if (!$ok) {
1737 die @err, (map { " $_\n" } keys %tried), "\n";
1738 }
1739 Git::SVN::Ra->new($self->{url});
1740 }
1741
1742 sub svnsync {
1743 my ($self) = @_;
1744 return $self->{svnsync} if $self->{svnsync};
1745
1746 if ($self->no_metadata) {
1747 die "Can't have both 'noMetadata' and ",
1748 "'useSvnsyncProps' options set!\n";
1749 }
1750 if ($self->rewrite_root) {
1751 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1752 "options set!\n";
1753 }
1754
1755 my $svnsync;
1756 # see if we have it in our config, first:
1757 eval {
1758 my $section = "svn-remote.$self->{repo_id}";
1759 $svnsync = {
1760 url => tmp_config('--get', "$section.svnsync-url"),
1761 uuid => tmp_config('--get', "$section.svnsync-uuid"),
1762 }
1763 };
1764 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1765 return $self->{svnsync} = $svnsync;
1766 }
1767
1768 my $err = "useSvnsyncProps set, but failed to read " .
1769 "svnsync property: svn:sync-from-";
1770 my $rp = $self->ra->rev_proplist(0);
1771
1772 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1773 $url =~ m{^[a-z\+]+://} or
1774 die "doesn't look right - svn:sync-from-url is '$url'\n";
1775
1776 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1777 $uuid =~ m{^[0-9a-f\-]{30,}$} or
1778 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1779
1780 my $section = "svn-remote.$self->{repo_id}";
1781 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1782 tmp_config('--add', "$section.svnsync-url", $url);
1783 return $self->{svnsync} = { url => $url, uuid => $uuid };
1784 }
1785
1786 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1787 # remote lookup (useful for 'git svn log').
1788 sub ra_uuid {
1789 my ($self) = @_;
1790 unless ($self->{ra_uuid}) {
1791 my $key = "svn-remote.$self->{repo_id}.uuid";
1792 my $uuid = eval { tmp_config('--get', $key) };
1793 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1794 $self->{ra_uuid} = $uuid;
1795 } else {
1796 die "ra_uuid called without URL\n" unless $self->{url};
1797 $self->{ra_uuid} = $self->ra->get_uuid;
1798 tmp_config('--add', $key, $self->{ra_uuid});
1799 }
1800 }
1801 $self->{ra_uuid};
1802 }
1803
1804 sub _set_repos_root {
1805 my ($self, $repos_root) = @_;
1806 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1807 $repos_root ||= $self->ra->{repos_root};
1808 tmp_config($k, $repos_root);
1809 $repos_root;
1810 }
1811
1812 sub repos_root {
1813 my ($self) = @_;
1814 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1815 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1816 }
1817
1818 sub ra {
1819 my ($self) = shift;
1820 my $ra = Git::SVN::Ra->new($self->{url});
1821 $self->_set_repos_root($ra->{repos_root});
1822 if ($self->use_svm_props && !$self->{svm}) {
1823 if ($self->no_metadata) {
1824 die "Can't have both 'noMetadata' and ",
1825 "'useSvmProps' options set!\n";
1826 } elsif ($self->use_svnsync_props) {
1827 die "Can't have both 'useSvnsyncProps' and ",
1828 "'useSvmProps' options set!\n";
1829 }
1830 $ra = $self->_set_svm_vars($ra);
1831 $self->{-want_revprops} = 1;
1832 }
1833 $ra;
1834 }
1835
1836 sub rel_path {
1837 my ($self) = @_;
1838 my $repos_root = $self->ra->{repos_root};
1839 return $self->{path} if ($self->{url} eq $repos_root);
1840 my $url = $self->{url} .
1841 (length $self->{path} ? "/$self->{path}" : $self->{path});
1842 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1843 $url;
1844 }
1845
1846 # prop_walk(PATH, REV, SUB)
1847 # -------------------------
1848 # Recursively traverse PATH at revision REV and invoke SUB for each
1849 # directory that contains a SVN property. SUB will be invoked as
1850 # follows: &SUB(gs, path, props); where `gs' is this instance of
1851 # Git::SVN, `path' the path to the directory where the properties
1852 # `props' were found. The `path' will be relative to point of checkout,
1853 # that is, if url://repo/trunk is the current Git branch, and that
1854 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1855 # as `path' (note the trailing `/').
1856 sub prop_walk {
1857 my ($self, $path, $rev, $sub) = @_;
1858
1859 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1860 $path =~ s#^/*#/#g;
1861 my $p = $path;
1862 # Strip the irrelevant part of the path.
1863 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1864 # Ensure the path is terminated by a `/'.
1865 $p =~ s#/*$#/#;
1866
1867 # The properties contain all the internal SVN stuff nobody
1868 # (usually) cares about.
1869 my $interesting_props = 0;
1870 foreach (keys %{$props}) {
1871 # If it doesn't start with `svn:', it must be a
1872 # user-defined property.
1873 ++$interesting_props and next if $_ !~ /^svn:/;
1874 # FIXME: Fragile, if SVN adds new public properties,
1875 # this needs to be updated.
1876 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1877 |eol-style|mime-type
1878 |externals|needs-lock)$/x;
1879 }
1880 &$sub($self, $p, $props) if $interesting_props;
1881
1882 foreach (sort keys %$dirent) {
1883 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1884 $self->prop_walk($path . '/' . $_, $rev, $sub);
1885 }
1886 }
1887
1888 sub last_rev { ($_[0]->last_rev_commit)[0] }
1889 sub last_commit { ($_[0]->last_rev_commit)[1] }
1890
1891 # returns the newest SVN revision number and newest commit SHA1
1892 sub last_rev_commit {
1893 my ($self) = @_;
1894 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1895 return ($self->{last_rev}, $self->{last_commit});
1896 }
1897 my $c = ::verify_ref($self->refname.'^0');
1898 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1899 my $rev = (::cmt_metadata($c))[1];
1900 if (defined $rev) {
1901 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1902 return ($rev, $c);
1903 }
1904 }
1905 my $map_path = $self->map_path;
1906 unless (-e $map_path) {
1907 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1908 return (undef, undef);
1909 }
1910 my ($rev, $commit) = $self->rev_map_max(1);
1911 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1912 return ($rev, $commit);
1913 }
1914
1915 sub get_fetch_range {
1916 my ($self, $min, $max) = @_;
1917 $max ||= $self->ra->get_latest_revnum;
1918 $min ||= $self->rev_map_max;
1919 (++$min, $max);
1920 }
1921
1922 sub tmp_config {
1923 my (@args) = @_;
1924 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1925 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1926 if (! -f $config && -f $old_def_config) {
1927 rename $old_def_config, $config or
1928 die "Failed rename $old_def_config => $config: $!\n";
1929 }
1930 my $old_config = $ENV{GIT_CONFIG};
1931 $ENV{GIT_CONFIG} = $config;
1932 $@ = undef;
1933 my @ret = eval {
1934 unless (-f $config) {
1935 mkfile($config);
1936 open my $fh, '>', $config or
1937 die "Can't open $config: $!\n";
1938 print $fh "; This file is used internally by ",
1939 "git-svn\n" or die
1940 "Couldn't write to $config: $!\n";
1941 print $fh "; You should not have to edit it\n" or
1942 die "Couldn't write to $config: $!\n";
1943 close $fh or die "Couldn't close $config: $!\n";
1944 }
1945 command('config', @args);
1946 };
1947 my $err = $@;
1948 if (defined $old_config) {
1949 $ENV{GIT_CONFIG} = $old_config;
1950 } else {
1951 delete $ENV{GIT_CONFIG};
1952 }
1953 die $err if $err;
1954 wantarray ? @ret : $ret[0];
1955 }
1956
1957 sub tmp_index_do {
1958 my ($self, $sub) = @_;
1959 my $old_index = $ENV{GIT_INDEX_FILE};
1960 $ENV{GIT_INDEX_FILE} = $self->{index};
1961 $@ = undef;
1962 my @ret = eval {
1963 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1964 mkpath([$dir]) unless -d $dir;
1965 &$sub;
1966 };
1967 my $err = $@;
1968 if (defined $old_index) {
1969 $ENV{GIT_INDEX_FILE} = $old_index;
1970 } else {
1971 delete $ENV{GIT_INDEX_FILE};
1972 }
1973 die $err if $err;
1974 wantarray ? @ret : $ret[0];
1975 }
1976
1977 sub assert_index_clean {
1978 my ($self, $treeish) = @_;
1979
1980 $self->tmp_index_do(sub {
1981 command_noisy('read-tree', $treeish) unless -e $self->{index};
1982 my $x = command_oneline('write-tree');
1983 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1984 /^tree ($::sha1)/mo);
1985 return if $y eq $x;
1986
1987 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1988 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1989 command_noisy('read-tree', $treeish);
1990 $x = command_oneline('write-tree');
1991 if ($y ne $x) {
1992 ::fatal "trees ($treeish) $y != $x\n",
1993 "Something is seriously wrong...";
1994 }
1995 });
1996 }
1997
1998 sub get_commit_parents {
1999 my ($self, $log_entry) = @_;
2000 my (%seen, @ret, @tmp);
2001 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2002 if (my $ip = $self->{inject_parents}) {
2003 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2004 push @tmp, $commit;
2005 }
2006 }
2007 if (my $cur = ::verify_ref($self->refname.'^0')) {
2008 push @tmp, $cur;
2009 }
2010 if (my $ipd = $self->{inject_parents_dcommit}) {
2011 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2012 push @tmp, @$commit;
2013 }
2014 }
2015 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2016 while (my $p = shift @tmp) {
2017 next if $seen{$p};
2018 $seen{$p} = 1;
2019 push @ret, $p;
2020 # MAXPARENT is defined to 16 in commit-tree.c:
2021 last if @ret >= 16;
2022 }
2023 if (@tmp) {
2024 die "r$log_entry->{revision}: No room for parents:\n\t",
2025 join("\n\t", @tmp), "\n";
2026 }
2027 @ret;
2028 }
2029
2030 sub rewrite_root {
2031 my ($self) = @_;
2032 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2033 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2034 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2035 if ($rwr) {
2036 $rwr =~ s#/+$##;
2037 if ($rwr !~ m#^[a-z\+]+://#) {
2038 die "$rwr is not a valid URL (key: $k)\n";
2039 }
2040 }
2041 $self->{-rewrite_root} = $rwr;
2042 }
2043
2044 sub metadata_url {
2045 my ($self) = @_;
2046 ($self->rewrite_root || $self->{url}) .
2047 (length $self->{path} ? '/' . $self->{path} : '');
2048 }
2049
2050 sub full_url {
2051 my ($self) = @_;
2052 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2053 }
2054
2055 sub do_git_commit {
2056 my ($self, $log_entry) = @_;
2057 my $lr = $self->last_rev;
2058 if (defined $lr && $lr >= $log_entry->{revision}) {
2059 die "Last fetched revision of ", $self->refname,
2060 " was r$lr, but we are about to fetch: ",
2061 "r$log_entry->{revision}!\n";
2062 }
2063 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2064 croak "$log_entry->{revision} = $c already exists! ",
2065 "Why are we refetching it?\n";
2066 }
2067 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2068 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2069 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2070
2071 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2072 ? $log_entry->{commit_name}
2073 : $log_entry->{name};
2074 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2075 ? $log_entry->{commit_email}
2076 : $log_entry->{email};
2077
2078 my $tree = $log_entry->{tree};
2079 if (!defined $tree) {
2080 $tree = $self->tmp_index_do(sub {
2081 command_oneline('write-tree') });
2082 }
2083 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2084
2085 my @exec = ('git-commit-tree', $tree);
2086 foreach ($self->get_commit_parents($log_entry)) {
2087 push @exec, '-p', $_;
2088 }
2089 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2090 or croak $!;
2091 print $msg_fh $log_entry->{log} or croak $!;
2092 unless ($self->no_metadata) {
2093 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2094 or croak $!;
2095 }
2096 $msg_fh->flush == 0 or croak $!;
2097 close $msg_fh or croak $!;
2098 chomp(my $commit = do { local $/; <$out_fh> });
2099 close $out_fh or croak $!;
2100 waitpid $pid, 0;
2101 croak $? if $?;
2102 if ($commit !~ /^$::sha1$/o) {
2103 die "Failed to commit, invalid sha1: $commit\n";
2104 }
2105
2106 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2107
2108 $self->{last_rev} = $log_entry->{revision};
2109 $self->{last_commit} = $commit;
2110 print "r$log_entry->{revision}";
2111 if (defined $log_entry->{svm_revision}) {
2112 print " (\@$log_entry->{svm_revision})";
2113 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2114 0, $self->svm_uuid);
2115 }
2116 print " = $commit ($self->{ref_id})\n";
2117 if (defined $_repack && (--$_repack_nr == 0)) {
2118 $_repack_nr = $_repack;
2119 # repack doesn't use any arguments with spaces in them, does it?
2120 print "Running git repack $_repack_flags ...\n";
2121 command_noisy('repack', split(/\s+/, $_repack_flags));
2122 print "Done repacking\n";
2123 }
2124 return $commit;
2125 }
2126
2127 sub match_paths {
2128 my ($self, $paths, $r) = @_;
2129 return 1 if $self->{path} eq '';
2130 if (my $path = $paths->{"/$self->{path}"}) {
2131 return ($path->{action} eq 'D') ? 0 : 1;
2132 }
2133 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2134 if (grep /$self->{path_regex}/, keys %$paths) {
2135 return 1;
2136 }
2137 my $c = '';
2138 foreach (split m#/#, $self->{path}) {
2139 $c .= "/$_";
2140 next unless ($paths->{$c} &&
2141 ($paths->{$c}->{action} =~ /^[AR]$/));
2142 if ($self->ra->check_path($self->{path}, $r) ==
2143 $SVN::Node::dir) {
2144 return 1;
2145 }
2146 }
2147 return 0;
2148 }
2149
2150 sub find_parent_branch {
2151 my ($self, $paths, $rev) = @_;
2152 return undef unless $self->follow_parent;
2153 unless (defined $paths) {
2154 my $err_handler = $SVN::Error::handler;
2155 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2156 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2157 $paths =
2158 Git::SVN::Ra::dup_changed_paths($_[0]) });
2159 $SVN::Error::handler = $err_handler;
2160 }
2161 return undef unless defined $paths;
2162
2163 # look for a parent from another branch:
2164 my @b_path_components = split m#/#, $self->rel_path;
2165 my @a_path_components;
2166 my $i;
2167 while (@b_path_components) {
2168 $i = $paths->{'/'.join('/', @b_path_components)};
2169 last if $i && defined $i->{copyfrom_path};
2170 unshift(@a_path_components, pop(@b_path_components));
2171 }
2172 return undef unless defined $i && defined $i->{copyfrom_path};
2173 my $branch_from = $i->{copyfrom_path};
2174 if (@a_path_components) {
2175 print STDERR "branch_from: $branch_from => ";
2176 $branch_from .= '/'.join('/', @a_path_components);
2177 print STDERR $branch_from, "\n";
2178 }
2179 my $r = $i->{copyfrom_rev};
2180 my $repos_root = $self->ra->{repos_root};
2181 my $url = $self->ra->{url};
2182 my $new_url = $repos_root . $branch_from;
2183 print STDERR "Found possible branch point: ",
2184 "$new_url => ", $self->full_url, ", $r\n";
2185 $branch_from =~ s#^/##;
2186 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2187 unless ($gs) {
2188 my $ref_id = $self->{ref_id};
2189 $ref_id =~ s/\@\d+$//;
2190 $ref_id .= "\@$r";
2191 # just grow a tail if we're not unique enough :x
2192 $ref_id .= '-' while find_ref($ref_id);
2193 print STDERR "Initializing parent: $ref_id\n";
2194 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2195 }
2196 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2197 if (!defined $r0 || !defined $parent) {
2198 my ($base, $head) = parse_revision_argument(0, $r);
2199 if ($base <= $r) {
2200 $gs->fetch($base, $r);
2201 }
2202 ($r0, $parent) = $gs->last_rev_commit;
2203 }
2204 if (defined $r0 && defined $parent) {
2205 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2206 my $ed;
2207 if ($self->ra->can_do_switch) {
2208 $self->assert_index_clean($parent);
2209 print STDERR "Following parent with do_switch\n";
2210 # do_switch works with svn/trunk >= r22312, but that
2211 # is not included with SVN 1.4.3 (the latest version
2212 # at the moment), so we can't rely on it
2213 $self->{last_commit} = $parent;
2214 $ed = SVN::Git::Fetcher->new($self);
2215 $gs->ra->gs_do_switch($r0, $rev, $gs,
2216 $self->full_url, $ed)
2217 or die "SVN connection failed somewhere...\n";
2218 } elsif ($self->ra->trees_match($new_url, $r0,
2219 $self->full_url, $rev)) {
2220 print STDERR "Trees match:\n",
2221 " $new_url\@$r0\n",
2222 " ${\$self->full_url}\@$rev\n",
2223 "Following parent with no changes\n";
2224 $self->tmp_index_do(sub {
2225 command_noisy('read-tree', $parent);
2226 });
2227 $self->{last_commit} = $parent;
2228 } else {
2229 print STDERR "Following parent with do_update\n";
2230 $ed = SVN::Git::Fetcher->new($self);
2231 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2232 or die "SVN connection failed somewhere...\n";
2233 }
2234 print STDERR "Successfully followed parent\n";
2235 return $self->make_log_entry($rev, [$parent], $ed);
2236 }
2237 return undef;
2238 }
2239
2240 sub do_fetch {
2241 my ($self, $paths, $rev) = @_;
2242 my $ed;
2243 my ($last_rev, @parents);
2244 if (my $lc = $self->last_commit) {
2245 # we can have a branch that was deleted, then re-added
2246 # under the same name but copied from another path, in
2247 # which case we'll have multiple parents (we don't
2248 # want to break the original ref, nor lose copypath info):
2249 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2250 push @{$log_entry->{parents}}, $lc;
2251 return $log_entry;
2252 }
2253 $ed = SVN::Git::Fetcher->new($self);
2254 $last_rev = $self->{last_rev};
2255 $ed->{c} = $lc;
2256 @parents = ($lc);
2257 } else {
2258 $last_rev = $rev;
2259 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2260 return $log_entry;
2261 }
2262 $ed = SVN::Git::Fetcher->new($self);
2263 }
2264 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2265 die "SVN connection failed somewhere...\n";
2266 }
2267 $self->make_log_entry($rev, \@parents, $ed);
2268 }
2269
2270 sub get_untracked {
2271 my ($self, $ed) = @_;
2272 my @out;
2273 my $h = $ed->{empty};
2274 foreach (sort keys %$h) {
2275 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2276 push @out, " $act: " . uri_encode($_);
2277 warn "W: $act: $_\n";
2278 }
2279 foreach my $t (qw/dir_prop file_prop/) {
2280 $h = $ed->{$t} or next;
2281 foreach my $path (sort keys %$h) {
2282 my $ppath = $path eq '' ? '.' : $path;
2283 foreach my $prop (sort keys %{$h->{$path}}) {
2284 next if $SKIP_PROP{$prop};
2285 my $v = $h->{$path}->{$prop};
2286 my $t_ppath_prop = "$t: " .
2287 uri_encode($ppath) . ' ' .
2288 uri_encode($prop);
2289 if (defined $v) {
2290 push @out, " +$t_ppath_prop " .
2291 uri_encode($v);
2292 } else {
2293 push @out, " -$t_ppath_prop";
2294 }
2295 }
2296 }
2297 }
2298 foreach my $t (qw/absent_file absent_directory/) {
2299 $h = $ed->{$t} or next;
2300 foreach my $parent (sort keys %$h) {
2301 foreach my $path (sort @{$h->{$parent}}) {
2302 push @out, " $t: " .
2303 uri_encode("$parent/$path");
2304 warn "W: $t: $parent/$path ",
2305 "Insufficient permissions?\n";
2306 }
2307 }
2308 }
2309 \@out;
2310 }
2311
2312 sub parse_svn_date {
2313 my $date = shift || return '+0000 1970-01-01 00:00:00';
2314 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2315 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2316 croak "Unable to parse date: $date\n";
2317 "+0000 $Y-$m-$d $H:$M:$S";
2318 }
2319
2320 sub check_author {
2321 my ($author) = @_;
2322 if (!defined $author || length $author == 0) {
2323 $author = '(no author)';
2324 }
2325 if (defined $::_authors && ! defined $::users{$author}) {
2326 die "Author: $author not defined in $::_authors file\n";
2327 }
2328 $author;
2329 }
2330
2331 sub make_log_entry {
2332 my ($self, $rev, $parents, $ed) = @_;
2333 my $untracked = $self->get_untracked($ed);
2334
2335 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2336 print $un "r$rev\n" or croak $!;
2337 print $un $_, "\n" foreach @$untracked;
2338 my %log_entry = ( parents => $parents || [], revision => $rev,
2339 log => '');
2340
2341 my $headrev;
2342 my $logged = delete $self->{logged_rev_props};
2343 if (!$logged || $self->{-want_revprops}) {
2344 my $rp = $self->ra->rev_proplist($rev);
2345 foreach (sort keys %$rp) {
2346 my $v = $rp->{$_};
2347 if (/^svn:(author|date|log)$/) {
2348 $log_entry{$1} = $v;
2349 } elsif ($_ eq 'svm:headrev') {
2350 $headrev = $v;
2351 } else {
2352 print $un " rev_prop: ", uri_encode($_), ' ',
2353 uri_encode($v), "\n";
2354 }
2355 }
2356 } else {
2357 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2358 }
2359 close $un or croak $!;
2360
2361 $log_entry{date} = parse_svn_date($log_entry{date});
2362 $log_entry{log} .= "\n";
2363 my $author = $log_entry{author} = check_author($log_entry{author});
2364 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2365 : ($author, undef);
2366
2367 my ($commit_name, $commit_email) = ($name, $email);
2368 if ($_use_log_author) {
2369 my $name_field;
2370 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2371 $name_field = $1;
2372 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2373 $name_field = $1;
2374 }
2375 if (!defined $name_field) {
2376 #
2377 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2378 ($name, $email) = ($1, $2);
2379 } elsif ($name_field =~ /(.*)@/) {
2380 ($name, $email) = ($1, $name_field);
2381 } else {
2382 ($name, $email) = ($name_field, 'unknown');
2383 }
2384 }
2385 if (defined $headrev && $self->use_svm_props) {
2386 if ($self->rewrite_root) {
2387 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2388 "options set!\n";
2389 }
2390 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2391 # we don't want "SVM: initializing mirror for junk" ...
2392 return undef if $r == 0;
2393 my $svm = $self->svm;
2394 if ($uuid ne $svm->{uuid}) {
2395 die "UUID mismatch on SVM path:\n",
2396 "expected: $svm->{uuid}\n",
2397 " got: $uuid\n";
2398 }
2399 my $full_url = $self->full_url;
2400 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2401 die "Failed to replace '$svm->{replace}' with ",
2402 "'$svm->{source}' in $full_url\n";
2403 # throw away username for storing in records
2404 remove_username($full_url);
2405 $log_entry{metadata} = "$full_url\@$r $uuid";
2406 $log_entry{svm_revision} = $r;
2407 $email ||= "$author\@$uuid";
2408 $commit_email ||= "$author\@$uuid";
2409 } elsif ($self->use_svnsync_props) {
2410 my $full_url = $self->svnsync->{url};
2411 $full_url .= "/$self->{path}" if length $self->{path};
2412 remove_username($full_url);
2413 my $uuid = $self->svnsync->{uuid};
2414 $log_entry{metadata} = "$full_url\@$rev $uuid";
2415 $email ||= "$author\@$uuid";
2416 $commit_email ||= "$author\@$uuid";
2417 } else {
2418 my $url = $self->metadata_url;
2419 remove_username($url);
2420 $log_entry{metadata} = "$url\@$rev " .
2421 $self->ra->get_uuid;
2422 $email ||= "$author\@" . $self->ra->get_uuid;
2423 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2424 }
2425 $log_entry{name} = $name;
2426 $log_entry{email} = $email;
2427 $log_entry{commit_name} = $commit_name;
2428 $log_entry{commit_email} = $commit_email;
2429 \%log_entry;
2430 }
2431
2432 sub fetch {
2433 my ($self, $min_rev, $max_rev, @parents) = @_;
2434 my ($last_rev, $last_commit) = $self->last_rev_commit;
2435 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2436 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2437 }
2438
2439 sub set_tree_cb {
2440 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2441 $self->{inject_parents} = { $rev => $tree };
2442 $self->fetch(undef, undef);
2443 }
2444
2445 sub set_tree {
2446 my ($self, $tree) = (shift, shift);
2447 my $log_entry = ::get_commit_entry($tree);
2448 unless ($self->{last_rev}) {
2449 fatal("Must have an existing revision to commit");
2450 }
2451 my %ed_opts = ( r => $self->{last_rev},
2452 log => $log_entry->{log},
2453 ra => $self->ra,
2454 tree_a => $self->{last_commit},
2455 tree_b => $tree,
2456 editor_cb => sub {
2457 $self->set_tree_cb($log_entry, $tree, @_) },
2458 svn_path => $self->{path} );
2459 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2460 print "No changes\nr$self->{last_rev} = $tree\n";
2461 }
2462 }
2463
2464 sub rebuild_from_rev_db {
2465 my ($self, $path) = @_;
2466 my $r = -1;
2467 open my $fh, '<', $path or croak "open: $!";
2468 while (<$fh>) {
2469 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2470 chomp($_);
2471 ++$r;
2472 next if $_ eq ('0' x 40);
2473 $self->rev_map_set($r, $_);
2474 print "r$r = $_\n";
2475 }
2476 close $fh or croak "close: $!";
2477 unlink $path or croak "unlink: $!";
2478 }
2479
2480 sub rebuild {
2481 my ($self) = @_;
2482 my $map_path = $self->map_path;
2483 return if (-e $map_path && ! -z $map_path);
2484 return unless ::verify_ref($self->refname.'^0');
2485 if ($self->use_svm_props || $self->no_metadata) {
2486 my $rev_db = $self->rev_db_path;
2487 $self->rebuild_from_rev_db($rev_db);
2488 if ($self->use_svm_props) {
2489 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2490 $self->rebuild_from_rev_db($svm_rev_db);
2491 }
2492 $self->unlink_rev_db_symlink;
2493 return;
2494 }
2495 print "Rebuilding $map_path ...\n";
2496 my ($log, $ctx) =
2497 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2498 $self->refname, '--');
2499 my $full_url = $self->full_url;
2500 remove_username($full_url);
2501 my $svn_uuid = $self->ra_uuid;
2502 my $c;
2503 while (<$log>) {
2504 if ( m{^commit ($::sha1)$} ) {
2505 $c = $1;
2506 next;
2507 }
2508 next unless s{^\s*(git-svn-id:)}{$1};
2509 my ($url, $rev, $uuid) = ::extract_metadata($_);
2510 remove_username($url);
2511
2512 # ignore merges (from set-tree)
2513 next if (!defined $rev || !$uuid);
2514
2515 # if we merged or otherwise started elsewhere, this is
2516 # how we break out of it
2517 if (($uuid ne $svn_uuid) ||
2518 ($full_url && $url && ($url ne $full_url))) {
2519 next;
2520 }
2521
2522 $self->rev_map_set($rev, $c);
2523 print "r$rev = $c\n";
2524 }
2525 command_close_pipe($log, $ctx);
2526 print "Done rebuilding $map_path\n";
2527 my $rev_db_path = $self->rev_db_path;
2528 if (-f $self->rev_db_path) {
2529 unlink $self->rev_db_path or croak "unlink: $!";
2530 }
2531 $self->unlink_rev_db_symlink;
2532 }
2533
2534 # rev_map:
2535 # Tie::File seems to be prone to offset errors if revisions get sparse,
2536 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2537 # one of my favorite modules is out :< Next up would be one of the DBM
2538 # modules, but I'm not sure which is most portable...
2539 #
2540 # This is the replacement for the rev_db format, which was too big
2541 # and inefficient for large repositories with a lot of sparse history
2542 # (mainly tags)
2543 #
2544 # The format is this:
2545 # - 24 bytes for every record,
2546 # * 4 bytes for the integer representing an SVN revision number
2547 # * 20 bytes representing the sha1 of a git commit
2548 # - No empty padding records like the old format
2549 # (except the last record, which can be overwritten)
2550 # - new records are written append-only since SVN revision numbers
2551 # increase monotonically
2552 # - lookups on SVN revision number are done via a binary search
2553 # - Piping the file to xxd -c24 is a good way of dumping it for
2554 # viewing or editing (piped back through xxd -r), should the need
2555 # ever arise.
2556 # - The last record can be padding revision with an all-zero sha1
2557 # This is used to optimize fetch performance when using multiple
2558 # "fetch" directives in .git/config
2559 #
2560 # These files are disposable unless noMetadata or useSvmProps is set
2561
2562 sub _rev_map_set {
2563 my ($fh, $rev, $commit) = @_;
2564
2565 my $size = (stat($fh))[7];
2566 ($size % 24) == 0 or croak "inconsistent size: $size";
2567
2568 my $wr_offset = 0;
2569 if ($size > 0) {
2570 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2571 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2572 $read == 24 or croak "read only $read bytes (!= 24)";
2573 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2574 if ($last_commit eq ('0' x40)) {
2575 if ($size >= 48) {
2576 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2577 $read = sysread($fh, $buf, 24) or
2578 croak "read: $!";
2579 $read == 24 or
2580 croak "read only $read bytes (!= 24)";
2581 ($last_rev, $last_commit) =
2582 unpack(rev_map_fmt, $buf);
2583 if ($last_commit eq ('0' x40)) {
2584 croak "inconsistent .rev_map\n";
2585 }
2586 }
2587 if ($last_rev >= $rev) {
2588 croak "last_rev is higher!: $last_rev >= $rev";
2589 }
2590 $wr_offset = -24;
2591 }
2592 }
2593 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2594 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2595 croak "write: $!";
2596 }
2597
2598 sub mkfile {
2599 my ($path) = @_;
2600 unless (-e $path) {
2601 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2602 mkpath([$dir]) unless -d $dir;
2603 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2604 close $fh or die "Couldn't close (create) $path: $!\n";
2605 }
2606 }
2607
2608 sub rev_map_set {
2609 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2610 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2611 my $db = $self->map_path($uuid);
2612 my $db_lock = "$db.lock";
2613 my $sig;
2614 if ($update_ref) {
2615 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2616 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2617 }
2618 mkfile($db);
2619
2620 $LOCKFILES{$db_lock} = 1;
2621 my $sync;
2622 # both of these options make our .rev_db file very, very important
2623 # and we can't afford to lose it because rebuild() won't work
2624 if ($self->use_svm_props || $self->no_metadata) {
2625 $sync = 1;
2626 copy($db, $db_lock) or die "rev_map_set(@_): ",
2627 "Failed to copy: ",
2628 "$db => $db_lock ($!)\n";
2629 } else {
2630 rename $db, $db_lock or die "rev_map_set(@_): ",
2631 "Failed to rename: ",
2632 "$db => $db_lock ($!)\n";
2633 }
2634
2635 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2636 or croak "Couldn't open $db_lock: $!\n";
2637 _rev_map_set($fh, $rev, $commit);
2638 if ($sync) {
2639 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2640 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2641 }
2642 close $fh or croak $!;
2643 if ($update_ref) {
2644 $_head = $self;
2645 command_noisy('update-ref', '-m', "r$rev",
2646 $self->refname, $commit);
2647 }
2648 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2649 "$db_lock => $db ($!)\n";
2650 delete $LOCKFILES{$db_lock};
2651 if ($update_ref) {
2652 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2653 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2654 kill $sig, $$ if defined $sig;
2655 }
2656 }
2657
2658 # If want_commit, this will return an array of (rev, commit) where
2659 # commit _must_ be a valid commit in the archive.
2660 # Otherwise, it'll return the max revision (whether or not the
2661 # commit is valid or just a 0x40 placeholder).
2662 sub rev_map_max {
2663 my ($self, $want_commit) = @_;
2664 $self->rebuild;
2665 my $map_path = $self->map_path;
2666 stat $map_path or return $want_commit ? (0, undef) : 0;
2667 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2668 my $size = (stat($fh))[7];
2669 ($size % 24) == 0 or croak "inconsistent size: $size";
2670
2671 if ($size == 0) {
2672 close $fh or croak "close: $!";
2673 return $want_commit ? (0, undef) : 0;
2674 }
2675
2676 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2677 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2678 my ($r, $c) = unpack(rev_map_fmt, $buf);
2679 if ($want_commit && $c eq ('0' x40)) {
2680 if ($size < 48) {
2681 return $want_commit ? (0, undef) : 0;
2682 }
2683 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2684 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2685 ($r, $c) = unpack(rev_map_fmt, $buf);
2686 if ($c eq ('0'x40)) {
2687 croak "Penultimate record is all-zeroes in $map_path";
2688 }
2689 }
2690 close $fh or croak "close: $!";
2691 $want_commit ? ($r, $c) : $r;
2692 }
2693
2694 sub rev_map_get {
2695 my ($self, $rev, $uuid) = @_;
2696 my $map_path = $self->map_path($uuid);
2697 return undef unless -e $map_path;
2698
2699 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2700 my $size = (stat($fh))[7];
2701 ($size % 24) == 0 or croak "inconsistent size: $size";
2702
2703 if ($size == 0) {
2704 close $fh or croak "close: $fh";
2705 return undef;
2706 }
2707
2708 my ($l, $u) = (0, $size - 24);
2709 my ($r, $c, $buf);
2710
2711 while ($l <= $u) {
2712 my $i = int(($l/24 + $u/24) / 2) * 24;
2713 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2714 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2715 my ($r, $c) = unpack('NH40', $buf);
2716
2717 if ($r < $rev) {
2718 $l = $i + 24;
2719 } elsif ($r > $rev) {
2720 $u = $i - 24;
2721 } else { # $r == $rev
2722 close($fh) or croak "close: $!";
2723 return $c eq ('0' x 40) ? undef : $c;
2724 }
2725 }
2726 close($fh) or croak "close: $!";
2727 undef;
2728 }
2729
2730 # Finds the first svn revision that exists on (if $eq_ok is true) or
2731 # before $rev for the current branch. It will not search any lower
2732 # than $min_rev. Returns the git commit hash and svn revision number
2733 # if found, else (undef, undef).
2734 sub find_rev_before {
2735 my ($self, $rev, $eq_ok, $min_rev) = @_;
2736 --$rev unless $eq_ok;
2737 $min_rev ||= 1;
2738 while ($rev >= $min_rev) {
2739 if (my $c = $self->rev_map_get($rev)) {
2740 return ($rev, $c);
2741 }
2742 --$rev;
2743 }
2744 return (undef, undef);
2745 }
2746
2747 # Finds the first svn revision that exists on (if $eq_ok is true) or
2748 # after $rev for the current branch. It will not search any higher
2749 # than $max_rev. Returns the git commit hash and svn revision number
2750 # if found, else (undef, undef).
2751 sub find_rev_after {
2752 my ($self, $rev, $eq_ok, $max_rev) = @_;
2753 ++$rev unless $eq_ok;
2754 $max_rev ||= $self->rev_map_max;
2755 while ($rev <= $max_rev) {
2756 if (my $c = $self->rev_map_get($rev)) {
2757 return ($rev, $c);
2758 }
2759 ++$rev;
2760 }
2761 return (undef, undef);
2762 }
2763
2764 sub _new {
2765 my ($class, $repo_id, $ref_id, $path) = @_;
2766 unless (defined $repo_id && length $repo_id) {
2767 $repo_id = $Git::SVN::default_repo_id;
2768 }
2769 unless (defined $ref_id && length $ref_id) {
2770 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2771 }
2772 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2773 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2774 $_[3] = $path = '' unless (defined $path);
2775 mkpath(["$ENV{GIT_DIR}/svn"]);
2776 bless {
2777 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2778 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2779 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2780 }
2781
2782 # for read-only access of old .rev_db formats
2783 sub unlink_rev_db_symlink {
2784 my ($self) = @_;
2785 my $link = $self->rev_db_path;
2786 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2787 if (-l $link) {
2788 unlink $link or croak "unlink: $link failed!";
2789 }
2790 }
2791
2792 sub rev_db_path {
2793 my ($self, $uuid) = @_;
2794 my $db_path = $self->map_path($uuid);
2795 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2796 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2797 $db_path;
2798 }
2799
2800 # the new replacement for .rev_db
2801 sub map_path {
2802 my ($self, $uuid) = @_;
2803 $uuid ||= $self->ra_uuid;
2804 "$self->{map_root}.$uuid";
2805 }
2806
2807 sub uri_encode {
2808 my ($f) = @_;
2809 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2810 $f
2811 }
2812
2813 sub remove_username {
2814 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2815 }
2816
2817 package Git::SVN::Prompt;
2818 use strict;
2819 use warnings;
2820 require SVN::Core;
2821 use vars qw/$_no_auth_cache $_username/;
2822
2823 sub simple {
2824 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2825 $may_save = undef if $_no_auth_cache;
2826 $default_username = $_username if defined $_username;
2827 if (defined $default_username && length $default_username) {
2828 if (defined $realm && length $realm) {
2829 print STDERR "Authentication realm: $realm\n";
2830 STDERR->flush;
2831 }
2832 $cred->username($default_username);
2833 } else {
2834 username($cred, $realm, $may_save, $pool);
2835 }
2836 $cred->password(_read_password("Password for '" .
2837 $cred->username . "': ", $realm));
2838 $cred->may_save($may_save);
2839 $SVN::_Core::SVN_NO_ERROR;
2840 }
2841
2842 sub ssl_server_trust {
2843 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2844 $may_save = undef if $_no_auth_cache;
2845 print STDERR "Error validating server certificate for '$realm':\n";
2846 {
2847 no warnings 'once';
2848 # All variables SVN::Auth::SSL::* are used only once,
2849 # so we're shutting up Perl warnings about this.
2850 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2851 print STDERR " - The certificate is not issued ",
2852 "by a trusted authority. Use the\n",
2853 " fingerprint to validate ",
2854 "the certificate manually!\n";
2855 }
2856 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2857 print STDERR " - The certificate hostname ",
2858 "does not match.\n";
2859 }
2860 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2861 print STDERR " - The certificate is not yet valid.\n";
2862 }
2863 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2864 print STDERR " - The certificate has expired.\n";
2865 }
2866 if ($failures & $SVN::Auth::SSL::OTHER) {
2867 print STDERR " - The certificate has ",
2868 "an unknown error.\n";
2869 }
2870 } # no warnings 'once'
2871 printf STDERR
2872 "Certificate information:\n".
2873 " - Hostname: %s\n".
2874 " - Valid: from %s until %s\n".
2875 " - Issuer: %s\n".
2876 " - Fingerprint: %s\n",
2877 map $cert_info->$_, qw(hostname valid_from valid_until
2878 issuer_dname fingerprint);
2879 my $choice;
2880 prompt:
2881 print STDERR $may_save ?
2882 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2883 "(R)eject or accept (t)emporarily? ";
2884 STDERR->flush;
2885 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2886 if ($choice =~ /^t$/i) {
2887 $cred->may_save(undef);
2888 } elsif ($choice =~ /^r$/i) {
2889 return -1;
2890 } elsif ($may_save && $choice =~ /^p$/i) {
2891 $cred->may_save($may_save);
2892 } else {
2893 goto prompt;
2894 }
2895 $cred->accepted_failures($failures);
2896 $SVN::_Core::SVN_NO_ERROR;
2897 }
2898
2899 sub ssl_client_cert {
2900 my ($cred, $realm, $may_save, $pool) = @_;
2901 $may_save = undef if $_no_auth_cache;
2902 print STDERR "Client certificate filename: ";
2903 STDERR->flush;
2904 chomp(my $filename = <STDIN>);
2905 $cred->cert_file($filename);
2906 $cred->may_save($may_save);
2907 $SVN::_Core::SVN_NO_ERROR;
2908 }
2909
2910 sub ssl_client_cert_pw {
2911 my ($cred, $realm, $may_save, $pool) = @_;
2912 $may_save = undef if $_no_auth_cache;
2913 $cred->password(_read_password("Password: ", $realm));
2914 $cred->may_save($may_save);
2915 $SVN::_Core::SVN_NO_ERROR;
2916 }
2917
2918 sub username {
2919 my ($cred, $realm, $may_save, $pool) = @_;
2920 $may_save = undef if $_no_auth_cache;
2921 if (defined $realm && length $realm) {
2922 print STDERR "Authentication realm: $realm\n";
2923 }
2924 my $username;
2925 if (defined $_username) {
2926 $username = $_username;
2927 } else {
2928 print STDERR "Username: ";
2929 STDERR->flush;
2930 chomp($username = <STDIN>);
2931 }
2932 $cred->username($username);
2933 $cred->may_save($may_save);
2934 $SVN::_Core::SVN_NO_ERROR;
2935 }
2936
2937 sub _read_password {
2938 my ($prompt, $realm) = @_;
2939 print STDERR $prompt;
2940 STDERR->flush;
2941 require Term::ReadKey;
2942 Term::ReadKey::ReadMode('noecho');
2943 my $password = '';
2944 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2945 last if $key =~ /[\012\015]/; # \n\r
2946 $password .= $key;
2947 }
2948 Term::ReadKey::ReadMode('restore');
2949 print STDERR "\n";
2950 STDERR->flush;
2951 $password;
2952 }
2953
2954 package SVN::Git::Fetcher;
2955 use vars qw/@ISA/;
2956 use strict;
2957 use warnings;
2958 use Carp qw/croak/;
2959 use IO::File qw//;
2960
2961 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2962 sub new {
2963 my ($class, $git_svn) = @_;
2964 my $self = SVN::Delta::Editor->new;
2965 bless $self, $class;
2966 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2967 $self->{empty} = {};
2968 $self->{dir_prop} = {};
2969 $self->{file_prop} = {};
2970 $self->{absent_dir} = {};
2971 $self->{absent_file} = {};
2972 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2973 $self;
2974 }
2975
2976 sub set_path_strip {
2977 my ($self, $path) = @_;
2978 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2979 }
2980
2981 sub open_root {
2982 { path => '' };
2983 }
2984
2985 sub open_directory {
2986 my ($self, $path, $pb, $rev) = @_;
2987 { path => $path };
2988 }
2989
2990 sub git_path {
2991 my ($self, $path) = @_;
2992 if ($self->{path_strip}) {
2993 $path =~ s!$self->{path_strip}!! or
2994 die "Failed to strip path '$path' ($self->{path_strip})\n";
2995 }
2996 $path;
2997 }
2998
2999 sub delete_entry {
3000 my ($self, $path, $rev, $pb) = @_;
3001
3002 my $gpath = $self->git_path($path);
3003 return undef if ($gpath eq '');
3004
3005 # remove entire directories.
3006 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3007 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3008 -r --name-only -z/,
3009 $self->{c}, '--', $gpath);
3010 local $/ = "\0";
3011 while (<$ls>) {
3012 chomp;
3013 $self->{gii}->remove($_);
3014 print "\tD\t$_\n" unless $::_q;
3015 }
3016 print "\tD\t$gpath/\n" unless $::_q;
3017 command_close_pipe($ls, $ctx);
3018 $self->{empty}->{$path} = 0
3019 } else {
3020 $self->{gii}->remove($gpath);
3021 print "\tD\t$gpath\n" unless $::_q;
3022 }
3023 undef;
3024 }
3025
3026 sub open_file {
3027 my ($self, $path, $pb, $rev) = @_;
3028 my $gpath = $self->git_path($path);
3029 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3030 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3031 unless (defined $mode && defined $blob) {
3032 die "$path was not found in commit $self->{c} (r$rev)\n";
3033 }
3034 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3035 pool => SVN::Pool->new, action => 'M' };
3036 }
3037
3038 sub add_file {
3039 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3040 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3041 delete $self->{empty}->{$dir};
3042 { path => $path, mode_a => 100644, mode_b => 100644,
3043 pool => SVN::Pool->new, action => 'A' };
3044 }
3045
3046 sub add_directory {
3047 my ($self, $path, $cp_path, $cp_rev) = @_;
3048 my $gpath = $self->git_path($path);
3049 if ($gpath eq '') {
3050 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3051 -r --name-only -z/,
3052 $self->{c});
3053 local $/ = "\0";
3054 while (<$ls>) {
3055 chomp;
3056 $self->{gii}->remove($_);
3057 print "\tD\t$_\n" unless $::_q;
3058 }
3059 command_close_pipe($ls, $ctx);
3060 $self->{empty}->{$path} = 0;
3061 }
3062 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3063 delete $self->{empty}->{$dir};
3064 $self->{empty}->{$path} = 1;
3065 { path => $path };
3066 }
3067
3068 sub change_dir_prop {
3069 my ($self, $db, $prop, $value) = @_;
3070 $self->{dir_prop}->{$db->{path}} ||= {};
3071 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3072 undef;
3073 }
3074
3075 sub absent_directory {
3076 my ($self, $path, $pb) = @_;
3077 $self->{absent_dir}->{$pb->{path}} ||= [];
3078 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3079 undef;
3080 }
3081
3082 sub absent_file {
3083 my ($self, $path, $pb) = @_;
3084 $self->{absent_file}->{$pb->{path}} ||= [];
3085 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3086 undef;
3087 }
3088
3089 sub change_file_prop {
3090 my ($self, $fb, $prop, $value) = @_;
3091 if ($prop eq 'svn:executable') {
3092 if ($fb->{mode_b} != 120000) {
3093 $fb->{mode_b} = defined $value ? 100755 : 100644;
3094 }
3095 } elsif ($prop eq 'svn:special') {
3096 $fb->{mode_b} = defined $value ? 120000 : 100644;
3097 } else {
3098 $self->{file_prop}->{$fb->{path}} ||= {};
3099 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3100 }
3101 undef;
3102 }
3103
3104 sub apply_textdelta {
3105 my ($self, $fb, $exp) = @_;
3106 my $fh = IO::File->new_tmpfile;
3107 $fh->autoflush(1);
3108 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3109 # (but $base does not,) so dup() it for reading in close_file
3110 open my $dup, '<&', $fh or croak $!;
3111 my $base = IO::File->new_tmpfile;
3112 $base->autoflush(1);
3113 if ($fb->{blob}) {
3114 defined (my $pid = fork) or croak $!;
3115 if (!$pid) {
3116 open STDOUT, '>&', $base or croak $!;
3117 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3118 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3119 }
3120 waitpid $pid, 0;
3121 croak $? if $?;
3122
3123 if (defined $exp) {
3124 seek $base, 0, 0 or croak $!;
3125 my $got = ::md5sum($base);
3126 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3127 "expected: $exp\n",
3128 " got: $got\n" if ($got ne $exp);
3129 }
3130 }
3131 seek $base, 0, 0 or croak $!;
3132 $fb->{fh} = $dup;
3133 $fb->{base} = $base;
3134 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3135 }
3136
3137 sub close_file {
3138 my ($self, $fb, $exp) = @_;
3139 my $hash;
3140 my $path = $self->git_path($fb->{path});
3141 if (my $fh = $fb->{fh}) {
3142 if (defined $exp) {
3143 seek($fh, 0, 0) or croak $!;
3144 my $got = ::md5sum($fh);
3145 if ($got ne $exp) {
3146 die "Checksum mismatch: $path\n",
3147 "expected: $exp\n got: $got\n";
3148 }
3149 }
3150 sysseek($fh, 0, 0) or croak $!;
3151 if ($fb->{mode_b} == 120000) {
3152 sysread($fh, my $buf, 5) == 5 or croak $!;
3153 $buf eq 'link ' or die "$path has mode 120000",
3154 "but is not a link\n";
3155 }
3156 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3157 if (!$pid) {
3158 open STDIN, '<&', $fh or croak $!;
3159 exec qw/git-hash-object -w --stdin/ or croak $!;
3160 }
3161 chomp($hash = do { local $/; <$out> });
3162 close $out or croak $!;
3163 close $fh or croak $!;
3164 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3165 close $fb->{base} or croak $!;
3166 } else {
3167 $hash = $fb->{blob} or die "no blob information\n";
3168 }
3169 $fb->{pool}->clear;
3170 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3171 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3172 undef;
3173 }
3174
3175 sub abort_edit {
3176 my $self = shift;
3177 $self->{nr} = $self->{gii}->{nr};
3178 delete $self->{gii};
3179 $self->SUPER::abort_edit(@_);
3180 }
3181
3182 sub close_edit {
3183 my $self = shift;
3184 $self->{git_commit_ok} = 1;
3185 $self->{nr} = $self->{gii}->{nr};
3186 delete $self->{gii};
3187 $self->SUPER::close_edit(@_);
3188 }
3189
3190 package SVN::Git::Editor;
3191 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3192 use strict;
3193 use warnings;
3194 use Carp qw/croak/;
3195 use IO::File;
3196
3197 sub new {
3198 my ($class, $opts) = @_;
3199 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3200 die "$_ required!\n" unless (defined $opts->{$_});
3201 }
3202
3203 my $pool = SVN::Pool->new;
3204 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3205 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3206 $opts->{r}, $mods);
3207
3208 # $opts->{ra} functions should not be used after this:
3209 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3210 $opts->{editor_cb}, $pool);
3211 my $self = SVN::Delta::Editor->new(@ce, $pool);
3212 bless $self, $class;
3213 foreach (qw/svn_path r tree_a tree_b/) {
3214 $self->{$_} = $opts->{$_};
3215 }
3216 $self->{url} = $opts->{ra}->{url};
3217 $self->{mods} = $mods;
3218 $self->{types} = $types;
3219 $self->{pool} = $pool;
3220 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3221 $self->{rm} = { };
3222 $self->{path_prefix} = length $self->{svn_path} ?
3223 "$self->{svn_path}/" : '';
3224 return $self;
3225 }
3226
3227 sub generate_diff {
3228 my ($tree_a, $tree_b) = @_;
3229 my @diff_tree = qw(diff-tree -z -r);
3230 if ($_cp_similarity) {
3231 push @diff_tree, "-C$_cp_similarity";
3232 } else {
3233 push @diff_tree, '-C';
3234 }
3235 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3236 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3237 push @diff_tree, $tree_a, $tree_b;
3238 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3239 local $/ = "\0";
3240 my $state = 'meta';
3241 my @mods;
3242 while (<$diff_fh>) {
3243 chomp $_; # this gets rid of the trailing "\0"
3244 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3245 $::sha1\s($::sha1)\s
3246 ([MTCRAD])\d*$/xo) {
3247 push @mods, { mode_a => $1, mode_b => $2,
3248 sha1_b => $3, chg => $4 };
3249 if ($4 =~ /^(?:C|R)$/) {
3250 $state = 'file_a';
3251 } else {
3252 $state = 'file_b';
3253 }
3254 } elsif ($state eq 'file_a') {
3255 my $x = $mods[$#mods] or croak "Empty array\n";
3256 if ($x->{chg} !~ /^(?:C|R)$/) {
3257 croak "Error parsing $_, $x->{chg}\n";
3258 }
3259 $x->{file_a} = $_;
3260 $state = 'file_b';
3261 } elsif ($state eq 'file_b') {
3262 my $x = $mods[$#mods] or croak "Empty array\n";
3263 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3264 croak "Error parsing $_, $x->{chg}\n";
3265 }
3266 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3267 croak "Error parsing $_, $x->{chg}\n";
3268 }
3269 $x->{file_b} = $_;
3270 $state = 'meta';
3271 } else {
3272 croak "Error parsing $_\n";
3273 }
3274 }
3275 command_close_pipe($diff_fh, $ctx);
3276 \@mods;
3277 }
3278
3279 sub check_diff_paths {
3280 my ($ra, $pfx, $rev, $mods) = @_;
3281 my %types;
3282 $pfx .= '/' if length $pfx;
3283
3284 sub type_diff_paths {
3285 my ($ra, $types, $path, $rev) = @_;
3286 my @p = split m#/+#, $path;
3287 my $c = shift @p;
3288 unless (defined $types->{$c}) {
3289 $types->{$c} = $ra->check_path($c, $rev);
3290 }
3291 while (@p) {
3292 $c .= '/' . shift @p;
3293 next if defined $types->{$c};
3294 $types->{$c} = $ra->check_path($c, $rev);
3295 }
3296 }
3297
3298 foreach my $m (@$mods) {
3299 foreach my $f (qw/file_a file_b/) {
3300 next unless defined $m->{$f};
3301 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3302 if (length $pfx.$dir && ! defined $types{$dir}) {
3303 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3304 }
3305 }
3306 }
3307 \%types;
3308 }
3309
3310 sub split_path {
3311 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3312 }
3313
3314 sub repo_path {
3315 my ($self, $path) = @_;
3316 $self->{path_prefix}.(defined $path ? $path : '');
3317 }
3318
3319 sub url_path {
3320 my ($self, $path) = @_;
3321 if ($self->{url} =~ m#^https?://#) {
3322 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3323 }
3324 $self->{url} . '/' . $self->repo_path($path);
3325 }
3326
3327 sub rmdirs {
3328 my ($self) = @_;
3329 my $rm = $self->{rm};
3330 delete $rm->{''}; # we never delete the url we're tracking
3331 return unless %$rm;
3332
3333 foreach (keys %$rm) {
3334 my @d = split m#/#, $_;
3335 my $c = shift @d;
3336 $rm->{$c} = 1;
3337 while (@d) {
3338 $c .= '/' . shift @d;
3339 $rm->{$c} = 1;
3340 }
3341 }
3342 delete $rm->{$self->{svn_path}};
3343 delete $rm->{''}; # we never delete the url we're tracking
3344 return unless %$rm;
3345
3346 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3347 $self->{tree_b});
3348 local $/ = "\0";
3349 while (<$fh>) {
3350 chomp;
3351 my @dn = split m#/#, $_;
3352 while (pop @dn) {
3353 delete $rm->{join '/', @dn};
3354 }
3355 unless (%$rm) {
3356 close $fh;
3357 return;
3358 }
3359 }
3360 command_close_pipe($fh, $ctx);
3361
3362 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3363 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3364 $self->close_directory($bat->{$d}, $p);
3365 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3366 print "\tD+\t$d/\n" unless $::_q;
3367 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3368 delete $bat->{$d};
3369 }
3370 }
3371
3372 sub open_or_add_dir {
3373 my ($self, $full_path, $baton) = @_;
3374 my $t = $self->{types}->{$full_path};
3375 if (!defined $t) {
3376 die "$full_path not known in r$self->{r} or we have a bug!\n";
3377 }
3378 {
3379 no warnings 'once';
3380 # SVN::Node::none and SVN::Node::file are used only once,
3381 # so we're shutting up Perl's warnings about them.
3382 if ($t == $SVN::Node::none) {
3383 return $self->add_directory($full_path, $baton,
3384 undef, -1, $self->{pool});
3385 } elsif ($t == $SVN::Node::dir) {
3386 return $self->open_directory($full_path, $baton,
3387 $self->{r}, $self->{pool});
3388 } # no warnings 'once'
3389 print STDERR "$full_path already exists in repository at ",
3390 "r$self->{r} and it is not a directory (",
3391 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3392 } # no warnings 'once'
3393 exit 1;
3394 }
3395
3396 sub ensure_path {
3397 my ($self, $path) = @_;
3398 my $bat = $self->{bat};
3399 my $repo_path = $self->repo_path($path);
3400 return $bat->{''} unless (length $repo_path);
3401 my @p = split m#/+#, $repo_path;
3402 my $c = shift @p;
3403 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3404 while (@p) {
3405 my $c0 = $c;
3406 $c .= '/' . shift @p;
3407 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3408 }
3409 return $bat->{$c};
3410 }
3411
3412 sub A {
3413 my ($self, $m) = @_;
3414 my ($dir, $file) = split_path($m->{file_b});
3415 my $pbat = $self->ensure_path($dir);
3416 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3417 undef, -1);
3418 print "\tA\t$m->{file_b}\n" unless $::_q;
3419 $self->chg_file($fbat, $m);
3420 $self->close_file($fbat,undef,$self->{pool});
3421 }
3422
3423 sub C {
3424 my ($self, $m) = @_;
3425 my ($dir, $file) = split_path($m->{file_b});
3426 my $pbat = $self->ensure_path($dir);
3427 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3428 $self->url_path($m->{file_a}), $self->{r});
3429 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3430 $self->chg_file($fbat, $m);
3431 $self->close_file($fbat,undef,$self->{pool});
3432 }
3433
3434 sub delete_entry {
3435 my ($self, $path, $pbat) = @_;
3436 my $rpath = $self->repo_path($path);
3437 my ($dir, $file) = split_path($rpath);
3438 $self->{rm}->{$dir} = 1;
3439 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3440 }
3441
3442 sub R {
3443 my ($self, $m) = @_;
3444 my ($dir, $file) = split_path($m->{file_b});
3445 my $pbat = $self->ensure_path($dir);
3446 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3447 $self->url_path($m->{file_a}), $self->{r});
3448 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3449 $self->chg_file($fbat, $m);
3450 $self->close_file($fbat,undef,$self->{pool});
3451
3452 ($dir, $file) = split_path($m->{file_a});
3453 $pbat = $self->ensure_path($dir);
3454 $self->delete_entry($m->{file_a}, $pbat);
3455 }
3456
3457 sub M {
3458 my ($self, $m) = @_;
3459 my ($dir, $file) = split_path($m->{file_b});
3460 my $pbat = $self->ensure_path($dir);
3461 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3462 $pbat,$self->{r},$self->{pool});
3463 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3464 $self->chg_file($fbat, $m);
3465 $self->close_file($fbat,undef,$self->{pool});
3466 }
3467
3468 sub T { shift->M(@_) }
3469
3470 sub change_file_prop {
3471 my ($self, $fbat, $pname, $pval) = @_;
3472 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3473 }
3474
3475 sub chg_file {
3476 my ($self, $fbat, $m) = @_;
3477 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3478 $self->change_file_prop($fbat,'svn:executable','*');
3479 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3480 $self->change_file_prop($fbat,'svn:executable',undef);
3481 }
3482 my $fh = IO::File->new_tmpfile or croak $!;
3483 if ($m->{mode_b} =~ /^120/) {
3484 print $fh 'link ' or croak $!;
3485 $self->change_file_prop($fbat,'svn:special','*');
3486 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3487 $self->change_file_prop($fbat,'svn:special',undef);
3488 }
3489 defined(my $pid = fork) or croak $!;
3490 if (!$pid) {
3491 open STDOUT, '>&', $fh or croak $!;
3492 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3493 }
3494 waitpid $pid, 0;
3495 croak $? if $?;
3496 $fh->flush == 0 or croak $!;
3497 seek $fh, 0, 0 or croak $!;
3498
3499 my $exp = ::md5sum($fh);
3500 seek $fh, 0, 0 or croak $!;
3501
3502 my $pool = SVN::Pool->new;
3503 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3504 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3505 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3506 $pool->clear;
3507
3508 close $fh or croak $!;
3509 }
3510
3511 sub D {
3512 my ($self, $m) = @_;
3513 my ($dir, $file) = split_path($m->{file_b});
3514 my $pbat = $self->ensure_path($dir);
3515 print "\tD\t$m->{file_b}\n" unless $::_q;
3516 $self->delete_entry($m->{file_b}, $pbat);
3517 }
3518
3519 sub close_edit {
3520 my ($self) = @_;
3521 my ($p,$bat) = ($self->{pool}, $self->{bat});
3522 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3523 next if $_ eq '';
3524 $self->close_directory($bat->{$_}, $p);
3525 }
3526 $self->close_directory($bat->{''}, $p);
3527 $self->SUPER::close_edit($p);
3528 $p->clear;
3529 }
3530
3531 sub abort_edit {
3532 my ($self) = @_;
3533 $self->SUPER::abort_edit($self->{pool});
3534 }
3535
3536 sub DESTROY {
3537 my $self = shift;
3538 $self->SUPER::DESTROY(@_);
3539 $self->{pool}->clear;
3540 }
3541
3542 # this drives the editor
3543 sub apply_diff {
3544 my ($self) = @_;
3545 my $mods = $self->{mods};
3546 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3547 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3548 my $f = $m->{chg};
3549 if (defined $o{$f}) {
3550 $self->$f($m);
3551 } else {
3552 fatal("Invalid change type: $f");
3553 }
3554 }
3555 $self->rmdirs if $_rmdir;
3556 if (@$mods == 0) {
3557 $self->abort_edit;
3558 } else {
3559 $self->close_edit;
3560 }
3561 return scalar @$mods;
3562 }
3563
3564 package Git::SVN::Ra;
3565 use vars qw/@ISA $config_dir $_log_window_size/;
3566 use strict;
3567 use warnings;
3568 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3569
3570 BEGIN {
3571 # enforce temporary pool usage for some simple functions
3572 no strict 'refs';
3573 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3574 my $SUPER = "SUPER::$f";
3575 *$f = sub {
3576 my $self = shift;
3577 my $pool = SVN::Pool->new;
3578 my @ret = $self->$SUPER(@_,$pool);
3579 $pool->clear;
3580 wantarray ? @ret : $ret[0];
3581 };
3582 }
3583 }
3584
3585 sub _auth_providers () {
3586 [
3587 SVN::Client::get_simple_provider(),
3588 SVN::Client::get_ssl_server_trust_file_provider(),
3589 SVN::Client::get_simple_prompt_provider(
3590 \&Git::SVN::Prompt::simple, 2),
3591 SVN::Client::get_ssl_client_cert_file_provider(),
3592 SVN::Client::get_ssl_client_cert_prompt_provider(
3593 \&Git::SVN::Prompt::ssl_client_cert, 2),
3594 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3595 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3596 SVN::Client::get_username_provider(),
3597 SVN::Client::get_ssl_server_trust_prompt_provider(
3598 \&Git::SVN::Prompt::ssl_server_trust),
3599 SVN::Client::get_username_prompt_provider(
3600 \&Git::SVN::Prompt::username, 2)
3601 ]
3602 }
3603
3604 sub escape_uri_only {
3605 my ($uri) = @_;
3606 my @tmp;
3607 foreach (split m{/}, $uri) {
3608 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3609 push @tmp, $_;
3610 }
3611 join('/', @tmp);
3612 }
3613
3614 sub escape_url {
3615 my ($url) = @_;
3616 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3617 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3618 $url = "$scheme://$domain$uri";
3619 }
3620 $url;
3621 }
3622
3623 sub new {
3624 my ($class, $url) = @_;
3625 $url =~ s!/+$!!;
3626 return $RA if ($RA && $RA->{url} eq $url);
3627
3628 SVN::_Core::svn_config_ensure($config_dir, undef);
3629 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3630 my $config = SVN::Core::config_get_config($config_dir);
3631 $RA = undef;
3632 my $dont_store_passwords = 1;
3633 my $conf_t = ${$config}{'config'};
3634 {
3635 no warnings 'once';
3636 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3637 # produces warnings that variables are used only once.
3638 # I had not found the better way to shut them up, so
3639 # the warnings of type 'once' are disabled in this block.
3640 if (SVN::_Core::svn_config_get_bool($conf_t,
3641 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3642 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3643 1) == 0) {
3644 SVN::_Core::svn_auth_set_parameter($baton,
3645 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3646 bless (\$dont_store_passwords, "_p_void"));
3647 }
3648 if (SVN::_Core::svn_config_get_bool($conf_t,
3649 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3650 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3651 1) == 0) {
3652 $Git::SVN::Prompt::_no_auth_cache = 1;
3653 }
3654 } # no warnings 'once'
3655 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3656 config => $config,
3657 pool => SVN::Pool->new,
3658 auth_provider_callbacks => $callbacks);
3659 $self->{url} = $url;
3660 $self->{svn_path} = $url;
3661 $self->{repos_root} = $self->get_repos_root;
3662 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3663 $self->{cache} = { check_path => { r => 0, data => {} },
3664 get_dir => { r => 0, data => {} } };
3665 $RA = bless $self, $class;
3666 }
3667
3668 sub check_path {
3669 my ($self, $path, $r) = @_;
3670 my $cache = $self->{cache}->{check_path};
3671 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3672 return $cache->{data}->{$path};
3673 }
3674 my $pool = SVN::Pool->new;
3675 my $t = $self->SUPER::check_path($path, $r, $pool);
3676 $pool->clear;
3677 if ($r != $cache->{r}) {
3678 %{$cache->{data}} = ();
3679 $cache->{r} = $r;
3680 }
3681 $cache->{data}->{$path} = $t;
3682 }
3683
3684 sub get_dir {
3685 my ($self, $dir, $r) = @_;
3686 my $cache = $self->{cache}->{get_dir};
3687 if ($r == $cache->{r}) {
3688 if (my $x = $cache->{data}->{$dir}) {
3689 return wantarray ? @$x : $x->[0];
3690 }
3691 }
3692 my $pool = SVN::Pool->new;
3693 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3694 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3695 $pool->clear;
3696 if ($r != $cache->{r}) {
3697 %{$cache->{data}} = ();
3698 $cache->{r} = $r;
3699 }
3700 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3701 wantarray ? (\%dirents, $r, $props) : \%dirents;
3702 }
3703
3704 sub DESTROY {
3705 # do not call the real DESTROY since we store ourselves in $RA
3706 }
3707
3708 sub get_log {
3709 my ($self, @args) = @_;
3710 my $pool = SVN::Pool->new;
3711 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3712 my $ret = $self->SUPER::get_log(@args, $pool);
3713 $pool->clear;
3714 $ret;
3715 }
3716
3717 sub trees_match {
3718 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3719 my $ctx = SVN::Client->new(auth => _auth_providers);
3720 my $out = IO::File->new_tmpfile;
3721
3722 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3723 # $ctx->diff(), so we'll create a default one
3724 my $pool = SVN::Pool->new_default_sub;
3725
3726 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3727 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3728 $out->flush;
3729 my $ret = (($out->stat)[7] == 0);
3730 close $out or croak $!;
3731
3732 $ret;
3733 }
3734
3735 sub get_commit_editor {
3736 my ($self, $log, $cb, $pool) = @_;
3737 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3738 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3739 }
3740
3741 sub gs_do_update {
3742 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3743 my $new = ($rev_a == $rev_b);
3744 my $path = $gs->{path};
3745
3746 if ($new && -e $gs->{index}) {
3747 unlink $gs->{index} or die
3748 "Couldn't unlink index: $gs->{index}: $!\n";
3749 }
3750 my $pool = SVN::Pool->new;
3751 $editor->set_path_strip($path);
3752 my (@pc) = split m#/#, $path;
3753 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3754 1, $editor, $pool);
3755 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3756
3757 # Since we can't rely on svn_ra_reparent being available, we'll
3758 # just have to do some magic with set_path to make it so
3759 # we only want a partial path.
3760 my $sp = '';
3761 my $final = join('/', @pc);
3762 while (@pc) {
3763 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3764 $sp .= '/' if length $sp;
3765 $sp .= shift @pc;
3766 }
3767 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3768
3769 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3770
3771 $reporter->finish_report($pool);
3772 $pool->clear;
3773 $editor->{git_commit_ok};
3774 }
3775
3776 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3777 # svn_ra_reparent didn't work before 1.4)
3778 sub gs_do_switch {
3779 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3780 my $path = $gs->{path};
3781 my $pool = SVN::Pool->new;
3782
3783 my $full_url = $self->{url};
3784 my $old_url = $full_url;
3785 $full_url .= '/' . escape_uri_only($path) if length $path;
3786 my ($ra, $reparented);
3787 if ($old_url ne $full_url) {
3788 if ($old_url !~ m#^svn(\+ssh)?://#) {
3789 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3790 $pool);
3791 $self->{url} = $full_url;
3792 $reparented = 1;
3793 } else {
3794 $_[0] = undef;
3795 $self = undef;
3796 $RA = undef;
3797 $ra = Git::SVN::Ra->new($full_url);
3798 $ra_invalid = 1;
3799 }
3800 }
3801 $ra ||= $self;
3802 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3803 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3804 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3805 $reporter->finish_report($pool);
3806
3807 if ($reparented) {
3808 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3809 $self->{url} = $old_url;
3810 }
3811
3812 $pool->clear;
3813 $editor->{git_commit_ok};
3814 }
3815
3816 sub longest_common_path {
3817 my ($gsv, $globs) = @_;
3818 my %common;
3819 my $common_max = scalar @$gsv;
3820
3821 foreach my $gs (@$gsv) {
3822 my @tmp = split m#/#, $gs->{path};
3823 my $p = '';
3824 foreach (@tmp) {
3825 $p .= length($p) ? "/$_" : $_;
3826 $common{$p} ||= 0;
3827 $common{$p}++;
3828 }
3829 }
3830 $globs ||= [];
3831 $common_max += scalar @$globs;
3832 foreach my $glob (@$globs) {
3833 my @tmp = split m#/#, $glob->{path}->{left};
3834 my $p = '';
3835 foreach (@tmp) {
3836 $p .= length($p) ? "/$_" : $_;
3837 $common{$p} ||= 0;
3838 $common{$p}++;
3839 }
3840 }
3841
3842 my $longest_path = '';
3843 foreach (sort {length $b <=> length $a} keys %common) {
3844 if ($common{$_} == $common_max) {
3845 $longest_path = $_;
3846 last;
3847 }
3848 }
3849 $longest_path;
3850 }
3851
3852 sub gs_fetch_loop_common {
3853 my ($self, $base, $head, $gsv, $globs) = @_;
3854 return if ($base > $head);
3855 my $inc = $_log_window_size;
3856 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3857 my $longest_path = longest_common_path($gsv, $globs);
3858 my $ra_url = $self->{url};
3859 while (1) {
3860 my %revs;
3861 my $err;
3862 my $err_handler = $SVN::Error::handler;
3863 $SVN::Error::handler = sub {
3864 ($err) = @_;
3865 skip_unknown_revs($err);
3866 };
3867 sub _cb {
3868 my ($paths, $r, $author, $date, $log) = @_;
3869 [ dup_changed_paths($paths),
3870 { author => $author, date => $date, log => $log } ];
3871 }
3872 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3873 sub { $revs{$_[1]} = _cb(@_) });
3874 if ($err && $max >= $head) {
3875 print STDERR "Path '$longest_path' ",
3876 "was probably deleted:\n",
3877 $err->expanded_message,
3878 "\nWill attempt to follow ",
3879 "revisions r$min .. r$max ",
3880 "committed before the deletion\n";
3881 my $hi = $max;
3882 while (--$hi >= $min) {
3883 my $ok;
3884 $self->get_log([$longest_path], $min, $hi,
3885 0, 1, 1, sub {
3886 $ok ||= $_[1];
3887 $revs{$_[1]} = _cb(@_) });
3888 if ($ok) {
3889 print STDERR "r$min .. r$ok OK\n";
3890 last;
3891 }
3892 }
3893 }
3894 $SVN::Error::handler = $err_handler;
3895
3896 my %exists = map { $_->{path} => $_ } @$gsv;
3897 foreach my $r (sort {$a <=> $b} keys %revs) {
3898 my ($paths, $logged) = @{$revs{$r}};
3899
3900 foreach my $gs ($self->match_globs(\%exists, $paths,
3901 $globs, $r)) {
3902 if ($gs->rev_map_max >= $r) {
3903 next;
3904 }
3905 next unless $gs->match_paths($paths, $r);
3906 $gs->{logged_rev_props} = $logged;
3907 if (my $last_commit = $gs->last_commit) {
3908 $gs->assert_index_clean($last_commit);
3909 }
3910 my $log_entry = $gs->do_fetch($paths, $r);
3911 if ($log_entry) {
3912 $gs->do_git_commit($log_entry);
3913 }
3914 }
3915 foreach my $g (@$globs) {
3916 my $k = "svn-remote.$g->{remote}." .
3917 "$g->{t}-maxRev";
3918 Git::SVN::tmp_config($k, $r);
3919 }
3920 if ($ra_invalid) {
3921 $_[0] = undef;
3922 $self = undef;
3923 $RA = undef;
3924 $self = Git::SVN::Ra->new($ra_url);
3925 $ra_invalid = undef;
3926 }
3927 }
3928 # pre-fill the .rev_db since it'll eventually get filled in
3929 # with '0' x40 if something new gets committed
3930 foreach my $gs (@$gsv) {
3931 next if $gs->rev_map_max >= $max;
3932 next if defined $gs->rev_map_get($max);
3933 $gs->rev_map_set($max, 0 x40);
3934 }
3935 foreach my $g (@$globs) {
3936 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3937 Git::SVN::tmp_config($k, $max);
3938 }
3939 last if $max >= $head;
3940 $min = $max + 1;
3941 $max += $inc;
3942 $max = $head if ($max > $head);
3943 }
3944 }
3945
3946 sub match_globs {
3947 my ($self, $exists, $paths, $globs, $r) = @_;
3948
3949 sub get_dir_check {
3950 my ($self, $exists, $g, $r) = @_;
3951 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3952 return unless scalar @x == 3;
3953 my $dirents = $x[0];
3954 foreach my $de (keys %$dirents) {
3955 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3956 my $p = $g->{path}->full_path($de);
3957 next if $exists->{$p};
3958 next if (length $g->{path}->{right} &&
3959 ($self->check_path($p, $r) !=
3960 $SVN::Node::dir));
3961 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3962 $g->{ref}->full_path($de), 1);
3963 }
3964 }
3965 foreach my $g (@$globs) {
3966 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3967 if ($path->{action} =~ /^[AR]$/) {
3968 get_dir_check($self, $exists, $g, $r);
3969 }
3970 }
3971 foreach (keys %$paths) {
3972 if (/$g->{path}->{left_regex}/ &&
3973 !/$g->{path}->{regex}/) {
3974 next if $paths->{$_}->{action} !~ /^[AR]$/;
3975 get_dir_check($self, $exists, $g, $r);
3976 }
3977 next unless /$g->{path}->{regex}/;
3978 my $p = $1;
3979 my $pathname = $g->{path}->full_path($p);
3980 next if $exists->{$pathname};
3981 next if ($self->check_path($pathname, $r) !=
3982 $SVN::Node::dir);
3983 $exists->{$pathname} = Git::SVN->init(
3984 $self->{url}, $pathname, undef,
3985 $g->{ref}->full_path($p), 1);
3986 }
3987 my $c = '';
3988 foreach (split m#/#, $g->{path}->{left}) {
3989 $c .= "/$_";
3990 next unless ($paths->{$c} &&
3991 ($paths->{$c}->{action} =~ /^[AR]$/));
3992 get_dir_check($self, $exists, $g, $r);
3993 }
3994 }
3995 values %$exists;
3996 }
3997
3998 sub minimize_url {
3999 my ($self) = @_;
4000 return $self->{url} if ($self->{url} eq $self->{repos_root});
4001 my $url = $self->{repos_root};
4002 my @components = split(m!/!, $self->{svn_path});
4003 my $c = '';
4004 do {
4005 $url .= "/$c" if length $c;
4006 eval { (ref $self)->new($url)->get_latest_revnum };
4007 } while ($@ && ($c = shift @components));
4008 $url;
4009 }
4010
4011 sub can_do_switch {
4012 my $self = shift;
4013 unless (defined $can_do_switch) {
4014 my $pool = SVN::Pool->new;
4015 my $rep = eval {
4016 $self->do_switch(1, '', 0, $self->{url},
4017 SVN::Delta::Editor->new, $pool);
4018 };
4019 if ($@) {
4020 $can_do_switch = 0;
4021 } else {
4022 $rep->abort_report($pool);
4023 $can_do_switch = 1;
4024 }
4025 $pool->clear;
4026 }
4027 $can_do_switch;
4028 }
4029
4030 sub skip_unknown_revs {
4031 my ($err) = @_;
4032 my $errno = $err->apr_err();
4033 # Maybe the branch we're tracking didn't
4034 # exist when the repo started, so it's
4035 # not an error if it doesn't, just continue
4036 #
4037 # Wonderfully consistent library, eh?
4038 # 160013 - svn:// and file://
4039 # 175002 - http(s)://
4040 # 175007 - http(s):// (this repo required authorization, too...)
4041 # More codes may be discovered later...
4042 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4043 my $err_key = $err->expanded_message;
4044 # revision numbers change every time, filter them out
4045 $err_key =~ s/\d+/\0/g;
4046 $err_key = "$errno\0$err_key";
4047 unless ($ignored_err{$err_key}) {
4048 warn "W: Ignoring error from SVN, path probably ",
4049 "does not exist: ($errno): ",
4050 $err->expanded_message,"\n";
4051 $ignored_err{$err_key} = 1;
4052 }
4053 return;
4054 }
4055 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4056 }
4057
4058 # svn_log_changed_path_t objects passed to get_log are likely to be
4059 # overwritten even if only the refs are copied to an external variable,
4060 # so we should dup the structures in their entirety. Using an externally
4061 # passed pool (instead of our temporary and quickly cleared pool in
4062 # Git::SVN::Ra) does not help matters at all...
4063 sub dup_changed_paths {
4064 my ($paths) = @_;
4065 return undef unless $paths;
4066 my %ret;
4067 foreach my $p (keys %$paths) {
4068 my $i = $paths->{$p};
4069 my %s = map { $_ => $i->$_ }
4070 qw/copyfrom_path copyfrom_rev action/;
4071 $ret{$p} = \%s;
4072 }
4073 \%ret;
4074 }
4075
4076 package Git::SVN::Log;
4077 use strict;
4078 use warnings;
4079 use POSIX qw/strftime/;
4080 use constant commit_log_separator => ('-' x 72) . "\n";
4081 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4082 %rusers $show_commit $incremental/;
4083 my $l_fmt;
4084
4085 sub cmt_showable {
4086 my ($c) = @_;
4087 return 1 if defined $c->{r};
4088
4089 # big commit message got truncated by the 16k pretty buffer in rev-list
4090 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4091 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4092 @{$c->{l}} = ();
4093 my @log = command(qw/cat-file commit/, $c->{c});
4094
4095 # shift off the headers
4096 shift @log while ($log[0] ne '');
4097 shift @log;
4098
4099 # TODO: make $c->{l} not have a trailing newline in the future
4100 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4101
4102 (undef, $c->{r}, undef) = ::extract_metadata(
4103 (grep(/^git-svn-id: /, @log))[-1]);
4104 }
4105 return defined $c->{r};
4106 }
4107
4108 sub log_use_color {
4109 return $color || Git->repository->get_colorbool('color.diff');
4110 }
4111
4112 sub git_svn_log_cmd {
4113 my ($r_min, $r_max, @args) = @_;
4114 my $head = 'HEAD';
4115 my (@files, @log_opts);
4116 foreach my $x (@args) {
4117 if ($x eq '--' || @files) {
4118 push @files, $x;
4119 } else {
4120 if (::verify_ref("$x^0")) {
4121 $head = $x;
4122 } else {
4123 push @log_opts, $x;
4124 }
4125 }
4126 }
4127
4128 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4129 $gs ||= Git::SVN->_new;
4130 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4131 $gs->refname);
4132 push @cmd, '-r' unless $non_recursive;
4133 push @cmd, qw/--raw --name-status/ if $verbose;
4134 push @cmd, '--color' if log_use_color();
4135 push @cmd, @log_opts;
4136 if (defined $r_max && $r_max == $r_min) {
4137 push @cmd, '--max-count=1';
4138 if (my $c = $gs->rev_map_get($r_max)) {
4139 push @cmd, $c;
4140 }
4141 } elsif (defined $r_max) {
4142 if ($r_max < $r_min) {
4143 ($r_min, $r_max) = ($r_max, $r_min);
4144 }
4145 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4146 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4147 # If there are no commits in the range, both $c_max and $c_min
4148 # will be undefined. If there is at least 1 commit in the
4149 # range, both will be defined.
4150 return () if !defined $c_min || !defined $c_max;
4151 if ($c_min eq $c_max) {
4152 push @cmd, '--max-count=1', $c_min;
4153 } else {
4154 push @cmd, '--boundary', "$c_min..$c_max";
4155 }
4156 }
4157 return (@cmd, @files);
4158 }
4159
4160 # adapted from pager.c
4161 sub config_pager {
4162 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4163 if (!defined $pager) {
4164 $pager = 'less';
4165 } elsif (length $pager == 0 || $pager eq 'cat') {
4166 $pager = undef;
4167 }
4168 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4169 }
4170
4171 sub run_pager {
4172 return unless -t *STDOUT && defined $pager;
4173 pipe my $rfd, my $wfd or return;
4174 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4175 if (!$pid) {
4176 open STDOUT, '>&', $wfd or
4177 ::fatal "Can't redirect to stdout: $!";
4178 return;
4179 }
4180 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4181 $ENV{LESS} ||= 'FRSX';
4182 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4183 }
4184
4185 sub format_svn_date {
4186 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4187 }
4188
4189 sub parse_git_date {
4190 my ($t, $tz) = @_;
4191 # Date::Parse isn't in the standard Perl distro :(
4192 if ($tz =~ s/^\+//) {
4193 $t += tz_to_s_offset($tz);
4194 } elsif ($tz =~ s/^\-//) {
4195 $t -= tz_to_s_offset($tz);
4196 }
4197 return $t;
4198 }
4199
4200 sub set_local_timezone {
4201 if (defined $TZ) {
4202 $ENV{TZ} = $TZ;
4203 } else {
4204 delete $ENV{TZ};
4205 }
4206 }
4207
4208 sub tz_to_s_offset {
4209 my ($tz) = @_;
4210 $tz =~ s/(\d\d)$//;
4211 return ($1 * 60) + ($tz * 3600);
4212 }
4213
4214 sub get_author_info {
4215 my ($dest, $author, $t, $tz) = @_;
4216 $author =~ s/(?:^\s*|\s*$)//g;
4217 $dest->{a_raw} = $author;
4218 my $au;
4219 if ($::_authors) {
4220 $au = $rusers{$author} || undef;
4221 }
4222 if (!$au) {
4223 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4224 }
4225 $dest->{t} = $t;
4226 $dest->{tz} = $tz;
4227 $dest->{a} = $au;
4228 $dest->{t_utc} = parse_git_date($t, $tz);
4229 }
4230
4231 sub process_commit {
4232 my ($c, $r_min, $r_max, $defer) = @_;
4233 if (defined $r_min && defined $r_max) {
4234 if ($r_min == $c->{r} && $r_min == $r_max) {
4235 show_commit($c);
4236 return 0;
4237 }
4238 return 1 if $r_min == $r_max;
4239 if ($r_min < $r_max) {
4240 # we need to reverse the print order
4241 return 0 if (defined $limit && --$limit < 0);
4242 push @$defer, $c;
4243 return 1;
4244 }
4245 if ($r_min != $r_max) {
4246 return 1 if ($r_min < $c->{r});
4247 return 1 if ($r_max > $c->{r});
4248 }
4249 }
4250 return 0 if (defined $limit && --$limit < 0);
4251 show_commit($c);
4252 return 1;
4253 }
4254
4255 sub show_commit {
4256 my $c = shift;
4257 if ($oneline) {
4258 my $x = "\n";
4259 if (my $l = $c->{l}) {
4260 while ($l->[0] =~ /^\s*$/) { shift @$l }
4261 $x = $l->[0];
4262 }
4263 $l_fmt ||= 'A' . length($c->{r});
4264 print 'r',pack($l_fmt, $c->{r}),' | ';
4265 print "$c->{c} | " if $show_commit;
4266 print $x;
4267 } else {
4268 show_commit_normal($c);
4269 }
4270 }
4271
4272 sub show_commit_changed_paths {
4273 my ($c) = @_;
4274 return unless $c->{changed};
4275 print "Changed paths:\n", @{$c->{changed}};
4276 }
4277
4278 sub show_commit_normal {
4279 my ($c) = @_;
4280 print commit_log_separator, "r$c->{r} | ";
4281 print "$c->{c} | " if $show_commit;
4282 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4283 my $nr_line = 0;
4284
4285 if (my $l = $c->{l}) {
4286 while ($l->[$#$l] eq "\n" && $#$l > 0
4287 && $l->[($#$l - 1)] eq "\n") {
4288 pop @$l;
4289 }
4290 $nr_line = scalar @$l;
4291 if (!$nr_line) {
4292 print "1 line\n\n\n";
4293 } else {
4294 if ($nr_line == 1) {
4295 $nr_line = '1 line';
4296 } else {
4297 $nr_line .= ' lines';
4298 }
4299 print $nr_line, "\n";
4300 show_commit_changed_paths($c);
4301 print "\n";
4302 print $_ foreach @$l;
4303 }
4304 } else {
4305 print "1 line\n";
4306 show_commit_changed_paths($c);
4307 print "\n";
4308
4309 }
4310 foreach my $x (qw/raw stat diff/) {
4311 if ($c->{$x}) {
4312 print "\n";
4313 print $_ foreach @{$c->{$x}}
4314 }
4315 }
4316 }
4317
4318 sub cmd_show_log {
4319 my (@args) = @_;
4320 my ($r_min, $r_max);
4321 my $r_last = -1; # prevent dupes
4322 set_local_timezone();
4323 if (defined $::_revision) {
4324 if ($::_revision =~ /^(\d+):(\d+)$/) {
4325 ($r_min, $r_max) = ($1, $2);
4326 } elsif ($::_revision =~ /^\d+$/) {
4327 $r_min = $r_max = $::_revision;
4328 } else {
4329 ::fatal "-r$::_revision is not supported, use ",
4330 "standard 'git log' arguments instead";
4331 }
4332 }
4333
4334 config_pager();
4335 @args = git_svn_log_cmd($r_min, $r_max, @args);
4336 if (!@args) {
4337 print commit_log_separator unless $incremental || $oneline;
4338 return;
4339 }
4340 my $log = command_output_pipe(@args);
4341 run_pager();
4342 my (@k, $c, $d, $stat);
4343 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4344 while (<$log>) {
4345 if (/^${esc_color}commit -?($::sha1_short)/o) {
4346 my $cmt = $1;
4347 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4348 $r_last = $c->{r};
4349 process_commit($c, $r_min, $r_max, \@k) or
4350 goto out;
4351 }
4352 $d = undef;
4353 $c = { c => $cmt };
4354 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4355 get_author_info($c, $1, $2, $3);
4356 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4357 # ignore
4358 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4359 push @{$c->{raw}}, $_;
4360 } elsif (/^${esc_color}[ACRMDT]\t/) {
4361 # we could add $SVN->{svn_path} here, but that requires
4362 # remote access at the moment (repo_path_split)...
4363 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4364 push @{$c->{changed}}, $_;
4365 } elsif (/^${esc_color}diff /o) {
4366 $d = 1;
4367 push @{$c->{diff}}, $_;
4368 } elsif ($d) {
4369 push @{$c->{diff}}, $_;
4370 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4371 $esc_color*[\+\-]*$esc_color$/x) {
4372 $stat = 1;
4373 push @{$c->{stat}}, $_;
4374 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4375 push @{$c->{stat}}, $_;
4376 $stat = undef;
4377 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4378 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4379 } elsif (s/^${esc_color} //o) {
4380 push @{$c->{l}}, $_;
4381 }
4382 }
4383 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4384 $r_last = $c->{r};
4385 process_commit($c, $r_min, $r_max, \@k);
4386 }
4387 if (@k) {
4388 ($r_min, $r_max) = ($r_max, $r_min);
4389 process_commit($_, $r_min, $r_max) foreach reverse @k;
4390 }
4391 out:
4392 close $log;
4393 print commit_log_separator unless $incremental || $oneline;
4394 }
4395
4396 package Git::SVN::Migration;
4397 # these version numbers do NOT correspond to actual version numbers
4398 # of git nor git-svn. They are just relative.
4399 #
4400 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4401 #
4402 # v1 layout: .git/$id/info/url, refs/remotes/$id
4403 #
4404 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4405 #
4406 # v3 layout: .git/svn/$id, refs/remotes/$id
4407 # - info/url may remain for backwards compatibility
4408 # - this is what we migrate up to this layout automatically,
4409 # - this will be used by git svn init on single branches
4410 # v3.1 layout (auto migrated):
4411 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4412 # for backwards compatibility
4413 #
4414 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4415 # - this is only created for newly multi-init-ed
4416 # repositories. Similar in spirit to the
4417 # --use-separate-remotes option in git-clone (now default)
4418 # - we do not automatically migrate to this (following
4419 # the example set by core git)
4420 #
4421 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4422 # - newer, more-efficient format that uses 24-bytes per record
4423 # with no filler space.
4424 # - use xxd -c24 < .rev_map.$UUID to view and debug
4425 # - This is a one-way migration, repositories updated to the
4426 # new format will not be able to use old git-svn without
4427 # rebuilding the .rev_db. Rebuilding the rev_db is not
4428 # possible if noMetadata or useSvmProps are set; but should
4429 # be no problem for users that use the (sensible) defaults.
4430 use strict;
4431 use warnings;
4432 use Carp qw/croak/;
4433 use File::Path qw/mkpath/;
4434 use File::Basename qw/dirname basename/;
4435 use vars qw/$_minimize/;
4436
4437 sub migrate_from_v0 {
4438 my $git_dir = $ENV{GIT_DIR};
4439 return undef unless -d $git_dir;
4440 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4441 my $migrated = 0;
4442 while (<$fh>) {
4443 chomp;
4444 my ($id, $orig_ref) = ($_, $_);
4445 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4446 next unless -f "$git_dir/$id/info/url";
4447 my $new_ref = "refs/remotes/$id";
4448 if (::verify_ref("$new_ref^0")) {
4449 print STDERR "W: $orig_ref is probably an old ",
4450 "branch used by an ancient version of ",
4451 "git-svn.\n",
4452 "However, $new_ref also exists.\n",
4453 "We will not be able ",
4454 "to use this branch until this ",
4455 "ambiguity is resolved.\n";
4456 next;
4457 }
4458 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4459 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4460 command_noisy('update-ref', $new_ref, $orig_ref);
4461 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4462 $migrated++;
4463 }
4464 command_close_pipe($fh, $ctx);
4465 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4466 $migrated;
4467 }
4468
4469 sub migrate_from_v1 {
4470 my $git_dir = $ENV{GIT_DIR};
4471 my $migrated = 0;
4472 return $migrated unless -d $git_dir;
4473 my $svn_dir = "$git_dir/svn";
4474
4475 # just in case somebody used 'svn' as their $id at some point...
4476 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4477
4478 print STDERR "Migrating from a git-svn v1 layout...\n";
4479 mkpath([$svn_dir]);
4480 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4481 "$svn_dir\n\t(required for this version ",
4482 "($::VERSION) of git-svn) does not. exist\n";
4483 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4484 while (<$fh>) {
4485 my $x = $_;
4486 next unless $x =~ s#^refs/remotes/##;
4487 chomp $x;
4488 next unless -f "$git_dir/$x/info/url";
4489 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4490 next unless $u;
4491 my $dn = dirname("$git_dir/svn/$x");
4492 mkpath([$dn]) unless -d $dn;
4493 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4494 mkpath(["$git_dir/svn/svn"]);
4495 print STDERR " - $git_dir/$x/info => ",
4496 "$git_dir/svn/$x/info\n";
4497 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4498 croak "$!: $x";
4499 # don't worry too much about these, they probably
4500 # don't exist with repos this old (save for index,
4501 # and we can easily regenerate that)
4502 foreach my $f (qw/unhandled.log index .rev_db/) {
4503 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4504 }
4505 } else {
4506 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4507 rename "$git_dir/$x", "$git_dir/svn/$x" or
4508 croak "$!: $x";
4509 }
4510 $migrated++;
4511 }
4512 command_close_pipe($fh, $ctx);
4513 print STDERR "Done migrating from a git-svn v1 layout\n";
4514 $migrated;
4515 }
4516
4517 sub read_old_urls {
4518 my ($l_map, $pfx, $path) = @_;
4519 my @dir;
4520 foreach (<$path/*>) {
4521 if (-r "$_/info/url") {
4522 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4523 my $ref_id = $pfx . basename $_;
4524 my $url = ::file_to_s("$_/info/url");
4525 $l_map->{$ref_id} = $url;
4526 } elsif (-d $_) {
4527 push @dir, $_;
4528 }
4529 }
4530 foreach (@dir) {
4531 my $x = $_;
4532 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4533 read_old_urls($l_map, $x, $_);
4534 }
4535 }
4536
4537 sub migrate_from_v2 {
4538 my @cfg = command(qw/config -l/);
4539 return if grep /^svn-remote\..+\.url=/, @cfg;
4540 my %l_map;
4541 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4542 my $migrated = 0;
4543
4544 foreach my $ref_id (sort keys %l_map) {
4545 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4546 if ($@) {
4547 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4548 }
4549 $migrated++;
4550 }
4551 $migrated;
4552 }
4553
4554 sub minimize_connections {
4555 my $r = Git::SVN::read_all_remotes();
4556 my $new_urls = {};
4557 my $root_repos = {};
4558 foreach my $repo_id (keys %$r) {
4559 my $url = $r->{$repo_id}->{url} or next;
4560 my $fetch = $r->{$repo_id}->{fetch} or next;
4561 my $ra = Git::SVN::Ra->new($url);
4562
4563 # skip existing cases where we already connect to the root
4564 if (($ra->{url} eq $ra->{repos_root}) ||
4565 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4566 $repo_id)) {
4567 $root_repos->{$ra->{url}} = $repo_id;
4568 next;
4569 }
4570
4571 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4572 my $root_path = $ra->{url};
4573 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4574 foreach my $path (keys %$fetch) {
4575 my $ref_id = $fetch->{$path};
4576 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4577
4578 # make sure we can read when connecting to
4579 # a higher level of a repository
4580 my ($last_rev, undef) = $gs->last_rev_commit;
4581 if (!defined $last_rev) {
4582 $last_rev = eval {
4583 $root_ra->get_latest_revnum;
4584 };
4585 next if $@;
4586 }
4587 my $new = $root_path;
4588 $new .= length $path ? "/$path" : '';
4589 eval {
4590 $root_ra->get_log([$new], $last_rev, $last_rev,
4591 0, 0, 1, sub { });
4592 };
4593 next if $@;
4594 $new_urls->{$ra->{repos_root}}->{$new} =
4595 { ref_id => $ref_id,
4596 old_repo_id => $repo_id,
4597 old_path => $path };
4598 }
4599 }
4600
4601 my @emptied;
4602 foreach my $url (keys %$new_urls) {
4603 # see if we can re-use an existing [svn-remote "repo_id"]
4604 # instead of creating a(n ugly) new section:
4605 my $repo_id = $root_repos->{$url} ||
4606 Git::SVN::sanitize_remote_name($url);
4607
4608 my $fetch = $new_urls->{$url};
4609 foreach my $path (keys %$fetch) {
4610 my $x = $fetch->{$path};
4611 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4612 my $pfx = "svn-remote.$x->{old_repo_id}";
4613
4614 my $old_fetch = quotemeta("$x->{old_path}:".
4615 "refs/remotes/$x->{ref_id}");
4616 command_noisy(qw/config --unset/,
4617 "$pfx.fetch", '^'. $old_fetch . '$');
4618 delete $r->{$x->{old_repo_id}}->
4619 {fetch}->{$x->{old_path}};
4620 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4621 command_noisy(qw/config --unset/,
4622 "$pfx.url");
4623 push @emptied, $x->{old_repo_id}
4624 }
4625 }
4626 }
4627 if (@emptied) {
4628 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4629 "$ENV{GIT_DIR}/config";
4630 print STDERR <<EOF;
4631 The following [svn-remote] sections in your config file ($file) are empty
4632 and can be safely removed:
4633 EOF
4634 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4635 }
4636 }
4637
4638 sub migration_check {
4639 migrate_from_v0();
4640 migrate_from_v1();
4641 migrate_from_v2();
4642 minimize_connections() if $_minimize;
4643 }
4644
4645 package Git::IndexInfo;
4646 use strict;
4647 use warnings;
4648 use Git qw/command_input_pipe command_close_pipe/;
4649
4650 sub new {
4651 my ($class) = @_;
4652 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4653 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4654 }
4655
4656 sub remove {
4657 my ($self, $path) = @_;
4658 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4659 return ++$self->{nr};
4660 }
4661 undef;
4662 }
4663
4664 sub update {
4665 my ($self, $mode, $hash, $path) = @_;
4666 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4667 return ++$self->{nr};
4668 }
4669 undef;
4670 }
4671
4672 sub DESTROY {
4673 my ($self) = @_;
4674 command_close_pipe($self->{gui}, $self->{ctx});
4675 }
4676
4677 package Git::SVN::GlobSpec;
4678 use strict;
4679 use warnings;
4680
4681 sub new {
4682 my ($class, $glob) = @_;
4683 my $re = $glob;
4684 $re =~ s!/+$!!g; # no need for trailing slashes
4685 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4686 my ($left, $right) = ($1, $2);
4687 if ($nr > 1) {
4688 die "Only one '*' wildcard expansion ",
4689 "is supported (got $nr): '$glob'\n";
4690 } elsif ($nr == 0) {
4691 die "One '*' is needed for glob: '$glob'\n";
4692 }
4693 $re = quotemeta($left) . $re . quotemeta($right);
4694 if (length $left && !($left =~ s!/+$!!g)) {
4695 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4696 }
4697 if (length $right && !($right =~ s!^/+!!g)) {
4698 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4699 }
4700 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4701 bless { left => $left, right => $right, left_regex => $left_re,
4702 regex => qr/$re/, glob => $glob }, $class;
4703 }
4704
4705 sub full_path {
4706 my ($self, $path) = @_;
4707 return (length $self->{left} ? "$self->{left}/" : '') .
4708 $path . (length $self->{right} ? "/$self->{right}" : '');
4709 }
4710
4711 __END__
4712
4713 Data structures:
4714
4715
4716 $remotes = { # returned by read_all_remotes()
4717 'svn' => {
4718 # svn-remote.svn.url=https://svn.musicpd.org
4719 url => 'https://svn.musicpd.org',
4720 # svn-remote.svn.fetch=mpd/trunk:trunk
4721 fetch => {
4722 'mpd/trunk' => 'trunk',
4723 },
4724 # svn-remote.svn.tags=mpd/tags/*:tags/*
4725 tags => {
4726 path => {
4727 left => 'mpd/tags',
4728 right => '',
4729 regex => qr!mpd/tags/([^/]+)$!,
4730 glob => 'tags/*',
4731 },
4732 ref => {
4733 left => 'tags',
4734 right => '',
4735 regex => qr!tags/([^/]+)$!,
4736 glob => 'tags/*',
4737 },
4738 }
4739 }
4740 };
4741
4742 $log_entry hashref as returned by libsvn_log_entry()
4743 {
4744 log => 'whitespace-formatted log entry
4745 ', # trailing newline is preserved
4746 revision => '8', # integer
4747 date => '2004-02-24T17:01:44.108345Z', # commit date
4748 author => 'committer name'
4749 };
4750
4751
4752 # this is generated by generate_diff();
4753 @mods = array of diff-index line hashes, each element represents one line
4754 of diff-index output
4755
4756 diff-index line ($m hash)
4757 {
4758 mode_a => first column of diff-index output, no leading ':',
4759 mode_b => second column of diff-index output,
4760 sha1_b => sha1sum of the final blob,
4761 chg => change type [MCRADT],
4762 file_a => original file name of a file (iff chg is 'C' or 'R')
4763 file_b => new/current file name of a file (any chg)
4764 }
4765 ;
4766
4767 # retval of read_url_paths{,_all}();
4768 $l_map = {
4769 # repository root url
4770 'https://svn.musicpd.org' => {
4771 # repository path # GIT_SVN_ID
4772 'mpd/trunk' => 'trunk',
4773 'mpd/tags/0.11.5' => 'tags/0.11.5',
4774 },
4775 }
4776
4777 Notes:
4778 I don't trust the each() function on unless I created %hash myself
4779 because the internal iterator may not have started at base.
The Best VCS Around