elisp/geiser-company.el

   1 ;;; geiser-company.el -- integration with company-mode
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2016 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Mon Aug 24, 2009 12:44
  11
  12 \f
  13 ;;; Code:
  14
  15 (require 'geiser-autodoc)
  16 (require 'geiser-completion)
  17 (require 'geiser-edit)
  18 (require 'geiser-base)
  19 (require 'geiser-doc)
  20
  21 (eval-when-compile (require 'cl-lib))
  22
  23 \f
  24 ;;; Helpers:
  25
  26 (make-variable-buffer-local
  27  (defvar geiser-company--enabled-flag nil))
  28
  29 (make-variable-buffer-local
  30  (defvar geiser-company--autodoc-flag nil))
  31
  32 (make-variable-buffer-local
  33  (defvar geiser-company--completions nil))
  34
  35 (defun geiser-company--candidates (prefix)
  36   (and (equal prefix (car geiser-company--completions))
  37        (cdr geiser-company--completions)))
  38
  39 (defun geiser-company--doc (id)
  40   (ignore-errors
  41     (when (not (geiser-autodoc--inhibit))
  42       (let ((help (geiser-autodoc--autodoc `((,id 0)))))
  43         (and help (substring-no-properties help))))))
  44
  45 (defun geiser-company--doc-buffer (id)
  46   (let* ((impl geiser-impl--implementation)
  47          (module (geiser-eval--get-module))
  48          (symbol (make-symbol id))
  49          (ds (geiser-doc--get-docstring symbol module)))
  50     (if (or (not ds) (not (listp ds)))
  51         (progn
  52           (message "No documentation available for '%s'" symbol)
  53           nil)
  54       (with-current-buffer (get-buffer-create "*company-documentation*")
  55         (geiser-doc--render-docstring ds symbol module impl)
  56         (current-buffer)))))
  57
  58 (defun geiser-company--docstring (id)
  59   (let* ((module (geiser-eval--get-module))
  60          (symbol (make-symbol id))
  61          (ds (geiser-doc--get-docstring symbol module)))
  62     (and ds
  63          (listp ds)
  64          (concat (geiser-autodoc--str* (cdr (assoc "signature" ds)))
  65                  "\n\n"
  66                  (cdr (assoc "docstring" ds))))))
  67
  68 (defun geiser-company--location (id)
  69   (ignore-errors
  70     (when (not (geiser-autodoc--inhibit))
  71       (let ((id (make-symbol id)))
  72         (condition-case nil
  73             (geiser-edit-module id 'noselect)
  74           (error (geiser-edit-symbol id 'noselect)))))))
  75
  76 (defun geiser-company--prefix-at-point ()
  77   (ignore-errors
  78     (when (and (not (geiser-autodoc--inhibit)) geiser-company--enabled-flag)
  79       (if (nth 8 (syntax-ppss)) 'stop
  80         (let* ((prefix (and (looking-at-p "\\_>")
  81                             (geiser-completion--prefix nil)))
  82                (cmps1 (and prefix
  83                            (geiser-completion--complete prefix nil)))
  84                (cmps2 (and prefix
  85                            (geiser-completion--complete prefix t)))
  86                (mprefix (and (not cmps1) (not cmps2)
  87                              (geiser-completion--prefix t)))
  88                (cmps3 (and mprefix (geiser-completion--complete mprefix t)))
  89                (cmps (or cmps3 (append cmps1 cmps2)))
  90                (prefix (or mprefix prefix)))
  91           (setq geiser-company--completions (cons prefix cmps))
  92           prefix)))))
  93
  94 \f
  95 ;;; Activation
  96
  97 (defun geiser-company--setup (enable)
  98   (setq geiser-company--enabled-flag enable)
  99   (when (fboundp 'geiser-company--setup-company)
 100     (geiser-company--setup-company enable)))
 101
 102 (defun geiser-company--inhibit-autodoc (ignored)
 103   (when (setq geiser-company--autodoc-flag geiser-autodoc-mode)
 104     (geiser-autodoc-mode -1)))
 105
 106 (defun geiser-company--restore-autodoc (&optional ignored)
 107   (when geiser-company--autodoc-flag
 108     (geiser-autodoc-mode 1)))
 109
 110 \f
 111 ;;; Company activation
 112
 113 (declare-function company-begin-backend "ext:company")
 114 (declare-function company-cancel "ext:company")
 115 (declare-function company-mode "ext:company")
 116 (defvar company-backends)
 117 (defvar company-active-map)
 118 (eval-after-load "company"
 119   '(progn
 120      (defun geiser-company-backend (command &optional arg &rest ignored)
 121        "A `company-mode' completion back-end for `geiser-mode'."
 122        (interactive (list 'interactive))
 123        (cl-case command
 124          ('interactive (company-begin-backend 'geiser-company-backend))
 125          ('prefix (geiser-company--prefix-at-point))
 126          ('candidates (geiser-company--candidates arg))
 127          ('meta (geiser-company--doc arg))
 128          ('doc-buffer (geiser-company--doc-buffer arg))
 129          ('quickhelp-string (geiser-company--docstring arg))
 130          ('location (geiser-company--location arg))
 131          ('sorted t)))
 132      (defun geiser-company--setup-company (enable)
 133        (when enable
 134          (set (make-local-variable 'company-backends)
 135               (add-to-list 'company-backends 'geiser-company-backend)))
 136        (company-mode (if enable 1 -1)))
 137      (add-hook 'company-completion-finished-hook
 138                'geiser-company--restore-autodoc)
 139      (add-hook 'company-completion-cancelled-hook
 140                'geiser-company--restore-autodoc)
 141      (add-hook 'company-completion-started-hook
 142                'geiser-company--inhibit-autodoc)
 143      (define-key company-active-map (kbd "M-`")
 144        (lambda ()
 145          (interactive)
 146          (company-cancel)
 147          (call-interactively 'geiser-completion--complete-module)))))
 148
 149
 150 \f
 151 (provide 'geiser-company)