git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --[no-]to               <str>  * Email To:
  51     --[no-]cc               <str>  * Email Cc:
  52     --[no-]bcc              <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  58
  59   Sending:
  60     --envelope-sender       <str>  * Email envelope sender.
  61     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  62                                      is optional. Default 'localhost'.
  63     --smtp-server-port      <int>  * Outgoing SMTP server port.
  64     --smtp-user             <str>  * Username for SMTP-AUTH.
  65     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  66     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  67     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  68     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  69     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  70
  71   Automating:
  72     --identity              <str>  * Use the sendemail.<id> options.
  73     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  74     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  75     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  76     --[no-]suppress-from           * Send to self. Default off.
  77     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  78     --[no-]thread                  * Use In-Reply-To: field. Default on.
  79
  80   Administering:
  81     --confirm               <str>  * Confirm recipients before sending;
  82                                      auto, cc, compose, always, or never.
  83     --quiet                        * Output one line of info per email.
  84     --dry-run                      * Don't actually send the emails.
  85     --[no-]validate                * Perform patch sanity checks. Default on.
  86     --[no-]format-patch            * understand any non optional arguments as
  87                                      `git format-patch` ones.
  88
  89 EOT
  90         exit(1);
  91 }
  92
  93 # most mail servers generate the Date: header, but not all...
  94 sub format_2822_time {
  95         my ($time) = @_;
  96         my @localtm = localtime($time);
  97         my @gmttm = gmtime($time);
  98         my $localmin = $localtm[1] + $localtm[2] * 60;
  99         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 100         if ($localtm[0] != $gmttm[0]) {
 101                 die "local zone differs from GMT by a non-minute interval\n";
 102         }
 103         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 104                 $localmin += 1440;
 105         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 106                 $localmin -= 1440;
 107         } elsif ($gmttm[6] != $localtm[6]) {
 108                 die "local time offset greater than or equal to 24 hours\n";
 109         }
 110         my $offset = $localmin - $gmtmin;
 111         my $offhour = $offset / 60;
 112         my $offmin = abs($offset % 60);
 113         if (abs($offhour) >= 24) {
 114                 die ("local time offset greater than or equal to 24 hours\n");
 115         }
 116
 117         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 118                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 119                        $localtm[3],
 120                        qw(Jan Feb Mar Apr May Jun
 121                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 122                        $localtm[5]+1900,
 123                        $localtm[2],
 124                        $localtm[1],
 125                        $localtm[0],
 126                        ($offset >= 0) ? '+' : '-',
 127                        abs($offhour),
 128                        $offmin,
 129                        );
 130 }
 131
 132 my $have_email_valid = eval { require Email::Valid; 1 };
 133 my $have_mail_address = eval { require Mail::Address; 1 };
 134 my $smtp;
 135 my $auth;
 136
 137 sub unique_email_list(@);
 138 sub cleanup_compose_files();
 139
 140 # Variables we fill in automatically, or via prompting:
 141 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 142         $initial_reply_to,$initial_subject,@files,
 143         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 144
 145 my $envelope_sender;
 146
 147 # Example reply to:
 148 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 149
 150 my $repo = eval { Git->repository() };
 151 my @repo = $repo ? ($repo) : ();
 152 my $term = eval {
 153         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 154                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 155                 : new Term::ReadLine 'git-send-email';
 156 };
 157 if ($@) {
 158         $term = new FakeTerm "$@: going non-interactive";
 159 }
 160
 161 # Behavior modification variables
 162 my ($quiet, $dry_run) = (0, 0);
 163 my $format_patch;
 164 my $compose_filename;
 165
 166 # Handle interactive edition of files.
 167 my $multiedit;
 168 my $editor;
 169
 170 sub do_edit {
 171         if (!defined($editor)) {
 172                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 173         }
 174         if (defined($multiedit) && !$multiedit) {
 175                 map {
 176                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 177                         if (($? & 127) || ($? >> 8)) {
 178                                 die("the editor exited uncleanly, aborting everything");
 179                         }
 180                 } @_;
 181         } else {
 182                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 183                 if (($? & 127) || ($? >> 8)) {
 184                         die("the editor exited uncleanly, aborting everything");
 185                 }
 186         }
 187 }
 188
 189 # Variables with corresponding config settings
 190 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 191 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 192 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts, $smtp_domain);
 193 my ($validate, $confirm);
 194 my (@suppress_cc);
 195 my ($auto_8bit_encoding);
 196
 197 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 198
 199 my $not_set_by_user = "true but not set by the user";
 200
 201 my %config_bool_settings = (
 202     "thread" => [\$thread, 1],
 203     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 204     "suppressfrom" => [\$suppress_from, undef],
 205     "signedoffbycc" => [\$signed_off_by_cc, undef],
 206     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 207     "validate" => [\$validate, 1],
 208 );
 209
 210 my %config_settings = (
 211     "smtpserver" => \$smtp_server,
 212     "smtpserverport" => \$smtp_server_port,
 213     "smtpuser" => \$smtp_authuser,
 214     "smtppass" => \$smtp_authpass,
 215         "smtpdomain" => \$smtp_domain,
 216     "to" => \@initial_to,
 217     "cc" => \@initial_cc,
 218     "cccmd" => \$cc_cmd,
 219     "aliasfiletype" => \$aliasfiletype,
 220     "bcc" => \@bcclist,
 221     "aliasesfile" => \@alias_files,
 222     "suppresscc" => \@suppress_cc,
 223     "envelopesender" => \$envelope_sender,
 224     "multiedit" => \$multiedit,
 225     "confirm"   => \$confirm,
 226     "from" => \$sender,
 227     "assume8bitencoding" => \$auto_8bit_encoding,
 228 );
 229
 230 # Help users prepare for 1.7.0
 231 sub chain_reply_to {
 232         if (defined $chain_reply_to &&
 233             $chain_reply_to eq $not_set_by_user) {
 234                 print STDERR
 235                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 236                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 237                     "you want to keep --chain-reply-to as your default.\n";
 238                 $chain_reply_to = 0;
 239         }
 240         return $chain_reply_to;
 241 }
 242
 243 # Handle Uncouth Termination
 244 sub signal_handler {
 245
 246         # Make text normal
 247         print color("reset"), "\n";
 248
 249         # SMTP password masked
 250         system "stty echo";
 251
 252         # tmp files from --compose
 253         if (defined $compose_filename) {
 254                 if (-e $compose_filename) {
 255                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 256                 }
 257                 if (-e ($compose_filename . ".final")) {
 258                         print "'$compose_filename.final' contains the composed email.\n"
 259                 }
 260         }
 261
 262         exit;
 263 };
 264
 265 $SIG{TERM} = \&signal_handler;
 266 $SIG{INT}  = \&signal_handler;
 267
 268 # Begin by accumulating all the variables (defined above), that we will end up
 269 # needing, first, from the command line:
 270
 271 my $rc = GetOptions("sender|from=s" => \$sender,
 272                     "in-reply-to=s" => \$initial_reply_to,
 273                     "subject=s" => \$initial_subject,
 274                     "to=s" => \@initial_to,
 275                     "no-to" => \$no_to,
 276                     "cc=s" => \@initial_cc,
 277                     "no-cc" => \$no_cc,
 278                     "bcc=s" => \@bcclist,
 279                     "no-bcc" => \$no_bcc,
 280                     "chain-reply-to!" => \$chain_reply_to,
 281                     "smtp-server=s" => \$smtp_server,
 282                     "smtp-server-port=s" => \$smtp_server_port,
 283                     "smtp-user=s" => \$smtp_authuser,
 284                     "smtp-pass:s" => \$smtp_authpass,
 285                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 286                     "smtp-encryption=s" => \$smtp_encryption,
 287                     "smtp-debug:i" => \$debug_net_smtp,
 288                     "smtp-domain:s" => \$smtp_domain,
 289                     "identity=s" => \$identity,
 290                     "annotate" => \$annotate,
 291                     "compose" => \$compose,
 292                     "quiet" => \$quiet,
 293                     "cc-cmd=s" => \$cc_cmd,
 294                     "suppress-from!" => \$suppress_from,
 295                     "suppress-cc=s" => \@suppress_cc,
 296                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 297                     "confirm=s" => \$confirm,
 298                     "dry-run" => \$dry_run,
 299                     "envelope-sender=s" => \$envelope_sender,
 300                     "thread!" => \$thread,
 301                     "validate!" => \$validate,
 302                     "format-patch!" => \$format_patch,
 303                     "8bit-encoding=s" => \$auto_8bit_encoding,
 304          );
 305
 306 unless ($rc) {
 307     usage();
 308 }
 309
 310 die "Cannot run git format-patch from outside a repository\n"
 311         if $format_patch and not $repo;
 312
 313 # Now, let's fill any that aren't set in with defaults:
 314
 315 sub read_config {
 316         my ($prefix) = @_;
 317
 318         foreach my $setting (keys %config_bool_settings) {
 319                 my $target = $config_bool_settings{$setting}->[0];
 320                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 321         }
 322
 323         foreach my $setting (keys %config_settings) {
 324                 my $target = $config_settings{$setting};
 325                 next if $setting eq "to" and defined $no_to;
 326                 next if $setting eq "cc" and defined $no_cc;
 327                 next if $setting eq "bcc" and defined $no_bcc;
 328                 if (ref($target) eq "ARRAY") {
 329                         unless (@$target) {
 330                                 my @values = Git::config(@repo, "$prefix.$setting");
 331                                 @$target = @values if (@values && defined $values[0]);
 332                         }
 333                 }
 334                 else {
 335                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 336                 }
 337         }
 338
 339         if (!defined $smtp_encryption) {
 340                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 341                 if (defined $enc) {
 342                         $smtp_encryption = $enc;
 343                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 344                         $smtp_encryption = 'ssl';
 345                 }
 346         }
 347 }
 348
 349 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 350 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 351 read_config("sendemail.$identity") if (defined $identity);
 352 read_config("sendemail");
 353
 354 # fall back on builtin bool defaults
 355 foreach my $setting (values %config_bool_settings) {
 356         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 357 }
 358
 359 # 'default' encryption is none -- this only prevents a warning
 360 $smtp_encryption = '' unless (defined $smtp_encryption);
 361
 362 # Set CC suppressions
 363 my(%suppress_cc);
 364 if (@suppress_cc) {
 365         foreach my $entry (@suppress_cc) {
 366                 die "Unknown --suppress-cc field: '$entry'\n"
 367                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 368                 $suppress_cc{$entry} = 1;
 369         }
 370 }
 371
 372 if ($suppress_cc{'all'}) {
 373         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 374                 $suppress_cc{$entry} = 1;
 375         }
 376         delete $suppress_cc{'all'};
 377 }
 378
 379 # If explicit old-style ones are specified, they trump --suppress-cc.
 380 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 381 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 382
 383 if ($suppress_cc{'body'}) {
 384         foreach my $entry (qw (sob bodycc)) {
 385                 $suppress_cc{$entry} = 1;
 386         }
 387         delete $suppress_cc{'body'};
 388 }
 389
 390 # Set confirm's default value
 391 my $confirm_unconfigured = !defined $confirm;
 392 if ($confirm_unconfigured) {
 393         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 394 };
 395 die "Unknown --confirm setting: '$confirm'\n"
 396         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 397
 398 # Debugging, print out the suppressions.
 399 if (0) {
 400         print "suppressions:\n";
 401         foreach my $entry (keys %suppress_cc) {
 402                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 403         }
 404 }
 405
 406 my ($repoauthor, $repocommitter);
 407 ($repoauthor) = Git::ident_person(@repo, 'author');
 408 ($repocommitter) = Git::ident_person(@repo, 'committer');
 409
 410 # Verify the user input
 411
 412 foreach my $entry (@initial_to) {
 413         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 414 }
 415
 416 foreach my $entry (@initial_cc) {
 417         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 418 }
 419
 420 foreach my $entry (@bcclist) {
 421         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 422 }
 423
 424 sub parse_address_line {
 425         if ($have_mail_address) {
 426                 return map { $_->format } Mail::Address->parse($_[0]);
 427         } else {
 428                 return split_addrs($_[0]);
 429         }
 430 }
 431
 432 sub split_addrs {
 433         return quotewords('\s*,\s*', 1, @_);
 434 }
 435
 436 my %aliases;
 437 my %parse_alias = (
 438         # multiline formats can be supported in the future
 439         mutt => sub { my $fh = shift; while (<$fh>) {
 440                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 441                         my ($alias, $addr) = ($1, $2);
 442                         $addr =~ s/#.*$//; # mutt allows # comments
 443                          # commas delimit multiple addresses
 444                         $aliases{$alias} = [ split_addrs($addr) ];
 445                 }}},
 446         mailrc => sub { my $fh = shift; while (<$fh>) {
 447                 if (/^alias\s+(\S+)\s+(.*)$/) {
 448                         # spaces delimit multiple addresses
 449                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 450                 }}},
 451         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 452                 for (my $x = ''; defined($x); $x = $_) {
 453                         chomp $x;
 454                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 455                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 456                         $aliases{$1} = [ split_addrs($2) ];
 457                 }},
 458         elm => sub  { my $fh = shift;
 459                       while (<$fh>) {
 460                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 461                               my ($alias, $addr) = ($1, $2);
 462                                $aliases{$alias} = [ split_addrs($addr) ];
 463                           }
 464                       } },
 465
 466         gnus => sub { my $fh = shift; while (<$fh>) {
 467                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 468                         $aliases{$1} = [ $2 ];
 469                 }}}
 470 );
 471
 472 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 473         foreach my $file (@alias_files) {
 474                 open my $fh, '<', $file or die "opening $file: $!\n";
 475                 $parse_alias{$aliasfiletype}->($fh);
 476                 close $fh;
 477         }
 478 }
 479
 480 ($sender) = expand_aliases($sender) if defined $sender;
 481
 482 # returns 1 if the conflict must be solved using it as a format-patch argument
 483 sub check_file_rev_conflict($) {
 484         return unless $repo;
 485         my $f = shift;
 486         try {
 487                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 488                 if (defined($format_patch)) {
 489                         return $format_patch;
 490                 }
 491                 die(<<EOF);
 492 File '$f' exists but it could also be the range of commits
 493 to produce patches for.  Please disambiguate by...
 494
 495     * Saying "./$f" if you mean a file; or
 496     * Giving --format-patch option if you mean a range.
 497 EOF
 498         } catch Git::Error::Command with {
 499                 return 0;
 500         }
 501 }
 502
 503 # Now that all the defaults are set, process the rest of the command line
 504 # arguments and collect up the files that need to be processed.
 505 my @rev_list_opts;
 506 while (defined(my $f = shift @ARGV)) {
 507         if ($f eq "--") {
 508                 push @rev_list_opts, "--", @ARGV;
 509                 @ARGV = ();
 510         } elsif (-d $f and !check_file_rev_conflict($f)) {
 511                 opendir(DH,$f)
 512                         or die "Failed to opendir $f: $!";
 513
 514                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 515                                 sort readdir(DH);
 516                 closedir(DH);
 517         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 518                 push @files, $f;
 519         } else {
 520                 push @rev_list_opts, $f;
 521         }
 522 }
 523
 524 if (@rev_list_opts) {
 525         die "Cannot run git format-patch from outside a repository\n"
 526                 unless $repo;
 527         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 528 }
 529
 530 if ($validate) {
 531         foreach my $f (@files) {
 532                 unless (-p $f) {
 533                         my $error = validate_patch($f);
 534                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 535                 }
 536         }
 537 }
 538
 539 if (@files) {
 540         unless ($quiet) {
 541                 print $_,"\n" for (@files);
 542         }
 543 } else {
 544         print STDERR "\nNo patch files specified!\n\n";
 545         usage();
 546 }
 547
 548 sub get_patch_subject($) {
 549         my $fn = shift;
 550         open (my $fh, '<', $fn);
 551         while (my $line = <$fh>) {
 552                 next unless ($line =~ /^Subject: (.*)$/);
 553                 close $fh;
 554                 return "GIT: $1\n";
 555         }
 556         close $fh;
 557         die "No subject line in $fn ?";
 558 }
 559
 560 if ($compose) {
 561         # Note that this does not need to be secure, but we will make a small
 562         # effort to have it be unique
 563         $compose_filename = ($repo ?
 564                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 565                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 566         open(C,">",$compose_filename)
 567                 or die "Failed to open for writing $compose_filename: $!";
 568
 569
 570         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 571         my $tpl_subject = $initial_subject || '';
 572         my $tpl_reply_to = $initial_reply_to || '';
 573
 574         print C <<EOT;
 575 From $tpl_sender # This line is ignored.
 576 GIT: Lines beginning in "GIT:" will be removed.
 577 GIT: Consider including an overall diffstat or table of contents
 578 GIT: for the patch you are writing.
 579 GIT:
 580 GIT: Clear the body content if you don't wish to send a summary.
 581 From: $tpl_sender
 582 Subject: $tpl_subject
 583 In-Reply-To: $tpl_reply_to
 584
 585 EOT
 586         for my $f (@files) {
 587                 print C get_patch_subject($f);
 588         }
 589         close(C);
 590
 591         if ($annotate) {
 592                 do_edit($compose_filename, @files);
 593         } else {
 594                 do_edit($compose_filename);
 595         }
 596
 597         open(C2,">",$compose_filename . ".final")
 598                 or die "Failed to open $compose_filename.final : " . $!;
 599
 600         open(C,"<",$compose_filename)
 601                 or die "Failed to open $compose_filename : " . $!;
 602
 603         my $need_8bit_cte = file_has_nonascii($compose_filename);
 604         my $in_body = 0;
 605         my $summary_empty = 1;
 606         while(<C>) {
 607                 next if m/^GIT:/;
 608                 if ($in_body) {
 609                         $summary_empty = 0 unless (/^\n$/);
 610                 } elsif (/^\n$/) {
 611                         $in_body = 1;
 612                         if ($need_8bit_cte) {
 613                                 print C2 "MIME-Version: 1.0\n",
 614                                          "Content-Type: text/plain; ",
 615                                            "charset=UTF-8\n",
 616                                          "Content-Transfer-Encoding: 8bit\n";
 617                         }
 618                 } elsif (/^MIME-Version:/i) {
 619                         $need_8bit_cte = 0;
 620                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 621                         $initial_subject = $1;
 622                         my $subject = $initial_subject;
 623                         $_ = "Subject: " .
 624                                 ($subject =~ /[^[:ascii:]]/ ?
 625                                  quote_rfc2047($subject) :
 626                                  $subject) .
 627                                 "\n";
 628                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 629                         $initial_reply_to = $1;
 630                         next;
 631                 } elsif (/^From:\s*(.+)\s*$/i) {
 632                         $sender = $1;
 633                         next;
 634                 } elsif (/^(?:To|Cc|Bcc):/i) {
 635                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 636                         next;
 637                 }
 638                 print C2 $_;
 639         }
 640         close(C);
 641         close(C2);
 642
 643         if ($summary_empty) {
 644                 print "Summary email is empty, skipping it\n";
 645                 $compose = -1;
 646         }
 647 } elsif ($annotate) {
 648         do_edit(@files);
 649 }
 650
 651 sub ask {
 652         my ($prompt, %arg) = @_;
 653         my $valid_re = $arg{valid_re};
 654         my $default = $arg{default};
 655         my $resp;
 656         my $i = 0;
 657         return defined $default ? $default : undef
 658                 unless defined $term->IN and defined fileno($term->IN) and
 659                        defined $term->OUT and defined fileno($term->OUT);
 660         while ($i++ < 10) {
 661                 $resp = $term->readline($prompt);
 662                 if (!defined $resp) { # EOF
 663                         print "\n";
 664                         return defined $default ? $default : undef;
 665                 }
 666                 if ($resp eq '' and defined $default) {
 667                         return $default;
 668                 }
 669                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 670                         return $resp;
 671                 }
 672         }
 673         return undef;
 674 }
 675
 676 my %broken_encoding;
 677
 678 sub file_declares_8bit_cte($) {
 679         my $fn = shift;
 680         open (my $fh, '<', $fn);
 681         while (my $line = <$fh>) {
 682                 last if ($line =~ /^$/);
 683                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 684         }
 685         close $fh;
 686         return 0;
 687 }
 688
 689 foreach my $f (@files) {
 690         next unless (body_or_subject_has_nonascii($f)
 691                      && !file_declares_8bit_cte($f));
 692         $broken_encoding{$f} = 1;
 693 }
 694
 695 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 696         print "The following files are 8bit, but do not declare " .
 697                 "a Content-Transfer-Encoding.\n";
 698         foreach my $f (sort keys %broken_encoding) {
 699                 print "    $f\n";
 700         }
 701         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 702                                   default => "UTF-8");
 703 }
 704
 705 my $prompting = 0;
 706 if (!defined $sender) {
 707         $sender = $repoauthor || $repocommitter || '';
 708         $sender = ask("Who should the emails appear to be from? [$sender] ",
 709                       default => $sender);
 710         print "Emails will be sent from: ", $sender, "\n";
 711         $prompting++;
 712 }
 713
 714 if (!@initial_to) {
 715         my $to = ask("Who should the emails be sent to? ");
 716         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 717         $prompting++;
 718 }
 719
 720 sub expand_aliases {
 721         return map { expand_one_alias($_) } @_;
 722 }
 723
 724 my %EXPANDED_ALIASES;
 725 sub expand_one_alias {
 726         my $alias = shift;
 727         if ($EXPANDED_ALIASES{$alias}) {
 728                 die "fatal: alias '$alias' expands to itself\n";
 729         }
 730         local $EXPANDED_ALIASES{$alias} = 1;
 731         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 732 }
 733
 734 @initial_to = expand_aliases(@initial_to);
 735 @initial_to = (map { sanitize_address($_) } @initial_to);
 736 @initial_cc = expand_aliases(@initial_cc);
 737 @bcclist = expand_aliases(@bcclist);
 738
 739 if ($thread && !defined $initial_reply_to && $prompting) {
 740         $initial_reply_to = ask(
 741                 "Message-ID to be used as In-Reply-To for the first email? ");
 742 }
 743 if (defined $initial_reply_to) {
 744         $initial_reply_to =~ s/^\s*<?//;
 745         $initial_reply_to =~ s/>?\s*$//;
 746         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 747 }
 748
 749 if (!defined $smtp_server) {
 750         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 751                 if (-x $_) {
 752                         $smtp_server = $_;
 753                         last;
 754                 }
 755         }
 756         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 757 }
 758
 759 if ($compose && $compose > 0) {
 760         @files = ($compose_filename . ".final", @files);
 761 }
 762
 763 # Variables we set as part of the loop over files
 764 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 765         $needs_confirm, $message_num, $ask_default);
 766
 767 sub extract_valid_address {
 768         my $address = shift;
 769         my $local_part_regexp = '[^<>"\s@]+';
 770         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 771
 772         # check for a local address:
 773         return $address if ($address =~ /^($local_part_regexp)$/);
 774
 775         $address =~ s/^\s*<(.*)>\s*$/$1/;
 776         if ($have_email_valid) {
 777                 return scalar Email::Valid->address($address);
 778         } else {
 779                 # less robust/correct than the monster regexp in Email::Valid,
 780                 # but still does a 99% job, and one less dependency
 781                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 782                 return $1;
 783         }
 784 }
 785
 786 # Usually don't need to change anything below here.
 787
 788 # we make a "fake" message id by taking the current number
 789 # of seconds since the beginning of Unix time and tacking on
 790 # a random number to the end, in case we are called quicker than
 791 # 1 second since the last time we were called.
 792
 793 # We'll setup a template for the message id, using the "from" address:
 794
 795 my ($message_id_stamp, $message_id_serial);
 796 sub make_message_id {
 797         my $uniq;
 798         if (!defined $message_id_stamp) {
 799                 $message_id_stamp = sprintf("%s-%s", time, $$);
 800                 $message_id_serial = 0;
 801         }
 802         $message_id_serial++;
 803         $uniq = "$message_id_stamp-$message_id_serial";
 804
 805         my $du_part;
 806         for ($sender, $repocommitter, $repoauthor) {
 807                 $du_part = extract_valid_address(sanitize_address($_));
 808                 last if (defined $du_part and $du_part ne '');
 809         }
 810         if (not defined $du_part or $du_part eq '') {
 811                 use Sys::Hostname qw();
 812                 $du_part = 'user@' . Sys::Hostname::hostname();
 813         }
 814         my $message_id_template = "<%s-git-send-email-%s>";
 815         $message_id = sprintf($message_id_template, $uniq, $du_part);
 816         #print "new message id = $message_id\n"; # Was useful for debugging
 817 }
 818
 819
 820
 821 $time = time - scalar $#files;
 822
 823 sub unquote_rfc2047 {
 824         local ($_) = @_;
 825         my $encoding;
 826         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 827                 $encoding = $1;
 828                 s/_/ /g;
 829                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 830         }
 831         return wantarray ? ($_, $encoding) : $_;
 832 }
 833
 834 sub quote_rfc2047 {
 835         local $_ = shift;
 836         my $encoding = shift || 'UTF-8';
 837         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 838         s/(.*)/=\?$encoding\?q\?$1\?=/;
 839         return $_;
 840 }
 841
 842 sub is_rfc2047_quoted {
 843         my $s = shift;
 844         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 845         my $encoded_text = '[!->@-~]+';
 846         length($s) <= 75 &&
 847         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 848 }
 849
 850 # use the simplest quoting being able to handle the recipient
 851 sub sanitize_address {
 852         my ($recipient) = @_;
 853         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 854
 855         if (not $recipient_name) {
 856                 return "$recipient";
 857         }
 858
 859         # if recipient_name is already quoted, do nothing
 860         if (is_rfc2047_quoted($recipient_name)) {
 861                 return $recipient;
 862         }
 863
 864         # rfc2047 is needed if a non-ascii char is included
 865         if ($recipient_name =~ /[^[:ascii:]]/) {
 866                 $recipient_name =~ s/^"(.*)"$/$1/;
 867                 $recipient_name = quote_rfc2047($recipient_name);
 868         }
 869
 870         # double quotes are needed if specials or CTLs are included
 871         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 872                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 873                 $recipient_name = "\"$recipient_name\"";
 874         }
 875
 876         return "$recipient_name $recipient_addr";
 877
 878 }
 879
 880 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 881 #
 882 # Tightly configured MTAa require that a caller sends a real DNS
 883 # domain name that corresponds the IP address in the HELO/EHLO
 884 # handshake. This is used to verify the connection and prevent
 885 # spammers from trying to hide their identity. If the DNS and IP don't
 886 # match, the receiveing MTA may deny the connection.
 887 #
 888 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 889 #
 890 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 891 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 892 #
 893 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 894 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 895
 896 sub valid_fqdn {
 897         my $domain = shift;
 898         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 899 }
 900
 901 sub maildomain_net {
 902         my $maildomain;
 903
 904         if (eval { require Net::Domain; 1 }) {
 905                 my $domain = Net::Domain::domainname();
 906                 $maildomain = $domain if valid_fqdn($domain);
 907         }
 908
 909         return $maildomain;
 910 }
 911
 912 sub maildomain_mta {
 913         my $maildomain;
 914
 915         if (eval { require Net::SMTP; 1 }) {
 916                 for my $host (qw(mailhost localhost)) {
 917                         my $smtp = Net::SMTP->new($host);
 918                         if (defined $smtp) {
 919                                 my $domain = $smtp->domain;
 920                                 $smtp->quit;
 921
 922                                 $maildomain = $domain if valid_fqdn($domain);
 923
 924                                 last if $maildomain;
 925                         }
 926                 }
 927         }
 928
 929         return $maildomain;
 930 }
 931
 932 sub maildomain {
 933         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
 934 }
 935
 936 # Returns 1 if the message was sent, and 0 otherwise.
 937 # In actuality, the whole program dies when there
 938 # is an error sending a message.
 939
 940 sub send_message {
 941         my @recipients = unique_email_list(@to);
 942         @cc = (grep { my $cc = extract_valid_address($_);
 943                       not grep { $cc eq $_ } @recipients
 944                     }
 945                map { sanitize_address($_) }
 946                @cc);
 947         my $to = join (",\n\t", @recipients);
 948         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 949         @recipients = (map { extract_valid_address($_) } @recipients);
 950         my $date = format_2822_time($time++);
 951         my $gitversion = '@@GIT_VERSION@@';
 952         if ($gitversion =~ m/..GIT_VERSION../) {
 953             $gitversion = Git::version();
 954         }
 955
 956         my $cc = join(",\n\t", unique_email_list(@cc));
 957         my $ccline = "";
 958         if ($cc ne '') {
 959                 $ccline = "\nCc: $cc";
 960         }
 961         my $sanitized_sender = sanitize_address($sender);
 962         make_message_id() unless defined($message_id);
 963
 964         my $header = "From: $sanitized_sender
 965 To: $to${ccline}
 966 Subject: $subject
 967 Date: $date
 968 Message-Id: $message_id
 969 X-Mailer: git-send-email $gitversion
 970 ";
 971         if ($reply_to) {
 972
 973                 $header .= "In-Reply-To: $reply_to\n";
 974                 $header .= "References: $references\n";
 975         }
 976         if (@xh) {
 977                 $header .= join("\n", @xh) . "\n";
 978         }
 979
 980         my @sendmail_parameters = ('-i', @recipients);
 981         my $raw_from = $sanitized_sender;
 982         if (defined $envelope_sender && $envelope_sender ne "auto") {
 983                 $raw_from = $envelope_sender;
 984         }
 985         $raw_from = extract_valid_address($raw_from);
 986         unshift (@sendmail_parameters,
 987                         '-f', $raw_from) if(defined $envelope_sender);
 988
 989         if ($needs_confirm && !$dry_run) {
 990                 print "\n$header\n";
 991                 if ($needs_confirm eq "inform") {
 992                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 993                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 994                         print "    The Cc list above has been expanded by additional\n";
 995                         print "    addresses found in the patch commit message. By default\n";
 996                         print "    send-email prompts before sending whenever this occurs.\n";
 997                         print "    This behavior is controlled by the sendemail.confirm\n";
 998                         print "    configuration setting.\n";
 999                         print "\n";
1000                         print "    For additional information, run 'git send-email --help'.\n";
1001                         print "    To retain the current behavior, but squelch this message,\n";
1002                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1003                 }
1004                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1005                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1006                          default => $ask_default);
1007                 die "Send this email reply required" unless defined $_;
1008                 if (/^n/i) {
1009                         return 0;
1010                 } elsif (/^q/i) {
1011                         cleanup_compose_files();
1012                         exit(0);
1013                 } elsif (/^a/i) {
1014                         $confirm = 'never';
1015                 }
1016         }
1017
1018         if ($dry_run) {
1019                 # We don't want to send the email.
1020         } elsif ($smtp_server =~ m#^/#) {
1021                 my $pid = open my $sm, '|-';
1022                 defined $pid or die $!;
1023                 if (!$pid) {
1024                         exec($smtp_server, @sendmail_parameters) or die $!;
1025                 }
1026                 print $sm "$header\n$message";
1027                 close $sm or die $?;
1028         } else {
1029
1030                 if (!defined $smtp_server) {
1031                         die "The required SMTP server is not properly defined."
1032                 }
1033
1034                 if ($smtp_encryption eq 'ssl') {
1035                         $smtp_server_port ||= 465; # ssmtp
1036                         require Net::SMTP::SSL;
1037                         $smtp_domain ||= maildomain();
1038                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1039                                                       Hello => $smtp_domain,
1040                                                       Port => $smtp_server_port);
1041                 }
1042                 else {
1043                         require Net::SMTP;
1044                         $smtp_domain ||= maildomain();
1045                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1046                                                  ? "$smtp_server:$smtp_server_port"
1047                                                  : $smtp_server,
1048                                                  Hello => $smtp_domain,
1049                                                  Debug => $debug_net_smtp);
1050                         if ($smtp_encryption eq 'tls' && $smtp) {
1051                                 require Net::SMTP::SSL;
1052                                 $smtp->command('STARTTLS');
1053                                 $smtp->response();
1054                                 if ($smtp->code == 220) {
1055                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1056                                                 or die "STARTTLS failed! ".$smtp->message;
1057                                         $smtp_encryption = '';
1058                                         # Send EHLO again to receive fresh
1059                                         # supported commands
1060                                         $smtp->hello();
1061                                 } else {
1062                                         die "Server does not support STARTTLS! ".$smtp->message;
1063                                 }
1064                         }
1065                 }
1066
1067                 if (!$smtp) {
1068                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1069                             "VALUES: server=$smtp_server ",
1070                             "encryption=$smtp_encryption ",
1071                             "hello=$smtp_domain",
1072                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1073                 }
1074
1075                 if (defined $smtp_authuser) {
1076
1077                         if (!defined $smtp_authpass) {
1078
1079                                 system "stty -echo";
1080
1081                                 do {
1082                                         print "Password: ";
1083                                         $_ = <STDIN>;
1084                                         print "\n";
1085                                 } while (!defined $_);
1086
1087                                 chomp($smtp_authpass = $_);
1088
1089                                 system "stty echo";
1090                         }
1091
1092                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1093                 }
1094
1095                 $smtp->mail( $raw_from ) or die $smtp->message;
1096                 $smtp->to( @recipients ) or die $smtp->message;
1097                 $smtp->data or die $smtp->message;
1098                 $smtp->datasend("$header\n$message") or die $smtp->message;
1099                 $smtp->dataend() or die $smtp->message;
1100                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1101         }
1102         if ($quiet) {
1103                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1104         } else {
1105                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1106                 if ($smtp_server !~ m#^/#) {
1107                         print "Server: $smtp_server\n";
1108                         print "MAIL FROM:<$raw_from>\n";
1109                         foreach my $entry (@recipients) {
1110                             print "RCPT TO:<$entry>\n";
1111                         }
1112                 } else {
1113                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1114                 }
1115                 print $header, "\n";
1116                 if ($smtp) {
1117                         print "Result: ", $smtp->code, ' ',
1118                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1119                 } else {
1120                         print "Result: OK\n";
1121                 }
1122         }
1123
1124         return 1;
1125 }
1126
1127 $reply_to = $initial_reply_to;
1128 $references = $initial_reply_to || '';
1129 $subject = $initial_subject;
1130 $message_num = 0;
1131
1132 foreach my $t (@files) {
1133         open(F,"<",$t) or die "can't open file $t";
1134
1135         my $author = undef;
1136         my $author_encoding;
1137         my $has_content_type;
1138         my $body_encoding;
1139         @to = ();
1140         @cc = ();
1141         @xh = ();
1142         my $input_format = undef;
1143         my @header = ();
1144         $message = "";
1145         $message_num++;
1146         # First unfold multiline header fields
1147         while(<F>) {
1148                 last if /^\s*$/;
1149                 if (/^\s+\S/ and @header) {
1150                         chomp($header[$#header]);
1151                         s/^\s+/ /;
1152                         $header[$#header] .= $_;
1153             } else {
1154                         push(@header, $_);
1155                 }
1156         }
1157         # Now parse the header
1158         foreach(@header) {
1159                 if (/^From /) {
1160                         $input_format = 'mbox';
1161                         next;
1162                 }
1163                 chomp;
1164                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1165                         $input_format = 'mbox';
1166                 }
1167
1168                 if (defined $input_format && $input_format eq 'mbox') {
1169                         if (/^Subject:\s+(.*)$/) {
1170                                 $subject = $1;
1171                         }
1172                         elsif (/^From:\s+(.*)$/) {
1173                                 ($author, $author_encoding) = unquote_rfc2047($1);
1174                                 next if $suppress_cc{'author'};
1175                                 next if $suppress_cc{'self'} and $author eq $sender;
1176                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1177                                         $1, $_) unless $quiet;
1178                                 push @cc, $1;
1179                         }
1180                         elsif (/^To:\s+(.*)$/) {
1181                                 foreach my $addr (parse_address_line($1)) {
1182                                         printf("(mbox) Adding to: %s from line '%s'\n",
1183                                                 $addr, $_) unless $quiet;
1184                                         push @to, sanitize_address($addr);
1185                                 }
1186                         }
1187                         elsif (/^Cc:\s+(.*)$/) {
1188                                 foreach my $addr (parse_address_line($1)) {
1189                                         if (unquote_rfc2047($addr) eq $sender) {
1190                                                 next if ($suppress_cc{'self'});
1191                                         } else {
1192                                                 next if ($suppress_cc{'cc'});
1193                                         }
1194                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1195                                                 $addr, $_) unless $quiet;
1196                                         push @cc, $addr;
1197                                 }
1198                         }
1199                         elsif (/^Content-type:/i) {
1200                                 $has_content_type = 1;
1201                                 if (/charset="?([^ "]+)/) {
1202                                         $body_encoding = $1;
1203                                 }
1204                                 push @xh, $_;
1205                         }
1206                         elsif (/^Message-Id: (.*)/i) {
1207                                 $message_id = $1;
1208                         }
1209                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1210                                 push @xh, $_;
1211                         }
1212
1213                 } else {
1214                         # In the traditional
1215                         # "send lots of email" format,
1216                         # line 1 = cc
1217                         # line 2 = subject
1218                         # So let's support that, too.
1219                         $input_format = 'lots';
1220                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1221                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1222                                         $_, $_) unless $quiet;
1223                                 push @cc, $_;
1224                         } elsif (!defined $subject) {
1225                                 $subject = $_;
1226                         }
1227                 }
1228         }
1229         # Now parse the message body
1230         while(<F>) {
1231                 $message .=  $_;
1232                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1233                         chomp;
1234                         my ($what, $c) = ($1, $2);
1235                         chomp $c;
1236                         if ($c eq $sender) {
1237                                 next if ($suppress_cc{'self'});
1238                         } else {
1239                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1240                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1241                         }
1242                         push @cc, $c;
1243                         printf("(body) Adding cc: %s from line '%s'\n",
1244                                 $c, $_) unless $quiet;
1245                 }
1246         }
1247         close F;
1248
1249         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1250                 open(F, "$cc_cmd \Q$t\E |")
1251                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1252                 while(<F>) {
1253                         my $c = $_;
1254                         $c =~ s/^\s*//g;
1255                         $c =~ s/\n$//g;
1256                         next if ($c eq $sender and $suppress_from);
1257                         push @cc, $c;
1258                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1259                                 $c, $cc_cmd) unless $quiet;
1260                 }
1261                 close F
1262                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1263         }
1264
1265         if ($broken_encoding{$t} && !$has_content_type) {
1266                 $has_content_type = 1;
1267                 push @xh, "MIME-Version: 1.0",
1268                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1269                         "Content-Transfer-Encoding: 8bit";
1270                 $body_encoding = $auto_8bit_encoding;
1271         }
1272
1273         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1274                 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1275         }
1276
1277         if (defined $author and $author ne $sender) {
1278                 $message = "From: $author\n\n$message";
1279                 if (defined $author_encoding) {
1280                         if ($has_content_type) {
1281                                 if ($body_encoding eq $author_encoding) {
1282                                         # ok, we already have the right encoding
1283                                 }
1284                                 else {
1285                                         # uh oh, we should re-encode
1286                                 }
1287                         }
1288                         else {
1289                                 $has_content_type = 1;
1290                                 push @xh,
1291                                   'MIME-Version: 1.0',
1292                                   "Content-Type: text/plain; charset=$author_encoding",
1293                                   'Content-Transfer-Encoding: 8bit';
1294                         }
1295                 }
1296         }
1297
1298         $needs_confirm = (
1299                 $confirm eq "always" or
1300                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1301                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1302         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1303
1304         @to = (@initial_to, @to);
1305         @cc = (@initial_cc, @cc);
1306
1307         my $message_was_sent = send_message();
1308
1309         # set up for the next message
1310         if ($thread && $message_was_sent &&
1311                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1312                 $reply_to = $message_id;
1313                 if (length $references > 0) {
1314                         $references .= "\n $message_id";
1315                 } else {
1316                         $references = "$message_id";
1317                 }
1318         }
1319         $message_id = undef;
1320 }
1321
1322 cleanup_compose_files();
1323
1324 sub cleanup_compose_files() {
1325         unlink($compose_filename, $compose_filename . ".final") if $compose;
1326 }
1327
1328 $smtp->quit if $smtp;
1329
1330 sub unique_email_list(@) {
1331         my %seen;
1332         my @emails;
1333
1334         foreach my $entry (@_) {
1335                 if (my $clean = extract_valid_address($entry)) {
1336                         $seen{$clean} ||= 0;
1337                         next if $seen{$clean}++;
1338                         push @emails, $entry;
1339                 } else {
1340                         print STDERR "W: unable to extract a valid address",
1341                                         " from: $entry\n";
1342                 }
1343         }
1344         return @emails;
1345 }
1346
1347 sub validate_patch {
1348         my $fn = shift;
1349         open(my $fh, '<', $fn)
1350                 or die "unable to open $fn: $!\n";
1351         while (my $line = <$fh>) {
1352                 if (length($line) > 998) {
1353                         return "$.: patch contains a line longer than 998 characters";
1354                 }
1355         }
1356         return undef;
1357 }
1358
1359 sub file_has_nonascii {
1360         my $fn = shift;
1361         open(my $fh, '<', $fn)
1362                 or die "unable to open $fn: $!\n";
1363         while (my $line = <$fh>) {
1364                 return 1 if $line =~ /[^[:ascii:]]/;
1365         }
1366         return 0;
1367 }
1368
1369 sub body_or_subject_has_nonascii {
1370         my $fn = shift;
1371         open(my $fh, '<', $fn)
1372                 or die "unable to open $fn: $!\n";
1373         while (my $line = <$fh>) {
1374                 last if $line =~ /^$/;
1375                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1376         }
1377         while (my $line = <$fh>) {
1378                 return 1 if $line =~ /[^[:ascii:]]/;
1379         }
1380         return 0;
1381 }