media-gfx/zw3d/zw3d-2022.0.3.1-r3.ebuild

   1 # Copyright 1999-2023 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 MY_PGK_NAME="com.zwsoft.zw3dprofessional"
   7 inherit unpacker xdg
   8
   9 DESCRIPTION="CAD/CAM software for 3D design and processing"
  10 HOMEPAGE="https://www.zwsoft.cn/product/zw3d/linux"
  11 SRC_URI="https://home-store-packages.uniontech.com/appstore/pool/appstore/c/${MY_PGK_NAME}/${MY_PGK_NAME}_${PV}_amd64.deb -> ${P}.deb"
  12
  13 LICENSE="all-rights-reserved"
  14 SLOT="0"
  15 KEYWORDS="-* ~amd64"
  16
  17 RESTRICT="strip mirror bindist"
  18
  19 RDEPEND="
  20         app-arch/bzip2
  21         app-arch/xz-utils
  22         app-text/djvu
  23         dev-db/sqlite:3
  24         dev-libs/glib:2
  25         dev-libs/libpcre
  26         dev-libs/libxml2
  27         dev-qt/qtcore:5
  28         dev-qt/qtgui:5
  29         dev-qt/qtnetwork:5
  30         dev-qt/qtprintsupport:5
  31         dev-qt/qtsvg:5
  32         media-fonts/noto-cjk
  33         media-gfx/imagemagick
  34         media-libs/jbigkit
  35         media-libs/libglvnd
  36         media-libs/libpng
  37         media-libs/opencollada
  38         media-libs/tiff
  39         media-libs/tiff-compat:4
  40         net-libs/zeromq
  41         sys-libs/zlib
  42         x11-libs/cairo
  43         x11-libs/gdk-pixbuf:2
  44         x11-libs/gtk+:3
  45         x11-libs/libX11
  46         x11-libs/libxcb
  47         x11-libs/libXcomposite
  48         x11-libs/libXext
  49         x11-libs/libxkbcommon
  50         x11-libs/libXmu
  51         x11-libs/libXrender
  52         x11-libs/libXt
  53         x11-libs/pango
  54 "
  55
  56 DEPEND="${RDEPEND}"
  57
  58 BDEPEND="
  59         dev-util/bbe
  60         dev-util/patchelf
  61 "
  62
  63 S=${WORKDIR}
  64
  65 QA_PREBUILT="*"
  66
  67 src_install() {
  68         # Install scalable icons
  69         mkdir -p "${S}"/usr/share/icons/hicolor/scalable/apps || die
  70         mv "${S}"/opt/apps/${MY_PGK_NAME}/entries/icons/hicolor/scalable/apps/*.svg \
  71                 "${S}"/usr/share/icons/hicolor/scalable/apps || die
  72
  73         # Set RPATH for preserve-libs handling
  74         pushd "${S}"/opt/apps/${MY_PGK_NAME}/files || die
  75         local x
  76         for x in $(find) ; do
  77                 # Use \x7fELF header to separate ELF executables and libraries
  78                 [[ -f ${x} && $(od -t x1 -N 4 "${x}") == *"7f 45 4c 46"* ]] || continue
  79                 local RPATH_ROOT="/opt/apps/${MY_PGK_NAME}/files"
  80                 local RPATH_S="${RPATH_ROOT}/:${RPATH_ROOT}/lib/:${RPATH_ROOT}/lib/xlator/:${RPATH_ROOT}/lib/xlator/InterOp/:${RPATH_ROOT}/libqt/:${RPATH_ROOT}/libqt/plugins/designer/:${RPATH_ROOT}/lib3rd/:/usr/lib64/"
  81                 patchelf --set-rpath "${RPATH_S}" "${x}" || \
  82                         die "patchelf failed on ${x}"
  83                 # patchelf --replace-needed libMagickCore-6.Q16.so.7 libMagickCore-7.Q16.so "${x}" || \
  84                 #       die "patchelf failed on ${x}"
  85                 patchelf --replace-needed libjbig.so.0 libjbig.so "${x}" || \
  86                         die "patchelf failed on ${x}"
  87         done
  88         popd || die
  89
  90         # Fix desktop files
  91         sed -E -i 's/^Exec=.*$/Exec=zw3d %F/g' "${S}/usr/share/applications/${MY_PGK_NAME}.desktop" || die
  92         sed -E -i 's/^Icon=.*$/Icon=ZW3Dprofessional/g' "${S}/usr/share/applications/${MY_PGK_NAME}.desktop" || die
  93         sed -E -i 's/Application;//g' "${S}/usr/share/applications/${MY_PGK_NAME}.desktop" || die
  94
  95         # Add zw3d command
  96         mkdir -p "${S}"/usr/bin/ || die
  97
  98         cat >> "${S}"/opt/apps/${MY_PGK_NAME}/zw3d <<- EOF || die
  99 #!/bin/sh
 100 sh /opt/apps/${MY_PGK_NAME}/files/zw3drun.sh \$*
 101         EOF
 102
 103         ln -s /opt/apps/${MY_PGK_NAME}/zw3d "${S}"/usr/bin/zw3d || die
 104
 105         # Use system libraries
 106         # rm -rf "${S}"/opt/apps/${MY_PGK_NAME}/files/lib3rd/libMagickCore* || die
 107         # rm -rf "${S}"/opt/apps/${MY_PGK_NAME}/files/lib3rd/libjpeg* || die
 108
 109         # Fix coredump while draw 2D sketch due to not find fonts
 110         # media-fonts/noto-cjk is required
 111         # and should use /usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc
 112         local MY_FONT_PATH_OLD="/usr/share/fonts/opentype/noto/NotoSansCJK-Regular.ttc"
 113         local MY_FONT_PATH_NEW="//////usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc"
 114         bbe -e "s|${MY_FONT_PATH_OLD}|${MY_FONT_PATH_NEW}|" "${S}/opt/apps/${MY_PGK_NAME}/files/lib/libdisp.so" \
 115                 > "${S}/opt/apps/${MY_PGK_NAME}/files/lib/libdisp.so.tmp" && \
 116         mv "${S}/opt/apps/${MY_PGK_NAME}/files/lib/libdisp.so.tmp" "${S}/opt/apps/${MY_PGK_NAME}/files/lib/libdisp.so" || die
 117
 118         # Install package and fix permissions
 119         insinto /opt/apps
 120         doins -r opt/apps/${MY_PGK_NAME}
 121         insinto /usr
 122         doins -r usr/*
 123
 124         fperms 0755 /opt/apps/${MY_PGK_NAME}/zw3d
 125
 126         pushd "${S}" || die
 127         for x in $(find "opt/apps/${MY_PGK_NAME}") ; do
 128                 # Fix shell script permissions
 129                 [[ "${x: -3}" == ".sh" ]] && fperms 0755 "/${x}"
 130                 # Use \x7fELF header to separate ELF executables and libraries
 131                 [[ -f ${x} && $(od -t x1 -N 4 "${x}") == *"7f 45 4c 46"* ]] && fperms 0755 "/${x}"
 132         done
 133         popd || die
 134 }