CMakeLists.txt

   1 #################################################################################
   2 # $Id$
   3 #
   4 # Main GEOS build configuration file for CMake build system
   5 #
   6 # Copyright (C) 2009 Mateusz Loskot <mateusz@loskot.net>
   7 #
   8 # This is free software; you can redistribute and/or modify it under
   9 # the terms of the GNU Lesser General Public Licence as published
  10 # by the Free Software Foundation.
  11 # See the COPYING file for more information.
  12 #
  13 #################################################################################
  14 project(geos)
  15 cmake_minimum_required(VERSION 2.6)
  16
  17 if(NOT CMAKE_VERSION)
  18     set(CMAKE_VERSION
  19       "${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
  20 endif()
  21
  22 # Location of custom CMake modules with macros used by GEOS
  23 set(CMAKE_MODULE_PATH "${geos_SOURCE_DIR}/cmake/modules")
  24
  25 #################################################################################
  26 # Setup GEOS version
  27 #################################################################################
  28
  29 # GEOS release version
  30 # GEOS C++ library SONAME will use these encoding ABI break at every release
  31 set(VERSION_MAJOR 3)
  32 set(VERSION_MINOR 3)
  33 set(VERSION_PATCH 0)
  34 set(VERSION "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  35
  36 # JTS_PORT is the version of JTS this release is bound to
  37 set(JTS_PORT 1.10.0)
  38 message(STATUS "Setting GEOS version ${VERSION} as port of JTS ${JTS_PORT}")
  39
  40 # GEOS C API version
  41 set(CAPI_INTERFACE_CURRENT 7)
  42 set(CAPI_INTERFACE_REVISION 1)
  43 set(CAPI_INTERFACE_AGE 6)
  44
  45 math(EXPR CAPI_VERSION_MAJOR "${CAPI_INTERFACE_CURRENT} - ${CAPI_INTERFACE_AGE}")
  46 set(CAPI_VERSION_MINOR ${CAPI_INTERFACE_AGE})
  47 set(CAPI_VERSION_PATCH ${CAPI_INTERFACE_REVISION})
  48 set(CAPI_VERSION "${CAPI_VERSION_MAJOR}.${CAPI_VERSION_MINOR}.${CAPI_VERSION_PATCH}")
  49 message(STATUS "Setting GEOS C API version ${CAPI_VERSION}")
  50
  51 #################################################################################
  52 # Check custom global options
  53 #################################################################################
  54
  55 option(GEOS_ENABLE_TESTS
  56   "Set to OFF|ON (default) to control build of GEOS tests package" ON)
  57
  58 option(GEOS_ENABLE_INLINE
  59   "Set to OFF|ON (default) to control GEOS compilation with small functions inlining" ON)
  60
  61 if(NOT MSVC)
  62   option(GEOS_ENABLE_ASSERT
  63     "Set to ON|OFF (default) to build GEOS with assert() macro enabled" OFF)
  64 endif()
  65
  66 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  67   option(GEOS_ENABLE_FLOATSTORE
  68     "Set to OFF|ON (default) to control IEEE754 conformance and remove extra precision" ON)
  69 endif()
  70
  71 #################################################################################
  72 # Setup C/C++ compiler options
  73 #################################################################################
  74
  75 if(NOT CMAKE_BUILD_TYPE)
  76   set(CMAKE_BUILD_TYPE Debug CACHE STRING
  77       "Choose the type of build, options are: None Debug Release" FORCE)
  78 endif()
  79 message(STATUS "Setting GEOS build type - ${CMAKE_BUILD_TYPE}")
  80
  81 if(CMAKE_BUILD_TYPE STREQUAL Debug)
  82   add_definitions(-D_DEBUG)
  83 endif()
  84
  85 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  86
  87   # General options
  88   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -ansi")
  89
  90   # Numerical stability
  91   if(GEOS_ENABLE_FLOATSTORE)
  92     # Remove extra precision by forcing conformance to IEEE 754 rather than IEEE 854
  93     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ffloat-store")
  94   endif()
  95   message(STATUS
  96     "Forcing IEEE 754 using flag -ffloat-store - ${GEOS_ENABLE_FLOATSTORE}")
  97
  98   # Warnings specification
  99   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wno-long-long")
 100
 101   # Turn on Position Independent Code generation for GEOS C shared library
 102   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
 103
 104   # Enable glibc ISO C99 features (macros isfinite, isnan)
 105   set(CMAKE_REQUIRED_DEFINITIONS "${CMAKE_REQUIRED_DEFINITIONS} -D_ISOC99_SOURCE=1")
 106
 107 elseif(MSVC)
 108
 109   # Set pedantic mode by default
 110   #set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 111   string(REGEX REPLACE "/W[0-9]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 112   message(STATUS "Z: ${CMAKE_CXX_FLAGS}")
 113
 114   if(MSVC80 OR MSVC90 OR MSVC10)
 115
 116     # Option is to enable the /MP switch for Visual Studio 2005 or later
 117     option(GEOS_MSVC_ENABLE_MP
 118       "Set to ON to build GEOS with the /MP option (Visual Studio 2005 and above)." ON)
 119     mark_as_advanced(GEOS_MSVC_ENABLE_MP)
 120     if(GEOS_MSVC_ENABLE_MP)
 121       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 122     endif()
 123     message(STATUS "Setting Visual Studio 2005+ option /MP to ${GEOS_MSVC_ENABLE_MP}")
 124
 125     # Disable C4996: 'function': was declared deprecated
 126     add_definitions(-D_SCL_SECURE_NO_WARNINGS)
 127     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 128   endif()
 129
 130 endif()
 131
 132 if(GEOS_ENABLE_INLINE)
 133   add_definitions(-DGEOS_INLINE)
 134 endif()
 135 message(STATUS
 136   "Setting GEOS compilation with small functions inlining - ${GEOS_ENABLE_INLINE}")
 137
 138 if(NOT MSVC)
 139   if(GEOS_ENABLE_ASSERT)
 140     string(REGEX REPLACE "[-/]D.*NDEBUG" "-U NDEBUG"
 141       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 142   endif()
 143   message(STATUS
 144     "Setting GEOS compilation with assert() macro enabled - ${GEOS_ENABLE_ASSERT}")
 145 endif()
 146
 147 #################################################################################
 148 # Setup C/C++ library features
 149 #################################################################################
 150
 151 include(TestForSTDNamespace)
 152 if (CMAKE_NO_STD_NAMESPACE)
 153   message(FATAL_ERROR "Detected compiler does not support std namespace on STL classes")
 154 endif()
 155
 156 # check header files
 157 include(CheckIncludeFiles)
 158
 159 check_include_files(stdint.h HAVE_STDINT_H)
 160 check_include_files(inttypes.h HAVE_INTTYPES_H)
 161 check_include_files(ieeefp.h HAVE_IEEEFP_H)
 162
 163 # check types and sizes
 164 include(CheckTypeSize)
 165
 166 if(MSVC)
 167   check_type_size("__int64" HAVE_INT64_T_64)
 168 else()
 169   if(HAVE_STDINT_H OR HAVE_INTTYPES_H)
 170     check_type_size("int64_t" HAVE_INT64_T_64)
 171   else()
 172     check_type_size("long long int" HAVE_LONG_LONG_INT_64)
 173   endif()
 174 endif()
 175
 176 # check functions and macros
 177 include(CheckPrototypeExists)
 178 include(CheckSymbolExists)
 179
 180 check_prototype_exists(isnan cmath HAVE_STD_ISNAN)
 181 if(NOT HAVE_STD_ISNAN)
 182   if(MSVC)
 183     check_prototype_exists(_isnan float.h HAVE_ISNAN)
 184   elseif(APPLE)
 185     check_prototype_exists(__isnand math.h HAVE_ISNAND_XCODE)
 186     if(NOT HAVE_ISNAND_XCODE)
 187       check_prototype_exists(__inline_isnand math.h HAVE_INLINE_ISNAND_XCODE)
 188     endif()
 189   else()
 190     check_symbol_exists(isnan math.h HAVE_ISNAN)
 191   endif()
 192 endif()
 193
 194 check_prototype_exists(isfinite cmath HAVE_STD_ISFINITE)
 195
 196 if(NOT HAVE_STD_ISFINITE)
 197   if(MSVC)
 198     check_prototype_exists(_finite float.h HAVE_FINITE)
 199   else()
 200     #CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 201     check_symbol_exists(isfinite math.h HAVE_ISFINITE)
 202   endif()
 203 endif()
 204
 205 ################################################################################
 206 # Setup include directories
 207 #################################################################################
 208
 209 # for including GEOS C++ API headers
 210 include_directories(${geos_SOURCE_DIR}/include)
 211
 212 # for including build-specific GEOS C API headers
 213 include_directories(${geos_BINARY_DIR}/capi)
 214
 215 # for including build-specific version.h, platform.h and geos_c.h
 216 include_directories(${geos_BINARY_DIR}/include)
 217
 218 #################################################################################
 219 # Setup checks and generate config headers
 220 #################################################################################
 221
 222 # TODO: output to CMAKE_CURRENT_BINARY_DIR instead of CMAKE_SOURCE_DIR
 223
 224 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h)
 225   message(STATUS "Disabling existing ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h")
 226
 227   if(${CMAKE_MAJOR_VERSION} EQUAL 2 AND ${CMAKE_MINOR_VERSION} EQUAL 6)
 228     file(REMOVE ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h)
 229     set(PH_RESULT "removed")
 230   else()
 231     file(RENAME
 232       ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h
 233       ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h.disabled)
 234       set(PH_RESULT "renamed")
 235   endif()
 236
 237   message(STATUS "Disabling existing ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h - ${PH_RESULT}")
 238 endif()
 239
 240 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h.cmake
 241   ${CMAKE_CURRENT_BINARY_DIR}/include/geos/platform.h)
 242
 243 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/geos/version.h.in
 244   ${CMAKE_CURRENT_BINARY_DIR}/include/geos/version.h @ONLY)
 245
 246 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/capi/geos_c.h.in
 247   ${CMAKE_CURRENT_BINARY_DIR}/capi/geos_c.h @ONLY)
 248
 249 #################################################################################
 250 # Configure tests
 251 #################################################################################
 252
 253 if(GEOS_ENABLE_TESTS)
 254
 255  # Include CTest support
 256  include(CTest)
 257  enable_testing()
 258
 259   # Define "make check" as alias for "make test"
 260   add_custom_target(check COMMAND ctest)
 261
 262 endif()
 263
 264 #################################################################################
 265 # Configure subdirectories
 266 #################################################################################
 267
 268 add_subdirectory(include)
 269 add_subdirectory(src)
 270 add_subdirectory(capi)
 271 add_subdirectory(tests)
 272 add_subdirectory(tools)
 273
 274 #################################################################################
 275 # Install/Uninstall
 276 #################################################################################
 277
 278 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 279   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 280   IMMEDIATE @ONLY)
 281
 282 add_custom_target(uninstall
 283   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 284
 285 #################################################################################
 286 # DEBUG settings - TODO: make a summary
 287
 288 message(STATUS "CMake ${CMAKE_VERSION} successfully configured ${PROJECT_NAME} using ${CMAKE_GENERATOR} generator")
 289
 290 #message(STATUS "XXX: CMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS}")
 291 #message(STATUS "XXX: CMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}")
 292 #message(STATUS "XXX: CMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}")