elisp/geiser-debug.el

   1 ;;; geiser-debug.el -- displaying debug information and evaluation results
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2020 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Mon Feb 23, 2009 22:34
  11
  12 \f
  13 ;;; Code:
  14
  15 (require 'geiser-edit)
  16 (require 'geiser-autodoc)
  17 (require 'geiser-impl)
  18 (require 'geiser-eval)
  19 (require 'geiser-menu)
  20 (require 'geiser-popup)
  21 (require 'geiser-base)
  22 (require 'geiser-image)
  23
  24 \f
  25 ;;; Customization:
  26
  27 (defgroup geiser-debug nil
  28   "Debugging and error display options."
  29   :group 'geiser)
  30
  31 (geiser-custom--defcustom geiser-debug-always-display-sexp-after-p nil
  32   "Whether to always display the sexp whose evaluation caused an
  33 error after the error message in the debug pop-up. If nil,
  34 expressions shorter than `geiser-debug-long-sexp-lines` lines are
  35 shown before the error message."
  36   :group 'geiser-debug
  37   :type 'boolean)
  38
  39 (geiser-custom--defcustom geiser-debug-long-sexp-lines 6
  40   "Length of an expression in order to be relegated to the bottom
  41 of the debug pop-up (after the error message). If
  42 `geiser-debug-always-display-sexp-after-p` is t, this variable
  43 has no effect."
  44   :group 'geiser-debug
  45   :type 'int)
  46
  47 (geiser-custom--defcustom geiser-debug-jump-to-debug-p t
  48   "When set to t (the default), jump to the debug pop-up buffer
  49 in case of evaluation errors.
  50
  51 See also `geiser-debug-show-debug-p`. "
  52   :group 'geiser-debug
  53   :type 'boolean)
  54
  55 (geiser-custom--defcustom geiser-debug-show-debug-p t
  56   "When set to t (the default), show the debug pop-up buffer in
  57 case of evaluation errors.
  58
  59 This option takes effect even if `geiser-debug-jump-to-debug-p`
  60 is set."
  61   :group 'geiser-debug
  62   :type 'boolean)
  63
  64 (geiser-custom--defcustom geiser-debug-auto-display-images-p t
  65   "Whether to automatically invoke the external viewer to display
  66 images when they're evaluated.
  67
  68 See also `geiser-repl-auto-display-images-p'."
  69   :group 'geiser-debug
  70   :type 'boolean)
  71
  72 \f
  73 ;;; Debug buffer mode:
  74
  75 (defvar geiser-debug-mode-map
  76   (let ((map (make-sparse-keymap)))
  77     (suppress-keymap map)
  78     (set-keymap-parent map button-buffer-map)
  79     map)
  80   "Keymap for `geiser-debug-mode'.")
  81
  82 (define-derived-mode geiser-debug-mode nil "Geiser DBG"
  83   "A major mode for displaying Scheme compilation and evaluation results.
  84 \\{geiser-debug-mode-map}"
  85   (buffer-disable-undo)
  86   (set-syntax-table scheme-mode-syntax-table)
  87   (setq next-error-function 'geiser-edit--open-next)
  88   (setq buffer-read-only t))
  89
  90 (defun geiser-debug--button-p (nextp)
  91   (let ((m (funcall (if nextp 'next-button 'previous-button) (point))))
  92     (and m (funcall (if nextp '< '>) (point) (marker-position m)))))
  93
  94 (geiser-menu--defmenu debug geiser-debug-mode-map
  95   ("Next error" "n" forward-button :enable (geiser-debug--button-p t))
  96   ("Previous error" "p" backward-button :enable (geiser-debug--button-p t))
  97   --
  98   ("Quit" nil View-quit))
  99
 100 \f
 101 ;;; Buffer for displaying evaluation results:
 102
 103 (geiser-popup--define debug "*Geiser dbg*" geiser-debug-mode)
 104
 105 \f
 106 ;;; Displaying retorts
 107
 108 (geiser-impl--define-caller geiser-debug--display-error
 109     display-error (module key message)
 110   "This method takes 3 parameters (a module name, the error key,
 111 and the accompanying error message) and should display
 112 (in the current buffer) a formatted version of the error. If the
 113 error was successfully displayed, the call should evaluate to a
 114 non-null value.")
 115
 116 (geiser-impl--define-caller geiser-debug--enter-debugger
 117     enter-debugger ()
 118   "This method is called upon entering the debugger, in the REPL
 119 buffer.")
 120
 121 (defun geiser-debug--display-after (what)
 122   (or geiser-debug-always-display-sexp-after-p
 123       (>= (with-temp-buffer
 124             (insert what)
 125             (count-lines (point-min) (point-max)))
 126           geiser-debug-long-sexp-lines)))
 127
 128 (defun geiser-debug--insert-res (res)
 129   (let ((begin (point)))
 130     (insert res)
 131     (let ((end (point)))
 132       (goto-char begin)
 133       (let ((no (geiser-image--replace-images
 134                  t geiser-debug-auto-display-images-p)))
 135         (goto-char end)
 136         (newline 2)
 137         (and no (> no 0))))))
 138
 139 (declare-function switch-to-geiser "geiser-repl")
 140
 141 (defun geiser-debug--display-retort (what ret &optional res auto-p)
 142   (let* ((err (geiser-eval--retort-error ret))
 143          (key (geiser-eval--error-key err))
 144          (output (geiser-eval--retort-output ret))
 145          (impl geiser-impl--implementation)
 146          (module (geiser-eval--get-module))
 147          (dbg nil)
 148          (img nil)
 149          (dir default-directory)
 150          (buffer (current-buffer))
 151          (debug (eq key 'geiser-debugger))
 152          (after (geiser-debug--display-after what)))
 153     (when debug
 154       (switch-to-geiser nil nil buffer)
 155       (geiser-debug--enter-debugger impl))
 156     (geiser-debug--with-buffer
 157       (erase-buffer)
 158       (when dir (setq default-directory dir))
 159       (unless after
 160         (geiser-debug--display-error impl module nil what)
 161         (goto-char (point-max))
 162         (newline 2))
 163       (setq img (when (and res (not err)) (geiser-debug--insert-res res)))
 164       (setq dbg (geiser-debug--display-error impl module key output))
 165       (when after
 166         (goto-char (point-max))
 167         (insert "\nExpression evaluated was:\n\n")
 168         (geiser-debug--display-error impl module nil what))
 169       (goto-char (point-min)))
 170     (when (or img dbg)
 171       (when (or geiser-debug-jump-to-debug-p geiser-debug-show-debug-p)
 172         (if geiser-debug-jump-to-debug-p
 173             (geiser-debug--pop-to-buffer)
 174           (display-buffer (geiser-debug--buffer))))
 175       (when err
 176         (ignore-errors (next-error))
 177         (message "=> %s" output)))))
 178
 179 (defsubst geiser-debug--wrap-region (str)
 180   (format "(begin %s\n)" str))
 181
 182 (defun geiser-debug--unwrap (str)
 183   (if (string-match "(begin[ \t\n\v\r]+\\(.+\\)*)" str)
 184       (match-string 1 str)
 185     str))
 186
 187 (defun geiser-debug--send-region (compile start end and-go wrap &optional nomsg)
 188   (let* ((str (buffer-substring-no-properties start end))
 189          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 190          (code `(,(if compile :comp :eval) (:scm ,wrapped)))
 191          (ret (geiser-eval--send/wait code))
 192          (res (geiser-eval--retort-result-str ret nil))
 193          (err (geiser-eval--retort-error ret)))
 194     (when and-go (funcall and-go))
 195     (when (not err)
 196       (save-excursion
 197         (goto-char (/ (+ end start) 2))
 198         (geiser-autodoc--clean-cache))
 199       (unless nomsg
 200         (save-match-data
 201           (when (string-match "\\(?:[ \t\n\r]+\\)\\'" res)
 202             (setq res (replace-match "" t t res))))
 203         (message "%s" res)))
 204     (geiser-debug--display-retort (geiser-syntax--scheme-str str) ret res)
 205     ret))
 206
 207 (defun geiser-debug--expand-region (start end all wrap)
 208   (let* ((str (buffer-substring-no-properties start end))
 209          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 210          (code `(:eval (:ge macroexpand (quote (:scm ,wrapped))
 211                             ,(if all :t :f))))
 212          (ret (geiser-eval--send/wait code))
 213          (err (geiser-eval--retort-error ret))
 214          (result (geiser-eval--retort-result ret)))
 215     (if err
 216         (geiser-debug--display-retort str ret)
 217       (geiser-debug--with-buffer
 218         (erase-buffer)
 219         (insert (format "%s" (if wrap (geiser-debug--unwrap result) result)))
 220         (goto-char (point-min)))
 221       (geiser-debug--pop-to-buffer))))
 222
 223 \f
 224 (provide 'geiser-debug)