CMakeLists.txt

   1 #################################################################################
   2 # $Id$
   3 #
   4 # Main GEOS build configuration file for CMake build system
   5 #
   6 # Copyright (C) 2009 Mateusz Loskot <mateusz@loskot.net>
   7 #
   8 # This is free software; you can redistribute and/or modify it under
   9 # the terms of the GNU Lesser General Public Licence as published
  10 # by the Free Software Foundation.
  11 # See the COPYING file for more information.
  12 #
  13 #################################################################################
  14 project(geos)
  15 cmake_minimum_required(VERSION 2.6)
  16
  17 if(NOT CMAKE_VERSION)
  18     set(CMAKE_VERSION
  19       "${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
  20 endif()
  21
  22 # Location of custom CMake modules with macros used by GEOS
  23 set(CMAKE_MODULE_PATH "${geos_SOURCE_DIR}/cmake/modules")
  24
  25 #################################################################################
  26 # Setup GEOS version
  27 #################################################################################
  28
  29 # GEOS release version
  30 # GEOS C++ library SONAME will use these encoding ABI break at every release
  31 set(VERSION_MAJOR 3)
  32 set(VERSION_MINOR 3)
  33 set(VERSION_PATCH 2dev)
  34 set(VERSION "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  35
  36 # JTS_PORT is the version of JTS this release is bound to
  37 set(JTS_PORT 1.12.0)
  38 message(STATUS "Setting GEOS version ${VERSION} as port of JTS ${JTS_PORT}")
  39
  40 # GEOS C API version
  41 set(CAPI_INTERFACE_CURRENT 8)
  42 set(CAPI_INTERFACE_REVISION 2)
  43 set(CAPI_INTERFACE_AGE 7)
  44
  45 math(EXPR CAPI_VERSION_MAJOR "${CAPI_INTERFACE_CURRENT} - ${CAPI_INTERFACE_AGE}")
  46 set(CAPI_VERSION_MINOR ${CAPI_INTERFACE_AGE})
  47 set(CAPI_VERSION_PATCH ${CAPI_INTERFACE_REVISION})
  48 set(CAPI_VERSION "${CAPI_VERSION_MAJOR}.${CAPI_VERSION_MINOR}.${CAPI_VERSION_PATCH}")
  49 message(STATUS "Setting GEOS C API version ${CAPI_VERSION}")
  50
  51 #################################################################################
  52 # Check custom global options
  53 #################################################################################
  54
  55 option(GEOS_ENABLE_TESTS
  56   "Set to OFF|ON (default) to control build of GEOS tests package" ON)
  57
  58 option(GEOS_ENABLE_INLINE
  59   "Set to OFF|ON (default) to control GEOS compilation with small functions inlining" ON)
  60
  61 if(NOT MSVC)
  62   option(GEOS_ENABLE_ASSERT
  63     "Set to ON|OFF (default) to build GEOS with assert() macro enabled" OFF)
  64 endif()
  65
  66 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  67   option(GEOS_ENABLE_FLOATSTORE
  68     "Set to OFF|ON (default) to control IEEE754 conformance and remove extra precision" ON)
  69 endif()
  70
  71 if(APPLE)
  72   option(GEOS_ENABLE_MACOSX_FRAMEWORK
  73     "Set to OFF|ON (default) to build GEOS as a Mac OS X framework" ON)
  74   option(GEOS_ENABLE_MACOSX_FRAMEWORK_UNIXCOMPAT
  75     "Set to ON|OFF (default) to add Unix compatibility to the Mac OS X framework" OFF)
  76 endif()
  77
  78 #################################################################################
  79 # Setup C/C++ compiler options
  80 #################################################################################
  81
  82 if(NOT MSVC_IDE)
  83   if(NOT CMAKE_BUILD_TYPE)
  84     set(CMAKE_BUILD_TYPE Debug CACHE STRING
  85       "Choose the type of build, options are: None Debug Release" FORCE)
  86   endif()
  87   message(STATUS "Setting GEOS build type - ${CMAKE_BUILD_TYPE}")
  88 endif()
  89
  90 if(CMAKE_BUILD_TYPE STREQUAL Debug)
  91   add_definitions(-D_DEBUG)
  92 endif()
  93
  94 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  95
  96   # General options
  97   set(CMAKE_CXX_FLAGS "-pedantic -ansi ${CMAKE_CXX_FLAGS}")
  98
  99   # Numerical stability
 100   if(GEOS_ENABLE_FLOATSTORE)
 101     # Remove extra precision by forcing conformance to IEEE 754 rather than IEEE 854
 102     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ffloat-store")
 103   endif()
 104   message(STATUS
 105     "Forcing IEEE 754 using flag -ffloat-store - ${GEOS_ENABLE_FLOATSTORE}")
 106
 107   # Warnings specification
 108   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wno-long-long")
 109
 110   # Turn on Position Independent Code generation for GEOS C shared library
 111   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
 112
 113   # Enable glibc ISO C99 features (macros isfinite, isnan)
 114   set(CMAKE_REQUIRED_DEFINITIONS "${CMAKE_REQUIRED_DEFINITIONS} -D_ISOC99_SOURCE=1")
 115
 116 elseif(MSVC)
 117
 118   # Set pedantic mode by default
 119   #set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 120   string(REGEX REPLACE "/W[0-9]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 121
 122   if(MSVC80 OR MSVC90 OR MSVC10)
 123
 124     # Option is to enable the /MP switch for Visual Studio 2005 or later
 125     option(GEOS_MSVC_ENABLE_MP
 126       "Set to ON to build GEOS with the /MP option (Visual Studio 2005 and above)." ON)
 127     mark_as_advanced(GEOS_MSVC_ENABLE_MP)
 128     if(GEOS_MSVC_ENABLE_MP)
 129       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 130     endif()
 131     message(STATUS "Setting Visual Studio 2005+ option /MP to ${GEOS_MSVC_ENABLE_MP}")
 132
 133     add_definitions(-D_SCL_SECURE_NO_WARNINGS)
 134     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 135     add_definitions(-DNOMINMAX)
 136   endif()
 137
 138 endif()
 139
 140 if(GEOS_ENABLE_INLINE)
 141   add_definitions(-DGEOS_INLINE)
 142 endif()
 143 message(STATUS
 144   "Setting GEOS compilation with small functions inlining - ${GEOS_ENABLE_INLINE}")
 145
 146 if(NOT MSVC)
 147   if(GEOS_ENABLE_ASSERT)
 148     string(REGEX REPLACE "[-/]D.*NDEBUG" "-U NDEBUG"
 149       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 150   endif()
 151   message(STATUS
 152     "Setting GEOS compilation with assert() macro enabled - ${GEOS_ENABLE_ASSERT}")
 153 endif()
 154
 155 #################################################################################
 156 # Setup C/C++ library features
 157 #################################################################################
 158
 159 # check header files
 160 include(CheckIncludeFiles)
 161
 162 check_include_files(stdint.h HAVE_STDINT_H)
 163 check_include_files(inttypes.h HAVE_INTTYPES_H)
 164 check_include_files(ieeefp.h HAVE_IEEEFP_H)
 165
 166 # check types and sizes
 167 include(CheckTypeSize)
 168
 169 if(MSVC)
 170   check_type_size("__int64" HAVE_INT64_T_64)
 171 else()
 172   if(HAVE_STDINT_H OR HAVE_INTTYPES_H)
 173     check_type_size("int64_t" HAVE_INT64_T_64)
 174   else()
 175     check_type_size("long long int" HAVE_LONG_LONG_INT_64)
 176   endif()
 177 endif()
 178
 179 # check functions and macros
 180 include(CheckPrototypeExists)
 181 include(CheckSymbolExists)
 182
 183 check_prototype_exists(isnan cmath HAVE_STD_ISNAN)
 184 if(NOT HAVE_STD_ISNAN)
 185   if(MSVC)
 186     check_prototype_exists(_isnan float.h HAVE_ISNAN)
 187   elseif(APPLE)
 188     check_prototype_exists(__isnand math.h HAVE_ISNAND_XCODE)
 189     if(NOT HAVE_ISNAND_XCODE)
 190       check_prototype_exists(__inline_isnand math.h HAVE_INLINE_ISNAND_XCODE)
 191     endif()
 192   else()
 193     check_symbol_exists(isnan math.h HAVE_ISNAN)
 194   endif()
 195 endif()
 196
 197 check_prototype_exists(isfinite cmath HAVE_STD_ISFINITE)
 198
 199 if(NOT HAVE_STD_ISFINITE)
 200   if(MSVC)
 201     check_prototype_exists(_finite float.h HAVE_FINITE)
 202   else()
 203     #CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 204     check_symbol_exists(isfinite math.h HAVE_ISFINITE)
 205   endif()
 206 endif()
 207
 208 ################################################################################
 209 # Setup build directories
 210 #################################################################################
 211
 212 # Put the libaries and binaries that get built into directories at the
 213 # top of the build tree rather than in hard-to-find leaf
 214 # directories. This simplifies manual testing and the use of the build
 215 # tree rather than installed Boost libraries.
 216 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 217 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 218 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 219
 220 ################################################################################
 221 # Setup include directories
 222 #################################################################################
 223
 224 # for including GEOS C++ API headers
 225 include_directories(${geos_SOURCE_DIR}/include)
 226
 227 # for including build-specific GEOS C API headers
 228 include_directories(${geos_BINARY_DIR}/capi)
 229
 230 # for including build-specific version.h, platform.h and geos_c.h
 231 include_directories(${geos_BINARY_DIR}/include)
 232
 233 #################################################################################
 234 # Setup checks and generate config headers
 235 #################################################################################
 236
 237 # TODO: output to CMAKE_CURRENT_BINARY_DIR instead of CMAKE_SOURCE_DIR
 238
 239 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h)
 240   message(STATUS "Disabling existing ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h")
 241
 242   if(${CMAKE_MAJOR_VERSION} EQUAL 2 AND ${CMAKE_MINOR_VERSION} EQUAL 6)
 243     file(REMOVE ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h)
 244     set(PH_RESULT "removed")
 245   else()
 246     file(RENAME
 247       ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h
 248       ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h.disabled)
 249       set(PH_RESULT "renamed")
 250   endif()
 251
 252   message(STATUS "Disabling existing ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h - ${PH_RESULT}")
 253 endif()
 254
 255 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h.cmake
 256   ${CMAKE_CURRENT_BINARY_DIR}/include/geos/platform.h)
 257
 258 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/geos/version.h.in
 259   ${CMAKE_CURRENT_BINARY_DIR}/include/geos/version.h @ONLY)
 260
 261 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/capi/geos_c.h.in
 262   ${CMAKE_CURRENT_BINARY_DIR}/capi/geos_c.h @ONLY)
 263
 264 #################################################################################
 265 # Configure tests
 266 #################################################################################
 267
 268 if(GEOS_ENABLE_TESTS)
 269
 270  # Include CTest support
 271  include(CTest)
 272  enable_testing()
 273
 274   # Define "make check" as alias for "make test"
 275   add_custom_target(check COMMAND ctest)
 276
 277 endif()
 278
 279 #################################################################################
 280 # Configure subdirectories
 281 #################################################################################
 282
 283 add_subdirectory(include)
 284 add_subdirectory(src)
 285 add_subdirectory(capi)
 286 add_subdirectory(tests)
 287 add_subdirectory(tools)
 288
 289 #################################################################################
 290 # Install/Uninstall
 291 #################################################################################
 292
 293 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 294   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 295   IMMEDIATE @ONLY)
 296
 297 add_custom_target(uninstall
 298   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 299
 300 #################################################################################
 301 # DEBUG settings - TODO: make a summary
 302
 303 message(STATUS "CMake ${CMAKE_VERSION} successfully configured ${PROJECT_NAME} using ${CMAKE_GENERATOR} generator")
 304
 305 #message(STATUS "XXX: CMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS}")
 306 #message(STATUS "XXX: CMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}")
 307 #message(STATUS "XXX: CMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}")