git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "smtp-server=s" => \$smtp_server,
 303                     "smtp-server-option=s" => \@smtp_server_options,
 304                     "smtp-server-port=s" => \$smtp_server_port,
 305                     "smtp-user=s" => \$smtp_authuser,
 306                     "smtp-pass:s" => \$smtp_authpass,
 307                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 308                     "smtp-encryption=s" => \$smtp_encryption,
 309                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 310                     "smtp-debug:i" => \$debug_net_smtp,
 311                     "smtp-domain:s" => \$smtp_domain,
 312                     "identity=s" => \$identity,
 313                     "annotate!" => \$annotate,
 314                     "compose" => \$compose,
 315                     "quiet" => \$quiet,
 316                     "cc-cmd=s" => \$cc_cmd,
 317                     "suppress-from!" => \$suppress_from,
 318                     "suppress-cc=s" => \@suppress_cc,
 319                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 320                     "cc-cover|cc-cover!" => \$cover_cc,
 321                     "to-cover|to-cover!" => \$cover_to,
 322                     "confirm=s" => \$confirm,
 323                     "dry-run" => \$dry_run,
 324                     "envelope-sender=s" => \$envelope_sender,
 325                     "thread!" => \$thread,
 326                     "validate!" => \$validate,
 327                     "transfer-encoding=s" => \$target_xfer_encoding,
 328                     "format-patch!" => \$format_patch,
 329                     "8bit-encoding=s" => \$auto_8bit_encoding,
 330                     "compose-encoding=s" => \$compose_encoding,
 331                     "force" => \$force,
 332                     "xmailer!" => \$use_xmailer,
 333          );
 334
 335 usage() if $help;
 336 unless ($rc) {
 337     usage();
 338 }
 339
 340 die "Cannot run git format-patch from outside a repository\n"
 341         if $format_patch and not $repo;
 342
 343 # Now, let's fill any that aren't set in with defaults:
 344
 345 sub read_config {
 346         my ($prefix) = @_;
 347
 348         foreach my $setting (keys %config_bool_settings) {
 349                 my $target = $config_bool_settings{$setting}->[0];
 350                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 351         }
 352
 353         foreach my $setting (keys %config_path_settings) {
 354                 my $target = $config_path_settings{$setting};
 355                 if (ref($target) eq "ARRAY") {
 356                         unless (@$target) {
 357                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 358                                 @$target = @values if (@values && defined $values[0]);
 359                         }
 360                 }
 361                 else {
 362                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 363                 }
 364         }
 365
 366         foreach my $setting (keys %config_settings) {
 367                 my $target = $config_settings{$setting};
 368                 next if $setting eq "to" and defined $no_to;
 369                 next if $setting eq "cc" and defined $no_cc;
 370                 next if $setting eq "bcc" and defined $no_bcc;
 371                 if (ref($target) eq "ARRAY") {
 372                         unless (@$target) {
 373                                 my @values = Git::config(@repo, "$prefix.$setting");
 374                                 @$target = @values if (@values && defined $values[0]);
 375                         }
 376                 }
 377                 else {
 378                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 379                 }
 380         }
 381
 382         if (!defined $smtp_encryption) {
 383                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 384                 if (defined $enc) {
 385                         $smtp_encryption = $enc;
 386                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 387                         $smtp_encryption = 'ssl';
 388                 }
 389         }
 390 }
 391
 392 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 393 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 394 read_config("sendemail.$identity") if (defined $identity);
 395 read_config("sendemail");
 396
 397 # fall back on builtin bool defaults
 398 foreach my $setting (values %config_bool_settings) {
 399         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 400 }
 401
 402 # 'default' encryption is none -- this only prevents a warning
 403 $smtp_encryption = '' unless (defined $smtp_encryption);
 404
 405 # Set CC suppressions
 406 my(%suppress_cc);
 407 if (@suppress_cc) {
 408         foreach my $entry (@suppress_cc) {
 409                 die "Unknown --suppress-cc field: '$entry'\n"
 410                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 411                 $suppress_cc{$entry} = 1;
 412         }
 413 }
 414
 415 if ($suppress_cc{'all'}) {
 416         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 417                 $suppress_cc{$entry} = 1;
 418         }
 419         delete $suppress_cc{'all'};
 420 }
 421
 422 # If explicit old-style ones are specified, they trump --suppress-cc.
 423 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 424 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 425
 426 if ($suppress_cc{'body'}) {
 427         foreach my $entry (qw (sob bodycc)) {
 428                 $suppress_cc{$entry} = 1;
 429         }
 430         delete $suppress_cc{'body'};
 431 }
 432
 433 # Set confirm's default value
 434 my $confirm_unconfigured = !defined $confirm;
 435 if ($confirm_unconfigured) {
 436         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 437 };
 438 die "Unknown --confirm setting: '$confirm'\n"
 439         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 440
 441 # Debugging, print out the suppressions.
 442 if (0) {
 443         print "suppressions:\n";
 444         foreach my $entry (keys %suppress_cc) {
 445                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 446         }
 447 }
 448
 449 my ($repoauthor, $repocommitter);
 450 ($repoauthor) = Git::ident_person(@repo, 'author');
 451 ($repocommitter) = Git::ident_person(@repo, 'committer');
 452
 453 # Verify the user input
 454
 455 foreach my $entry (@initial_to) {
 456         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 457 }
 458
 459 foreach my $entry (@initial_cc) {
 460         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 461 }
 462
 463 foreach my $entry (@bcclist) {
 464         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 465 }
 466
 467 sub parse_address_line {
 468         if ($have_mail_address) {
 469                 return map { $_->format } Mail::Address->parse($_[0]);
 470         } else {
 471                 return split_addrs($_[0]);
 472         }
 473 }
 474
 475 sub split_addrs {
 476         return quotewords('\s*,\s*', 1, @_);
 477 }
 478
 479 my %aliases;
 480 my %parse_alias = (
 481         # multiline formats can be supported in the future
 482         mutt => sub { my $fh = shift; while (<$fh>) {
 483                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 484                         my ($alias, $addr) = ($1, $2);
 485                         $addr =~ s/#.*$//; # mutt allows # comments
 486                          # commas delimit multiple addresses
 487                         $aliases{$alias} = [ split_addrs($addr) ];
 488                 }}},
 489         mailrc => sub { my $fh = shift; while (<$fh>) {
 490                 if (/^alias\s+(\S+)\s+(.*)$/) {
 491                         # spaces delimit multiple addresses
 492                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 493                 }}},
 494         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 495                 for (my $x = ''; defined($x); $x = $_) {
 496                         chomp $x;
 497                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 498                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 499                         $aliases{$1} = [ split_addrs($2) ];
 500                 }},
 501         elm => sub  { my $fh = shift;
 502                       while (<$fh>) {
 503                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 504                               my ($alias, $addr) = ($1, $2);
 505                                $aliases{$alias} = [ split_addrs($addr) ];
 506                           }
 507                       } },
 508
 509         gnus => sub { my $fh = shift; while (<$fh>) {
 510                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 511                         $aliases{$1} = [ $2 ];
 512                 }}}
 513 );
 514
 515 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 516         foreach my $file (@alias_files) {
 517                 open my $fh, '<', $file or die "opening $file: $!\n";
 518                 $parse_alias{$aliasfiletype}->($fh);
 519                 close $fh;
 520         }
 521 }
 522
 523 ($sender) = expand_aliases($sender) if defined $sender;
 524
 525 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 526 # $f is a revision list specification to be passed to format-patch.
 527 sub is_format_patch_arg {
 528         return unless $repo;
 529         my $f = shift;
 530         try {
 531                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 532                 if (defined($format_patch)) {
 533                         return $format_patch;
 534                 }
 535                 die(<<EOF);
 536 File '$f' exists but it could also be the range of commits
 537 to produce patches for.  Please disambiguate by...
 538
 539     * Saying "./$f" if you mean a file; or
 540     * Giving --format-patch option if you mean a range.
 541 EOF
 542         } catch Git::Error::Command with {
 543                 # Not a valid revision.  Treat it as a filename.
 544                 return 0;
 545         }
 546 }
 547
 548 # Now that all the defaults are set, process the rest of the command line
 549 # arguments and collect up the files that need to be processed.
 550 my @rev_list_opts;
 551 while (defined(my $f = shift @ARGV)) {
 552         if ($f eq "--") {
 553                 push @rev_list_opts, "--", @ARGV;
 554                 @ARGV = ();
 555         } elsif (-d $f and !is_format_patch_arg($f)) {
 556                 opendir my $dh, $f
 557                         or die "Failed to opendir $f: $!";
 558
 559                 push @files, grep { -f $_ } map { catfile($f, $_) }
 560                                 sort readdir $dh;
 561                 closedir $dh;
 562         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 563                 push @files, $f;
 564         } else {
 565                 push @rev_list_opts, $f;
 566         }
 567 }
 568
 569 if (@rev_list_opts) {
 570         die "Cannot run git format-patch from outside a repository\n"
 571                 unless $repo;
 572         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 573 }
 574
 575 if ($validate) {
 576         foreach my $f (@files) {
 577                 unless (-p $f) {
 578                         my $error = validate_patch($f);
 579                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 580                 }
 581         }
 582 }
 583
 584 if (@files) {
 585         unless ($quiet) {
 586                 print $_,"\n" for (@files);
 587         }
 588 } else {
 589         print STDERR "\nNo patch files specified!\n\n";
 590         usage();
 591 }
 592
 593 sub get_patch_subject {
 594         my $fn = shift;
 595         open (my $fh, '<', $fn);
 596         while (my $line = <$fh>) {
 597                 next unless ($line =~ /^Subject: (.*)$/);
 598                 close $fh;
 599                 return "GIT: $1\n";
 600         }
 601         close $fh;
 602         die "No subject line in $fn ?";
 603 }
 604
 605 if ($compose) {
 606         # Note that this does not need to be secure, but we will make a small
 607         # effort to have it be unique
 608         $compose_filename = ($repo ?
 609                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 610                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 611         open my $c, ">", $compose_filename
 612                 or die "Failed to open for writing $compose_filename: $!";
 613
 614
 615         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 616         my $tpl_subject = $initial_subject || '';
 617         my $tpl_reply_to = $initial_reply_to || '';
 618
 619         print $c <<EOT;
 620 From $tpl_sender # This line is ignored.
 621 GIT: Lines beginning in "GIT:" will be removed.
 622 GIT: Consider including an overall diffstat or table of contents
 623 GIT: for the patch you are writing.
 624 GIT:
 625 GIT: Clear the body content if you don't wish to send a summary.
 626 From: $tpl_sender
 627 Subject: $tpl_subject
 628 In-Reply-To: $tpl_reply_to
 629
 630 EOT
 631         for my $f (@files) {
 632                 print $c get_patch_subject($f);
 633         }
 634         close $c;
 635
 636         if ($annotate) {
 637                 do_edit($compose_filename, @files);
 638         } else {
 639                 do_edit($compose_filename);
 640         }
 641
 642         open my $c2, ">", $compose_filename . ".final"
 643                 or die "Failed to open $compose_filename.final : " . $!;
 644
 645         open $c, "<", $compose_filename
 646                 or die "Failed to open $compose_filename : " . $!;
 647
 648         my $need_8bit_cte = file_has_nonascii($compose_filename);
 649         my $in_body = 0;
 650         my $summary_empty = 1;
 651         if (!defined $compose_encoding) {
 652                 $compose_encoding = "UTF-8";
 653         }
 654         while(<$c>) {
 655                 next if m/^GIT:/;
 656                 if ($in_body) {
 657                         $summary_empty = 0 unless (/^\n$/);
 658                 } elsif (/^\n$/) {
 659                         $in_body = 1;
 660                         if ($need_8bit_cte) {
 661                                 print $c2 "MIME-Version: 1.0\n",
 662                                          "Content-Type: text/plain; ",
 663                                            "charset=$compose_encoding\n",
 664                                          "Content-Transfer-Encoding: 8bit\n";
 665                         }
 666                 } elsif (/^MIME-Version:/i) {
 667                         $need_8bit_cte = 0;
 668                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 669                         $initial_subject = $1;
 670                         my $subject = $initial_subject;
 671                         $_ = "Subject: " .
 672                                 quote_subject($subject, $compose_encoding) .
 673                                 "\n";
 674                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 675                         $initial_reply_to = $1;
 676                         next;
 677                 } elsif (/^From:\s*(.+)\s*$/i) {
 678                         $sender = $1;
 679                         next;
 680                 } elsif (/^(?:To|Cc|Bcc):/i) {
 681                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 682                         next;
 683                 }
 684                 print $c2 $_;
 685         }
 686         close $c;
 687         close $c2;
 688
 689         if ($summary_empty) {
 690                 print "Summary email is empty, skipping it\n";
 691                 $compose = -1;
 692         }
 693 } elsif ($annotate) {
 694         do_edit(@files);
 695 }
 696
 697 sub ask {
 698         my ($prompt, %arg) = @_;
 699         my $valid_re = $arg{valid_re};
 700         my $default = $arg{default};
 701         my $confirm_only = $arg{confirm_only};
 702         my $resp;
 703         my $i = 0;
 704         return defined $default ? $default : undef
 705                 unless defined $term->IN and defined fileno($term->IN) and
 706                        defined $term->OUT and defined fileno($term->OUT);
 707         while ($i++ < 10) {
 708                 $resp = $term->readline($prompt);
 709                 if (!defined $resp) { # EOF
 710                         print "\n";
 711                         return defined $default ? $default : undef;
 712                 }
 713                 if ($resp eq '' and defined $default) {
 714                         return $default;
 715                 }
 716                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 717                         return $resp;
 718                 }
 719                 if ($confirm_only) {
 720                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 721                         if (defined $yesno && $yesno =~ /y/i) {
 722                                 return $resp;
 723                         }
 724                 }
 725         }
 726         return;
 727 }
 728
 729 my %broken_encoding;
 730
 731 sub file_declares_8bit_cte {
 732         my $fn = shift;
 733         open (my $fh, '<', $fn);
 734         while (my $line = <$fh>) {
 735                 last if ($line =~ /^$/);
 736                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 737         }
 738         close $fh;
 739         return 0;
 740 }
 741
 742 foreach my $f (@files) {
 743         next unless (body_or_subject_has_nonascii($f)
 744                      && !file_declares_8bit_cte($f));
 745         $broken_encoding{$f} = 1;
 746 }
 747
 748 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 749         print "The following files are 8bit, but do not declare " .
 750                 "a Content-Transfer-Encoding.\n";
 751         foreach my $f (sort keys %broken_encoding) {
 752                 print "    $f\n";
 753         }
 754         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 755                                   default => "UTF-8");
 756 }
 757
 758 if (!$force) {
 759         for my $f (@files) {
 760                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 761                         die "Refusing to send because the patch\n\t$f\n"
 762                                 . "has the template subject '*** SUBJECT HERE ***'. "
 763                                 . "Pass --force if you really want to send.\n";
 764                 }
 765         }
 766 }
 767
 768 if (!defined $sender) {
 769         $sender = $repoauthor || $repocommitter || '';
 770 }
 771
 772 # $sender could be an already sanitized address
 773 # (e.g. sendemail.from could be manually sanitized by user).
 774 # But it's a no-op to run sanitize_address on an already sanitized address.
 775 $sender = sanitize_address($sender);
 776
 777 my $prompting = 0;
 778 if (!@initial_to && !defined $to_cmd) {
 779         my $to = ask("Who should the emails be sent to (if any)? ",
 780                      default => "",
 781                      valid_re => qr/\@.*\./, confirm_only => 1);
 782         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 783         $prompting++;
 784 }
 785
 786 sub expand_aliases {
 787         return map { expand_one_alias($_) } @_;
 788 }
 789
 790 my %EXPANDED_ALIASES;
 791 sub expand_one_alias {
 792         my $alias = shift;
 793         if ($EXPANDED_ALIASES{$alias}) {
 794                 die "fatal: alias '$alias' expands to itself\n";
 795         }
 796         local $EXPANDED_ALIASES{$alias} = 1;
 797         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 798 }
 799
 800 @initial_to = expand_aliases(@initial_to);
 801 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 802 @initial_cc = expand_aliases(@initial_cc);
 803 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 804 @bcclist = expand_aliases(@bcclist);
 805 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 806
 807 if ($thread && !defined $initial_reply_to && $prompting) {
 808         $initial_reply_to = ask(
 809                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 810                 default => "",
 811                 valid_re => qr/\@.*\./, confirm_only => 1);
 812 }
 813 if (defined $initial_reply_to) {
 814         $initial_reply_to =~ s/^\s*<?//;
 815         $initial_reply_to =~ s/>?\s*$//;
 816         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 817 }
 818
 819 if (!defined $smtp_server) {
 820         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 821                 if (-x $_) {
 822                         $smtp_server = $_;
 823                         last;
 824                 }
 825         }
 826         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 827 }
 828
 829 if ($compose && $compose > 0) {
 830         @files = ($compose_filename . ".final", @files);
 831 }
 832
 833 # Variables we set as part of the loop over files
 834 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 835         $needs_confirm, $message_num, $ask_default);
 836
 837 sub extract_valid_address {
 838         my $address = shift;
 839         my $local_part_regexp = qr/[^<>"\s@]+/;
 840         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 841
 842         # check for a local address:
 843         return $address if ($address =~ /^($local_part_regexp)$/);
 844
 845         $address =~ s/^\s*<(.*)>\s*$/$1/;
 846         if ($have_email_valid) {
 847                 return scalar Email::Valid->address($address);
 848         }
 849
 850         # less robust/correct than the monster regexp in Email::Valid,
 851         # but still does a 99% job, and one less dependency
 852         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 853         return;
 854 }
 855
 856 sub extract_valid_address_or_die {
 857         my $address = shift;
 858         $address = extract_valid_address($address);
 859         die "error: unable to extract a valid address from: $address\n"
 860                 if !$address;
 861         return $address;
 862 }
 863
 864 sub validate_address {
 865         my $address = shift;
 866         while (!extract_valid_address($address)) {
 867                 print STDERR "error: unable to extract a valid address from: $address\n";
 868                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 869                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 870                         default => 'q');
 871                 if (/^d/i) {
 872                         return undef;
 873                 } elsif (/^q/i) {
 874                         cleanup_compose_files();
 875                         exit(0);
 876                 }
 877                 $address = ask("Who should the email be sent to (if any)? ",
 878                         default => "",
 879                         valid_re => qr/\@.*\./, confirm_only => 1);
 880         }
 881         return $address;
 882 }
 883
 884 sub validate_address_list {
 885         return (grep { defined $_ }
 886                 map { validate_address($_) } @_);
 887 }
 888
 889 # Usually don't need to change anything below here.
 890
 891 # we make a "fake" message id by taking the current number
 892 # of seconds since the beginning of Unix time and tacking on
 893 # a random number to the end, in case we are called quicker than
 894 # 1 second since the last time we were called.
 895
 896 # We'll setup a template for the message id, using the "from" address:
 897
 898 my ($message_id_stamp, $message_id_serial);
 899 sub make_message_id {
 900         my $uniq;
 901         if (!defined $message_id_stamp) {
 902                 $message_id_stamp = sprintf("%s-%s", time, $$);
 903                 $message_id_serial = 0;
 904         }
 905         $message_id_serial++;
 906         $uniq = "$message_id_stamp-$message_id_serial";
 907
 908         my $du_part;
 909         for ($sender, $repocommitter, $repoauthor) {
 910                 $du_part = extract_valid_address(sanitize_address($_));
 911                 last if (defined $du_part and $du_part ne '');
 912         }
 913         if (not defined $du_part or $du_part eq '') {
 914                 require Sys::Hostname;
 915                 $du_part = 'user@' . Sys::Hostname::hostname();
 916         }
 917         my $message_id_template = "<%s-git-send-email-%s>";
 918         $message_id = sprintf($message_id_template, $uniq, $du_part);
 919         #print "new message id = $message_id\n"; # Was useful for debugging
 920 }
 921
 922
 923
 924 $time = time - scalar $#files;
 925
 926 sub unquote_rfc2047 {
 927         local ($_) = @_;
 928         my $charset;
 929         my $sep = qr/[ \t]+/;
 930         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 931                 my @words = split $sep, $&;
 932                 foreach (@words) {
 933                         m/$re_encoded_word/;
 934                         $charset = $1;
 935                         my $encoding = $2;
 936                         my $text = $3;
 937                         if ($encoding eq 'q' || $encoding eq 'Q') {
 938                                 $_ = $text;
 939                                 s/_/ /g;
 940                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 941                         } else {
 942                                 # other encodings not supported yet
 943                         }
 944                 }
 945                 join '', @words;
 946         }eg;
 947         return wantarray ? ($_, $charset) : $_;
 948 }
 949
 950 sub quote_rfc2047 {
 951         local $_ = shift;
 952         my $encoding = shift || 'UTF-8';
 953         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 954         s/(.*)/=\?$encoding\?q\?$1\?=/;
 955         return $_;
 956 }
 957
 958 sub is_rfc2047_quoted {
 959         my $s = shift;
 960         length($s) <= 75 &&
 961         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 962 }
 963
 964 sub subject_needs_rfc2047_quoting {
 965         my $s = shift;
 966
 967         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 968 }
 969
 970 sub quote_subject {
 971         local $subject = shift;
 972         my $encoding = shift || 'UTF-8';
 973
 974         if (subject_needs_rfc2047_quoting($subject)) {
 975                 return quote_rfc2047($subject, $encoding);
 976         }
 977         return $subject;
 978 }
 979
 980 # use the simplest quoting being able to handle the recipient
 981 sub sanitize_address {
 982         my ($recipient) = @_;
 983
 984         # remove garbage after email address
 985         $recipient =~ s/(.*>).*$/$1/;
 986
 987         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 988
 989         if (not $recipient_name) {
 990                 return $recipient;
 991         }
 992
 993         # if recipient_name is already quoted, do nothing
 994         if (is_rfc2047_quoted($recipient_name)) {
 995                 return $recipient;
 996         }
 997
 998         # rfc2047 is needed if a non-ascii char is included
 999         if ($recipient_name =~ /[^[:ascii:]]/) {
1000                 $recipient_name =~ s/^"(.*)"$/$1/;
1001                 $recipient_name = quote_rfc2047($recipient_name);
1002         }
1003
1004         # double quotes are needed if specials or CTLs are included
1005         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1006                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1007                 $recipient_name = qq["$recipient_name"];
1008         }
1009
1010         return "$recipient_name $recipient_addr";
1011
1012 }
1013
1014 sub sanitize_address_list {
1015         return (map { sanitize_address($_) } @_);
1016 }
1017
1018 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1019 #
1020 # Tightly configured MTAa require that a caller sends a real DNS
1021 # domain name that corresponds the IP address in the HELO/EHLO
1022 # handshake. This is used to verify the connection and prevent
1023 # spammers from trying to hide their identity. If the DNS and IP don't
1024 # match, the receiveing MTA may deny the connection.
1025 #
1026 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1027 #
1028 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1029 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1030 #
1031 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1032 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1033
1034 sub valid_fqdn {
1035         my $domain = shift;
1036         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1037 }
1038
1039 sub maildomain_net {
1040         my $maildomain;
1041
1042         if (eval { require Net::Domain; 1 }) {
1043                 my $domain = Net::Domain::domainname();
1044                 $maildomain = $domain if valid_fqdn($domain);
1045         }
1046
1047         return $maildomain;
1048 }
1049
1050 sub maildomain_mta {
1051         my $maildomain;
1052
1053         if (eval { require Net::SMTP; 1 }) {
1054                 for my $host (qw(mailhost localhost)) {
1055                         my $smtp = Net::SMTP->new($host);
1056                         if (defined $smtp) {
1057                                 my $domain = $smtp->domain;
1058                                 $smtp->quit;
1059
1060                                 $maildomain = $domain if valid_fqdn($domain);
1061
1062                                 last if $maildomain;
1063                         }
1064                 }
1065         }
1066
1067         return $maildomain;
1068 }
1069
1070 sub maildomain {
1071         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1072 }
1073
1074 sub smtp_host_string {
1075         if (defined $smtp_server_port) {
1076                 return "$smtp_server:$smtp_server_port";
1077         } else {
1078                 return $smtp_server;
1079         }
1080 }
1081
1082 # Returns 1 if authentication succeeded or was not necessary
1083 # (smtp_user was not specified), and 0 otherwise.
1084
1085 sub smtp_auth_maybe {
1086         if (!defined $smtp_authuser || $auth) {
1087                 return 1;
1088         }
1089
1090         # Workaround AUTH PLAIN/LOGIN interaction defect
1091         # with Authen::SASL::Cyrus
1092         eval {
1093                 require Authen::SASL;
1094                 Authen::SASL->import(qw(Perl));
1095         };
1096
1097         # TODO: Authentication may fail not because credentials were
1098         # invalid but due to other reasons, in which we should not
1099         # reject credentials.
1100         $auth = Git::credential({
1101                 'protocol' => 'smtp',
1102                 'host' => smtp_host_string(),
1103                 'username' => $smtp_authuser,
1104                 # if there's no password, "git credential fill" will
1105                 # give us one, otherwise it'll just pass this one.
1106                 'password' => $smtp_authpass
1107         }, sub {
1108                 my $cred = shift;
1109                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1110         });
1111
1112         return $auth;
1113 }
1114
1115 sub ssl_verify_params {
1116         eval {
1117                 require IO::Socket::SSL;
1118                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1119         };
1120         if ($@) {
1121                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1122                 return;
1123         }
1124
1125         if (!defined $smtp_ssl_cert_path) {
1126                 # use the OpenSSL defaults
1127                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1128         }
1129
1130         if ($smtp_ssl_cert_path eq "") {
1131                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1132         } elsif (-d $smtp_ssl_cert_path) {
1133                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1134                         SSL_ca_path => $smtp_ssl_cert_path);
1135         } elsif (-f $smtp_ssl_cert_path) {
1136                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1137                         SSL_ca_file => $smtp_ssl_cert_path);
1138         } else {
1139                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1140                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1141         }
1142 }
1143
1144 sub file_name_is_absolute {
1145         my ($path) = @_;
1146
1147         # msys does not grok DOS drive-prefixes
1148         if ($^O eq 'msys') {
1149                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1150         }
1151
1152         require File::Spec::Functions;
1153         return File::Spec::Functions::file_name_is_absolute($path);
1154 }
1155
1156 # Returns 1 if the message was sent, and 0 otherwise.
1157 # In actuality, the whole program dies when there
1158 # is an error sending a message.
1159
1160 sub send_message {
1161         my @recipients = unique_email_list(@to);
1162         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1163                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1164                     }
1165                @cc);
1166         my $to = join (",\n\t", @recipients);
1167         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1168         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1169         my $date = format_2822_time($time++);
1170         my $gitversion = '@@GIT_VERSION@@';
1171         if ($gitversion =~ m/..GIT_VERSION../) {
1172             $gitversion = Git::version();
1173         }
1174
1175         my $cc = join(",\n\t", unique_email_list(@cc));
1176         my $ccline = "";
1177         if ($cc ne '') {
1178                 $ccline = "\nCc: $cc";
1179         }
1180         make_message_id() unless defined($message_id);
1181
1182         my $header = "From: $sender
1183 To: $to${ccline}
1184 Subject: $subject
1185 Date: $date
1186 Message-Id: $message_id
1187 ";
1188         if ($use_xmailer) {
1189                 $header .= "X-Mailer: git-send-email $gitversion\n";
1190         }
1191         if ($reply_to) {
1192
1193                 $header .= "In-Reply-To: $reply_to\n";
1194                 $header .= "References: $references\n";
1195         }
1196         if (@xh) {
1197                 $header .= join("\n", @xh) . "\n";
1198         }
1199
1200         my @sendmail_parameters = ('-i', @recipients);
1201         my $raw_from = $sender;
1202         if (defined $envelope_sender && $envelope_sender ne "auto") {
1203                 $raw_from = $envelope_sender;
1204         }
1205         $raw_from = extract_valid_address($raw_from);
1206         unshift (@sendmail_parameters,
1207                         '-f', $raw_from) if(defined $envelope_sender);
1208
1209         if ($needs_confirm && !$dry_run) {
1210                 print "\n$header\n";
1211                 if ($needs_confirm eq "inform") {
1212                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1213                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1214                         print "    The Cc list above has been expanded by additional\n";
1215                         print "    addresses found in the patch commit message. By default\n";
1216                         print "    send-email prompts before sending whenever this occurs.\n";
1217                         print "    This behavior is controlled by the sendemail.confirm\n";
1218                         print "    configuration setting.\n";
1219                         print "\n";
1220                         print "    For additional information, run 'git send-email --help'.\n";
1221                         print "    To retain the current behavior, but squelch this message,\n";
1222                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1223                 }
1224                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1225                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1226                          default => $ask_default);
1227                 die "Send this email reply required" unless defined $_;
1228                 if (/^n/i) {
1229                         return 0;
1230                 } elsif (/^q/i) {
1231                         cleanup_compose_files();
1232                         exit(0);
1233                 } elsif (/^a/i) {
1234                         $confirm = 'never';
1235                 }
1236         }
1237
1238         unshift (@sendmail_parameters, @smtp_server_options);
1239
1240         if ($dry_run) {
1241                 # We don't want to send the email.
1242         } elsif (file_name_is_absolute($smtp_server)) {
1243                 my $pid = open my $sm, '|-';
1244                 defined $pid or die $!;
1245                 if (!$pid) {
1246                         exec($smtp_server, @sendmail_parameters) or die $!;
1247                 }
1248                 print $sm "$header\n$message";
1249                 close $sm or die $!;
1250         } else {
1251
1252                 if (!defined $smtp_server) {
1253                         die "The required SMTP server is not properly defined."
1254                 }
1255
1256                 if ($smtp_encryption eq 'ssl') {
1257                         $smtp_server_port ||= 465; # ssmtp
1258                         require Net::SMTP::SSL;
1259                         $smtp_domain ||= maildomain();
1260                         require IO::Socket::SSL;
1261                         # Net::SMTP::SSL->new() does not forward any SSL options
1262                         IO::Socket::SSL::set_client_defaults(
1263                                 ssl_verify_params());
1264                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1265                                                       Hello => $smtp_domain,
1266                                                       Port => $smtp_server_port,
1267                                                       Debug => $debug_net_smtp);
1268                 }
1269                 else {
1270                         require Net::SMTP;
1271                         $smtp_domain ||= maildomain();
1272                         $smtp_server_port ||= 25;
1273                         $smtp ||= Net::SMTP->new($smtp_server,
1274                                                  Hello => $smtp_domain,
1275                                                  Debug => $debug_net_smtp,
1276                                                  Port => $smtp_server_port);
1277                         if ($smtp_encryption eq 'tls' && $smtp) {
1278                                 require Net::SMTP::SSL;
1279                                 $smtp->command('STARTTLS');
1280                                 $smtp->response();
1281                                 if ($smtp->code == 220) {
1282                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1283                                                                           ssl_verify_params())
1284                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1285                                         $smtp_encryption = '';
1286                                         # Send EHLO again to receive fresh
1287                                         # supported commands
1288                                         $smtp->hello($smtp_domain);
1289                                 } else {
1290                                         die "Server does not support STARTTLS! ".$smtp->message;
1291                                 }
1292                         }
1293                 }
1294
1295                 if (!$smtp) {
1296                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1297                             "VALUES: server=$smtp_server ",
1298                             "encryption=$smtp_encryption ",
1299                             "hello=$smtp_domain",
1300                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1301                 }
1302
1303                 smtp_auth_maybe or die $smtp->message;
1304
1305                 $smtp->mail( $raw_from ) or die $smtp->message;
1306                 $smtp->to( @recipients ) or die $smtp->message;
1307                 $smtp->data or die $smtp->message;
1308                 $smtp->datasend("$header\n$message") or die $smtp->message;
1309                 $smtp->dataend() or die $smtp->message;
1310                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1311         }
1312         if ($quiet) {
1313                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1314         } else {
1315                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1316                 if (!file_name_is_absolute($smtp_server)) {
1317                         print "Server: $smtp_server\n";
1318                         print "MAIL FROM:<$raw_from>\n";
1319                         foreach my $entry (@recipients) {
1320                             print "RCPT TO:<$entry>\n";
1321                         }
1322                 } else {
1323                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1324                 }
1325                 print $header, "\n";
1326                 if ($smtp) {
1327                         print "Result: ", $smtp->code, ' ',
1328                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1329                 } else {
1330                         print "Result: OK\n";
1331                 }
1332         }
1333
1334         return 1;
1335 }
1336
1337 $reply_to = $initial_reply_to;
1338 $references = $initial_reply_to || '';
1339 $subject = $initial_subject;
1340 $message_num = 0;
1341
1342 foreach my $t (@files) {
1343         open my $fh, "<", $t or die "can't open file $t";
1344
1345         my $author = undef;
1346         my $sauthor = undef;
1347         my $author_encoding;
1348         my $has_content_type;
1349         my $body_encoding;
1350         my $xfer_encoding;
1351         my $has_mime_version;
1352         @to = ();
1353         @cc = ();
1354         @xh = ();
1355         my $input_format = undef;
1356         my @header = ();
1357         $message = "";
1358         $message_num++;
1359         # First unfold multiline header fields
1360         while(<$fh>) {
1361                 last if /^\s*$/;
1362                 if (/^\s+\S/ and @header) {
1363                         chomp($header[$#header]);
1364                         s/^\s+/ /;
1365                         $header[$#header] .= $_;
1366             } else {
1367                         push(@header, $_);
1368                 }
1369         }
1370         # Now parse the header
1371         foreach(@header) {
1372                 if (/^From /) {
1373                         $input_format = 'mbox';
1374                         next;
1375                 }
1376                 chomp;
1377                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1378                         $input_format = 'mbox';
1379                 }
1380
1381                 if (defined $input_format && $input_format eq 'mbox') {
1382                         if (/^Subject:\s+(.*)$/i) {
1383                                 $subject = $1;
1384                         }
1385                         elsif (/^From:\s+(.*)$/i) {
1386                                 ($author, $author_encoding) = unquote_rfc2047($1);
1387                                 $sauthor = sanitize_address($author);
1388                                 next if $suppress_cc{'author'};
1389                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1390                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1391                                         $1, $_) unless $quiet;
1392                                 push @cc, $1;
1393                         }
1394                         elsif (/^To:\s+(.*)$/i) {
1395                                 foreach my $addr (parse_address_line($1)) {
1396                                         printf("(mbox) Adding to: %s from line '%s'\n",
1397                                                 $addr, $_) unless $quiet;
1398                                         push @to, $addr;
1399                                 }
1400                         }
1401                         elsif (/^Cc:\s+(.*)$/i) {
1402                                 foreach my $addr (parse_address_line($1)) {
1403                                         my $qaddr = unquote_rfc2047($addr);
1404                                         my $saddr = sanitize_address($qaddr);
1405                                         if ($saddr eq $sender) {
1406                                                 next if ($suppress_cc{'self'});
1407                                         } else {
1408                                                 next if ($suppress_cc{'cc'});
1409                                         }
1410                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1411                                                 $addr, $_) unless $quiet;
1412                                         push @cc, $addr;
1413                                 }
1414                         }
1415                         elsif (/^Content-type:/i) {
1416                                 $has_content_type = 1;
1417                                 if (/charset="?([^ "]+)/) {
1418                                         $body_encoding = $1;
1419                                 }
1420                                 push @xh, $_;
1421                         }
1422                         elsif (/^MIME-Version/i) {
1423                                 $has_mime_version = 1;
1424                                 push @xh, $_;
1425                         }
1426                         elsif (/^Message-Id: (.*)/i) {
1427                                 $message_id = $1;
1428                         }
1429                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1430                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1431                         }
1432                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1433                                 push @xh, $_;
1434                         }
1435
1436                 } else {
1437                         # In the traditional
1438                         # "send lots of email" format,
1439                         # line 1 = cc
1440                         # line 2 = subject
1441                         # So let's support that, too.
1442                         $input_format = 'lots';
1443                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1444                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1445                                         $_, $_) unless $quiet;
1446                                 push @cc, $_;
1447                         } elsif (!defined $subject) {
1448                                 $subject = $_;
1449                         }
1450                 }
1451         }
1452         # Now parse the message body
1453         while(<$fh>) {
1454                 $message .=  $_;
1455                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1456                         chomp;
1457                         my ($what, $c) = ($1, $2);
1458                         chomp $c;
1459                         my $sc = sanitize_address($c);
1460                         if ($sc eq $sender) {
1461                                 next if ($suppress_cc{'self'});
1462                         } else {
1463                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1464                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1465                         }
1466                         push @cc, $c;
1467                         printf("(body) Adding cc: %s from line '%s'\n",
1468                                 $c, $_) unless $quiet;
1469                 }
1470         }
1471         close $fh;
1472
1473         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1474                 if defined $to_cmd;
1475         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1476                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1477
1478         if ($broken_encoding{$t} && !$has_content_type) {
1479                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1480                 $has_content_type = 1;
1481                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1482                 $body_encoding = $auto_8bit_encoding;
1483         }
1484
1485         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1486                 $subject = quote_subject($subject, $auto_8bit_encoding);
1487         }
1488
1489         if (defined $sauthor and $sauthor ne $sender) {
1490                 $message = "From: $author\n\n$message";
1491                 if (defined $author_encoding) {
1492                         if ($has_content_type) {
1493                                 if ($body_encoding eq $author_encoding) {
1494                                         # ok, we already have the right encoding
1495                                 }
1496                                 else {
1497                                         # uh oh, we should re-encode
1498                                 }
1499                         }
1500                         else {
1501                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1502                                 $has_content_type = 1;
1503                                 push @xh,
1504                                   "Content-Type: text/plain; charset=$author_encoding";
1505                         }
1506                 }
1507         }
1508         if (defined $target_xfer_encoding) {
1509                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1510                 $message = apply_transfer_encoding(
1511                         $message, $xfer_encoding, $target_xfer_encoding);
1512                 $xfer_encoding = $target_xfer_encoding;
1513         }
1514         if (defined $xfer_encoding) {
1515                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1516         }
1517         if (defined $xfer_encoding or $has_content_type) {
1518                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1519         }
1520
1521         $needs_confirm = (
1522                 $confirm eq "always" or
1523                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1524                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1525         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1526
1527         @to = validate_address_list(sanitize_address_list(@to));
1528         @cc = validate_address_list(sanitize_address_list(@cc));
1529
1530         @to = (@initial_to, @to);
1531         @cc = (@initial_cc, @cc);
1532
1533         if ($message_num == 1) {
1534                 if (defined $cover_cc and $cover_cc) {
1535                         @initial_cc = @cc;
1536                 }
1537                 if (defined $cover_to and $cover_to) {
1538                         @initial_to = @to;
1539                 }
1540         }
1541
1542         my $message_was_sent = send_message();
1543
1544         # set up for the next message
1545         if ($thread && $message_was_sent &&
1546                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1547                 $message_num == 1)) {
1548                 $reply_to = $message_id;
1549                 if (length $references > 0) {
1550                         $references .= "\n $message_id";
1551                 } else {
1552                         $references = "$message_id";
1553                 }
1554         }
1555         $message_id = undef;
1556 }
1557
1558 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1559 # and return a results array
1560 sub recipients_cmd {
1561         my ($prefix, $what, $cmd, $file) = @_;
1562
1563         my @addresses = ();
1564         open my $fh, "-|", "$cmd \Q$file\E"
1565             or die "($prefix) Could not execute '$cmd'";
1566         while (my $address = <$fh>) {
1567                 $address =~ s/^\s*//g;
1568                 $address =~ s/\s*$//g;
1569                 $address = sanitize_address($address);
1570                 next if ($address eq $sender and $suppress_cc{'self'});
1571                 push @addresses, $address;
1572                 printf("($prefix) Adding %s: %s from: '%s'\n",
1573                        $what, $address, $cmd) unless $quiet;
1574                 }
1575         close $fh
1576             or die "($prefix) failed to close pipe to '$cmd'";
1577         return @addresses;
1578 }
1579
1580 cleanup_compose_files();
1581
1582 sub cleanup_compose_files {
1583         unlink($compose_filename, $compose_filename . ".final") if $compose;
1584 }
1585
1586 $smtp->quit if $smtp;
1587
1588 sub apply_transfer_encoding {
1589         my $message = shift;
1590         my $from = shift;
1591         my $to = shift;
1592
1593         return $message if ($from eq $to and $from ne '7bit');
1594
1595         require MIME::QuotedPrint;
1596         require MIME::Base64;
1597
1598         $message = MIME::QuotedPrint::decode($message)
1599                 if ($from eq 'quoted-printable');
1600         $message = MIME::Base64::decode($message)
1601                 if ($from eq 'base64');
1602
1603         die "cannot send message as 7bit"
1604                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1605         return $message
1606                 if ($to eq '7bit' or $to eq '8bit');
1607         return MIME::QuotedPrint::encode($message, "\n", 0)
1608                 if ($to eq 'quoted-printable');
1609         return MIME::Base64::encode($message, "\n")
1610                 if ($to eq 'base64');
1611         die "invalid transfer encoding";
1612 }
1613
1614 sub unique_email_list {
1615         my %seen;
1616         my @emails;
1617
1618         foreach my $entry (@_) {
1619                 my $clean = extract_valid_address_or_die($entry);
1620                 $seen{$clean} ||= 0;
1621                 next if $seen{$clean}++;
1622                 push @emails, $entry;
1623         }
1624         return @emails;
1625 }
1626
1627 sub validate_patch {
1628         my $fn = shift;
1629         open(my $fh, '<', $fn)
1630                 or die "unable to open $fn: $!\n";
1631         while (my $line = <$fh>) {
1632                 if (length($line) > 998) {
1633                         return "$.: patch contains a line longer than 998 characters";
1634                 }
1635         }
1636         return;
1637 }
1638
1639 sub file_has_nonascii {
1640         my $fn = shift;
1641         open(my $fh, '<', $fn)
1642                 or die "unable to open $fn: $!\n";
1643         while (my $line = <$fh>) {
1644                 return 1 if $line =~ /[^[:ascii:]]/;
1645         }
1646         return 0;
1647 }
1648
1649 sub body_or_subject_has_nonascii {
1650         my $fn = shift;
1651         open(my $fh, '<', $fn)
1652                 or die "unable to open $fn: $!\n";
1653         while (my $line = <$fh>) {
1654                 last if $line =~ /^$/;
1655                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1656         }
1657         while (my $line = <$fh>) {
1658                 return 1 if $line =~ /[^[:ascii:]]/;
1659         }
1660         return 0;
1661 }