toolbox/update-all-config.pl

   1 #!/usr/bin/perl
   2
   3 # update-all-config.pl - Update all out-of-date config
   4
   5 use strict;
   6 use warnings;
   7 use vars qw($VERSION);
   8 BEGIN {*VERSION = \'2.0'}
   9 use File::Basename;
  10 use File::Spec;
  11 use Cwd qw(realpath);
  12 use POSIX qw();
  13 use Getopt::Long;
  14 use Pod::Usage;
  15 use lib "__BASEDIR__";
  16 use Girocco::Config;
  17 use Girocco::Util;
  18 use Girocco::CLIUtil;
  19 use Girocco::Project;
  20
  21 my $shbin;
  22 BEGIN {
  23     $shbin = $Girocco::Config::posix_sh_bin;
  24     defined($shbin) && $shbin ne "" or $shbin = "/bin/sh";
  25 }
  26
  27 exit(&main(@ARGV)||0);
  28
  29 my ($dryrun, $force, $quiet);
  30
  31 sub die_usage {
  32         pod2usage(-exitval => 2);
  33 }
  34
  35 sub do_help {
  36         pod2usage(-verbose => 2, -exitval => 0);
  37 }
  38
  39 sub do_version {
  40         print basename($0), " version ", $VERSION, "\n";
  41         exit 0;
  42 }
  43
  44 my ($dmode, $dperm, $drwxmode, $fmode, $fmodeoct, $fperm, $wall);
  45 BEGIN {
  46         $dmode=02775;
  47         $dperm='drwxrwsr-x';
  48         $drwxmode='ug+rwx,o+rx';
  49         $fmode=0664;
  50         $fmodeoct='0664';
  51         $fperm='-rw-rw-r--';
  52         $wall=0;
  53 }
  54
  55 my $owning_group_id;
  56
  57 sub main {
  58         local *ARGV = \@_;
  59         my ($help, $version);
  60
  61         umask 002;
  62         close(DATA) if fileno(DATA);
  63         Getopt::Long::Configure('bundling');
  64         GetOptions(
  65                 'help|h'        => sub {do_help},
  66                 'version|V'     => sub {do_version},
  67                 'dry-run|n'     => \$dryrun,
  68                 'quiet|q'       => \$quiet,
  69                 'force|f'       => \$force,
  70         ) or die_usage;
  71         $dryrun and $quiet = 0;
  72
  73         -f jailed_file("/etc/group") or
  74                 die "Girocco group file not found: " . jailed_file("/etc/group") . "\n";
  75
  76         if (!defined($Girocco::Config::owning_group) || $Girocco::Config::owning_group eq "") {
  77                 die "\$Girocco::Config::owning_group unset, refusing to run without --force\n" unless $force;
  78                 $dmode=02777;
  79                 $dperm='drwxrwsrwx';
  80                 $drwxmode='a+rwx';
  81                 $fmode=0666;
  82                 $fmodeoct='0666';
  83                 $fperm='-rw-rw-rw-';
  84                 $wall=1;
  85                 warn "Mode 666 in effect\n" unless $quiet;
  86         } elsif (($owning_group_id = scalar(getgrnam($Girocco::Config::owning_group))) !~ /^\d+$/) {
  87                 die "\$Girocco::Config::owning_group invalid ($Girocco::Config::owning_group), refusing to run\n";
  88         }
  89
  90         my @allprojs = Girocco::Project::get_full_list;
  91         my @projects = ();
  92
  93         my $root = $Girocco::Config::reporoot;
  94         $root or die "\$Girocco::Config::reporoot is invalid\n";
  95         $root =~ s,/+$,,;
  96         $root ne "" or $root = "/";
  97         $root = realpath($root);
  98         if (@ARGV) {
  99                 my %projnames = map {($_ => 1)} @allprojs;
 100                 foreach (@ARGV) {
 101                         s,/+$,,;
 102                         $_ or $_ = "/";
 103                         -d $_ and $_ = realpath($_);
 104                         s,^\Q$root\E/,,;
 105                         s,\.git$,,;
 106                         if (!exists($projnames{$_})) {
 107                                 warn "$_: unknown to Girocco (not in etc/group)\n"
 108                                         unless $quiet;
 109                                 next;
 110                         }
 111                         push(@projects, $_);
 112                 }
 113         } else {
 114                 @projects = sort {lc($a) cmp lc($b)} @allprojs;
 115         }
 116
 117         nice_me(18);
 118         my $bad = 0;
 119         foreach (@projects) {
 120                 my $projdir = "$root/$_.git";
 121                 if (! -d $projdir) {
 122                         warn "$_: does not exist -- skipping\n" unless $quiet;
 123                         next;
 124                 }
 125                 if (!is_git_dir($projdir)) {
 126                         warn "$_: is not a .git directory -- skipping\n" unless $quiet;
 127                         next;
 128                 }
 129                 if (-e "$projdir/.noconfig") {
 130                         warn "$_: found .noconfig -- skipping\n" unless $quiet;
 131                         next;
 132                 }
 133                 if (!chdir($projdir)) {
 134                         warn "$_: chdir to project directory failed: $!\n" unless $quiet;
 135                         next;
 136                 }
 137                 process_one_project($_) or $bad = 1;
 138         }
 139
 140         return $bad ? 1 : 0;
 141 }
 142
 143 my (@mkdirs, @mkfiles);
 144 my (@fixdpermsdirs, @fixdpermsrwx, @fixfpermsfiles, @fixfpermsdirs);
 145 BEGIN {
 146         @mkdirs = qw(refs info hooks ctags htmlcache bundles reflogs objects objects/info);
 147         @mkfiles = qw(config info/lastactivity);
 148         @fixdpermsdirs = qw(. refs info ctags htmlcache bundles reflogs objects objects/info);
 149         @fixdpermsrwx = qw(refs objects);
 150         @fixfpermsfiles = qw(HEAD config description packed-refs README.html info/lastactivity
 151                 info/alternates info/http-alternates info/packs);
 152         @fixfpermsdirs = qw(ctags);
 153 }
 154
 155 my (@boolvars, @falsevars, @false0vars, @truevars);
 156 BEGIN {
 157         @boolvars = qw(gitweb.statusupdates);
 158         @falsevars = qw(core.ignorecase receive.denynonfastforwards);
 159         @false0vars = qw(gc.auto receive.autogc);
 160         @truevars = qw(receive.updateserverinfo repack.writebitmaps transfer.fsckobjects);
 161 }
 162
 163 my $hdr;
 164
 165 sub defval($$) {
 166         return defined($_[0]) ? $_[0] : $_[1];
 167 }
 168
 169 sub openfind_ {
 170         my $noe = shift;
 171         my $duperr;
 172         if ($noe) {{
 173                 open $duperr, '>&2' or last;
 174                 my $errfd = POSIX::open(File::Spec->devnull, &POSIX::O_RDWR);
 175                 defined($errfd) or close($duperr), $duperr = undef, last;
 176                 POSIX::dup2($errfd, 2) or close($duperr), $duperr = undef;
 177                 POSIX::close($errfd);
 178         }}
 179         my $fd;
 180         my $ans = open $fd, '-|', "find", @_;
 181         if ($noe && defined($duperr) && defined(fileno($duperr))) {
 182                 POSIX::dup2(fileno($duperr), 2);
 183                 close($duperr);
 184         }
 185         $ans or die "find failed: $!\n";
 186         return $fd;
 187 }
 188
 189 sub openfind { return openfind_(0, @_); }
 190 sub openfindne { return openfind_(1, @_); }
 191
 192 sub process_one_project
 193 {
 194         my ($proj) = @_;
 195         my $bad = 0;
 196         my $reallybad = 0;
 197         $hdr = 0;
 198         do {
 199                 if (! -d $_) {
 200                         if (-e $_) {
 201                                 warn "$proj: bypassing project, exists but not directory: $_\n" unless $quiet;
 202                                 $reallybad = $bad = 1;
 203                                 last;
 204                         } else {
 205                                 do_mkdir($proj, $_) or $bad = 1, last;
 206                         }
 207                 }
 208         } foreach (@mkdirs);
 209         return 0 if $reallybad;
 210
 211         -d $_ && check_dperm($proj, $_) or $bad = 1 foreach (@fixdpermsdirs);
 212         my $fp = openfindne(@fixdpermsrwx, qw(-xdev -type d ( ! -path objects/?? -o -prune ) ! -perm), "-$drwxmode", "-print");
 213         while (<$fp>) {
 214                 chomp;
 215                 change_dpermrwx($proj, $_) or $bad = 1;
 216         }
 217         close($fp) or $bad = 1;
 218         $fp = openfind(qw(. -xdev -type d ( ! -path ./objects/?? -o -prune ) ! -perm -a+rx -print));
 219         while (<$fp>) {
 220                 chomp;
 221                 change_dpermrx($proj, $_) or $bad = 1;
 222         }
 223         close($fp) or $bad = 1;
 224
 225         do {
 226                 if (-e $_) {
 227                         if (! -f $_) {
 228                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 229                                 $reallybad = $bad = 1;
 230                                 last;
 231                         }
 232                 } else {
 233                         my $result = "(dryrun)";
 234                         if (!$dryrun) {
 235                                 $result = "";
 236                                 my $tf;
 237                                 open($tf, '>', $_) && close ($tf) or $result = "FAILED", $bad = 1;
 238                         }
 239                         pmsg($proj, "$_: created", $result) unless $quiet;
 240                 }
 241         } foreach(@mkfiles);
 242         return 0 if $reallybad;
 243
 244         $dryrun || check_fperm($proj, "config") or $bad = 1;
 245         my $config = read_config_file_hash("config", !$quiet);
 246         if (!defined($config)) {
 247                 warn "$proj: could not read config file -- skipping\n" unless $quiet;
 248                 return 0;
 249         }
 250
 251         my $do_config = sub {
 252                 my ($item, $val) = @_;
 253                 my $oldval = defval($config->{$item},"");
 254                 my $result = "(dryrun)";
 255                 if (!$dryrun) {
 256                         $result = "";
 257                         system($Girocco::Config::git_bin, "config", "--file", "config", "--replace-all", $item, $val) == 0 or
 258                                 $result = "FAILED", $bad = 1;
 259                 }
 260                 if (!exists($config->{$item})) {
 261                         pmsg($proj, "config $item: created \"$val\"", $result) unless $quiet;
 262                 } else {
 263                         pmsg($proj, "config $item: \"$oldval\" -> \"$val\"", $result) unless $quiet;
 264                 }
 265         };
 266         my $do_config_unset = sub {
 267                 my ($item, $msg) = @_;
 268                 defined($msg) or $msg = "";
 269                 $msg eq "" or $msg = " " . $msg;
 270                 my $oldval = defval($config->{$item},"");
 271                 my $result = "(dryrun)";
 272                 if (!$dryrun) {
 273                         $result = "";
 274                         system($Girocco::Config::git_bin, "config", "--file", "config", "--unset-all", $item) == 0 or
 275                                 $result = "FAILED", $bad = 1;
 276                 }
 277                 pmsg($proj, "config $item: removed$msg \"$oldval\"", $result) unless $quiet;
 278         };
 279
 280         my $repovers = $config->{'core.repositoryformatversion'};
 281         if (!defined($repovers)) {
 282                 $repovers = "";
 283         } elsif ($repovers =~ /^[2345]$/) {
 284                 pmsg($proj, "WARNING: unknown core.repositoryformatversion value left unchanged: \"$repovers\"");
 285         } elsif ($repovers !~ /^[01]$/) {
 286                 pmsg($proj, "WARNING: replacing invalid core.repositoryformatversion value: \"$repovers\"") unless $quiet;
 287                 $repovers = "";
 288         }
 289         &$do_config('core.repositoryformatversion', 0) if $repovers eq "";
 290         my $hookspath = $Girocco::Config::reporoot . "/_global/hooks";
 291         defval($config->{'core.hookspath'},"") eq $hookspath or &$do_config('core.hookspath', $hookspath);
 292         my $cmplvl = defval($config->{'core.compression'},"");
 293         if ($cmplvl !~ /^-?\d+$/ || $cmplvl < -1 || $cmplvl > 9 || "" . (0 + $cmplvl) ne "" . $cmplvl) {
 294                 pmsg($proj, "WARNING: replacing invalid core.compression value: \"$cmplvl\"") unless $cmplvl eq "" || $quiet;
 295                 $cmplvl = "";
 296         } elsif ($cmplvl != 5) {
 297                 pmsg($proj, "WARNING: suboptimal core.compression value left unchanged: \"$cmplvl\"") unless $quiet;
 298         }
 299         $cmplvl ne "" or &$do_config('core.compression', 5);
 300         my $grpshr = defval($config->{'core.sharedrepository'},"");
 301         if ($grpshr eq "" || (valid_bool($grpshr) && !git_bool($grpshr))) {
 302                 &$do_config('core.sharedrepository', 1);
 303         } elsif (!(valid_bool($grpshr) && git_bool($grpshr))) {
 304                 pmsg($proj, "WARNING: odd core.sharedrepository value left unchanged: \"$grpshr\"");
 305         }
 306         if (git_bool($config->{'core.bare'})) {
 307                 my $setlaru = 1;
 308                 my $laru = $config->{'core.logallrefupdates'};
 309                 if (defined($laru)) {
 310                         if (valid_bool($laru)) {
 311                                 $setlaru = 0;
 312                                 if (git_bool($laru)) {
 313                                         pmsg($proj, "WARNING: core.logallrefupdates is true (left unchanged)") unless $quiet;
 314                                 }
 315                         } else {
 316                                 pmsg($proj, "WARNING: replacing non-boolean core.logallrefupdates value") unless $quiet;
 317                         }
 318                 }
 319                 !$setlaru or &$do_config('core.logallrefupdates', 'false');
 320         } else {
 321                 pmsg($proj, "WARNING: core.bare is not true (left unchanged)") unless $quiet;
 322         }
 323         defval($config->{'transfer.unpacklimit'},"") eq "1" or &$do_config('transfer.unpacklimit', 1);
 324         lc(defval($config->{'receive.denydeletecurrent'},"")) eq "warn" or &$do_config('receive.denydeletecurrent', 'warn');
 325         do {
 326                 !exists($config->{$_}) || valid_bool(defval($config->{$_},"")) or &$do_config_unset($_, "(not a boolean)");
 327         } foreach (@boolvars);
 328         do {
 329                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, "false");
 330         } foreach (@falsevars);
 331         do {
 332                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, 0);
 333         } foreach (@false0vars);
 334         do {
 335                 (valid_bool(defval($config->{$_},"")) && git_bool($config->{$_})) or &$do_config($_, "true");
 336         } foreach (@truevars);
 337
 338         if (defined($Girocco::Config::owning_group) && $Girocco::Config::owning_group ne "") {
 339                 $fp = openfind(qw(. -xdev ( -type d -o -type f ) ! -group), $Girocco::Config::owning_group, "-print");
 340                 while (<$fp>) {
 341                         chomp;
 342                         change_group($proj, $_) or $bad = 1;
 343                 }
 344                 close($fp) or $bad = 1;
 345         }
 346         foreach (@fixfpermsfiles) {
 347                 if (-e $_) {
 348                         if (! -f $_) {
 349                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 350                                 $reallybad = $bad = 1;
 351                                 last;
 352                         }
 353                         check_fperm($proj, $_) or $bad = 1;
 354                 }
 355         }
 356         return 0 if $reallybad;
 357
 358         $fp = openfindne(@fixfpermsdirs, qw(-xdev -type f ! -perm), $fmodeoct, "-print");
 359         while (<$fp>) {
 360                 chomp;
 361                 check_fperm($proj, $_) or $bad = 1;
 362         }
 363         close($fp) or $bad = 1;
 364         $fp = openfind(qw(. -xdev -type f ! -perm -a+r -print));
 365         while (<$fp>) {
 366                 chomp;
 367                 check_fpermr($proj, $_) or $bad = 1;
 368         }
 369         close($fp) or $bad = 1;
 370         $fp = openfind(qw(. -xdev -type d ( -path ./hooks -o -path ./mob/hooks ) -prune -o -type f -perm +a+x -print));
 371         while (<$fp>) {
 372                 chomp;
 373                 check_fpermnox($proj, $_) or $bad = 1;
 374         }
 375         close($fp) or $bad = 1;
 376
 377         my $bu = defval($config->{'gitweb.baseurl'},"");
 378         if (-e ".nofetch") {
 379                 $bu eq "" or pmsg($proj, "WARNING: .nofetch exists but gitweb.baseurl is not empty ($bu)") unless $quiet;
 380         } else {
 381                 $bu ne "" or pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist") unless $quiet;
 382         }
 383
 384         return !$bad;
 385 }
 386
 387 sub do_mkdir
 388 {
 389         my ($proj, $subdir) = @_;
 390         my $result = "";
 391         if (!$dryrun) {
 392                 mkdir("$subdir") && -d "$subdir" or $result = "FAILED";
 393         } else {
 394                 $result = "(dryrun)";
 395         }
 396         pmsg($proj, "$subdir/: created", $result);
 397         return $result ne "FAILED";
 398 }
 399
 400 sub check_dperm {
 401         my ($proj, $subdir) = @_;
 402         my $oldmode = (stat($subdir))[2];
 403         if (!defined($oldmode) || $oldmode eq "") {
 404                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 405                 return 0;
 406         }
 407         my $newmode = ($oldmode & ~07777) | $dmode;
 408         $newmode == $oldmode and return 1;
 409         my $result = "";
 410         if (!$dryrun) {
 411                 if (!chmod($newmode & 07777, $subdir)) {
 412                         $result = "FAILED";
 413                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 414                 }
 415         } else {
 416                 $result = "(dryrun)";
 417         }
 418         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 419         return $result ne "FAILED";
 420 }
 421
 422 sub change_dpermrwx {
 423         my ($proj, $subdir) = @_;
 424         my $oldmode = (stat($subdir))[2];
 425         if (!defined($oldmode) || $oldmode eq "") {
 426                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 427                 return 0;
 428         }
 429         my $newmode = $oldmode | ($wall ? 0777 : 0775);
 430         $newmode == $oldmode and return 1;
 431         my $result = "";
 432         if (!$dryrun) {
 433                 if (!chmod($newmode & 07777, $subdir)) {
 434                         $result = "FAILED";
 435                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 436                 }
 437         } else {
 438                 $result = "(dryrun)";
 439         }
 440         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 441         return $result ne "FAILED";
 442 }
 443
 444 sub change_dpermrx {
 445         my ($proj, $subdir) = @_;
 446         $subdir =~ s,^\./,,;
 447         my $oldmode = (stat($subdir))[2];
 448         if (!defined($oldmode) || $oldmode eq "") {
 449                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 450                 return 0;
 451         }
 452         my $newmode = $oldmode | 0555;
 453         $newmode == $oldmode and return 1;
 454         my $result = "";
 455         if (!$dryrun) {
 456                 if (!chmod($newmode & 07777, $subdir)) {
 457                         $result = "FAILED";
 458                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 459                 }
 460         } else {
 461                 $result = "(dryrun)";
 462         }
 463         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 464         return $result ne "FAILED";
 465 }
 466
 467 sub check_fperm {
 468         my ($proj, $file) = @_;
 469         my $oldmode = (stat($file))[2];
 470         if (!defined($oldmode) || $oldmode eq "") {
 471                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 472                 return 0;
 473         }
 474         my $newmode = ($oldmode & ~07777) | $fmode;
 475         $newmode == $oldmode and return 1;
 476         my $result = "";
 477         if (!$dryrun) {
 478                 if (!chmod($newmode & 07777, $file)) {
 479                         $result = "FAILED";
 480                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 481                 }
 482         } else {
 483                 $result = "(dryrun)";
 484         }
 485         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 486         return $result ne "FAILED";
 487 }
 488
 489 sub check_fpermr {
 490         my ($proj, $file) = @_;
 491         $file =~ s,^\./,,;
 492         my $oldmode = (stat($file))[2];
 493         if (!defined($oldmode) || $oldmode eq "") {
 494                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 495                 return 0;
 496         }
 497         my $newmode = $oldmode | 0444;
 498         $newmode == $oldmode and return 1;
 499         my $result = "";
 500         if (!$dryrun) {
 501                 if (!chmod($newmode & 07777, $file)) {
 502                         $result = "FAILED";
 503                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 504                 }
 505         } else {
 506                 $result = "(dryrun)";
 507         }
 508         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 509         return $result ne "FAILED";
 510 }
 511
 512 sub check_fpermnox {
 513         my ($proj, $file) = @_;
 514         $file =~ s,^\./,,;
 515         my $oldmode = (stat($file))[2];
 516         if (!defined($oldmode) || $oldmode eq "") {
 517                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 518                 return 0;
 519         }
 520         my $newmode = $oldmode & ~0111;
 521         $newmode == $oldmode and return 1;
 522         my $result = "";
 523         if (!$dryrun) {
 524                 if (!chmod($newmode & 07777, $file)) {
 525                         $result = "FAILED";
 526                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 527                 }
 528         } else {
 529                 $result = "(dryrun)";
 530         }
 531         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 532         return $result ne "FAILED";
 533 }
 534
 535 sub change_group {
 536         my ($proj, $item) = @_;
 537         $item =~ s,^\./,,;
 538         my @info = stat($item);
 539         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 540                 warn "chgrp: ($proj) $item: No such file or directory\n" unless $quiet;
 541                 return 0;
 542         }
 543         $info[5] == $owning_group_id and return 1;
 544         my $result = "";
 545         if (!$dryrun) {
 546                 if (!chown($info[4], $owning_group_id, $item)) {
 547                         $result = "FAILED";
 548                         warn "chgrp: ($proj) $item: $!\n" unless $quiet;
 549                 } elsif (!chmod($info[2] & 07777, $item)) {
 550                         $result = "FAILED";
 551                         warn "chmod: ($proj) $item: $!\n" unless $quiet;
 552                 }
 553         } else {
 554                 $result = "(dryrun)";
 555         }
 556         my $isdir = ((($info[2] >> 12) & 017) == 004) ? '/' : '';
 557         pmsg($proj, "$item$isdir: group", get_grp_nam($info[5]), '->', $Girocco::Config::owning_group, $result);
 558         return $result ne "FAILED";
 559 }
 560
 561 my $wrote; BEGIN {$wrote = ""}
 562 sub pmsg {
 563         my $proj = shift;
 564         my $msg = join(" ", @_);
 565         $msg =~ s/\s+$//;
 566         my $prefix = "";
 567         if (!$hdr) {
 568                 $prefix = $wrote . $proj . ":\n";
 569                 $hdr = 1;
 570         }
 571         print $prefix, "  ", join(' ', @_), "\n";
 572         $wrote = "\n";
 573 }
 574
 575 my %ftypes;
 576 BEGIN {%ftypes = (
 577         000 => '?',
 578         001 => 'p',
 579         002 => 'c',
 580         003 => '?',
 581         004 => 'd',
 582         005 => '?',
 583         006 => 'b',
 584         007 => '?',
 585         010 => '-',
 586         011 => '?',
 587         012 => 'l',
 588         013 => '?',
 589         014 => 's',
 590         015 => '?',
 591         016 => 'w',
 592         017 => '?'
 593 )}
 594 my %fperms;
 595 BEGIN {%fperms = (
 596         0 => '---',
 597         1 => '--x',
 598         2 => '-w-',
 599         3 => '-wx',
 600         4 => 'r--',
 601         5 => 'r-x',
 602         6 => 'rw-',
 603         7 => 'rwx'
 604 )}
 605
 606 sub get_mode_perm {
 607         my $mode = $_[0];
 608         my $str = $ftypes{($mode >> 12) & 017} .
 609                 $fperms{($mode >> 6) & 7} .
 610                 $fperms{($mode >> 3) & 7} .
 611                 $fperms{$mode & 7};
 612         substr($str,3,1) = ($mode & 0100) ? 's' : 'S' if $mode & 04000;
 613         substr($str,6,1) = ($mode & 0010) ? 's' : 'S' if $mode & 02000;
 614         substr($str,9,1) = ($mode & 0001) ? 't' : 'T' if $mode & 01000;
 615         return $str;
 616 }
 617
 618 sub get_perm {
 619         my $mode = (stat($_[0]))[2];
 620         defined($mode) or return '??????????';
 621         return get_mode_perm($mode);
 622 }
 623
 624 sub get_grp_nam {
 625         my $grpid = $_[0];
 626         defined($grpid) or return '?';
 627         my $grpnm = scalar(getgrgid($grpid));
 628         return defined($grpnm) && $grpnm ne "" ? $grpnm : $grpid;
 629 }
 630
 631 sub get_grp {
 632         my $grp = (stat($_[0]))[5];
 633         defined($grp) or return '?';
 634         return get_grp_nam($grp);
 635 }
 636
 637 __END__
 638
 639 =head1 NAME
 640
 641 update-all-config.pl - Update all projects' config settings
 642
 643 =head1 SYNOPSIS
 644
 645 update-all-config.pl [<options>] [<projname>]...
 646
 647  Options:
 648    -h | --help                  detailed instructions
 649    -V | --version               show version
 650    -n | --dry-run               show what would be done but don't do it
 651    -f | --force                 run without a Config.pm owning_group
 652    -q | --quiet                 suppress change messages
 653
 654  <projname>                     if given, only operate on these projects
 655
 656 =head1 OPTIONS
 657
 658 =over 8
 659
 660 =item B<-h>, B<--help>
 661
 662 Print the full description of update-all-config.pl's options.
 663
 664 =item B<-V>, B<--version>
 665
 666 Print the version of update-all-config.pl.
 667
 668 =item B<-n>, B<--dry-run>
 669
 670 Do not actually make any changes, just show what would be done without
 671 actually doing it.
 672
 673 =item B<-q>, B<--quiet>
 674
 675 Suppress the messages about what's actually being changed.  This option
 676 is ignored if B<--dry-run> is in effect.
 677
 678 The warnings about missing and unknown-to-Girocco projects are also
 679 suppressed by this option.
 680
 681 =item B<-f>, B<--force>
 682
 683 Allow running without a $Girocco::Config::owning_group set.  This is not
 684 recommended as it results in world-writable items being used (instead of
 685 just world-readable).
 686
 687 =item B<<projname>>
 688
 689 If no project names are specified then I<all> projects are processed.
 690
 691 If one or more project names are specified then only those projects are
 692 processed.  Specifying non-existent projects produces a warning for them,
 693 but the rest of the projects specified will still be processed.
 694
 695 Each B<projname> may be either a full absolute path starting with
 696 $Girocco::Config::reporoot or just the project name part with or without
 697 a trailing C<.git>.
 698
 699 Any explicitly specified projects that do exist but are not known to
 700 Girocco will be skipped (with a warning).
 701
 702 =back
 703
 704 =head1 DESCRIPTION
 705
 706 Inspect the C<config> files of Girocco projects (i.e. $GIT_DIR/config) and
 707 look for anomalies and out-of-date settings.
 708
 709 Additionally check the existence and permissions on various files and
 710 directories in the project.
 711
 712 If an explicity specified project is located under $Girocco::Config::reporoot
 713 but is not actually known to Girocco (i.e. it's not in the etc/group file)
 714 then it will be skipped.
 715
 716 By default, any anomalies or out-of-date settings will be corrected with a
 717 message to that effect.  However using B<--dry-run> will only show the
 718 correction(s) which would be made without making them and B<--quiet> will make
 719 the correction(s) without any messages.
 720
 721 Any projects that have a C<$GIT_DIR/.noconfig> file are always skipped (with a
 722 message unless B<--quiet> is used).
 723
 724 =cut