elisp/geiser-syntax.el

   1 ;;; geiser-syntax.el -- utilities for parsing scheme syntax
   2
   3 ;; Copyright (C) 2009, 2010 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:03
  11
  12 \f
  13
  14 (require 'geiser-impl)
  15 (require 'geiser-popup)
  16 (require 'geiser-base)
  17
  18 (require 'scheme)
  19
  20 (eval-when-compile (require 'cl))
  21
  22 \f
  23 ;;; Indentation:
  24
  25 (defmacro geiser-syntax--scheme-indent (&rest pairs)
  26   `(progn ,@(mapcar (lambda (p)
  27                       `(put ',(car p) 'scheme-indent-function ',(cadr p)))
  28                     pairs)))
  29
  30 (geiser-syntax--scheme-indent
  31  (begin0 1)
  32  (c-declare 0)
  33  (c-lambda 2)
  34  (case-lambda 0)
  35  (case-lambda: 0)
  36  (catch defun)
  37  (class defun)
  38  (class* defun)
  39  (compound-unit/sig 0)
  40  (define: defun)
  41  (dynamic-wind 0)
  42  (for/fold 2)
  43  (instantiate 2)
  44  (interface 1)
  45  (lambda: 1)
  46  (lambda/kw 1)
  47  (let*-values 1)
  48  (let*-values: 1)
  49  (let+ 1)
  50  (let: 1)
  51  (letrec: 1)
  52  (letrec* 1)
  53  (letrec-values 1)
  54  (letrec-values: 1)
  55  (let-values 1)
  56  (let-values: 1)
  57  (let/cc: 1)
  58  (let/ec 1)
  59  (match defun)
  60  (mixin 2)
  61  (module defun)
  62  (opt-lambda 1)
  63  (parameterize 1)
  64  (parameterize-break 1)
  65  (parameterize* 1)
  66  (pmatch defun)
  67  (quasisyntax/loc 1)
  68  (receive 2)
  69  (send* 1)
  70  (sigaction 1)
  71  (syntax-case 2)
  72  (syntax/loc 1)
  73  (type-case defun)
  74  (unit defun)
  75  (unit/sig 2)
  76  (unless 1)
  77  (when 1)
  78  (while 1)
  79  (with-fluid* 1)
  80  (with-fluids 1)
  81  (with-fluids* 1)
  82  (with-handlers 1)
  83  (with-handlers: 1)
  84  (with-method 1)
  85  (with-syntax 1))
  86
  87 \f
  88 ;;; Extra syntax keywords
  89 (defconst geiser-syntax--keywords
  90   '(("\\[\\(else\\)\\>" . 1)
  91     ("(\\(parameterize\\)\\>" . 1)))
  92
  93 (font-lock-add-keywords 'scheme-mode geiser-syntax--keywords)
  94
  95 (geiser-impl--define-caller geiser-syntax--impl-kws keywords ()
  96   "A variable (or thunk returning a value) giving additional,
  97 implementation-specific entries for font-lock-keywords.")
  98
  99 (defun geiser-syntax--add-kws ()
 100   (let ((kw (geiser-syntax--impl-kws geiser-impl--implementation)))
 101     (when kw (font-lock-add-keywords nil kw))))
 102
 103 \f
 104 ;;; A simple scheme reader
 105
 106 (defvar geiser-syntax--read/buffer-limit nil)
 107
 108 (defsubst geiser-syntax--read/eos ()
 109   (or (eobp)
 110       (and geiser-syntax--read/buffer-limit
 111            (<= geiser-syntax--read/buffer-limit (point)))))
 112
 113 (defsubst geiser-syntax--read/next-char ()
 114   (unless (geiser-syntax--read/eos)
 115     (forward-char)
 116     (char-after)))
 117
 118 (defsubst geiser-syntax--read/token (token)
 119   (geiser-syntax--read/next-char)
 120   (if (listp token) token (list token)))
 121
 122 (defsubst geiser-syntax--read/elisp ()
 123   (ignore-errors (read (current-buffer))))
 124
 125 (defun geiser-syntax--read/matching (open close)
 126   (let ((count 1)
 127         (p (1+ (point))))
 128     (while (and (> count 0)
 129                 (geiser-syntax--read/next-char))
 130       (cond ((looking-at-p open) (setq count (1+ count)))
 131             ((looking-at-p close) (setq count (1- count)))))
 132     (buffer-substring-no-properties p (point))))
 133
 134 (defsubst geiser-syntax--read/unprintable ()
 135   (geiser-syntax--read/token
 136    (cons 'unprintable (geiser-syntax--read/matching "<" ">"))))
 137
 138 (defun geiser-syntax--read/skip-comment ()
 139   (while (and (geiser-syntax--read/next-char)
 140               (nth 8 (syntax-ppss))))
 141   (geiser-syntax--read/next-token))
 142
 143 (defun geiser-syntax--read/next-token ()
 144   (skip-syntax-forward "->")
 145   (if (geiser-syntax--read/eos) '(eob)
 146     (case (char-after)
 147       (?\; (geiser-syntax--read/skip-comment))
 148       ((?\( ?\[) (geiser-syntax--read/token 'lparen))
 149       ((?\) ?\]) (geiser-syntax--read/token 'rparen))
 150       (?. (if (memq (car (syntax-after (1+ (point)))) '(0 11 12))
 151               (geiser-syntax--read/token 'dot)
 152             (cons 'atom (geiser-syntax--read/elisp))))
 153       (?\# (case (geiser-syntax--read/next-char)
 154              ('nil '(eob))
 155              (?| (geiser-syntax--read/skip-comment))
 156              (?: (if (geiser-syntax--read/next-char)
 157                      (cons 'kwd (geiser-syntax--read/elisp))
 158                    '(eob)))
 159              (?\\ (cons 'char (geiser-syntax--read/elisp)))
 160              (?\( (geiser-syntax--read/token 'vectorb))
 161              (?\< (geiser-syntax--read/unprintable))
 162              ((?' ?` ?,) (geiser-syntax--read/next-token))
 163              (t (let ((tok (geiser-syntax--read/elisp)))
 164                   (if tok (cons 'atom (intern (format "#%s" tok)))
 165                     (geiser-syntax--read/next-token))))))
 166       (?\' (geiser-syntax--read/token '(quote . quote)))
 167       (?\` (geiser-syntax--read/token
 168             `(backquote . ,backquote-backquote-symbol)))
 169       (?, (if (eq (geiser-syntax--read/next-char) ?@)
 170               (geiser-syntax--read/token
 171                `(splice . ,backquote-splice-symbol))
 172             `(unquote . ,backquote-unquote-symbol)))
 173       (?\" (cons 'string (geiser-syntax--read/elisp)))
 174       (t (cons 'atom (geiser-syntax--read/elisp))))))
 175
 176 (defsubst geiser-syntax--read/match (&rest tks)
 177   (let ((token (geiser-syntax--read/next-token)))
 178     (if (memq (car token) tks) token
 179       (error "Unexpected token: %s" token))))
 180
 181 (defsubst geiser-syntax--read/skip-until (&rest tks)
 182   (let (token)
 183     (while (and (not (memq (car token) tks))
 184                 (not (eq (car token) 'eob)))
 185       (setq token (geiser-syntax--read/next-token)))
 186     token))
 187
 188 (defsubst geiser-syntax--read/try (&rest tks)
 189   (let ((p (point))
 190         (tk (ignore-errors (apply 'geiser-syntax--read/match tks))))
 191     (unless tk (goto-char p))
 192     tk))
 193
 194 (defun geiser-syntax--read/list ()
 195   (cond ((geiser-syntax--read/try 'dot)
 196          (let ((tail (geiser-syntax--read)))
 197            (geiser-syntax--read/skip-until 'eob 'rparen)
 198            tail))
 199         ((geiser-syntax--read/try 'rparen 'eob) nil)
 200         (t (cons (geiser-syntax--read)
 201                  (geiser-syntax--read/list)))))
 202
 203 (defun geiser-syntax--read ()
 204   (let ((token (geiser-syntax--read/next-token))
 205         (max-lisp-eval-depth (max max-lisp-eval-depth 3000)))
 206     (case (car token)
 207       (eob nil)
 208       (lparen (geiser-syntax--read/list))
 209       (vectorb (apply 'vector (geiser-syntax--read/list)))
 210       ((quote backquote unquote splice) (list (cdr token)
 211                                               (geiser-syntax--read)))
 212       (kwd (intern (format ":%s" (cdr token))))
 213       (unprintable (format "#<%s>" (cdr token)))
 214       ((char string atom) (cdr token))
 215       (t (error "Reading scheme syntax: unexpected token: %s" token)))))
 216
 217 (defun geiser-syntax--read-from-string (string &optional start end)
 218   (when (stringp string)
 219     (let* ((start (or start 0))
 220            (end (or end (length string)))
 221            (max-lisp-eval-depth (max max-lisp-eval-depth (- end start))))
 222       (with-temp-buffer
 223         (save-excursion (insert string))
 224         (cons (ignore-errors (geiser-syntax--read)) (point))))))
 225
 226 (defsubst geiser-syntax--form-after-point (&optional boundary)
 227   (let ((geiser-syntax--read/buffer-limit (and (numberp boundary) boundary)))
 228     (save-excursion (values (geiser-syntax--read) (point)))))
 229
 230 \f
 231 ;;; Code parsing:
 232
 233 (defsubst geiser-syntax--symbol-at-point ()
 234   (and (not (nth 8 (syntax-ppss)))
 235        (let ((s (thing-at-point 'symbol)))
 236          (and s
 237               (not (equal s "."))
 238               (make-symbol (substring-no-properties s))))))
 239
 240 (defsubst geiser-syntax--skip-comment/string ()
 241   (let ((pos (nth 8 (syntax-ppss))))
 242     (goto-char (or pos (point)))
 243     pos))
 244
 245 (defsubst geiser-syntax--nesting-level ()
 246   (or (nth 0 (syntax-ppss)) 0))
 247
 248 (defsubst geiser-syntax--pair-length (p)
 249   (if (cdr (last p)) (1+ (safe-length p)) (length p)))
 250
 251 (defun geiser-syntax--shallow-form (boundary)
 252   (when (looking-at-p "\\s(")
 253     (save-excursion
 254       (forward-char)
 255       (let ((elems))
 256         (ignore-errors
 257           (while (< (point) boundary)
 258             (skip-syntax-forward "-<>")
 259             (when (<= (point) boundary)
 260               (forward-sexp)
 261               (let ((s (thing-at-point 'symbol)))
 262                 (cond ((not s) (push s elems))
 263                       ((not (equal "." s)) (push (make-symbol s) elems)))))))
 264         (nreverse elems)))))
 265
 266 (defun geiser-syntax--scan-sexps (&optional begin)
 267   (let* ((fst (geiser-syntax--symbol-at-point))
 268          (smth (or fst (not (looking-at-p "[\s \s)\s>\s<\n]"))))
 269          (path (and fst `((,fst 0)))))
 270     (save-excursion
 271       (while (not (zerop (geiser-syntax--nesting-level)))
 272         (let ((boundary (point)))
 273           (geiser-syntax--skip-comment/string)
 274           (backward-up-list)
 275           (let ((form (geiser-syntax--shallow-form boundary)))
 276             (when (and (listp form) (car form) (symbolp (car form)))
 277               (let* ((len (geiser-syntax--pair-length form))
 278                      (pos (if smth (1- len) (progn (setq smth t) len)))
 279                      (prev (and (> pos 1) (nth (1- pos) form)))
 280                      (prev (and (keywordp prev) (list prev))))
 281                 (push `(,(car form) ,pos ,@prev) path)))))))
 282     (mapcar (lambda (e) (cons (format "%s" (car e)) (cdr e)))
 283             (nreverse path))))
 284
 285 (defsubst geiser-syntax--binding-form-p (bfs sbfs f)
 286   (or (memq f '(define define* define-syntax define-syntax-rule
 287                 lambda let let* letrec parameterize))
 288       (memq f bfs)
 289       (memq f sbfs)))
 290
 291 (defsubst geiser-syntax--binding-form*-p (sbfs f)
 292   (or (eq 'let* f) (memq f sbfs)))
 293
 294 (defsubst geiser-syntax--if-symbol (x) (and (symbolp x) x))
 295 (defsubst geiser-syntax--if-list (x) (and (listp x) x))
 296 (defsubst geiser-syntax--normalize (vars)
 297   (mapcar (lambda (i) (if (listp i) (car i) i)) vars))
 298
 299 (defun geiser-syntax--linearize (form)
 300   (cond ((not (listp form)) (list form))
 301         ((null form) nil)
 302         (t (cons (car form) (geiser-syntax--linearize (cdr form))))))
 303
 304 (defun geiser-syntax--scan-locals (bfs sbfs form partial locals)
 305   (if (or (null form) (not (listp form)))
 306       (geiser-syntax--normalize locals)
 307     (if (not (geiser-syntax--binding-form-p bfs sbfs (car form)))
 308         (geiser-syntax--scan-locals bfs sbfs
 309                                     (car (last form)) partial locals)
 310       (let* ((head (car form))
 311              (name (geiser-syntax--if-symbol (cadr form)))
 312              (names (if name (geiser-syntax--if-list (caddr form))
 313                       (geiser-syntax--if-list (cadr form))))
 314              (rest (if name (cdddr form) (cddr form)))
 315              (use-names (or rest
 316                             (not partial)
 317                             (geiser-syntax--binding-form*-p sbfs
 318                                                             head))))
 319         (when name (push name locals))
 320         (when use-names
 321           (dolist (n (geiser-syntax--linearize names))
 322             (push n locals)))
 323         (dolist (f (butlast rest))
 324           (when (and (listp f) (eq (car f) 'define))
 325             (push (cadr f) locals)))
 326         (geiser-syntax--scan-locals bfs sbfs
 327                                     (car (last (or rest names)))
 328                                     partial
 329                                     locals)))))
 330
 331 (defun geiser-syntax--locals-around-point (bfs sbfs)
 332   (when (eq major-mode 'scheme-mode)
 333     (save-excursion
 334       (let* ((sym (unless (geiser-syntax--skip-comment/string)
 335                     (symbol-at-point)))
 336              (boundary (point)))
 337         (while (not (zerop (geiser-syntax--nesting-level)))
 338           (backward-up-list))
 339         (multiple-value-bind (form end)
 340             (geiser-syntax--form-after-point boundary)
 341           (delq sym
 342                 (geiser-syntax--scan-locals bfs sbfs form
 343                                             (> end boundary) '())))))))
 344
 345 \f
 346 ;;; Fontify strings as Scheme code:
 347
 348 (defun geiser-syntax--font-lock-buffer ()
 349   (let ((name " *geiser font lock*"))
 350     (or (get-buffer name)
 351         (let ((buffer (get-buffer-create name)))
 352           (set-buffer buffer)
 353           (let ((geiser-default-implementation
 354                  (or geiser-default-implementation
 355                      (car geiser-active-implementations))))
 356             (scheme-mode))
 357           buffer))))
 358
 359 (defun geiser-syntax--scheme-str (str)
 360   (save-current-buffer
 361     (set-buffer (geiser-syntax--font-lock-buffer))
 362     (erase-buffer)
 363     (insert str)
 364     (let ((font-lock-verbose nil)) (font-lock-fontify-buffer))
 365     (buffer-string)))
 366
 367 \f
 368 (provide 'geiser-syntax)
 369 ;;; geiser-syntax.el ends here