x11-libs/qt-gui/qt-gui-4.4.0_rc1.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="1"
   6 inherit eutils qt4-qt-copy
   7
   8 DESCRIPTION="The GUI module(s) for the Qt toolkit."
   9 HOMEPAGE="http://www.trolltech.com/"
  10
  11 LICENSE="|| ( QPL-1.0 GPL-3 GPL-2 )"
  12 SLOT="4"
  13 KEYWORDS="~amd64 ~x86"
  14
  15 IUSE_INPUT_DEVICES="input_devices_wacom"
  16 IUSE="+accessibility cups dbus debug glib mng nas nis tiff +qt3support xinerama ${IUSE_INPUT_DEVICES}"
  17
  18 RDEPEND="
  19         media-libs/fontconfig
  20         media-libs/freetype:2
  21         media-libs/jpeg
  22         media-libs/libpng
  23         sys-libs/zlib
  24         x11-libs/libXrandr
  25         x11-libs/libXcursor
  26         x11-libs/libXfont
  27         x11-libs/libSM
  28         ~x11-libs/qt-core-${PV}
  29         ~x11-libs/qt-script-${PV}
  30         cups? ( net-print/cups )
  31         dbus? ( ~x11-libs/qt-dbus-${PV} )
  32         input_devices_wacom? ( x11-libs/libXi x11-drivers/linuxwacom )
  33         mng? ( >=media-libs/libmng-1.0.9 )
  34         nas? ( >=media-libs/nas-1.5 )
  35         tiff? ( media-libs/tiff )
  36         xinerama? ( x11-libs/libXinerama )"
  37 DEPEND="${RDEPEND}
  38         xinerama? ( x11-proto/xineramaproto )
  39         x11-proto/xextproto
  40         x11-proto/inputproto"
  41
  42 QT4_TARGET_DIRECTORIES="
  43 src/gui
  44 tools/designer
  45 tools/linguist
  46 src/plugins/imageformats/gif
  47 src/plugins/imageformats/ico
  48 src/plugins/imageformats/jpeg"
  49 QT4_EXTRACT_DIRECTORIES="
  50 src/tools/rcc/
  51 tools/shared/"
  52
  53 pkg_setup() {
  54         use glib && QT4_BUILT_WITH_USE_CHECK="${QT4_BUILT_WITH_USE_CHECK}
  55                 ~x11-libs/qt-core-${PV} glib"
  56         use qt3support && QT4_BUILT_WITH_USE_CHECK="${QT4_BUILT_WITH_USE_CHECK}
  57                 ~x11-libs/qt-core-${PV} qt3support"
  58
  59         qt4-build_pkg_setup
  60 }
  61
  62 src_unpack() {
  63         use dbus && QT4_TARGET_DIRECTORIES="${QT4_TARGET_DIRECTORIES} tools/qdbus/qdbusviewer"
  64         use mng && QT4_TARGET_DIRECTORIES="${QT4_TARGET_DIRECTORIES} src/plugins/imageformats/mng"
  65         use tiff && QT4_TARGET_DIRECTORIES="${QT4_TARGET_DIRECTORIES} src/plugins/imageformats/tiff"
  66
  67         qt4-qt-copy_src_unpack
  68
  69         # Don't build plugins this go around, because they depend on qt3support lib
  70         sed -i -e "s:CONFIG(shared:# &:g" "${S}"/tools/designer/src/src.pro
  71 }
  72
  73 src_compile() {
  74         export PATH="${S}/bin:${PATH}"
  75         export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"
  76
  77         local myconf
  78         myconf="$(qt_use accessibility)
  79                 $(qt_use cups)
  80                 $(qt_use glib)
  81                 $(qt_use input_devices_wacom tablet)
  82                 $(qt_use mng libmng system)
  83                 $(qt_use nis)
  84                 $(qt_use tiff libtiff system)
  85                 $(qt_use qdbus)
  86                 $(qt_use qt3support)
  87                 $(qt_use xinerama)"
  88
  89         use nas && myconf="${myconf} -system-nas-sound"
  90
  91         myconf="${myconf} -qt-gif -system-libpng -system-libjpeg
  92                 -no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite -no-sql-sqlite2 -no-sql-odbc
  93                 -xrender -xrandr -xkb -xshape -sm  -no-svg"
  94
  95         # Explictly don't compile these packages.
  96         # Emerge "qt-webkit", "qt-phonon", etc for their functionality.
  97         myconf="${myconf} -no-webkit -no-phonon -no-dbus -no-opengl"
  98
  99         qt4-build_src_compile
 100 }
 101
 102 src_install() {
 103         QCONFIG_ADD="x11sm xshape xcursor xfixes xrandr xrender xkb fontconfig
 104                 $(use input_devices_wacom && echo tablet) $(usev accessibility)
 105                 $(usev xinerama) $(usev cups) $(usev nas) gif png system-png system-jpeg
 106                 $(use mng && echo system-mng) $(use tiff && echo system-tiff)"
 107         QCONFIG_REMOVE="no-gif no-png"
 108         QCONFIG_DEFINE="$(use accessibility && echo QT_ACCESSIBILITY)
 109         $(use cups && echo QT_CUPS) QT_FONTCONFIG QT_IMAGEFORMAT_JPEG
 110         $(use mng && echo QT_IMAGEFORMAT_MNG) $(use nas && echo QT_NAS)
 111         $(use nis && echo QT_NIS) QT_IMAGEFORMAT_PNG QT_SESSIONMANAGER QT_SHAPE
 112         $(use tiff && echo QT_IMAGEFORMAT_TIFF) QT_XCURSOR
 113         $(use xinerama && echo QT_XINERAMA) QT_XFIXES QT_XKB QT_XRANDR QT_XRENDER"
 114         qt4-build_src_install
 115
 116         domenu "${FILESDIR}"/{Designer,Linguist}.desktop
 117 }