dev-lang/inform/inform-7.6g_p60.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=1
   6
   7 inherit eutils versionator
   8
   9 MY_MAJOR=$(get_version_component_range 2)
  10 MY_LETTER=$(get_version_component_range 3)
  11 MY_MINOR=$(get_version_component_range 4)
  12
  13 MY_LOWERS=abcdefghijklmnopqrstuvwxyz
  14 MY_UPPERS=ABCDEFGHIJKLMNOPQRSTUVWXYZ
  15 MY_INDEX=${MY_LOWERS%${MY_LETTER}*}
  16 MY_UPPER=${MY_UPPERS:${#MY_INDEX}:1}
  17
  18 MY_PV=${MY_MAJOR}${MY_UPPER}${MY_MINOR#p}
  19 DESCRIPTION="Design system for interactive fiction"
  20 HOMEPAGE="http://inform7.com/"
  21 SRC_URI="http://inform7.com/download/content/${MY_PV}/I7_${MY_PV}_Linux_all.tar.gz"
  22
  23 # "Inform" for the core, "GPL-2" for the i7 user-interface script
  24 LICENSE="Inform GPL-2"
  25 SLOT="7"
  26 #KEYWORDS="-* ~amd64 ~arm ~ppc ~s390 ~x86"
  27 KEYWORDS="~amd64 ~x86"
  28 IUSE="doc"
  29
  30 RESTRICT="strip"
  31
  32 DEPEND=""
  33 # i7 is written in perl, and uses uuidgen from e2fsprogs
  34 RDEPEND="dev-lang/perl
  35         sys-fs/e2fsprogs
  36         games-engines/glkfrotz
  37         games-engines/glulxe
  38         >=dev-lang/inform-6.32:0"
  39
  40 S=${WORKDIR}/inform7-${MY_PV}
  41
  42 src_unpack() {
  43         unpack ${A}
  44         cd "${S}"
  45
  46         mkdir usr
  47         cd usr
  48
  49         case ${CHOST} in
  50                 # XXX if the arm team wants to keyword this, someone who knows
  51                 # how these things work should probably restrict this to
  52                 # compatible CHOSTS
  53                 arm*-*)     MY_ARCH=armv5tel ;;
  54                 i?86-*)     MY_ARCH=i386     ;;
  55                 # XXX does it work on ppc64? (statically linked, so doesn't
  56                 # need 32bit libs)
  57                 powerpc*-*) MY_ARCH=ppc      ;;
  58                 s390-*)     MY_ARCH=s390     ;;
  59                 s390x-*)    MY_ARCH=s390x    ;;
  60                 x86_64-*)   MY_ARCH=x86_64   ;;
  61                 *) die "unsupported CHOST"
  62         esac
  63
  64         unpack ./../inform7-common_${MY_PV}_all.tar.gz
  65         unpack ./../inform7-compilers_${MY_PV}_${MY_ARCH}.tar.gz
  66         # We don't currently use anything from here, but a future version
  67         # might include more interpreters.
  68         unpack ./../inform7-interpreters_${MY_PV}_${MY_ARCH}.tar.gz
  69
  70         epatch "${FILESDIR}"/inform7-6G60-paths.patch
  71
  72         find . -name '._*' -delete || die "find failed"
  73 }
  74
  75 src_install() {
  76         cp -pPR usr "${D}" || die "cp usr failed"
  77         cd "${D}"/usr
  78
  79         dodoc share/doc/inform7/README || die "dodoc README failed"
  80         rm share/doc/inform7/README
  81         docinto ChangeLogs
  82         dodoc share/doc/inform7/ChangeLogs/*.txt || die "dodoc ChangeLogs failed"
  83         rm share/doc/inform7/ChangeLogs/*.txt
  84         rmdir share/doc/inform7/ChangeLogs
  85         rm share/doc/inform7/INSTALL
  86         rmdir share/doc/inform7 || die "rmdir doc/inform7 failed"
  87
  88         if use doc; then
  89                 mv share/inform7/Documentation share/doc/${PF}/html || die "mv Documentation failed"
  90                 dosym /usr/share/doc/${PF}/html /usr/share/inform7/Documentation || die "dosym Documentation failed"
  91         else
  92                 rm -r share/inform7/Documentation || die "rm -r Documentation failed"
  93         fi
  94
  95         # Don't use the bundled interpreter binaries or Inform 6 compiler.
  96         #
  97         # The binaries that we do keep are unpacked into /usr/share with
  98         # symlinks in /usr/libexec, which is silly; move them to libexec
  99         # (there doesn't seem to be any need to recreate the symlinks
 100         # going the other way: the i7 script accesses them from libexec).
 101         # List the kept binaries explicitly (instead of using a wildcard)
 102         # so that if a future version adds more, the rmdir will fail and
 103         # alert the maintainer that changes (new dependencies etc) might
 104         # be required.
 105         rm libexec/* || die "rm libexec failed"
 106         mv share/inform7/Compilers/{ni,cBlorb} libexec || die "mv Compilers failed"
 107         rm share/inform7/Compilers/inform-6.32-biplatform
 108         rmdir share/inform7/Compilers || die "rmdir Compilers failed"
 109         rm share/inform7/Interpreters/{dumb-frotz,dumb-glulxe,dumb-git}
 110         rmdir share/inform7/Interpreters || die "rmdir Interpreters failed"
 111
 112         mv man share/man || die "mv man failed"
 113 }