CMakeLists.txt

   1 #################################################################################
   2 # $Id$
   3 #
   4 # Main GEOS build configuration file for CMake build system
   5 #
   6 # Copyright (C) 2009 Mateusz Loskot <mateusz@loskot.net>
   7 #
   8 # This is free software; you can redistribute and/or modify it under
   9 # the terms of the GNU Lesser General Public Licence as published
  10 # by the Free Software Foundation.
  11 # See the COPYING file for more information.
  12 #
  13 #################################################################################
  14 project(geos)
  15 cmake_minimum_required(VERSION 2.6)
  16
  17 if(NOT CMAKE_VERSION)
  18     set(CMAKE_VERSION
  19       "${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
  20 endif()
  21
  22 # Location of custom CMake modules with macros used by GEOS
  23 set(CMAKE_MODULE_PATH "${geos_SOURCE_DIR}/cmake/modules")
  24
  25 #################################################################################
  26 # Setup GEOS version
  27 #################################################################################
  28
  29 # GEOS release version
  30 # GEOS C++ library SONAME will use these encoding ABI break at every release
  31 set(VERSION_MAJOR 3)
  32 set(VERSION_MINOR 3)
  33 set(VERSION_PATCH 0)
  34 set(VERSION "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  35
  36 # JTS_PORT is the version of JTS this release is bound to
  37 set(JTS_PORT 1.10.0)
  38 message(STATUS "Setting GEOS version ${VERSION} as port of JTS ${JTS_PORT}")
  39
  40 # GEOS C API version
  41 set(CAPI_INTERFACE_CURRENT 7)
  42 set(CAPI_INTERFACE_REVISION 1)
  43 set(CAPI_INTERFACE_AGE 6)
  44
  45 math(EXPR CAPI_VERSION_MAJOR "${CAPI_INTERFACE_CURRENT} - ${CAPI_INTERFACE_AGE}")
  46 set(CAPI_VERSION_MINOR ${CAPI_INTERFACE_AGE})
  47 set(CAPI_VERSION_PATCH ${CAPI_INTERFACE_REVISION})
  48 set(CAPI_VERSION "${CAPI_VERSION_MAJOR}.${CAPI_VERSION_MINOR}.${CAPI_VERSION_PATCH}")
  49 message(STATUS "Setting GEOS C API version ${CAPI_VERSION}")
  50
  51 #################################################################################
  52 # Check custom global options
  53 #################################################################################
  54
  55 option(GEOS_ENABLE_TESTS
  56   "Set to OFF|ON (default) to control build of GEOS tests package" ON)
  57
  58 option(GEOS_ENABLE_INLINE
  59   "Set to OFF|ON (default) to control GEOS compilation with small functions inlining" ON)
  60
  61 if(NOT MSVC)
  62   option(GEOS_ENABLE_ASSERT
  63     "Set to ON|OFF (default) to build GEOS with assert() macro enabled" OFF)
  64 endif()
  65
  66 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  67   option(GEOS_ENABLE_FLOATSTORE
  68     "Set to OFF|ON (default) to control IEEE754 conformance and remove extra precision" ON)
  69 endif()
  70
  71 #################################################################################
  72 # Setup C/C++ compiler options
  73 #################################################################################
  74
  75 if(NOT MSVC_IDE)
  76   if(NOT CMAKE_BUILD_TYPE)
  77     set(CMAKE_BUILD_TYPE Debug CACHE STRING
  78       "Choose the type of build, options are: None Debug Release" FORCE)
  79   endif()
  80   message(STATUS "Setting GEOS build type - ${CMAKE_BUILD_TYPE}")
  81 endif()
  82
  83 if(CMAKE_BUILD_TYPE STREQUAL Debug)
  84   add_definitions(-D_DEBUG)
  85 endif()
  86
  87 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  88
  89   # General options
  90   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -ansi")
  91
  92   # Numerical stability
  93   if(GEOS_ENABLE_FLOATSTORE)
  94     # Remove extra precision by forcing conformance to IEEE 754 rather than IEEE 854
  95     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ffloat-store")
  96   endif()
  97   message(STATUS
  98     "Forcing IEEE 754 using flag -ffloat-store - ${GEOS_ENABLE_FLOATSTORE}")
  99
 100   # Warnings specification
 101   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wno-long-long")
 102
 103   # Turn on Position Independent Code generation for GEOS C shared library
 104   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
 105
 106   # Enable glibc ISO C99 features (macros isfinite, isnan)
 107   set(CMAKE_REQUIRED_DEFINITIONS "${CMAKE_REQUIRED_DEFINITIONS} -D_ISOC99_SOURCE=1")
 108
 109 elseif(MSVC)
 110
 111   # Set pedantic mode by default
 112   #set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 113   string(REGEX REPLACE "/W[0-9]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 114
 115   if(MSVC80 OR MSVC90 OR MSVC10)
 116
 117     # Option is to enable the /MP switch for Visual Studio 2005 or later
 118     option(GEOS_MSVC_ENABLE_MP
 119       "Set to ON to build GEOS with the /MP option (Visual Studio 2005 and above)." ON)
 120     mark_as_advanced(GEOS_MSVC_ENABLE_MP)
 121     if(GEOS_MSVC_ENABLE_MP)
 122       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
 123     endif()
 124     message(STATUS "Setting Visual Studio 2005+ option /MP to ${GEOS_MSVC_ENABLE_MP}")
 125
 126     add_definitions(-D_SCL_SECURE_NO_WARNINGS)
 127     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 128     add_definitions(-DNOMINMAX)
 129   endif()
 130
 131 endif()
 132
 133 if(GEOS_ENABLE_INLINE)
 134   add_definitions(-DGEOS_INLINE)
 135 endif()
 136 message(STATUS
 137   "Setting GEOS compilation with small functions inlining - ${GEOS_ENABLE_INLINE}")
 138
 139 if(NOT MSVC)
 140   if(GEOS_ENABLE_ASSERT)
 141     string(REGEX REPLACE "[-/]D.*NDEBUG" "-U NDEBUG"
 142       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 143   endif()
 144   message(STATUS
 145     "Setting GEOS compilation with assert() macro enabled - ${GEOS_ENABLE_ASSERT}")
 146 endif()
 147
 148 #################################################################################
 149 # Setup C/C++ library features
 150 #################################################################################
 151
 152 include(TestForSTDNamespace)
 153 if (CMAKE_NO_STD_NAMESPACE)
 154   message(FATAL_ERROR "Detected compiler does not support std namespace on STL classes")
 155 endif()
 156
 157 # check header files
 158 include(CheckIncludeFiles)
 159
 160 check_include_files(stdint.h HAVE_STDINT_H)
 161 check_include_files(inttypes.h HAVE_INTTYPES_H)
 162 check_include_files(ieeefp.h HAVE_IEEEFP_H)
 163
 164 # check types and sizes
 165 include(CheckTypeSize)
 166
 167 if(MSVC)
 168   check_type_size("__int64" HAVE_INT64_T_64)
 169 else()
 170   if(HAVE_STDINT_H OR HAVE_INTTYPES_H)
 171     check_type_size("int64_t" HAVE_INT64_T_64)
 172   else()
 173     check_type_size("long long int" HAVE_LONG_LONG_INT_64)
 174   endif()
 175 endif()
 176
 177 # check functions and macros
 178 include(CheckPrototypeExists)
 179 include(CheckSymbolExists)
 180
 181 check_prototype_exists(isnan cmath HAVE_STD_ISNAN)
 182 if(NOT HAVE_STD_ISNAN)
 183   if(MSVC)
 184     check_prototype_exists(_isnan float.h HAVE_ISNAN)
 185   elseif(APPLE)
 186     check_prototype_exists(__isnand math.h HAVE_ISNAND_XCODE)
 187     if(NOT HAVE_ISNAND_XCODE)
 188       check_prototype_exists(__inline_isnand math.h HAVE_INLINE_ISNAND_XCODE)
 189     endif()
 190   else()
 191     check_symbol_exists(isnan math.h HAVE_ISNAN)
 192   endif()
 193 endif()
 194
 195 check_prototype_exists(isfinite cmath HAVE_STD_ISFINITE)
 196
 197 if(NOT HAVE_STD_ISFINITE)
 198   if(MSVC)
 199     check_prototype_exists(_finite float.h HAVE_FINITE)
 200   else()
 201     #CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 202     check_symbol_exists(isfinite math.h HAVE_ISFINITE)
 203   endif()
 204 endif()
 205
 206 ################################################################################
 207 # Setup build directories
 208 #################################################################################
 209
 210 # Put the libaries and binaries that get built into directories at the
 211 # top of the build tree rather than in hard-to-find leaf
 212 # directories. This simplifies manual testing and the use of the build
 213 # tree rather than installed Boost libraries.
 214 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 215 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
 216 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 217
 218 ################################################################################
 219 # Setup include directories
 220 #################################################################################
 221
 222 # for including GEOS C++ API headers
 223 include_directories(${geos_SOURCE_DIR}/include)
 224
 225 # for including build-specific GEOS C API headers
 226 include_directories(${geos_BINARY_DIR}/capi)
 227
 228 # for including build-specific version.h, platform.h and geos_c.h
 229 include_directories(${geos_BINARY_DIR}/include)
 230
 231 #################################################################################
 232 # Setup checks and generate config headers
 233 #################################################################################
 234
 235 # TODO: output to CMAKE_CURRENT_BINARY_DIR instead of CMAKE_SOURCE_DIR
 236
 237 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h)
 238   message(STATUS "Disabling existing ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h")
 239
 240   if(${CMAKE_MAJOR_VERSION} EQUAL 2 AND ${CMAKE_MINOR_VERSION} EQUAL 6)
 241     file(REMOVE ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h)
 242     set(PH_RESULT "removed")
 243   else()
 244     file(RENAME
 245       ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h
 246       ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h.disabled)
 247       set(PH_RESULT "renamed")
 248   endif()
 249
 250   message(STATUS "Disabling existing ${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h - ${PH_RESULT}")
 251 endif()
 252
 253 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/geos/platform.h.cmake
 254   ${CMAKE_CURRENT_BINARY_DIR}/include/geos/platform.h)
 255
 256 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/geos/version.h.in
 257   ${CMAKE_CURRENT_BINARY_DIR}/include/geos/version.h @ONLY)
 258
 259 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/capi/geos_c.h.in
 260   ${CMAKE_CURRENT_BINARY_DIR}/capi/geos_c.h @ONLY)
 261
 262 #################################################################################
 263 # Configure tests
 264 #################################################################################
 265
 266 if(GEOS_ENABLE_TESTS)
 267
 268  # Include CTest support
 269  include(CTest)
 270  enable_testing()
 271
 272   # Define "make check" as alias for "make test"
 273   add_custom_target(check COMMAND ctest)
 274
 275 endif()
 276
 277 #################################################################################
 278 # Configure subdirectories
 279 #################################################################################
 280
 281 add_subdirectory(include)
 282 add_subdirectory(src)
 283 add_subdirectory(capi)
 284 add_subdirectory(tests)
 285 add_subdirectory(tools)
 286
 287 #################################################################################
 288 # Install/Uninstall
 289 #################################################################################
 290
 291 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 292   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 293   IMMEDIATE @ONLY)
 294
 295 add_custom_target(uninstall
 296   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 297
 298 #################################################################################
 299 # DEBUG settings - TODO: make a summary
 300
 301 message(STATUS "CMake ${CMAKE_VERSION} successfully configured ${PROJECT_NAME} using ${CMAKE_GENERATOR} generator")
 302
 303 #message(STATUS "XXX: CMAKE_CXX_FLAGS=${CMAKE_CXX_FLAGS}")
 304 #message(STATUS "XXX: CMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}")
 305 #message(STATUS "XXX: CMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}")