media-libs/libvorbis/libvorbis-1.2.0.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="1"
   6
   7 inherit libtool flag-o-matic eutils toolchain-funcs
   8
   9 DESCRIPTION="the Ogg Vorbis sound file format library"
  10 HOMEPAGE="http://xiph.org/vorbis aotuv? ( http://www.geocities.jp/aoyoume/aotuv/ )"
  11 SRC_URI="http://downloads.xiph.org/releases/vorbis/${P}.tar.bz2"
  12
  13 LICENSE="BSD"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd"
  16 IUSE="+aotuv doc"
  17
  18 RDEPEND=">=media-libs/libogg-1"
  19 DEPEND="${RDEPEND}
  20                 dev-util/pkgconfig"
  21
  22 src_unpack() {
  23         unpack ${A}
  24         cd "${S}"
  25
  26         if use aotuv; then
  27                 epatch "${FILESDIR}"/${P}-aotuvb5.5.diff.gz
  28         fi
  29
  30         elibtoolize
  31
  32         epunt_cxx #74493
  33
  34         # Insane.
  35         sed -i -e "s:-O20::g" -e "s:-mfused-madd::g" configure
  36         sed -i -e "s:-mcpu=750::g" configure
  37 }
  38
  39 src_compile() {
  40         # gcc-3.4 and k6 with -ftracer causes code generation problems #49472
  41         if [[ "$(gcc-major-version)$(gcc-minor-version)" == "34" ]]; then
  42                 is-flag -march=k6* && filter-flags -ftracer
  43                 is-flag -mtune=k6* && filter-flags -ftracer
  44                 replace-flags -Os -O2
  45         fi
  46
  47         econf
  48         emake || die "emake failed."
  49 }
  50
  51 src_install() {
  52         emake DESTDIR="${D}" install || die "emake install failed."
  53
  54         rm -rf "${D}"/usr/share/doc/${P}
  55
  56         dodoc AUTHORS CHANGES README todo.txt
  57
  58         if use doc; then
  59                 docinto txt
  60                 dodoc doc/*.txt
  61                 dohtml -r doc
  62         fi
  63 }