dev-games/gnome-inform7/gnome-inform7-7.6g_p60.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=1
   6
   7 inherit eutils versionator autotools gnome2-utils
   8
   9 MY_MAJOR=$(get_version_component_range 2)
  10 MY_LETTER=$(get_version_component_range 3)
  11 MY_MINOR=$(get_version_component_range 4)
  12 MY_PATCH=$(get_version_component_range 5)
  13
  14 MY_LOWERS=abcdefghijklmnopqrstuvwxyz
  15 MY_UPPERS=ABCDEFGHIJKLMNOPQRSTUVWXYZ
  16 MY_INDEX=${MY_LOWERS%${MY_LETTER}*}
  17 MY_UPPER=${MY_UPPERS:${#MY_INDEX}:1}
  18
  19 MY_PV=${MY_MAJOR}${MY_UPPER}${MY_MINOR#p}${MY_PATCH:+.${MY_PATCH#p}}
  20 DESCRIPTION="GNOME user interface for Inform 7"
  21 HOMEPAGE="http://inform7.com/ http://sourceforge.net/projects/gnome-inform7/"
  22 SRC_URI="mirror://sourceforge/${PN}/I7_${MY_PV}_GNOME_Source.tar.gz"
  23
  24 LICENSE="GPL-3 LGPL-3 GPL-2 LGPL-2.1 BSD MIT Zarf"
  25 SLOT="0"
  26 KEYWORDS="~amd64 ~x86"
  27 IUSE="linguas_es" # optional nls seems broken
  28
  29 RESTRICT="test" # intltool silliness
  30
  31 DEPEND="app-text/gtkspell:2
  32         dev-libs/dbus-glib
  33         >=dev-libs/glib-2.16:2
  34         dev-libs/libxml2
  35         >=gnome-base/gconf-2.4:2
  36         net-libs/webkit-gtk:2
  37         || ( >=sys-apps/util-linux-2.16
  38                 <sys-libs/e2fsprogs-libs-1.41.8
  39                 <sys-fs/e2fsprogs-1.41.0 )
  40         virtual/libintl
  41         >=x11-libs/gdk-pixbuf-2.6:2
  42         x11-libs/goocanvas:0
  43         >=x11-libs/gtk+-2.12:2
  44         >=x11-libs/gtksourceview-2.2:2.0
  45         x11-libs/pango"
  46 RDEPEND="${DEPEND}
  47         ~dev-lang/inform-${PV%${MY_PATCH:+_${MY_PATCH}}}"
  48 DEPEND="${DEPEND}
  49         app-arch/xz-utils
  50         >=dev-util/intltool-0.35.0
  51         virtual/pkgconfig
  52         >=sys-devel/gettext-0.17"
  53
  54 S=${WORKDIR}/${PN}-${MY_PV}
  55
  56 src_unpack() {
  57         unpack ${A}
  58         cd "${S}"
  59
  60         epatch "${FILESDIR}"/gnome-inform7-6G60-unbundling.patch
  61
  62         eautoreconf
  63 }
  64
  65 src_install() {
  66         emake DESTDIR="${D}" GCONFTOOL=true install || die "emake install failed"
  67
  68         dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "dodoc failed"
  69         docinto frotz
  70         dodoc src/interpreters/frotz/{AUTHORS,README,TODO} || die "dodoc frotz failed"
  71         docinto git
  72         dodoc src/interpreters/git/README.txt || die "dodoc git failed"
  73         docinto glulxe
  74         dodoc src/interpreters/glulxe/README || die "dodoc glulxe failed"
  75
  76         cd "${D}"/usr/share
  77         rm -r doc/gnome-inform7 || die "rm doc failed"
  78         rm -r gnome-inform7/Extensions || die "rm Extensions failed"
  79         rm gnome-inform7/uninstall_manifest.txt || die "rm uninstall_manifest.txt failed"
  80         mv gnome-inform7/Documentation doc/${PF}/html || die "mv Documentation failed"
  81         dosym /usr/share/doc/${PF}/html /usr/share/gnome-inform7/Documentation || die "dosym Documentation failed"
  82
  83         dodir /usr/libexec/gnome-inform7 || die "dodir failed"
  84         dosym /usr/libexec{,/gnome-inform7}/cBlorb || die "dosym cBlorb failed"
  85         dosym /usr/bin/inform /usr/libexec/gnome-inform7/inform-6.32-biplatform || die "dosym inform-6.32-biplatform failed"
  86         dosym /usr/libexec{,/gnome-inform7}/ni || die "dosym ni failed"
  87
  88         dosym /usr/share/{inform7/Inform7,gnome-inform7}/Extensions || die "dosym Inform7 failed"
  89 }
  90
  91 pkg_preinst() {
  92         gnome2_gconf_savelist
  93 }
  94
  95 pkg_postinst() {
  96         gnome2_gconf_install
  97 }
  98
  99 #pkg_prerm() {
 100 #       gnome2_gconf_uninstall
 101 #}