elisp/geiser-chicken.el

   1 ;; geiser-chicken.el -- chicken's implementation of the geiser protocols
   2
   3 ;; Copyright (C) 2014, 2015 Daniel Leslie
   4
   5 ;; Based on geiser-guile.el by Jose Antonio Ortego Ruize
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the Modified BSD License. You should
   9 ;; have received a copy of the license along with this program. If
  10 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
  11
  12 ;; Start date: Sun Mar 08, 2009 23:03
  13
  14
  15 (require 'geiser-connection)
  16 (require 'geiser-syntax)
  17 (require 'geiser-custom)
  18 (require 'geiser-base)
  19 (require 'geiser-eval)
  20 (require 'geiser-edit)
  21 (require 'geiser-log)
  22 (require 'geiser)
  23
  24 (require 'compile)
  25 (require 'info-look)
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (defconst geiser-chicken-builtin-keywords
  30   '("assume"
  31     "compiler-typecase"
  32     "cond-expand"
  33     "condition-case"
  34     "declare"
  35     "define-constant"
  36     "define-inline"
  37     "define-interface"
  38     "define-record"
  39     "define-specialization"
  40     "define-type"
  41     "dotimes"
  42     "ecase"
  43     "fluid-let"
  44     "foreign-lambda"
  45     "foreign-lambda*"
  46     "foreign-primitive"
  47     "foreign-safe-lambda"
  48     "foreign-safe-lambda*"
  49     "functor"
  50     "handle-exceptions"
  51     "let-location"
  52     "let-optionals"
  53     "let-optionals*"
  54     "letrec-values"
  55     "module"
  56     "regex-case"
  57     "select"
  58     "use"
  59     "with-input-from-pipe"))
  60
  61 ;;; Customization:
  62
  63 (defgroup geiser-chicken nil
  64   "Customization for Geiser's Chicken flavour."
  65   :group 'geiser)
  66
  67 (geiser-custom--defcustom geiser-chicken-prefix-delimiters
  68     '("^:" "^#")
  69     "Regex to match symbol prefix delimiters."
  70   :type '(repeat string)
  71   :group 'geiser-chicken)
  72
  73 (geiser-custom--defcustom geiser-chicken-binary
  74   (cond ((eq system-type 'windows-nt) '("csi.exe" "-:c"))
  75         ((eq system-type 'darwin) "csi")
  76         (t "csi"))
  77   "Name to use to call the Chicken executable when starting a REPL."
  78   :type '(choice string (repeat string))
  79   :group 'geiser-chicken)
  80
  81 (geiser-custom--defcustom geiser-chicken-load-path nil
  82   "A list of paths to be added to Chicken's load path when it's
  83 started."
  84   :type '(repeat file)
  85   :group 'geiser-chicken)
  86
  87 (geiser-custom--defcustom geiser-chicken-compile-geiser-p t
  88   "Non-nil means that the Geiser runtime will be compiled on load."
  89   :type 'boolean
  90   :group 'geiser-chicken)
  91
  92 (geiser-custom--defcustom geiser-chicken-init-file "~/.chicken-geiser"
  93   "Initialization file with user code for the Chicken REPL.
  94 If all you want is to load ~/.csirc, set
  95 `geiser-chicken-load-init-file-p' instead."
  96   :type 'string
  97   :group 'geiser-chicken)
  98
  99 (geiser-custom--defcustom geiser-chicken-load-init-file-p nil
 100   "Whether to load ~/.chicken when starting Chicken.
 101 Note that, due to peculiarities in the way Chicken loads its init
 102 file, using `geiser-chicken-init-file' is not equivalent to setting
 103 this variable to t."
 104   :type 'boolean
 105   :group 'geiser-chicken)
 106
 107 (geiser-custom--defcustom geiser-chicken-extra-keywords nil
 108   "Extra keywords highlighted in Chicken scheme buffers."
 109   :type '(repeat string)
 110   :group 'geiser-chicken)
 111
 112 (geiser-custom--defcustom geiser-chicken-case-sensitive-p t
 113   "Non-nil means keyword highlighting is case-sensitive."
 114   :type 'boolean
 115   :group 'geiser-chicken)
 116
 117
 118 ;;; REPL support:
 119
 120 (defun geiser-chicken--binary ()
 121   (if (listp geiser-chicken-binary)
 122       (car geiser-chicken-binary)
 123     geiser-chicken-binary))
 124
 125 (defun geiser-chicken--parameters ()
 126   "Return a list with all parameters needed to start Chicken.
 127 This function uses `geiser-chicken-init-file' if it exists."
 128   (let ((init-file (and (stringp geiser-chicken-init-file)
 129                         (expand-file-name geiser-chicken-init-file)))
 130         (n-flags (and (not geiser-chicken-load-init-file-p) '("-n"))))
 131   `(,@(and (listp geiser-chicken-binary) (cdr geiser-chicken-binary))
 132     ,@n-flags "-include-path" ,(expand-file-name "chicken/" geiser-scheme-dir)
 133     ,@(apply 'append (mapcar (lambda (p) (list "-include-path" p))
 134                              geiser-chicken-load-path))
 135     ,@(and init-file (file-readable-p init-file) (list init-file)))))
 136
 137 (defconst geiser-chicken--prompt-regexp "#[^;]*;[^:0-9]*:?[0-9]+> ")
 138
 139 ;;; Evaluation support:
 140
 141 (defun geiser-chicken--geiser-procedure (proc &rest args)
 142   (let ((fmt
 143          (case proc
 144            ((eval compile)
 145             (let ((form (mapconcat 'identity (cdr args) " ")))
 146               (format ",geiser-eval %s %s" (or (car args) "#f") form)))
 147            ((load-file compile-file)
 148             (format ",geiser-load-file %s" (car args)))
 149            ((no-values)
 150             ",geiser-no-values")
 151            (t
 152             (let ((form (mapconcat 'identity args " ")))
 153               (format "(geiser-%s %s)" proc form))))))
 154     ;;(message fmt)
 155     fmt))
 156
 157 (defconst geiser-chicken--module-re
 158   "( *module +\\(([^)]+)\\|[^ ]+\\)\\|( *define-library +\\(([^)]+)\\|[^ ]+\\)")
 159
 160 (defun geiser-chicken--get-module (&optional module)
 161   (cond ((null module)
 162          (save-excursion
 163            (geiser-syntax--pop-to-top)
 164            (if (or (re-search-backward geiser-chicken--module-re nil t)
 165                    (looking-at geiser-chicken--module-re)
 166                    (re-search-forward geiser-chicken--module-re nil t))
 167                (geiser-chicken--get-module (match-string-no-properties 1))
 168              :f)))
 169         ((listp module) module)
 170         ((stringp module)
 171          (condition-case nil
 172              (car (geiser-syntax--read-from-string module))
 173            (error :f)))
 174         (t :f)))
 175
 176 (defun geiser-chicken--module-cmd (module fmt &optional def)
 177   (when module
 178     (let* ((module (geiser-chicken--get-module module))
 179            (module (cond ((or (null module) (eq module :f)) def)
 180                          (t (format "%s" module)))))
 181       (and module (format fmt module)))))
 182
 183 (defun geiser-chicken--import-command (module)
 184   (geiser-chicken--module-cmd module "(use %s)"))
 185
 186 (defun geiser-chicken--enter-command (module)
 187   (geiser-chicken--module-cmd module ",m %s" module))
 188
 189 (defun geiser-chicken--exit-command () ",q")
 190
 191 (defun geiser-chicken--symbol-begin (module)
 192   (apply
 193    'max
 194    (append
 195     (list (save-excursion (beginning-of-line) (point))
 196           (save-excursion (skip-syntax-backward "^-()>") (point)))
 197     (mapcar
 198      (lambda (match-string)
 199        (save-excursion (skip-chars-backward match-string) (point)))
 200      geiser-chicken-prefix-delimiters))))
 201
 202 ;;; Error display
 203
 204 (defun geiser-chicken--display-error (module key msg)
 205   (newline)
 206   (when (stringp msg)
 207     (save-excursion (insert msg))
 208     (geiser-edit--buttonize-files))
 209   (and (not key) msg (not (zerop (length msg)))))
 210
 211 ;;; Trying to ascertain whether a buffer is Chicken Scheme:
 212
 213 (defconst geiser-chicken--guess-re
 214   (regexp-opt (append '("csi" "chicken") geiser-chicken-builtin-keywords)))
 215
 216 (defun geiser-chicken--guess ()
 217   (save-excursion
 218     (goto-char (point-min))
 219     (re-search-forward geiser-chicken--guess-re nil t)))
 220
 221 (defun geiser-chicken--external-help (id module)
 222   "Loads chicken doc into a buffer"
 223   (browse-url (format "http://api.call-cc.org/cdoc?q=%s&query-name=Look+up" id)))
 224
 225 ;;; Keywords and syntax
 226
 227 (defun geiser-chicken--keywords ()
 228   (append
 229    (geiser-syntax--simple-keywords geiser-chicken-extra-keywords)
 230    (geiser-syntax--simple-keywords geiser-chicken-builtin-keywords)))
 231
 232 (geiser-syntax--scheme-indent
 233  (receive 2)
 234  (match 1)
 235  (match-lambda 0)
 236  (match-lambda* 0)
 237  (match-let scheme-let-indent)
 238  (match-let* 1)
 239  (match-letrec 1)
 240  (declare 0)
 241  (cond-expand 0)
 242  (let-values scheme-let-indent)
 243  (let*-values scheme-let-indent)
 244  (letrec-values 1)
 245  (letrec* 1)
 246  (parameterize scheme-let-indent)
 247  (let-location 1)
 248  (foreign-lambda 2)
 249  (foreign-lambda* 2)
 250  (foreign-primitive 2)
 251  (foreign-safe-lambda 2)
 252  (foreign-safe-lambda* 2)
 253  (set! 1)
 254  (let-optionals* 2)
 255  (let-optionals 2)
 256  (condition-case 1)
 257  (fluid-let 1)
 258  (and-let* 1)
 259  (assume 1)
 260  (cut 1)
 261  (cute 1)
 262  (when 1)
 263  (unless 1)
 264  (dotimes 1)
 265  (compiler-typecase 1)
 266  (ecase 1)
 267  (use 0)
 268  (require-extension 0)
 269  (import 0)
 270  (handle-exceptions 2)
 271  (regex-case 1)
 272  (define-inline 1)
 273  (define-constant 1)
 274  (define-syntax-rule 1)
 275  (define-record-type 1)
 276  (define-values 1)
 277  (define-record 1)
 278  (define-specialization 1)
 279  (define-type 1)
 280  (with-input-from-pipe 1)
 281  (with-output-to-pipe 1)
 282  (select 1)
 283  (functor 3)
 284  (define-interface 1)
 285  (module 2))
 286
 287 ;;; REPL startup
 288
 289 (defconst geiser-chicken-minimum-version "4.8.0.0")
 290
 291 (defun geiser-chicken--version (binary)
 292   (shell-command-to-string (format "%s -e \"(display (chicken-version))\""
 293                                    binary)))
 294
 295 (defun connect-to-chicken ()
 296   "Start a Chicken REPL connected to a remote process."
 297   (interactive)
 298   (geiser-connect 'chicken))
 299
 300 (defun geiser-chicken--compile-or-load (force-load)
 301   (let ((target
 302          (expand-file-name "chicken/geiser/emacs.so" geiser-scheme-dir))
 303         (source
 304          (expand-file-name "chicken/geiser/emacs.scm" geiser-scheme-dir))
 305         (force-load (or force-load (eq system-type 'windows-nt)))
 306         (suppression-prefix
 307          "(define geiser-stdout (current-output-port))(current-output-port (make-output-port (lambda a #f) (lambda a #f)))")
 308         (suppression-postfix
 309          "(current-output-port geiser-stdout)"))
 310     (let ((load-sequence
 311            (cond
 312             (force-load
 313              (format "(load \"%s\")\n" source))
 314             ((file-exists-p target)
 315              (format "%s(load \"%s\")(import geiser)%s\n"
 316                      suppression-prefix target suppression-postfix))
 317             (t
 318              (format "%s(use utils)(compile-file \"%s\" options: '(\"-O3\") output-file: \"%s\" load: #t)(import geiser)%s\n"
 319                      suppression-prefix source target suppression-postfix)))))
 320       (geiser-eval--send/wait load-sequence))))
 321
 322 (defun geiser-chicken--startup (remote)
 323   (compilation-setup t)
 324   (geiser-chicken--compile-or-load (not geiser-chicken-compile-geiser-p)))
 325
 326 ;;; Implementation definition:
 327
 328 (define-geiser-implementation chicken
 329   (unsupported-procedures '(callers callees generic-methods))
 330   (binary geiser-chicken--binary)
 331   (arglist geiser-chicken--parameters)
 332   (version-command geiser-chicken--version)
 333   (minimum-version geiser-chicken-minimum-version)
 334   (repl-startup geiser-chicken--startup)
 335   (prompt-regexp geiser-chicken--prompt-regexp)
 336   (debugger-prompt-regexp nil)
 337   (enter-debugger nil)
 338   (marshall-procedure geiser-chicken--geiser-procedure)
 339   (find-module geiser-chicken--get-module)
 340   (enter-command geiser-chicken--enter-command)
 341   (exit-command geiser-chicken--exit-command)
 342   (import-command geiser-chicken--import-command)
 343   (find-symbol-begin geiser-chicken--symbol-begin)
 344   (display-error geiser-chicken--display-error)
 345   (external-help geiser-chicken--external-help)
 346   (check-buffer geiser-chicken--guess)
 347   (keywords geiser-chicken--keywords)
 348   (case-sensitive geiser-chicken-case-sensitive-p))
 349
 350 (geiser-impl--add-to-alist 'regexp "\\.scm$" 'chicken t)
 351 (geiser-impl--add-to-alist 'regexp "\\.release-info$" 'chicken t)
 352 (geiser-impl--add-to-alist 'regexp "\\.meta$" 'chicken t)
 353 (geiser-impl--add-to-alist 'regexp "\\.setup$" 'chicken t)
 354
 355 (provide 'geiser-chicken)