dev-games/glkloader/glkloader-0.3.2.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils autotools
   6
   7 DESCRIPTION="A Glk library which dynamically loads another Glk library"
   8 HOMEPAGE="http://www.eblong.com/zarf/glk/"
   9 SRC_URI="mirror://ifarchive/programming/glk/implementations/${P}.tar.gz
  10         http://www.eblong.com/zarf/glk/${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 IUSE=""
  15 KEYWORDS="~amd64 ~x86"
  16
  17 DEPEND=""
  18 PDEPEND="virtual/glk"
  19
  20 src_unpack() {
  21         unpack ${A}
  22         cd "${S}"
  23
  24         epatch "${FILESDIR}"/glkloader-0.3.2-double-free.patch
  25         epatch "${FILESDIR}"/glkloader-0.3.2-64bit.patch
  26         epatch "${FILESDIR}"/glkloader-0.3.2-glk-0.7.0.patch
  27         epatch "${FILESDIR}"/glkloader-0.3.2-gtkglk-extensions.patch
  28         epatch "${FILESDIR}"/glkloader-0.3.2-garglk-extensions.patch
  29         epatch "${FILESDIR}"/glkloader-0.3.2-dynamic-blorb-dispa.patch
  30         epatch "${FILESDIR}"/glkloader-0.3.2-cache-function-pointers.patch
  31         epatch "${FILESDIR}"/glkloader-0.3.2-no-rdynamic.patch
  32
  33         cp "${FILESDIR}"/glkloader-0.3.2-configure.ac configure.ac || die "cp configure.ac failed"
  34         cp "${FILESDIR}"/glkloader-0.3.2-Makefile.am Makefile.am || die "cp Makefile.am failed"
  35         sed -i -e "s,@PV@,${PV}," configure.ac || die "sed failed"
  36         eautoreconf
  37
  38         cp "${FILESDIR}"/glkstart.h glkstart.h || die "cp glkstart.h failed"
  39 }
  40
  41 src_compile() {
  42         cd xpconfig || die "cd xpconfig failed"
  43         econf --with-method=rcfile || die "econf xpconfig failed"
  44         emake || die "emake xpconfig failed"
  45
  46         cd .. || die "cd failed"
  47         econf || die "econf failed"
  48         emake || die "emake failed"
  49 }
  50
  51 src_install() {
  52         cd xpconfig || die "cd xpconfig failed"
  53         emake DESTDIR="${D}" install || die "emake install xpconfig failed"
  54
  55         cd .. || die "cd failed"
  56         emake DESTDIR="${D}" install || die "emake install failed"
  57         dodoc ChangeLog README || die "dodoc failed"
  58         docinto makefile-samples
  59         dodoc makefile-samples/* || die "dodoc makefile-samples failed"
  60
  61         keepdir /etc/glkloader.d
  62         insinto /etc
  63         cat >"${T}"/glkloaderrc <<-EOF
  64                 [Default]
  65                 libs = Gtk Gargoyle X Term Cheap
  66         EOF
  67         doins "${T}"/glkloaderrc || die "doins glkloaderrc failed"
  68 }