Merge branch 'es/doc-worktree-guessremote-config'
[git.git] / configure.ac
blobe0d0da3c0c9bccb0b6b1b1a5a3db0097f4f10757
1 #                                               -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ## Definitions of private macros.
6 # GIT_CONF_SUBST(VAL, VAR)
7 # ------------------------
8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
9 AC_DEFUN([GIT_CONF_SUBST],
10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
11 config_appended_defs="$config_appended_defs${newline}dnl
12 $1=m4_if([$#],[1],[${$1}],[$2])"])
14 # GIT_CONF_SUBST_INIT
15 # -------------------
16 # Prepare shell variables and autoconf machine required by later calls
17 # to GIT_CONF_SUBST.
18 AC_DEFUN([GIT_CONF_SUBST_INIT],
19     [config_appended_defs=; newline='
21     AC_CONFIG_COMMANDS([$config_file],
22                        [echo "$config_appended_defs" >> "$config_file"],
23                        [config_file=$config_file
24                         config_appended_defs="$config_appended_defs"])])
26 # GIT_ARG_SET_PATH(PROGRAM)
27 # -------------------------
28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
30 # --without-PROGRAM version used.
31 AC_DEFUN([GIT_ARG_SET_PATH],
32     [AC_ARG_WITH([$1],
33         [AS_HELP_STRING([--with-$1=PATH],
34                         [provide PATH to $1])],
35         [GIT_CONF_APPEND_PATH([$1], [$2])],
36         [])])
38 # GIT_CONF_APPEND_PATH(PROGRAM)
39 # -----------------------------
40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
41 # Used by GIT_ARG_SET_PATH(PROGRAM)
42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
43 # --without-PROGRAM is used.
44 AC_DEFUN([GIT_CONF_APPEND_PATH],
45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
46     if test "$withval" = "no"; then
47         if test -n "$2"; then
48                 GIT_UC_PROGRAM[]_PATH=$withval
49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
52         else
53                 AC_MSG_ERROR([You cannot use git without $1])
54         fi
55     else
56         if test "$withval" = "yes"; then
57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
58         else
59                 GIT_UC_PROGRAM[]_PATH=$withval
60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
62         fi
63     fi
64     m4_popdef([GIT_UC_PROGRAM])])
66 # GIT_PARSE_WITH(PACKAGE)
67 # -----------------------
68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
72 AC_DEFUN([GIT_PARSE_WITH],
73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
74     if test "$withval" = "no"; then
75         NO_[]GIT_UC_PACKAGE=YesPlease
76     elif test "$withval" = "yes"; then
77         NO_[]GIT_UC_PACKAGE=
78     else
79         NO_[]GIT_UC_PACKAGE=
80         GIT_UC_PACKAGE[]DIR=$withval
81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
83     fi
84     m4_popdef([GIT_UC_PACKAGE])])
86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
87 # -----------------------------------------------------
88 # Set VAR to the value specied by --with-WITHNAME.
89 # No verification of arguments is performed, but warnings are issued
90 # if either 'yes' or 'no' is specified.
91 # HELP_TEXT is presented when --help is called.
92 # This is a direct way to allow setting variables in the Makefile.
93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
94 [AC_ARG_WITH([$1],
95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
96  if test -n "$withval"; then
97   if test "$withval" = "yes" -o "$withval" = "no"; then
98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
99                      [a value for $1 ($2).  Maybe you do...?])
100   fi
101   AC_MSG_NOTICE([Setting $2 to $withval])
102   GIT_CONF_SUBST([$2], [$withval])
103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
107 # -----------------------------------------
108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
110 # -Wall), it does not work.  By looking for function definition in
111 # libraries, this problem can be worked around.
112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
113   AC_SEARCH_LIBS([$1],,
114   [$2],[$3])
115 ],[$3])])
118 # GIT_STASH_FLAGS(BASEPATH_VAR)
119 # -----------------------------
120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
121 # tests that may want to take user settings into account.
122 AC_DEFUN([GIT_STASH_FLAGS],[
123 if test -n "$1"; then
124    old_CPPFLAGS="$CPPFLAGS"
125    old_LDFLAGS="$LDFLAGS"
126    CPPFLAGS="-I$1/include $CPPFLAGS"
127    LDFLAGS="-L$1/$lib $LDFLAGS"
132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
133 dnl -----------------------------
134 dnl Restore the stashed *FLAGS values.
135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
136 if test -n "$1"; then
137    CPPFLAGS="$old_CPPFLAGS"
138    LDFLAGS="$old_LDFLAGS"
142 ## Configure body starts here.
144 AC_PREREQ(2.59)
145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
147 AC_CONFIG_SRCDIR([git.c])
149 config_file=config.mak.autogen
150 config_in=config.mak.in
152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
154 # Directories holding "saner" versions of common or POSIX binaries.
155 AC_ARG_WITH([sane-tool-path],
156   [AS_HELP_STRING(
157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
158     [Directories to prepend to PATH in build system and generated scripts])],
159   [if test "$withval" = "no"; then
160     withval=''
161   else
162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
163   fi
164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
165   [# If the "--with-sane-tool-path" option was not given, don't touch
166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
167    # This should minimize spurious differences in the behaviour of the
168    # Git build system when configure is used w.r.t. when it is not.
169    :])
171 ## Site configuration related to programs (before tests)
172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
174 # Set lib to alternative name of lib directory (e.g. lib64)
175 AC_ARG_WITH([lib],
176  [AS_HELP_STRING([--with-lib=ARG],
177                  [ARG specifies alternative name for lib directory])],
178  [if test "$withval" = "no" || test "$withval" = "yes"; then
179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
180   else
181         lib=$withval
182         AC_MSG_NOTICE([Setting lib to '$lib'])
183         GIT_CONF_SUBST([lib])
184   fi])
186 if test -z "$lib"; then
187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
188    lib=lib
191 AC_ARG_ENABLE([pthreads],
192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
194   [The default if FLAGS is not specified is to try first -pthread]
195   [and then -lpthread.]
196   [--disable-pthreads will disable threading.])],
198 if test "x$enableval" = "xyes"; then
199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
200 elif test "x$enableval" != "xno"; then
201    PTHREAD_CFLAGS=$enableval
202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
203 else
204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
205    NO_PTHREADS=YesPlease
206    USER_NOPTHREAD=1
207 fi],
209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
212 # Define option to enable JavaScript minification
213 AC_ARG_ENABLE([jsmin],
214 [AS_HELP_STRING([--enable-jsmin=PATH],
215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
217   JSMIN=$enableval;
218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
219   GIT_CONF_SUBST([JSMIN])
222 # Define option to enable CSS minification
223 AC_ARG_ENABLE([cssmin],
224 [AS_HELP_STRING([--enable-cssmin=PATH],
225   [PATH is the name of a CSS minifier or the absolute path to one.])],
227   CSSMIN=$enableval;
228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
229   GIT_CONF_SUBST([CSSMIN])
232 ## Site configuration (override autodetection)
233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
234 AC_MSG_NOTICE([CHECKS for site configuration])
236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
237 # tests.  These tests take up a significant amount of the total test time
238 # but are not needed unless you plan to talk to SVN repos.
240 # Define PPC_SHA1 environment variable when running make to make use of
241 # a bundled SHA1 routine optimized for PowerPC.
243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
246 # /foo/bar/include and /foo/bar/lib directories.
247 AC_ARG_WITH(openssl,
248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
249 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
250 GIT_PARSE_WITH([openssl]))
252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
253 # commands such as log and grep offer runtime options to use
254 # Perl-compatible regular expressions instead of standard or extended
255 # POSIX regular expressions.
257 # USE_LIBPCRE is a synonym for USE_LIBPCRE2, define USE_LIBPCRE1
258 # instead if you'd like to use the legacy version 1 of the PCRE
259 # library. Support for version 1 will likely be removed in some future
260 # release of Git, as upstream has all but abandoned it.
262 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
263 # /foo/bar/include and /foo/bar/lib directories.
265 AC_ARG_WITH(libpcre,
266 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
267     if test "$withval" = "no"; then
268         USE_LIBPCRE2=
269     elif test "$withval" = "yes"; then
270         USE_LIBPCRE2=YesPlease
271     else
272         USE_LIBPCRE2=YesPlease
273         LIBPCREDIR=$withval
274         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
275         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
276         dnl it yet.
277         GIT_CONF_SUBST([LIBPCREDIR])
278     fi)
280 AC_ARG_WITH(libpcre1,
281 AS_HELP_STRING([--with-libpcre1],[support Perl-compatible regexes via libpcre1 (default is NO)])
282 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
283     if test "$withval" = "no"; then
284         USE_LIBPCRE1=
285     elif test "$withval" = "yes"; then
286         USE_LIBPCRE1=YesPlease
287     else
288         USE_LIBPCRE1=YesPlease
289         LIBPCREDIR=$withval
290         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
291         dnl USE_LIBPCRE1 can still be modified below, so don't substitute
292         dnl it yet.
293         GIT_CONF_SUBST([LIBPCREDIR])
294     fi)
296 AC_ARG_WITH(libpcre2,
297 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
298 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
299     if test -n "$USE_LIBPCRE2"; then
300         AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
301     fi
303     if test -n "$USE_LIBPCRE1"; then
304         AC_MSG_ERROR([Only supply one of --with-libpcre1 or --with-libpcre2!])
305     fi
307     if test "$withval" = "no"; then
308         USE_LIBPCRE2=
309     elif test "$withval" = "yes"; then
310         USE_LIBPCRE2=YesPlease
311     else
312         USE_LIBPCRE2=YesPlease
313         LIBPCREDIR=$withval
314         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
315         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
316         dnl it yet.
317         GIT_CONF_SUBST([LIBPCREDIR])
318     fi)
320 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
321 AC_FUNC_ALLOCA
322 case $ac_cv_working_alloca_h in
323     yes)    HAVE_ALLOCA_H=YesPlease;;
324     *)      HAVE_ALLOCA_H='';;
325 esac
326 GIT_CONF_SUBST([HAVE_ALLOCA_H])
328 # Define NO_CURL if you do not have curl installed.  git-http-pull and
329 # git-http-push are not built, and you cannot use http:// and https://
330 # transports.
332 # Define CURLDIR=/foo/bar if your curl header and library files are in
333 # /foo/bar/include and /foo/bar/lib directories.
334 AC_ARG_WITH(curl,
335 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
336 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
337 GIT_PARSE_WITH(curl))
339 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
340 # not built, and you cannot push using http:// and https:// transports.
342 # Define EXPATDIR=/foo/bar if your expat header and library files are in
343 # /foo/bar/include and /foo/bar/lib directories.
344 AC_ARG_WITH(expat,
345 AS_HELP_STRING([--with-expat],
346 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
347 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
348 GIT_PARSE_WITH(expat))
350 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
351 # installed in /sw, but don't want GIT to link against any libraries
352 # installed there.  If defined you may specify your own (or Fink's)
353 # include directories and library directories by defining CFLAGS
354 # and LDFLAGS appropriately.
356 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
357 # have DarwinPorts installed in /opt/local, but don't want GIT to
358 # link against any libraries installed there.  If defined you may
359 # specify your own (or DarwinPort's) include directories and
360 # library directories by defining CFLAGS and LDFLAGS appropriately.
362 # Define NO_MMAP if you want to avoid mmap.
364 # Define NO_ICONV if your libc does not properly support iconv.
365 AC_ARG_WITH(iconv,
366 AS_HELP_STRING([--without-iconv],
367 [if your architecture doesn't properly support iconv])
368 AS_HELP_STRING([--with-iconv=PATH],
369 [PATH is prefix for libiconv library and headers])
370 AS_HELP_STRING([],
371 [used only if you need linking with libiconv]),
372 GIT_PARSE_WITH(iconv))
374 ## --enable-FEATURE[=ARG] and --disable-FEATURE
376 # Define USE_NSEC below if you want git to care about sub-second file mtimes
377 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
378 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
379 # randomly break unless your underlying filesystem supports those sub-second
380 # times (my ext3 doesn't).
382 # Define USE_STDEV below if you want git to care about the underlying device
383 # change being considered an inode change from the update-index perspective.
386 # Allow user to set ETC_GITCONFIG variable
387 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
388                         Use VALUE instead of /etc/gitconfig as the
389                         global git configuration file.
390                         If VALUE is not fully qualified it will be interpreted
391                         as a path relative to the computed prefix at runtime.)
394 # Allow user to set ETC_GITATTRIBUTES variable
395 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
396                         Use VALUE instead of /etc/gitattributes as the
397                         global git attributes file.
398                         If VALUE is not fully qualified it will be interpreted
399                         as a path relative to the computed prefix at runtime.)
402 # Allow user to set the default pager
403 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
404                         Use VALUE as the fall-back pager instead of 'less'.
405                         This is used by things like 'git log' when the user
406                         does not specify a pager to use through alternate
407                         methods. eg: /usr/bin/pager)
409 # Allow user to set the default editor
410 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
411                         Use VALUE as the fall-back editor instead of 'vi'.
412                         This is used by things like 'git commit' when the user
413                         does not specify a preferred editor through other
414                         methods. eg: /usr/bin/editor)
417 # Define SHELL_PATH to provide path to shell.
418 GIT_ARG_SET_PATH(shell)
420 # Define PERL_PATH to provide path to Perl.
421 GIT_ARG_SET_PATH(perl)
423 # Define PYTHON_PATH to provide path to Python.
424 GIT_ARG_SET_PATH(python, allow-without)
426 # Define ZLIB_PATH to provide path to zlib.
427 GIT_ARG_SET_PATH(zlib)
429 # Declare the with-tcltk/without-tcltk options.
430 AC_ARG_WITH(tcltk,
431 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
432 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
433 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
434 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
435 GIT_PARSE_WITH(tcltk))
439 ## Checks for programs.
440 AC_MSG_NOTICE([CHECKS for programs])
442 AC_PROG_CC([cc gcc])
443 AC_C_INLINE
444 case $ac_cv_c_inline in
445   inline | yes | no) INLINE='';;
446   *)                 INLINE=$ac_cv_c_inline ;;
447 esac
448 GIT_CONF_SUBST([INLINE])
450 # which switch to pass runtime path to dynamic libraries to the linker
451 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
452    SAVE_LDFLAGS="${LDFLAGS}"
453    LDFLAGS="${SAVE_LDFLAGS} -R /"
454    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
455    LDFLAGS="${SAVE_LDFLAGS}"
457 if test "$git_cv_ld_dashr" = "yes"; then
458    CC_LD_DYNPATH=-R
459 else
460    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
461       SAVE_LDFLAGS="${LDFLAGS}"
462       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
463       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
464       LDFLAGS="${SAVE_LDFLAGS}"
465    ])
466    if test "$git_cv_ld_wl_rpath" = "yes"; then
467       CC_LD_DYNPATH=-Wl,-rpath,
468    else
469       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
470          SAVE_LDFLAGS="${LDFLAGS}"
471          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
472          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
473          LDFLAGS="${SAVE_LDFLAGS}"
474       ])
475       if test "$git_cv_ld_rpath" = "yes"; then
476          CC_LD_DYNPATH=-rpath
477       else
478          CC_LD_DYNPATH=
479          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
480       fi
481    fi
483 GIT_CONF_SUBST([CC_LD_DYNPATH])
484 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
485 AC_CHECK_TOOLS(AR, [gar ar], :)
486 AC_CHECK_PROGS(TAR, [gtar tar])
487 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
488 # TCLTK_PATH will be set to some value if we want Tcl/Tk
489 # or will be empty otherwise.
490 if test -n "$NO_TCLTK"; then
491   TCLTK_PATH=
492 else
493   if test "$with_tcltk" = ""; then
494   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
495     TCLTK_PATH=wish
496   elif test "$with_tcltk" = "yes"; then
497   # Tcl/Tk check requested.
498     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
499   else
500     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
501     TCLTK_PATH="$with_tcltk"
502   fi
504 GIT_CONF_SUBST([TCLTK_PATH])
505 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
506 if test -n "$ASCIIDOC"; then
507         AC_MSG_CHECKING([for asciidoc version])
508         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
509         case "${asciidoc_version}" in
510         asciidoc' '8*)
511                 AC_MSG_RESULT([${asciidoc_version}])
512                 ;;
513         *)
514                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
515                 ;;
516         esac
519 if grep -a ascii configure.ac >/dev/null; then
520   AC_MSG_RESULT([Using 'grep -a' for sane_grep])
521   SANE_TEXT_GREP=-a
522 else
523   SANE_TEXT_GREP=
525 GIT_CONF_SUBST([SANE_TEXT_GREP])
527 ## Checks for libraries.
528 AC_MSG_NOTICE([CHECKS for libraries])
530 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
531 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
533 GIT_STASH_FLAGS($OPENSSLDIR)
535 AC_CHECK_LIB([crypto], [SHA1_Init],
536 [NEEDS_SSL_WITH_CRYPTO=],
537 [AC_CHECK_LIB([ssl], [SHA1_Init],
538  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
539  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
541 GIT_UNSTASH_FLAGS($OPENSSLDIR)
543 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
544 GIT_CONF_SUBST([NO_OPENSSL])
547 # Handle the USE_LIBPCRE1 and USE_LIBPCRE2 options potentially set
548 # above.
551 if test -n "$USE_LIBPCRE1"; then
553 GIT_STASH_FLAGS($LIBPCREDIR)
555 AC_CHECK_LIB([pcre], [pcre_version],
556 [USE_LIBPCRE1=YesPlease],
557 [USE_LIBPCRE1=])
559 GIT_UNSTASH_FLAGS($LIBPCREDIR)
561 GIT_CONF_SUBST([USE_LIBPCRE1])
566 if test -n "$USE_LIBPCRE2"; then
568 GIT_STASH_FLAGS($LIBPCREDIR)
570 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
571 [USE_LIBPCRE2=YesPlease],
572 [USE_LIBPCRE2=])
574 GIT_UNSTASH_FLAGS($LIBPCREDIR)
576 GIT_CONF_SUBST([USE_LIBPCRE2])
581 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
582 # git-http-push are not built, and you cannot use http:// and https://
583 # transports.
585 GIT_STASH_FLAGS($CURLDIR)
587 AC_CHECK_LIB([curl], [curl_global_init],
588 [NO_CURL=],
589 [NO_CURL=YesPlease])
591 GIT_UNSTASH_FLAGS($CURLDIR)
593 GIT_CONF_SUBST([NO_CURL])
595 if test -z "$NO_CURL"; then
597 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
598 [curl-config],
599 [no])
601 if test $CURL_CONFIG != no; then
602     GIT_CONF_SUBST([CURL_CONFIG])
604     if test -z "$CURL_CONFIG_OPTS"; then
605         CURL_CONFIG_OPTS="--libs"
606     fi
608     CURL_LDFLAGS=$($CURL_CONFIG $CURL_CONFIG_OPTS)
609     AC_MSG_NOTICE([Setting CURL_LDFLAGS to '$CURL_LDFLAGS'])
610     GIT_CONF_SUBST([CURL_LDFLAGS], [$CURL_LDFLAGS])
617 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
618 # not built, and you cannot push using http:// and https:// transports.
620 GIT_STASH_FLAGS($EXPATDIR)
622 AC_CHECK_LIB([expat], [XML_ParserCreate],
623 [NO_EXPAT=],
624 [NO_EXPAT=YesPlease])
626 GIT_UNSTASH_FLAGS($EXPATDIR)
628 GIT_CONF_SUBST([NO_EXPAT])
631 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
632 # some Solaris installations).
633 # Define NO_ICONV if neither libc nor libiconv support iconv.
635 if test -z "$NO_ICONV"; then
637 GIT_STASH_FLAGS($ICONVDIR)
639 AC_DEFUN([ICONVTEST_SRC],
640 [AC_LANG_PROGRAM([#include <iconv.h>],
641  [iconv_open("", "");])])
643 if test -n "$ICONVDIR"; then
644    lib_order="-liconv -lc"
645 else
646    lib_order="-lc -liconv"
649 NO_ICONV=YesPlease
651 for l in $lib_order; do
652     if test "$l" = "-liconv"; then
653        NEEDS_LIBICONV=YesPlease
654     else
655        NEEDS_LIBICONV=
656     fi
658     old_LIBS="$LIBS"
659     LIBS="$LIBS $l"
660     AC_MSG_CHECKING([for iconv in $l])
661     AC_LINK_IFELSE([ICONVTEST_SRC],
662         [AC_MSG_RESULT([yes])
663         NO_ICONV=
664         break],
665         [AC_MSG_RESULT([no])])
666     LIBS="$old_LIBS"
667 done
669 #in case of break
670 LIBS="$old_LIBS"
672 GIT_UNSTASH_FLAGS($ICONVDIR)
674 GIT_CONF_SUBST([NEEDS_LIBICONV])
675 GIT_CONF_SUBST([NO_ICONV])
677 if test -n "$NO_ICONV"; then
678     NEEDS_LIBICONV=
684 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
686 GIT_STASH_FLAGS($ZLIB_PATH)
688 AC_DEFUN([ZLIBTEST_SRC], [
689 AC_LANG_PROGRAM([#include <zlib.h>],
690  [deflateBound(0, 0);])])
691 AC_MSG_CHECKING([for deflateBound in -lz])
692 old_LIBS="$LIBS"
693 LIBS="$LIBS -lz"
694 AC_LINK_IFELSE([ZLIBTEST_SRC],
695         [AC_MSG_RESULT([yes])],
696         [AC_MSG_RESULT([no])
697         NO_DEFLATE_BOUND=yes])
698 LIBS="$old_LIBS"
700 GIT_UNSTASH_FLAGS($ZLIB_PATH)
702 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
705 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
706 # Patrick Mauritz).
707 AC_CHECK_LIB([c], [socket],
708 [NEEDS_SOCKET=],
709 [NEEDS_SOCKET=YesPlease])
710 GIT_CONF_SUBST([NEEDS_SOCKET])
711 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
714 # The next few tests will define NEEDS_RESOLV if linking with
715 # libresolv provides some of the functions we would normally get
716 # from libc.
717 NEEDS_RESOLV=
719 # Define NO_INET_NTOP if linking with -lresolv is not enough.
720 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
721 NO_INET_NTOP=
722 AC_CHECK_FUNC([inet_ntop],
723     [],
724     [AC_CHECK_LIB([resolv], [inet_ntop],
725         [NEEDS_RESOLV=YesPlease],
726         [NO_INET_NTOP=YesPlease])
728 GIT_CONF_SUBST([NO_INET_NTOP])
730 # Define NO_INET_PTON if linking with -lresolv is not enough.
731 # Solaris 2.7 in particular hos inet_pton in -lresolv.
732 NO_INET_PTON=
733 AC_CHECK_FUNC([inet_pton],
734     [],
735     [AC_CHECK_LIB([resolv], [inet_pton],
736         [NEEDS_RESOLV=YesPlease],
737         [NO_INET_PTON=YesPlease])
739 GIT_CONF_SUBST([NO_INET_PTON])
741 # Define NO_HSTRERROR if linking with -lresolv is not enough.
742 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
743 NO_HSTRERROR=
744 AC_CHECK_FUNC([hstrerror],
745     [],
746     [AC_CHECK_LIB([resolv], [hstrerror],
747         [NEEDS_RESOLV=YesPlease],
748         [NO_HSTRERROR=YesPlease])
750 GIT_CONF_SUBST([NO_HSTRERROR])
752 dnl This must go after all the possible places for its initialization,
753 dnl in the AC_CHECK_FUNC invocations above.
754 GIT_CONF_SUBST([NEEDS_RESOLV])
756 # If any of the above tests determined that -lresolv is needed at
757 # build-time, also set it here for remaining configure-time checks.
758 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
760 AC_CHECK_LIB([c], [basename],
761 [NEEDS_LIBGEN=],
762 [NEEDS_LIBGEN=YesPlease])
763 GIT_CONF_SUBST([NEEDS_LIBGEN])
764 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
766 AC_CHECK_LIB([c], [gettext],
767 [LIBC_CONTAINS_LIBINTL=YesPlease],
768 [LIBC_CONTAINS_LIBINTL=])
769 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
772 # Define NO_GETTEXT if you don't want Git output to be translated.
773 # A translated Git requires GNU libintl or another gettext implementation
774 AC_CHECK_HEADER([libintl.h],
775 [NO_GETTEXT=],
776 [NO_GETTEXT=YesPlease])
777 GIT_CONF_SUBST([NO_GETTEXT])
779 if test -z "$NO_GETTEXT"; then
780     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
783 ## Checks for header files.
784 AC_MSG_NOTICE([CHECKS for header files])
786 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
787 AC_CHECK_HEADER([sys/select.h],
788 [NO_SYS_SELECT_H=],
789 [NO_SYS_SELECT_H=UnfortunatelyYes])
790 GIT_CONF_SUBST([NO_SYS_SELECT_H])
792 # Define NO_POLL_H if you don't have poll.h
793 AC_CHECK_HEADER([poll.h],
794 [NO_POLL_H=],
795 [NO_POLL_H=UnfortunatelyYes])
796 GIT_CONF_SUBST([NO_POLL_H])
798 # Define NO_SYS_POLL_H if you don't have sys/poll.h
799 AC_CHECK_HEADER([sys/poll.h],
800 [NO_SYS_POLL_H=],
801 [NO_SYS_POLL_H=UnfortunatelyYes])
802 GIT_CONF_SUBST([NO_SYS_POLL_H])
804 # Define NO_INTTYPES_H if you don't have inttypes.h
805 AC_CHECK_HEADER([inttypes.h],
806 [NO_INTTYPES_H=],
807 [NO_INTTYPES_H=UnfortunatelyYes])
808 GIT_CONF_SUBST([NO_INTTYPES_H])
810 # Define OLD_ICONV if your library has an old iconv(), where the second
811 # (input buffer pointer) parameter is declared with type (const char **).
812 AC_DEFUN([OLDICONVTEST_SRC], [
813 AC_LANG_PROGRAM([[
814 #include <iconv.h>
816 extern size_t iconv(iconv_t cd,
817                     char **inbuf, size_t *inbytesleft,
818                     char **outbuf, size_t *outbytesleft);
819 ]], [])])
821 GIT_STASH_FLAGS($ICONVDIR)
823 AC_MSG_CHECKING([for old iconv()])
824 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
825         [AC_MSG_RESULT([no])],
826         [AC_MSG_RESULT([yes])
827         OLD_ICONV=UnfortunatelyYes])
829 GIT_UNSTASH_FLAGS($ICONVDIR)
831 GIT_CONF_SUBST([OLD_ICONV])
833 ## Checks for typedefs, structures, and compiler characteristics.
834 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
836 TYPE_SOCKLEN_T
837 case $ac_cv_type_socklen_t in
838   yes)  SOCKLEN_T='';;
839   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
840 esac
841 GIT_CONF_SUBST([SOCKLEN_T])
844 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
845 AC_CHECK_TYPES([struct itimerval],
846 [NO_STRUCT_ITIMERVAL=],
847 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
848 [#include <sys/time.h>])
849 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
851 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
852 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
853 # stat.st_mtimespec.tv_nsec exists.
854 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
855 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
856 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
857         USE_ST_TIMESPEC=YesPlease
858         GIT_CONF_SUBST([USE_ST_TIMESPEC])
859 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
860         NO_NSEC=YesPlease
861         GIT_CONF_SUBST([NO_NSEC])
864 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
865 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
866 AC_CHECK_MEMBER(struct dirent.d_type,
867 [NO_D_TYPE_IN_DIRENT=],
868 [NO_D_TYPE_IN_DIRENT=YesPlease],
869 [#include <dirent.h>])
870 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
872 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
873 # in the C library.
874 AC_CHECK_MEMBER(struct passwd.pw_gecos,
875 [NO_GECOS_IN_PWENT=],
876 [NO_GECOS_IN_PWENT=YesPlease],
877 [#include <pwd.h>])
878 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
880 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
881 # sockaddr_storage.
882 AC_CHECK_TYPE(struct sockaddr_storage,
883 [NO_SOCKADDR_STORAGE=],
884 [NO_SOCKADDR_STORAGE=YesPlease],[
885 #include <sys/types.h>
886 #include <sys/socket.h>
888 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
890 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
891 AC_CHECK_TYPE([struct addrinfo],[
892  GIT_CHECK_FUNC([getaddrinfo],
893   [NO_IPV6=],
894   [NO_IPV6=YesPlease])
895 ],[NO_IPV6=YesPlease],[
896 #include <sys/types.h>
897 #include <sys/socket.h>
898 #include <netdb.h>
900 GIT_CONF_SUBST([NO_IPV6])
902 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
903 # feature.
904 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
905  [ac_cv_c_regex_with_reg_startend], [
906 AC_EGREP_CPP(yippeeyeswehaveit,
907         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
908 #include <regex.h>
910 [#ifdef REG_STARTEND
911 yippeeyeswehaveit
912 #endif
914         [ac_cv_c_regex_with_reg_startend=yes],
915         [ac_cv_c_regex_with_reg_startend=no])
917 if test $ac_cv_c_regex_with_reg_startend = yes; then
918         NO_REGEX=
919 else
920         NO_REGEX=YesPlease
922 GIT_CONF_SUBST([NO_REGEX])
924 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
925 # when attempting to read from an fopen'ed directory.
926 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
927  [ac_cv_fread_reads_directories],
929 AC_RUN_IFELSE(
930         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
931                 [[
932                 FILE *f = fopen(".", "r");
933                 return f != NULL;]])],
934         [ac_cv_fread_reads_directories=no],
935         [ac_cv_fread_reads_directories=yes])
937 if test $ac_cv_fread_reads_directories = yes; then
938         FREAD_READS_DIRECTORIES=UnfortunatelyYes
939 else
940         FREAD_READS_DIRECTORIES=
942 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
944 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
945 # or vsnprintf() return -1 instead of number of characters which would
946 # have been written to the final string if enough space had been available.
947 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
948  [ac_cv_snprintf_returns_bogus],
950 AC_RUN_IFELSE(
951         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
952                 #include "stdarg.h"
954                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
955                 {
956                   int ret;
957                   va_list ap;
958                   va_start(ap, format);
959                   ret = vsnprintf(str, maxsize, format, ap);
960                   va_end(ap);
961                   return ret;
962                 }],
963                 [[char buf[6];
964                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
965                       || strcmp(buf, "12")) return 1;
966                   if (snprintf(buf, 3, "%s", "12345") != 5
967                       || strcmp(buf, "12")) return 1]])],
968         [ac_cv_snprintf_returns_bogus=no],
969         [ac_cv_snprintf_returns_bogus=yes])
971 if test $ac_cv_snprintf_returns_bogus = yes; then
972         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
973 else
974         SNPRINTF_RETURNS_BOGUS=
976 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
978 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
979 # bits in mode values.
980 AC_CACHE_CHECK([whether the platform uses typical file type bits],
981  [ac_cv_sane_mode_bits], [
982 AC_EGREP_CPP(yippeeyeswehaveit,
983         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
984 [#if S_IFMT == 0170000 && \
985         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
986         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
987         S_IFIFO == 0010000 && S_IFSOCK == 0140000
988 yippeeyeswehaveit
989 #endif
991         [ac_cv_sane_mode_bits=yes],
992         [ac_cv_sane_mode_bits=no])
994 if test $ac_cv_sane_mode_bits = yes; then
995         NEEDS_MODE_TRANSLATION=
996 else
997         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
999 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
1002 ## Checks for library functions.
1003 ## (in default C library and libraries checked by AC_CHECK_LIB)
1004 AC_MSG_NOTICE([CHECKS for library functions])
1006 # Define NO_LIBGEN_H if you don't have libgen.h.
1007 AC_CHECK_HEADER([libgen.h],
1008 [NO_LIBGEN_H=],
1009 [NO_LIBGEN_H=YesPlease])
1010 GIT_CONF_SUBST([NO_LIBGEN_H])
1012 # Define HAVE_PATHS_H if you have paths.h.
1013 AC_CHECK_HEADER([paths.h],
1014 [HAVE_PATHS_H=YesPlease],
1015 [HAVE_PATHS_H=])
1016 GIT_CONF_SUBST([HAVE_PATHS_H])
1018 # Define HAVE_LIBCHARSET_H if have libcharset.h
1019 AC_CHECK_HEADER([libcharset.h],
1020 [HAVE_LIBCHARSET_H=YesPlease],
1021 [HAVE_LIBCHARSET_H=])
1022 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1024 # Define HAVE_STRINGS_H if you have strings.h
1025 AC_CHECK_HEADER([strings.h],
1026 [HAVE_STRINGS_H=YesPlease],
1027 [HAVE_STRINGS_H=])
1028 GIT_CONF_SUBST([HAVE_STRINGS_H])
1029 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1030 # and libcharset does
1031 CHARSET_LIB=
1032 AC_CHECK_LIB([iconv], [locale_charset],
1033        [CHARSET_LIB=-liconv],
1034        [AC_CHECK_LIB([charset], [locale_charset],
1035                      [CHARSET_LIB=-lcharset])])
1036 GIT_CONF_SUBST([CHARSET_LIB])
1038 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1039 GIT_CHECK_FUNC(clock_gettime,
1040         [HAVE_CLOCK_GETTIME=YesPlease],
1041         [HAVE_CLOCK_GETTIME=])
1042 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1044 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1045 AC_LANG_PROGRAM([[
1046 #include <time.h>
1047 clockid_t id = CLOCK_MONOTONIC;
1048 ]])])
1051 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1052 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1053 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1054         [AC_MSG_RESULT([yes])
1055         HAVE_CLOCK_MONOTONIC=YesPlease],
1056         [AC_MSG_RESULT([no])
1057         HAVE_CLOCK_MONOTONIC=])
1058 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1060 # Define NO_SETITIMER if you don't have setitimer.
1061 GIT_CHECK_FUNC(setitimer,
1062 [NO_SETITIMER=],
1063 [NO_SETITIMER=YesPlease])
1064 GIT_CONF_SUBST([NO_SETITIMER])
1066 # Define NO_STRCASESTR if you don't have strcasestr.
1067 GIT_CHECK_FUNC(strcasestr,
1068 [NO_STRCASESTR=],
1069 [NO_STRCASESTR=YesPlease])
1070 GIT_CONF_SUBST([NO_STRCASESTR])
1072 # Define NO_MEMMEM if you don't have memmem.
1073 GIT_CHECK_FUNC(memmem,
1074 [NO_MEMMEM=],
1075 [NO_MEMMEM=YesPlease])
1076 GIT_CONF_SUBST([NO_MEMMEM])
1078 # Define NO_STRLCPY if you don't have strlcpy.
1079 GIT_CHECK_FUNC(strlcpy,
1080 [NO_STRLCPY=],
1081 [NO_STRLCPY=YesPlease])
1082 GIT_CONF_SUBST([NO_STRLCPY])
1084 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1085 AC_CHECK_TYPE(uintmax_t,
1086 [NO_UINTMAX_T=],
1087 [NO_UINTMAX_T=YesPlease],[
1088 #include <inttypes.h>
1090 GIT_CONF_SUBST([NO_UINTMAX_T])
1092 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1093 GIT_CHECK_FUNC(strtoumax,
1094 [NO_STRTOUMAX=],
1095 [NO_STRTOUMAX=YesPlease])
1096 GIT_CONF_SUBST([NO_STRTOUMAX])
1098 # Define NO_SETENV if you don't have setenv in the C library.
1099 GIT_CHECK_FUNC(setenv,
1100 [NO_SETENV=],
1101 [NO_SETENV=YesPlease])
1102 GIT_CONF_SUBST([NO_SETENV])
1104 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1105 GIT_CHECK_FUNC(unsetenv,
1106 [NO_UNSETENV=],
1107 [NO_UNSETENV=YesPlease])
1108 GIT_CONF_SUBST([NO_UNSETENV])
1110 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1111 GIT_CHECK_FUNC(mkdtemp,
1112 [NO_MKDTEMP=],
1113 [NO_MKDTEMP=YesPlease])
1114 GIT_CONF_SUBST([NO_MKDTEMP])
1116 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1117 GIT_CHECK_FUNC(initgroups,
1118 [NO_INITGROUPS=],
1119 [NO_INITGROUPS=YesPlease])
1120 GIT_CONF_SUBST([NO_INITGROUPS])
1122 # Define HAVE_GETDELIM if you have getdelim in the C library.
1123 GIT_CHECK_FUNC(getdelim,
1124 [HAVE_GETDELIM=YesPlease],
1125 [HAVE_GETDELIM=])
1126 GIT_CONF_SUBST([HAVE_GETDELIM])
1129 # Define NO_MMAP if you want to avoid mmap.
1131 # Define NO_ICONV if your libc does not properly support iconv.
1133 AC_DEFUN([BSD_SYSCTL_SRC], [
1134 AC_LANG_PROGRAM([[
1135 #include <stddef.h>
1136 #include <sys/types.h>
1137 #include <sys/sysctl.h>
1138 ]],[[
1139 int val, mib[2];
1140 size_t len;
1141 mib[0] = CTL_HW;
1142 mib[1] = 1;
1143 len = sizeof(val);
1144 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1145 ]])])
1148 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1149 AC_MSG_CHECKING([for BSD sysctl])
1150 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1151         [AC_MSG_RESULT([yes])
1152         HAVE_BSD_SYSCTL=YesPlease],
1153         [AC_MSG_RESULT([no])
1154         HAVE_BSD_SYSCTL=])
1155 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1157 ## Other checks.
1158 # Define USE_PIC if you need the main git objects to be built with -fPIC
1159 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1161 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1162 # Enable it on Windows.  By default, symrefs are still used.
1164 # Define NO_PTHREADS if we do not have pthreads.
1166 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1167 AC_DEFUN([PTHREADTEST_SRC], [
1168 AC_LANG_PROGRAM([[
1169 #include <pthread.h>
1170 static void *noop(void *ignore) { return ignore; }
1171 ]], [[
1172         pthread_mutex_t test_mutex;
1173         pthread_key_t test_key;
1174         pthread_t th;
1175         int retcode = 0;
1176         void *ret = (void *)0;
1177         retcode |= pthread_key_create(&test_key, (void *)0);
1178         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1179         retcode |= pthread_mutex_lock(&test_mutex);
1180         retcode |= pthread_mutex_unlock(&test_mutex);
1181         retcode |= pthread_create(&th, ret, noop, ret);
1182         retcode |= pthread_join(th, &ret);
1183         return retcode;
1184 ]])])
1186 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1187 dnl   [[#include <pthread.h>]],
1188 dnl   [[pthread_mutex_t test_mutex;]]
1189 dnl )])
1191 NO_PTHREADS=UnfortunatelyYes
1192 PTHREAD_LIBS=
1194 if test -n "$USER_NOPTHREAD"; then
1195    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1196 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1197 # -D_REENTRANT' or some such.
1198 elif test -z "$PTHREAD_CFLAGS"; then
1199   threads_found=no
1200   # Attempt to compile and link some code using pthreads to determine
1201   # required linker flags. The order is somewhat important here: We
1202   # first try it without any extra flags, to catch systems where
1203   # pthreads are part of the C library, then go on testing various other
1204   # flags. We do so to avoid false positives. For example, on Mac OS X
1205   # pthreads are part of the C library; moreover, the compiler allows us
1206   # to add "-mt" to the CFLAGS (although it will do nothing except
1207   # trigger a warning about an unused flag). Hence if we checked for
1208   # "-mt" before "" we would end up picking it. But unfortunately this
1209   # would then trigger compiler warnings on every single file we compile.
1210   for opt in "" -mt -pthread -lpthread; do
1211      old_CFLAGS="$CFLAGS"
1212      old_LIBS="$LIBS"
1213      case "$opt" in
1214         -l*)  LIBS="$opt $LIBS" ;;
1215         *)    CFLAGS="$opt $CFLAGS" ;;
1216      esac
1218      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1219      AC_LINK_IFELSE([PTHREADTEST_SRC],
1220         [AC_MSG_RESULT([yes])
1221                 NO_PTHREADS=
1222                 PTHREAD_LIBS="$opt"
1223                 PTHREAD_CFLAGS="$opt"
1224                 threads_found=yes
1225                 break
1226         ],
1227         [AC_MSG_RESULT([no])])
1228       CFLAGS="$old_CFLAGS"
1229       LIBS="$old_LIBS"
1230   done
1231   if test $threads_found != yes; then
1232     AC_CHECK_LIB([pthread], [pthread_create],
1233         [PTHREAD_LIBS="-lpthread"],
1234         [NO_PTHREADS=UnfortunatelyYes])
1235   fi
1236 else
1237   old_CFLAGS="$CFLAGS"
1238   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1239   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1240   AC_LINK_IFELSE([PTHREADTEST_SRC],
1241         [AC_MSG_RESULT([yes])
1242                 NO_PTHREADS=
1243                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1244         ],
1245         [AC_MSG_RESULT([no])])
1247   CFLAGS="$old_CFLAGS"
1250 CFLAGS="$old_CFLAGS"
1252 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1253 GIT_CONF_SUBST([PTHREAD_LIBS])
1254 GIT_CONF_SUBST([NO_PTHREADS])
1256 ## Output files
1257 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1258 AC_OUTPUT