Git.pm: hard-depend on the File::{Temp,Spec} modules
[git.git] / perl / Git.pm
blob151b0e714490a936479fa530e6155fe51739781d
1 =head1 NAME
3 Git - Perl interface to the Git version control system
5 =cut
8 package Git;
10 use 5.008;
11 use strict;
12 use warnings;
14 use File::Temp ();
15 use File::Spec ();
17 BEGIN {
19 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK);
21 # Totally unstable API.
22 $VERSION = '0.01';
25 =head1 SYNOPSIS
27 use Git;
29 my $version = Git::command_oneline('version');
31 git_cmd_try { Git::command_noisy('update-server-info') }
32 '%s failed w/ code %d';
34 my $repo = Git->repository (Directory => '/srv/git/cogito.git');
37 my @revs = $repo->command('rev-list', '--since=last monday', '--all');
39 my ($fh, $c) = $repo->command_output_pipe('rev-list', '--since=last monday', '--all');
40 my $lastrev = <$fh>; chomp $lastrev;
41 $repo->command_close_pipe($fh, $c);
43 my $lastrev = $repo->command_oneline( [ 'rev-list', '--all' ],
44 STDERR => 0 );
46 my $sha1 = $repo->hash_and_insert_object('file.txt');
47 my $tempfile = tempfile();
48 my $size = $repo->cat_blob($sha1, $tempfile);
50 =cut
53 require Exporter;
55 @ISA = qw(Exporter);
57 @EXPORT = qw(git_cmd_try);
59 # Methods which can be called as standalone functions as well:
60 @EXPORT_OK = qw(command command_oneline command_noisy
61 command_output_pipe command_input_pipe command_close_pipe
62 command_bidi_pipe command_close_bidi_pipe
63 version exec_path html_path hash_object git_cmd_try
64 remote_refs prompt
65 get_tz_offset get_record
66 credential credential_read credential_write
67 temp_acquire temp_is_locked temp_release temp_reset temp_path
68 unquote_path);
71 =head1 DESCRIPTION
73 This module provides Perl scripts easy way to interface the Git version control
74 system. The modules have an easy and well-tested way to call arbitrary Git
75 commands; in the future, the interface will also provide specialized methods
76 for doing easily operations which are not totally trivial to do over
77 the generic command interface.
79 While some commands can be executed outside of any context (e.g. 'version'
80 or 'init'), most operations require a repository context, which in practice
81 means getting an instance of the Git object using the repository() constructor.
82 (In the future, we will also get a new_repository() constructor.) All commands
83 called as methods of the object are then executed in the context of the
84 repository.
86 Part of the "repository state" is also information about path to the attached
87 working copy (unless you work with a bare repository). You can also navigate
88 inside of the working copy using the C<wc_chdir()> method. (Note that
89 the repository object is self-contained and will not change working directory
90 of your process.)
92 TODO: In the future, we might also do
94 my $remoterepo = $repo->remote_repository (Name => 'cogito', Branch => 'master');
95 $remoterepo ||= Git->remote_repository ('http://git.or.cz/cogito.git/');
96 my @refs = $remoterepo->refs();
98 Currently, the module merely wraps calls to external Git tools. In the future,
99 it will provide a much faster way to interact with Git by linking directly
100 to libgit. This should be completely opaque to the user, though (performance
101 increase notwithstanding).
103 =cut
106 use Carp qw(carp croak); # but croak is bad - throw instead
107 use Git::Error qw(:try);
108 use Cwd qw(abs_path cwd);
109 use IPC::Open2 qw(open2);
110 use Fcntl qw(SEEK_SET SEEK_CUR);
111 use Time::Local qw(timegm);
115 =head1 CONSTRUCTORS
117 =over 4
119 =item repository ( OPTIONS )
121 =item repository ( DIRECTORY )
123 =item repository ()
125 Construct a new repository object.
126 C<OPTIONS> are passed in a hash like fashion, using key and value pairs.
127 Possible options are:
129 B<Repository> - Path to the Git repository.
131 B<WorkingCopy> - Path to the associated working copy; not strictly required
132 as many commands will happily crunch on a bare repository.
134 B<WorkingSubdir> - Subdirectory in the working copy to work inside.
135 Just left undefined if you do not want to limit the scope of operations.
137 B<Directory> - Path to the Git working directory in its usual setup.
138 The C<.git> directory is searched in the directory and all the parent
139 directories; if found, C<WorkingCopy> is set to the directory containing
140 it and C<Repository> to the C<.git> directory itself. If no C<.git>
141 directory was found, the C<Directory> is assumed to be a bare repository,
142 C<Repository> is set to point at it and C<WorkingCopy> is left undefined.
143 If the C<$GIT_DIR> environment variable is set, things behave as expected
144 as well.
146 You should not use both C<Directory> and either of C<Repository> and
147 C<WorkingCopy> - the results of that are undefined.
149 Alternatively, a directory path may be passed as a single scalar argument
150 to the constructor; it is equivalent to setting only the C<Directory> option
151 field.
153 Calling the constructor with no options whatsoever is equivalent to
154 calling it with C<< Directory => '.' >>. In general, if you are building
155 a standard porcelain command, simply doing C<< Git->repository() >> should
156 do the right thing and setup the object to reflect exactly where the user
157 is right now.
159 =cut
161 sub repository {
162 my $class = shift;
163 my @args = @_;
164 my %opts = ();
165 my $self;
167 if (defined $args[0]) {
168 if ($#args % 2 != 1) {
169 # Not a hash.
170 $#args == 0 or throw Error::Simple("bad usage");
171 %opts = ( Directory => $args[0] );
172 } else {
173 %opts = @args;
177 if (not defined $opts{Repository} and not defined $opts{WorkingCopy}
178 and not defined $opts{Directory}) {
179 $opts{Directory} = '.';
182 if (defined $opts{Directory}) {
183 -d $opts{Directory} or throw Error::Simple("Directory not found: $opts{Directory} $!");
185 my $search = Git->repository(WorkingCopy => $opts{Directory});
186 my $dir;
187 try {
188 $dir = $search->command_oneline(['rev-parse', '--git-dir'],
189 STDERR => 0);
190 } catch Git::Error::Command with {
191 $dir = undef;
194 if ($dir) {
195 File::Spec->file_name_is_absolute($dir) or $dir = $opts{Directory} . '/' . $dir;
196 $opts{Repository} = abs_path($dir);
198 # If --git-dir went ok, this shouldn't die either.
199 my $prefix = $search->command_oneline('rev-parse', '--show-prefix');
200 $dir = abs_path($opts{Directory}) . '/';
201 if ($prefix) {
202 if (substr($dir, -length($prefix)) ne $prefix) {
203 throw Error::Simple("rev-parse confused me - $dir does not have trailing $prefix");
205 substr($dir, -length($prefix)) = '';
207 $opts{WorkingCopy} = $dir;
208 $opts{WorkingSubdir} = $prefix;
210 } else {
211 # A bare repository? Let's see...
212 $dir = $opts{Directory};
214 unless (-d "$dir/refs" and -d "$dir/objects" and -e "$dir/HEAD") {
215 # Mimic git-rev-parse --git-dir error message:
216 throw Error::Simple("fatal: Not a git repository: $dir");
218 my $search = Git->repository(Repository => $dir);
219 try {
220 $search->command('symbolic-ref', 'HEAD');
221 } catch Git::Error::Command with {
222 # Mimic git-rev-parse --git-dir error message:
223 throw Error::Simple("fatal: Not a git repository: $dir");
226 $opts{Repository} = abs_path($dir);
229 delete $opts{Directory};
232 $self = { opts => \%opts };
233 bless $self, $class;
236 =back
238 =head1 METHODS
240 =over 4
242 =item command ( COMMAND [, ARGUMENTS... ] )
244 =item command ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
246 Execute the given Git C<COMMAND> (specify it without the 'git-'
247 prefix), optionally with the specified extra C<ARGUMENTS>.
249 The second more elaborate form can be used if you want to further adjust
250 the command execution. Currently, only one option is supported:
252 B<STDERR> - How to deal with the command's error output. By default (C<undef>)
253 it is delivered to the caller's C<STDERR>. A false value (0 or '') will cause
254 it to be thrown away. If you want to process it, you can get it in a filehandle
255 you specify, but you must be extremely careful; if the error output is not
256 very short and you want to read it in the same process as where you called
257 C<command()>, you are set up for a nice deadlock!
259 The method can be called without any instance or on a specified Git repository
260 (in that case the command will be run in the repository context).
262 In scalar context, it returns all the command output in a single string
263 (verbatim).
265 In array context, it returns an array containing lines printed to the
266 command's stdout (without trailing newlines).
268 In both cases, the command's stdin and stderr are the same as the caller's.
270 =cut
272 sub command {
273 my ($fh, $ctx) = command_output_pipe(@_);
275 if (not defined wantarray) {
276 # Nothing to pepper the possible exception with.
277 _cmd_close($ctx, $fh);
279 } elsif (not wantarray) {
280 local $/;
281 my $text = <$fh>;
282 try {
283 _cmd_close($ctx, $fh);
284 } catch Git::Error::Command with {
285 # Pepper with the output:
286 my $E = shift;
287 $E->{'-outputref'} = \$text;
288 throw $E;
290 return $text;
292 } else {
293 my @lines = <$fh>;
294 defined and chomp for @lines;
295 try {
296 _cmd_close($ctx, $fh);
297 } catch Git::Error::Command with {
298 my $E = shift;
299 $E->{'-outputref'} = \@lines;
300 throw $E;
302 return @lines;
307 =item command_oneline ( COMMAND [, ARGUMENTS... ] )
309 =item command_oneline ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
311 Execute the given C<COMMAND> in the same way as command()
312 does but always return a scalar string containing the first line
313 of the command's standard output.
315 =cut
317 sub command_oneline {
318 my ($fh, $ctx) = command_output_pipe(@_);
320 my $line = <$fh>;
321 defined $line and chomp $line;
322 try {
323 _cmd_close($ctx, $fh);
324 } catch Git::Error::Command with {
325 # Pepper with the output:
326 my $E = shift;
327 $E->{'-outputref'} = \$line;
328 throw $E;
330 return $line;
334 =item command_output_pipe ( COMMAND [, ARGUMENTS... ] )
336 =item command_output_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
338 Execute the given C<COMMAND> in the same way as command()
339 does but return a pipe filehandle from which the command output can be
340 read.
342 The function can return C<($pipe, $ctx)> in array context.
343 See C<command_close_pipe()> for details.
345 =cut
347 sub command_output_pipe {
348 _command_common_pipe('-|', @_);
352 =item command_input_pipe ( COMMAND [, ARGUMENTS... ] )
354 =item command_input_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
356 Execute the given C<COMMAND> in the same way as command_output_pipe()
357 does but return an input pipe filehandle instead; the command output
358 is not captured.
360 The function can return C<($pipe, $ctx)> in array context.
361 See C<command_close_pipe()> for details.
363 =cut
365 sub command_input_pipe {
366 _command_common_pipe('|-', @_);
370 =item command_close_pipe ( PIPE [, CTX ] )
372 Close the C<PIPE> as returned from C<command_*_pipe()>, checking
373 whether the command finished successfully. The optional C<CTX> argument
374 is required if you want to see the command name in the error message,
375 and it is the second value returned by C<command_*_pipe()> when
376 called in array context. The call idiom is:
378 my ($fh, $ctx) = $r->command_output_pipe('status');
379 while (<$fh>) { ... }
380 $r->command_close_pipe($fh, $ctx);
382 Note that you should not rely on whatever actually is in C<CTX>;
383 currently it is simply the command name but in future the context might
384 have more complicated structure.
386 =cut
388 sub command_close_pipe {
389 my ($self, $fh, $ctx) = _maybe_self(@_);
390 $ctx ||= '<unknown>';
391 _cmd_close($ctx, $fh);
394 =item command_bidi_pipe ( COMMAND [, ARGUMENTS... ] )
396 Execute the given C<COMMAND> in the same way as command_output_pipe()
397 does but return both an input pipe filehandle and an output pipe filehandle.
399 The function will return C<($pid, $pipe_in, $pipe_out, $ctx)>.
400 See C<command_close_bidi_pipe()> for details.
402 =cut
404 sub command_bidi_pipe {
405 my ($pid, $in, $out);
406 my ($self) = _maybe_self(@_);
407 local %ENV = %ENV;
408 my $cwd_save = undef;
409 if ($self) {
410 shift;
411 $cwd_save = cwd();
412 _setup_git_cmd_env($self);
414 $pid = open2($in, $out, 'git', @_);
415 chdir($cwd_save) if $cwd_save;
416 return ($pid, $in, $out, join(' ', @_));
419 =item command_close_bidi_pipe ( PID, PIPE_IN, PIPE_OUT [, CTX] )
421 Close the C<PIPE_IN> and C<PIPE_OUT> as returned from C<command_bidi_pipe()>,
422 checking whether the command finished successfully. The optional C<CTX>
423 argument is required if you want to see the command name in the error message,
424 and it is the fourth value returned by C<command_bidi_pipe()>. The call idiom
427 my ($pid, $in, $out, $ctx) = $r->command_bidi_pipe('cat-file --batch-check');
428 print $out "000000000\n";
429 while (<$in>) { ... }
430 $r->command_close_bidi_pipe($pid, $in, $out, $ctx);
432 Note that you should not rely on whatever actually is in C<CTX>;
433 currently it is simply the command name but in future the context might
434 have more complicated structure.
436 C<PIPE_IN> and C<PIPE_OUT> may be C<undef> if they have been closed prior to
437 calling this function. This may be useful in a query-response type of
438 commands where caller first writes a query and later reads response, eg:
440 my ($pid, $in, $out, $ctx) = $r->command_bidi_pipe('cat-file --batch-check');
441 print $out "000000000\n";
442 close $out;
443 while (<$in>) { ... }
444 $r->command_close_bidi_pipe($pid, $in, undef, $ctx);
446 This idiom may prevent potential dead locks caused by data sent to the output
447 pipe not being flushed and thus not reaching the executed command.
449 =cut
451 sub command_close_bidi_pipe {
452 local $?;
453 my ($self, $pid, $in, $out, $ctx) = _maybe_self(@_);
454 _cmd_close($ctx, (grep { defined } ($in, $out)));
455 waitpid $pid, 0;
456 if ($? >> 8) {
457 throw Git::Error::Command($ctx, $? >>8);
462 =item command_noisy ( COMMAND [, ARGUMENTS... ] )
464 Execute the given C<COMMAND> in the same way as command() does but do not
465 capture the command output - the standard output is not redirected and goes
466 to the standard output of the caller application.
468 While the method is called command_noisy(), you might want to as well use
469 it for the most silent Git commands which you know will never pollute your
470 stdout but you want to avoid the overhead of the pipe setup when calling them.
472 The function returns only after the command has finished running.
474 =cut
476 sub command_noisy {
477 my ($self, $cmd, @args) = _maybe_self(@_);
478 _check_valid_cmd($cmd);
480 my $pid = fork;
481 if (not defined $pid) {
482 throw Error::Simple("fork failed: $!");
483 } elsif ($pid == 0) {
484 _cmd_exec($self, $cmd, @args);
486 if (waitpid($pid, 0) > 0 and $?>>8 != 0) {
487 throw Git::Error::Command(join(' ', $cmd, @args), $? >> 8);
492 =item version ()
494 Return the Git version in use.
496 =cut
498 sub version {
499 my $verstr = command_oneline('--version');
500 $verstr =~ s/^git version //;
501 $verstr;
505 =item exec_path ()
507 Return path to the Git sub-command executables (the same as
508 C<git --exec-path>). Useful mostly only internally.
510 =cut
512 sub exec_path { command_oneline('--exec-path') }
515 =item html_path ()
517 Return path to the Git html documentation (the same as
518 C<git --html-path>). Useful mostly only internally.
520 =cut
522 sub html_path { command_oneline('--html-path') }
525 =item get_tz_offset ( TIME )
527 Return the time zone offset from GMT in the form +/-HHMM where HH is
528 the number of hours from GMT and MM is the number of minutes. This is
529 the equivalent of what strftime("%z", ...) would provide on a GNU
530 platform.
532 If TIME is not supplied, the current local time is used.
534 =cut
536 sub get_tz_offset {
537 # some systems don't handle or mishandle %z, so be creative.
538 my $t = shift || time;
539 my $gm = timegm(localtime($t));
540 my $sign = qw( + + - )[ $gm <=> $t ];
541 return sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
544 =item get_record ( FILEHANDLE, INPUT_RECORD_SEPARATOR )
546 Read one record from FILEHANDLE delimited by INPUT_RECORD_SEPARATOR,
547 removing any trailing INPUT_RECORD_SEPARATOR.
549 =cut
551 sub get_record {
552 my ($fh, $rs) = @_;
553 local $/ = $rs;
554 my $rec = <$fh>;
555 chomp $rec if defined $rs;
556 $rec;
559 =item prompt ( PROMPT , ISPASSWORD )
561 Query user C<PROMPT> and return answer from user.
563 Honours GIT_ASKPASS and SSH_ASKPASS environment variables for querying
564 the user. If no *_ASKPASS variable is set or an error occoured,
565 the terminal is tried as a fallback.
566 If C<ISPASSWORD> is set and true, the terminal disables echo.
568 =cut
570 sub prompt {
571 my ($prompt, $isPassword) = @_;
572 my $ret;
573 if (exists $ENV{'GIT_ASKPASS'}) {
574 $ret = _prompt($ENV{'GIT_ASKPASS'}, $prompt);
576 if (!defined $ret && exists $ENV{'SSH_ASKPASS'}) {
577 $ret = _prompt($ENV{'SSH_ASKPASS'}, $prompt);
579 if (!defined $ret) {
580 print STDERR $prompt;
581 STDERR->flush;
582 if (defined $isPassword && $isPassword) {
583 require Term::ReadKey;
584 Term::ReadKey::ReadMode('noecho');
585 $ret = '';
586 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
587 last if $key =~ /[\012\015]/; # \n\r
588 $ret .= $key;
590 Term::ReadKey::ReadMode('restore');
591 print STDERR "\n";
592 STDERR->flush;
593 } else {
594 chomp($ret = <STDIN>);
597 return $ret;
600 sub _prompt {
601 my ($askpass, $prompt) = @_;
602 return unless length $askpass;
603 $prompt =~ s/\n/ /g;
604 my $ret;
605 open my $fh, "-|", $askpass, $prompt or return;
606 $ret = <$fh>;
607 $ret =~ s/[\015\012]//g; # strip \r\n, chomp does not work on all systems (i.e. windows) as expected
608 close ($fh);
609 return $ret;
612 =item repo_path ()
614 Return path to the git repository. Must be called on a repository instance.
616 =cut
618 sub repo_path { $_[0]->{opts}->{Repository} }
621 =item wc_path ()
623 Return path to the working copy. Must be called on a repository instance.
625 =cut
627 sub wc_path { $_[0]->{opts}->{WorkingCopy} }
630 =item wc_subdir ()
632 Return path to the subdirectory inside of a working copy. Must be called
633 on a repository instance.
635 =cut
637 sub wc_subdir { $_[0]->{opts}->{WorkingSubdir} ||= '' }
640 =item wc_chdir ( SUBDIR )
642 Change the working copy subdirectory to work within. The C<SUBDIR> is
643 relative to the working copy root directory (not the current subdirectory).
644 Must be called on a repository instance attached to a working copy
645 and the directory must exist.
647 =cut
649 sub wc_chdir {
650 my ($self, $subdir) = @_;
651 $self->wc_path()
652 or throw Error::Simple("bare repository");
654 -d $self->wc_path().'/'.$subdir
655 or throw Error::Simple("subdir not found: $subdir $!");
656 # Of course we will not "hold" the subdirectory so anyone
657 # can delete it now and we will never know. But at least we tried.
659 $self->{opts}->{WorkingSubdir} = $subdir;
663 =item config ( VARIABLE )
665 Retrieve the configuration C<VARIABLE> in the same manner as C<config>
666 does. In scalar context requires the variable to be set only one time
667 (exception is thrown otherwise), in array context returns allows the
668 variable to be set multiple times and returns all the values.
670 =cut
672 sub config {
673 return _config_common({}, @_);
677 =item config_bool ( VARIABLE )
679 Retrieve the bool configuration C<VARIABLE>. The return value
680 is usable as a boolean in perl (and C<undef> if it's not defined,
681 of course).
683 =cut
685 sub config_bool {
686 my $val = scalar _config_common({'kind' => '--bool'}, @_);
688 # Do not rewrite this as return (defined $val && $val eq 'true')
689 # as some callers do care what kind of falsehood they receive.
690 if (!defined $val) {
691 return undef;
692 } else {
693 return $val eq 'true';
698 =item config_path ( VARIABLE )
700 Retrieve the path configuration C<VARIABLE>. The return value
701 is an expanded path or C<undef> if it's not defined.
703 =cut
705 sub config_path {
706 return _config_common({'kind' => '--path'}, @_);
710 =item config_int ( VARIABLE )
712 Retrieve the integer configuration C<VARIABLE>. The return value
713 is simple decimal number. An optional value suffix of 'k', 'm',
714 or 'g' in the config file will cause the value to be multiplied
715 by 1024, 1048576 (1024^2), or 1073741824 (1024^3) prior to output.
716 It would return C<undef> if configuration variable is not defined.
718 =cut
720 sub config_int {
721 return scalar _config_common({'kind' => '--int'}, @_);
724 # Common subroutine to implement bulk of what the config* family of methods
725 # do. This currently wraps command('config') so it is not so fast.
726 sub _config_common {
727 my ($opts) = shift @_;
728 my ($self, $var) = _maybe_self(@_);
730 try {
731 my @cmd = ('config', $opts->{'kind'} ? $opts->{'kind'} : ());
732 unshift @cmd, $self if $self;
733 if (wantarray) {
734 return command(@cmd, '--get-all', $var);
735 } else {
736 return command_oneline(@cmd, '--get', $var);
738 } catch Git::Error::Command with {
739 my $E = shift;
740 if ($E->value() == 1) {
741 # Key not found.
742 return;
743 } else {
744 throw $E;
749 =item get_colorbool ( NAME )
751 Finds if color should be used for NAMEd operation from the configuration,
752 and returns boolean (true for "use color", false for "do not use color").
754 =cut
756 sub get_colorbool {
757 my ($self, $var) = @_;
758 my $stdout_to_tty = (-t STDOUT) ? "true" : "false";
759 my $use_color = $self->command_oneline('config', '--get-colorbool',
760 $var, $stdout_to_tty);
761 return ($use_color eq 'true');
764 =item get_color ( SLOT, COLOR )
766 Finds color for SLOT from the configuration, while defaulting to COLOR,
767 and returns the ANSI color escape sequence:
769 print $repo->get_color("color.interactive.prompt", "underline blue white");
770 print "some text";
771 print $repo->get_color("", "normal");
773 =cut
775 sub get_color {
776 my ($self, $slot, $default) = @_;
777 my $color = $self->command_oneline('config', '--get-color', $slot, $default);
778 if (!defined $color) {
779 $color = "";
781 return $color;
784 =item remote_refs ( REPOSITORY [, GROUPS [, REFGLOBS ] ] )
786 This function returns a hashref of refs stored in a given remote repository.
787 The hash is in the format C<refname =\> hash>. For tags, the C<refname> entry
788 contains the tag object while a C<refname^{}> entry gives the tagged objects.
790 C<REPOSITORY> has the same meaning as the appropriate C<git-ls-remote>
791 argument; either a URL or a remote name (if called on a repository instance).
792 C<GROUPS> is an optional arrayref that can contain 'tags' to return all the
793 tags and/or 'heads' to return all the heads. C<REFGLOB> is an optional array
794 of strings containing a shell-like glob to further limit the refs returned in
795 the hash; the meaning is again the same as the appropriate C<git-ls-remote>
796 argument.
798 This function may or may not be called on a repository instance. In the former
799 case, remote names as defined in the repository are recognized as repository
800 specifiers.
802 =cut
804 sub remote_refs {
805 my ($self, $repo, $groups, $refglobs) = _maybe_self(@_);
806 my @args;
807 if (ref $groups eq 'ARRAY') {
808 foreach (@$groups) {
809 if ($_ eq 'heads') {
810 push (@args, '--heads');
811 } elsif ($_ eq 'tags') {
812 push (@args, '--tags');
813 } else {
814 # Ignore unknown groups for future
815 # compatibility
819 push (@args, $repo);
820 if (ref $refglobs eq 'ARRAY') {
821 push (@args, @$refglobs);
824 my @self = $self ? ($self) : (); # Ultra trickery
825 my ($fh, $ctx) = Git::command_output_pipe(@self, 'ls-remote', @args);
826 my %refs;
827 while (<$fh>) {
828 chomp;
829 my ($hash, $ref) = split(/\t/, $_, 2);
830 $refs{$ref} = $hash;
832 Git::command_close_pipe(@self, $fh, $ctx);
833 return \%refs;
837 =item ident ( TYPE | IDENTSTR )
839 =item ident_person ( TYPE | IDENTSTR | IDENTARRAY )
841 This suite of functions retrieves and parses ident information, as stored
842 in the commit and tag objects or produced by C<var GIT_type_IDENT> (thus
843 C<TYPE> can be either I<author> or I<committer>; case is insignificant).
845 The C<ident> method retrieves the ident information from C<git var>
846 and either returns it as a scalar string or as an array with the fields parsed.
847 Alternatively, it can take a prepared ident string (e.g. from the commit
848 object) and just parse it.
850 C<ident_person> returns the person part of the ident - name and email;
851 it can take the same arguments as C<ident> or the array returned by C<ident>.
853 The synopsis is like:
855 my ($name, $email, $time_tz) = ident('author');
856 "$name <$email>" eq ident_person('author');
857 "$name <$email>" eq ident_person($name);
858 $time_tz =~ /^\d+ [+-]\d{4}$/;
860 =cut
862 sub ident {
863 my ($self, $type) = _maybe_self(@_);
864 my $identstr;
865 if (lc $type eq lc 'committer' or lc $type eq lc 'author') {
866 my @cmd = ('var', 'GIT_'.uc($type).'_IDENT');
867 unshift @cmd, $self if $self;
868 $identstr = command_oneline(@cmd);
869 } else {
870 $identstr = $type;
872 if (wantarray) {
873 return $identstr =~ /^(.*) <(.*)> (\d+ [+-]\d{4})$/;
874 } else {
875 return $identstr;
879 sub ident_person {
880 my ($self, @ident) = _maybe_self(@_);
881 $#ident == 0 and @ident = $self ? $self->ident($ident[0]) : ident($ident[0]);
882 return "$ident[0] <$ident[1]>";
885 =item hash_object ( TYPE, FILENAME )
887 Compute the SHA1 object id of the given C<FILENAME> considering it is
888 of the C<TYPE> object type (C<blob>, C<commit>, C<tree>).
890 The method can be called without any instance or on a specified Git repository,
891 it makes zero difference.
893 The function returns the SHA1 hash.
895 =cut
897 # TODO: Support for passing FILEHANDLE instead of FILENAME
898 sub hash_object {
899 my ($self, $type, $file) = _maybe_self(@_);
900 command_oneline('hash-object', '-t', $type, $file);
904 =item hash_and_insert_object ( FILENAME )
906 Compute the SHA1 object id of the given C<FILENAME> and add the object to the
907 object database.
909 The function returns the SHA1 hash.
911 =cut
913 # TODO: Support for passing FILEHANDLE instead of FILENAME
914 sub hash_and_insert_object {
915 my ($self, $filename) = @_;
917 carp "Bad filename \"$filename\"" if $filename =~ /[\r\n]/;
919 $self->_open_hash_and_insert_object_if_needed();
920 my ($in, $out) = ($self->{hash_object_in}, $self->{hash_object_out});
922 unless (print $out $filename, "\n") {
923 $self->_close_hash_and_insert_object();
924 throw Error::Simple("out pipe went bad");
927 chomp(my $hash = <$in>);
928 unless (defined($hash)) {
929 $self->_close_hash_and_insert_object();
930 throw Error::Simple("in pipe went bad");
933 return $hash;
936 sub _open_hash_and_insert_object_if_needed {
937 my ($self) = @_;
939 return if defined($self->{hash_object_pid});
941 ($self->{hash_object_pid}, $self->{hash_object_in},
942 $self->{hash_object_out}, $self->{hash_object_ctx}) =
943 $self->command_bidi_pipe(qw(hash-object -w --stdin-paths --no-filters));
946 sub _close_hash_and_insert_object {
947 my ($self) = @_;
949 return unless defined($self->{hash_object_pid});
951 my @vars = map { 'hash_object_' . $_ } qw(pid in out ctx);
953 command_close_bidi_pipe(@$self{@vars});
954 delete @$self{@vars};
957 =item cat_blob ( SHA1, FILEHANDLE )
959 Prints the contents of the blob identified by C<SHA1> to C<FILEHANDLE> and
960 returns the number of bytes printed.
962 =cut
964 sub cat_blob {
965 my ($self, $sha1, $fh) = @_;
967 $self->_open_cat_blob_if_needed();
968 my ($in, $out) = ($self->{cat_blob_in}, $self->{cat_blob_out});
970 unless (print $out $sha1, "\n") {
971 $self->_close_cat_blob();
972 throw Error::Simple("out pipe went bad");
975 my $description = <$in>;
976 if ($description =~ / missing$/) {
977 carp "$sha1 doesn't exist in the repository";
978 return -1;
981 if ($description !~ /^[0-9a-fA-F]{40} \S+ (\d+)$/) {
982 carp "Unexpected result returned from git cat-file";
983 return -1;
986 my $size = $1;
988 my $blob;
989 my $bytesLeft = $size;
991 while (1) {
992 last unless $bytesLeft;
994 my $bytesToRead = $bytesLeft < 1024 ? $bytesLeft : 1024;
995 my $read = read($in, $blob, $bytesToRead);
996 unless (defined($read)) {
997 $self->_close_cat_blob();
998 throw Error::Simple("in pipe went bad");
1000 unless (print $fh $blob) {
1001 $self->_close_cat_blob();
1002 throw Error::Simple("couldn't write to passed in filehandle");
1004 $bytesLeft -= $read;
1007 # Skip past the trailing newline.
1008 my $newline;
1009 my $read = read($in, $newline, 1);
1010 unless (defined($read)) {
1011 $self->_close_cat_blob();
1012 throw Error::Simple("in pipe went bad");
1014 unless ($read == 1 && $newline eq "\n") {
1015 $self->_close_cat_blob();
1016 throw Error::Simple("didn't find newline after blob");
1019 return $size;
1022 sub _open_cat_blob_if_needed {
1023 my ($self) = @_;
1025 return if defined($self->{cat_blob_pid});
1027 ($self->{cat_blob_pid}, $self->{cat_blob_in},
1028 $self->{cat_blob_out}, $self->{cat_blob_ctx}) =
1029 $self->command_bidi_pipe(qw(cat-file --batch));
1032 sub _close_cat_blob {
1033 my ($self) = @_;
1035 return unless defined($self->{cat_blob_pid});
1037 my @vars = map { 'cat_blob_' . $_ } qw(pid in out ctx);
1039 command_close_bidi_pipe(@$self{@vars});
1040 delete @$self{@vars};
1044 =item credential_read( FILEHANDLE )
1046 Reads credential key-value pairs from C<FILEHANDLE>. Reading stops at EOF or
1047 when an empty line is encountered. Each line must be of the form C<key=value>
1048 with a non-empty key. Function returns hash with all read values. Any white
1049 space (other than new-line character) is preserved.
1051 =cut
1053 sub credential_read {
1054 my ($self, $reader) = _maybe_self(@_);
1055 my %credential;
1056 while (<$reader>) {
1057 chomp;
1058 if ($_ eq '') {
1059 last;
1060 } elsif (!/^([^=]+)=(.*)$/) {
1061 throw Error::Simple("unable to parse git credential data:\n$_");
1063 $credential{$1} = $2;
1065 return %credential;
1068 =item credential_write( FILEHANDLE, CREDENTIAL_HASHREF )
1070 Writes credential key-value pairs from hash referenced by
1071 C<CREDENTIAL_HASHREF> to C<FILEHANDLE>. Keys and values cannot contain
1072 new-lines or NUL bytes characters, and key cannot contain equal signs nor be
1073 empty (if they do Error::Simple is thrown). Any white space is preserved. If
1074 value for a key is C<undef>, it will be skipped.
1076 If C<'url'> key exists it will be written first. (All the other key-value
1077 pairs are written in sorted order but you should not depend on that). Once
1078 all lines are written, an empty line is printed.
1080 =cut
1082 sub credential_write {
1083 my ($self, $writer, $credential) = _maybe_self(@_);
1084 my ($key, $value);
1086 # Check if $credential is valid prior to writing anything
1087 while (($key, $value) = each %$credential) {
1088 if (!defined $key || !length $key) {
1089 throw Error::Simple("credential key empty or undefined");
1090 } elsif ($key =~ /[=\n\0]/) {
1091 throw Error::Simple("credential key contains invalid characters: $key");
1092 } elsif (defined $value && $value =~ /[\n\0]/) {
1093 throw Error::Simple("credential value for key=$key contains invalid characters: $value");
1097 for $key (sort {
1098 # url overwrites other fields, so it must come first
1099 return -1 if $a eq 'url';
1100 return 1 if $b eq 'url';
1101 return $a cmp $b;
1102 } keys %$credential) {
1103 if (defined $credential->{$key}) {
1104 print $writer $key, '=', $credential->{$key}, "\n";
1107 print $writer "\n";
1110 sub _credential_run {
1111 my ($self, $credential, $op) = _maybe_self(@_);
1112 my ($pid, $reader, $writer, $ctx) = command_bidi_pipe('credential', $op);
1114 credential_write $writer, $credential;
1115 close $writer;
1117 if ($op eq "fill") {
1118 %$credential = credential_read $reader;
1120 if (<$reader>) {
1121 throw Error::Simple("unexpected output from git credential $op response:\n$_\n");
1124 command_close_bidi_pipe($pid, $reader, undef, $ctx);
1127 =item credential( CREDENTIAL_HASHREF [, OPERATION ] )
1129 =item credential( CREDENTIAL_HASHREF, CODE )
1131 Executes C<git credential> for a given set of credentials and specified
1132 operation. In both forms C<CREDENTIAL_HASHREF> needs to be a reference to
1133 a hash which stores credentials. Under certain conditions the hash can
1134 change.
1136 In the first form, C<OPERATION> can be C<'fill'>, C<'approve'> or C<'reject'>,
1137 and function will execute corresponding C<git credential> sub-command. If
1138 it's omitted C<'fill'> is assumed. In case of C<'fill'> the values stored in
1139 C<CREDENTIAL_HASHREF> will be changed to the ones returned by the C<git
1140 credential fill> command. The usual usage would look something like:
1142 my %cred = (
1143 'protocol' => 'https',
1144 'host' => 'example.com',
1145 'username' => 'bob'
1147 Git::credential \%cred;
1148 if (try_to_authenticate($cred{'username'}, $cred{'password'})) {
1149 Git::credential \%cred, 'approve';
1150 ... do more stuff ...
1151 } else {
1152 Git::credential \%cred, 'reject';
1155 In the second form, C<CODE> needs to be a reference to a subroutine. The
1156 function will execute C<git credential fill> to fill the provided credential
1157 hash, then call C<CODE> with C<CREDENTIAL_HASHREF> as the sole argument. If
1158 C<CODE>'s return value is defined, the function will execute C<git credential
1159 approve> (if return value yields true) or C<git credential reject> (if return
1160 value is false). If the return value is undef, nothing at all is executed;
1161 this is useful, for example, if the credential could neither be verified nor
1162 rejected due to an unrelated network error. The return value is the same as
1163 what C<CODE> returns. With this form, the usage might look as follows:
1165 if (Git::credential {
1166 'protocol' => 'https',
1167 'host' => 'example.com',
1168 'username' => 'bob'
1169 }, sub {
1170 my $cred = shift;
1171 return !!try_to_authenticate($cred->{'username'},
1172 $cred->{'password'});
1173 }) {
1174 ... do more stuff ...
1177 =cut
1179 sub credential {
1180 my ($self, $credential, $op_or_code) = (_maybe_self(@_), 'fill');
1182 if ('CODE' eq ref $op_or_code) {
1183 _credential_run $credential, 'fill';
1184 my $ret = $op_or_code->($credential);
1185 if (defined $ret) {
1186 _credential_run $credential, $ret ? 'approve' : 'reject';
1188 return $ret;
1189 } else {
1190 _credential_run $credential, $op_or_code;
1194 { # %TEMP_* Lexical Context
1196 my (%TEMP_FILEMAP, %TEMP_FILES);
1198 =item temp_acquire ( NAME )
1200 Attempts to retrieve the temporary file mapped to the string C<NAME>. If an
1201 associated temp file has not been created this session or was closed, it is
1202 created, cached, and set for autoflush and binmode.
1204 Internally locks the file mapped to C<NAME>. This lock must be released with
1205 C<temp_release()> when the temp file is no longer needed. Subsequent attempts
1206 to retrieve temporary files mapped to the same C<NAME> while still locked will
1207 cause an error. This locking mechanism provides a weak guarantee and is not
1208 threadsafe. It does provide some error checking to help prevent temp file refs
1209 writing over one another.
1211 In general, the L<File::Handle> returned should not be closed by consumers as
1212 it defeats the purpose of this caching mechanism. If you need to close the temp
1213 file handle, then you should use L<File::Temp> or another temp file faculty
1214 directly. If a handle is closed and then requested again, then a warning will
1215 issue.
1217 =cut
1219 sub temp_acquire {
1220 my $temp_fd = _temp_cache(@_);
1222 $TEMP_FILES{$temp_fd}{locked} = 1;
1223 $temp_fd;
1226 =item temp_is_locked ( NAME )
1228 Returns true if the internal lock created by a previous C<temp_acquire()>
1229 call with C<NAME> is still in effect.
1231 When temp_acquire is called on a C<NAME>, it internally locks the temporary
1232 file mapped to C<NAME>. That lock will not be released until C<temp_release()>
1233 is called with either the original C<NAME> or the L<File::Handle> that was
1234 returned from the original call to temp_acquire.
1236 Subsequent attempts to call C<temp_acquire()> with the same C<NAME> will fail
1237 unless there has been an intervening C<temp_release()> call for that C<NAME>
1238 (or its corresponding L<File::Handle> that was returned by the original
1239 C<temp_acquire()> call).
1241 If true is returned by C<temp_is_locked()> for a C<NAME>, an attempt to
1242 C<temp_acquire()> the same C<NAME> will cause an error unless
1243 C<temp_release> is first called on that C<NAME> (or its corresponding
1244 L<File::Handle> that was returned by the original C<temp_acquire()> call).
1246 =cut
1248 sub temp_is_locked {
1249 my ($self, $name) = _maybe_self(@_);
1250 my $temp_fd = \$TEMP_FILEMAP{$name};
1252 defined $$temp_fd && $$temp_fd->opened && $TEMP_FILES{$$temp_fd}{locked};
1255 =item temp_release ( NAME )
1257 =item temp_release ( FILEHANDLE )
1259 Releases a lock acquired through C<temp_acquire()>. Can be called either with
1260 the C<NAME> mapping used when acquiring the temp file or with the C<FILEHANDLE>
1261 referencing a locked temp file.
1263 Warns if an attempt is made to release a file that is not locked.
1265 The temp file will be truncated before being released. This can help to reduce
1266 disk I/O where the system is smart enough to detect the truncation while data
1267 is in the output buffers. Beware that after the temp file is released and
1268 truncated, any operations on that file may fail miserably until it is
1269 re-acquired. All contents are lost between each release and acquire mapped to
1270 the same string.
1272 =cut
1274 sub temp_release {
1275 my ($self, $temp_fd, $trunc) = _maybe_self(@_);
1277 if (exists $TEMP_FILEMAP{$temp_fd}) {
1278 $temp_fd = $TEMP_FILES{$temp_fd};
1280 unless ($TEMP_FILES{$temp_fd}{locked}) {
1281 carp "Attempt to release temp file '",
1282 $temp_fd, "' that has not been locked";
1284 temp_reset($temp_fd) if $trunc and $temp_fd->opened;
1286 $TEMP_FILES{$temp_fd}{locked} = 0;
1287 undef;
1290 sub _temp_cache {
1291 my ($self, $name) = _maybe_self(@_);
1293 my $temp_fd = \$TEMP_FILEMAP{$name};
1294 if (defined $$temp_fd and $$temp_fd->opened) {
1295 if ($TEMP_FILES{$$temp_fd}{locked}) {
1296 throw Error::Simple("Temp file with moniker '" .
1297 $name . "' already in use");
1299 } else {
1300 if (defined $$temp_fd) {
1301 # then we're here because of a closed handle.
1302 carp "Temp file '", $name,
1303 "' was closed. Opening replacement.";
1305 my $fname;
1307 my $tmpdir;
1308 if (defined $self) {
1309 $tmpdir = $self->repo_path();
1312 my $n = $name;
1313 $n =~ s/\W/_/g; # no strange chars
1315 ($$temp_fd, $fname) = File::Temp::tempfile(
1316 "Git_${n}_XXXXXX", UNLINK => 1, DIR => $tmpdir,
1317 ) or throw Error::Simple("couldn't open new temp file");
1319 $$temp_fd->autoflush;
1320 binmode $$temp_fd;
1321 $TEMP_FILES{$$temp_fd}{fname} = $fname;
1323 $$temp_fd;
1326 =item temp_reset ( FILEHANDLE )
1328 Truncates and resets the position of the C<FILEHANDLE>.
1330 =cut
1332 sub temp_reset {
1333 my ($self, $temp_fd) = _maybe_self(@_);
1335 truncate $temp_fd, 0
1336 or throw Error::Simple("couldn't truncate file");
1337 sysseek($temp_fd, 0, SEEK_SET) and seek($temp_fd, 0, SEEK_SET)
1338 or throw Error::Simple("couldn't seek to beginning of file");
1339 sysseek($temp_fd, 0, SEEK_CUR) == 0 and tell($temp_fd) == 0
1340 or throw Error::Simple("expected file position to be reset");
1343 =item temp_path ( NAME )
1345 =item temp_path ( FILEHANDLE )
1347 Returns the filename associated with the given tempfile.
1349 =cut
1351 sub temp_path {
1352 my ($self, $temp_fd) = _maybe_self(@_);
1354 if (exists $TEMP_FILEMAP{$temp_fd}) {
1355 $temp_fd = $TEMP_FILEMAP{$temp_fd};
1357 $TEMP_FILES{$temp_fd}{fname};
1360 sub END {
1361 unlink values %TEMP_FILEMAP if %TEMP_FILEMAP;
1364 } # %TEMP_* Lexical Context
1366 =item prefix_lines ( PREFIX, STRING [, STRING... ])
1368 Prefixes lines in C<STRING> with C<PREFIX>.
1370 =cut
1372 sub prefix_lines {
1373 my $prefix = shift;
1374 my $string = join("\n", @_);
1375 $string =~ s/^/$prefix/mg;
1376 return $string;
1379 =item unquote_path ( PATH )
1381 Unquote a quoted path containing c-escapes as returned by ls-files etc.
1382 when not using -z or when parsing the output of diff -u.
1384 =cut
1387 my %cquote_map = (
1388 "a" => chr(7),
1389 "b" => chr(8),
1390 "t" => chr(9),
1391 "n" => chr(10),
1392 "v" => chr(11),
1393 "f" => chr(12),
1394 "r" => chr(13),
1395 "\\" => "\\",
1396 "\042" => "\042",
1399 sub unquote_path {
1400 local ($_) = @_;
1401 my ($retval, $remainder);
1402 if (!/^\042(.*)\042$/) {
1403 return $_;
1405 ($_, $retval) = ($1, "");
1406 while (/^([^\\]*)\\(.*)$/) {
1407 $remainder = $2;
1408 $retval .= $1;
1409 for ($remainder) {
1410 if (/^([0-3][0-7][0-7])(.*)$/) {
1411 $retval .= chr(oct($1));
1412 $_ = $2;
1413 last;
1415 if (/^([\\\042abtnvfr])(.*)$/) {
1416 $retval .= $cquote_map{$1};
1417 $_ = $2;
1418 last;
1420 # This is malformed
1421 throw Error::Simple("invalid quoted path $_[0]");
1423 $_ = $remainder;
1425 $retval .= $_;
1426 return $retval;
1430 =item get_comment_line_char ( )
1432 Gets the core.commentchar configuration value.
1433 The value falls-back to '#' if core.commentchar is set to 'auto'.
1435 =cut
1437 sub get_comment_line_char {
1438 my $comment_line_char = config("core.commentchar") || '#';
1439 $comment_line_char = '#' if ($comment_line_char eq 'auto');
1440 $comment_line_char = '#' if (length($comment_line_char) != 1);
1441 return $comment_line_char;
1444 =item comment_lines ( STRING [, STRING... ])
1446 Comments lines following core.commentchar configuration.
1448 =cut
1450 sub comment_lines {
1451 my $comment_line_char = get_comment_line_char;
1452 return prefix_lines("$comment_line_char ", @_);
1455 =back
1457 =head1 ERROR HANDLING
1459 All functions are supposed to throw Perl exceptions in case of errors.
1460 See the L<Error> module on how to catch those. Most exceptions are mere
1461 L<Error::Simple> instances.
1463 However, the C<command()>, C<command_oneline()> and C<command_noisy()>
1464 functions suite can throw C<Git::Error::Command> exceptions as well: those are
1465 thrown when the external command returns an error code and contain the error
1466 code as well as access to the captured command's output. The exception class
1467 provides the usual C<stringify> and C<value> (command's exit code) methods and
1468 in addition also a C<cmd_output> method that returns either an array or a
1469 string with the captured command output (depending on the original function
1470 call context; C<command_noisy()> returns C<undef>) and $<cmdline> which
1471 returns the command and its arguments (but without proper quoting).
1473 Note that the C<command_*_pipe()> functions cannot throw this exception since
1474 it has no idea whether the command failed or not. You will only find out
1475 at the time you C<close> the pipe; if you want to have that automated,
1476 use C<command_close_pipe()>, which can throw the exception.
1478 =cut
1481 package Git::Error::Command;
1483 @Git::Error::Command::ISA = qw(Error);
1485 sub new {
1486 my $self = shift;
1487 my $cmdline = '' . shift;
1488 my $value = 0 + shift;
1489 my $outputref = shift;
1490 my(@args) = ();
1492 local $Error::Depth = $Error::Depth + 1;
1494 push(@args, '-cmdline', $cmdline);
1495 push(@args, '-value', $value);
1496 push(@args, '-outputref', $outputref);
1498 $self->SUPER::new(-text => 'command returned error', @args);
1501 sub stringify {
1502 my $self = shift;
1503 my $text = $self->SUPER::stringify;
1504 $self->cmdline() . ': ' . $text . ': ' . $self->value() . "\n";
1507 sub cmdline {
1508 my $self = shift;
1509 $self->{'-cmdline'};
1512 sub cmd_output {
1513 my $self = shift;
1514 my $ref = $self->{'-outputref'};
1515 defined $ref or undef;
1516 if (ref $ref eq 'ARRAY') {
1517 return @$ref;
1518 } else { # SCALAR
1519 return $$ref;
1524 =over 4
1526 =item git_cmd_try { CODE } ERRMSG
1528 This magical statement will automatically catch any C<Git::Error::Command>
1529 exceptions thrown by C<CODE> and make your program die with C<ERRMSG>
1530 on its lips; the message will have %s substituted for the command line
1531 and %d for the exit status. This statement is useful mostly for producing
1532 more user-friendly error messages.
1534 In case of no exception caught the statement returns C<CODE>'s return value.
1536 Note that this is the only auto-exported function.
1538 =cut
1540 sub git_cmd_try(&$) {
1541 my ($code, $errmsg) = @_;
1542 my @result;
1543 my $err;
1544 my $array = wantarray;
1545 try {
1546 if ($array) {
1547 @result = &$code;
1548 } else {
1549 $result[0] = &$code;
1551 } catch Git::Error::Command with {
1552 my $E = shift;
1553 $err = $errmsg;
1554 $err =~ s/\%s/$E->cmdline()/ge;
1555 $err =~ s/\%d/$E->value()/ge;
1556 # We can't croak here since Error.pm would mangle
1557 # that to Error::Simple.
1559 $err and croak $err;
1560 return $array ? @result : $result[0];
1564 =back
1566 =head1 COPYRIGHT
1568 Copyright 2006 by Petr Baudis E<lt>pasky@suse.czE<gt>.
1570 This module is free software; it may be used, copied, modified
1571 and distributed under the terms of the GNU General Public Licence,
1572 either version 2, or (at your option) any later version.
1574 =cut
1577 # Take raw method argument list and return ($obj, @args) in case
1578 # the method was called upon an instance and (undef, @args) if
1579 # it was called directly.
1580 sub _maybe_self {
1581 UNIVERSAL::isa($_[0], 'Git') ? @_ : (undef, @_);
1584 # Check if the command id is something reasonable.
1585 sub _check_valid_cmd {
1586 my ($cmd) = @_;
1587 $cmd =~ /^[a-z0-9A-Z_-]+$/ or throw Error::Simple("bad command: $cmd");
1590 # Common backend for the pipe creators.
1591 sub _command_common_pipe {
1592 my $direction = shift;
1593 my ($self, @p) = _maybe_self(@_);
1594 my (%opts, $cmd, @args);
1595 if (ref $p[0]) {
1596 ($cmd, @args) = @{shift @p};
1597 %opts = ref $p[0] ? %{$p[0]} : @p;
1598 } else {
1599 ($cmd, @args) = @p;
1601 _check_valid_cmd($cmd);
1603 my $fh;
1604 if ($^O eq 'MSWin32') {
1605 # ActiveState Perl
1606 #defined $opts{STDERR} and
1607 # warn 'ignoring STDERR option - running w/ ActiveState';
1608 $direction eq '-|' or
1609 die 'input pipe for ActiveState not implemented';
1610 # the strange construction with *ACPIPE is just to
1611 # explain the tie below that we want to bind to
1612 # a handle class, not scalar. It is not known if
1613 # it is something specific to ActiveState Perl or
1614 # just a Perl quirk.
1615 tie (*ACPIPE, 'Git::activestate_pipe', $cmd, @args);
1616 $fh = *ACPIPE;
1618 } else {
1619 my $pid = open($fh, $direction);
1620 if (not defined $pid) {
1621 throw Error::Simple("open failed: $!");
1622 } elsif ($pid == 0) {
1623 if ($opts{STDERR}) {
1624 open (STDERR, '>&', $opts{STDERR})
1625 or die "dup failed: $!";
1626 } elsif (defined $opts{STDERR}) {
1627 open (STDERR, '>', '/dev/null')
1628 or die "opening /dev/null failed: $!";
1630 _cmd_exec($self, $cmd, @args);
1633 return wantarray ? ($fh, join(' ', $cmd, @args)) : $fh;
1636 # When already in the subprocess, set up the appropriate state
1637 # for the given repository and execute the git command.
1638 sub _cmd_exec {
1639 my ($self, @args) = @_;
1640 _setup_git_cmd_env($self);
1641 _execv_git_cmd(@args);
1642 die qq[exec "@args" failed: $!];
1645 # set up the appropriate state for git command
1646 sub _setup_git_cmd_env {
1647 my $self = shift;
1648 if ($self) {
1649 $self->repo_path() and $ENV{'GIT_DIR'} = $self->repo_path();
1650 $self->repo_path() and $self->wc_path()
1651 and $ENV{'GIT_WORK_TREE'} = $self->wc_path();
1652 $self->wc_path() and chdir($self->wc_path());
1653 $self->wc_subdir() and chdir($self->wc_subdir());
1657 # Execute the given Git command ($_[0]) with arguments ($_[1..])
1658 # by searching for it at proper places.
1659 sub _execv_git_cmd { exec('git', @_); }
1661 # Close pipe to a subprocess.
1662 sub _cmd_close {
1663 my $ctx = shift @_;
1664 foreach my $fh (@_) {
1665 if (close $fh) {
1666 # nop
1667 } elsif ($!) {
1668 # It's just close, no point in fatalities
1669 carp "error closing pipe: $!";
1670 } elsif ($? >> 8) {
1671 # The caller should pepper this.
1672 throw Git::Error::Command($ctx, $? >> 8);
1674 # else we might e.g. closed a live stream; the command
1675 # dying of SIGPIPE would drive us here.
1680 sub DESTROY {
1681 my ($self) = @_;
1682 $self->_close_hash_and_insert_object();
1683 $self->_close_cat_blob();
1687 # Pipe implementation for ActiveState Perl.
1689 package Git::activestate_pipe;
1691 sub TIEHANDLE {
1692 my ($class, @params) = @_;
1693 # FIXME: This is probably horrible idea and the thing will explode
1694 # at the moment you give it arguments that require some quoting,
1695 # but I have no ActiveState clue... --pasky
1696 # Let's just hope ActiveState Perl does at least the quoting
1697 # correctly.
1698 my @data = qx{git @params};
1699 bless { i => 0, data => \@data }, $class;
1702 sub READLINE {
1703 my $self = shift;
1704 if ($self->{i} >= scalar @{$self->{data}}) {
1705 return undef;
1707 my $i = $self->{i};
1708 if (wantarray) {
1709 $self->{i} = $#{$self->{'data'}} + 1;
1710 return splice(@{$self->{'data'}}, $i);
1712 $self->{i} = $i + 1;
1713 return $self->{'data'}->[ $i ];
1716 sub CLOSE {
1717 my $self = shift;
1718 delete $self->{data};
1719 delete $self->{i};
1722 sub EOF {
1723 my $self = shift;
1724 return ($self->{i} >= scalar @{$self->{data}});
1728 1; # Famous last words