git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use File::Basename qw/dirname basename/;
  15 use File::Path qw/mkpath/;
  16 use File::Spec;
  17 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  18 use Memoize;
  19
  20 use Git::SVN;
  21 use Git::SVN::Editor;
  22 use Git::SVN::Fetcher;
  23 use Git::SVN::Ra;
  24 use Git::SVN::Prompt;
  25 use Git::SVN::Log;
  26 use Git::SVN::Migration;
  27
  28 use Git::SVN::Utils qw(
  29         fatal
  30         can_compress
  31         canonicalize_path
  32         canonicalize_url
  33         join_paths
  34         add_path_to_url
  35         join_paths
  36 );
  37
  38 use Git qw(
  39         git_cmd_try
  40         command
  41         command_oneline
  42         command_noisy
  43         command_output_pipe
  44         command_close_pipe
  45         command_bidi_pipe
  46         command_close_bidi_pipe
  47         get_record
  48 );
  49
  50 BEGIN {
  51         Memoize::memoize 'Git::config';
  52         Memoize::memoize 'Git::config_bool';
  53 }
  54
  55
  56 # From which subdir have we been invoked?
  57 my $cmd_dir_prefix = eval {
  58         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  59 } || '';
  60
  61 $Git::SVN::Ra::_log_window_size = 100;
  62
  63 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  64         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  65 }
  66
  67 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  68         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  69         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  70 }
  71
  72 $Git::SVN::Log::TZ = $ENV{TZ};
  73 $ENV{TZ} = 'UTC';
  74 $| = 1; # unbuffer STDOUT
  75
  76 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  77 # repository decides to close the connection which we expect to be kept alive.
  78 $SIG{PIPE} = 'IGNORE';
  79
  80 # Given a dot separated version number, "subtract" it from
  81 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  82 # is at least at the version the caller asked for.
  83 sub compare_svn_version {
  84         my (@ours) = split(/\./, $SVN::Core::VERSION);
  85         my (@theirs) = split(/\./, $_[0]);
  86         my ($i, $diff);
  87
  88         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  89                 $diff = $ours[$i] - $theirs[$i];
  90                 return $diff if ($diff);
  91         }
  92         return 1 if ($i < @ours);
  93         return -1 if ($i < @theirs);
  94         return 0;
  95 }
  96
  97 sub _req_svn {
  98         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  99         require SVN::Ra;
 100         require SVN::Delta;
 101         if (::compare_svn_version('1.1.0') < 0) {
 102                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 103         }
 104 }
 105
 106 $sha1 = qr/[a-f\d]{40}/;
 107 $sha1_short = qr/[a-f\d]{4,40}/;
 108 my ($_stdin, $_help, $_edit,
 109         $_message, $_file, $_branch_dest,
 110         $_template, $_shared,
 111         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 112         $_before, $_after,
 113         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
 114         $_prefix, $_no_checkout, $_url, $_verbose,
 115         $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
 116
 117 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 118 sub opt_prefix { return $_prefix || '' }
 119
 120 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 121 $_q ||= 0;
 122 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 123                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 124                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 125                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 126                     'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 127                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 128 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 129                 'authors-file|A=s' => \$_authors,
 130                 'authors-prog=s' => \$_authors_prog,
 131                 'repack:i' => \$Git::SVN::_repack,
 132                 'noMetadata' => \$Git::SVN::_no_metadata,
 133                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 134                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 135                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 136                 'no-checkout' => \$_no_checkout,
 137                 'quiet|q+' => \$_q,
 138                 'repack-flags|repack-args|repack-opts=s' =>
 139                    \$Git::SVN::_repack_flags,
 140                 'use-log-author' => \$Git::SVN::_use_log_author,
 141                 'add-author-from' => \$Git::SVN::_add_author_from,
 142                 'localtime' => \$Git::SVN::_localtime,
 143                 %remote_opts );
 144
 145 my ($_trunk, @_tags, @_branches, $_stdlayout);
 146 my %icv;
 147 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 148                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 149                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 150                   'stdlayout|s' => \$_stdlayout,
 151                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 152                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 153                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 154                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 155                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 156                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 157                   %remote_opts );
 158 my %cmt_opts = ( 'edit|e' => \$_edit,
 159                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 160                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 161                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 162                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 163 );
 164
 165 my %cmd = (
 166         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 167                         { 'revision|r=s' => \$_revision,
 168                           'fetch-all|all' => \$_fetch_all,
 169                           'parent|p' => \$_fetch_parent,
 170                            %fc_opts } ],
 171         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 172                         { 'revision|r=s' => \$_revision,
 173                           'preserve-empty-dirs' =>
 174                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 175                           'placeholder-filename=s' =>
 176                                 \$Git::SVN::Fetcher::_placeholder_filename,
 177                            %fc_opts, %init_opts } ],
 178         init => [ \&cmd_init, "Initialize a repo for tracking" .
 179                           " (requires URL argument)",
 180                           \%init_opts ],
 181         'multi-init' => [ \&cmd_multi_init,
 182                           "Deprecated alias for ".
 183                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 184                           \%init_opts ],
 185         dcommit => [ \&cmd_dcommit,
 186                      'Commit several diffs to merge with upstream',
 187                         { 'merge|m|M' => \$_merge,
 188                           'strategy|s=s' => \$_strategy,
 189                           'verbose|v' => \$_verbose,
 190                           'dry-run|n' => \$_dry_run,
 191                           'fetch-all|all' => \$_fetch_all,
 192                           'commit-url=s' => \$_commit_url,
 193                           'set-svn-props=s' => \$_set_svn_props,
 194                           'revision|r=i' => \$_revision,
 195                           'no-rebase' => \$_no_rebase,
 196                           'mergeinfo=s' => \$_merge_info,
 197                           'interactive|i' => \$_interactive,
 198                         %cmt_opts, %fc_opts } ],
 199         branch => [ \&cmd_branch,
 200                     'Create a branch in the SVN repository',
 201                     { 'message|m=s' => \$_message,
 202                       'destination|d=s' => \$_branch_dest,
 203                       'dry-run|n' => \$_dry_run,
 204                       'parents' => \$_parents,
 205                       'tag|t' => \$_tag,
 206                       'username=s' => \$Git::SVN::Prompt::_username,
 207                       'commit-url=s' => \$_commit_url } ],
 208         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 209                  'Create a tag in the SVN repository',
 210                  { 'message|m=s' => \$_message,
 211                    'destination|d=s' => \$_branch_dest,
 212                    'dry-run|n' => \$_dry_run,
 213                    'parents' => \$_parents,
 214                    'username=s' => \$Git::SVN::Prompt::_username,
 215                    'commit-url=s' => \$_commit_url } ],
 216         'set-tree' => [ \&cmd_set_tree,
 217                         "Set an SVN repository to a git tree-ish",
 218                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 219         'create-ignore' => [ \&cmd_create_ignore,
 220                              'Create a .gitignore per svn:ignore',
 221                              { 'revision|r=i' => \$_revision
 222                              } ],
 223         'mkdirs' => [ \&cmd_mkdirs ,
 224                       "recreate empty directories after a checkout",
 225                       { 'revision|r=i' => \$_revision } ],
 226         'propget' => [ \&cmd_propget,
 227                        'Print the value of a property on a file or directory',
 228                        { 'revision|r=i' => \$_revision } ],
 229         'propset' => [ \&cmd_propset,
 230                        'Set the value of a property on a file or directory - will be set on commit',
 231                        {} ],
 232         'proplist' => [ \&cmd_proplist,
 233                        'List all properties of a file or directory',
 234                        { 'revision|r=i' => \$_revision } ],
 235         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 236                         { 'revision|r=i' => \$_revision
 237                         } ],
 238         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 239                         { 'revision|r=i' => \$_revision
 240                         } ],
 241         'multi-fetch' => [ \&cmd_multi_fetch,
 242                            "Deprecated alias for $0 fetch --all",
 243                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 244         'migrate' => [ sub { },
 245                        # no-op, we automatically run this anyways,
 246                        'Migrate configuration/metadata/layout from
 247                         previous versions of git-svn',
 248                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 249                          %remote_opts } ],
 250         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 251                         { 'limit=i' => \$Git::SVN::Log::limit,
 252                           'revision|r=s' => \$_revision,
 253                           'verbose|v' => \$Git::SVN::Log::verbose,
 254                           'incremental' => \$Git::SVN::Log::incremental,
 255                           'oneline' => \$Git::SVN::Log::oneline,
 256                           'show-commit' => \$Git::SVN::Log::show_commit,
 257                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 258                           'authors-file|A=s' => \$_authors,
 259                           'color' => \$Git::SVN::Log::color,
 260                           'pager=s' => \$Git::SVN::Log::pager
 261                         } ],
 262         'find-rev' => [ \&cmd_find_rev,
 263                         "Translate between SVN revision numbers and tree-ish",
 264                         { 'B|before' => \$_before,
 265                           'A|after' => \$_after } ],
 266         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 267                         { 'merge|m|M' => \$_merge,
 268                           'verbose|v' => \$_verbose,
 269                           'strategy|s=s' => \$_strategy,
 270                           'local|l' => \$_local,
 271                           'fetch-all|all' => \$_fetch_all,
 272                           'dry-run|n' => \$_dry_run,
 273                           'preserve-merges|p' => \$_preserve_merges,
 274                           %fc_opts } ],
 275         'commit-diff' => [ \&cmd_commit_diff,
 276                            'Commit a diff between two trees',
 277                         { 'message|m=s' => \$_message,
 278                           'file|F=s' => \$_file,
 279                           'revision|r=s' => \$_revision,
 280                         %cmt_opts } ],
 281         'info' => [ \&cmd_info,
 282                     "Show info about the latest SVN revision
 283                      on the current branch",
 284                     { 'url' => \$_url, } ],
 285         'blame' => [ \&Git::SVN::Log::cmd_blame,
 286                     "Show what revision and author last modified each line of a file",
 287                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 288         'reset' => [ \&cmd_reset,
 289                      "Undo fetches back to the specified SVN revision",
 290                      { 'revision|r=s' => \$_revision,
 291                        'parent|p' => \$_fetch_parent } ],
 292         'gc' => [ \&cmd_gc,
 293                   "Compress unhandled.log files in .git/svn and remove " .
 294                   "index files in .git/svn",
 295                 {} ],
 296 );
 297
 298 package FakeTerm;
 299 sub new {
 300         my ($class, $reason) = @_;
 301         return bless \$reason, shift;
 302 }
 303 sub readline {
 304         my $self = shift;
 305         die "Cannot use readline on FakeTerm: $$self";
 306 }
 307 package main;
 308
 309 my $term;
 310 sub term_init {
 311         $term = eval {
 312                 require Term::ReadLine;
 313                 $ENV{"GIT_SVN_NOTTY"}
 314                         ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 315                         : new Term::ReadLine 'git-svn';
 316         };
 317         if ($@) {
 318                 $term = new FakeTerm "$@: going non-interactive";
 319         }
 320 }
 321
 322 my $cmd;
 323 for (my $i = 0; $i < @ARGV; $i++) {
 324         if (defined $cmd{$ARGV[$i]}) {
 325                 $cmd = $ARGV[$i];
 326                 splice @ARGV, $i, 1;
 327                 last;
 328         } elsif ($ARGV[$i] eq 'help') {
 329                 $cmd = $ARGV[$i+1];
 330                 usage(0);
 331         }
 332 };
 333
 334 # make sure we're always running at the top-level working directory
 335 if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 336         $ENV{GIT_DIR} ||= ".git";
 337         # catch the submodule case
 338         if (-f $ENV{GIT_DIR}) {
 339                 open(my $fh, '<', $ENV{GIT_DIR}) or
 340                         die "failed to open $ENV{GIT_DIR}: $!\n";
 341                 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
 342         }
 343 } elsif ($cmd) {
 344         my ($git_dir, $cdup);
 345         git_cmd_try {
 346                 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 347         } "Unable to find .git directory\n";
 348         git_cmd_try {
 349                 $cdup = command_oneline(qw/rev-parse --show-cdup/);
 350                 chomp $cdup if ($cdup);
 351                 $cdup = "." unless ($cdup && length $cdup);
 352         } "Already at toplevel, but $git_dir not found\n";
 353         $ENV{GIT_DIR} = $git_dir;
 354         chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 355         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 356 }
 357
 358 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 359
 360 read_git_config(\%opts) if $ENV{GIT_DIR};
 361 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 362         Getopt::Long::Configure('pass_through');
 363 }
 364 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 365                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 366                     'id|i=s' => \$Git::SVN::default_ref_id,
 367                     'svn-remote|remote|R=s' => sub {
 368                        $Git::SVN::no_reuse_existing = 1;
 369                        $Git::SVN::default_repo_id = $_[1] });
 370 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 371
 372 usage(0) if $_help;
 373 version() if $_version;
 374 usage(1) unless defined $cmd;
 375 load_authors() if $_authors;
 376 if (defined $_authors_prog) {
 377         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 378 }
 379
 380 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 381         Git::SVN::Migration::migration_check();
 382 }
 383 Git::SVN::init_vars();
 384 eval {
 385         Git::SVN::verify_remotes_sanity();
 386         $cmd{$cmd}->[0]->(@ARGV);
 387         post_fetch_checkout();
 388 };
 389 fatal $@ if $@;
 390 exit 0;
 391
 392 ####################### primary functions ######################
 393 sub usage {
 394         my $exit = shift || 0;
 395         my $fd = $exit ? \*STDERR : \*STDOUT;
 396         print $fd <<"";
 397 git-svn - bidirectional operations between a single Subversion tree and git
 398 usage: git svn <command> [options] [arguments]\n
 399
 400         print $fd "Available commands:\n" unless $cmd;
 401
 402         foreach (sort keys %cmd) {
 403                 next if $cmd && $cmd ne $_;
 404                 next if /^multi-/; # don't show deprecated commands
 405                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 406                 foreach (sort keys %{$cmd{$_}->[2]}) {
 407                         # mixed-case options are for .git/config only
 408                         next if /[A-Z]/ && /^[a-z]+$/i;
 409                         # prints out arguments as they should be passed:
 410                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 411                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 412                                                         "--$_" : "-$_" }
 413                                                 split /\|/,$_)," $x\n";
 414                 }
 415         }
 416         print $fd <<"";
 417 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 418 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 419 one git repository and want to keep them separate.  See git-svn(1) for more
 420 information.
 421
 422         exit $exit;
 423 }
 424
 425 sub version {
 426         ::_req_svn();
 427         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 428         exit 0;
 429 }
 430
 431 sub ask {
 432         my ($prompt, %arg) = @_;
 433         my $valid_re = $arg{valid_re};
 434         my $default = $arg{default};
 435         my $resp;
 436         my $i = 0;
 437         term_init() unless $term;
 438
 439         if ( !( defined($term->IN)
 440             && defined( fileno($term->IN) )
 441             && defined( $term->OUT )
 442             && defined( fileno($term->OUT) ) ) ){
 443                 return defined($default) ? $default : undef;
 444         }
 445
 446         while ($i++ < 10) {
 447                 $resp = $term->readline($prompt);
 448                 if (!defined $resp) { # EOF
 449                         print "\n";
 450                         return defined $default ? $default : undef;
 451                 }
 452                 if ($resp eq '' and defined $default) {
 453                         return $default;
 454                 }
 455                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 456                         return $resp;
 457                 }
 458         }
 459         return undef;
 460 }
 461
 462 sub do_git_init_db {
 463         unless (-d $ENV{GIT_DIR}) {
 464                 my @init_db = ('init');
 465                 push @init_db, "--template=$_template" if defined $_template;
 466                 if (defined $_shared) {
 467                         if ($_shared =~ /[a-z]/) {
 468                                 push @init_db, "--shared=$_shared";
 469                         } else {
 470                                 push @init_db, "--shared";
 471                         }
 472                 }
 473                 command_noisy(@init_db);
 474                 $_repository = Git->repository(Repository => ".git");
 475         }
 476         my $set;
 477         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 478         foreach my $i (keys %icv) {
 479                 die "'$set' and '$i' cannot both be set\n" if $set;
 480                 next unless defined $icv{$i};
 481                 command_noisy('config', "$pfx.$i", $icv{$i});
 482                 $set = $i;
 483         }
 484         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 485         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 486                 if defined $$ignore_paths_regex;
 487         my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 488         command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 489                 if defined $$include_paths_regex;
 490         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 491         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 492                 if defined $$ignore_refs_regex;
 493
 494         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 495                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 496                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 497                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 498         }
 499 }
 500
 501 sub init_subdir {
 502         my $repo_path = shift or return;
 503         mkpath([$repo_path]) unless -d $repo_path;
 504         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 505         $ENV{GIT_DIR} = '.git';
 506         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 507 }
 508
 509 sub cmd_clone {
 510         my ($url, $path) = @_;
 511         if (!$url) {
 512                 die "SVN repository location required ",
 513                     "as a command-line argument\n";
 514         } elsif (!defined $path &&
 515             (defined $_trunk || @_branches || @_tags ||
 516              defined $_stdlayout) &&
 517             $url !~ m#^[a-z\+]+://#) {
 518                 $path = $url;
 519         }
 520         $path = basename($url) if !defined $path || !length $path;
 521         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 522         cmd_init($url, $path);
 523         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 524             if $_authors;
 525         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 526 }
 527
 528 sub cmd_init {
 529         if (defined $_stdlayout) {
 530                 $_trunk = 'trunk' if (!defined $_trunk);
 531                 @_tags = 'tags' if (! @_tags);
 532                 @_branches = 'branches' if (! @_branches);
 533         }
 534         if (defined $_trunk || @_branches || @_tags) {
 535                 return cmd_multi_init(@_);
 536         }
 537         my $url = shift or die "SVN repository location required ",
 538                                "as a command-line argument\n";
 539         $url = canonicalize_url($url);
 540         init_subdir(@_);
 541         do_git_init_db();
 542
 543         if ($Git::SVN::_minimize_url eq 'unset') {
 544                 $Git::SVN::_minimize_url = 0;
 545         }
 546
 547         Git::SVN->init($url);
 548 }
 549
 550 sub cmd_fetch {
 551         if (grep /^\d+=./, @_) {
 552                 die "'<rev>=<commit>' fetch arguments are ",
 553                     "no longer supported.\n";
 554         }
 555         my ($remote) = @_;
 556         if (@_ > 1) {
 557                 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 558         }
 559         $Git::SVN::no_reuse_existing = undef;
 560         if ($_fetch_parent) {
 561                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 562                 unless ($gs) {
 563                         die "Unable to determine upstream SVN information from ",
 564                             "working tree history\n";
 565                 }
 566                 # just fetch, don't checkout.
 567                 $_no_checkout = 'true';
 568                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 569         } elsif ($_fetch_all) {
 570                 cmd_multi_fetch();
 571         } else {
 572                 $remote ||= $Git::SVN::default_repo_id;
 573                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 574         }
 575 }
 576
 577 sub cmd_set_tree {
 578         my (@commits) = @_;
 579         if ($_stdin || !@commits) {
 580                 print "Reading from stdin...\n";
 581                 @commits = ();
 582                 while (<STDIN>) {
 583                         if (/\b($sha1_short)\b/o) {
 584                                 unshift @commits, $1;
 585                         }
 586                 }
 587         }
 588         my @revs;
 589         foreach my $c (@commits) {
 590                 my @tmp = command('rev-parse',$c);
 591                 if (scalar @tmp == 1) {
 592                         push @revs, $tmp[0];
 593                 } elsif (scalar @tmp > 1) {
 594                         push @revs, reverse(command('rev-list',@tmp));
 595                 } else {
 596                         fatal "Failed to rev-parse $c";
 597                 }
 598         }
 599         my $gs = Git::SVN->new;
 600         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 601         $gs->fetch;
 602         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 603                 fatal "There are new revisions that were fetched ",
 604                       "and need to be merged (or acknowledged) ",
 605                       "before committing.\nlast rev: $r_last\n",
 606                       " current: $gs->{last_rev}";
 607         }
 608         $gs->set_tree($_) foreach @revs;
 609         print "Done committing ",scalar @revs," revisions to SVN\n";
 610         unlink $gs->{index};
 611 }
 612
 613 sub split_merge_info_range {
 614         my ($range) = @_;
 615         if ($range =~ /(\d+)-(\d+)/) {
 616                 return (int($1), int($2));
 617         } else {
 618                 return (int($range), int($range));
 619         }
 620 }
 621
 622 sub combine_ranges {
 623         my ($in) = @_;
 624
 625         my @fnums = ();
 626         my @arr = split(/,/, $in);
 627         for my $element (@arr) {
 628                 my ($start, $end) = split_merge_info_range($element);
 629                 push @fnums, $start;
 630         }
 631
 632         my @sorted = @arr [ sort {
 633                 $fnums[$a] <=> $fnums[$b]
 634         } 0..$#arr ];
 635
 636         my @return = ();
 637         my $last = -1;
 638         my $first = -1;
 639         for my $element (@sorted) {
 640                 my ($start, $end) = split_merge_info_range($element);
 641
 642                 if ($last == -1) {
 643                         $first = $start;
 644                         $last = $end;
 645                         next;
 646                 }
 647                 if ($start <= $last+1) {
 648                         if ($end > $last) {
 649                                 $last = $end;
 650                         }
 651                         next;
 652                 }
 653                 if ($first == $last) {
 654                         push @return, "$first";
 655                 } else {
 656                         push @return, "$first-$last";
 657                 }
 658                 $first = $start;
 659                 $last = $end;
 660         }
 661
 662         if ($first != -1) {
 663                 if ($first == $last) {
 664                         push @return, "$first";
 665                 } else {
 666                         push @return, "$first-$last";
 667                 }
 668         }
 669
 670         return join(',', @return);
 671 }
 672
 673 sub merge_revs_into_hash {
 674         my ($hash, $minfo) = @_;
 675         my @lines = split(' ', $minfo);
 676
 677         for my $line (@lines) {
 678                 my ($branchpath, $revs) = split(/:/, $line);
 679
 680                 if (exists($hash->{$branchpath})) {
 681                         # Merge the two revision sets
 682                         my $combined = "$hash->{$branchpath},$revs";
 683                         $hash->{$branchpath} = combine_ranges($combined);
 684                 } else {
 685                         # Just do range combining for consolidation
 686                         $hash->{$branchpath} = combine_ranges($revs);
 687                 }
 688         }
 689 }
 690
 691 sub merge_merge_info {
 692         my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 693         my %result_hash = ();
 694
 695         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 696         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 697
 698         delete $result_hash{$ignore_branch} if $ignore_branch;
 699
 700         my $result = '';
 701         # Sort below is for consistency's sake
 702         for my $branchname (sort keys(%result_hash)) {
 703                 my $revlist = $result_hash{$branchname};
 704                 $result .= "$branchname:$revlist\n"
 705         }
 706         return $result;
 707 }
 708
 709 sub populate_merge_info {
 710         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 711
 712         my %parentshash;
 713         read_commit_parents(\%parentshash, $d);
 714         my @parents = @{$parentshash{$d}};
 715         if ($#parents > 0) {
 716                 # Merge commit
 717                 my $all_parents_ok = 1;
 718                 my $aggregate_mergeinfo = '';
 719                 my $rooturl = $gs->repos_root;
 720                 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 721
 722                 if (defined($rewritten_parent)) {
 723                         # Replace first parent with newly-rewritten version
 724                         shift @parents;
 725                         unshift @parents, $rewritten_parent;
 726                 }
 727
 728                 foreach my $parent (@parents) {
 729                         my ($branchurl, $svnrev, $paruuid) =
 730                                 cmt_metadata($parent);
 731
 732                         unless (defined($svnrev)) {
 733                                 # Should have been caught be preflight check
 734                                 fatal "merge commit $d has ancestor $parent, but that change "
 735                      ."does not have git-svn metadata!";
 736                         }
 737                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 738                                 fatal "commit $parent git-svn metadata changed mid-run!";
 739                         }
 740                         my $branchpath = $1;
 741
 742                         my $ra = Git::SVN::Ra->new($branchurl);
 743                         my (undef, undef, $props) =
 744                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 745                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 746                         unless (defined $par_mergeinfo) {
 747                                 $par_mergeinfo = '';
 748                         }
 749                         # Merge previous mergeinfo values
 750                         $aggregate_mergeinfo =
 751                                 merge_merge_info($aggregate_mergeinfo,
 752                                                                 $par_mergeinfo,
 753                                                                 $target_branch);
 754
 755                         next if $parent eq $parents[0]; # Skip first parent
 756                         # Add new changes being placed in tree by merge
 757                         my @cmd = (qw/rev-list --reverse/,
 758                                            $parent, qw/--not/);
 759                         foreach my $par (@parents) {
 760                                 unless ($par eq $parent) {
 761                                         push @cmd, $par;
 762                                 }
 763                         }
 764                         my @revsin = ();
 765                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 766                         while (<$revlist>) {
 767                                 my $irev = $_;
 768                                 chomp $irev;
 769                                 my (undef, $csvnrev, undef) =
 770                                         cmt_metadata($irev);
 771                                 unless (defined $csvnrev) {
 772                                         # A child is missing SVN annotations...
 773                                         # this might be OK, or might not be.
 774                                         warn "W:child $irev is merged into revision "
 775                                                  ."$d but does not have git-svn metadata. "
 776                                                  ."This means git-svn cannot determine the "
 777                                                  ."svn revision numbers to place into the "
 778                                                  ."svn:mergeinfo property. You must ensure "
 779                                                  ."a branch is entirely committed to "
 780                                                  ."SVN before merging it in order for "
 781                                                  ."svn:mergeinfo population to function "
 782                                                  ."properly";
 783                                 }
 784                                 push @revsin, $csvnrev;
 785                         }
 786                         command_close_pipe($revlist, $ctx);
 787
 788                         last unless $all_parents_ok;
 789
 790                         # We now have a list of all SVN revnos which are
 791                         # merged by this particular parent. Integrate them.
 792                         next if $#revsin == -1;
 793                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 794                         $aggregate_mergeinfo =
 795                                 merge_merge_info($aggregate_mergeinfo,
 796                                                                 $newmergeinfo,
 797                                                                 $target_branch);
 798                 }
 799                 if ($all_parents_ok and $aggregate_mergeinfo) {
 800                         return $aggregate_mergeinfo;
 801                 }
 802         }
 803
 804         return undef;
 805 }
 806
 807 sub dcommit_rebase {
 808         my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 809         my @diff;
 810
 811         if ($svn_error) {
 812                 print STDERR "\nERROR from SVN:\n",
 813                                 $svn_error->expanded_message, "\n";
 814         }
 815         unless ($_no_rebase) {
 816                 # we always want to rebase against the current HEAD,
 817                 # not any head that was passed to us
 818                 @diff = command('diff-tree', $current,
 819                            $fetched_ref, '--');
 820                 my @finish;
 821                 if (@diff) {
 822                         @finish = rebase_cmd();
 823                         print STDERR "W: $current and ", $fetched_ref,
 824                                      " differ, using @finish:\n",
 825                                      join("\n", @diff), "\n";
 826                 } elsif ($is_last) {
 827                         print "No changes between ", $current, " and ",
 828                               $fetched_ref,
 829                               "\nResetting to the latest ",
 830                               $fetched_ref, "\n";
 831                         @finish = qw/reset --mixed/;
 832                 }
 833                 command_noisy(@finish, $fetched_ref) if @finish;
 834         }
 835         if ($svn_error) {
 836                 die "ERROR: Not all changes have been committed into SVN"
 837                         .($_no_rebase ? ".\n" : ", however the committed\n"
 838                         ."ones (if any) seem to be successfully integrated "
 839                         ."into the working tree.\n")
 840                         ."Please see the above messages for details.\n";
 841         }
 842         return @diff;
 843 }
 844
 845 sub cmd_dcommit {
 846         my $head = shift;
 847         command_noisy(qw/update-index --refresh/);
 848         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 849                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 850                 . "or stash them with `git stash'.\n";
 851         $head ||= 'HEAD';
 852
 853         my $old_head;
 854         if ($head ne 'HEAD') {
 855                 $old_head = eval {
 856                         command_oneline([qw/symbolic-ref -q HEAD/])
 857                 };
 858                 if ($old_head) {
 859                         $old_head =~ s{^refs/heads/}{};
 860                 } else {
 861                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 862                 }
 863                 command(['checkout', $head], STDERR => 0);
 864         }
 865
 866         my @refs;
 867         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 868         unless ($gs) {
 869                 die "Unable to determine upstream SVN information from ",
 870                     "$head history.\nPerhaps the repository is empty.";
 871         }
 872
 873         if (defined $_commit_url) {
 874                 $url = $_commit_url;
 875         } else {
 876                 $url = eval { command_oneline('config', '--get',
 877                               "svn-remote.$gs->{repo_id}.commiturl") };
 878                 if (!$url) {
 879                         $url = $gs->full_pushurl
 880                 }
 881         }
 882
 883         my $last_rev = $_revision if defined $_revision;
 884         if ($url) {
 885                 print "Committing to $url ...\n";
 886         }
 887         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 888         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 889                 warn "Attempting to commit more than one change while ",
 890                      "--no-rebase is enabled.\n",
 891                      "If these changes depend on each other, re-running ",
 892                      "without --no-rebase may be required."
 893         }
 894
 895         if (defined $_interactive){
 896                 my $ask_default = "y";
 897                 foreach my $d (@$linear_refs){
 898                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 899                         while (<$fh>){
 900                                 print $_;
 901                         }
 902                         command_close_pipe($fh, $ctx);
 903                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 904                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 905                                  default => $ask_default);
 906                         die "Commit this patch reply required" unless defined $_;
 907                         if (/^[nq]/i) {
 908                                 exit(0);
 909                         } elsif (/^a/i) {
 910                                 last;
 911                         }
 912                 }
 913         }
 914
 915         my $expect_url = $url;
 916
 917         my $push_merge_info = eval {
 918                 command_oneline(qw/config --get svn.pushmergeinfo/)
 919                 };
 920         if (not defined($push_merge_info)
 921                         or $push_merge_info eq "false"
 922                         or $push_merge_info eq "no"
 923                         or $push_merge_info eq "never") {
 924                 $push_merge_info = 0;
 925         }
 926
 927         unless (defined($_merge_info) || ! $push_merge_info) {
 928                 # Preflight check of changes to ensure no issues with mergeinfo
 929                 # This includes check for uncommitted-to-SVN parents
 930                 # (other than the first parent, which we will handle),
 931                 # information from different SVN repos, and paths
 932                 # which are not underneath this repository root.
 933                 my $rooturl = $gs->repos_root;
 934                 Git::SVN::remove_username($rooturl);
 935                 foreach my $d (@$linear_refs) {
 936                         my %parentshash;
 937                         read_commit_parents(\%parentshash, $d);
 938                         my @realparents = @{$parentshash{$d}};
 939                         if ($#realparents > 0) {
 940                                 # Merge commit
 941                                 shift @realparents; # Remove/ignore first parent
 942                                 foreach my $parent (@realparents) {
 943                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 944                                         unless (defined $paruuid) {
 945                                                 # A parent is missing SVN annotations...
 946                                                 # abort the whole operation.
 947                                                 fatal "$parent is merged into revision $d, "
 948                                                          ."but does not have git-svn metadata. "
 949                                                          ."Either dcommit the branch or use a "
 950                                                          ."local cherry-pick, FF merge, or rebase "
 951                                                          ."instead of an explicit merge commit.";
 952                                         }
 953
 954                                         unless ($paruuid eq $uuid) {
 955                                                 # Parent has SVN metadata from different repository
 956                                                 fatal "merge parent $parent for change $d has "
 957                                                          ."git-svn uuid $paruuid, while current change "
 958                                                          ."has uuid $uuid!";
 959                                         }
 960
 961                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 962                                                 # This branch is very strange indeed.
 963                                                 fatal "merge parent $parent for $d is on branch "
 964                                                          ."$branchurl, which is not under the "
 965                                                          ."git-svn root $rooturl!";
 966                                         }
 967                                 }
 968                         }
 969                 }
 970         }
 971
 972         my $rewritten_parent;
 973         my $current_head = command_oneline(qw/rev-parse HEAD/);
 974         Git::SVN::remove_username($expect_url);
 975         if (defined($_merge_info)) {
 976                 $_merge_info =~ tr{ }{\n};
 977         }
 978         while (1) {
 979                 my $d = shift @$linear_refs or last;
 980                 unless (defined $last_rev) {
 981                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 982                         unless (defined $last_rev) {
 983                                 fatal "Unable to extract revision information ",
 984                                       "from commit $d~1";
 985                         }
 986                 }
 987                 if ($_dry_run) {
 988                         print "diff-tree $d~1 $d\n";
 989                 } else {
 990                         my $cmt_rev;
 991
 992                         unless (defined($_merge_info) || ! $push_merge_info) {
 993                                 $_merge_info = populate_merge_info($d, $gs,
 994                                                              $uuid,
 995                                                              $linear_refs,
 996                                                              $rewritten_parent);
 997                         }
 998
 999                         my %ed_opts = ( r => $last_rev,
1000                                         log => get_commit_entry($d)->{log},
1001                                         ra => Git::SVN::Ra->new($url),
1002                                         config => SVN::Core::config_get_config(
1003                                                 $Git::SVN::Ra::config_dir
1004                                         ),
1005                                         tree_a => "$d~1",
1006                                         tree_b => $d,
1007                                         editor_cb => sub {
1008                                                print "Committed r$_[0]\n";
1009                                                $cmt_rev = $_[0];
1010                                         },
1011                                         mergeinfo => $_merge_info,
1012                                         svn_path => '');
1013
1014                         my $err_handler = $SVN::Error::handler;
1015                         $SVN::Error::handler = sub {
1016                                 my $err = shift;
1017                                 dcommit_rebase(1, $current_head, $gs->refname,
1018                                         $err);
1019                         };
1020
1021                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1022                                 print "No changes\n$d~1 == $d\n";
1023                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
1024                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1025                                                                $parents->{$d};
1026                         }
1027                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
1028                         $SVN::Error::handler = $err_handler;
1029                         $last_rev = $cmt_rev;
1030                         next if $_no_rebase;
1031
1032                         my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1033                                                 $gs->refname, undef);
1034
1035                         $rewritten_parent = command_oneline(qw/rev-parse/,
1036                                                         $gs->refname);
1037
1038                         if (@diff) {
1039                                 $current_head = command_oneline(qw/rev-parse
1040                                                                 HEAD/);
1041                                 @refs = ();
1042                                 my ($url_, $rev_, $uuid_, $gs_) =
1043                                               working_head_info('HEAD', \@refs);
1044                                 my ($linear_refs_, $parents_) =
1045                                               linearize_history($gs_, \@refs);
1046                                 if (scalar(@$linear_refs) !=
1047                                     scalar(@$linear_refs_)) {
1048                                         fatal "# of revisions changed ",
1049                                           "\nbefore:\n",
1050                                           join("\n", @$linear_refs),
1051                                           "\n\nafter:\n",
1052                                           join("\n", @$linear_refs_), "\n",
1053                                           'If you are attempting to commit ',
1054                                           "merges, try running:\n\t",
1055                                           'git rebase --interactive',
1056                                           '--preserve-merges ',
1057                                           $gs->refname,
1058                                           "\nBefore dcommitting";
1059                                 }
1060                                 if ($url_ ne $expect_url) {
1061                                         if ($url_ eq $gs->metadata_url) {
1062                                                 print
1063                                                   "Accepting rewritten URL:",
1064                                                   " $url_\n";
1065                                         } else {
1066                                                 fatal
1067                                                   "URL mismatch after rebase:",
1068                                                   " $url_ != $expect_url";
1069                                         }
1070                                 }
1071                                 if ($uuid_ ne $uuid) {
1072                                         fatal "uuid mismatch after rebase: ",
1073                                               "$uuid_ != $uuid";
1074                                 }
1075                                 # remap parents
1076                                 my (%p, @l, $i);
1077                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1078                                         my $new = $linear_refs_->[$i] or next;
1079                                         $p{$new} =
1080                                                 $parents->{$linear_refs->[$i]};
1081                                         push @l, $new;
1082                                 }
1083                                 $parents = \%p;
1084                                 $linear_refs = \@l;
1085                                 undef $last_rev;
1086                         }
1087                 }
1088         }
1089
1090         if ($old_head) {
1091                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1092                 my $new_is_symbolic = eval {
1093                         command_oneline(qw/symbolic-ref -q HEAD/);
1094                 };
1095                 if ($new_is_symbolic) {
1096                         print "dcommitted the branch ", $head, "\n";
1097                 } else {
1098                         print "dcommitted on a detached HEAD because you gave ",
1099                               "a revision argument.\n",
1100                               "The rewritten commit is: ", $new_head, "\n";
1101                 }
1102                 command(['checkout', $old_head], STDERR => 0);
1103         }
1104
1105         unlink $gs->{index};
1106 }
1107
1108 sub cmd_branch {
1109         my ($branch_name, $head) = @_;
1110
1111         unless (defined $branch_name && length $branch_name) {
1112                 die(($_tag ? "tag" : "branch") . " name required\n");
1113         }
1114         $head ||= 'HEAD';
1115
1116         my (undef, $rev, undef, $gs) = working_head_info($head);
1117         my $src = $gs->full_pushurl;
1118
1119         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1120         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1121         my $glob;
1122         if ($#{$allglobs} == 0) {
1123                 $glob = $allglobs->[0];
1124         } else {
1125                 unless(defined $_branch_dest) {
1126                         die "Multiple ",
1127                             $_tag ? "tag" : "branch",
1128                             " paths defined for Subversion repository.\n",
1129                             "You must specify where you want to create the ",
1130                             $_tag ? "tag" : "branch",
1131                             " with the --destination argument.\n";
1132                 }
1133                 foreach my $g (@{$allglobs}) {
1134                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1135                         if ($_branch_dest =~ /$re/) {
1136                                 $glob = $g;
1137                                 last;
1138                         }
1139                 }
1140                 unless (defined $glob) {
1141                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1142                         foreach my $g (@{$allglobs}) {
1143                                 $g->{path}->{left} =~ /$dest_re/ or next;
1144                                 if (defined $glob) {
1145                                         die "Ambiguous destination: ",
1146                                             $_branch_dest, "\nmatches both '",
1147                                             $glob->{path}->{left}, "' and '",
1148                                             $g->{path}->{left}, "'\n";
1149                                 }
1150                                 $glob = $g;
1151                         }
1152                         unless (defined $glob) {
1153                                 die "Unknown ",
1154                                     $_tag ? "tag" : "branch",
1155                                     " destination $_branch_dest\n";
1156                         }
1157                 }
1158         }
1159         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1160         my $url;
1161         if (defined $_commit_url) {
1162                 $url = $_commit_url;
1163         } else {
1164                 $url = eval { command_oneline('config', '--get',
1165                         "svn-remote.$gs->{repo_id}.commiturl") };
1166                 if (!$url) {
1167                         $url = $remote->{pushurl} || $remote->{url};
1168                 }
1169         }
1170         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1171
1172         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1173                 $src=~s/^http:/https:/;
1174         }
1175
1176         ::_req_svn();
1177         require SVN::Client;
1178
1179         my ($config, $baton, undef) = Git::SVN::Ra::prepare_config_once();
1180         my $ctx = SVN::Client->new(
1181                 auth => $baton,
1182                 config => $config,
1183                 log_msg => sub {
1184                         ${ $_[0] } = defined $_message
1185                                 ? $_message
1186                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1187                                 . $branch_name;
1188                 },
1189         );
1190
1191         eval {
1192                 $ctx->ls($dst, 'HEAD', 0);
1193         } and die "branch ${branch_name} already exists\n";
1194
1195         if ($_parents) {
1196                 mk_parent_dirs($ctx, $dst);
1197         }
1198
1199         print "Copying ${src} at r${rev} to ${dst}...\n";
1200         $ctx->copy($src, $rev, $dst)
1201                 unless $_dry_run;
1202
1203         $gs->fetch_all;
1204 }
1205
1206 sub mk_parent_dirs {
1207         my ($ctx, $parent) = @_;
1208         $parent =~ s{/[^/]*$}{};
1209
1210         if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1211                 mk_parent_dirs($ctx, $parent);
1212                 print "Creating parent folder ${parent} ...\n";
1213                 $ctx->mkdir($parent) unless $_dry_run;
1214         }
1215 }
1216
1217 sub cmd_find_rev {
1218         my $revision_or_hash = shift or die "SVN or git revision required ",
1219                                             "as a command-line argument\n";
1220         my $result;
1221         if ($revision_or_hash =~ /^r\d+$/) {
1222                 my $head = shift;
1223                 $head ||= 'HEAD';
1224                 my @refs;
1225                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1226                 unless ($gs) {
1227                         die "Unable to determine upstream SVN information from ",
1228                             "$head history\n";
1229                 }
1230                 my $desired_revision = substr($revision_or_hash, 1);
1231                 if ($_before) {
1232                         $result = $gs->find_rev_before($desired_revision, 1);
1233                 } elsif ($_after) {
1234                         $result = $gs->find_rev_after($desired_revision, 1);
1235                 } else {
1236                         $result = $gs->rev_map_get($desired_revision, $uuid);
1237                 }
1238         } else {
1239                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1240                 $result = $rev;
1241         }
1242         print "$result\n" if $result;
1243 }
1244
1245 sub auto_create_empty_directories {
1246         my ($gs) = @_;
1247         my $var = eval { command_oneline('config', '--get', '--bool',
1248                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1249         # By default, create empty directories by consulting the unhandled log,
1250         # but allow setting it to 'false' to skip it.
1251         return !($var && $var eq 'false');
1252 }
1253
1254 sub cmd_rebase {
1255         command_noisy(qw/update-index --refresh/);
1256         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1257         unless ($gs) {
1258                 die "Unable to determine upstream SVN information from ",
1259                     "working tree history\n";
1260         }
1261         if ($_dry_run) {
1262                 print "Remote Branch: " . $gs->refname . "\n";
1263                 print "SVN URL: " . $url . "\n";
1264                 return;
1265         }
1266         if (command(qw/diff-index HEAD --/)) {
1267                 print STDERR "Cannot rebase with uncommitted changes:\n";
1268                 command_noisy('status');
1269                 exit 1;
1270         }
1271         unless ($_local) {
1272                 # rebase will checkout for us, so no need to do it explicitly
1273                 $_no_checkout = 'true';
1274                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1275         }
1276         command_noisy(rebase_cmd(), $gs->refname);
1277         if (auto_create_empty_directories($gs)) {
1278                 $gs->mkemptydirs;
1279         }
1280 }
1281
1282 sub cmd_show_ignore {
1283         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1284         $gs ||= Git::SVN->new;
1285         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1286         $gs->prop_walk($gs->path, $r, sub {
1287                 my ($gs, $path, $props) = @_;
1288                 print STDOUT "\n# $path\n";
1289                 my $s = $props->{'svn:ignore'} or return;
1290                 $s =~ s/[\r\n]+/\n/g;
1291                 $s =~ s/^\n+//;
1292                 chomp $s;
1293                 $s =~ s#^#$path#gm;
1294                 print STDOUT "$s\n";
1295         });
1296 }
1297
1298 sub cmd_show_externals {
1299         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1300         $gs ||= Git::SVN->new;
1301         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1302         $gs->prop_walk($gs->path, $r, sub {
1303                 my ($gs, $path, $props) = @_;
1304                 print STDOUT "\n# $path\n";
1305                 my $s = $props->{'svn:externals'} or return;
1306                 $s =~ s/[\r\n]+/\n/g;
1307                 chomp $s;
1308                 $s =~ s#^#$path#gm;
1309                 print STDOUT "$s\n";
1310         });
1311 }
1312
1313 sub cmd_create_ignore {
1314         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1315         $gs ||= Git::SVN->new;
1316         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1317         $gs->prop_walk($gs->path, $r, sub {
1318                 my ($gs, $path, $props) = @_;
1319                 # $path is of the form /path/to/dir/
1320                 $path = '.' . $path;
1321                 # SVN can have attributes on empty directories,
1322                 # which git won't track
1323                 mkpath([$path]) unless -d $path;
1324                 my $ignore = $path . '.gitignore';
1325                 my $s = $props->{'svn:ignore'} or return;
1326                 open(GITIGNORE, '>', $ignore)
1327                   or fatal("Failed to open `$ignore' for writing: $!");
1328                 $s =~ s/[\r\n]+/\n/g;
1329                 $s =~ s/^\n+//;
1330                 chomp $s;
1331                 # Prefix all patterns so that the ignore doesn't apply
1332                 # to sub-directories.
1333                 $s =~ s#^#/#gm;
1334                 print GITIGNORE "$s\n";
1335                 close(GITIGNORE)
1336                   or fatal("Failed to close `$ignore': $!");
1337                 command_noisy('add', '-f', $ignore);
1338         });
1339 }
1340
1341 sub cmd_mkdirs {
1342         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1343         $gs ||= Git::SVN->new;
1344         $gs->mkemptydirs($_revision);
1345 }
1346
1347 # get_svnprops(PATH)
1348 # ------------------
1349 # Helper for cmd_propget and cmd_proplist below.
1350 sub get_svnprops {
1351         my $path = shift;
1352         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1353         $gs ||= Git::SVN->new;
1354
1355         # prefix THE PATH by the sub-directory from which the user
1356         # invoked us.
1357         $path = $cmd_dir_prefix . $path;
1358         fatal("No such file or directory: $path") unless -e $path;
1359         my $is_dir = -d $path ? 1 : 0;
1360         $path = join_paths($gs->path, $path);
1361
1362         # canonicalize the path (otherwise libsvn will abort or fail to
1363         # find the file)
1364         $path = canonicalize_path($path);
1365
1366         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1367         my $props;
1368         if ($is_dir) {
1369                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1370         }
1371         else {
1372                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1373         }
1374         return $props;
1375 }
1376
1377 # cmd_propget (PROP, PATH)
1378 # ------------------------
1379 # Print the SVN property PROP for PATH.
1380 sub cmd_propget {
1381         my ($prop, $path) = @_;
1382         $path = '.' if not defined $path;
1383         usage(1) if not defined $prop;
1384         my $props = get_svnprops($path);
1385         if (not defined $props->{$prop}) {
1386                 fatal("`$path' does not have a `$prop' SVN property.");
1387         }
1388         print $props->{$prop} . "\n";
1389 }
1390
1391 # cmd_propset (PROPNAME, PROPVAL, PATH)
1392 # ------------------------
1393 # Adjust the SVN property PROPNAME to PROPVAL for PATH.
1394 sub cmd_propset {
1395         my ($propname, $propval, $path) = @_;
1396         $path = '.' if not defined $path;
1397         $path = $cmd_dir_prefix . $path;
1398         usage(1) if not defined $propname;
1399         usage(1) if not defined $propval;
1400         my $file = basename($path);
1401         my $dn = dirname($path);
1402         my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1403         my @new_props;
1404         if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1405                 push @new_props, "$propname=$propval";
1406         } else {
1407                 # TODO: handle combining properties better
1408                 my @props = split(/;/, $cur_props);
1409                 my $replaced_prop;
1410                 foreach my $prop (@props) {
1411                         # Parse 'name=value' syntax and set the property.
1412                         if ($prop =~ /([^=]+)=(.*)/) {
1413                                 my ($n,$v) = ($1,$2);
1414                                 if ($n eq $propname) {
1415                                         $v = $propval;
1416                                         $replaced_prop = 1;
1417                                 }
1418                                 push @new_props, "$n=$v";
1419                         }
1420                 }
1421                 if (!$replaced_prop) {
1422                         push @new_props, "$propname=$propval";
1423                 }
1424         }
1425         my $attrfile = "$dn/.gitattributes";
1426         open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1427         # TODO: don't simply append here if $file already has svn-properties
1428         my $new_props = join(';', @new_props);
1429         print $attrfh "$file svn-properties=$new_props\n" or
1430                 die "write to $attrfile: $!\n";
1431         close $attrfh or die "close $attrfile: $!\n";
1432 }
1433
1434 # cmd_proplist (PATH)
1435 # -------------------
1436 # Print the list of SVN properties for PATH.
1437 sub cmd_proplist {
1438         my $path = shift;
1439         $path = '.' if not defined $path;
1440         my $props = get_svnprops($path);
1441         print "Properties on '$path':\n";
1442         foreach (sort keys %{$props}) {
1443                 print "  $_\n";
1444         }
1445 }
1446
1447 sub cmd_multi_init {
1448         my $url = shift;
1449         unless (defined $_trunk || @_branches || @_tags) {
1450                 usage(1);
1451         }
1452
1453         $_prefix = 'origin/' unless defined $_prefix;
1454         if (defined $url) {
1455                 $url = canonicalize_url($url);
1456                 init_subdir(@_);
1457         }
1458         do_git_init_db();
1459         if (defined $_trunk) {
1460                 $_trunk =~ s#^/+##;
1461                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1462                 # try both old-style and new-style lookups:
1463                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1464                 unless ($gs_trunk) {
1465                         my ($trunk_url, $trunk_path) =
1466                                               complete_svn_url($url, $_trunk);
1467                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1468                                                    undef, $trunk_ref);
1469                 }
1470         }
1471         return unless @_branches || @_tags;
1472         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1473         foreach my $path (@_branches) {
1474                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1475         }
1476         foreach my $path (@_tags) {
1477                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1478         }
1479 }
1480
1481 sub cmd_multi_fetch {
1482         $Git::SVN::no_reuse_existing = undef;
1483         my $remotes = Git::SVN::read_all_remotes();
1484         foreach my $repo_id (sort keys %$remotes) {
1485                 if ($remotes->{$repo_id}->{url}) {
1486                         Git::SVN::fetch_all($repo_id, $remotes);
1487                 }
1488         }
1489 }
1490
1491 # this command is special because it requires no metadata
1492 sub cmd_commit_diff {
1493         my ($ta, $tb, $url) = @_;
1494         my $usage = "usage: $0 commit-diff -r<revision> ".
1495                     "<tree-ish> <tree-ish> [<URL>]";
1496         fatal($usage) if (!defined $ta || !defined $tb);
1497         my $svn_path = '';
1498         if (!defined $url) {
1499                 my $gs = eval { Git::SVN->new };
1500                 if (!$gs) {
1501                         fatal("Needed URL or usable git-svn --id in ",
1502                               "the command-line\n", $usage);
1503                 }
1504                 $url = $gs->url;
1505                 $svn_path = $gs->path;
1506         }
1507         unless (defined $_revision) {
1508                 fatal("-r|--revision is a required argument\n", $usage);
1509         }
1510         if (defined $_message && defined $_file) {
1511                 fatal("Both --message/-m and --file/-F specified ",
1512                       "for the commit message.\n",
1513                       "I have no idea what you mean");
1514         }
1515         if (defined $_file) {
1516                 $_message = file_to_s($_file);
1517         } else {
1518                 $_message ||= get_commit_entry($tb)->{log};
1519         }
1520         my $ra ||= Git::SVN::Ra->new($url);
1521         my $r = $_revision;
1522         if ($r eq 'HEAD') {
1523                 $r = $ra->get_latest_revnum;
1524         } elsif ($r !~ /^\d+$/) {
1525                 die "revision argument: $r not understood by git-svn\n";
1526         }
1527         my %ed_opts = ( r => $r,
1528                         log => $_message,
1529                         ra => $ra,
1530                         tree_a => $ta,
1531                         tree_b => $tb,
1532                         editor_cb => sub { print "Committed r$_[0]\n" },
1533                         svn_path => $svn_path );
1534         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1535                 print "No changes\n$ta == $tb\n";
1536         }
1537 }
1538
1539 sub cmd_info {
1540         my $path_arg = defined($_[0]) ? $_[0] : '.';
1541         my $path = $path_arg;
1542         if (File::Spec->file_name_is_absolute($path)) {
1543                 $path = canonicalize_path($path);
1544
1545                 my $toplevel = eval {
1546                         my @cmd = qw/rev-parse --show-toplevel/;
1547                         command_oneline(\@cmd, STDERR => 0);
1548                 };
1549
1550                 # remove $toplevel from the absolute path:
1551                 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1552                 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1553                 my @dirs = File::Spec->splitdir($dirs);
1554                 my @tdirs = File::Spec->splitdir($tdirs);
1555                 pop @dirs if $dirs[-1] eq '';
1556                 pop @tdirs if $tdirs[-1] eq '';
1557                 push @dirs, $file;
1558                 push @tdirs, $tfile;
1559                 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1560                         shift @dirs;
1561                         shift @tdirs;
1562                 }
1563                 $dirs = File::Spec->catdir(@dirs);
1564                 $path = File::Spec->catpath($vol, $dirs);
1565
1566                 $path = canonicalize_path($path);
1567         } else {
1568                 $path = canonicalize_path($cmd_dir_prefix . $path);
1569         }
1570         if (exists $_[1]) {
1571                 die "Too many arguments specified\n";
1572         }
1573
1574         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1575
1576         if (!$file_type && !$diff_status) {
1577                 print STDERR "svn: '$path' is not under version control\n";
1578                 exit 1;
1579         }
1580
1581         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1582         unless ($gs) {
1583                 die "Unable to determine upstream SVN information from ",
1584                     "working tree history\n";
1585         }
1586
1587         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1588         $path = "." if $path eq "";
1589
1590         my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1591
1592         if ($_url) {
1593                 print "$full_url\n";
1594                 return;
1595         }
1596
1597         my $result = "Path: $path_arg\n";
1598         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1599         $result .= "URL: $full_url\n";
1600
1601         eval {
1602                 my $repos_root = $gs->repos_root;
1603                 Git::SVN::remove_username($repos_root);
1604                 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1605         };
1606         if ($@) {
1607                 $result .= "Repository Root: (offline)\n";
1608         }
1609         ::_req_svn();
1610         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1611                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1612         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1613
1614         $result .= "Node Kind: " .
1615                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1616
1617         my $schedule = $diff_status eq "A"
1618                        ? "add"
1619                        : ($diff_status eq "D" ? "delete" : "normal");
1620         $result .= "Schedule: $schedule\n";
1621
1622         if ($diff_status eq "A") {
1623                 print $result, "\n";
1624                 return;
1625         }
1626
1627         my ($lc_author, $lc_rev, $lc_date_utc);
1628         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1629         my $log = command_output_pipe(@args);
1630         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1631         while (<$log>) {
1632                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1633                         $lc_author = $1;
1634                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1635                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1636                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1637                 }
1638         }
1639         close $log;
1640
1641         Git::SVN::Log::set_local_timezone();
1642
1643         $result .= "Last Changed Author: $lc_author\n";
1644         $result .= "Last Changed Rev: $lc_rev\n";
1645         $result .= "Last Changed Date: " .
1646                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1647
1648         if ($file_type ne "dir") {
1649                 my $text_last_updated_date =
1650                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1651                 $result .=
1652                     "Text Last Updated: " .
1653                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1654                     "\n";
1655                 my $checksum;
1656                 if ($diff_status eq "D") {
1657                         my ($fh, $ctx) =
1658                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1659                         if ($file_type eq "link") {
1660                                 my $file_name = <$fh>;
1661                                 $checksum = md5sum("link $file_name");
1662                         } else {
1663                                 $checksum = md5sum($fh);
1664                         }
1665                         command_close_pipe($fh, $ctx);
1666                 } elsif ($file_type eq "link") {
1667                         my $file_name =
1668                             command(qw(cat-file blob), "HEAD:$path");
1669                         $checksum =
1670                             md5sum("link " . $file_name);
1671                 } else {
1672                         open FILE, "<", $path or die $!;
1673                         $checksum = md5sum(\*FILE);
1674                         close FILE or die $!;
1675                 }
1676                 $result .= "Checksum: " . $checksum . "\n";
1677         }
1678
1679         print $result, "\n";
1680 }
1681
1682 sub cmd_reset {
1683         my $target = shift || $_revision or die "SVN revision required\n";
1684         $target = $1 if $target =~ /^r(\d+)$/;
1685         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1686         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1687         unless ($gs) {
1688                 die "Unable to determine upstream SVN information from ".
1689                     "history\n";
1690         }
1691         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1692         die "Cannot find SVN revision $target\n" unless defined($c);
1693         $gs->rev_map_set($r, $c, 'reset', $uuid);
1694         print "r$r = $c ($gs->{ref_id})\n";
1695 }
1696
1697 sub cmd_gc {
1698         require File::Find;
1699         if (!can_compress()) {
1700                 warn "Compress::Zlib could not be found; unhandled.log " .
1701                      "files will not be compressed.\n";
1702         }
1703         File::Find::find({ wanted => \&gc_directory, no_chdir => 1},
1704                          Git::SVN::svn_dir());
1705 }
1706
1707 ########################### utility functions #########################
1708
1709 sub rebase_cmd {
1710         my @cmd = qw/rebase/;
1711         push @cmd, '-v' if $_verbose;
1712         push @cmd, qw/--merge/ if $_merge;
1713         push @cmd, "--strategy=$_strategy" if $_strategy;
1714         push @cmd, "--preserve-merges" if $_preserve_merges;
1715         @cmd;
1716 }
1717
1718 sub post_fetch_checkout {
1719         return if $_no_checkout;
1720         return if verify_ref('HEAD^0');
1721         my $gs = $Git::SVN::_head or return;
1722
1723         # look for "trunk" ref if it exists
1724         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1725         my $fetch = $remote->{fetch};
1726         if ($fetch) {
1727                 foreach my $p (keys %$fetch) {
1728                         basename($fetch->{$p}) eq 'trunk' or next;
1729                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1730                         last;
1731                 }
1732         }
1733
1734         command_noisy(qw(update-ref HEAD), $gs->refname);
1735         return unless verify_ref('HEAD^0');
1736
1737         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1738         my $index = command_oneline(qw(rev-parse --git-path index));
1739         return if -f $index;
1740
1741         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1742         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1743         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1744         print STDERR "Checked out HEAD:\n  ",
1745                      $gs->full_url, " r", $gs->last_rev, "\n";
1746         if (auto_create_empty_directories($gs)) {
1747                 $gs->mkemptydirs($gs->last_rev);
1748         }
1749 }
1750
1751 sub complete_svn_url {
1752         my ($url, $path) = @_;
1753
1754         if ($path =~ m#^[a-z\+]+://#i) { # path is a URL
1755                 $path = canonicalize_url($path);
1756         } else {
1757                 $path = canonicalize_path($path);
1758                 if (!defined $url || $url !~ m#^[a-z\+]+://#i) {
1759                         fatal("E: '$path' is not a complete URL ",
1760                               "and a separate URL is not specified");
1761                 }
1762                 return ($url, $path);
1763         }
1764         return ($path, '');
1765 }
1766
1767 sub complete_url_ls_init {
1768         my ($ra, $repo_path, $switch, $pfx) = @_;
1769         unless ($repo_path) {
1770                 print STDERR "W: $switch not specified\n";
1771                 return;
1772         }
1773         if ($repo_path =~ m#^[a-z\+]+://#i) {
1774                 $repo_path = canonicalize_url($repo_path);
1775                 $ra = Git::SVN::Ra->new($repo_path);
1776                 $repo_path = '';
1777         } else {
1778                 $repo_path = canonicalize_path($repo_path);
1779                 $repo_path =~ s#^/+##;
1780                 unless ($ra) {
1781                         fatal("E: '$repo_path' is not a complete URL ",
1782                               "and a separate URL is not specified");
1783                 }
1784         }
1785         my $url = $ra->url;
1786         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1787         my $k = "svn-remote.$gs->{repo_id}.url";
1788         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1789         if ($orig_url && ($orig_url ne $gs->url)) {
1790                 die "$k already set: $orig_url\n",
1791                     "wanted to set to: $gs->url\n";
1792         }
1793         command_oneline('config', $k, $gs->url) unless $orig_url;
1794
1795         my $remote_path = join_paths( $gs->path, $repo_path );
1796         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1797         $remote_path =~ s#^/##g;
1798         $remote_path .= "/*" if $remote_path !~ /\*/;
1799         my ($n) = ($switch =~ /^--(\w+)/);
1800         if (length $pfx && $pfx !~ m#/$#) {
1801                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1802         }
1803         command_noisy('config',
1804                       '--add',
1805                       "svn-remote.$gs->{repo_id}.$n",
1806                       "$remote_path:refs/remotes/$pfx*" .
1807                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1808 }
1809
1810 sub verify_ref {
1811         my ($ref) = @_;
1812         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1813                                { STDERR => 0 }); };
1814 }
1815
1816 sub get_tree_from_treeish {
1817         my ($treeish) = @_;
1818         # $treeish can be a symbolic ref, too:
1819         my $type = command_oneline(qw/cat-file -t/, $treeish);
1820         my $expected;
1821         while ($type eq 'tag') {
1822                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1823         }
1824         if ($type eq 'commit') {
1825                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1826                                                     $treeish))[0];
1827                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1828                 die "Unable to get tree from $treeish\n" unless $expected;
1829         } elsif ($type eq 'tree') {
1830                 $expected = $treeish;
1831         } else {
1832                 die "$treeish is a $type, expected tree, tag or commit\n";
1833         }
1834         return $expected;
1835 }
1836
1837 sub get_commit_entry {
1838         my ($treeish) = shift;
1839         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1840         my @git_path = qw(rev-parse --git-path);
1841         my $commit_editmsg = command_oneline(@git_path, 'COMMIT_EDITMSG');
1842         my $commit_msg = command_oneline(@git_path, 'COMMIT_MSG');
1843         open my $log_fh, '>', $commit_editmsg or croak $!;
1844
1845         my $type = command_oneline(qw/cat-file -t/, $treeish);
1846         if ($type eq 'commit' || $type eq 'tag') {
1847                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1848                                                          $type, $treeish);
1849                 my $in_msg = 0;
1850                 my $author;
1851                 my $saw_from = 0;
1852                 my $msgbuf = "";
1853                 while (<$msg_fh>) {
1854                         if (!$in_msg) {
1855                                 $in_msg = 1 if (/^$/);
1856                                 $author = $1 if (/^author (.*>)/);
1857                         } elsif (/^git-svn-id: /) {
1858                                 # skip this for now, we regenerate the
1859                                 # correct one on re-fetch anyways
1860                                 # TODO: set *:merge properties or like...
1861                         } else {
1862                                 if (/^From:/ || /^Signed-off-by:/) {
1863                                         $saw_from = 1;
1864                                 }
1865                                 $msgbuf .= $_;
1866                         }
1867                 }
1868                 $msgbuf =~ s/\s+$//s;
1869                 $msgbuf =~ s/\r\n/\n/sg; # SVN 1.6+ disallows CRLF
1870                 if ($Git::SVN::_add_author_from && defined($author)
1871                     && !$saw_from) {
1872                         $msgbuf .= "\n\nFrom: $author";
1873                 }
1874                 print $log_fh $msgbuf or croak $!;
1875                 command_close_pipe($msg_fh, $ctx);
1876         }
1877         close $log_fh or croak $!;
1878
1879         if ($_edit || ($type eq 'tree')) {
1880                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1881                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1882         }
1883         rename $commit_editmsg, $commit_msg or croak $!;
1884         {
1885                 require Encode;
1886                 # SVN requires messages to be UTF-8 when entering the repo
1887                 open $log_fh, '<', $commit_msg or croak $!;
1888                 binmode $log_fh;
1889                 chomp($log_entry{log} = get_record($log_fh, undef));
1890
1891                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1892                 my $msg = $log_entry{log};
1893
1894                 eval { $msg = Encode::decode($enc, $msg, 1) };
1895                 if ($@) {
1896                         die "Could not decode as $enc:\n", $msg,
1897                             "\nPerhaps you need to set i18n.commitencoding\n";
1898                 }
1899
1900                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1901                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1902
1903                 $log_entry{log} = $msg;
1904
1905                 close $log_fh or croak $!;
1906         }
1907         unlink $commit_msg;
1908         \%log_entry;
1909 }
1910
1911 sub s_to_file {
1912         my ($str, $file, $mode) = @_;
1913         open my $fd,'>',$file or croak $!;
1914         print $fd $str,"\n" or croak $!;
1915         close $fd or croak $!;
1916         chmod ($mode &~ umask, $file) if (defined $mode);
1917 }
1918
1919 sub file_to_s {
1920         my $file = shift;
1921         open my $fd,'<',$file or croak "$!: file: $file\n";
1922         local $/;
1923         my $ret = <$fd>;
1924         close $fd or croak $!;
1925         $ret =~ s/\s*$//s;
1926         return $ret;
1927 }
1928
1929 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1930 sub load_authors {
1931         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1932         my $log = $cmd eq 'log';
1933         while (<$authors>) {
1934                 chomp;
1935                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.*)>\s*$/;
1936                 my ($user, $name, $email) = ($1, $2, $3);
1937                 if ($log) {
1938                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1939                 } else {
1940                         $users{$user} = [$name, $email];
1941                 }
1942         }
1943         close $authors or croak $!;
1944 }
1945
1946 # convert GetOpt::Long specs for use by git-config
1947 sub read_git_config {
1948         my $opts = shift;
1949         my @config_only;
1950         foreach my $o (keys %$opts) {
1951                 # if we have mixedCase and a long option-only, then
1952                 # it's a config-only variable that we don't need for
1953                 # the command-line.
1954                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1955                 my $v = $opts->{$o};
1956                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1957                 $key =~ s/-//g;
1958                 my $arg = 'git config';
1959                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1960                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1961                 if (ref $v eq 'ARRAY') {
1962                         chomp(my @tmp = `$arg --get-all svn.$key`);
1963                         @$v = @tmp if @tmp;
1964                 } else {
1965                         chomp(my $tmp = `$arg --get svn.$key`);
1966                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1967                                 $$v = $tmp;
1968                         }
1969                 }
1970         }
1971         delete @$opts{@config_only} if @config_only;
1972 }
1973
1974 sub extract_metadata {
1975         my $id = shift or return (undef, undef, undef);
1976         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1977                                                         \s([a-f\d\-]+)$/ix);
1978         if (!defined $rev || !$uuid || !$url) {
1979                 # some of the original repositories I made had
1980                 # identifiers like this:
1981                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1982         }
1983         return ($url, $rev, $uuid);
1984 }
1985
1986 sub cmt_metadata {
1987         return extract_metadata((grep(/^git-svn-id: /,
1988                 command(qw/cat-file commit/, shift)))[-1]);
1989 }
1990
1991 sub cmt_sha2rev_batch {
1992         my %s2r;
1993         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1994         my $list = shift;
1995
1996         foreach my $sha (@{$list}) {
1997                 my $first = 1;
1998                 my $size = 0;
1999                 print $out $sha, "\n";
2000
2001                 while (my $line = <$in>) {
2002                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
2003                                 last;
2004                         } elsif ($first &&
2005                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
2006                                 $first = 0;
2007                                 $size = $1;
2008                                 next;
2009                         } elsif ($line =~ /^(git-svn-id: )/) {
2010                                 my (undef, $rev, undef) =
2011                                                       extract_metadata($line);
2012                                 $s2r{$sha} = $rev;
2013                         }
2014
2015                         $size -= length($line);
2016                         last if ($size == 0);
2017                 }
2018         }
2019
2020         command_close_bidi_pipe($pid, $in, $out, $ctx);
2021
2022         return \%s2r;
2023 }
2024
2025 sub working_head_info {
2026         my ($head, $refs) = @_;
2027         my @args = qw/rev-list --first-parent --pretty=medium/;
2028         my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2029         my $hash;
2030         my %max;
2031         while (<$fh>) {
2032                 if ( m{^commit ($::sha1)$} ) {
2033                         unshift @$refs, $hash if $hash and $refs;
2034                         $hash = $1;
2035                         next;
2036                 }
2037                 next unless s{^\s*(git-svn-id:)}{$1};
2038                 my ($url, $rev, $uuid) = extract_metadata($_);
2039                 if (defined $url && defined $rev) {
2040                         next if $max{$url} and $max{$url} < $rev;
2041                         if (my $gs = Git::SVN->find_by_url($url)) {
2042                                 my $c = $gs->rev_map_get($rev, $uuid);
2043                                 if ($c && $c eq $hash) {
2044                                         close $fh; # break the pipe
2045                                         return ($url, $rev, $uuid, $gs);
2046                                 } else {
2047                                         $max{$url} ||= $gs->rev_map_max;
2048                                 }
2049                         }
2050                 }
2051         }
2052         command_close_pipe($fh, $ctx);
2053         (undef, undef, undef, undef);
2054 }
2055
2056 sub read_commit_parents {
2057         my ($parents, $c) = @_;
2058         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2059         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2060         @{$parents->{$c}} = split(/ /, $p);
2061 }
2062
2063 sub linearize_history {
2064         my ($gs, $refs) = @_;
2065         my %parents;
2066         foreach my $c (@$refs) {
2067                 read_commit_parents(\%parents, $c);
2068         }
2069
2070         my @linear_refs;
2071         my %skip = ();
2072         my $last_svn_commit = $gs->last_commit;
2073         foreach my $c (reverse @$refs) {
2074                 next if $c eq $last_svn_commit;
2075                 last if $skip{$c};
2076
2077                 unshift @linear_refs, $c;
2078                 $skip{$c} = 1;
2079
2080                 # we only want the first parent to diff against for linear
2081                 # history, we save the rest to inject when we finalize the
2082                 # svn commit
2083                 my $fp_a = verify_ref("$c~1");
2084                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2085                 if (!$fp_a || !$fp_b) {
2086                         die "Commit $c\n",
2087                             "has no parent commit, and therefore ",
2088                             "nothing to diff against.\n",
2089                             "You should be working from a repository ",
2090                             "originally created by git-svn\n";
2091                 }
2092                 if ($fp_a ne $fp_b) {
2093                         die "$c~1 = $fp_a, however parsing commit $c ",
2094                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2095                 }
2096
2097                 foreach my $p (@{$parents{$c}}) {
2098                         $skip{$p} = 1;
2099                 }
2100         }
2101         (\@linear_refs, \%parents);
2102 }
2103
2104 sub find_file_type_and_diff_status {
2105         my ($path) = @_;
2106         return ('dir', '') if $path eq '';
2107
2108         my $diff_output =
2109             command_oneline(qw(diff --cached --name-status --), $path) || "";
2110         my $diff_status = (split(' ', $diff_output))[0] || "";
2111
2112         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2113
2114         return (undef, undef) if !$diff_status && !$ls_tree;
2115
2116         if ($diff_status eq "A") {
2117                 return ("link", $diff_status) if -l $path;
2118                 return ("dir", $diff_status) if -d $path;
2119                 return ("file", $diff_status);
2120         }
2121
2122         my $mode = (split(' ', $ls_tree))[0] || "";
2123
2124         return ("link", $diff_status) if $mode eq "120000";
2125         return ("dir", $diff_status) if $mode eq "040000";
2126         return ("file", $diff_status);
2127 }
2128
2129 sub md5sum {
2130         my $arg = shift;
2131         my $ref = ref $arg;
2132         require Digest::MD5;
2133         my $md5 = Digest::MD5->new();
2134         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2135                 $md5->addfile($arg) or croak $!;
2136         } elsif ($ref eq 'SCALAR') {
2137                 $md5->add($$arg) or croak $!;
2138         } elsif (!$ref) {
2139                 $md5->add($arg) or croak $!;
2140         } else {
2141                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2142         }
2143         return $md5->hexdigest();
2144 }
2145
2146 sub gc_directory {
2147         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2148                 my $out_filename = $_ . ".gz";
2149                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2150                 binmode $in_fh;
2151                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2152                                 die "Unable to open $out_filename: $!\n";
2153
2154                 my $res;
2155                 while ($res = sysread($in_fh, my $str, 1024)) {
2156                         $gz->gzwrite($str) or
2157                                 die "Unable to write: ".$gz->gzerror()."!\n";
2158                 }
2159                 no warnings 'once'; # $File::Find::name would warn
2160                 unlink $_ or die "unlink $File::Find::name: $!\n";
2161         } elsif (-f $_ && basename($_) eq "index") {
2162                 unlink $_ or die "unlink $_: $!\n";
2163         }
2164 }
2165
2166 __END__
2167
2168 Data structures:
2169
2170
2171 $remotes = { # returned by read_all_remotes()
2172         'svn' => {
2173                 # svn-remote.svn.url=https://svn.musicpd.org
2174                 url => 'https://svn.musicpd.org',
2175                 # svn-remote.svn.fetch=mpd/trunk:trunk
2176                 fetch => {
2177                         'mpd/trunk' => 'trunk',
2178                 },
2179                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2180                 tags => {
2181                         path => {
2182                                 left => 'mpd/tags',
2183                                 right => '',
2184                                 regex => qr!mpd/tags/([^/]+)$!,
2185                                 glob => 'tags/*',
2186                         },
2187                         ref => {
2188                                 left => 'tags',
2189                                 right => '',
2190                                 regex => qr!tags/([^/]+)$!,
2191                                 glob => 'tags/*',
2192                         },
2193                 }
2194         }
2195 };
2196
2197 $log_entry hashref as returned by libsvn_log_entry()
2198 {
2199         log => 'whitespace-formatted log entry
2200 ',                                              # trailing newline is preserved
2201         revision => '8',                        # integer
2202         date => '2004-02-24T17:01:44.108345Z',  # commit date
2203         author => 'committer name'
2204 };
2205
2206
2207 # this is generated by generate_diff();
2208 @mods = array of diff-index line hashes, each element represents one line
2209         of diff-index output
2210
2211 diff-index line ($m hash)
2212 {
2213         mode_a => first column of diff-index output, no leading ':',
2214         mode_b => second column of diff-index output,
2215         sha1_b => sha1sum of the final blob,
2216         chg => change type [MCRADT],
2217         file_a => original file name of a file (iff chg is 'C' or 'R')
2218         file_b => new/current file name of a file (any chg)
2219 }
2220 ;
2221
2222 # retval of read_url_paths{,_all}();
2223 $l_map = {
2224         # repository root url
2225         'https://svn.musicpd.org' => {
2226                 # repository path               # GIT_SVN_ID
2227                 'mpd/trunk'             =>      'trunk',
2228                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2229         },
2230 }
2231
2232 Notes:
2233         I don't trust the each() function on unless I created %hash myself
2234         because the internal iterator may not have started at base.