git-gui

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set copyright {
   6 Copyright © 2006 Shawn Pearce, Paul Mackerras.
   7
   8 All rights reserved.
   9
  10 This program is free software; it may be used, copied, modified
  11 and distributed under the terms of the GNU General Public Licence,
  12 either version 2, or (at your option) any later version.}
  13
  14 set appname [lindex [file split $argv0] end]
  15 set gitdir {}
  16
  17 ######################################################################
  18 ##
  19 ## config
  20
  21 proc is_many_config {name} {
  22         switch -glob -- $name {
  23         remote.*.fetch -
  24         remote.*.push
  25                 {return 1}
  26         *
  27                 {return 0}
  28         }
  29 }
  30
  31 proc load_config {include_global} {
  32         global repo_config global_config default_config
  33
  34         array unset global_config
  35         if {$include_global} {
  36                 catch {
  37                         set fd_rc [open "| git repo-config --global --list" r]
  38                         while {[gets $fd_rc line] >= 0} {
  39                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  40                                         if {[is_many_config $name]} {
  41                                                 lappend global_config($name) $value
  42                                         } else {
  43                                                 set global_config($name) $value
  44                                         }
  45                                 }
  46                         }
  47                         close $fd_rc
  48                 }
  49         }
  50
  51         array unset repo_config
  52         catch {
  53                 set fd_rc [open "| git repo-config --list" r]
  54                 while {[gets $fd_rc line] >= 0} {
  55                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  56                                 if {[is_many_config $name]} {
  57                                         lappend repo_config($name) $value
  58                                 } else {
  59                                         set repo_config($name) $value
  60                                 }
  61                         }
  62                 }
  63                 close $fd_rc
  64         }
  65
  66         foreach name [array names default_config] {
  67                 if {[catch {set v $global_config($name)}]} {
  68                         set global_config($name) $default_config($name)
  69                 }
  70                 if {[catch {set v $repo_config($name)}]} {
  71                         set repo_config($name) $default_config($name)
  72                 }
  73         }
  74 }
  75
  76 proc save_config {} {
  77         global default_config font_descs
  78         global repo_config global_config
  79         global repo_config_new global_config_new
  80
  81         foreach option $font_descs {
  82                 set name [lindex $option 0]
  83                 set font [lindex $option 1]
  84                 font configure $font \
  85                         -family $global_config_new(gui.$font^^family) \
  86                         -size $global_config_new(gui.$font^^size)
  87                 font configure ${font}bold \
  88                         -family $global_config_new(gui.$font^^family) \
  89                         -size $global_config_new(gui.$font^^size)
  90                 set global_config_new(gui.$name) [font configure $font]
  91                 unset global_config_new(gui.$font^^family)
  92                 unset global_config_new(gui.$font^^size)
  93         }
  94
  95         foreach name [array names default_config] {
  96                 set value $global_config_new($name)
  97                 if {$value ne $global_config($name)} {
  98                         if {$value eq $default_config($name)} {
  99                                 catch {exec git repo-config --global --unset $name}
 100                         } else {
 101                                 regsub -all "\[{}\]" $value {"} value
 102                                 exec git repo-config --global $name $value
 103                         }
 104                         set global_config($name) $value
 105                         if {$value eq $repo_config($name)} {
 106                                 catch {exec git repo-config --unset $name}
 107                                 set repo_config($name) $value
 108                         }
 109                 }
 110         }
 111
 112         foreach name [array names default_config] {
 113                 set value $repo_config_new($name)
 114                 if {$value ne $repo_config($name)} {
 115                         if {$value eq $global_config($name)} {
 116                                 catch {exec git repo-config --unset $name}
 117                         } else {
 118                                 regsub -all "\[{}\]" $value {"} value
 119                                 exec git repo-config $name $value
 120                         }
 121                         set repo_config($name) $value
 122                 }
 123         }
 124 }
 125
 126 proc error_popup {msg} {
 127         global gitdir appname
 128
 129         set title $appname
 130         if {$gitdir ne {}} {
 131                 append title { (}
 132                 append title [lindex \
 133                         [file split [file normalize [file dirname $gitdir]]] \
 134                         end]
 135                 append title {)}
 136         }
 137         set cmd [list tk_messageBox \
 138                 -icon error \
 139                 -type ok \
 140                 -title "$title: error" \
 141                 -message $msg]
 142         if {[winfo ismapped .]} {
 143                 lappend cmd -parent .
 144         }
 145         eval $cmd
 146 }
 147
 148 proc warn_popup {msg} {
 149         global gitdir appname
 150
 151         set title $appname
 152         if {$gitdir ne {}} {
 153                 append title { (}
 154                 append title [lindex \
 155                         [file split [file normalize [file dirname $gitdir]]] \
 156                         end]
 157                 append title {)}
 158         }
 159         set cmd [list tk_messageBox \
 160                 -icon warning \
 161                 -type ok \
 162                 -title "$title: warning" \
 163                 -message $msg]
 164         if {[winfo ismapped .]} {
 165                 lappend cmd -parent .
 166         }
 167         eval $cmd
 168 }
 169
 170 proc info_popup {msg} {
 171         global gitdir appname
 172
 173         set title $appname
 174         if {$gitdir ne {}} {
 175                 append title { (}
 176                 append title [lindex \
 177                         [file split [file normalize [file dirname $gitdir]]] \
 178                         end]
 179                 append title {)}
 180         }
 181         tk_messageBox \
 182                 -parent . \
 183                 -icon info \
 184                 -type ok \
 185                 -title $title \
 186                 -message $msg
 187 }
 188
 189 ######################################################################
 190 ##
 191 ## repository setup
 192
 193 if {   [catch {set gitdir $env(GIT_DIR)}]
 194         && [catch {set gitdir [exec git rev-parse --git-dir]} err]} {
 195         catch {wm withdraw .}
 196         error_popup "Cannot find the git directory:\n\n$err"
 197         exit 1
 198 }
 199 if {![file isdirectory $gitdir]} {
 200         catch {wm withdraw .}
 201         error_popup "Git directory not found:\n\n$gitdir"
 202         exit 1
 203 }
 204 if {[lindex [file split $gitdir] end] ne {.git}} {
 205         catch {wm withdraw .}
 206         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 207         exit 1
 208 }
 209 if {[catch {cd [file dirname $gitdir]} err]} {
 210         catch {wm withdraw .}
 211         error_popup "No working directory [file dirname $gitdir]:\n\n$err"
 212         exit 1
 213 }
 214
 215 set single_commit 0
 216 if {$appname eq {git-citool}} {
 217         set single_commit 1
 218 }
 219
 220 ######################################################################
 221 ##
 222 ## task management
 223
 224 set rescan_active 0
 225 set diff_active 0
 226 set last_clicked {}
 227
 228 set disable_on_lock [list]
 229 set index_lock_type none
 230
 231 proc lock_index {type} {
 232         global index_lock_type disable_on_lock
 233
 234         if {$index_lock_type eq {none}} {
 235                 set index_lock_type $type
 236                 foreach w $disable_on_lock {
 237                         uplevel #0 $w disabled
 238                 }
 239                 return 1
 240         } elseif {$index_lock_type eq "begin-$type"} {
 241                 set index_lock_type $type
 242                 return 1
 243         }
 244         return 0
 245 }
 246
 247 proc unlock_index {} {
 248         global index_lock_type disable_on_lock
 249
 250         set index_lock_type none
 251         foreach w $disable_on_lock {
 252                 uplevel #0 $w normal
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## status
 259
 260 proc repository_state {ctvar hdvar mhvar} {
 261         global gitdir current_branch
 262         upvar $ctvar ct $hdvar hd $mhvar mh
 263
 264         set mh [list]
 265
 266         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 267                 set current_branch {}
 268         } else {
 269                 regsub ^refs/((heads|tags|remotes)/)? \
 270                         $current_branch \
 271                         {} \
 272                         current_branch
 273         }
 274
 275         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 276                 set hd {}
 277                 set ct initial
 278                 return
 279         }
 280
 281         set merge_head [file join $gitdir MERGE_HEAD]
 282         if {[file exists $merge_head]} {
 283                 set ct merge
 284                 set fd_mh [open $merge_head r]
 285                 while {[gets $fd_mh line] >= 0} {
 286                         lappend mh $line
 287                 }
 288                 close $fd_mh
 289                 return
 290         }
 291
 292         set ct normal
 293 }
 294
 295 proc PARENT {} {
 296         global PARENT empty_tree
 297
 298         set p [lindex $PARENT 0]
 299         if {$p ne {}} {
 300                 return $p
 301         }
 302         if {$empty_tree eq {}} {
 303                 set empty_tree [exec git mktree << {}]
 304         }
 305         return $empty_tree
 306 }
 307
 308 proc rescan {after} {
 309         global HEAD PARENT MERGE_HEAD commit_type
 310         global ui_index ui_other ui_status_value ui_comm
 311         global rescan_active file_states
 312         global repo_config
 313
 314         if {$rescan_active > 0 || ![lock_index read]} return
 315
 316         repository_state newType newHEAD newMERGE_HEAD
 317         if {[string match amend* $commit_type]
 318                 && $newType eq {normal}
 319                 && $newHEAD eq $HEAD} {
 320         } else {
 321                 set HEAD $newHEAD
 322                 set PARENT $newHEAD
 323                 set MERGE_HEAD $newMERGE_HEAD
 324                 set commit_type $newType
 325         }
 326
 327         array unset file_states
 328
 329         if {![$ui_comm edit modified]
 330                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 331                 if {[load_message GITGUI_MSG]} {
 332                 } elseif {[load_message MERGE_MSG]} {
 333                 } elseif {[load_message SQUASH_MSG]} {
 334                 }
 335                 $ui_comm edit reset
 336                 $ui_comm edit modified false
 337         }
 338
 339         if {$repo_config(gui.trustmtime) eq {true}} {
 340                 rescan_stage2 {} $after
 341         } else {
 342                 set rescan_active 1
 343                 set ui_status_value {Refreshing file status...}
 344                 set cmd [list git update-index]
 345                 lappend cmd -q
 346                 lappend cmd --unmerged
 347                 lappend cmd --ignore-missing
 348                 lappend cmd --refresh
 349                 set fd_rf [open "| $cmd" r]
 350                 fconfigure $fd_rf -blocking 0 -translation binary
 351                 fileevent $fd_rf readable \
 352                         [list rescan_stage2 $fd_rf $after]
 353         }
 354 }
 355
 356 proc rescan_stage2 {fd after} {
 357         global gitdir ui_status_value
 358         global rescan_active buf_rdi buf_rdf buf_rlo
 359
 360         if {$fd ne {}} {
 361                 read $fd
 362                 if {![eof $fd]} return
 363                 close $fd
 364         }
 365
 366         set ls_others [list | git ls-files --others -z \
 367                 --exclude-per-directory=.gitignore]
 368         set info_exclude [file join $gitdir info exclude]
 369         if {[file readable $info_exclude]} {
 370                 lappend ls_others "--exclude-from=$info_exclude"
 371         }
 372
 373         set buf_rdi {}
 374         set buf_rdf {}
 375         set buf_rlo {}
 376
 377         set rescan_active 3
 378         set ui_status_value {Scanning for modified files ...}
 379         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 380         set fd_df [open "| git diff-files -z" r]
 381         set fd_lo [open $ls_others r]
 382
 383         fconfigure $fd_di -blocking 0 -translation binary
 384         fconfigure $fd_df -blocking 0 -translation binary
 385         fconfigure $fd_lo -blocking 0 -translation binary
 386         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 387         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 388         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 389 }
 390
 391 proc load_message {file} {
 392         global gitdir ui_comm
 393
 394         set f [file join $gitdir $file]
 395         if {[file isfile $f]} {
 396                 if {[catch {set fd [open $f r]}]} {
 397                         return 0
 398                 }
 399                 set content [string trim [read $fd]]
 400                 close $fd
 401                 $ui_comm delete 0.0 end
 402                 $ui_comm insert end $content
 403                 return 1
 404         }
 405         return 0
 406 }
 407
 408 proc read_diff_index {fd after} {
 409         global buf_rdi
 410
 411         append buf_rdi [read $fd]
 412         set c 0
 413         set n [string length $buf_rdi]
 414         while {$c < $n} {
 415                 set z1 [string first "\0" $buf_rdi $c]
 416                 if {$z1 == -1} break
 417                 incr z1
 418                 set z2 [string first "\0" $buf_rdi $z1]
 419                 if {$z2 == -1} break
 420
 421                 incr c
 422                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 423                 merge_state \
 424                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 425                         [lindex $i 4]? \
 426                         [list [lindex $i 0] [lindex $i 2]] \
 427                         [list]
 428                 set c $z2
 429                 incr c
 430         }
 431         if {$c < $n} {
 432                 set buf_rdi [string range $buf_rdi $c end]
 433         } else {
 434                 set buf_rdi {}
 435         }
 436
 437         rescan_done $fd buf_rdi $after
 438 }
 439
 440 proc read_diff_files {fd after} {
 441         global buf_rdf
 442
 443         append buf_rdf [read $fd]
 444         set c 0
 445         set n [string length $buf_rdf]
 446         while {$c < $n} {
 447                 set z1 [string first "\0" $buf_rdf $c]
 448                 if {$z1 == -1} break
 449                 incr z1
 450                 set z2 [string first "\0" $buf_rdf $z1]
 451                 if {$z2 == -1} break
 452
 453                 incr c
 454                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 455                 merge_state \
 456                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 457                         ?[lindex $i 4] \
 458                         [list] \
 459                         [list [lindex $i 0] [lindex $i 2]]
 460                 set c $z2
 461                 incr c
 462         }
 463         if {$c < $n} {
 464                 set buf_rdf [string range $buf_rdf $c end]
 465         } else {
 466                 set buf_rdf {}
 467         }
 468
 469         rescan_done $fd buf_rdf $after
 470 }
 471
 472 proc read_ls_others {fd after} {
 473         global buf_rlo
 474
 475         append buf_rlo [read $fd]
 476         set pck [split $buf_rlo "\0"]
 477         set buf_rlo [lindex $pck end]
 478         foreach p [lrange $pck 0 end-1] {
 479                 merge_state $p ?O
 480         }
 481         rescan_done $fd buf_rlo $after
 482 }
 483
 484 proc rescan_done {fd buf after} {
 485         global rescan_active
 486         global file_states repo_config
 487         upvar $buf to_clear
 488
 489         if {![eof $fd]} return
 490         set to_clear {}
 491         close $fd
 492         if {[incr rescan_active -1] > 0} return
 493
 494         prune_selection
 495         unlock_index
 496         display_all_files
 497
 498         if {$repo_config(gui.partialinclude) ne {true}} {
 499                 set pathList [list]
 500                 foreach path [array names file_states] {
 501                         switch -- [lindex $file_states($path) 0] {
 502                         A? -
 503                         M? {lappend pathList $path}
 504                         }
 505                 }
 506                 if {$pathList ne {}} {
 507                         update_index \
 508                                 "Updating included files" \
 509                                 $pathList \
 510                                 [concat {reshow_diff;} $after]
 511                         return
 512                 }
 513         }
 514
 515         reshow_diff
 516         uplevel #0 $after
 517 }
 518
 519 proc prune_selection {} {
 520         global file_states selected_paths
 521
 522         foreach path [array names selected_paths] {
 523                 if {[catch {set still_here $file_states($path)}]} {
 524                         unset selected_paths($path)
 525                 }
 526         }
 527 }
 528
 529 ######################################################################
 530 ##
 531 ## diff
 532
 533 proc clear_diff {} {
 534         global ui_diff current_diff ui_index ui_other
 535
 536         $ui_diff conf -state normal
 537         $ui_diff delete 0.0 end
 538         $ui_diff conf -state disabled
 539
 540         set current_diff {}
 541
 542         $ui_index tag remove in_diff 0.0 end
 543         $ui_other tag remove in_diff 0.0 end
 544 }
 545
 546 proc reshow_diff {} {
 547         global current_diff ui_status_value file_states
 548
 549         if {$current_diff eq {}
 550                 || [catch {set s $file_states($current_diff)}]} {
 551                 clear_diff
 552         } else {
 553                 show_diff $current_diff
 554         }
 555 }
 556
 557 proc handle_empty_diff {} {
 558         global current_diff file_states file_lists
 559
 560         set path $current_diff
 561         set s $file_states($path)
 562         if {[lindex $s 0] ne {_M}} return
 563
 564         info_popup "No differences detected.
 565
 566 [short_path $path] has no changes.
 567
 568 The modification date of this file was updated
 569 by another application and you currently have
 570 the Trust File Modification Timestamps option
 571 enabled, so Git did not automatically detect
 572 that there are no content differences in this
 573 file.
 574
 575 This file will now be removed from the modified
 576 files list, to prevent possible confusion.
 577 "
 578         if {[catch {exec git update-index -- $path} err]} {
 579                 error_popup "Failed to refresh index:\n\n$err"
 580         }
 581
 582         clear_diff
 583         set old_w [mapcol [lindex $file_states($path) 0] $path]
 584         set lno [lsearch -sorted $file_lists($old_w) $path]
 585         if {$lno >= 0} {
 586                 set file_lists($old_w) \
 587                         [lreplace $file_lists($old_w) $lno $lno]
 588                 incr lno
 589                 $old_w conf -state normal
 590                 $old_w delete $lno.0 [expr {$lno + 1}].0
 591                 $old_w conf -state disabled
 592         }
 593 }
 594
 595 proc show_diff {path {w {}} {lno {}}} {
 596         global file_states file_lists
 597         global is_3way_diff diff_active repo_config
 598         global ui_diff current_diff ui_status_value
 599
 600         if {$diff_active || ![lock_index read]} return
 601
 602         clear_diff
 603         if {$w eq {} || $lno == {}} {
 604                 foreach w [array names file_lists] {
 605                         set lno [lsearch -sorted $file_lists($w) $path]
 606                         if {$lno >= 0} {
 607                                 incr lno
 608                                 break
 609                         }
 610                 }
 611         }
 612         if {$w ne {} && $lno >= 1} {
 613                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 614         }
 615
 616         set s $file_states($path)
 617         set m [lindex $s 0]
 618         set is_3way_diff 0
 619         set diff_active 1
 620         set current_diff $path
 621         set ui_status_value "Loading diff of [escape_path $path]..."
 622
 623         set cmd [list | git diff-index]
 624         lappend cmd --no-color
 625         if {$repo_config(gui.diffcontext) > 0} {
 626                 lappend cmd "-U$repo_config(gui.diffcontext)"
 627         }
 628         lappend cmd -p
 629
 630         switch $m {
 631         MM {
 632                 lappend cmd -c
 633         }
 634         _O {
 635                 if {[catch {
 636                                 set fd [open $path r]
 637                                 set content [read $fd]
 638                                 close $fd
 639                         } err ]} {
 640                         set diff_active 0
 641                         unlock_index
 642                         set ui_status_value "Unable to display [escape_path $path]"
 643                         error_popup "Error loading file:\n\n$err"
 644                         return
 645                 }
 646                 $ui_diff conf -state normal
 647                 $ui_diff insert end $content
 648                 $ui_diff conf -state disabled
 649                 set diff_active 0
 650                 unlock_index
 651                 set ui_status_value {Ready.}
 652                 return
 653         }
 654         }
 655
 656         lappend cmd [PARENT]
 657         lappend cmd --
 658         lappend cmd $path
 659
 660         if {[catch {set fd [open $cmd r]} err]} {
 661                 set diff_active 0
 662                 unlock_index
 663                 set ui_status_value "Unable to display [escape_path $path]"
 664                 error_popup "Error loading diff:\n\n$err"
 665                 return
 666         }
 667
 668         fconfigure $fd -blocking 0 -translation auto
 669         fileevent $fd readable [list read_diff $fd]
 670 }
 671
 672 proc read_diff {fd} {
 673         global ui_diff ui_status_value is_3way_diff diff_active
 674         global repo_config
 675
 676         $ui_diff conf -state normal
 677         while {[gets $fd line] >= 0} {
 678                 # -- Cleanup uninteresting diff header lines.
 679                 #
 680                 if {[string match {diff --git *}      $line]} continue
 681                 if {[string match {diff --combined *} $line]} continue
 682                 if {[string match {--- *}             $line]} continue
 683                 if {[string match {+++ *}             $line]} continue
 684                 if {$line eq {deleted file mode 120000}} {
 685                         set line "deleted symlink"
 686                 }
 687
 688                 # -- Automatically detect if this is a 3 way diff.
 689                 #
 690                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 691
 692                 # -- Reformat a 3 way diff, 'cause its too weird.
 693                 #
 694                 if {$is_3way_diff} {
 695                         set op [string range $line 0 1]
 696                         switch -- $op {
 697                         {@@} {set tags d_@}
 698                         {++} {set tags d_+ ; set op { +}}
 699                         {--} {set tags d_- ; set op { -}}
 700                         { +} {set tags d_++; set op {++}}
 701                         { -} {set tags d_--; set op {--}}
 702                         {+ } {set tags d_-+; set op {-+}}
 703                         {- } {set tags d_+-; set op {+-}}
 704                         default {set tags {}}
 705                         }
 706                         set line [string replace $line 0 1 $op]
 707                 } else {
 708                         switch -- [string index $line 0] {
 709                         @ {set tags d_@}
 710                         + {set tags d_+}
 711                         - {set tags d_-}
 712                         default {set tags {}}
 713                         }
 714                 }
 715                 $ui_diff insert end $line $tags
 716                 $ui_diff insert end "\n" $tags
 717         }
 718         $ui_diff conf -state disabled
 719
 720         if {[eof $fd]} {
 721                 close $fd
 722                 set diff_active 0
 723                 unlock_index
 724                 set ui_status_value {Ready.}
 725
 726                 if {$repo_config(gui.trustmtime) eq {true}
 727                         && [$ui_diff index end] eq {2.0}} {
 728                         handle_empty_diff
 729                 }
 730         }
 731 }
 732
 733 ######################################################################
 734 ##
 735 ## commit
 736
 737 proc load_last_commit {} {
 738         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 739
 740         if {[llength $PARENT] == 0} {
 741                 error_popup {There is nothing to amend.
 742
 743 You are about to create the initial commit.
 744 There is no commit before this to amend.
 745 }
 746                 return
 747         }
 748
 749         repository_state curType curHEAD curMERGE_HEAD
 750         if {$curType eq {merge}} {
 751                 error_popup {Cannot amend while merging.
 752
 753 You are currently in the middle of a merge that
 754 has not been fully completed.  You cannot amend
 755 the prior commit unless you first abort the
 756 current merge activity.
 757 }
 758                 return
 759         }
 760
 761         set msg {}
 762         set parents [list]
 763         if {[catch {
 764                         set fd [open "| git cat-file commit $curHEAD" r]
 765                         while {[gets $fd line] > 0} {
 766                                 if {[string match {parent *} $line]} {
 767                                         lappend parents [string range $line 7 end]
 768                                 }
 769                         }
 770                         set msg [string trim [read $fd]]
 771                         close $fd
 772                 } err]} {
 773                 error_popup "Error loading commit data for amend:\n\n$err"
 774                 return
 775         }
 776
 777         set HEAD $curHEAD
 778         set PARENT $parents
 779         set MERGE_HEAD [list]
 780         switch -- [llength $parents] {
 781         0       {set commit_type amend-initial}
 782         1       {set commit_type amend}
 783         default {set commit_type amend-merge}
 784         }
 785
 786         $ui_comm delete 0.0 end
 787         $ui_comm insert end $msg
 788         $ui_comm edit reset
 789         $ui_comm edit modified false
 790         rescan {set ui_status_value {Ready.}}
 791 }
 792
 793 proc create_new_commit {} {
 794         global commit_type ui_comm
 795
 796         set commit_type normal
 797         $ui_comm delete 0.0 end
 798         $ui_comm edit reset
 799         $ui_comm edit modified false
 800         rescan {set ui_status_value {Ready.}}
 801 }
 802
 803 set GIT_COMMITTER_IDENT {}
 804
 805 proc committer_ident {} {
 806         global GIT_COMMITTER_IDENT
 807
 808         if {$GIT_COMMITTER_IDENT eq {}} {
 809                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 810                         error_popup "Unable to obtain your identity:\n\n$err"
 811                         return {}
 812                 }
 813                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 814                         $me me GIT_COMMITTER_IDENT]} {
 815                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 816                         return {}
 817                 }
 818         }
 819
 820         return $GIT_COMMITTER_IDENT
 821 }
 822
 823 proc commit_tree {} {
 824         global HEAD commit_type file_states ui_comm repo_config
 825
 826         if {![lock_index update]} return
 827         if {[committer_ident] eq {}} return
 828
 829         # -- Our in memory state should match the repository.
 830         #
 831         repository_state curType curHEAD curMERGE_HEAD
 832         if {[string match amend* $commit_type]
 833                 && $curType eq {normal}
 834                 && $curHEAD eq $HEAD} {
 835         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 836                 info_popup {Last scanned state does not match repository state.
 837
 838 Another Git program has modified this repository
 839 since the last scan.  A rescan must be performed
 840 before another commit can be created.
 841
 842 The rescan will be automatically started now.
 843 }
 844                 unlock_index
 845                 rescan {set ui_status_value {Ready.}}
 846                 return
 847         }
 848
 849         # -- At least one file should differ in the index.
 850         #
 851         set files_ready 0
 852         foreach path [array names file_states] {
 853                 switch -glob -- [lindex $file_states($path) 0] {
 854                 _? {continue}
 855                 A? -
 856                 D? -
 857                 M? {set files_ready 1; break}
 858                 U? {
 859                         error_popup "Unmerged files cannot be committed.
 860
 861 File [short_path $path] has merge conflicts.
 862 You must resolve them and include the file before committing.
 863 "
 864                         unlock_index
 865                         return
 866                 }
 867                 default {
 868                         error_popup "Unknown file state [lindex $s 0] detected.
 869
 870 File [short_path $path] cannot be committed by this program.
 871 "
 872                 }
 873                 }
 874         }
 875         if {!$files_ready} {
 876                 error_popup {No included files to commit.
 877
 878 You must include at least 1 file before you can commit.
 879 }
 880                 unlock_index
 881                 return
 882         }
 883
 884         # -- A message is required.
 885         #
 886         set msg [string trim [$ui_comm get 1.0 end]]
 887         if {$msg eq {}} {
 888                 error_popup {Please supply a commit message.
 889
 890 A good commit message has the following format:
 891
 892 - First line: Describe in one sentance what you did.
 893 - Second line: Blank
 894 - Remaining lines: Describe why this change is good.
 895 }
 896                 unlock_index
 897                 return
 898         }
 899
 900         # -- Update included files if partialincludes are off.
 901         #
 902         if {$repo_config(gui.partialinclude) ne {true}} {
 903                 set pathList [list]
 904                 foreach path [array names file_states] {
 905                         switch -glob -- [lindex $file_states($path) 0] {
 906                         A? -
 907                         M? {lappend pathList $path}
 908                         }
 909                 }
 910                 if {$pathList ne {}} {
 911                         unlock_index
 912                         update_index \
 913                                 "Updating included files" \
 914                                 $pathList \
 915                                 [concat {lock_index update;} \
 916                                         [list commit_prehook $curHEAD $msg]]
 917                         return
 918                 }
 919         }
 920
 921         commit_prehook $curHEAD $msg
 922 }
 923
 924 proc commit_prehook {curHEAD msg} {
 925         global gitdir ui_status_value pch_error
 926
 927         set pchook [file join $gitdir hooks pre-commit]
 928
 929         # On Cygwin [file executable] might lie so we need to ask
 930         # the shell if the hook is executable.  Yes that's annoying.
 931         #
 932         if {[is_Windows] && [file isfile $pchook]} {
 933                 set pchook [list sh -c [concat \
 934                         "if test -x \"$pchook\";" \
 935                         "then exec \"$pchook\" 2>&1;" \
 936                         "fi"]]
 937         } elseif {[file executable $pchook]} {
 938                 set pchook [list $pchook |& cat]
 939         } else {
 940                 commit_writetree $curHEAD $msg
 941                 return
 942         }
 943
 944         set ui_status_value {Calling pre-commit hook...}
 945         set pch_error {}
 946         set fd_ph [open "| $pchook" r]
 947         fconfigure $fd_ph -blocking 0 -translation binary
 948         fileevent $fd_ph readable \
 949                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 950 }
 951
 952 proc commit_prehook_wait {fd_ph curHEAD msg} {
 953         global pch_error ui_status_value
 954
 955         append pch_error [read $fd_ph]
 956         fconfigure $fd_ph -blocking 1
 957         if {[eof $fd_ph]} {
 958                 if {[catch {close $fd_ph}]} {
 959                         set ui_status_value {Commit declined by pre-commit hook.}
 960                         hook_failed_popup pre-commit $pch_error
 961                         unlock_index
 962                 } else {
 963                         commit_writetree $curHEAD $msg
 964                 }
 965                 set pch_error {}
 966                 return
 967         }
 968         fconfigure $fd_ph -blocking 0
 969 }
 970
 971 proc commit_writetree {curHEAD msg} {
 972         global ui_status_value
 973
 974         set ui_status_value {Committing changes...}
 975         set fd_wt [open "| git write-tree" r]
 976         fileevent $fd_wt readable \
 977                 [list commit_committree $fd_wt $curHEAD $msg]
 978 }
 979
 980 proc commit_committree {fd_wt curHEAD msg} {
 981         global HEAD PARENT MERGE_HEAD commit_type
 982         global single_commit gitdir
 983         global ui_status_value ui_comm selected_commit_type
 984         global file_states selected_paths rescan_active
 985
 986         gets $fd_wt tree_id
 987         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
 988                 error_popup "write-tree failed:\n\n$err"
 989                 set ui_status_value {Commit failed.}
 990                 unlock_index
 991                 return
 992         }
 993
 994         # -- Create the commit.
 995         #
 996         set cmd [list git commit-tree $tree_id]
 997         set parents [concat $PARENT $MERGE_HEAD]
 998         if {[llength $parents] > 0} {
 999                 foreach p $parents {
1000                         lappend cmd -p $p
1001                 }
1002         } else {
1003                 # git commit-tree writes to stderr during initial commit.
1004                 lappend cmd 2>/dev/null
1005         }
1006         lappend cmd << $msg
1007         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1008                 error_popup "commit-tree failed:\n\n$err"
1009                 set ui_status_value {Commit failed.}
1010                 unlock_index
1011                 return
1012         }
1013
1014         # -- Update the HEAD ref.
1015         #
1016         set reflogm commit
1017         if {$commit_type ne {normal}} {
1018                 append reflogm " ($commit_type)"
1019         }
1020         set i [string first "\n" $msg]
1021         if {$i >= 0} {
1022                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1023         } else {
1024                 append reflogm {: } $msg
1025         }
1026         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1027         if {[catch {eval exec $cmd} err]} {
1028                 error_popup "update-ref failed:\n\n$err"
1029                 set ui_status_value {Commit failed.}
1030                 unlock_index
1031                 return
1032         }
1033
1034         # -- Cleanup after ourselves.
1035         #
1036         catch {file delete [file join $gitdir MERGE_HEAD]}
1037         catch {file delete [file join $gitdir MERGE_MSG]}
1038         catch {file delete [file join $gitdir SQUASH_MSG]}
1039         catch {file delete [file join $gitdir GITGUI_MSG]}
1040
1041         # -- Let rerere do its thing.
1042         #
1043         if {[file isdirectory [file join $gitdir rr-cache]]} {
1044                 catch {exec git rerere}
1045         }
1046
1047         # -- Run the post-commit hook.
1048         #
1049         set pchook [file join $gitdir hooks post-commit]
1050         if {[is_Windows] && [file isfile $pchook]} {
1051                 set pchook [list sh -c [concat \
1052                         "if test -x \"$pchook\";" \
1053                         "then exec \"$pchook\";" \
1054                         "fi"]]
1055         } elseif {![file executable $pchook]} {
1056                 set pchook {}
1057         }
1058         if {$pchook ne {}} {
1059                 catch {exec $pchook &}
1060         }
1061
1062         $ui_comm delete 0.0 end
1063         $ui_comm edit reset
1064         $ui_comm edit modified false
1065
1066         if {$single_commit} do_quit
1067
1068         # -- Update in memory status
1069         #
1070         set selected_commit_type new
1071         set commit_type normal
1072         set HEAD $cmt_id
1073         set PARENT $cmt_id
1074         set MERGE_HEAD [list]
1075
1076         foreach path [array names file_states] {
1077                 set s $file_states($path)
1078                 set m [lindex $s 0]
1079                 switch -glob -- $m {
1080                 _O -
1081                 _M -
1082                 _D {continue}
1083                 __ -
1084                 A_ -
1085                 M_ -
1086                 DD {
1087                         unset file_states($path)
1088                         catch {unset selected_paths($path)}
1089                 }
1090                 DO {
1091                         set file_states($path) [list _O [lindex $s 1] {} {}]
1092                 }
1093                 AM -
1094                 AD -
1095                 MM -
1096                 MD -
1097                 DM {
1098                         set file_states($path) [list \
1099                                 _[string index $m 1] \
1100                                 [lindex $s 1] \
1101                                 [lindex $s 3] \
1102                                 {}]
1103                 }
1104                 }
1105         }
1106
1107         display_all_files
1108         unlock_index
1109         reshow_diff
1110         set ui_status_value \
1111                 "Changes committed as [string range $cmt_id 0 7]."
1112 }
1113
1114 ######################################################################
1115 ##
1116 ## fetch pull push
1117
1118 proc fetch_from {remote} {
1119         set w [new_console "fetch $remote" \
1120                 "Fetching new changes from $remote"]
1121         set cmd [list git fetch]
1122         lappend cmd $remote
1123         console_exec $w $cmd
1124 }
1125
1126 proc pull_remote {remote branch} {
1127         global HEAD commit_type file_states repo_config
1128
1129         if {![lock_index update]} return
1130
1131         # -- Our in memory state should match the repository.
1132         #
1133         repository_state curType curHEAD curMERGE_HEAD
1134         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1135                 info_popup {Last scanned state does not match repository state.
1136
1137 Another Git program has modified this repository
1138 since the last scan.  A rescan must be performed
1139 before a pull operation can be started.
1140
1141 The rescan will be automatically started now.
1142 }
1143                 unlock_index
1144                 rescan {set ui_status_value {Ready.}}
1145                 return
1146         }
1147
1148         # -- No differences should exist before a pull.
1149         #
1150         if {[array size file_states] != 0} {
1151                 error_popup {Uncommitted but modified files are present.
1152
1153 You should not perform a pull with unmodified
1154 files in your working directory as Git will be
1155 unable to recover from an incorrect merge.
1156
1157 You should commit or revert all changes before
1158 starting a pull operation.
1159 }
1160                 unlock_index
1161                 return
1162         }
1163
1164         set w [new_console "pull $remote $branch" \
1165                 "Pulling new changes from branch $branch in $remote"]
1166         set cmd [list git pull]
1167         if {$repo_config(gui.pullsummary) eq {false}} {
1168                 lappend cmd --no-summary
1169         }
1170         lappend cmd $remote
1171         lappend cmd $branch
1172         console_exec $w $cmd [list post_pull_remote $remote $branch]
1173 }
1174
1175 proc post_pull_remote {remote branch success} {
1176         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1177         global ui_status_value
1178
1179         unlock_index
1180         if {$success} {
1181                 repository_state commit_type HEAD MERGE_HEAD
1182                 set PARENT $HEAD
1183                 set selected_commit_type new
1184                 set ui_status_value "Pulling $branch from $remote complete."
1185         } else {
1186                 rescan [list set ui_status_value \
1187                         "Conflicts detected while pulling $branch from $remote."]
1188         }
1189 }
1190
1191 proc push_to {remote} {
1192         set w [new_console "push $remote" \
1193                 "Pushing changes to $remote"]
1194         set cmd [list git push]
1195         lappend cmd $remote
1196         console_exec $w $cmd
1197 }
1198
1199 ######################################################################
1200 ##
1201 ## ui helpers
1202
1203 proc mapcol {state path} {
1204         global all_cols ui_other
1205
1206         if {[catch {set r $all_cols($state)}]} {
1207                 puts "error: no column for state={$state} $path"
1208                 return $ui_other
1209         }
1210         return $r
1211 }
1212
1213 proc mapicon {state path} {
1214         global all_icons
1215
1216         if {[catch {set r $all_icons($state)}]} {
1217                 puts "error: no icon for state={$state} $path"
1218                 return file_plain
1219         }
1220         return $r
1221 }
1222
1223 proc mapdesc {state path} {
1224         global all_descs
1225
1226         if {[catch {set r $all_descs($state)}]} {
1227                 puts "error: no desc for state={$state} $path"
1228                 return $state
1229         }
1230         return $r
1231 }
1232
1233 proc escape_path {path} {
1234         regsub -all "\n" $path "\\n" path
1235         return $path
1236 }
1237
1238 proc short_path {path} {
1239         return [escape_path [lindex [file split $path] end]]
1240 }
1241
1242 set next_icon_id 0
1243 set null_sha1 [string repeat 0 40]
1244
1245 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1246         global file_states next_icon_id null_sha1
1247
1248         set s0 [string index $new_state 0]
1249         set s1 [string index $new_state 1]
1250
1251         if {[catch {set info $file_states($path)}]} {
1252                 set state __
1253                 set icon n[incr next_icon_id]
1254         } else {
1255                 set state [lindex $info 0]
1256                 set icon [lindex $info 1]
1257                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1258                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1259         }
1260
1261         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1262         elseif {$s0 eq {_}} {set s0 _}
1263
1264         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1265         elseif {$s1 eq {_}} {set s1 _}
1266
1267         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1268                 set head_info [list 0 $null_sha1]
1269         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1270                 && $head_info eq {}} {
1271                 set head_info $index_info
1272         }
1273
1274         set file_states($path) [list $s0$s1 $icon \
1275                 $head_info $index_info \
1276                 ]
1277         return $state
1278 }
1279
1280 proc display_file {path state} {
1281         global file_states file_lists selected_paths
1282
1283         set old_m [merge_state $path $state]
1284         set s $file_states($path)
1285         set new_m [lindex $s 0]
1286         set new_w [mapcol $new_m $path]
1287         set old_w [mapcol $old_m $path]
1288         set new_icon [mapicon $new_m $path]
1289
1290         if {$new_m eq {__}} {
1291                 set lno [lsearch -sorted $file_lists($old_w) $path]
1292                 if {$lno >= 0} {
1293                         set file_lists($old_w) \
1294                                 [lreplace $file_lists($old_w) $lno $lno]
1295                         incr lno
1296                         $old_w conf -state normal
1297                         $old_w delete $lno.0 [expr {$lno + 1}].0
1298                         $old_w conf -state disabled
1299                 }
1300                 unset file_states($path)
1301                 catch {unset selected_paths($path)}
1302                 return
1303         }
1304
1305         if {$new_w ne $old_w} {
1306                 set lno [lsearch -sorted $file_lists($old_w) $path]
1307                 if {$lno >= 0} {
1308                         set file_lists($old_w) \
1309                                 [lreplace $file_lists($old_w) $lno $lno]
1310                         incr lno
1311                         $old_w conf -state normal
1312                         $old_w delete $lno.0 [expr {$lno + 1}].0
1313                         $old_w conf -state disabled
1314                 }
1315
1316                 lappend file_lists($new_w) $path
1317                 set file_lists($new_w) [lsort $file_lists($new_w)]
1318                 set lno [lsearch -sorted $file_lists($new_w) $path]
1319                 incr lno
1320                 $new_w conf -state normal
1321                 $new_w image create $lno.0 \
1322                         -align center -padx 5 -pady 1 \
1323                         -name [lindex $s 1] \
1324                         -image $new_icon
1325                 $new_w insert $lno.1 "[escape_path $path]\n"
1326                 if {[catch {set in_sel $selected_paths($path)}]} {
1327                         set in_sel 0
1328                 }
1329                 if {$in_sel} {
1330                         $new_w tag add in_sel $lno.0 [expr {$lno + 1}].0
1331                 }
1332                 $new_w conf -state disabled
1333         } elseif {$new_icon ne [mapicon $old_m $path]} {
1334                 $new_w conf -state normal
1335                 $new_w image conf [lindex $s 1] -image $new_icon
1336                 $new_w conf -state disabled
1337         }
1338 }
1339
1340 proc display_all_files {} {
1341         global ui_index ui_other
1342         global file_states file_lists
1343         global last_clicked selected_paths
1344
1345         $ui_index conf -state normal
1346         $ui_other conf -state normal
1347
1348         $ui_index delete 0.0 end
1349         $ui_other delete 0.0 end
1350         set last_clicked {}
1351
1352         set file_lists($ui_index) [list]
1353         set file_lists($ui_other) [list]
1354
1355         foreach path [lsort [array names file_states]] {
1356                 set s $file_states($path)
1357                 set m [lindex $s 0]
1358                 set w [mapcol $m $path]
1359                 lappend file_lists($w) $path
1360                 set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1361                 $w image create end \
1362                         -align center -padx 5 -pady 1 \
1363                         -name [lindex $s 1] \
1364                         -image [mapicon $m $path]
1365                 $w insert end "[escape_path $path]\n"
1366                 if {[catch {set in_sel $selected_paths($path)}]} {
1367                         set in_sel 0
1368                 }
1369                 if {$in_sel} {
1370                         $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1371                 }
1372         }
1373
1374         $ui_index conf -state disabled
1375         $ui_other conf -state disabled
1376 }
1377
1378 proc update_indexinfo {msg pathList after} {
1379         global update_index_cp ui_status_value
1380
1381         if {![lock_index update]} return
1382
1383         set update_index_cp 0
1384         set pathList [lsort $pathList]
1385         set totalCnt [llength $pathList]
1386         set batch [expr {int($totalCnt * .01) + 1}]
1387         if {$batch > 25} {set batch 25}
1388
1389         set ui_status_value [format \
1390                 "$msg... %i/%i files (%.2f%%)" \
1391                 $update_index_cp \
1392                 $totalCnt \
1393                 0.0]
1394         set fd [open "| git update-index -z --index-info" w]
1395         fconfigure $fd \
1396                 -blocking 0 \
1397                 -buffering full \
1398                 -buffersize 512 \
1399                 -translation binary
1400         fileevent $fd writable [list \
1401                 write_update_indexinfo \
1402                 $fd \
1403                 $pathList \
1404                 $totalCnt \
1405                 $batch \
1406                 $msg \
1407                 $after \
1408                 ]
1409 }
1410
1411 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1412         global update_index_cp ui_status_value
1413         global file_states current_diff
1414
1415         if {$update_index_cp >= $totalCnt} {
1416                 close $fd
1417                 unlock_index
1418                 uplevel #0 $after
1419                 return
1420         }
1421
1422         for {set i $batch} \
1423                 {$update_index_cp < $totalCnt && $i > 0} \
1424                 {incr i -1} {
1425                 set path [lindex $pathList $update_index_cp]
1426                 incr update_index_cp
1427
1428                 set s $file_states($path)
1429                 switch -glob -- [lindex $s 0] {
1430                 A? {set new _O}
1431                 M? {set new _M}
1432                 D? {set new _?}
1433                 ?? {continue}
1434                 }
1435                 set info [lindex $s 2]
1436                 if {$info eq {}} continue
1437
1438                 puts -nonewline $fd $info
1439                 puts -nonewline $fd "\t"
1440                 puts -nonewline $fd $path
1441                 puts -nonewline $fd "\0"
1442                 display_file $path $new
1443         }
1444
1445         set ui_status_value [format \
1446                 "$msg... %i/%i files (%.2f%%)" \
1447                 $update_index_cp \
1448                 $totalCnt \
1449                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1450 }
1451
1452 proc update_index {msg pathList after} {
1453         global update_index_cp ui_status_value
1454
1455         if {![lock_index update]} return
1456
1457         set update_index_cp 0
1458         set pathList [lsort $pathList]
1459         set totalCnt [llength $pathList]
1460         set batch [expr {int($totalCnt * .01) + 1}]
1461         if {$batch > 25} {set batch 25}
1462
1463         set ui_status_value [format \
1464                 "$msg... %i/%i files (%.2f%%)" \
1465                 $update_index_cp \
1466                 $totalCnt \
1467                 0.0]
1468         set fd [open "| git update-index --add --remove -z --stdin" w]
1469         fconfigure $fd \
1470                 -blocking 0 \
1471                 -buffering full \
1472                 -buffersize 512 \
1473                 -translation binary
1474         fileevent $fd writable [list \
1475                 write_update_index \
1476                 $fd \
1477                 $pathList \
1478                 $totalCnt \
1479                 $batch \
1480                 $msg \
1481                 $after \
1482                 ]
1483 }
1484
1485 proc write_update_index {fd pathList totalCnt batch msg after} {
1486         global update_index_cp ui_status_value
1487         global file_states current_diff
1488
1489         if {$update_index_cp >= $totalCnt} {
1490                 close $fd
1491                 unlock_index
1492                 uplevel #0 $after
1493                 return
1494         }
1495
1496         for {set i $batch} \
1497                 {$update_index_cp < $totalCnt && $i > 0} \
1498                 {incr i -1} {
1499                 set path [lindex $pathList $update_index_cp]
1500                 incr update_index_cp
1501
1502                 switch -glob -- [lindex $file_states($path) 0] {
1503                 AD -
1504                 MD -
1505                 UD -
1506                 _D {set new DD}
1507
1508                 _M -
1509                 MM -
1510                 UM -
1511                 U_ -
1512                 M_ {set new M_}
1513
1514                 _O -
1515                 AM -
1516                 A_ {set new A_}
1517
1518                 ?? {continue}
1519                 }
1520
1521                 puts -nonewline $fd $path
1522                 puts -nonewline $fd "\0"
1523                 display_file $path $new
1524         }
1525
1526         set ui_status_value [format \
1527                 "$msg... %i/%i files (%.2f%%)" \
1528                 $update_index_cp \
1529                 $totalCnt \
1530                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1531 }
1532
1533 proc checkout_index {msg pathList after} {
1534         global update_index_cp ui_status_value
1535
1536         if {![lock_index update]} return
1537
1538         set update_index_cp 0
1539         set pathList [lsort $pathList]
1540         set totalCnt [llength $pathList]
1541         set batch [expr {int($totalCnt * .01) + 1}]
1542         if {$batch > 25} {set batch 25}
1543
1544         set ui_status_value [format \
1545                 "$msg... %i/%i files (%.2f%%)" \
1546                 $update_index_cp \
1547                 $totalCnt \
1548                 0.0]
1549         set cmd [list git checkout-index]
1550         lappend cmd --index
1551         lappend cmd --quiet
1552         lappend cmd --force
1553         lappend cmd -z
1554         lappend cmd --stdin
1555         set fd [open "| $cmd " w]
1556         fconfigure $fd \
1557                 -blocking 0 \
1558                 -buffering full \
1559                 -buffersize 512 \
1560                 -translation binary
1561         fileevent $fd writable [list \
1562                 write_checkout_index \
1563                 $fd \
1564                 $pathList \
1565                 $totalCnt \
1566                 $batch \
1567                 $msg \
1568                 $after \
1569                 ]
1570 }
1571
1572 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1573         global update_index_cp ui_status_value
1574         global file_states current_diff
1575
1576         if {$update_index_cp >= $totalCnt} {
1577                 close $fd
1578                 unlock_index
1579                 uplevel #0 $after
1580                 return
1581         }
1582
1583         for {set i $batch} \
1584                 {$update_index_cp < $totalCnt && $i > 0} \
1585                 {incr i -1} {
1586                 set path [lindex $pathList $update_index_cp]
1587                 incr update_index_cp
1588
1589                 switch -glob -- [lindex $file_states($path) 0] {
1590                 AM -
1591                 AD {set new A_}
1592                 MM -
1593                 MD {set new M_}
1594                 _M -
1595                 _D {set new __}
1596                 ?? {continue}
1597                 }
1598
1599                 puts -nonewline $fd $path
1600                 puts -nonewline $fd "\0"
1601                 display_file $path $new
1602         }
1603
1604         set ui_status_value [format \
1605                 "$msg... %i/%i files (%.2f%%)" \
1606                 $update_index_cp \
1607                 $totalCnt \
1608                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1609 }
1610
1611 ######################################################################
1612 ##
1613 ## branch management
1614
1615 proc load_all_heads {} {
1616         global all_heads tracking_branches
1617
1618         set all_heads [list]
1619         set cmd [list git for-each-ref]
1620         lappend cmd --format=%(refname)
1621         lappend cmd refs/heads
1622         set fd [open "| $cmd" r]
1623         while {[gets $fd line] > 0} {
1624                 if {![catch {set info $tracking_branches($line)}]} continue
1625                 if {![regsub ^refs/heads/ $line {} name]} continue
1626                 lappend all_heads $name
1627         }
1628         close $fd
1629
1630         set all_heads [lsort $all_heads]
1631 }
1632
1633 proc populate_branch_menu {m} {
1634         global all_heads disable_on_lock
1635
1636         $m add separator
1637         foreach b $all_heads {
1638                 $m add radiobutton \
1639                         -label $b \
1640                         -command [list switch_branch $b] \
1641                         -variable current_branch \
1642                         -value $b \
1643                         -font font_ui
1644                 lappend disable_on_lock \
1645                         [list $m entryconf [$m index last] -state]
1646         }
1647 }
1648
1649 proc do_create_branch {} {
1650         error "NOT IMPLEMENTED"
1651 }
1652
1653 proc do_delete_branch {} {
1654         error "NOT IMPLEMENTED"
1655 }
1656
1657 proc switch_branch {b} {
1658         global HEAD commit_type file_states current_branch
1659         global selected_commit_type ui_comm
1660
1661         if {![lock_index switch]} return
1662
1663         # -- Backup the selected branch (repository_state resets it)
1664         #
1665         set new_branch $current_branch
1666
1667         # -- Our in memory state should match the repository.
1668         #
1669         repository_state curType curHEAD curMERGE_HEAD
1670         if {[string match amend* $commit_type]
1671                 && $curType eq {normal}
1672                 && $curHEAD eq $HEAD} {
1673         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1674                 info_popup {Last scanned state does not match repository state.
1675
1676 Another Git program has modified this repository
1677 since the last scan.  A rescan must be performed
1678 before the current branch can be changed.
1679
1680 The rescan will be automatically started now.
1681 }
1682                 unlock_index
1683                 rescan {set ui_status_value {Ready.}}
1684                 return
1685         }
1686
1687         # -- Toss the message buffer if we are in amend mode.
1688         #
1689         if {[string match amend* $curType]} {
1690                 $ui_comm delete 0.0 end
1691                 $ui_comm edit reset
1692                 $ui_comm edit modified false
1693         }
1694
1695         set selected_commit_type new
1696         set current_branch $new_branch
1697
1698         unlock_index
1699         error "NOT FINISHED"
1700 }
1701
1702 ######################################################################
1703 ##
1704 ## remote management
1705
1706 proc load_all_remotes {} {
1707         global gitdir repo_config
1708         global all_remotes tracking_branches
1709
1710         set all_remotes [list]
1711         array unset tracking_branches
1712
1713         set rm_dir [file join $gitdir remotes]
1714         if {[file isdirectory $rm_dir]} {
1715                 set all_remotes [glob \
1716                         -types f \
1717                         -tails \
1718                         -nocomplain \
1719                         -directory $rm_dir *]
1720
1721                 foreach name $all_remotes {
1722                         catch {
1723                                 set fd [open [file join $rm_dir $name] r]
1724                                 while {[gets $fd line] >= 0} {
1725                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
1726                                                 $line line src dst]} continue
1727                                         if {![regexp ^refs/ $dst]} {
1728                                                 set dst "refs/heads/$dst"
1729                                         }
1730                                         set tracking_branches($dst) [list $name $src]
1731                                 }
1732                                 close $fd
1733                         }
1734                 }
1735         }
1736
1737         foreach line [array names repo_config remote.*.url] {
1738                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
1739                 lappend all_remotes $name
1740
1741                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
1742                         set fl {}
1743                 }
1744                 foreach line $fl {
1745                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
1746                         if {![regexp ^refs/ $dst]} {
1747                                 set dst "refs/heads/$dst"
1748                         }
1749                         set tracking_branches($dst) [list $name $src]
1750                 }
1751         }
1752
1753         set all_remotes [lsort -unique $all_remotes]
1754 }
1755
1756 proc populate_fetch_menu {m} {
1757         global gitdir all_remotes repo_config
1758
1759         foreach r $all_remotes {
1760                 set enable 0
1761                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1762                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
1763                                 set enable 1
1764                         }
1765                 } else {
1766                         catch {
1767                                 set fd [open [file join $gitdir remotes $r] r]
1768                                 while {[gets $fd n] >= 0} {
1769                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
1770                                                 set enable 1
1771                                                 break
1772                                         }
1773                                 }
1774                                 close $fd
1775                         }
1776                 }
1777
1778                 if {$enable} {
1779                         $m add command \
1780                                 -label "Fetch from $r..." \
1781                                 -command [list fetch_from $r] \
1782                                 -font font_ui
1783                 }
1784         }
1785 }
1786
1787 proc populate_push_menu {m} {
1788         global gitdir all_remotes repo_config
1789
1790         foreach r $all_remotes {
1791                 set enable 0
1792                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1793                         if {![catch {set a $repo_config(remote.$r.push)}]} {
1794                                 set enable 1
1795                         }
1796                 } else {
1797                         catch {
1798                                 set fd [open [file join $gitdir remotes $r] r]
1799                                 while {[gets $fd n] >= 0} {
1800                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
1801                                                 set enable 1
1802                                                 break
1803                                         }
1804                                 }
1805                                 close $fd
1806                         }
1807                 }
1808
1809                 if {$enable} {
1810                         $m add command \
1811                                 -label "Push to $r..." \
1812                                 -command [list push_to $r] \
1813                                 -font font_ui
1814                 }
1815         }
1816 }
1817
1818 proc populate_pull_menu {m} {
1819         global gitdir repo_config all_remotes disable_on_lock
1820
1821         foreach remote $all_remotes {
1822                 set rb {}
1823                 if {[array get repo_config remote.$remote.url] ne {}} {
1824                         if {[array get repo_config remote.$remote.fetch] ne {}} {
1825                                 regexp {^([^:]+):} \
1826                                         [lindex $repo_config(remote.$remote.fetch) 0] \
1827                                         line rb
1828                         }
1829                 } else {
1830                         catch {
1831                                 set fd [open [file join $gitdir remotes $remote] r]
1832                                 while {[gets $fd line] >= 0} {
1833                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
1834                                                 break
1835                                         }
1836                                 }
1837                                 close $fd
1838                         }
1839                 }
1840
1841                 set rb_short $rb
1842                 regsub ^refs/heads/ $rb {} rb_short
1843                 if {$rb_short ne {}} {
1844                         $m add command \
1845                                 -label "Branch $rb_short from $remote..." \
1846                                 -command [list pull_remote $remote $rb] \
1847                                 -font font_ui
1848                         lappend disable_on_lock \
1849                                 [list $m entryconf [$m index last] -state]
1850                 }
1851         }
1852 }
1853
1854 ######################################################################
1855 ##
1856 ## icons
1857
1858 set filemask {
1859 #define mask_width 14
1860 #define mask_height 15
1861 static unsigned char mask_bits[] = {
1862    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1863    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1864    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1865 }
1866
1867 image create bitmap file_plain -background white -foreground black -data {
1868 #define plain_width 14
1869 #define plain_height 15
1870 static unsigned char plain_bits[] = {
1871    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1872    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1873    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1874 } -maskdata $filemask
1875
1876 image create bitmap file_mod -background white -foreground blue -data {
1877 #define mod_width 14
1878 #define mod_height 15
1879 static unsigned char mod_bits[] = {
1880    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1881    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1882    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1883 } -maskdata $filemask
1884
1885 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1886 #define file_fulltick_width 14
1887 #define file_fulltick_height 15
1888 static unsigned char file_fulltick_bits[] = {
1889    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1890    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1891    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1892 } -maskdata $filemask
1893
1894 image create bitmap file_parttick -background white -foreground "#005050" -data {
1895 #define parttick_width 14
1896 #define parttick_height 15
1897 static unsigned char parttick_bits[] = {
1898    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1899    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1900    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1901 } -maskdata $filemask
1902
1903 image create bitmap file_question -background white -foreground black -data {
1904 #define file_question_width 14
1905 #define file_question_height 15
1906 static unsigned char file_question_bits[] = {
1907    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1908    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1909    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1910 } -maskdata $filemask
1911
1912 image create bitmap file_removed -background white -foreground red -data {
1913 #define file_removed_width 14
1914 #define file_removed_height 15
1915 static unsigned char file_removed_bits[] = {
1916    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1917    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1918    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1919 } -maskdata $filemask
1920
1921 image create bitmap file_merge -background white -foreground blue -data {
1922 #define file_merge_width 14
1923 #define file_merge_height 15
1924 static unsigned char file_merge_bits[] = {
1925    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1926    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1927    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1928 } -maskdata $filemask
1929
1930 set ui_index .vpane.files.index.list
1931 set ui_other .vpane.files.other.list
1932 set max_status_desc 0
1933 foreach i {
1934                 {__ i plain    "Unmodified"}
1935                 {_M i mod      "Modified"}
1936                 {M_ i fulltick "Included in commit"}
1937                 {MM i parttick "Partially included"}
1938                 {MD i question "Included (but gone)"}
1939
1940                 {_O o plain    "Untracked"}
1941                 {A_ o fulltick "Added by commit"}
1942                 {AM o parttick "Partially added"}
1943                 {AD o question "Added (but gone)"}
1944
1945                 {_D i question "Missing"}
1946                 {DD i removed  "Removed by commit"}
1947                 {DO i removed  "Removed (still exists)"}
1948                 {DM i removed  "Removed (but modified)"}
1949
1950                 {UD i merge    "Merge conflicts"}
1951                 {UM i merge    "Merge conflicts"}
1952                 {U_ i merge    "Merge conflicts"}
1953         } {
1954         if {$max_status_desc < [string length [lindex $i 3]]} {
1955                 set max_status_desc [string length [lindex $i 3]]
1956         }
1957         if {[lindex $i 1] eq {i}} {
1958                 set all_cols([lindex $i 0]) $ui_index
1959         } else {
1960                 set all_cols([lindex $i 0]) $ui_other
1961         }
1962         set all_icons([lindex $i 0]) file_[lindex $i 2]
1963         set all_descs([lindex $i 0]) [lindex $i 3]
1964 }
1965 unset filemask i
1966
1967 ######################################################################
1968 ##
1969 ## util
1970
1971 proc is_MacOSX {} {
1972         global tcl_platform tk_library
1973         if {[tk windowingsystem] eq {aqua}} {
1974                 return 1
1975         }
1976         return 0
1977 }
1978
1979 proc is_Windows {} {
1980         global tcl_platform
1981         if {$tcl_platform(platform) eq {windows}} {
1982                 return 1
1983         }
1984         return 0
1985 }
1986
1987 proc bind_button3 {w cmd} {
1988         bind $w <Any-Button-3> $cmd
1989         if {[is_MacOSX]} {
1990                 bind $w <Control-Button-1> $cmd
1991         }
1992 }
1993
1994 proc incr_font_size {font {amt 1}} {
1995         set sz [font configure $font -size]
1996         incr sz $amt
1997         font configure $font -size $sz
1998         font configure ${font}bold -size $sz
1999 }
2000
2001 proc hook_failed_popup {hook msg} {
2002         global gitdir appname
2003
2004         set w .hookfail
2005         toplevel $w
2006
2007         frame $w.m
2008         label $w.m.l1 -text "$hook hook failed:" \
2009                 -anchor w \
2010                 -justify left \
2011                 -font font_uibold
2012         text $w.m.t \
2013                 -background white -borderwidth 1 \
2014                 -relief sunken \
2015                 -width 80 -height 10 \
2016                 -font font_diff \
2017                 -yscrollcommand [list $w.m.sby set]
2018         label $w.m.l2 \
2019                 -text {You must correct the above errors before committing.} \
2020                 -anchor w \
2021                 -justify left \
2022                 -font font_uibold
2023         scrollbar $w.m.sby -command [list $w.m.t yview]
2024         pack $w.m.l1 -side top -fill x
2025         pack $w.m.l2 -side bottom -fill x
2026         pack $w.m.sby -side right -fill y
2027         pack $w.m.t -side left -fill both -expand 1
2028         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2029
2030         $w.m.t insert 1.0 $msg
2031         $w.m.t conf -state disabled
2032
2033         button $w.ok -text OK \
2034                 -width 15 \
2035                 -font font_ui \
2036                 -command "destroy $w"
2037         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2038
2039         bind $w <Visibility> "grab $w; focus $w"
2040         bind $w <Key-Return> "destroy $w"
2041         wm title $w "$appname ([lindex [file split \
2042                 [file normalize [file dirname $gitdir]]] \
2043                 end]): error"
2044         tkwait window $w
2045 }
2046
2047 set next_console_id 0
2048
2049 proc new_console {short_title long_title} {
2050         global next_console_id console_data
2051         set w .console[incr next_console_id]
2052         set console_data($w) [list $short_title $long_title]
2053         return [console_init $w]
2054 }
2055
2056 proc console_init {w} {
2057         global console_cr console_data
2058         global gitdir appname M1B
2059
2060         set console_cr($w) 1.0
2061         toplevel $w
2062         frame $w.m
2063         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2064                 -anchor w \
2065                 -justify left \
2066                 -font font_uibold
2067         text $w.m.t \
2068                 -background white -borderwidth 1 \
2069                 -relief sunken \
2070                 -width 80 -height 10 \
2071                 -font font_diff \
2072                 -state disabled \
2073                 -yscrollcommand [list $w.m.sby set]
2074         label $w.m.s -text {Working... please wait...} \
2075                 -anchor w \
2076                 -justify left \
2077                 -font font_uibold
2078         scrollbar $w.m.sby -command [list $w.m.t yview]
2079         pack $w.m.l1 -side top -fill x
2080         pack $w.m.s -side bottom -fill x
2081         pack $w.m.sby -side right -fill y
2082         pack $w.m.t -side left -fill both -expand 1
2083         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2084
2085         menu $w.ctxm -tearoff 0
2086         $w.ctxm add command -label "Copy" \
2087                 -font font_ui \
2088                 -command "tk_textCopy $w.m.t"
2089         $w.ctxm add command -label "Select All" \
2090                 -font font_ui \
2091                 -command "$w.m.t tag add sel 0.0 end"
2092         $w.ctxm add command -label "Copy All" \
2093                 -font font_ui \
2094                 -command "
2095                         $w.m.t tag add sel 0.0 end
2096                         tk_textCopy $w.m.t
2097                         $w.m.t tag remove sel 0.0 end
2098                 "
2099
2100         button $w.ok -text {Close} \
2101                 -font font_ui \
2102                 -state disabled \
2103                 -command "destroy $w"
2104         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2105
2106         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2107         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2108         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2109         bind $w <Visibility> "focus $w"
2110         wm title $w "$appname ([lindex [file split \
2111                 [file normalize [file dirname $gitdir]]] \
2112                 end]): [lindex $console_data($w) 0]"
2113         return $w
2114 }
2115
2116 proc console_exec {w cmd {after {}}} {
2117         # -- Windows tosses the enviroment when we exec our child.
2118         #    But most users need that so we have to relogin. :-(
2119         #
2120         if {[is_Windows]} {
2121                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2122         }
2123
2124         # -- Tcl won't let us redirect both stdout and stderr to
2125         #    the same pipe.  So pass it through cat...
2126         #
2127         set cmd [concat | $cmd |& cat]
2128
2129         set fd_f [open $cmd r]
2130         fconfigure $fd_f -blocking 0 -translation binary
2131         fileevent $fd_f readable [list console_read $w $fd_f $after]
2132 }
2133
2134 proc console_read {w fd after} {
2135         global console_cr console_data
2136
2137         set buf [read $fd]
2138         if {$buf ne {}} {
2139                 if {![winfo exists $w]} {console_init $w}
2140                 $w.m.t conf -state normal
2141                 set c 0
2142                 set n [string length $buf]
2143                 while {$c < $n} {
2144                         set cr [string first "\r" $buf $c]
2145                         set lf [string first "\n" $buf $c]
2146                         if {$cr < 0} {set cr [expr {$n + 1}]}
2147                         if {$lf < 0} {set lf [expr {$n + 1}]}
2148
2149                         if {$lf < $cr} {
2150                                 $w.m.t insert end [string range $buf $c $lf]
2151                                 set console_cr($w) [$w.m.t index {end -1c}]
2152                                 set c $lf
2153                                 incr c
2154                         } else {
2155                                 $w.m.t delete $console_cr($w) end
2156                                 $w.m.t insert end "\n"
2157                                 $w.m.t insert end [string range $buf $c $cr]
2158                                 set c $cr
2159                                 incr c
2160                         }
2161                 }
2162                 $w.m.t conf -state disabled
2163                 $w.m.t see end
2164         }
2165
2166         fconfigure $fd -blocking 1
2167         if {[eof $fd]} {
2168                 if {[catch {close $fd}]} {
2169                         if {![winfo exists $w]} {console_init $w}
2170                         $w.m.s conf -background red -text {Error: Command Failed}
2171                         $w.ok conf -state normal
2172                         set ok 0
2173                 } elseif {[winfo exists $w]} {
2174                         $w.m.s conf -background green -text {Success}
2175                         $w.ok conf -state normal
2176                         set ok 1
2177                 }
2178                 array unset console_cr $w
2179                 array unset console_data $w
2180                 if {$after ne {}} {
2181                         uplevel #0 $after $ok
2182                 }
2183                 return
2184         }
2185         fconfigure $fd -blocking 0
2186 }
2187
2188 ######################################################################
2189 ##
2190 ## ui commands
2191
2192 set starting_gitk_msg {Please wait... Starting gitk...}
2193
2194 proc do_gitk {revs} {
2195         global ui_status_value starting_gitk_msg
2196
2197         set cmd gitk
2198         if {$revs ne {}} {
2199                 append cmd { }
2200                 append cmd $revs
2201         }
2202         if {[is_Windows]} {
2203                 set cmd "sh -c \"exec $cmd\""
2204         }
2205         append cmd { &}
2206
2207         if {[catch {eval exec $cmd} err]} {
2208                 error_popup "Failed to start gitk:\n\n$err"
2209         } else {
2210                 set ui_status_value $starting_gitk_msg
2211                 after 10000 {
2212                         if {$ui_status_value eq $starting_gitk_msg} {
2213                                 set ui_status_value {Ready.}
2214                         }
2215                 }
2216         }
2217 }
2218
2219 proc do_repack {} {
2220         set w [new_console {repack} \
2221                 {Repacking the object database}]
2222         set cmd [list git repack]
2223         lappend cmd -a
2224         lappend cmd -d
2225         console_exec $w $cmd
2226 }
2227
2228 proc do_fsck_objects {} {
2229         set w [new_console {fsck-objects} \
2230                 {Verifying the object database with fsck-objects}]
2231         set cmd [list git fsck-objects]
2232         lappend cmd --full
2233         lappend cmd --cache
2234         lappend cmd --strict
2235         console_exec $w $cmd
2236 }
2237
2238 set is_quitting 0
2239
2240 proc do_quit {} {
2241         global gitdir ui_comm is_quitting repo_config commit_type
2242
2243         if {$is_quitting} return
2244         set is_quitting 1
2245
2246         # -- Stash our current commit buffer.
2247         #
2248         set save [file join $gitdir GITGUI_MSG]
2249         set msg [string trim [$ui_comm get 0.0 end]]
2250         if {![string match amend* $commit_type]
2251                 && [$ui_comm edit modified]
2252                 && $msg ne {}} {
2253                 catch {
2254                         set fd [open $save w]
2255                         puts $fd [string trim [$ui_comm get 0.0 end]]
2256                         close $fd
2257                 }
2258         } else {
2259                 catch {file delete $save}
2260         }
2261
2262         # -- Stash our current window geometry into this repository.
2263         #
2264         set cfg_geometry [list]
2265         lappend cfg_geometry [wm geometry .]
2266         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2267         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2268         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2269                 set rc_geometry {}
2270         }
2271         if {$cfg_geometry ne $rc_geometry} {
2272                 catch {exec git repo-config gui.geometry $cfg_geometry}
2273         }
2274
2275         destroy .
2276 }
2277
2278 proc do_rescan {} {
2279         rescan {set ui_status_value {Ready.}}
2280 }
2281
2282 proc remove_helper {txt paths} {
2283         global file_states current_diff
2284
2285         if {![lock_index begin-update]} return
2286
2287         set pathList [list]
2288         set after {}
2289         foreach path $paths {
2290                 switch -glob -- [lindex $file_states($path) 0] {
2291                 A? -
2292                 M? -
2293                 D? {
2294                         lappend pathList $path
2295                         if {$path eq $current_diff} {
2296                                 set after {reshow_diff;}
2297                         }
2298                 }
2299                 }
2300         }
2301         if {$pathList eq {}} {
2302                 unlock_index
2303         } else {
2304                 update_indexinfo \
2305                         $txt \
2306                         $pathList \
2307                         [concat $after {set ui_status_value {Ready.}}]
2308         }
2309 }
2310
2311 proc do_remove_selection {} {
2312         global current_diff selected_paths
2313
2314         if {[array size selected_paths] > 0} {
2315                 remove_helper \
2316                         {Removing selected files from commit} \
2317                         [array names selected_paths]
2318         } elseif {$current_diff ne {}} {
2319                 remove_helper \
2320                         "Removing [short_path $current_diff] from commit" \
2321                         [list $current_diff]
2322         }
2323 }
2324
2325 proc include_helper {txt paths} {
2326         global file_states current_diff
2327
2328         if {![lock_index begin-update]} return
2329
2330         set pathList [list]
2331         set after {}
2332         foreach path $paths {
2333                 switch -glob -- [lindex $file_states($path) 0] {
2334                 AM -
2335                 AD -
2336                 MM -
2337                 MD -
2338                 U? -
2339                 _M -
2340                 _D -
2341                 _O {
2342                         lappend pathList $path
2343                         if {$path eq $current_diff} {
2344                                 set after {reshow_diff;}
2345                         }
2346                 }
2347                 }
2348         }
2349         if {$pathList eq {}} {
2350                 unlock_index
2351         } else {
2352                 update_index \
2353                         $txt \
2354                         $pathList \
2355                         [concat $after {set ui_status_value {Ready to commit.}}]
2356         }
2357 }
2358
2359 proc do_include_selection {} {
2360         global current_diff selected_paths
2361
2362         if {[array size selected_paths] > 0} {
2363                 include_helper \
2364                         {Including selected files} \
2365                         [array names selected_paths]
2366         } elseif {$current_diff ne {}} {
2367                 include_helper \
2368                         "Including [short_path $current_diff]" \
2369                         [list $current_diff]
2370         }
2371 }
2372
2373 proc do_include_all {} {
2374         global file_states
2375
2376         set paths [list]
2377         foreach path [array names file_states] {
2378                 switch -- [lindex $file_states($path) 0] {
2379                 AM -
2380                 AD -
2381                 MM -
2382                 MD -
2383                 _M -
2384                 _D {lappend paths $path}
2385                 }
2386         }
2387         include_helper \
2388                 {Including all modified files} \
2389                 $paths
2390 }
2391
2392 proc revert_helper {txt paths} {
2393         global gitdir appname
2394         global file_states current_diff
2395
2396         if {![lock_index begin-update]} return
2397
2398         set pathList [list]
2399         set after {}
2400         foreach path $paths {
2401                 switch -glob -- [lindex $file_states($path) 0] {
2402                 AM -
2403                 AD -
2404                 MM -
2405                 MD -
2406                 _M -
2407                 _D {
2408                         lappend pathList $path
2409                         if {$path eq $current_diff} {
2410                                 set after {reshow_diff;}
2411                         }
2412                 }
2413                 }
2414         }
2415
2416         set n [llength $pathList]
2417         if {$n == 0} {
2418                 unlock_index
2419                 return
2420         } elseif {$n == 1} {
2421                 set s "[short_path [lindex $pathList]]"
2422         } else {
2423                 set s "these $n files"
2424         }
2425
2426         set reponame [lindex [file split \
2427                 [file normalize [file dirname $gitdir]]] \
2428                 end]
2429
2430         set reply [tk_dialog \
2431                 .confirm_revert \
2432                 "$appname ($reponame)" \
2433                 "Revert unincluded changes in $s?
2434
2435 Any unincluded changes will be permanently lost by the revert." \
2436                 question \
2437                 1 \
2438                 {Do Nothing} \
2439                 {Revert Changes} \
2440                 ]
2441         if {$reply == 1} {
2442                 checkout_index \
2443                         $txt \
2444                         $pathList \
2445                         [concat $after {set ui_status_value {Ready.}}]
2446         } else {
2447                 unlock_index
2448         }
2449 }
2450
2451 proc do_revert_selection {} {
2452         global current_diff selected_paths
2453
2454         if {[array size selected_paths] > 0} {
2455                 revert_helper \
2456                         {Reverting selected files} \
2457                         [array names selected_paths]
2458         } elseif {$current_diff ne {}} {
2459                 revert_helper \
2460                         "Reverting [short_path $current_diff]" \
2461                         [list $current_diff]
2462         }
2463 }
2464
2465 proc do_signoff {} {
2466         global ui_comm
2467
2468         set me [committer_ident]
2469         if {$me eq {}} return
2470
2471         set sob "Signed-off-by: $me"
2472         set last [$ui_comm get {end -1c linestart} {end -1c}]
2473         if {$last ne $sob} {
2474                 $ui_comm edit separator
2475                 if {$last ne {}
2476                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2477                         $ui_comm insert end "\n"
2478                 }
2479                 $ui_comm insert end "\n$sob"
2480                 $ui_comm edit separator
2481                 $ui_comm see end
2482         }
2483 }
2484
2485 proc do_select_commit_type {} {
2486         global commit_type selected_commit_type
2487
2488         if {$selected_commit_type eq {new}
2489                 && [string match amend* $commit_type]} {
2490                 create_new_commit
2491         } elseif {$selected_commit_type eq {amend}
2492                 && ![string match amend* $commit_type]} {
2493                 load_last_commit
2494
2495                 # The amend request was rejected...
2496                 #
2497                 if {![string match amend* $commit_type]} {
2498                         set selected_commit_type new
2499                 }
2500         }
2501 }
2502
2503 proc do_commit {} {
2504         commit_tree
2505 }
2506
2507 proc do_about {} {
2508         global appname copyright
2509         global tcl_patchLevel tk_patchLevel
2510
2511         set w .about_dialog
2512         toplevel $w
2513         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2514
2515         label $w.header -text "About $appname" \
2516                 -font font_uibold
2517         pack $w.header -side top -fill x
2518
2519         frame $w.buttons
2520         button $w.buttons.close -text {Close} \
2521                 -font font_ui \
2522                 -command [list destroy $w]
2523         pack $w.buttons.close -side right
2524         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2525
2526         label $w.desc \
2527                 -text "$appname - a commit creation tool for Git.
2528 $copyright" \
2529                 -padx 5 -pady 5 \
2530                 -justify left \
2531                 -anchor w \
2532                 -borderwidth 1 \
2533                 -relief solid \
2534                 -font font_ui
2535         pack $w.desc -side top -fill x -padx 5 -pady 5
2536
2537         set v [exec git --version]
2538         append v "\n\n"
2539         if {$tcl_patchLevel eq $tk_patchLevel} {
2540                 append v "Tcl/Tk version $tcl_patchLevel"
2541         } else {
2542                 append v "Tcl version $tcl_patchLevel"
2543                 append v ", Tk version $tk_patchLevel"
2544         }
2545
2546         label $w.vers \
2547                 -text $v \
2548                 -padx 5 -pady 5 \
2549                 -justify left \
2550                 -anchor w \
2551                 -borderwidth 1 \
2552                 -relief solid \
2553                 -font font_ui
2554         pack $w.vers -side top -fill x -padx 5 -pady 5
2555
2556         bind $w <Visibility> "grab $w; focus $w"
2557         bind $w <Key-Escape> "destroy $w"
2558         wm title $w "About $appname"
2559         tkwait window $w
2560 }
2561
2562 proc do_options {} {
2563         global appname gitdir font_descs
2564         global repo_config global_config
2565         global repo_config_new global_config_new
2566
2567         array unset repo_config_new
2568         array unset global_config_new
2569         foreach name [array names repo_config] {
2570                 set repo_config_new($name) $repo_config($name)
2571         }
2572         load_config 1
2573         foreach name [array names repo_config] {
2574                 switch -- $name {
2575                 gui.diffcontext {continue}
2576                 }
2577                 set repo_config_new($name) $repo_config($name)
2578         }
2579         foreach name [array names global_config] {
2580                 set global_config_new($name) $global_config($name)
2581         }
2582         set reponame [lindex [file split \
2583                 [file normalize [file dirname $gitdir]]] \
2584                 end]
2585
2586         set w .options_editor
2587         toplevel $w
2588         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2589
2590         label $w.header -text "$appname Options" \
2591                 -font font_uibold
2592         pack $w.header -side top -fill x
2593
2594         frame $w.buttons
2595         button $w.buttons.restore -text {Restore Defaults} \
2596                 -font font_ui \
2597                 -command do_restore_defaults
2598         pack $w.buttons.restore -side left
2599         button $w.buttons.save -text Save \
2600                 -font font_ui \
2601                 -command [list do_save_config $w]
2602         pack $w.buttons.save -side right
2603         button $w.buttons.cancel -text {Cancel} \
2604                 -font font_ui \
2605                 -command [list destroy $w]
2606         pack $w.buttons.cancel -side right
2607         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2608
2609         labelframe $w.repo -text "$reponame Repository" \
2610                 -font font_ui \
2611                 -relief raised -borderwidth 2
2612         labelframe $w.global -text {Global (All Repositories)} \
2613                 -font font_ui \
2614                 -relief raised -borderwidth 2
2615         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2616         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2617
2618         foreach option {
2619                 {b partialinclude {Allow Partially Included Files}}
2620                 {b pullsummary {Show Pull Summary}}
2621                 {b trustmtime  {Trust File Modification Timestamps}}
2622                 {i diffcontext {Number of Diff Context Lines}}
2623                 } {
2624                 set type [lindex $option 0]
2625                 set name [lindex $option 1]
2626                 set text [lindex $option 2]
2627                 foreach f {repo global} {
2628                         switch $type {
2629                         b {
2630                                 checkbutton $w.$f.$name -text $text \
2631                                         -variable ${f}_config_new(gui.$name) \
2632                                         -onvalue true \
2633                                         -offvalue false \
2634                                         -font font_ui
2635                                 pack $w.$f.$name -side top -anchor w
2636                         }
2637                         i {
2638                                 frame $w.$f.$name
2639                                 label $w.$f.$name.l -text "$text:" -font font_ui
2640                                 pack $w.$f.$name.l -side left -anchor w -fill x
2641                                 spinbox $w.$f.$name.v \
2642                                         -textvariable ${f}_config_new(gui.$name) \
2643                                         -from 1 -to 99 -increment 1 \
2644                                         -width 3 \
2645                                         -font font_ui
2646                                 pack $w.$f.$name.v -side right -anchor e
2647                                 pack $w.$f.$name -side top -anchor w -fill x
2648                         }
2649                         }
2650                 }
2651         }
2652
2653         set all_fonts [lsort [font families]]
2654         foreach option $font_descs {
2655                 set name [lindex $option 0]
2656                 set font [lindex $option 1]
2657                 set text [lindex $option 2]
2658
2659                 set global_config_new(gui.$font^^family) \
2660                         [font configure $font -family]
2661                 set global_config_new(gui.$font^^size) \
2662                         [font configure $font -size]
2663
2664                 frame $w.global.$name
2665                 label $w.global.$name.l -text "$text:" -font font_ui
2666                 pack $w.global.$name.l -side left -anchor w -fill x
2667                 eval tk_optionMenu $w.global.$name.family \
2668                         global_config_new(gui.$font^^family) \
2669                         $all_fonts
2670                 spinbox $w.global.$name.size \
2671                         -textvariable global_config_new(gui.$font^^size) \
2672                         -from 2 -to 80 -increment 1 \
2673                         -width 3 \
2674                         -font font_ui
2675                 pack $w.global.$name.size -side right -anchor e
2676                 pack $w.global.$name.family -side right -anchor e
2677                 pack $w.global.$name -side top -anchor w -fill x
2678         }
2679
2680         bind $w <Visibility> "grab $w; focus $w"
2681         bind $w <Key-Escape> "destroy $w"
2682         wm title $w "$appname ($reponame): Options"
2683         tkwait window $w
2684 }
2685
2686 proc do_restore_defaults {} {
2687         global font_descs default_config repo_config
2688         global repo_config_new global_config_new
2689
2690         foreach name [array names default_config] {
2691                 set repo_config_new($name) $default_config($name)
2692                 set global_config_new($name) $default_config($name)
2693         }
2694
2695         foreach option $font_descs {
2696                 set name [lindex $option 0]
2697                 set repo_config(gui.$name) $default_config(gui.$name)
2698         }
2699         apply_config
2700
2701         foreach option $font_descs {
2702                 set name [lindex $option 0]
2703                 set font [lindex $option 1]
2704                 set global_config_new(gui.$font^^family) \
2705                         [font configure $font -family]
2706                 set global_config_new(gui.$font^^size) \
2707                         [font configure $font -size]
2708         }
2709 }
2710
2711 proc do_save_config {w} {
2712         if {[catch {save_config} err]} {
2713                 error_popup "Failed to completely save options:\n\n$err"
2714         }
2715         reshow_diff
2716         destroy $w
2717 }
2718
2719 proc do_windows_shortcut {} {
2720         global gitdir appname argv0
2721
2722         set reponame [lindex [file split \
2723                 [file normalize [file dirname $gitdir]]] \
2724                 end]
2725
2726         if {[catch {
2727                 set desktop [exec cygpath \
2728                         --windows \
2729                         --absolute \
2730                         --long-name \
2731                         --desktop]
2732                 }]} {
2733                         set desktop .
2734         }
2735         set fn [tk_getSaveFile \
2736                 -parent . \
2737                 -title "$appname ($reponame): Create Desktop Icon" \
2738                 -initialdir $desktop \
2739                 -initialfile "Git $reponame.bat"]
2740         if {$fn != {}} {
2741                 if {[catch {
2742                                 set fd [open $fn w]
2743                                 set sh [exec cygpath \
2744                                         --windows \
2745                                         --absolute \
2746                                         --long-name \
2747                                         /bin/sh]
2748                                 set me [exec cygpath \
2749                                         --unix \
2750                                         --absolute \
2751                                         $argv0]
2752                                 set gd [exec cygpath \
2753                                         --unix \
2754                                         --absolute \
2755                                         $gitdir]
2756                                 regsub -all ' $me "'\\''" me
2757                                 regsub -all ' $gd "'\\''" gd
2758                                 puts -nonewline $fd "\"$sh\" --login -c \""
2759                                 puts -nonewline $fd "GIT_DIR='$gd'"
2760                                 puts -nonewline $fd " '$me'"
2761                                 puts $fd "&\""
2762                                 close $fd
2763                         } err]} {
2764                         error_popup "Cannot write script:\n\n$err"
2765                 }
2766         }
2767 }
2768
2769 proc do_macosx_app {} {
2770         global gitdir appname argv0 env
2771
2772         set reponame [lindex [file split \
2773                 [file normalize [file dirname $gitdir]]] \
2774                 end]
2775
2776         set fn [tk_getSaveFile \
2777                 -parent . \
2778                 -title "$appname ($reponame): Create Desktop Icon" \
2779                 -initialdir [file join $env(HOME) Desktop] \
2780                 -initialfile "Git $reponame.app"]
2781         if {$fn != {}} {
2782                 if {[catch {
2783                                 set Contents [file join $fn Contents]
2784                                 set MacOS [file join $Contents MacOS]
2785                                 set exe [file join $MacOS git-gui]
2786
2787                                 file mkdir $MacOS
2788
2789                                 set fd [open [file join $Contents Info.plist] w]
2790                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
2791 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
2792 <plist version="1.0">
2793 <dict>
2794         <key>CFBundleDevelopmentRegion</key>
2795         <string>English</string>
2796         <key>CFBundleExecutable</key>
2797         <string>git-gui</string>
2798         <key>CFBundleIdentifier</key>
2799         <string>org.spearce.git-gui</string>
2800         <key>CFBundleInfoDictionaryVersion</key>
2801         <string>6.0</string>
2802         <key>CFBundlePackageType</key>
2803         <string>APPL</string>
2804         <key>CFBundleSignature</key>
2805         <string>????</string>
2806         <key>CFBundleVersion</key>
2807         <string>1.0</string>
2808         <key>NSPrincipalClass</key>
2809         <string>NSApplication</string>
2810 </dict>
2811 </plist>}
2812                                 close $fd
2813
2814                                 set fd [open $exe w]
2815                                 set gd [file normalize $gitdir]
2816                                 set ep [file normalize [exec git --exec-path]]
2817                                 regsub -all ' $gd "'\\''" gd
2818                                 regsub -all ' $ep "'\\''" ep
2819                                 puts $fd "#!/bin/sh"
2820                                 foreach name [array names env] {
2821                                         if {[string match GIT_* $name]} {
2822                                                 regsub -all ' $env($name) "'\\''" v
2823                                                 puts $fd "export $name='$v'"
2824                                         }
2825                                 }
2826                                 puts $fd "export PATH='$ep':\$PATH"
2827                                 puts $fd "export GIT_DIR='$gd'"
2828                                 puts $fd "exec [file normalize $argv0]"
2829                                 close $fd
2830
2831                                 file attributes $exe -permissions u+x,g+x,o+x
2832                         } err]} {
2833                         error_popup "Cannot write icon:\n\n$err"
2834                 }
2835         }
2836 }
2837
2838 proc toggle_or_diff {w x y} {
2839         global file_states file_lists current_diff ui_index ui_other
2840         global last_clicked selected_paths
2841
2842         set pos [split [$w index @$x,$y] .]
2843         set lno [lindex $pos 0]
2844         set col [lindex $pos 1]
2845         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2846         if {$path eq {}} {
2847                 set last_clicked {}
2848                 return
2849         }
2850
2851         set last_clicked [list $w $lno]
2852         array unset selected_paths
2853         $ui_index tag remove in_sel 0.0 end
2854         $ui_other tag remove in_sel 0.0 end
2855
2856         if {$col == 0} {
2857                 if {$current_diff eq $path} {
2858                         set after {reshow_diff;}
2859                 } else {
2860                         set after {}
2861                 }
2862                 switch -glob -- [lindex $file_states($path) 0] {
2863                 A_ -
2864                 M_ -
2865                 DD -
2866                 DO -
2867                 DM {
2868                         update_indexinfo \
2869                                 "Removing [short_path $path] from commit" \
2870                                 [list $path] \
2871                                 [concat $after {set ui_status_value {Ready.}}]
2872                 }
2873                 ?? {
2874                         update_index \
2875                                 "Including [short_path $path]" \
2876                                 [list $path] \
2877                                 [concat $after {set ui_status_value {Ready.}}]
2878                 }
2879                 }
2880         } else {
2881                 show_diff $path $w $lno
2882         }
2883 }
2884
2885 proc add_one_to_selection {w x y} {
2886         global file_lists
2887         global last_clicked selected_paths
2888
2889         set pos [split [$w index @$x,$y] .]
2890         set lno [lindex $pos 0]
2891         set col [lindex $pos 1]
2892         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2893         if {$path eq {}} {
2894                 set last_clicked {}
2895                 return
2896         }
2897
2898         set last_clicked [list $w $lno]
2899         if {[catch {set in_sel $selected_paths($path)}]} {
2900                 set in_sel 0
2901         }
2902         if {$in_sel} {
2903                 unset selected_paths($path)
2904                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2905         } else {
2906                 set selected_paths($path) 1
2907                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2908         }
2909 }
2910
2911 proc add_range_to_selection {w x y} {
2912         global file_lists
2913         global last_clicked selected_paths
2914
2915         if {[lindex $last_clicked 0] ne $w} {
2916                 toggle_or_diff $w $x $y
2917                 return
2918         }
2919
2920         set pos [split [$w index @$x,$y] .]
2921         set lno [lindex $pos 0]
2922         set lc [lindex $last_clicked 1]
2923         if {$lc < $lno} {
2924                 set begin $lc
2925                 set end $lno
2926         } else {
2927                 set begin $lno
2928                 set end $lc
2929         }
2930
2931         foreach path [lrange $file_lists($w) \
2932                 [expr {$begin - 1}] \
2933                 [expr {$end - 1}]] {
2934                 set selected_paths($path) 1
2935         }
2936         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2937 }
2938
2939 ######################################################################
2940 ##
2941 ## config defaults
2942
2943 set cursor_ptr arrow
2944 font create font_diff -family Courier -size 10
2945 font create font_ui
2946 catch {
2947         label .dummy
2948         eval font configure font_ui [font actual [.dummy cget -font]]
2949         destroy .dummy
2950 }
2951
2952 font create font_uibold
2953 font create font_diffbold
2954
2955 if {[is_Windows]} {
2956         set M1B Control
2957         set M1T Ctrl
2958 } elseif {[is_MacOSX]} {
2959         set M1B M1
2960         set M1T Cmd
2961 } else {
2962         set M1B M1
2963         set M1T M1
2964 }
2965
2966 proc apply_config {} {
2967         global repo_config font_descs
2968
2969         foreach option $font_descs {
2970                 set name [lindex $option 0]
2971                 set font [lindex $option 1]
2972                 if {[catch {
2973                         foreach {cn cv} $repo_config(gui.$name) {
2974                                 font configure $font $cn $cv
2975                         }
2976                         } err]} {
2977                         error_popup "Invalid font specified in gui.$name:\n\n$err"
2978                 }
2979                 foreach {cn cv} [font configure $font] {
2980                         font configure ${font}bold $cn $cv
2981                 }
2982                 font configure ${font}bold -weight bold
2983         }
2984 }
2985
2986 set default_config(gui.trustmtime) false
2987 set default_config(gui.pullsummary) true
2988 set default_config(gui.partialinclude) false
2989 set default_config(gui.diffcontext) 5
2990 set default_config(gui.fontui) [font configure font_ui]
2991 set default_config(gui.fontdiff) [font configure font_diff]
2992 set font_descs {
2993         {fontui   font_ui   {Main Font}}
2994         {fontdiff font_diff {Diff/Console Font}}
2995 }
2996 load_config 0
2997 apply_config
2998
2999 ######################################################################
3000 ##
3001 ## ui construction
3002
3003 # -- Menu Bar
3004 #
3005 menu .mbar -tearoff 0
3006 .mbar add cascade -label Repository -menu .mbar.repository
3007 .mbar add cascade -label Edit -menu .mbar.edit
3008 if {!$single_commit} {
3009         .mbar add cascade -label Branch -menu .mbar.branch
3010 }
3011 .mbar add cascade -label Commit -menu .mbar.commit
3012 if {!$single_commit} {
3013         .mbar add cascade -label Fetch -menu .mbar.fetch
3014         .mbar add cascade -label Pull -menu .mbar.pull
3015         .mbar add cascade -label Push -menu .mbar.push
3016 }
3017 . configure -menu .mbar
3018
3019 # -- Repository Menu
3020 #
3021 menu .mbar.repository
3022 .mbar.repository add command \
3023         -label {Visualize Current Branch} \
3024         -command {do_gitk {}} \
3025         -font font_ui
3026 if {![is_MacOSX]} {
3027         .mbar.repository add command \
3028                 -label {Visualize All Branches} \
3029                 -command {do_gitk {--all}} \
3030                 -font font_ui
3031 }
3032 .mbar.repository add separator
3033
3034 if {!$single_commit} {
3035         .mbar.repository add command -label {Repack Database} \
3036                 -command do_repack \
3037                 -font font_ui
3038
3039         .mbar.repository add command -label {Verify Database} \
3040                 -command do_fsck_objects \
3041                 -font font_ui
3042
3043         .mbar.repository add separator
3044
3045         if {[is_Windows]} {
3046                 .mbar.repository add command \
3047                         -label {Create Desktop Icon} \
3048                         -command do_windows_shortcut \
3049                         -font font_ui
3050         } elseif {[is_MacOSX]} {
3051                 .mbar.repository add command \
3052                         -label {Create Desktop Icon} \
3053                         -command do_macosx_app \
3054                         -font font_ui
3055         }
3056 }
3057
3058 .mbar.repository add command -label Quit \
3059         -command do_quit \
3060         -accelerator $M1T-Q \
3061         -font font_ui
3062
3063 # -- Edit Menu
3064 #
3065 menu .mbar.edit
3066 .mbar.edit add command -label Undo \
3067         -command {catch {[focus] edit undo}} \
3068         -accelerator $M1T-Z \
3069         -font font_ui
3070 .mbar.edit add command -label Redo \
3071         -command {catch {[focus] edit redo}} \
3072         -accelerator $M1T-Y \
3073         -font font_ui
3074 .mbar.edit add separator
3075 .mbar.edit add command -label Cut \
3076         -command {catch {tk_textCut [focus]}} \
3077         -accelerator $M1T-X \
3078         -font font_ui
3079 .mbar.edit add command -label Copy \
3080         -command {catch {tk_textCopy [focus]}} \
3081         -accelerator $M1T-C \
3082         -font font_ui
3083 .mbar.edit add command -label Paste \
3084         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3085         -accelerator $M1T-V \
3086         -font font_ui
3087 .mbar.edit add command -label Delete \
3088         -command {catch {[focus] delete sel.first sel.last}} \
3089         -accelerator Del \
3090         -font font_ui
3091 .mbar.edit add separator
3092 .mbar.edit add command -label {Select All} \
3093         -command {catch {[focus] tag add sel 0.0 end}} \
3094         -accelerator $M1T-A \
3095         -font font_ui
3096
3097 # -- Branch Menu
3098 #
3099 if {!$single_commit} {
3100         menu .mbar.branch
3101
3102         .mbar.branch add command -label {Create...} \
3103                 -command do_create_branch \
3104                 -font font_ui
3105         lappend disable_on_lock [list .mbar.branch entryconf \
3106                 [.mbar.branch index last] -state]
3107
3108         .mbar.branch add command -label {Delete...} \
3109                 -command do_delete_branch \
3110                 -font font_ui
3111         lappend disable_on_lock [list .mbar.branch entryconf \
3112                 [.mbar.branch index last] -state]
3113 }
3114
3115 # -- Commit Menu
3116 #
3117 menu .mbar.commit
3118
3119 .mbar.commit add radiobutton \
3120         -label {New Commit} \
3121         -command do_select_commit_type \
3122         -variable selected_commit_type \
3123         -value new \
3124         -font font_ui
3125 lappend disable_on_lock \
3126         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3127
3128 .mbar.commit add radiobutton \
3129         -label {Amend Last Commit} \
3130         -command do_select_commit_type \
3131         -variable selected_commit_type \
3132         -value amend \
3133         -font font_ui
3134 lappend disable_on_lock \
3135         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3136
3137 .mbar.commit add separator
3138
3139 .mbar.commit add command -label Rescan \
3140         -command do_rescan \
3141         -accelerator F5 \
3142         -font font_ui
3143 lappend disable_on_lock \
3144         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3145
3146 .mbar.commit add command -label {Add To Commit} \
3147         -command do_include_selection \
3148         -font font_ui
3149 lappend disable_on_lock \
3150         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3151
3152 .mbar.commit add command -label {Add All To Commit} \
3153         -command do_include_all \
3154         -accelerator $M1T-I \
3155         -font font_ui
3156 lappend disable_on_lock \
3157         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3158
3159 .mbar.commit add command -label {Remove From Commit} \
3160         -command do_remove_selection \
3161         -font font_ui
3162 lappend disable_on_lock \
3163         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3164
3165 .mbar.commit add command -label {Revert Changes} \
3166         -command do_revert_selection \
3167         -font font_ui
3168 lappend disable_on_lock \
3169         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3170
3171 .mbar.commit add separator
3172
3173 .mbar.commit add command -label {Sign Off} \
3174         -command do_signoff \
3175         -accelerator $M1T-S \
3176         -font font_ui
3177
3178 .mbar.commit add command -label Commit \
3179         -command do_commit \
3180         -accelerator $M1T-Return \
3181         -font font_ui
3182 lappend disable_on_lock \
3183         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3184
3185 # -- Transport menus
3186 #
3187 if {!$single_commit} {
3188         menu .mbar.fetch
3189         menu .mbar.pull
3190         menu .mbar.push
3191 }
3192
3193 if {[is_MacOSX]} {
3194         # -- Apple Menu (Mac OS X only)
3195         #
3196         .mbar add cascade -label Apple -menu .mbar.apple
3197         menu .mbar.apple
3198
3199         .mbar.apple add command -label "About $appname" \
3200                 -command do_about \
3201                 -font font_ui
3202         .mbar.apple add command -label "$appname Options..." \
3203                 -command do_options \
3204                 -font font_ui
3205 } else {
3206         # -- Edit Menu
3207         #
3208         .mbar.edit add separator
3209         .mbar.edit add command -label {Options...} \
3210                 -command do_options \
3211                 -font font_ui
3212
3213         # -- Tools Menu
3214         #
3215         if {[file exists /usr/local/miga/lib/gui-miga]} {
3216         proc do_miga {} {
3217                 global gitdir ui_status_value
3218                 if {![lock_index update]} return
3219                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3220                 set miga_fd [open "|$cmd" r]
3221                 fconfigure $miga_fd -blocking 0
3222                 fileevent $miga_fd readable [list miga_done $miga_fd]
3223                 set ui_status_value {Running miga...}
3224         }
3225         proc miga_done {fd} {
3226                 read $fd 512
3227                 if {[eof $fd]} {
3228                         close $fd
3229                         unlock_index
3230                         rescan [list set ui_status_value {Ready.}]
3231                 }
3232         }
3233         .mbar add cascade -label Tools -menu .mbar.tools
3234         menu .mbar.tools
3235         .mbar.tools add command -label "Migrate" \
3236                 -command do_miga \
3237                 -font font_ui
3238         lappend disable_on_lock \
3239                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3240         }
3241
3242         # -- Help Menu
3243         #
3244         .mbar add cascade -label Help -menu .mbar.help
3245         menu .mbar.help
3246
3247         .mbar.help add command -label "About $appname" \
3248                 -command do_about \
3249                 -font font_ui
3250 }
3251
3252
3253 # -- Branch Control
3254 #
3255 frame .branch \
3256         -borderwidth 1 \
3257         -relief sunken
3258 label .branch.l1 \
3259         -text {Current Branch:} \
3260         -anchor w \
3261         -justify left \
3262         -font font_ui
3263 label .branch.cb \
3264         -textvariable current_branch \
3265         -anchor w \
3266         -justify left \
3267         -font font_ui
3268 pack .branch.l1 -side left
3269 pack .branch.cb -side left -fill x
3270 pack .branch -side top -fill x
3271
3272 # -- Main Window Layout
3273 #
3274 panedwindow .vpane -orient vertical
3275 panedwindow .vpane.files -orient horizontal
3276 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3277 pack .vpane -anchor n -side top -fill both -expand 1
3278
3279 # -- Index File List
3280 #
3281 frame .vpane.files.index -height 100 -width 400
3282 label .vpane.files.index.title -text {Modified Files} \
3283         -background green \
3284         -font font_ui
3285 text $ui_index -background white -borderwidth 0 \
3286         -width 40 -height 10 \
3287         -font font_ui \
3288         -cursor $cursor_ptr \
3289         -yscrollcommand {.vpane.files.index.sb set} \
3290         -state disabled
3291 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3292 pack .vpane.files.index.title -side top -fill x
3293 pack .vpane.files.index.sb -side right -fill y
3294 pack $ui_index -side left -fill both -expand 1
3295 .vpane.files add .vpane.files.index -sticky nsew
3296
3297 # -- Other (Add) File List
3298 #
3299 frame .vpane.files.other -height 100 -width 100
3300 label .vpane.files.other.title -text {Untracked Files} \
3301         -background red \
3302         -font font_ui
3303 text $ui_other -background white -borderwidth 0 \
3304         -width 40 -height 10 \
3305         -font font_ui \
3306         -cursor $cursor_ptr \
3307         -yscrollcommand {.vpane.files.other.sb set} \
3308         -state disabled
3309 scrollbar .vpane.files.other.sb -command [list $ui_other yview]
3310 pack .vpane.files.other.title -side top -fill x
3311 pack .vpane.files.other.sb -side right -fill y
3312 pack $ui_other -side left -fill both -expand 1
3313 .vpane.files add .vpane.files.other -sticky nsew
3314
3315 foreach i [list $ui_index $ui_other] {
3316         $i tag conf in_diff -font font_uibold
3317         $i tag conf in_sel \
3318                 -background [$i cget -foreground] \
3319                 -foreground [$i cget -background]
3320 }
3321 unset i
3322
3323 # -- Diff and Commit Area
3324 #
3325 frame .vpane.lower -height 300 -width 400
3326 frame .vpane.lower.commarea
3327 frame .vpane.lower.diff -relief sunken -borderwidth 1
3328 pack .vpane.lower.commarea -side top -fill x
3329 pack .vpane.lower.diff -side bottom -fill both -expand 1
3330 .vpane add .vpane.lower -stick nsew
3331
3332 # -- Commit Area Buttons
3333 #
3334 frame .vpane.lower.commarea.buttons
3335 label .vpane.lower.commarea.buttons.l -text {} \
3336         -anchor w \
3337         -justify left \
3338         -font font_ui
3339 pack .vpane.lower.commarea.buttons.l -side top -fill x
3340 pack .vpane.lower.commarea.buttons -side left -fill y
3341
3342 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3343         -command do_rescan \
3344         -font font_ui
3345 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3346 lappend disable_on_lock \
3347         {.vpane.lower.commarea.buttons.rescan conf -state}
3348
3349 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3350         -command do_include_all \
3351         -font font_ui
3352 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3353 lappend disable_on_lock \
3354         {.vpane.lower.commarea.buttons.incall conf -state}
3355
3356 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3357         -command do_signoff \
3358         -font font_ui
3359 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3360
3361 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3362         -command do_commit \
3363         -font font_ui
3364 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3365 lappend disable_on_lock \
3366         {.vpane.lower.commarea.buttons.commit conf -state}
3367
3368 # -- Commit Message Buffer
3369 #
3370 frame .vpane.lower.commarea.buffer
3371 frame .vpane.lower.commarea.buffer.header
3372 set ui_comm .vpane.lower.commarea.buffer.t
3373 set ui_coml .vpane.lower.commarea.buffer.header.l
3374 radiobutton .vpane.lower.commarea.buffer.header.new \
3375         -text {New Commit} \
3376         -command do_select_commit_type \
3377         -variable selected_commit_type \
3378         -value new \
3379         -font font_ui
3380 lappend disable_on_lock \
3381         [list .vpane.lower.commarea.buffer.header.new conf -state]
3382 radiobutton .vpane.lower.commarea.buffer.header.amend \
3383         -text {Amend Last Commit} \
3384         -command do_select_commit_type \
3385         -variable selected_commit_type \
3386         -value amend \
3387         -font font_ui
3388 lappend disable_on_lock \
3389         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3390 label $ui_coml \
3391         -anchor w \
3392         -justify left \
3393         -font font_ui
3394 proc trace_commit_type {varname args} {
3395         global ui_coml commit_type
3396         switch -glob -- $commit_type {
3397         initial       {set txt {Initial Commit Message:}}
3398         amend         {set txt {Amended Commit Message:}}
3399         amend-initial {set txt {Amended Initial Commit Message:}}
3400         amend-merge   {set txt {Amended Merge Commit Message:}}
3401         merge         {set txt {Merge Commit Message:}}
3402         *             {set txt {Commit Message:}}
3403         }
3404         $ui_coml conf -text $txt
3405 }
3406 trace add variable commit_type write trace_commit_type
3407 pack $ui_coml -side left -fill x
3408 pack .vpane.lower.commarea.buffer.header.amend -side right
3409 pack .vpane.lower.commarea.buffer.header.new -side right
3410
3411 text $ui_comm -background white -borderwidth 1 \
3412         -undo true \
3413         -maxundo 20 \
3414         -autoseparators true \
3415         -relief sunken \
3416         -width 75 -height 9 -wrap none \
3417         -font font_diff \
3418         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3419 scrollbar .vpane.lower.commarea.buffer.sby \
3420         -command [list $ui_comm yview]
3421 pack .vpane.lower.commarea.buffer.header -side top -fill x
3422 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3423 pack $ui_comm -side left -fill y
3424 pack .vpane.lower.commarea.buffer -side left -fill y
3425
3426 # -- Commit Message Buffer Context Menu
3427 #
3428 set ctxm .vpane.lower.commarea.buffer.ctxm
3429 menu $ctxm -tearoff 0
3430 $ctxm add command \
3431         -label {Cut} \
3432         -font font_ui \
3433         -command {tk_textCut $ui_comm}
3434 $ctxm add command \
3435         -label {Copy} \
3436         -font font_ui \
3437         -command {tk_textCopy $ui_comm}
3438 $ctxm add command \
3439         -label {Paste} \
3440         -font font_ui \
3441         -command {tk_textPaste $ui_comm}
3442 $ctxm add command \
3443         -label {Delete} \
3444         -font font_ui \
3445         -command {$ui_comm delete sel.first sel.last}
3446 $ctxm add separator
3447 $ctxm add command \
3448         -label {Select All} \
3449         -font font_ui \
3450         -command {$ui_comm tag add sel 0.0 end}
3451 $ctxm add command \
3452         -label {Copy All} \
3453         -font font_ui \
3454         -command {
3455                 $ui_comm tag add sel 0.0 end
3456                 tk_textCopy $ui_comm
3457                 $ui_comm tag remove sel 0.0 end
3458         }
3459 $ctxm add separator
3460 $ctxm add command \
3461         -label {Sign Off} \
3462         -font font_ui \
3463         -command do_signoff
3464 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3465
3466 # -- Diff Header
3467 #
3468 set current_diff {}
3469 set diff_actions [list]
3470 proc trace_current_diff {varname args} {
3471         global current_diff diff_actions file_states
3472         if {$current_diff eq {}} {
3473                 set s {}
3474                 set f {}
3475                 set p {}
3476                 set o disabled
3477         } else {
3478                 set p $current_diff
3479                 set s [mapdesc [lindex $file_states($p) 0] $p]
3480                 set f {File:}
3481                 set p [escape_path $p]
3482                 set o normal
3483         }
3484
3485         .vpane.lower.diff.header.status configure -text $s
3486         .vpane.lower.diff.header.file configure -text $f
3487         .vpane.lower.diff.header.path configure -text $p
3488         foreach w $diff_actions {
3489                 uplevel #0 $w $o
3490         }
3491 }
3492 trace add variable current_diff write trace_current_diff
3493
3494 frame .vpane.lower.diff.header -background orange
3495 label .vpane.lower.diff.header.status \
3496         -background orange \
3497         -width $max_status_desc \
3498         -anchor w \
3499         -justify left \
3500         -font font_ui
3501 label .vpane.lower.diff.header.file \
3502         -background orange \
3503         -anchor w \
3504         -justify left \
3505         -font font_ui
3506 label .vpane.lower.diff.header.path \
3507         -background orange \
3508         -anchor w \
3509         -justify left \
3510         -font font_ui
3511 pack .vpane.lower.diff.header.status -side left
3512 pack .vpane.lower.diff.header.file -side left
3513 pack .vpane.lower.diff.header.path -fill x
3514 set ctxm .vpane.lower.diff.header.ctxm
3515 menu $ctxm -tearoff 0
3516 $ctxm add command \
3517         -label {Copy} \
3518         -font font_ui \
3519         -command {
3520                 clipboard clear
3521                 clipboard append \
3522                         -format STRING \
3523                         -type STRING \
3524                         -- $current_diff
3525         }
3526 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3527 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3528
3529 # -- Diff Body
3530 #
3531 frame .vpane.lower.diff.body
3532 set ui_diff .vpane.lower.diff.body.t
3533 text $ui_diff -background white -borderwidth 0 \
3534         -width 80 -height 15 -wrap none \
3535         -font font_diff \
3536         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3537         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3538         -state disabled
3539 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3540         -command [list $ui_diff xview]
3541 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3542         -command [list $ui_diff yview]
3543 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3544 pack .vpane.lower.diff.body.sby -side right -fill y
3545 pack $ui_diff -side left -fill both -expand 1
3546 pack .vpane.lower.diff.header -side top -fill x
3547 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3548
3549 $ui_diff tag conf d_@ -font font_diffbold
3550 $ui_diff tag conf d_+  -foreground blue
3551 $ui_diff tag conf d_-  -foreground red
3552 $ui_diff tag conf d_++ -foreground {#00a000}
3553 $ui_diff tag conf d_-- -foreground {#a000a0}
3554 $ui_diff tag conf d_+- \
3555         -foreground red \
3556         -background {light goldenrod yellow}
3557 $ui_diff tag conf d_-+ \
3558         -foreground blue \
3559         -background azure2
3560
3561 # -- Diff Body Context Menu
3562 #
3563 set ctxm .vpane.lower.diff.body.ctxm
3564 menu $ctxm -tearoff 0
3565 $ctxm add command \
3566         -label {Copy} \
3567         -font font_ui \
3568         -command {tk_textCopy $ui_diff}
3569 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3570 $ctxm add command \
3571         -label {Select All} \
3572         -font font_ui \
3573         -command {$ui_diff tag add sel 0.0 end}
3574 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3575 $ctxm add command \
3576         -label {Copy All} \
3577         -font font_ui \
3578         -command {
3579                 $ui_diff tag add sel 0.0 end
3580                 tk_textCopy $ui_diff
3581                 $ui_diff tag remove sel 0.0 end
3582         }
3583 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3584 $ctxm add separator
3585 $ctxm add command \
3586         -label {Decrease Font Size} \
3587         -font font_ui \
3588         -command {incr_font_size font_diff -1}
3589 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3590 $ctxm add command \
3591         -label {Increase Font Size} \
3592         -font font_ui \
3593         -command {incr_font_size font_diff 1}
3594 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3595 $ctxm add separator
3596 $ctxm add command \
3597         -label {Show Less Context} \
3598         -font font_ui \
3599         -command {if {$repo_config(gui.diffcontext) >= 2} {
3600                 incr repo_config(gui.diffcontext) -1
3601                 reshow_diff
3602         }}
3603 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3604 $ctxm add command \
3605         -label {Show More Context} \
3606         -font font_ui \
3607         -command {
3608                 incr repo_config(gui.diffcontext)
3609                 reshow_diff
3610         }
3611 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3612 $ctxm add separator
3613 $ctxm add command -label {Options...} \
3614         -font font_ui \
3615         -command do_options
3616 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3617
3618 # -- Status Bar
3619 #
3620 set ui_status_value {Initializing...}
3621 label .status -textvariable ui_status_value \
3622         -anchor w \
3623         -justify left \
3624         -borderwidth 1 \
3625         -relief sunken \
3626         -font font_ui
3627 pack .status -anchor w -side bottom -fill x
3628
3629 # -- Load geometry
3630 #
3631 catch {
3632 set gm $repo_config(gui.geometry)
3633 wm geometry . [lindex $gm 0]
3634 .vpane sash place 0 \
3635         [lindex [.vpane sash coord 0] 0] \
3636         [lindex $gm 1]
3637 .vpane.files sash place 0 \
3638         [lindex $gm 2] \
3639         [lindex [.vpane.files sash coord 0] 1]
3640 unset gm
3641 }
3642
3643 # -- Key Bindings
3644 #
3645 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3646 bind $ui_comm <$M1B-Key-i> {do_include_all;break}
3647 bind $ui_comm <$M1B-Key-I> {do_include_all;break}
3648 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3649 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3650 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3651 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3652 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3653 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3654 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3655 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3656
3657 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3658 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3659 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3660 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3661 bind $ui_diff <$M1B-Key-v> {break}
3662 bind $ui_diff <$M1B-Key-V> {break}
3663 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3664 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3665 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3666 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3667 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3668 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3669
3670 bind .   <Destroy> do_quit
3671 bind all <Key-F5> do_rescan
3672 bind all <$M1B-Key-r> do_rescan
3673 bind all <$M1B-Key-R> do_rescan
3674 bind .   <$M1B-Key-s> do_signoff
3675 bind .   <$M1B-Key-S> do_signoff
3676 bind .   <$M1B-Key-i> do_include_all
3677 bind .   <$M1B-Key-I> do_include_all
3678 bind .   <$M1B-Key-Return> do_commit
3679 bind all <$M1B-Key-q> do_quit
3680 bind all <$M1B-Key-Q> do_quit
3681 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3682 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3683 foreach i [list $ui_index $ui_other] {
3684         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3685         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3686         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3687 }
3688 unset i
3689
3690 set file_lists($ui_index) [list]
3691 set file_lists($ui_other) [list]
3692
3693 set HEAD {}
3694 set PARENT {}
3695 set MERGE_HEAD [list]
3696 set commit_type {}
3697 set empty_tree {}
3698 set current_branch {}
3699 set current_diff {}
3700 set selected_commit_type new
3701
3702 wm title . "$appname ([file normalize [file dirname $gitdir]])"
3703 focus -force $ui_comm
3704
3705 # -- Warn the user about environmental problems.  Cygwin's Tcl
3706 #    does *not* pass its env array onto any processes it spawns.
3707 #    This means that git processes get none of our environment.
3708 #
3709 if {[is_Windows]} {
3710         set ignored_env 0
3711         set suggest_user {}
3712         set msg "Possible environment issues exist.
3713
3714 The following environment variables are probably
3715 going to be ignored by any Git subprocess run
3716 by $appname:
3717
3718 "
3719         foreach name [array names env] {
3720                 switch -regexp -- $name {
3721                 {^GIT_INDEX_FILE$} -
3722                 {^GIT_OBJECT_DIRECTORY$} -
3723                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3724                 {^GIT_DIFF_OPTS$} -
3725                 {^GIT_EXTERNAL_DIFF$} -
3726                 {^GIT_PAGER$} -
3727                 {^GIT_TRACE$} -
3728                 {^GIT_CONFIG$} -
3729                 {^GIT_CONFIG_LOCAL$} -
3730                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3731                         append msg " - $name\n"
3732                         incr ignored_env
3733                 }
3734                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3735                         append msg " - $name\n"
3736                         incr ignored_env
3737                         set suggest_user $name
3738                 }
3739                 }
3740         }
3741         if {$ignored_env > 0} {
3742                 append msg "
3743 This is due to a known issue with the
3744 Tcl binary distributed by Cygwin."
3745
3746                 if {$suggest_user ne {}} {
3747                         append msg "
3748
3749 A good replacement for $suggest_user
3750 is placing values for the user.name and
3751 user.email settings into your personal
3752 ~/.gitconfig file.
3753 "
3754                 }
3755                 warn_popup $msg
3756         }
3757         unset ignored_env msg suggest_user name
3758 }
3759
3760 # -- Only initialize complex UI if we are going to stay running.
3761 #
3762 if {!$single_commit} {
3763         load_all_remotes
3764         load_all_heads
3765
3766         populate_branch_menu .mbar.branch
3767         populate_fetch_menu .mbar.fetch
3768         populate_pull_menu .mbar.pull
3769         populate_push_menu .mbar.push
3770 }
3771
3772 lock_index begin-read
3773 after 1 do_rescan