dev-games/glkterm/glkterm-0.8.1.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils autotools
   6
   7 MY_P=${P//./}
   8 DESCRIPTION="An ncurses implementation of the Glk API"
   9 HOMEPAGE="http://www.eblong.com/zarf/glk/"
  10 SRC_URI="mirror://ifarchive/programming/glk/implementations/${MY_P}.tar.gz"
  11
  12 LICENSE="Zarf"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 RDEPEND="sys-libs/ncurses"
  18 DEPEND="${RDEPEND}
  19         >=dev-games/glk-headers-0.7.0-r1"
  20
  21 S=${WORKDIR}/${PN}
  22
  23 src_unpack() {
  24         unpack ${A}
  25         cd "${S}"
  26
  27         epatch "${FILESDIR}"/glkterm-0.7.8-latin1.patch
  28         epatch "${FILESDIR}"/glkterm-0.8.0-r1-garglk-extensions.patch
  29
  30         cp "${FILESDIR}"/glkterm-0.7.8-configure.ac configure.ac || die "cp configure.ac failed"
  31         cp "${FILESDIR}"/glkterm-0.8.0-Makefile.am Makefile.am || die "cp Makefile.am failed"
  32         sed -i -e "s,@PV@,${PV}," configure.ac || die "sed failed"
  33         eautoreconf
  34
  35         rm glk.h gi_blorb.h gi_dispa.h glkstart.h || die "rm glk headers failed"
  36 }
  37
  38 src_install() {
  39         emake DESTDIR="${D}" install || die "emake install failed"
  40         dodoc readme.txt || die "dodoc failed"
  41
  42         insinto /etc/glkloader.d
  43         cat >"${T}"/glkterm.rc <<-EOF
  44                 [Term]
  45                 path = /usr/$(get_libdir)/libglkterm.so
  46         EOF
  47         doins "${T}"/glkterm.rc || die "doins glkterm.rc failed"
  48 }