git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 if { [info exists ::env(GIT_GUI_LIB_DIR) ] } {
  53         set oguilib $::env(GIT_GUI_LIB_DIR)
  54 } else {
  55         set oguilib {@@GITGUI_LIBDIR@@}
  56 }
  57 set oguirel {@@GITGUI_RELATIVE@@}
  58 if {$oguirel eq {1}} {
  59         set oguilib [file dirname [file normalize $argv0]]
  60         if {[file tail $oguilib] eq {git-core}} {
  61                 set oguilib [file dirname $oguilib]
  62         }
  63         set oguilib [file dirname $oguilib]
  64         set oguilib [file join $oguilib share git-gui lib]
  65         set oguimsg [file join $oguilib msgs]
  66 } elseif {[string match @@* $oguirel]} {
  67         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  68         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  69 } else {
  70         set oguimsg [file join $oguilib msgs]
  71 }
  72 unset oguirel
  73
  74 ######################################################################
  75 ##
  76 ## enable verbose loading?
  77
  78 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  79         unset _verbose
  80         rename auto_load real__auto_load
  81         proc auto_load {name args} {
  82                 puts stderr "auto_load $name"
  83                 return [uplevel 1 real__auto_load $name $args]
  84         }
  85         rename source real__source
  86         proc source {args} {
  87                 puts stderr "source    $args"
  88                 uplevel 1 [linsert $args 0 real__source]
  89         }
  90         if {[tk windowingsystem] eq "win32"} { console show }
  91 }
  92
  93 ######################################################################
  94 ##
  95 ## Internationalization (i18n) through msgcat and gettext. See
  96 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  97
  98 package require msgcat
  99
 100 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
 101 if {[tk windowingsystem] eq "win32"
 102         && [package vcompare [package provide msgcat] 1.4.4] < 0
 103 } then {
 104         proc _mc_update_locale {} {
 105                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 106                 if {![catch {
 107                         package require registry
 108                         set uilocale [registry get $key "PreferredUILanguages"]
 109                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 110                 } uilocale]} {
 111                         if {[string length $uilocale] > 0} {
 112                                 msgcat::mclocale $uilocale
 113                         }
 114                 }
 115         }
 116         _mc_update_locale
 117 }
 118
 119 proc _mc_trim {fmt} {
 120         set cmk [string first @@ $fmt]
 121         if {$cmk > 0} {
 122                 return [string range $fmt 0 [expr {$cmk - 1}]]
 123         }
 124         return $fmt
 125 }
 126
 127 proc mc {en_fmt args} {
 128         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 129         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 130                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 131         }
 132         return $msg
 133 }
 134
 135 proc strcat {args} {
 136         return [join $args {}]
 137 }
 138
 139 ::msgcat::mcload $oguimsg
 140 unset oguimsg
 141
 142 ######################################################################
 143 ##
 144 ## On Mac, bring the current Wish process window to front
 145
 146 if {[tk windowingsystem] eq "aqua"} {
 147         catch {
 148                 exec osascript -e [format {
 149                         tell application "System Events"
 150                                 set frontmost of processes whose unix id is %d to true
 151                         end tell
 152                 } [pid]]
 153         }
 154 }
 155
 156 ######################################################################
 157 ##
 158 ## read only globals
 159
 160 set _appname {Git Gui}
 161 set _gitdir {}
 162 set _gitworktree {}
 163 set _isbare {}
 164 set _gitexec {}
 165 set _githtmldir {}
 166 set _reponame {}
 167 set _iscygwin {}
 168 set _search_path {}
 169 set _shellpath {@@SHELL_PATH@@}
 170
 171 set _trace [lsearch -exact $argv --trace]
 172 if {$_trace >= 0} {
 173         set argv [lreplace $argv $_trace $_trace]
 174         set _trace 1
 175         if {[tk windowingsystem] eq "win32"} { console show }
 176 } else {
 177         set _trace 0
 178 }
 179
 180 # variable for the last merged branch (useful for a default when deleting
 181 # branches).
 182 set _last_merged_branch {}
 183
 184 proc shellpath {} {
 185         global _shellpath env
 186         if {[string match @@* $_shellpath]} {
 187                 if {[info exists env(SHELL)]} {
 188                         return $env(SHELL)
 189                 } else {
 190                         return /bin/sh
 191                 }
 192         }
 193         return $_shellpath
 194 }
 195
 196 proc appname {} {
 197         global _appname
 198         return $_appname
 199 }
 200
 201 proc gitdir {args} {
 202         global _gitdir
 203         if {$args eq {}} {
 204                 return $_gitdir
 205         }
 206         return [eval [list file join $_gitdir] $args]
 207 }
 208
 209 proc gitexec {args} {
 210         global _gitexec
 211         if {$_gitexec eq {}} {
 212                 if {[catch {set _gitexec [git --exec-path]} err]} {
 213                         error "Git not installed?\n\n$err"
 214                 }
 215                 if {[is_Cygwin]} {
 216                         set _gitexec [exec cygpath \
 217                                 --windows \
 218                                 --absolute \
 219                                 $_gitexec]
 220                 } else {
 221                         set _gitexec [file normalize $_gitexec]
 222                 }
 223         }
 224         if {$args eq {}} {
 225                 return $_gitexec
 226         }
 227         return [eval [list file join $_gitexec] $args]
 228 }
 229
 230 proc githtmldir {args} {
 231         global _githtmldir
 232         if {$_githtmldir eq {}} {
 233                 if {[catch {set _githtmldir [git --html-path]}]} {
 234                         # Git not installed or option not yet supported
 235                         return {}
 236                 }
 237                 if {[is_Cygwin]} {
 238                         set _githtmldir [exec cygpath \
 239                                 --windows \
 240                                 --absolute \
 241                                 $_githtmldir]
 242                 } else {
 243                         set _githtmldir [file normalize $_githtmldir]
 244                 }
 245         }
 246         if {$args eq {}} {
 247                 return $_githtmldir
 248         }
 249         return [eval [list file join $_githtmldir] $args]
 250 }
 251
 252 proc reponame {} {
 253         return $::_reponame
 254 }
 255
 256 proc is_MacOSX {} {
 257         if {[tk windowingsystem] eq {aqua}} {
 258                 return 1
 259         }
 260         return 0
 261 }
 262
 263 proc is_Windows {} {
 264         if {$::tcl_platform(platform) eq {windows}} {
 265                 return 1
 266         }
 267         return 0
 268 }
 269
 270 proc is_Cygwin {} {
 271         global _iscygwin
 272         if {$_iscygwin eq {}} {
 273                 if {$::tcl_platform(platform) eq {windows}} {
 274                         if {[catch {set p [exec cygpath --windir]} err]} {
 275                                 set _iscygwin 0
 276                         } else {
 277                                 set _iscygwin 1
 278                         }
 279                 } else {
 280                         set _iscygwin 0
 281                 }
 282         }
 283         return $_iscygwin
 284 }
 285
 286 proc is_enabled {option} {
 287         global enabled_options
 288         if {[catch {set on $enabled_options($option)}]} {return 0}
 289         return $on
 290 }
 291
 292 proc enable_option {option} {
 293         global enabled_options
 294         set enabled_options($option) 1
 295 }
 296
 297 proc disable_option {option} {
 298         global enabled_options
 299         set enabled_options($option) 0
 300 }
 301
 302 ######################################################################
 303 ##
 304 ## config
 305
 306 proc is_many_config {name} {
 307         switch -glob -- $name {
 308         gui.recentrepo -
 309         remote.*.fetch -
 310         remote.*.push
 311                 {return 1}
 312         *
 313                 {return 0}
 314         }
 315 }
 316
 317 proc is_config_true {name} {
 318         global repo_config
 319         if {[catch {set v $repo_config($name)}]} {
 320                 return 0
 321         }
 322         set v [string tolower $v]
 323         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 324                 return 1
 325         } else {
 326                 return 0
 327         }
 328 }
 329
 330 proc is_config_false {name} {
 331         global repo_config
 332         if {[catch {set v $repo_config($name)}]} {
 333                 return 0
 334         }
 335         set v [string tolower $v]
 336         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 337                 return 1
 338         } else {
 339                 return 0
 340         }
 341 }
 342
 343 proc get_config {name} {
 344         global repo_config
 345         if {[catch {set v $repo_config($name)}]} {
 346                 return {}
 347         } else {
 348                 return $v
 349         }
 350 }
 351
 352 proc is_bare {} {
 353         global _isbare
 354         global _gitdir
 355         global _gitworktree
 356
 357         if {$_isbare eq {}} {
 358                 if {[catch {
 359                         set _bare [git rev-parse --is-bare-repository]
 360                         switch  -- $_bare {
 361                         true { set _isbare 1 }
 362                         false { set _isbare 0}
 363                         default { throw }
 364                         }
 365                 }]} {
 366                         if {[is_config_true core.bare]
 367                                 || ($_gitworktree eq {}
 368                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 369                                 set _isbare 1
 370                         } else {
 371                                 set _isbare 0
 372                         }
 373                 }
 374         }
 375         return $_isbare
 376 }
 377
 378 ######################################################################
 379 ##
 380 ## handy utils
 381
 382 proc _trace_exec {cmd} {
 383         if {!$::_trace} return
 384         set d {}
 385         foreach v $cmd {
 386                 if {$d ne {}} {
 387                         append d { }
 388                 }
 389                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 390                         set v [sq $v]
 391                 }
 392                 append d $v
 393         }
 394         puts stderr $d
 395 }
 396
 397 #'"  fix poor old emacs font-lock mode
 398
 399 proc _git_cmd {name} {
 400         global _git_cmd_path
 401
 402         if {[catch {set v $_git_cmd_path($name)}]} {
 403                 switch -- $name {
 404                   version   -
 405                 --version   -
 406                 --exec-path { return [list $::_git $name] }
 407                 }
 408
 409                 set p [gitexec git-$name$::_search_exe]
 410                 if {[file exists $p]} {
 411                         set v [list $p]
 412                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 413                         # Try to determine what sort of magic will make
 414                         # git-$name go and do its thing, because native
 415                         # Tcl on Windows doesn't know it.
 416                         #
 417                         set p [gitexec git-$name]
 418                         set f [open $p r]
 419                         set s [gets $f]
 420                         close $f
 421
 422                         switch -glob -- [lindex $s 0] {
 423                         #!*sh     { set i sh     }
 424                         #!*perl   { set i perl   }
 425                         #!*python { set i python }
 426                         default   { error "git-$name is not supported: $s" }
 427                         }
 428
 429                         upvar #0 _$i interp
 430                         if {![info exists interp]} {
 431                                 set interp [_which $i]
 432                         }
 433                         if {$interp eq {}} {
 434                                 error "git-$name requires $i (not in PATH)"
 435                         }
 436                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 437                 } else {
 438                         # Assume it is builtin to git somehow and we
 439                         # aren't actually able to see a file for it.
 440                         #
 441                         set v [list $::_git $name]
 442                 }
 443                 set _git_cmd_path($name) $v
 444         }
 445         return $v
 446 }
 447
 448 proc _which {what args} {
 449         global env _search_exe _search_path
 450
 451         if {$_search_path eq {}} {
 452                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 453                         set _search_path [split [exec cygpath \
 454                                 --windows \
 455                                 --path \
 456                                 --absolute \
 457                                 $env(PATH)] {;}]
 458                         set _search_exe .exe
 459                 } elseif {[is_Windows]} {
 460                         set gitguidir [file dirname [info script]]
 461                         regsub -all ";" $gitguidir "\\;" gitguidir
 462                         set env(PATH) "$gitguidir;$env(PATH)"
 463                         set _search_path [split $env(PATH) {;}]
 464                         set _search_exe .exe
 465                 } else {
 466                         set _search_path [split $env(PATH) :]
 467                         set _search_exe {}
 468                 }
 469         }
 470
 471         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 472                 set suffix {}
 473         } else {
 474                 set suffix $_search_exe
 475         }
 476
 477         foreach p $_search_path {
 478                 set p [file join $p $what$suffix]
 479                 if {[file exists $p]} {
 480                         return [file normalize $p]
 481                 }
 482         }
 483         return {}
 484 }
 485
 486 # Test a file for a hashbang to identify executable scripts on Windows.
 487 proc is_shellscript {filename} {
 488         if {![file exists $filename]} {return 0}
 489         set f [open $filename r]
 490         fconfigure $f -encoding binary
 491         set magic [read $f 2]
 492         close $f
 493         return [expr {$magic eq "#!"}]
 494 }
 495
 496 # Run a command connected via pipes on stdout.
 497 # This is for use with textconv filters and uses sh -c "..." to allow it to
 498 # contain a command with arguments. On windows we must check for shell
 499 # scripts specifically otherwise just call the filter command.
 500 proc open_cmd_pipe {cmd path} {
 501         global env
 502         if {![file executable [shellpath]]} {
 503                 set exe [auto_execok [lindex $cmd 0]]
 504                 if {[is_shellscript [lindex $exe 0]]} {
 505                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 506                 } else {
 507                         set run [concat $exe [lrange $cmd 1 end] $path]
 508                 }
 509         } else {
 510                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 511         }
 512         return [open |$run r]
 513 }
 514
 515 proc _lappend_nice {cmd_var} {
 516         global _nice
 517         upvar $cmd_var cmd
 518
 519         if {![info exists _nice]} {
 520                 set _nice [_which nice]
 521                 if {[catch {exec $_nice git version}]} {
 522                         set _nice {}
 523                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 524                         set _nice {}
 525                 }
 526         }
 527         if {$_nice ne {}} {
 528                 lappend cmd $_nice
 529         }
 530 }
 531
 532 proc git {args} {
 533         set opt [list]
 534
 535         while {1} {
 536                 switch -- [lindex $args 0] {
 537                 --nice {
 538                         _lappend_nice opt
 539                 }
 540
 541                 default {
 542                         break
 543                 }
 544
 545                 }
 546
 547                 set args [lrange $args 1 end]
 548         }
 549
 550         set cmdp [_git_cmd [lindex $args 0]]
 551         set args [lrange $args 1 end]
 552
 553         _trace_exec [concat $opt $cmdp $args]
 554         set result [eval exec $opt $cmdp $args]
 555         if {$::_trace} {
 556                 puts stderr "< $result"
 557         }
 558         return $result
 559 }
 560
 561 proc _open_stdout_stderr {cmd} {
 562         _trace_exec $cmd
 563         if {[catch {
 564                         set fd [open [concat [list | ] $cmd] r]
 565                 } err]} {
 566                 if {   [lindex $cmd end] eq {2>@1}
 567                     && $err eq {can not find channel named "1"}
 568                         } {
 569                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 570                         # redirect operator.  Fallback to |& cat for those.
 571                         # The command was not actually started, so its safe
 572                         # to try to start it a second time.
 573                         #
 574                         set fd [open [concat \
 575                                 [list | ] \
 576                                 [lrange $cmd 0 end-1] \
 577                                 [list |& cat] \
 578                                 ] r]
 579                 } else {
 580                         error $err
 581                 }
 582         }
 583         fconfigure $fd -eofchar {}
 584         return $fd
 585 }
 586
 587 proc git_read {args} {
 588         set opt [list]
 589
 590         while {1} {
 591                 switch -- [lindex $args 0] {
 592                 --nice {
 593                         _lappend_nice opt
 594                 }
 595
 596                 --stderr {
 597                         lappend args 2>@1
 598                 }
 599
 600                 default {
 601                         break
 602                 }
 603
 604                 }
 605
 606                 set args [lrange $args 1 end]
 607         }
 608
 609         set cmdp [_git_cmd [lindex $args 0]]
 610         set args [lrange $args 1 end]
 611
 612         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 613 }
 614
 615 proc git_write {args} {
 616         set opt [list]
 617
 618         while {1} {
 619                 switch -- [lindex $args 0] {
 620                 --nice {
 621                         _lappend_nice opt
 622                 }
 623
 624                 default {
 625                         break
 626                 }
 627
 628                 }
 629
 630                 set args [lrange $args 1 end]
 631         }
 632
 633         set cmdp [_git_cmd [lindex $args 0]]
 634         set args [lrange $args 1 end]
 635
 636         _trace_exec [concat $opt $cmdp $args]
 637         return [open [concat [list | ] $opt $cmdp $args] w]
 638 }
 639
 640 proc githook_read {hook_name args} {
 641         set pchook [gitdir hooks $hook_name]
 642         lappend args 2>@1
 643
 644         # On Windows [file executable] might lie so we need to ask
 645         # the shell if the hook is executable.  Yes that's annoying.
 646         #
 647         if {[is_Windows]} {
 648                 upvar #0 _sh interp
 649                 if {![info exists interp]} {
 650                         set interp [_which sh]
 651                 }
 652                 if {$interp eq {}} {
 653                         error "hook execution requires sh (not in PATH)"
 654                 }
 655
 656                 set scr {if test -x "$1";then exec "$@";fi}
 657                 set sh_c [list $interp -c $scr $interp $pchook]
 658                 return [_open_stdout_stderr [concat $sh_c $args]]
 659         }
 660
 661         if {[file executable $pchook]} {
 662                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 663         }
 664
 665         return {}
 666 }
 667
 668 proc kill_file_process {fd} {
 669         set process [pid $fd]
 670
 671         catch {
 672                 if {[is_Windows]} {
 673                         exec taskkill /pid $process
 674                 } else {
 675                         exec kill $process
 676                 }
 677         }
 678 }
 679
 680 proc gitattr {path attr default} {
 681         if {[catch {set r [git check-attr $attr -- $path]}]} {
 682                 set r unspecified
 683         } else {
 684                 set r [join [lrange [split $r :] 2 end] :]
 685                 regsub {^ } $r {} r
 686         }
 687         if {$r eq {unspecified}} {
 688                 return $default
 689         }
 690         return $r
 691 }
 692
 693 proc sq {value} {
 694         regsub -all ' $value "'\\''" value
 695         return "'$value'"
 696 }
 697
 698 proc load_current_branch {} {
 699         global current_branch is_detached
 700
 701         set fd [open [gitdir HEAD] r]
 702         if {[gets $fd ref] < 1} {
 703                 set ref {}
 704         }
 705         close $fd
 706
 707         set pfx {ref: refs/heads/}
 708         set len [string length $pfx]
 709         if {[string equal -length $len $pfx $ref]} {
 710                 # We're on a branch.  It might not exist.  But
 711                 # HEAD looks good enough to be a branch.
 712                 #
 713                 set current_branch [string range $ref $len end]
 714                 set is_detached 0
 715         } else {
 716                 # Assume this is a detached head.
 717                 #
 718                 set current_branch HEAD
 719                 set is_detached 1
 720         }
 721 }
 722
 723 auto_load tk_optionMenu
 724 rename tk_optionMenu real__tkOptionMenu
 725 proc tk_optionMenu {w varName args} {
 726         set m [eval real__tkOptionMenu $w $varName $args]
 727         $m configure -font font_ui
 728         $w configure -font font_ui
 729         return $m
 730 }
 731
 732 proc rmsel_tag {text} {
 733         $text tag conf sel \
 734                 -background [$text cget -background] \
 735                 -foreground [$text cget -foreground] \
 736                 -borderwidth 0
 737         $text tag conf in_sel -background lightgray
 738         bind $text <Motion> break
 739         return $text
 740 }
 741
 742 wm withdraw .
 743 set root_exists 0
 744 bind . <Visibility> {
 745         bind . <Visibility> {}
 746         set root_exists 1
 747 }
 748
 749 if {[is_Windows]} {
 750         wm iconbitmap . -default $oguilib/git-gui.ico
 751         set ::tk::AlwaysShowSelection 1
 752         bind . <Control-F2> {console show}
 753
 754         # Spoof an X11 display for SSH
 755         if {![info exists env(DISPLAY)]} {
 756                 set env(DISPLAY) :9999
 757         }
 758 } else {
 759         catch {
 760                 image create photo gitlogo -width 16 -height 16
 761
 762                 gitlogo put #33CC33 -to  7  0  9  2
 763                 gitlogo put #33CC33 -to  4  2 12  4
 764                 gitlogo put #33CC33 -to  7  4  9  6
 765                 gitlogo put #CC3333 -to  4  6 12  8
 766                 gitlogo put gray26  -to  4  9  6 10
 767                 gitlogo put gray26  -to  3 10  6 12
 768                 gitlogo put gray26  -to  8  9 13 11
 769                 gitlogo put gray26  -to  8 11 10 12
 770                 gitlogo put gray26  -to 11 11 13 14
 771                 gitlogo put gray26  -to  3 12  5 14
 772                 gitlogo put gray26  -to  5 13
 773                 gitlogo put gray26  -to 10 13
 774                 gitlogo put gray26  -to  4 14 12 15
 775                 gitlogo put gray26  -to  5 15 11 16
 776                 gitlogo redither
 777
 778                 image create photo gitlogo32 -width 32 -height 32
 779                 gitlogo32 copy gitlogo -zoom 2 2
 780
 781                 wm iconphoto . -default gitlogo gitlogo32
 782         }
 783 }
 784
 785 ######################################################################
 786 ##
 787 ## config defaults
 788
 789 set cursor_ptr arrow
 790 font create font_ui
 791 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 792         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 793         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 794 } else {
 795         font create font_diff -family Courier -size 10
 796         catch {
 797                 label .dummy
 798                 eval font configure font_ui [font actual [.dummy cget -font]]
 799                 destroy .dummy
 800         }
 801 }
 802
 803 font create font_uiitalic
 804 font create font_uibold
 805 font create font_diffbold
 806 font create font_diffitalic
 807
 808 foreach class {Button Checkbutton Entry Label
 809                 Labelframe Listbox Message
 810                 Radiobutton Spinbox Text} {
 811         option add *$class.font font_ui
 812 }
 813 if {![is_MacOSX]} {
 814         option add *Menu.font font_ui
 815         option add *Entry.borderWidth 1 startupFile
 816         option add *Entry.relief sunken startupFile
 817         option add *RadioButton.anchor w startupFile
 818 }
 819 unset class
 820
 821 if {[is_Windows] || [is_MacOSX]} {
 822         option add *Menu.tearOff 0
 823 }
 824
 825 if {[is_MacOSX]} {
 826         set M1B M1
 827         set M1T Cmd
 828 } else {
 829         set M1B Control
 830         set M1T Ctrl
 831 }
 832
 833 proc bind_button3 {w cmd} {
 834         bind $w <Any-Button-3> $cmd
 835         if {[is_MacOSX]} {
 836                 # Mac OS X sends Button-2 on right click through three-button mouse,
 837                 # or through trackpad right-clicking (two-finger touch + click).
 838                 bind $w <Any-Button-2> $cmd
 839                 bind $w <Control-Button-1> $cmd
 840         }
 841 }
 842
 843 proc apply_config {} {
 844         global repo_config font_descs
 845
 846         foreach option $font_descs {
 847                 set name [lindex $option 0]
 848                 set font [lindex $option 1]
 849                 if {[catch {
 850                         set need_weight 1
 851                         foreach {cn cv} $repo_config(gui.$name) {
 852                                 if {$cn eq {-weight}} {
 853                                         set need_weight 0
 854                                 }
 855                                 font configure $font $cn $cv
 856                         }
 857                         if {$need_weight} {
 858                                 font configure $font -weight normal
 859                         }
 860                         } err]} {
 861                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 862                 }
 863                 foreach {cn cv} [font configure $font] {
 864                         font configure ${font}bold $cn $cv
 865                         font configure ${font}italic $cn $cv
 866                 }
 867                 font configure ${font}bold -weight bold
 868                 font configure ${font}italic -slant italic
 869         }
 870
 871         global use_ttk NS
 872         set use_ttk 0
 873         set NS {}
 874         if {$repo_config(gui.usettk)} {
 875                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 876                 if {$use_ttk} {
 877                         set NS ttk
 878                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 879                         pave_toplevel .
 880                 }
 881         }
 882 }
 883
 884 set default_config(branch.autosetupmerge) true
 885 set default_config(merge.tool) {}
 886 set default_config(mergetool.keepbackup) true
 887 set default_config(merge.diffstat) true
 888 set default_config(merge.summary) false
 889 set default_config(merge.verbosity) 2
 890 set default_config(user.name) {}
 891 set default_config(user.email) {}
 892
 893 set default_config(gui.encoding) [encoding system]
 894 set default_config(gui.matchtrackingbranch) false
 895 set default_config(gui.textconv) true
 896 set default_config(gui.pruneduringfetch) false
 897 set default_config(gui.trustmtime) false
 898 set default_config(gui.fastcopyblame) false
 899 set default_config(gui.maxrecentrepo) 10
 900 set default_config(gui.copyblamethreshold) 40
 901 set default_config(gui.blamehistoryctx) 7
 902 set default_config(gui.diffcontext) 5
 903 set default_config(gui.diffopts) {}
 904 set default_config(gui.commitmsgwidth) 75
 905 set default_config(gui.newbranchtemplate) {}
 906 set default_config(gui.spellingdictionary) {}
 907 set default_config(gui.fontui) [font configure font_ui]
 908 set default_config(gui.fontdiff) [font configure font_diff]
 909 # TODO: this option should be added to the git-config documentation
 910 set default_config(gui.maxfilesdisplayed) 5000
 911 set default_config(gui.usettk) 1
 912 set default_config(gui.warndetachedcommit) 1
 913 set default_config(gui.tabsize) 8
 914 set font_descs {
 915         {fontui   font_ui   {mc "Main Font"}}
 916         {fontdiff font_diff {mc "Diff/Console Font"}}
 917 }
 918 set default_config(gui.stageuntracked) ask
 919 set default_config(gui.displayuntracked) true
 920
 921 ######################################################################
 922 ##
 923 ## find git
 924
 925 set _git  [_which git]
 926 if {$_git eq {}} {
 927         catch {wm withdraw .}
 928         tk_messageBox \
 929                 -icon error \
 930                 -type ok \
 931                 -title [mc "git-gui: fatal error"] \
 932                 -message [mc "Cannot find git in PATH."]
 933         exit 1
 934 }
 935
 936 ######################################################################
 937 ##
 938 ## version check
 939
 940 if {[catch {set _git_version [git --version]} err]} {
 941         catch {wm withdraw .}
 942         tk_messageBox \
 943                 -icon error \
 944                 -type ok \
 945                 -title [mc "git-gui: fatal error"] \
 946                 -message "Cannot determine Git version:
 947
 948 $err
 949
 950 [appname] requires Git 1.5.0 or later."
 951         exit 1
 952 }
 953 if {![regsub {^git version } $_git_version {} _git_version]} {
 954         catch {wm withdraw .}
 955         tk_messageBox \
 956                 -icon error \
 957                 -type ok \
 958                 -title [mc "git-gui: fatal error"] \
 959                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 960         exit 1
 961 }
 962
 963 proc get_trimmed_version {s} {
 964     set r {}
 965     foreach x [split $s -._] {
 966         if {[string is integer -strict $x]} {
 967             lappend r $x
 968         } else {
 969             break
 970         }
 971     }
 972     return [join $r .]
 973 }
 974 set _real_git_version $_git_version
 975 set _git_version [get_trimmed_version $_git_version]
 976
 977 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 978         catch {wm withdraw .}
 979         if {[tk_messageBox \
 980                 -icon warning \
 981                 -type yesno \
 982                 -default no \
 983                 -title "[appname]: warning" \
 984                  -message [mc "Git version cannot be determined.
 985
 986 %s claims it is version '%s'.
 987
 988 %s requires at least Git 1.5.0 or later.
 989
 990 Assume '%s' is version 1.5.0?
 991 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 992                 set _git_version 1.5.0
 993         } else {
 994                 exit 1
 995         }
 996 }
 997 unset _real_git_version
 998
 999 proc git-version {args} {
1000         global _git_version
1001
1002         switch [llength $args] {
1003         0 {
1004                 return $_git_version
1005         }
1006
1007         2 {
1008                 set op [lindex $args 0]
1009                 set vr [lindex $args 1]
1010                 set cm [package vcompare $_git_version $vr]
1011                 return [expr $cm $op 0]
1012         }
1013
1014         4 {
1015                 set type [lindex $args 0]
1016                 set name [lindex $args 1]
1017                 set parm [lindex $args 2]
1018                 set body [lindex $args 3]
1019
1020                 if {($type ne {proc} && $type ne {method})} {
1021                         error "Invalid arguments to git-version"
1022                 }
1023                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1024                         error "Last arm of $type $name must be default"
1025                 }
1026
1027                 foreach {op vr cb} [lrange $body 0 end-2] {
1028                         if {[git-version $op $vr]} {
1029                                 return [uplevel [list $type $name $parm $cb]]
1030                         }
1031                 }
1032
1033                 return [uplevel [list $type $name $parm [lindex $body end]]]
1034         }
1035
1036         default {
1037                 error "git-version >= x"
1038         }
1039
1040         }
1041 }
1042
1043 if {[git-version < 1.5]} {
1044         catch {wm withdraw .}
1045         tk_messageBox \
1046                 -icon error \
1047                 -type ok \
1048                 -title [mc "git-gui: fatal error"] \
1049                 -message "[appname] requires Git 1.5.0 or later.
1050
1051 You are using [git-version]:
1052
1053 [git --version]"
1054         exit 1
1055 }
1056
1057 ######################################################################
1058 ##
1059 ## configure our library
1060
1061 set idx [file join $oguilib tclIndex]
1062 if {[catch {set fd [open $idx r]} err]} {
1063         catch {wm withdraw .}
1064         tk_messageBox \
1065                 -icon error \
1066                 -type ok \
1067                 -title [mc "git-gui: fatal error"] \
1068                 -message $err
1069         exit 1
1070 }
1071 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1072         set idx [list]
1073         while {[gets $fd n] >= 0} {
1074                 if {$n ne {} && ![string match #* $n]} {
1075                         lappend idx $n
1076                 }
1077         }
1078 } else {
1079         set idx {}
1080 }
1081 close $fd
1082
1083 if {$idx ne {}} {
1084         set loaded [list]
1085         foreach p $idx {
1086                 if {[lsearch -exact $loaded $p] >= 0} continue
1087                 source [file join $oguilib $p]
1088                 lappend loaded $p
1089         }
1090         unset loaded p
1091 } else {
1092         set auto_path [concat [list $oguilib] $auto_path]
1093 }
1094 unset -nocomplain idx fd
1095
1096 ######################################################################
1097 ##
1098 ## config file parsing
1099
1100 git-version proc _parse_config {arr_name args} {
1101         >= 1.5.3 {
1102                 upvar $arr_name arr
1103                 array unset arr
1104                 set buf {}
1105                 catch {
1106                         set fd_rc [eval \
1107                                 [list git_read config] \
1108                                 $args \
1109                                 [list --null --list]]
1110                         fconfigure $fd_rc -translation binary
1111                         set buf [read $fd_rc]
1112                         close $fd_rc
1113                 }
1114                 foreach line [split $buf "\0"] {
1115                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1116                                 if {[is_many_config $name]} {
1117                                         lappend arr($name) $value
1118                                 } else {
1119                                         set arr($name) $value
1120                                 }
1121                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1122                                 # no value given, but interpreting them as
1123                                 # boolean will be handled as true
1124                                 set arr($name) {}
1125                         }
1126                 }
1127         }
1128         default {
1129                 upvar $arr_name arr
1130                 array unset arr
1131                 catch {
1132                         set fd_rc [eval [list git_read config --list] $args]
1133                         while {[gets $fd_rc line] >= 0} {
1134                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1135                                         if {[is_many_config $name]} {
1136                                                 lappend arr($name) $value
1137                                         } else {
1138                                                 set arr($name) $value
1139                                         }
1140                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1141                                         # no value given, but interpreting them as
1142                                         # boolean will be handled as true
1143                                         set arr($name) {}
1144                                 }
1145                         }
1146                         close $fd_rc
1147                 }
1148         }
1149 }
1150
1151 proc load_config {include_global} {
1152         global repo_config global_config system_config default_config
1153
1154         if {$include_global} {
1155                 _parse_config system_config --system
1156                 _parse_config global_config --global
1157         }
1158         _parse_config repo_config
1159
1160         foreach name [array names default_config] {
1161                 if {[catch {set v $system_config($name)}]} {
1162                         set system_config($name) $default_config($name)
1163                 }
1164         }
1165         foreach name [array names system_config] {
1166                 if {[catch {set v $global_config($name)}]} {
1167                         set global_config($name) $system_config($name)
1168                 }
1169                 if {[catch {set v $repo_config($name)}]} {
1170                         set repo_config($name) $system_config($name)
1171                 }
1172         }
1173 }
1174
1175 ######################################################################
1176 ##
1177 ## feature option selection
1178
1179 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1180         unset _junk
1181 } else {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui.sh}} {
1185         set subcommand gui
1186 }
1187 if {$subcommand eq {gui} && [llength $argv] > 0} {
1188         set subcommand [lindex $argv 0]
1189         set argv [lrange $argv 1 end]
1190 }
1191
1192 enable_option multicommit
1193 enable_option branch
1194 enable_option transport
1195 disable_option bare
1196
1197 switch -- $subcommand {
1198 browser -
1199 blame {
1200         enable_option bare
1201
1202         disable_option multicommit
1203         disable_option branch
1204         disable_option transport
1205 }
1206 citool {
1207         enable_option singlecommit
1208         enable_option retcode
1209
1210         disable_option multicommit
1211         disable_option branch
1212         disable_option transport
1213
1214         while {[llength $argv] > 0} {
1215                 set a [lindex $argv 0]
1216                 switch -- $a {
1217                 --amend {
1218                         enable_option initialamend
1219                 }
1220                 --nocommit {
1221                         enable_option nocommit
1222                         enable_option nocommitmsg
1223                 }
1224                 --commitmsg {
1225                         disable_option nocommitmsg
1226                 }
1227                 default {
1228                         break
1229                 }
1230                 }
1231
1232                 set argv [lrange $argv 1 end]
1233         }
1234 }
1235 }
1236
1237 ######################################################################
1238 ##
1239 ## execution environment
1240
1241 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1242
1243 # Suggest our implementation of askpass, if none is set
1244 if {![info exists env(SSH_ASKPASS)]} {
1245         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1246 }
1247
1248 ######################################################################
1249 ##
1250 ## repository setup
1251
1252 set picked 0
1253 if {[catch {
1254                 set _gitdir $env(GIT_DIR)
1255                 set _prefix {}
1256                 }]
1257         && [catch {
1258                 # beware that from the .git dir this sets _gitdir to .
1259                 # and _prefix to the empty string
1260                 set _gitdir [git rev-parse --git-dir]
1261                 set _prefix [git rev-parse --show-prefix]
1262         } err]} {
1263         load_config 1
1264         apply_config
1265         choose_repository::pick
1266         set picked 1
1267 }
1268
1269 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1270 # run from the .git dir itself) lest the routines to find the worktree
1271 # get confused
1272 if {$_gitdir eq "."} {
1273         set _gitdir [pwd]
1274 }
1275
1276 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1277         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1278 }
1279 if {![file isdirectory $_gitdir]} {
1280         catch {wm withdraw .}
1281         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1282         exit 1
1283 }
1284 # _gitdir exists, so try loading the config
1285 load_config 0
1286 apply_config
1287
1288 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1289 if {[package vcompare $_git_version 1.7.0] >= 0} {
1290         if { [is_Cygwin] } {
1291                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1292         } else {
1293                 set _gitworktree [git rev-parse --show-toplevel]
1294         }
1295 } else {
1296         # try to set work tree from environment, core.worktree or use
1297         # cdup to obtain a relative path to the top of the worktree. If
1298         # run from the top, the ./ prefix ensures normalize expands pwd.
1299         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1300                 set _gitworktree [get_config core.worktree]
1301                 if {$_gitworktree eq ""} {
1302                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1303                 }
1304         }
1305 }
1306
1307 if {$_prefix ne {}} {
1308         if {$_gitworktree eq {}} {
1309                 regsub -all {[^/]+/} $_prefix ../ cdup
1310         } else {
1311                 set cdup $_gitworktree
1312         }
1313         if {[catch {cd $cdup} err]} {
1314                 catch {wm withdraw .}
1315                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1316                 exit 1
1317         }
1318         set _gitworktree [pwd]
1319         unset cdup
1320 } elseif {![is_enabled bare]} {
1321         if {[is_bare]} {
1322                 catch {wm withdraw .}
1323                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1324                 exit 1
1325         }
1326         if {$_gitworktree eq {}} {
1327                 set _gitworktree [file dirname $_gitdir]
1328         }
1329         if {[catch {cd $_gitworktree} err]} {
1330                 catch {wm withdraw .}
1331                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1332                 exit 1
1333         }
1334         set _gitworktree [pwd]
1335 }
1336 set _reponame [file split [file normalize $_gitdir]]
1337 if {[lindex $_reponame end] eq {.git}} {
1338         set _reponame [lindex $_reponame end-1]
1339 } else {
1340         set _reponame [lindex $_reponame end]
1341 }
1342
1343 set env(GIT_DIR) $_gitdir
1344 set env(GIT_WORK_TREE) $_gitworktree
1345
1346 ######################################################################
1347 ##
1348 ## global init
1349
1350 set current_diff_path {}
1351 set current_diff_side {}
1352 set diff_actions [list]
1353
1354 set HEAD {}
1355 set PARENT {}
1356 set MERGE_HEAD [list]
1357 set commit_type {}
1358 set empty_tree {}
1359 set current_branch {}
1360 set is_detached 0
1361 set current_diff_path {}
1362 set is_3way_diff 0
1363 set is_submodule_diff 0
1364 set is_conflict_diff 0
1365 set selected_commit_type new
1366 set diff_empty_count 0
1367
1368 set nullid "0000000000000000000000000000000000000000"
1369 set nullid2 "0000000000000000000000000000000000000001"
1370
1371 ######################################################################
1372 ##
1373 ## task management
1374
1375 set rescan_active 0
1376 set diff_active 0
1377 set last_clicked {}
1378
1379 set disable_on_lock [list]
1380 set index_lock_type none
1381
1382 proc lock_index {type} {
1383         global index_lock_type disable_on_lock
1384
1385         if {$index_lock_type eq {none}} {
1386                 set index_lock_type $type
1387                 foreach w $disable_on_lock {
1388                         uplevel #0 $w disabled
1389                 }
1390                 return 1
1391         } elseif {$index_lock_type eq "begin-$type"} {
1392                 set index_lock_type $type
1393                 return 1
1394         }
1395         return 0
1396 }
1397
1398 proc unlock_index {} {
1399         global index_lock_type disable_on_lock
1400
1401         set index_lock_type none
1402         foreach w $disable_on_lock {
1403                 uplevel #0 $w normal
1404         }
1405 }
1406
1407 ######################################################################
1408 ##
1409 ## status
1410
1411 proc repository_state {ctvar hdvar mhvar} {
1412         global current_branch
1413         upvar $ctvar ct $hdvar hd $mhvar mh
1414
1415         set mh [list]
1416
1417         load_current_branch
1418         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1419                 set hd {}
1420                 set ct initial
1421                 return
1422         }
1423
1424         set merge_head [gitdir MERGE_HEAD]
1425         if {[file exists $merge_head]} {
1426                 set ct merge
1427                 set fd_mh [open $merge_head r]
1428                 while {[gets $fd_mh line] >= 0} {
1429                         lappend mh $line
1430                 }
1431                 close $fd_mh
1432                 return
1433         }
1434
1435         set ct normal
1436 }
1437
1438 proc PARENT {} {
1439         global PARENT empty_tree
1440
1441         set p [lindex $PARENT 0]
1442         if {$p ne {}} {
1443                 return $p
1444         }
1445         if {$empty_tree eq {}} {
1446                 set empty_tree [git mktree << {}]
1447         }
1448         return $empty_tree
1449 }
1450
1451 proc force_amend {} {
1452         global selected_commit_type
1453         global HEAD PARENT MERGE_HEAD commit_type
1454
1455         repository_state newType newHEAD newMERGE_HEAD
1456         set HEAD $newHEAD
1457         set PARENT $newHEAD
1458         set MERGE_HEAD $newMERGE_HEAD
1459         set commit_type $newType
1460
1461         set selected_commit_type amend
1462         do_select_commit_type
1463 }
1464
1465 proc rescan {after {honor_trustmtime 1}} {
1466         global HEAD PARENT MERGE_HEAD commit_type
1467         global ui_index ui_workdir ui_comm
1468         global rescan_active file_states
1469         global repo_config
1470
1471         if {$rescan_active > 0 || ![lock_index read]} return
1472
1473         repository_state newType newHEAD newMERGE_HEAD
1474         if {[string match amend* $commit_type]
1475                 && $newType eq {normal}
1476                 && $newHEAD eq $HEAD} {
1477         } else {
1478                 set HEAD $newHEAD
1479                 set PARENT $newHEAD
1480                 set MERGE_HEAD $newMERGE_HEAD
1481                 set commit_type $newType
1482         }
1483
1484         array unset file_states
1485
1486         if {!$::GITGUI_BCK_exists &&
1487                 (![$ui_comm edit modified]
1488                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1489                 if {[string match amend* $commit_type]} {
1490                 } elseif {[load_message GITGUI_MSG utf-8]} {
1491                 } elseif {[run_prepare_commit_msg_hook]} {
1492                 } elseif {[load_message MERGE_MSG]} {
1493                 } elseif {[load_message SQUASH_MSG]} {
1494                 }
1495                 $ui_comm edit reset
1496                 $ui_comm edit modified false
1497         }
1498
1499         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1500                 rescan_stage2 {} $after
1501         } else {
1502                 set rescan_active 1
1503                 ui_status [mc "Refreshing file status..."]
1504                 set fd_rf [git_read update-index \
1505                         -q \
1506                         --unmerged \
1507                         --ignore-missing \
1508                         --refresh \
1509                         ]
1510                 fconfigure $fd_rf -blocking 0 -translation binary
1511                 fileevent $fd_rf readable \
1512                         [list rescan_stage2 $fd_rf $after]
1513         }
1514 }
1515
1516 if {[is_Cygwin]} {
1517         set is_git_info_exclude {}
1518         proc have_info_exclude {} {
1519                 global is_git_info_exclude
1520
1521                 if {$is_git_info_exclude eq {}} {
1522                         if {[catch {exec test -f [gitdir info exclude]}]} {
1523                                 set is_git_info_exclude 0
1524                         } else {
1525                                 set is_git_info_exclude 1
1526                         }
1527                 }
1528                 return $is_git_info_exclude
1529         }
1530 } else {
1531         proc have_info_exclude {} {
1532                 return [file readable [gitdir info exclude]]
1533         }
1534 }
1535
1536 proc rescan_stage2 {fd after} {
1537         global rescan_active buf_rdi buf_rdf buf_rlo
1538
1539         if {$fd ne {}} {
1540                 read $fd
1541                 if {![eof $fd]} return
1542                 close $fd
1543         }
1544
1545         if {[package vcompare $::_git_version 1.6.3] >= 0} {
1546                 set ls_others [list --exclude-standard]
1547         } else {
1548                 set ls_others [list --exclude-per-directory=.gitignore]
1549                 if {[have_info_exclude]} {
1550                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1551                 }
1552                 set user_exclude [get_config core.excludesfile]
1553                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1554                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1555                 }
1556         }
1557
1558         set buf_rdi {}
1559         set buf_rdf {}
1560         set buf_rlo {}
1561
1562         set rescan_active 2
1563         ui_status [mc "Scanning for modified files ..."]
1564         if {[git-version >= "1.7.2"]} {
1565                 set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1566         } else {
1567                 set fd_di [git_read diff-index --cached -z [PARENT]]
1568         }
1569         set fd_df [git_read diff-files -z]
1570
1571         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1572         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1573
1574         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1575         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1576
1577         if {[is_config_true gui.displayuntracked]} {
1578                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1579                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1580                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1581                 incr rescan_active
1582         }
1583 }
1584
1585 proc load_message {file {encoding {}}} {
1586         global ui_comm
1587
1588         set f [gitdir $file]
1589         if {[file isfile $f]} {
1590                 if {[catch {set fd [open $f r]}]} {
1591                         return 0
1592                 }
1593                 fconfigure $fd -eofchar {}
1594                 if {$encoding ne {}} {
1595                         fconfigure $fd -encoding $encoding
1596                 }
1597                 set content [string trim [read $fd]]
1598                 close $fd
1599                 regsub -all -line {[ \r\t]+$} $content {} content
1600                 $ui_comm delete 0.0 end
1601                 $ui_comm insert end $content
1602                 return 1
1603         }
1604         return 0
1605 }
1606
1607 proc run_prepare_commit_msg_hook {} {
1608         global pch_error
1609
1610         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1611         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1612         # empty file but existent file.
1613
1614         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1615
1616         if {[file isfile [gitdir MERGE_MSG]]} {
1617                 set pcm_source "merge"
1618                 set fd_mm [open [gitdir MERGE_MSG] r]
1619                 fconfigure $fd_mm -encoding utf-8
1620                 puts -nonewline $fd_pcm [read $fd_mm]
1621                 close $fd_mm
1622         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1623                 set pcm_source "squash"
1624                 set fd_sm [open [gitdir SQUASH_MSG] r]
1625                 fconfigure $fd_sm -encoding utf-8
1626                 puts -nonewline $fd_pcm [read $fd_sm]
1627                 close $fd_sm
1628         } else {
1629                 set pcm_source ""
1630         }
1631
1632         close $fd_pcm
1633
1634         set fd_ph [githook_read prepare-commit-msg \
1635                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1636         if {$fd_ph eq {}} {
1637                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1638                 return 0;
1639         }
1640
1641         ui_status [mc "Calling prepare-commit-msg hook..."]
1642         set pch_error {}
1643
1644         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1645         fileevent $fd_ph readable \
1646                 [list prepare_commit_msg_hook_wait $fd_ph]
1647
1648         return 1;
1649 }
1650
1651 proc prepare_commit_msg_hook_wait {fd_ph} {
1652         global pch_error
1653
1654         append pch_error [read $fd_ph]
1655         fconfigure $fd_ph -blocking 1
1656         if {[eof $fd_ph]} {
1657                 if {[catch {close $fd_ph}]} {
1658                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1659                         hook_failed_popup prepare-commit-msg $pch_error
1660                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1661                         exit 1
1662                 } else {
1663                         load_message PREPARE_COMMIT_MSG
1664                 }
1665                 set pch_error {}
1666                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1667                 return
1668         }
1669         fconfigure $fd_ph -blocking 0
1670         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1671 }
1672
1673 proc read_diff_index {fd after} {
1674         global buf_rdi
1675
1676         append buf_rdi [read $fd]
1677         set c 0
1678         set n [string length $buf_rdi]
1679         while {$c < $n} {
1680                 set z1 [string first "\0" $buf_rdi $c]
1681                 if {$z1 == -1} break
1682                 incr z1
1683                 set z2 [string first "\0" $buf_rdi $z1]
1684                 if {$z2 == -1} break
1685
1686                 incr c
1687                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1688                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1689                 merge_state \
1690                         [encoding convertfrom $p] \
1691                         [lindex $i 4]? \
1692                         [list [lindex $i 0] [lindex $i 2]] \
1693                         [list]
1694                 set c $z2
1695                 incr c
1696         }
1697         if {$c < $n} {
1698                 set buf_rdi [string range $buf_rdi $c end]
1699         } else {
1700                 set buf_rdi {}
1701         }
1702
1703         rescan_done $fd buf_rdi $after
1704 }
1705
1706 proc read_diff_files {fd after} {
1707         global buf_rdf
1708
1709         append buf_rdf [read $fd]
1710         set c 0
1711         set n [string length $buf_rdf]
1712         while {$c < $n} {
1713                 set z1 [string first "\0" $buf_rdf $c]
1714                 if {$z1 == -1} break
1715                 incr z1
1716                 set z2 [string first "\0" $buf_rdf $z1]
1717                 if {$z2 == -1} break
1718
1719                 incr c
1720                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1721                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1722                 merge_state \
1723                         [encoding convertfrom $p] \
1724                         ?[lindex $i 4] \
1725                         [list] \
1726                         [list [lindex $i 0] [lindex $i 2]]
1727                 set c $z2
1728                 incr c
1729         }
1730         if {$c < $n} {
1731                 set buf_rdf [string range $buf_rdf $c end]
1732         } else {
1733                 set buf_rdf {}
1734         }
1735
1736         rescan_done $fd buf_rdf $after
1737 }
1738
1739 proc read_ls_others {fd after} {
1740         global buf_rlo
1741
1742         append buf_rlo [read $fd]
1743         set pck [split $buf_rlo "\0"]
1744         set buf_rlo [lindex $pck end]
1745         foreach p [lrange $pck 0 end-1] {
1746                 set p [encoding convertfrom $p]
1747                 if {[string index $p end] eq {/}} {
1748                         set p [string range $p 0 end-1]
1749                 }
1750                 merge_state $p ?O
1751         }
1752         rescan_done $fd buf_rlo $after
1753 }
1754
1755 proc rescan_done {fd buf after} {
1756         global rescan_active current_diff_path
1757         global file_states repo_config
1758         upvar $buf to_clear
1759
1760         if {![eof $fd]} return
1761         set to_clear {}
1762         close $fd
1763         if {[incr rescan_active -1] > 0} return
1764
1765         prune_selection
1766         unlock_index
1767         display_all_files
1768         if {$current_diff_path ne {}} { reshow_diff $after }
1769         if {$current_diff_path eq {}} { select_first_diff $after }
1770 }
1771
1772 proc prune_selection {} {
1773         global file_states selected_paths
1774
1775         foreach path [array names selected_paths] {
1776                 if {[catch {set still_here $file_states($path)}]} {
1777                         unset selected_paths($path)
1778                 }
1779         }
1780 }
1781
1782 ######################################################################
1783 ##
1784 ## ui helpers
1785
1786 proc mapicon {w state path} {
1787         global all_icons
1788
1789         if {[catch {set r $all_icons($state$w)}]} {
1790                 puts "error: no icon for $w state={$state} $path"
1791                 return file_plain
1792         }
1793         return $r
1794 }
1795
1796 proc mapdesc {state path} {
1797         global all_descs
1798
1799         if {[catch {set r $all_descs($state)}]} {
1800                 puts "error: no desc for state={$state} $path"
1801                 return $state
1802         }
1803         return $r
1804 }
1805
1806 proc ui_status {msg} {
1807         global main_status
1808         if {[info exists main_status]} {
1809                 $main_status show $msg
1810         }
1811 }
1812
1813 proc ui_ready {{test {}}} {
1814         global main_status
1815         if {[info exists main_status]} {
1816                 $main_status show [mc "Ready."] $test
1817         }
1818 }
1819
1820 proc escape_path {path} {
1821         regsub -all {\\} $path "\\\\" path
1822         regsub -all "\n" $path "\\n" path
1823         return $path
1824 }
1825
1826 proc short_path {path} {
1827         return [escape_path [lindex [file split $path] end]]
1828 }
1829
1830 set next_icon_id 0
1831 set null_sha1 [string repeat 0 40]
1832
1833 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1834         global file_states next_icon_id null_sha1
1835
1836         set s0 [string index $new_state 0]
1837         set s1 [string index $new_state 1]
1838
1839         if {[catch {set info $file_states($path)}]} {
1840                 set state __
1841                 set icon n[incr next_icon_id]
1842         } else {
1843                 set state [lindex $info 0]
1844                 set icon [lindex $info 1]
1845                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1846                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1847         }
1848
1849         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1850         elseif {$s0 eq {_}} {set s0 _}
1851
1852         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1853         elseif {$s1 eq {_}} {set s1 _}
1854
1855         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1856                 set head_info [list 0 $null_sha1]
1857         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1858                 && $head_info eq {}} {
1859                 set head_info $index_info
1860         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1861                 set index_info $head_info
1862                 set head_info {}
1863         }
1864
1865         set file_states($path) [list $s0$s1 $icon \
1866                 $head_info $index_info \
1867                 ]
1868         return $state
1869 }
1870
1871 proc display_file_helper {w path icon_name old_m new_m} {
1872         global file_lists
1873
1874         if {$new_m eq {_}} {
1875                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1876                 if {$lno >= 0} {
1877                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1878                         incr lno
1879                         $w conf -state normal
1880                         $w delete $lno.0 [expr {$lno + 1}].0
1881                         $w conf -state disabled
1882                 }
1883         } elseif {$old_m eq {_} && $new_m ne {_}} {
1884                 lappend file_lists($w) $path
1885                 set file_lists($w) [lsort -unique $file_lists($w)]
1886                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1887                 incr lno
1888                 $w conf -state normal
1889                 $w image create $lno.0 \
1890                         -align center -padx 5 -pady 1 \
1891                         -name $icon_name \
1892                         -image [mapicon $w $new_m $path]
1893                 $w insert $lno.1 "[escape_path $path]\n"
1894                 $w conf -state disabled
1895         } elseif {$old_m ne $new_m} {
1896                 $w conf -state normal
1897                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1898                 $w conf -state disabled
1899         }
1900 }
1901
1902 proc display_file {path state} {
1903         global file_states selected_paths
1904         global ui_index ui_workdir
1905
1906         set old_m [merge_state $path $state]
1907         set s $file_states($path)
1908         set new_m [lindex $s 0]
1909         set icon_name [lindex $s 1]
1910
1911         set o [string index $old_m 0]
1912         set n [string index $new_m 0]
1913         if {$o eq {U}} {
1914                 set o _
1915         }
1916         if {$n eq {U}} {
1917                 set n _
1918         }
1919         display_file_helper     $ui_index $path $icon_name $o $n
1920
1921         if {[string index $old_m 0] eq {U}} {
1922                 set o U
1923         } else {
1924                 set o [string index $old_m 1]
1925         }
1926         if {[string index $new_m 0] eq {U}} {
1927                 set n U
1928         } else {
1929                 set n [string index $new_m 1]
1930         }
1931         display_file_helper     $ui_workdir $path $icon_name $o $n
1932
1933         if {$new_m eq {__}} {
1934                 unset file_states($path)
1935                 catch {unset selected_paths($path)}
1936         }
1937 }
1938
1939 proc display_all_files_helper {w path icon_name m} {
1940         global file_lists
1941
1942         lappend file_lists($w) $path
1943         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1944         $w image create end \
1945                 -align center -padx 5 -pady 1 \
1946                 -name $icon_name \
1947                 -image [mapicon $w $m $path]
1948         $w insert end "[escape_path $path]\n"
1949 }
1950
1951 set files_warning 0
1952 proc display_all_files {} {
1953         global ui_index ui_workdir
1954         global file_states file_lists
1955         global last_clicked
1956         global files_warning
1957
1958         $ui_index conf -state normal
1959         $ui_workdir conf -state normal
1960
1961         $ui_index delete 0.0 end
1962         $ui_workdir delete 0.0 end
1963         set last_clicked {}
1964
1965         set file_lists($ui_index) [list]
1966         set file_lists($ui_workdir) [list]
1967
1968         set to_display [lsort [array names file_states]]
1969         set display_limit [get_config gui.maxfilesdisplayed]
1970         set displayed 0
1971         foreach path $to_display {
1972                 set s $file_states($path)
1973                 set m [lindex $s 0]
1974                 set icon_name [lindex $s 1]
1975
1976                 if {$displayed > $display_limit && [string index $m 1] eq {O} } {
1977                         if {!$files_warning} {
1978                                 # do not repeatedly warn:
1979                                 set files_warning 1
1980                                 info_popup [mc "Display limit (gui.maxfilesdisplayed = %s) reached, not showing all %s files." \
1981                                         $display_limit [llength $to_display]]
1982                         }
1983                         continue
1984                 }
1985
1986                 set s [string index $m 0]
1987                 if {$s ne {U} && $s ne {_}} {
1988                         display_all_files_helper $ui_index $path \
1989                                 $icon_name $s
1990                 }
1991
1992                 if {[string index $m 0] eq {U}} {
1993                         set s U
1994                 } else {
1995                         set s [string index $m 1]
1996                 }
1997                 if {$s ne {_}} {
1998                         display_all_files_helper $ui_workdir $path \
1999                                 $icon_name $s
2000                         incr displayed
2001                 }
2002         }
2003
2004         $ui_index conf -state disabled
2005         $ui_workdir conf -state disabled
2006 }
2007
2008 ######################################################################
2009 ##
2010 ## icons
2011
2012 set filemask {
2013 #define mask_width 14
2014 #define mask_height 15
2015 static unsigned char mask_bits[] = {
2016    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2017    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2018    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2019 }
2020
2021 image create bitmap file_plain -background white -foreground black -data {
2022 #define plain_width 14
2023 #define plain_height 15
2024 static unsigned char plain_bits[] = {
2025    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2026    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2027    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2028 } -maskdata $filemask
2029
2030 image create bitmap file_mod -background white -foreground blue -data {
2031 #define mod_width 14
2032 #define mod_height 15
2033 static unsigned char mod_bits[] = {
2034    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2035    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2036    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2037 } -maskdata $filemask
2038
2039 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2040 #define file_fulltick_width 14
2041 #define file_fulltick_height 15
2042 static unsigned char file_fulltick_bits[] = {
2043    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2044    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2045    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2046 } -maskdata $filemask
2047
2048 image create bitmap file_question -background white -foreground black -data {
2049 #define file_question_width 14
2050 #define file_question_height 15
2051 static unsigned char file_question_bits[] = {
2052    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2053    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2054    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2055 } -maskdata $filemask
2056
2057 image create bitmap file_removed -background white -foreground red -data {
2058 #define file_removed_width 14
2059 #define file_removed_height 15
2060 static unsigned char file_removed_bits[] = {
2061    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2062    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2063    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2064 } -maskdata $filemask
2065
2066 image create bitmap file_merge -background white -foreground blue -data {
2067 #define file_merge_width 14
2068 #define file_merge_height 15
2069 static unsigned char file_merge_bits[] = {
2070    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2071    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2072    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2073 } -maskdata $filemask
2074
2075 image create bitmap file_statechange -background white -foreground green -data {
2076 #define file_statechange_width 14
2077 #define file_statechange_height 15
2078 static unsigned char file_statechange_bits[] = {
2079    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2080    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2081    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2082 } -maskdata $filemask
2083
2084 set ui_index .vpane.files.index.list
2085 set ui_workdir .vpane.files.workdir.list
2086
2087 set all_icons(_$ui_index)   file_plain
2088 set all_icons(A$ui_index)   file_plain
2089 set all_icons(M$ui_index)   file_fulltick
2090 set all_icons(D$ui_index)   file_removed
2091 set all_icons(U$ui_index)   file_merge
2092 set all_icons(T$ui_index)   file_statechange
2093
2094 set all_icons(_$ui_workdir) file_plain
2095 set all_icons(M$ui_workdir) file_mod
2096 set all_icons(D$ui_workdir) file_question
2097 set all_icons(U$ui_workdir) file_merge
2098 set all_icons(O$ui_workdir) file_plain
2099 set all_icons(T$ui_workdir) file_statechange
2100
2101 set max_status_desc 0
2102 foreach i {
2103                 {__ {mc "Unmodified"}}
2104
2105                 {_M {mc "Modified, not staged"}}
2106                 {M_ {mc "Staged for commit"}}
2107                 {MM {mc "Portions staged for commit"}}
2108                 {MD {mc "Staged for commit, missing"}}
2109
2110                 {_T {mc "File type changed, not staged"}}
2111                 {MT {mc "File type changed, old type staged for commit"}}
2112                 {AT {mc "File type changed, old type staged for commit"}}
2113                 {T_ {mc "File type changed, staged"}}
2114                 {TM {mc "File type change staged, modification not staged"}}
2115                 {TD {mc "File type change staged, file missing"}}
2116
2117                 {_O {mc "Untracked, not staged"}}
2118                 {A_ {mc "Staged for commit"}}
2119                 {AM {mc "Portions staged for commit"}}
2120                 {AD {mc "Staged for commit, missing"}}
2121
2122                 {_D {mc "Missing"}}
2123                 {D_ {mc "Staged for removal"}}
2124                 {DO {mc "Staged for removal, still present"}}
2125
2126                 {_U {mc "Requires merge resolution"}}
2127                 {U_ {mc "Requires merge resolution"}}
2128                 {UU {mc "Requires merge resolution"}}
2129                 {UM {mc "Requires merge resolution"}}
2130                 {UD {mc "Requires merge resolution"}}
2131                 {UT {mc "Requires merge resolution"}}
2132         } {
2133         set text [eval [lindex $i 1]]
2134         if {$max_status_desc < [string length $text]} {
2135                 set max_status_desc [string length $text]
2136         }
2137         set all_descs([lindex $i 0]) $text
2138 }
2139 unset i
2140
2141 ######################################################################
2142 ##
2143 ## util
2144
2145 proc scrollbar2many {list mode args} {
2146         foreach w $list {eval $w $mode $args}
2147 }
2148
2149 proc many2scrollbar {list mode sb top bottom} {
2150         $sb set $top $bottom
2151         foreach w $list {$w $mode moveto $top}
2152 }
2153
2154 proc incr_font_size {font {amt 1}} {
2155         set sz [font configure $font -size]
2156         incr sz $amt
2157         font configure $font -size $sz
2158         font configure ${font}bold -size $sz
2159         font configure ${font}italic -size $sz
2160 }
2161
2162 ######################################################################
2163 ##
2164 ## ui commands
2165
2166 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2167
2168 proc do_gitk {revs {is_submodule false}} {
2169         global current_diff_path file_states current_diff_side ui_index
2170         global _gitdir _gitworktree
2171
2172         # -- Always start gitk through whatever we were loaded with.  This
2173         #    lets us bypass using shell process on Windows systems.
2174         #
2175         set exe [_which gitk -script]
2176         set cmd [list [info nameofexecutable] $exe]
2177         if {$exe eq {}} {
2178                 error_popup [mc "Couldn't find gitk in PATH"]
2179         } else {
2180                 global env
2181
2182                 set pwd [pwd]
2183
2184                 if {!$is_submodule} {
2185                         if {![is_bare]} {
2186                                 cd $_gitworktree
2187                         }
2188                 } else {
2189                         cd $current_diff_path
2190                         if {$revs eq {--}} {
2191                                 set s $file_states($current_diff_path)
2192                                 set old_sha1 {}
2193                                 set new_sha1 {}
2194                                 switch -glob -- [lindex $s 0] {
2195                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2196                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2197                                 MM {
2198                                         if {$current_diff_side eq $ui_index} {
2199                                                 set old_sha1 [lindex [lindex $s 2] 1]
2200                                                 set new_sha1 [lindex [lindex $s 3] 1]
2201                                         } else {
2202                                                 set old_sha1 [lindex [lindex $s 3] 1]
2203                                         }
2204                                 }
2205                                 }
2206                                 set revs $old_sha1...$new_sha1
2207                         }
2208                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2209                         # we've been using for the main repository, so unset them.
2210                         # TODO we could make life easier (start up faster?) for gitk
2211                         # by setting these to the appropriate values to allow gitk
2212                         # to skip the heuristics to find their proper value
2213                         unset env(GIT_DIR)
2214                         unset env(GIT_WORK_TREE)
2215                 }
2216                 eval exec $cmd $revs "--" "--" &
2217
2218                 set env(GIT_DIR) $_gitdir
2219                 set env(GIT_WORK_TREE) $_gitworktree
2220                 cd $pwd
2221
2222                 ui_status $::starting_gitk_msg
2223                 after 10000 {
2224                         ui_ready $starting_gitk_msg
2225                 }
2226         }
2227 }
2228
2229 proc do_git_gui {} {
2230         global current_diff_path
2231
2232         # -- Always start git gui through whatever we were loaded with.  This
2233         #    lets us bypass using shell process on Windows systems.
2234         #
2235         set exe [list [_which git]]
2236         if {$exe eq {}} {
2237                 error_popup [mc "Couldn't find git gui in PATH"]
2238         } else {
2239                 global env
2240                 global _gitdir _gitworktree
2241
2242                 # see note in do_gitk about unsetting these vars when
2243                 # running tools in a submodule
2244                 unset env(GIT_DIR)
2245                 unset env(GIT_WORK_TREE)
2246
2247                 set pwd [pwd]
2248                 cd $current_diff_path
2249
2250                 eval exec $exe gui &
2251
2252                 set env(GIT_DIR) $_gitdir
2253                 set env(GIT_WORK_TREE) $_gitworktree
2254                 cd $pwd
2255
2256                 ui_status $::starting_gitk_msg
2257                 after 10000 {
2258                         ui_ready $starting_gitk_msg
2259                 }
2260         }
2261 }
2262
2263 proc do_explore {} {
2264         global _gitworktree
2265         set explorer {}
2266         if {[is_Cygwin] || [is_Windows]} {
2267                 set explorer "explorer.exe"
2268         } elseif {[is_MacOSX]} {
2269                 set explorer "open"
2270         } else {
2271                 # freedesktop.org-conforming system is our best shot
2272                 set explorer "xdg-open"
2273         }
2274         eval exec $explorer [list [file nativename $_gitworktree]] &
2275 }
2276
2277 set is_quitting 0
2278 set ret_code    1
2279
2280 proc terminate_me {win} {
2281         global ret_code
2282         if {$win ne {.}} return
2283         exit $ret_code
2284 }
2285
2286 proc do_quit {{rc {1}}} {
2287         global ui_comm is_quitting repo_config commit_type
2288         global GITGUI_BCK_exists GITGUI_BCK_i
2289         global ui_comm_spell
2290         global ret_code use_ttk
2291
2292         if {$is_quitting} return
2293         set is_quitting 1
2294
2295         if {[winfo exists $ui_comm]} {
2296                 # -- Stash our current commit buffer.
2297                 #
2298                 set save [gitdir GITGUI_MSG]
2299                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2300                         file rename -force [gitdir GITGUI_BCK] $save
2301                         set GITGUI_BCK_exists 0
2302                 } else {
2303                         set msg [string trim [$ui_comm get 0.0 end]]
2304                         regsub -all -line {[ \r\t]+$} $msg {} msg
2305                         if {(![string match amend* $commit_type]
2306                                 || [$ui_comm edit modified])
2307                                 && $msg ne {}} {
2308                                 catch {
2309                                         set fd [open $save w]
2310                                         fconfigure $fd -encoding utf-8
2311                                         puts -nonewline $fd $msg
2312                                         close $fd
2313                                 }
2314                         } else {
2315                                 catch {file delete $save}
2316                         }
2317                 }
2318
2319                 # -- Cancel our spellchecker if its running.
2320                 #
2321                 if {[info exists ui_comm_spell]} {
2322                         $ui_comm_spell stop
2323                 }
2324
2325                 # -- Remove our editor backup, its not needed.
2326                 #
2327                 after cancel $GITGUI_BCK_i
2328                 if {$GITGUI_BCK_exists} {
2329                         catch {file delete [gitdir GITGUI_BCK]}
2330                 }
2331
2332                 # -- Stash our current window geometry into this repository.
2333                 #
2334                 set cfg_wmstate [wm state .]
2335                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2336                         set rc_wmstate {}
2337                 }
2338                 if {$cfg_wmstate ne $rc_wmstate} {
2339                         catch {git config gui.wmstate $cfg_wmstate}
2340                 }
2341                 if {$cfg_wmstate eq {zoomed}} {
2342                         # on Windows wm geometry will lie about window
2343                         # position (but not size) when window is zoomed
2344                         # restore the window before querying wm geometry
2345                         wm state . normal
2346                 }
2347                 set cfg_geometry [list]
2348                 lappend cfg_geometry [wm geometry .]
2349                 if {$use_ttk} {
2350                         lappend cfg_geometry [.vpane sashpos 0]
2351                         lappend cfg_geometry [.vpane.files sashpos 0]
2352                 } else {
2353                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2354                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2355                 }
2356                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2357                         set rc_geometry {}
2358                 }
2359                 if {$cfg_geometry ne $rc_geometry} {
2360                         catch {git config gui.geometry $cfg_geometry}
2361                 }
2362         }
2363
2364         set ret_code $rc
2365
2366         # Briefly enable send again, working around Tk bug
2367         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2368         tk appname [appname]
2369
2370         destroy .
2371 }
2372
2373 proc do_rescan {} {
2374         rescan ui_ready
2375 }
2376
2377 proc ui_do_rescan {} {
2378         rescan {force_first_diff ui_ready}
2379 }
2380
2381 proc do_commit {} {
2382         commit_tree
2383 }
2384
2385 proc next_diff {{after {}}} {
2386         global next_diff_p next_diff_w next_diff_i
2387         show_diff $next_diff_p $next_diff_w {} {} $after
2388 }
2389
2390 proc find_anchor_pos {lst name} {
2391         set lid [lsearch -sorted -exact $lst $name]
2392
2393         if {$lid == -1} {
2394                 set lid 0
2395                 foreach lname $lst {
2396                         if {$lname >= $name} break
2397                         incr lid
2398                 }
2399         }
2400
2401         return $lid
2402 }
2403
2404 proc find_file_from {flist idx delta path mmask} {
2405         global file_states
2406
2407         set len [llength $flist]
2408         while {$idx >= 0 && $idx < $len} {
2409                 set name [lindex $flist $idx]
2410
2411                 if {$name ne $path && [info exists file_states($name)]} {
2412                         set state [lindex $file_states($name) 0]
2413
2414                         if {$mmask eq {} || [regexp $mmask $state]} {
2415                                 return $idx
2416                         }
2417                 }
2418
2419                 incr idx $delta
2420         }
2421
2422         return {}
2423 }
2424
2425 proc find_next_diff {w path {lno {}} {mmask {}}} {
2426         global next_diff_p next_diff_w next_diff_i
2427         global file_lists ui_index ui_workdir
2428
2429         set flist $file_lists($w)
2430         if {$lno eq {}} {
2431                 set lno [find_anchor_pos $flist $path]
2432         } else {
2433                 incr lno -1
2434         }
2435
2436         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2437                 if {$w eq $ui_index} {
2438                         set mmask "^$mmask"
2439                 } else {
2440                         set mmask "$mmask\$"
2441                 }
2442         }
2443
2444         set idx [find_file_from $flist $lno 1 $path $mmask]
2445         if {$idx eq {}} {
2446                 incr lno -1
2447                 set idx [find_file_from $flist $lno -1 $path $mmask]
2448         }
2449
2450         if {$idx ne {}} {
2451                 set next_diff_w $w
2452                 set next_diff_p [lindex $flist $idx]
2453                 set next_diff_i [expr {$idx+1}]
2454                 return 1
2455         } else {
2456                 return 0
2457         }
2458 }
2459
2460 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2461         global current_diff_path
2462
2463         if {$path ne $current_diff_path} {
2464                 return {}
2465         } elseif {[find_next_diff $w $path $lno $mmask]} {
2466                 return {next_diff;}
2467         } else {
2468                 return {reshow_diff;}
2469         }
2470 }
2471
2472 proc select_first_diff {after} {
2473         global ui_workdir
2474
2475         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2476             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2477                 next_diff $after
2478         } else {
2479                 uplevel #0 $after
2480         }
2481 }
2482
2483 proc force_first_diff {after} {
2484         global ui_workdir current_diff_path file_states
2485
2486         if {[info exists file_states($current_diff_path)]} {
2487                 set state [lindex $file_states($current_diff_path) 0]
2488         } else {
2489                 set state {OO}
2490         }
2491
2492         set reselect 0
2493         if {[string first {U} $state] >= 0} {
2494                 # Already a conflict, do nothing
2495         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2496                 set reselect 1
2497         } elseif {[string index $state 1] ne {O}} {
2498                 # Already a diff & no conflicts, do nothing
2499         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2500                 set reselect 1
2501         }
2502
2503         if {$reselect} {
2504                 next_diff $after
2505         } else {
2506                 uplevel #0 $after
2507         }
2508 }
2509
2510 proc toggle_or_diff {w x y} {
2511         global file_states file_lists current_diff_path ui_index ui_workdir
2512         global last_clicked selected_paths
2513
2514         set pos [split [$w index @$x,$y] .]
2515         set lno [lindex $pos 0]
2516         set col [lindex $pos 1]
2517         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2518         if {$path eq {}} {
2519                 set last_clicked {}
2520                 return
2521         }
2522
2523         set last_clicked [list $w $lno]
2524         array unset selected_paths
2525         $ui_index tag remove in_sel 0.0 end
2526         $ui_workdir tag remove in_sel 0.0 end
2527
2528         # Determine the state of the file
2529         if {[info exists file_states($path)]} {
2530                 set state [lindex $file_states($path) 0]
2531         } else {
2532                 set state {__}
2533         }
2534
2535         # Restage the file, or simply show the diff
2536         if {$col == 0 && $y > 1} {
2537                 # Conflicts need special handling
2538                 if {[string first {U} $state] >= 0} {
2539                         # $w must always be $ui_workdir, but...
2540                         if {$w ne $ui_workdir} { set lno {} }
2541                         merge_stage_workdir $path $lno
2542                         return
2543                 }
2544
2545                 if {[string index $state 1] eq {O}} {
2546                         set mmask {}
2547                 } else {
2548                         set mmask {[^O]}
2549                 }
2550
2551                 set after [next_diff_after_action $w $path $lno $mmask]
2552
2553                 if {$w eq $ui_index} {
2554                         update_indexinfo \
2555                                 "Unstaging [short_path $path] from commit" \
2556                                 [list $path] \
2557                                 [concat $after [list ui_ready]]
2558                 } elseif {$w eq $ui_workdir} {
2559                         update_index \
2560                                 "Adding [short_path $path]" \
2561                                 [list $path] \
2562                                 [concat $after [list ui_ready]]
2563                 }
2564         } else {
2565                 set selected_paths($path) 1
2566                 show_diff $path $w $lno
2567         }
2568 }
2569
2570 proc add_one_to_selection {w x y} {
2571         global file_lists last_clicked selected_paths
2572
2573         set lno [lindex [split [$w index @$x,$y] .] 0]
2574         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2575         if {$path eq {}} {
2576                 set last_clicked {}
2577                 return
2578         }
2579
2580         if {$last_clicked ne {}
2581                 && [lindex $last_clicked 0] ne $w} {
2582                 array unset selected_paths
2583                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2584         }
2585
2586         set last_clicked [list $w $lno]
2587         if {[catch {set in_sel $selected_paths($path)}]} {
2588                 set in_sel 0
2589         }
2590         if {$in_sel} {
2591                 unset selected_paths($path)
2592                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2593         } else {
2594                 set selected_paths($path) 1
2595                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2596         }
2597 }
2598
2599 proc add_range_to_selection {w x y} {
2600         global file_lists last_clicked selected_paths
2601
2602         if {[lindex $last_clicked 0] ne $w} {
2603                 toggle_or_diff $w $x $y
2604                 return
2605         }
2606
2607         set lno [lindex [split [$w index @$x,$y] .] 0]
2608         set lc [lindex $last_clicked 1]
2609         if {$lc < $lno} {
2610                 set begin $lc
2611                 set end $lno
2612         } else {
2613                 set begin $lno
2614                 set end $lc
2615         }
2616
2617         foreach path [lrange $file_lists($w) \
2618                 [expr {$begin - 1}] \
2619                 [expr {$end - 1}]] {
2620                 set selected_paths($path) 1
2621         }
2622         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2623 }
2624
2625 proc show_more_context {} {
2626         global repo_config
2627         if {$repo_config(gui.diffcontext) < 99} {
2628                 incr repo_config(gui.diffcontext)
2629                 reshow_diff
2630         }
2631 }
2632
2633 proc show_less_context {} {
2634         global repo_config
2635         if {$repo_config(gui.diffcontext) > 1} {
2636                 incr repo_config(gui.diffcontext) -1
2637                 reshow_diff
2638         }
2639 }
2640
2641 ######################################################################
2642 ##
2643 ## ui construction
2644
2645 set ui_comm {}
2646
2647 # -- Menu Bar
2648 #
2649 menu .mbar -tearoff 0
2650 if {[is_MacOSX]} {
2651         # -- Apple Menu (Mac OS X only)
2652         #
2653         .mbar add cascade -label Apple -menu .mbar.apple
2654         menu .mbar.apple
2655 }
2656 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2657 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2658 if {[is_enabled branch]} {
2659         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2660 }
2661 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2662         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2663 }
2664 if {[is_enabled transport]} {
2665         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2666         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2667 }
2668 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2669         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2670 }
2671
2672 # -- Repository Menu
2673 #
2674 menu .mbar.repository
2675
2676 if {![is_bare]} {
2677         .mbar.repository add command \
2678                 -label [mc "Explore Working Copy"] \
2679                 -command {do_explore}
2680 }
2681
2682 if {[is_Windows]} {
2683         .mbar.repository add command \
2684                 -label [mc "Git Bash"] \
2685                 -command {eval exec [auto_execok start] \
2686                                           [list "Git Bash" bash --login -l &]}
2687 }
2688
2689 if {[is_Windows] || ![is_bare]} {
2690         .mbar.repository add separator
2691 }
2692
2693 .mbar.repository add command \
2694         -label [mc "Browse Current Branch's Files"] \
2695         -command {browser::new $current_branch}
2696 set ui_browse_current [.mbar.repository index last]
2697 .mbar.repository add command \
2698         -label [mc "Browse Branch Files..."] \
2699         -command browser_open::dialog
2700 .mbar.repository add separator
2701
2702 .mbar.repository add command \
2703         -label [mc "Visualize Current Branch's History"] \
2704         -command {do_gitk $current_branch}
2705 set ui_visualize_current [.mbar.repository index last]
2706 .mbar.repository add command \
2707         -label [mc "Visualize All Branch History"] \
2708         -command {do_gitk --all}
2709 .mbar.repository add separator
2710
2711 proc current_branch_write {args} {
2712         global current_branch
2713         .mbar.repository entryconf $::ui_browse_current \
2714                 -label [mc "Browse %s's Files" $current_branch]
2715         .mbar.repository entryconf $::ui_visualize_current \
2716                 -label [mc "Visualize %s's History" $current_branch]
2717 }
2718 trace add variable current_branch write current_branch_write
2719
2720 if {[is_enabled multicommit]} {
2721         .mbar.repository add command -label [mc "Database Statistics"] \
2722                 -command do_stats
2723
2724         .mbar.repository add command -label [mc "Compress Database"] \
2725                 -command do_gc
2726
2727         .mbar.repository add command -label [mc "Verify Database"] \
2728                 -command do_fsck_objects
2729
2730         .mbar.repository add separator
2731
2732         if {[is_Cygwin]} {
2733                 .mbar.repository add command \
2734                         -label [mc "Create Desktop Icon"] \
2735                         -command do_cygwin_shortcut
2736         } elseif {[is_Windows]} {
2737                 .mbar.repository add command \
2738                         -label [mc "Create Desktop Icon"] \
2739                         -command do_windows_shortcut
2740         } elseif {[is_MacOSX]} {
2741                 .mbar.repository add command \
2742                         -label [mc "Create Desktop Icon"] \
2743                         -command do_macosx_app
2744         }
2745 }
2746
2747 if {[is_MacOSX]} {
2748         proc ::tk::mac::Quit {args} { do_quit }
2749 } else {
2750         .mbar.repository add command -label [mc Quit] \
2751                 -command do_quit \
2752                 -accelerator $M1T-Q
2753 }
2754
2755 # -- Edit Menu
2756 #
2757 menu .mbar.edit
2758 .mbar.edit add command -label [mc Undo] \
2759         -command {catch {[focus] edit undo}} \
2760         -accelerator $M1T-Z
2761 .mbar.edit add command -label [mc Redo] \
2762         -command {catch {[focus] edit redo}} \
2763         -accelerator $M1T-Y
2764 .mbar.edit add separator
2765 .mbar.edit add command -label [mc Cut] \
2766         -command {catch {tk_textCut [focus]}} \
2767         -accelerator $M1T-X
2768 .mbar.edit add command -label [mc Copy] \
2769         -command {catch {tk_textCopy [focus]}} \
2770         -accelerator $M1T-C
2771 .mbar.edit add command -label [mc Paste] \
2772         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2773         -accelerator $M1T-V
2774 .mbar.edit add command -label [mc Delete] \
2775         -command {catch {[focus] delete sel.first sel.last}} \
2776         -accelerator Del
2777 .mbar.edit add separator
2778 .mbar.edit add command -label [mc "Select All"] \
2779         -command {catch {[focus] tag add sel 0.0 end}} \
2780         -accelerator $M1T-A
2781
2782 # -- Branch Menu
2783 #
2784 if {[is_enabled branch]} {
2785         menu .mbar.branch
2786
2787         .mbar.branch add command -label [mc "Create..."] \
2788                 -command branch_create::dialog \
2789                 -accelerator $M1T-N
2790         lappend disable_on_lock [list .mbar.branch entryconf \
2791                 [.mbar.branch index last] -state]
2792
2793         .mbar.branch add command -label [mc "Checkout..."] \
2794                 -command branch_checkout::dialog \
2795                 -accelerator $M1T-O
2796         lappend disable_on_lock [list .mbar.branch entryconf \
2797                 [.mbar.branch index last] -state]
2798
2799         .mbar.branch add command -label [mc "Rename..."] \
2800                 -command branch_rename::dialog
2801         lappend disable_on_lock [list .mbar.branch entryconf \
2802                 [.mbar.branch index last] -state]
2803
2804         .mbar.branch add command -label [mc "Delete..."] \
2805                 -command branch_delete::dialog
2806         lappend disable_on_lock [list .mbar.branch entryconf \
2807                 [.mbar.branch index last] -state]
2808
2809         .mbar.branch add command -label [mc "Reset..."] \
2810                 -command merge::reset_hard
2811         lappend disable_on_lock [list .mbar.branch entryconf \
2812                 [.mbar.branch index last] -state]
2813 }
2814
2815 # -- Commit Menu
2816 #
2817 proc commit_btn_caption {} {
2818         if {[is_enabled nocommit]} {
2819                 return [mc "Done"]
2820         } else {
2821                 return [mc Commit@@verb]
2822         }
2823 }
2824
2825 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2826         menu .mbar.commit
2827
2828         if {![is_enabled nocommit]} {
2829                 .mbar.commit add radiobutton \
2830                         -label [mc "New Commit"] \
2831                         -command do_select_commit_type \
2832                         -variable selected_commit_type \
2833                         -value new
2834                 lappend disable_on_lock \
2835                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2836
2837                 .mbar.commit add radiobutton \
2838                         -label [mc "Amend Last Commit"] \
2839                         -command do_select_commit_type \
2840                         -variable selected_commit_type \
2841                         -value amend
2842                 lappend disable_on_lock \
2843                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2844
2845                 .mbar.commit add separator
2846         }
2847
2848         .mbar.commit add command -label [mc Rescan] \
2849                 -command ui_do_rescan \
2850                 -accelerator F5
2851         lappend disable_on_lock \
2852                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2853
2854         .mbar.commit add command -label [mc "Stage To Commit"] \
2855                 -command do_add_selection \
2856                 -accelerator $M1T-T
2857         lappend disable_on_lock \
2858                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2859
2860         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2861                 -command do_add_all \
2862                 -accelerator $M1T-I
2863         lappend disable_on_lock \
2864                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2865
2866         .mbar.commit add command -label [mc "Unstage From Commit"] \
2867                 -command do_unstage_selection \
2868                 -accelerator $M1T-U
2869         lappend disable_on_lock \
2870                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2871
2872         .mbar.commit add command -label [mc "Revert Changes"] \
2873                 -command do_revert_selection \
2874                 -accelerator $M1T-J
2875         lappend disable_on_lock \
2876                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2877
2878         .mbar.commit add separator
2879
2880         .mbar.commit add command -label [mc "Show Less Context"] \
2881                 -command show_less_context \
2882                 -accelerator $M1T-\-
2883
2884         .mbar.commit add command -label [mc "Show More Context"] \
2885                 -command show_more_context \
2886                 -accelerator $M1T-=
2887
2888         .mbar.commit add separator
2889
2890         if {![is_enabled nocommitmsg]} {
2891                 .mbar.commit add command -label [mc "Sign Off"] \
2892                         -command do_signoff \
2893                         -accelerator $M1T-S
2894         }
2895
2896         .mbar.commit add command -label [commit_btn_caption] \
2897                 -command do_commit \
2898                 -accelerator $M1T-Return
2899         lappend disable_on_lock \
2900                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2901 }
2902
2903 # -- Merge Menu
2904 #
2905 if {[is_enabled branch]} {
2906         menu .mbar.merge
2907         .mbar.merge add command -label [mc "Local Merge..."] \
2908                 -command merge::dialog \
2909                 -accelerator $M1T-M
2910         lappend disable_on_lock \
2911                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2912         .mbar.merge add command -label [mc "Abort Merge..."] \
2913                 -command merge::reset_hard
2914         lappend disable_on_lock \
2915                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2916 }
2917
2918 # -- Transport Menu
2919 #
2920 if {[is_enabled transport]} {
2921         menu .mbar.remote
2922
2923         .mbar.remote add command \
2924                 -label [mc "Add..."] \
2925                 -command remote_add::dialog \
2926                 -accelerator $M1T-A
2927         .mbar.remote add command \
2928                 -label [mc "Push..."] \
2929                 -command do_push_anywhere \
2930                 -accelerator $M1T-P
2931         .mbar.remote add command \
2932                 -label [mc "Delete Branch..."] \
2933                 -command remote_branch_delete::dialog
2934 }
2935
2936 if {[is_MacOSX]} {
2937         proc ::tk::mac::ShowPreferences {} {do_options}
2938 } else {
2939         # -- Edit Menu
2940         #
2941         .mbar.edit add separator
2942         .mbar.edit add command -label [mc "Options..."] \
2943                 -command do_options
2944 }
2945
2946 # -- Tools Menu
2947 #
2948 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2949         set tools_menubar .mbar.tools
2950         menu $tools_menubar
2951         $tools_menubar add separator
2952         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2953         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2954         set tools_tailcnt 3
2955         if {[array names repo_config guitool.*.cmd] ne {}} {
2956                 tools_populate_all
2957         }
2958 }
2959
2960 # -- Help Menu
2961 #
2962 .mbar add cascade -label [mc Help] -menu .mbar.help
2963 menu .mbar.help
2964
2965 if {[is_MacOSX]} {
2966         .mbar.apple add command -label [mc "About %s" [appname]] \
2967                 -command do_about
2968         .mbar.apple add separator
2969 } else {
2970         .mbar.help add command -label [mc "About %s" [appname]] \
2971                 -command do_about
2972 }
2973 . configure -menu .mbar
2974
2975 set doc_path [githtmldir]
2976 if {$doc_path ne {}} {
2977         set doc_path [file join $doc_path index.html]
2978
2979         if {[is_Cygwin]} {
2980                 set doc_path [exec cygpath --mixed $doc_path]
2981         }
2982 }
2983
2984 if {[file isfile $doc_path]} {
2985         set doc_url "file:$doc_path"
2986 } else {
2987         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2988 }
2989
2990 proc start_browser {url} {
2991         git "web--browse" $url
2992 }
2993
2994 .mbar.help add command -label [mc "Online Documentation"] \
2995         -command [list start_browser $doc_url]
2996
2997 .mbar.help add command -label [mc "Show SSH Key"] \
2998         -command do_ssh_key
2999
3000 unset doc_path doc_url
3001
3002 # -- Standard bindings
3003 #
3004 wm protocol . WM_DELETE_WINDOW do_quit
3005 bind all <$M1B-Key-q> do_quit
3006 bind all <$M1B-Key-Q> do_quit
3007 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3008 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3009
3010 set subcommand_args {}
3011 proc usage {} {
3012         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3013         if {[tk windowingsystem] eq "win32"} {
3014                 wm withdraw .
3015                 tk_messageBox -icon info -message $s \
3016                         -title [mc "Usage"]
3017         } else {
3018                 puts stderr $s
3019         }
3020         exit 1
3021 }
3022
3023 proc normalize_relpath {path} {
3024         set elements {}
3025         foreach item [file split $path] {
3026                 if {$item eq {.}} continue
3027                 if {$item eq {..} && [llength $elements] > 0
3028                     && [lindex $elements end] ne {..}} {
3029                         set elements [lrange $elements 0 end-1]
3030                         continue
3031                 }
3032                 lappend elements $item
3033         }
3034         return [eval file join $elements]
3035 }
3036
3037 # -- Not a normal commit type invocation?  Do that instead!
3038 #
3039 switch -- $subcommand {
3040 browser -
3041 blame {
3042         if {$subcommand eq "blame"} {
3043                 set subcommand_args {[--line=<num>] rev? path}
3044         } else {
3045                 set subcommand_args {rev? path}
3046         }
3047         if {$argv eq {}} usage
3048         set head {}
3049         set path {}
3050         set jump_spec {}
3051         set is_path 0
3052         foreach a $argv {
3053                 set p [file join $_prefix $a]
3054
3055                 if {$is_path || [file exists $p]} {
3056                         if {$path ne {}} usage
3057                         set path [normalize_relpath $p]
3058                         break
3059                 } elseif {$a eq {--}} {
3060                         if {$path ne {}} {
3061                                 if {$head ne {}} usage
3062                                 set head $path
3063                                 set path {}
3064                         }
3065                         set is_path 1
3066                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3067                         if {$jump_spec ne {} || $head ne {}} usage
3068                         set jump_spec [list $lnum]
3069                 } elseif {$head eq {}} {
3070                         if {$head ne {}} usage
3071                         set head $a
3072                         set is_path 1
3073                 } else {
3074                         usage
3075                 }
3076         }
3077         unset is_path
3078
3079         if {$head ne {} && $path eq {}} {
3080                 if {[string index $head 0] eq {/}} {
3081                         set path [normalize_relpath $head]
3082                         set head {}
3083                 } else {
3084                         set path [normalize_relpath $_prefix$head]
3085                         set head {}
3086                 }
3087         }
3088
3089         if {$head eq {}} {
3090                 load_current_branch
3091         } else {
3092                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3093                         if {[catch {
3094                                         set head [git rev-parse --verify $head]
3095                                 } err]} {
3096                                 if {[tk windowingsystem] eq "win32"} {
3097                                         tk_messageBox -icon error -title [mc Error] -message $err
3098                                 } else {
3099                                         puts stderr $err
3100                                 }
3101                                 exit 1
3102                         }
3103                 }
3104                 set current_branch $head
3105         }
3106
3107         wm deiconify .
3108         switch -- $subcommand {
3109         browser {
3110                 if {$jump_spec ne {}} usage
3111                 if {$head eq {}} {
3112                         if {$path ne {} && [file isdirectory $path]} {
3113                                 set head $current_branch
3114                         } else {
3115                                 set head $path
3116                                 set path {}
3117                         }
3118                 }
3119                 browser::new $head $path
3120         }
3121         blame   {
3122                 if {$head eq {} && ![file exists $path]} {
3123                         catch {wm withdraw .}
3124                         tk_messageBox \
3125                                 -icon error \
3126                                 -type ok \
3127                                 -title [mc "git-gui: fatal error"] \
3128                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3129                         exit 1
3130                 }
3131                 blame::new $head $path $jump_spec
3132         }
3133         }
3134         return
3135 }
3136 citool -
3137 gui {
3138         if {[llength $argv] != 0} {
3139                 usage
3140         }
3141         # fall through to setup UI for commits
3142 }
3143 default {
3144         set err "usage: $argv0 \[{blame|browser|citool}\]"
3145         if {[tk windowingsystem] eq "win32"} {
3146                 wm withdraw .
3147                 tk_messageBox -icon error -message $err \
3148                         -title [mc "Usage"]
3149         } else {
3150                 puts stderr $err
3151         }
3152         exit 1
3153 }
3154 }
3155
3156 # -- Branch Control
3157 #
3158 ${NS}::frame .branch
3159 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3160 ${NS}::label .branch.l1 \
3161         -text [mc "Current Branch:"] \
3162         -anchor w \
3163         -justify left
3164 ${NS}::label .branch.cb \
3165         -textvariable current_branch \
3166         -anchor w \
3167         -justify left
3168 pack .branch.l1 -side left
3169 pack .branch.cb -side left -fill x
3170 pack .branch -side top -fill x
3171
3172 # -- Main Window Layout
3173 #
3174 ${NS}::panedwindow .vpane -orient horizontal
3175 ${NS}::panedwindow .vpane.files -orient vertical
3176 if {$use_ttk} {
3177         .vpane add .vpane.files
3178 } else {
3179         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3180 }
3181 pack .vpane -anchor n -side top -fill both -expand 1
3182
3183 # -- Index File List
3184 #
3185 ${NS}::frame .vpane.files.index -height 100 -width 200
3186 tlabel .vpane.files.index.title \
3187         -text [mc "Staged Changes (Will Commit)"] \
3188         -background lightgreen -foreground black
3189 text $ui_index -background white -foreground black \
3190         -borderwidth 0 \
3191         -width 20 -height 10 \
3192         -wrap none \
3193         -cursor $cursor_ptr \
3194         -xscrollcommand {.vpane.files.index.sx set} \
3195         -yscrollcommand {.vpane.files.index.sy set} \
3196         -state disabled
3197 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3198 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3199 pack .vpane.files.index.title -side top -fill x
3200 pack .vpane.files.index.sx -side bottom -fill x
3201 pack .vpane.files.index.sy -side right -fill y
3202 pack $ui_index -side left -fill both -expand 1
3203
3204 # -- Working Directory File List
3205 #
3206 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3207 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3208         -background lightsalmon -foreground black
3209 text $ui_workdir -background white -foreground black \
3210         -borderwidth 0 \
3211         -width 20 -height 10 \
3212         -wrap none \
3213         -cursor $cursor_ptr \
3214         -xscrollcommand {.vpane.files.workdir.sx set} \
3215         -yscrollcommand {.vpane.files.workdir.sy set} \
3216         -state disabled
3217 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3218 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3219 pack .vpane.files.workdir.title -side top -fill x
3220 pack .vpane.files.workdir.sx -side bottom -fill x
3221 pack .vpane.files.workdir.sy -side right -fill y
3222 pack $ui_workdir -side left -fill both -expand 1
3223
3224 .vpane.files add .vpane.files.workdir
3225 .vpane.files add .vpane.files.index
3226 if {!$use_ttk} {
3227         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3228         .vpane.files paneconfigure .vpane.files.index -sticky news
3229 }
3230
3231 foreach i [list $ui_index $ui_workdir] {
3232         rmsel_tag $i
3233         $i tag conf in_diff -background [$i tag cget in_sel -background]
3234 }
3235 unset i
3236
3237 # -- Diff and Commit Area
3238 #
3239 if {$have_tk85} {
3240         ${NS}::panedwindow .vpane.lower -orient vertical
3241         ${NS}::frame .vpane.lower.commarea
3242         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3243         .vpane.lower add .vpane.lower.diff
3244         .vpane.lower add .vpane.lower.commarea
3245         .vpane add .vpane.lower
3246         if {$use_ttk} {
3247                 .vpane.lower pane .vpane.lower.diff -weight 1
3248                 .vpane.lower pane .vpane.lower.commarea -weight 0
3249         } else {
3250                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3251                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3252         }
3253 } else {
3254         frame .vpane.lower -height 300 -width 400
3255         frame .vpane.lower.commarea
3256         frame .vpane.lower.diff -relief sunken -borderwidth 1
3257         pack .vpane.lower.diff -fill both -expand 1
3258         pack .vpane.lower.commarea -side bottom -fill x
3259         .vpane add .vpane.lower
3260         .vpane paneconfigure .vpane.lower -sticky nsew
3261 }
3262
3263 # -- Commit Area Buttons
3264 #
3265 ${NS}::frame .vpane.lower.commarea.buttons
3266 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3267         -anchor w \
3268         -justify left
3269 pack .vpane.lower.commarea.buttons.l -side top -fill x
3270 pack .vpane.lower.commarea.buttons -side left -fill y
3271
3272 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3273         -command ui_do_rescan
3274 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3275 lappend disable_on_lock \
3276         {.vpane.lower.commarea.buttons.rescan conf -state}
3277
3278 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3279         -command do_add_all
3280 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3281 lappend disable_on_lock \
3282         {.vpane.lower.commarea.buttons.incall conf -state}
3283
3284 if {![is_enabled nocommitmsg]} {
3285         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3286                 -command do_signoff
3287         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3288 }
3289
3290 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3291         -command do_commit
3292 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3293 lappend disable_on_lock \
3294         {.vpane.lower.commarea.buttons.commit conf -state}
3295
3296 if {![is_enabled nocommit]} {
3297         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3298                 -command do_push_anywhere
3299         pack .vpane.lower.commarea.buttons.push -side top -fill x
3300 }
3301
3302 # -- Commit Message Buffer
3303 #
3304 ${NS}::frame .vpane.lower.commarea.buffer
3305 ${NS}::frame .vpane.lower.commarea.buffer.header
3306 set ui_comm .vpane.lower.commarea.buffer.t
3307 set ui_coml .vpane.lower.commarea.buffer.header.l
3308
3309 if {![is_enabled nocommit]} {
3310         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3311                 -text [mc "New Commit"] \
3312                 -command do_select_commit_type \
3313                 -variable selected_commit_type \
3314                 -value new
3315         lappend disable_on_lock \
3316                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3317         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3318                 -text [mc "Amend Last Commit"] \
3319                 -command do_select_commit_type \
3320                 -variable selected_commit_type \
3321                 -value amend
3322         lappend disable_on_lock \
3323                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3324 }
3325
3326 ${NS}::label $ui_coml \
3327         -anchor w \
3328         -justify left
3329 proc trace_commit_type {varname args} {
3330         global ui_coml commit_type
3331         switch -glob -- $commit_type {
3332         initial       {set txt [mc "Initial Commit Message:"]}
3333         amend         {set txt [mc "Amended Commit Message:"]}
3334         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3335         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3336         merge         {set txt [mc "Merge Commit Message:"]}
3337         *             {set txt [mc "Commit Message:"]}
3338         }
3339         $ui_coml conf -text $txt
3340 }
3341 trace add variable commit_type write trace_commit_type
3342 pack $ui_coml -side left -fill x
3343
3344 if {![is_enabled nocommit]} {
3345         pack .vpane.lower.commarea.buffer.header.amend -side right
3346         pack .vpane.lower.commarea.buffer.header.new -side right
3347 }
3348
3349 text $ui_comm -background white -foreground black \
3350         -borderwidth 1 \
3351         -undo true \
3352         -maxundo 20 \
3353         -autoseparators true \
3354         -relief sunken \
3355         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3356         -font font_diff \
3357         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3358 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3359         -command [list $ui_comm yview]
3360 pack .vpane.lower.commarea.buffer.header -side top -fill x
3361 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3362 pack $ui_comm -side left -fill y
3363 pack .vpane.lower.commarea.buffer -side left -fill y
3364
3365 # -- Commit Message Buffer Context Menu
3366 #
3367 set ctxm .vpane.lower.commarea.buffer.ctxm
3368 menu $ctxm -tearoff 0
3369 $ctxm add command \
3370         -label [mc Cut] \
3371         -command {tk_textCut $ui_comm}
3372 $ctxm add command \
3373         -label [mc Copy] \
3374         -command {tk_textCopy $ui_comm}
3375 $ctxm add command \
3376         -label [mc Paste] \
3377         -command {tk_textPaste $ui_comm}
3378 $ctxm add command \
3379         -label [mc Delete] \
3380         -command {catch {$ui_comm delete sel.first sel.last}}
3381 $ctxm add separator
3382 $ctxm add command \
3383         -label [mc "Select All"] \
3384         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3385 $ctxm add command \
3386         -label [mc "Copy All"] \
3387         -command {
3388                 $ui_comm tag add sel 0.0 end
3389                 tk_textCopy $ui_comm
3390                 $ui_comm tag remove sel 0.0 end
3391         }
3392 $ctxm add separator
3393 $ctxm add command \
3394         -label [mc "Sign Off"] \
3395         -command do_signoff
3396 set ui_comm_ctxm $ctxm
3397
3398 # -- Diff Header
3399 #
3400 proc trace_current_diff_path {varname args} {
3401         global current_diff_path diff_actions file_states
3402         if {$current_diff_path eq {}} {
3403                 set s {}
3404                 set f {}
3405                 set p {}
3406                 set o disabled
3407         } else {
3408                 set p $current_diff_path
3409                 set s [mapdesc [lindex $file_states($p) 0] $p]
3410                 set f [mc "File:"]
3411                 set p [escape_path $p]
3412                 set o normal
3413         }
3414
3415         .vpane.lower.diff.header.status configure -text $s
3416         .vpane.lower.diff.header.file configure -text $f
3417         .vpane.lower.diff.header.path configure -text $p
3418         foreach w $diff_actions {
3419                 uplevel #0 $w $o
3420         }
3421 }
3422 trace add variable current_diff_path write trace_current_diff_path
3423
3424 gold_frame .vpane.lower.diff.header
3425 tlabel .vpane.lower.diff.header.status \
3426         -background gold \
3427         -foreground black \
3428         -width $max_status_desc \
3429         -anchor w \
3430         -justify left
3431 tlabel .vpane.lower.diff.header.file \
3432         -background gold \
3433         -foreground black \
3434         -anchor w \
3435         -justify left
3436 tlabel .vpane.lower.diff.header.path \
3437         -background gold \
3438         -foreground black \
3439         -anchor w \
3440         -justify left
3441 pack .vpane.lower.diff.header.status -side left
3442 pack .vpane.lower.diff.header.file -side left
3443 pack .vpane.lower.diff.header.path -fill x
3444 set ctxm .vpane.lower.diff.header.ctxm
3445 menu $ctxm -tearoff 0
3446 $ctxm add command \
3447         -label [mc Copy] \
3448         -command {
3449                 clipboard clear
3450                 clipboard append \
3451                         -format STRING \
3452                         -type STRING \
3453                         -- $current_diff_path
3454         }
3455 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3456 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3457
3458 # -- Diff Body
3459 #
3460 ${NS}::frame .vpane.lower.diff.body
3461 set ui_diff .vpane.lower.diff.body.t
3462 text $ui_diff -background white -foreground black \
3463         -borderwidth 0 \
3464         -width 80 -height 5 -wrap none \
3465         -font font_diff \
3466         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3467         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3468         -state disabled
3469 catch {$ui_diff configure -tabstyle wordprocessor}
3470 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3471         -command [list $ui_diff xview]
3472 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3473         -command [list $ui_diff yview]
3474 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3475 pack .vpane.lower.diff.body.sby -side right -fill y
3476 pack $ui_diff -side left -fill both -expand 1
3477 pack .vpane.lower.diff.header -side top -fill x
3478 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3479
3480 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3481         $ui_diff tag configure clr4$n -background $c
3482         $ui_diff tag configure clri4$n -foreground $c
3483         $ui_diff tag configure clr3$n -foreground $c
3484         $ui_diff tag configure clri3$n -background $c
3485 }
3486 $ui_diff tag configure clr1 -font font_diffbold
3487 $ui_diff tag configure clr4 -underline 1
3488
3489 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3490
3491 $ui_diff tag conf d_cr -elide true
3492 $ui_diff tag conf d_@ -font font_diffbold
3493 $ui_diff tag conf d_+ -foreground {#00a000}
3494 $ui_diff tag conf d_- -foreground red
3495
3496 $ui_diff tag conf d_++ -foreground {#00a000}
3497 $ui_diff tag conf d_-- -foreground red
3498 $ui_diff tag conf d_+s \
3499         -foreground {#00a000} \
3500         -background {#e2effa}
3501 $ui_diff tag conf d_-s \
3502         -foreground red \
3503         -background {#e2effa}
3504 $ui_diff tag conf d_s+ \
3505         -foreground {#00a000} \
3506         -background ivory1
3507 $ui_diff tag conf d_s- \
3508         -foreground red \
3509         -background ivory1
3510
3511 $ui_diff tag conf d< \
3512         -foreground orange \
3513         -font font_diffbold
3514 $ui_diff tag conf d= \
3515         -foreground orange \
3516         -font font_diffbold
3517 $ui_diff tag conf d> \
3518         -foreground orange \
3519         -font font_diffbold
3520
3521 $ui_diff tag raise sel
3522
3523 # -- Diff Body Context Menu
3524 #
3525
3526 proc create_common_diff_popup {ctxm} {
3527         $ctxm add command \
3528                 -label [mc Refresh] \
3529                 -command reshow_diff
3530         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3531         $ctxm add command \
3532                 -label [mc Copy] \
3533                 -command {tk_textCopy $ui_diff}
3534         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3535         $ctxm add command \
3536                 -label [mc "Select All"] \
3537                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3538         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3539         $ctxm add command \
3540                 -label [mc "Copy All"] \
3541                 -command {
3542                         $ui_diff tag add sel 0.0 end
3543                         tk_textCopy $ui_diff
3544                         $ui_diff tag remove sel 0.0 end
3545                 }
3546         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3547         $ctxm add separator
3548         $ctxm add command \
3549                 -label [mc "Decrease Font Size"] \
3550                 -command {incr_font_size font_diff -1}
3551         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3552         $ctxm add command \
3553                 -label [mc "Increase Font Size"] \
3554                 -command {incr_font_size font_diff 1}
3555         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3556         $ctxm add separator
3557         set emenu $ctxm.enc
3558         menu $emenu
3559         build_encoding_menu $emenu [list force_diff_encoding]
3560         $ctxm add cascade \
3561                 -label [mc "Encoding"] \
3562                 -menu $emenu
3563         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3564         $ctxm add separator
3565         $ctxm add command -label [mc "Options..."] \
3566                 -command do_options
3567 }
3568
3569 set ctxm .vpane.lower.diff.body.ctxm
3570 menu $ctxm -tearoff 0
3571 $ctxm add command \
3572         -label [mc "Apply/Reverse Hunk"] \
3573         -command {apply_hunk $cursorX $cursorY}
3574 set ui_diff_applyhunk [$ctxm index last]
3575 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3576 $ctxm add command \
3577         -label [mc "Apply/Reverse Line"] \
3578         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3579 set ui_diff_applyline [$ctxm index last]
3580 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3581 $ctxm add separator
3582 $ctxm add command \
3583         -label [mc "Show Less Context"] \
3584         -command show_less_context
3585 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3586 $ctxm add command \
3587         -label [mc "Show More Context"] \
3588         -command show_more_context
3589 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3590 $ctxm add separator
3591 create_common_diff_popup $ctxm
3592
3593 set ctxmmg .vpane.lower.diff.body.ctxmmg
3594 menu $ctxmmg -tearoff 0
3595 $ctxmmg add command \
3596         -label [mc "Run Merge Tool"] \
3597         -command {merge_resolve_tool}
3598 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3599 $ctxmmg add separator
3600 $ctxmmg add command \
3601         -label [mc "Use Remote Version"] \
3602         -command {merge_resolve_one 3}
3603 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3604 $ctxmmg add command \
3605         -label [mc "Use Local Version"] \
3606         -command {merge_resolve_one 2}
3607 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3608 $ctxmmg add command \
3609         -label [mc "Revert To Base"] \
3610         -command {merge_resolve_one 1}
3611 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3612 $ctxmmg add separator
3613 $ctxmmg add command \
3614         -label [mc "Show Less Context"] \
3615         -command show_less_context
3616 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3617 $ctxmmg add command \
3618         -label [mc "Show More Context"] \
3619         -command show_more_context
3620 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3621 $ctxmmg add separator
3622 create_common_diff_popup $ctxmmg
3623
3624 set ctxmsm .vpane.lower.diff.body.ctxmsm
3625 menu $ctxmsm -tearoff 0
3626 $ctxmsm add command \
3627         -label [mc "Visualize These Changes In The Submodule"] \
3628         -command {do_gitk -- true}
3629 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3630 $ctxmsm add command \
3631         -label [mc "Visualize Current Branch History In The Submodule"] \
3632         -command {do_gitk {} true}
3633 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3634 $ctxmsm add command \
3635         -label [mc "Visualize All Branch History In The Submodule"] \
3636         -command {do_gitk --all true}
3637 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3638 $ctxmsm add separator
3639 $ctxmsm add command \
3640         -label [mc "Start git gui In The Submodule"] \
3641         -command {do_git_gui}
3642 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3643 $ctxmsm add separator
3644 create_common_diff_popup $ctxmsm
3645
3646 proc has_textconv {path} {
3647         if {[is_config_false gui.textconv]} {
3648                 return 0
3649         }
3650         set filter [gitattr $path diff set]
3651         set textconv [get_config [join [list diff $filter textconv] .]]
3652         if {$filter ne {set} && $textconv ne {}} {
3653                 return 1
3654         } else {
3655                 return 0
3656         }
3657 }
3658
3659 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3660         global current_diff_path file_states
3661         set ::cursorX $x
3662         set ::cursorY $y
3663         if {[info exists file_states($current_diff_path)]} {
3664                 set state [lindex $file_states($current_diff_path) 0]
3665         } else {
3666                 set state {__}
3667         }
3668         if {[string first {U} $state] >= 0} {
3669                 tk_popup $ctxmmg $X $Y
3670         } elseif {$::is_submodule_diff} {
3671                 tk_popup $ctxmsm $X $Y
3672         } else {
3673                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3674                 if {$::ui_index eq $::current_diff_side} {
3675                         set l [mc "Unstage Hunk From Commit"]
3676                         if {$has_range} {
3677                                 set t [mc "Unstage Lines From Commit"]
3678                         } else {
3679                                 set t [mc "Unstage Line From Commit"]
3680                         }
3681                 } else {
3682                         set l [mc "Stage Hunk For Commit"]
3683                         if {$has_range} {
3684                                 set t [mc "Stage Lines For Commit"]
3685                         } else {
3686                                 set t [mc "Stage Line For Commit"]
3687                         }
3688                 }
3689                 if {$::is_3way_diff
3690                         || $current_diff_path eq {}
3691                         || {__} eq $state
3692                         || {_O} eq $state
3693                         || [string match {?T} $state]
3694                         || [string match {T?} $state]
3695                         || [has_textconv $current_diff_path]} {
3696                         set s disabled
3697                 } else {
3698                         set s normal
3699                 }
3700                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3701                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3702                 tk_popup $ctxm $X $Y
3703         }
3704 }
3705 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3706
3707 # -- Status Bar
3708 #
3709 set main_status [::status_bar::new .status]
3710 pack .status -anchor w -side bottom -fill x
3711 $main_status show [mc "Initializing..."]
3712
3713 # -- Load geometry
3714 #
3715 proc on_ttk_pane_mapped {w pane pos} {
3716         bind $w <Map> {}
3717         after 0 [list after idle [list $w sashpos $pane $pos]]
3718 }
3719 proc on_tk_pane_mapped {w pane x y} {
3720         bind $w <Map> {}
3721         after 0 [list after idle [list $w sash place $pane $x $y]]
3722 }
3723 proc on_application_mapped {} {
3724         global repo_config use_ttk
3725         bind . <Map> {}
3726         set gm $repo_config(gui.geometry)
3727         if {$use_ttk} {
3728                 bind .vpane <Map> \
3729                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3730                 bind .vpane.files <Map> \
3731                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3732         } else {
3733                 bind .vpane <Map> \
3734                     [list on_tk_pane_mapped %W 0 \
3735                          [lindex $gm 1] \
3736                          [lindex [.vpane sash coord 0] 1]]
3737                 bind .vpane.files <Map> \
3738                     [list on_tk_pane_mapped %W 0 \
3739                          [lindex [.vpane.files sash coord 0] 0] \
3740                          [lindex $gm 2]]
3741         }
3742         wm geometry . [lindex $gm 0]
3743 }
3744 if {[info exists repo_config(gui.geometry)]} {
3745         bind . <Map> [list on_application_mapped]
3746         wm geometry . [lindex $repo_config(gui.geometry) 0]
3747 }
3748
3749 # -- Load window state
3750 #
3751 if {[info exists repo_config(gui.wmstate)]} {
3752         catch {wm state . $repo_config(gui.wmstate)}
3753 }
3754
3755 # -- Key Bindings
3756 #
3757 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3758 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3759 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3760 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3761 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3762 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3763 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3764 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3765 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3766 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3767 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3768 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3769 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3770 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3771 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3772 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3773 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3774 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3775 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3776 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3777 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3778 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3779
3780 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3781 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3782 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3783 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3784 bind $ui_diff <$M1B-Key-v> {break}
3785 bind $ui_diff <$M1B-Key-V> {break}
3786 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3787 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3788 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3789 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3790 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3791 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3792 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3793 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3794 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3795 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3796 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3797 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3798 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3799 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3800 bind $ui_diff <Button-1>   {focus %W}
3801
3802 if {[is_enabled branch]} {
3803         bind . <$M1B-Key-n> branch_create::dialog
3804         bind . <$M1B-Key-N> branch_create::dialog
3805         bind . <$M1B-Key-o> branch_checkout::dialog
3806         bind . <$M1B-Key-O> branch_checkout::dialog
3807         bind . <$M1B-Key-m> merge::dialog
3808         bind . <$M1B-Key-M> merge::dialog
3809 }
3810 if {[is_enabled transport]} {
3811         bind . <$M1B-Key-p> do_push_anywhere
3812         bind . <$M1B-Key-P> do_push_anywhere
3813 }
3814
3815 bind .   <Key-F5>     ui_do_rescan
3816 bind .   <$M1B-Key-r> ui_do_rescan
3817 bind .   <$M1B-Key-R> ui_do_rescan
3818 bind .   <$M1B-Key-s> do_signoff
3819 bind .   <$M1B-Key-S> do_signoff
3820 bind .   <$M1B-Key-t> do_add_selection
3821 bind .   <$M1B-Key-T> do_add_selection
3822 bind .   <$M1B-Key-u> do_unstage_selection
3823 bind .   <$M1B-Key-U> do_unstage_selection
3824 bind .   <$M1B-Key-j> do_revert_selection
3825 bind .   <$M1B-Key-J> do_revert_selection
3826 bind .   <$M1B-Key-i> do_add_all
3827 bind .   <$M1B-Key-I> do_add_all
3828 bind .   <$M1B-Key-minus> {show_less_context;break}
3829 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3830 bind .   <$M1B-Key-equal> {show_more_context;break}
3831 bind .   <$M1B-Key-plus> {show_more_context;break}
3832 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3833 bind .   <$M1B-Key-Return> do_commit
3834 foreach i [list $ui_index $ui_workdir] {
3835         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3836         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3837         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3838 }
3839 unset i
3840
3841 set file_lists($ui_index) [list]
3842 set file_lists($ui_workdir) [list]
3843
3844 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3845 focus -force $ui_comm
3846
3847 # -- Warn the user about environmental problems.  Cygwin's Tcl
3848 #    does *not* pass its env array onto any processes it spawns.
3849 #    This means that git processes get none of our environment.
3850 #
3851 if {[is_Cygwin]} {
3852         set ignored_env 0
3853         set suggest_user {}
3854         set msg [mc "Possible environment issues exist.
3855
3856 The following environment variables are probably
3857 going to be ignored by any Git subprocess run
3858 by %s:
3859
3860 " [appname]]
3861         foreach name [array names env] {
3862                 switch -regexp -- $name {
3863                 {^GIT_INDEX_FILE$} -
3864                 {^GIT_OBJECT_DIRECTORY$} -
3865                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3866                 {^GIT_DIFF_OPTS$} -
3867                 {^GIT_EXTERNAL_DIFF$} -
3868                 {^GIT_PAGER$} -
3869                 {^GIT_TRACE$} -
3870                 {^GIT_CONFIG$} -
3871                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3872                         append msg " - $name\n"
3873                         incr ignored_env
3874                 }
3875                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3876                         append msg " - $name\n"
3877                         incr ignored_env
3878                         set suggest_user $name
3879                 }
3880                 }
3881         }
3882         if {$ignored_env > 0} {
3883                 append msg [mc "
3884 This is due to a known issue with the
3885 Tcl binary distributed by Cygwin."]
3886
3887                 if {$suggest_user ne {}} {
3888                         append msg [mc "
3889
3890 A good replacement for %s
3891 is placing values for the user.name and
3892 user.email settings into your personal
3893 ~/.gitconfig file.
3894 " $suggest_user]
3895                 }
3896                 warn_popup $msg
3897         }
3898         unset ignored_env msg suggest_user name
3899 }
3900
3901 # -- Only initialize complex UI if we are going to stay running.
3902 #
3903 if {[is_enabled transport]} {
3904         load_all_remotes
3905
3906         set n [.mbar.remote index end]
3907         populate_remotes_menu
3908         set n [expr {[.mbar.remote index end] - $n}]
3909         if {$n > 0} {
3910                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3911                 .mbar.remote insert $n separator
3912         }
3913         unset n
3914 }
3915
3916 if {[winfo exists $ui_comm]} {
3917         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3918
3919         # -- If both our backup and message files exist use the
3920         #    newer of the two files to initialize the buffer.
3921         #
3922         if {$GITGUI_BCK_exists} {
3923                 set m [gitdir GITGUI_MSG]
3924                 if {[file isfile $m]} {
3925                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3926                                 catch {file delete [gitdir GITGUI_MSG]}
3927                         } else {
3928                                 $ui_comm delete 0.0 end
3929                                 $ui_comm edit reset
3930                                 $ui_comm edit modified false
3931                                 catch {file delete [gitdir GITGUI_BCK]}
3932                                 set GITGUI_BCK_exists 0
3933                         }
3934                 }
3935                 unset m
3936         }
3937
3938         proc backup_commit_buffer {} {
3939                 global ui_comm GITGUI_BCK_exists
3940
3941                 set m [$ui_comm edit modified]
3942                 if {$m || $GITGUI_BCK_exists} {
3943                         set msg [string trim [$ui_comm get 0.0 end]]
3944                         regsub -all -line {[ \r\t]+$} $msg {} msg
3945
3946                         if {$msg eq {}} {
3947                                 if {$GITGUI_BCK_exists} {
3948                                         catch {file delete [gitdir GITGUI_BCK]}
3949                                         set GITGUI_BCK_exists 0
3950                                 }
3951                         } elseif {$m} {
3952                                 catch {
3953                                         set fd [open [gitdir GITGUI_BCK] w]
3954                                         fconfigure $fd -encoding utf-8
3955                                         puts -nonewline $fd $msg
3956                                         close $fd
3957                                         set GITGUI_BCK_exists 1
3958                                 }
3959                         }
3960
3961                         $ui_comm edit modified false
3962                 }
3963
3964                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3965         }
3966
3967         backup_commit_buffer
3968
3969         # -- If the user has aspell available we can drive it
3970         #    in pipe mode to spellcheck the commit message.
3971         #
3972         set spell_cmd [list |]
3973         set spell_dict [get_config gui.spellingdictionary]
3974         lappend spell_cmd aspell
3975         if {$spell_dict ne {}} {
3976                 lappend spell_cmd --master=$spell_dict
3977         }
3978         lappend spell_cmd --mode=none
3979         lappend spell_cmd --encoding=utf-8
3980         lappend spell_cmd pipe
3981         if {$spell_dict eq {none}
3982          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3983                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3984         } else {
3985                 set ui_comm_spell [spellcheck::init \
3986                         $spell_fd \
3987                         $ui_comm \
3988                         $ui_comm_ctxm \
3989                 ]
3990         }
3991         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3992 }
3993
3994 lock_index begin-read
3995 if {![winfo ismapped .]} {
3996         wm deiconify .
3997 }
3998 after 1 {
3999         if {[is_enabled initialamend]} {
4000                 force_amend
4001         } else {
4002                 do_rescan
4003         }
4004
4005         if {[is_enabled nocommitmsg]} {
4006                 $ui_comm configure -state disabled -background gray
4007         }
4008 }
4009 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4010         after 1000 hint_gc
4011 }
4012 if {[is_enabled retcode]} {
4013         bind . <Destroy> {+terminate_me %W}
4014 }
4015 if {$picked && [is_config_true gui.autoexplore]} {
4016         do_explore
4017 }
4018
4019 # Local variables:
4020 # mode: tcl
4021 # indent-tabs-mode: t
4022 # tab-width: 4
4023 # End: