elisp/geiser-chicken.el

   1 ;; geiser-chicken.el -- chicken's implementation of the geiser protocols
   2
   3 ;; Copyright (C) 2014, 2015 Daniel Leslie
   4
   5 ;; Based on geiser-guile.el by Jose Antonio Ortego Ruize
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the Modified BSD License. You should
   9 ;; have received a copy of the license along with this program. If
  10 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
  11
  12 ;; Start date: Sun Mar 08, 2009 23:03
  13
  14
  15 (require 'geiser-connection)
  16 (require 'geiser-syntax)
  17 (require 'geiser-custom)
  18 (require 'geiser-base)
  19 (require 'geiser-eval)
  20 (require 'geiser-edit)
  21 (require 'geiser-log)
  22 (require 'geiser)
  23
  24 (require 'compile)
  25 (require 'info-look)
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (defconst geiser-chicken-builtin-keywords
  30   '("assume"
  31     "compiler-typecase"
  32     "cond-expand"
  33     "condition-case"
  34     "declare"
  35     "define-constant"
  36     "define-inline"
  37     "define-interface"
  38     "define-record"
  39     "define-specialization"
  40     "define-type"
  41     "dotimes"
  42     "ecase"
  43     "fluid-let"
  44     "foreign-lambda"
  45     "foreign-lambda*"
  46     "foreign-primitive"
  47     "foreign-safe-lambda"
  48     "foreign-safe-lambda*"
  49     "functor"
  50     "handle-exceptions"
  51     "let-location"
  52     "let-optionals"
  53     "let-optionals*"
  54     "letrec-values"
  55     "module"
  56     "regex-case"
  57     "select"
  58     "use"
  59     "with-input-from-pipe"))
  60
  61 \f
  62 ;;; Customization:
  63
  64 (defgroup geiser-chicken nil
  65   "Customization for Geiser's Chicken flavour."
  66   :group 'geiser)
  67
  68 (geiser-custom--defcustom geiser-chicken-binary
  69   (cond ((eq system-type 'windows-nt) '("csi.exe" "-:c"))
  70         ((eq system-type 'darwin) "csi")
  71         (t "csi"))
  72   "Name to use to call the Chicken executable when starting a REPL."
  73   :type '(choice string (repeat string))
  74   :group 'geiser-chicken)
  75
  76 (geiser-custom--defcustom geiser-chicken-load-path nil
  77   "A list of paths to be added to Chicken's load path when it's
  78 started."
  79   :type '(repeat file)
  80   :group 'geiser-chicken)
  81
  82 (geiser-custom--defcustom geiser-chicken-compile-geiser-p t
  83   "Non-nil means that the Geiser runtime will be compiled on load."
  84   :type 'boolean
  85   :group 'geiser-chicken)
  86
  87 (geiser-custom--defcustom geiser-chicken-init-file "~/.chicken-geiser"
  88   "Initialization file with user code for the Chicken REPL.
  89 If all you want is to load ~/.csirc, set
  90 `geiser-chicken-load-init-file-p' instead."
  91   :type 'string
  92   :group 'geiser-chicken)
  93
  94 (geiser-custom--defcustom geiser-chicken-load-init-file-p nil
  95   "Whether to load ~/.chicken when starting Chicken.
  96 Note that, due to peculiarities in the way Chicken loads its init
  97 file, using `geiser-chicken-init-file' is not equivalent to setting
  98 this variable to t."
  99   :type 'boolean
 100   :group 'geiser-chicken)
 101
 102 (geiser-custom--defcustom geiser-chicken-extra-keywords nil
 103   "Extra keywords highlighted in Chicken scheme buffers."
 104   :type '(repeat string)
 105   :group 'geiser-chicken)
 106
 107 (geiser-custom--defcustom geiser-chicken-case-sensitive-p t
 108   "Non-nil means keyword highlighting is case-sensitive."
 109   :type 'boolean
 110   :group 'geiser-chicken)
 111
 112 \f
 113 ;;; REPL support:
 114
 115 (defun geiser-chicken--binary ()
 116   (if (listp geiser-chicken-binary)
 117       (car geiser-chicken-binary)
 118     geiser-chicken-binary))
 119
 120 (defun geiser-chicken--parameters ()
 121   "Return a list with all parameters needed to start Chicken.
 122 This function uses `geiser-chicken-init-file' if it exists."
 123   (let ((init-file (and (stringp geiser-chicken-init-file)
 124                         (expand-file-name geiser-chicken-init-file)))
 125         (n-flags (and (not geiser-chicken-load-init-file-p) '("-n"))))
 126   `(,@(and (listp geiser-chicken-binary) (cdr geiser-chicken-binary))
 127     ,@n-flags "-include-path" ,(expand-file-name "chicken/" geiser-scheme-dir)
 128     ,@(apply 'append (mapcar (lambda (p) (list "-include-path" p))
 129                              geiser-chicken-load-path))
 130     ,@(and init-file (file-readable-p init-file) (list init-file)))))
 131
 132 (defconst geiser-chicken--prompt-regexp "#[^;]*;[^:0-9]*:?[0-9]+> ")
 133
 134 \f
 135 ;;; Evaluation support:
 136
 137 (defun geiser-chicken--geiser-procedure (proc &rest args)
 138   (case proc
 139     ((eval compile)
 140      (let ((form (mapconcat 'identity (cdr args) " "))
 141            (module (if (car args) (concat "'" (car args)) "#f")))
 142        (format "(geiser-eval %s '%s)" module form)))
 143     ((load-file compile-file)
 144      (format "(geiser-load-file %s)" (car args)))
 145     ((no-values)
 146      "(geiser-no-values)")
 147     (t
 148      (let ((form (mapconcat 'identity args " ")))
 149        (format "(geiser-%s %s)" proc form)))))
 150
 151 (defconst geiser-chicken--module-re
 152   "( *module +\\(([^)]+)\\|[^ ]+\\)\\|( *define-library +\\(([^)]+)\\|[^ ]+\\)")
 153
 154 (defun geiser-chicken--get-module (&optional module)
 155   (cond ((null module)
 156          (save-excursion
 157            (geiser-syntax--pop-to-top)
 158            (if (or (re-search-backward geiser-chicken--module-re nil t)
 159                    (looking-at geiser-chicken--module-re)
 160                    (re-search-forward geiser-chicken--module-re nil t))
 161                (geiser-chicken--get-module (match-string-no-properties 1))
 162              :f)))
 163         ((listp module) module)
 164         ((stringp module)
 165          (condition-case nil
 166              (car (geiser-syntax--read-from-string module))
 167            (error :f)))
 168         (t :f)))
 169
 170 (defun geiser-chicken--module-cmd (module fmt &optional def)
 171   (when module
 172     (let* ((module (geiser-chicken--get-module module))
 173            (module (cond ((or (null module) (eq module :f)) def)
 174                          (t (format "%s" module)))))
 175       (and module (format fmt module)))))
 176
 177 (defun geiser-chicken--import-command (module)
 178   (geiser-chicken--module-cmd module "(use %s)"))
 179
 180 (defun geiser-chicken--enter-command (module)
 181   (geiser-chicken--module-cmd module ",m %s" module))
 182
 183 (defun geiser-chicken--exit-command () ",q")
 184
 185 (defun geiser-chicken--symbol-begin (module)
 186   (if module
 187       (max (save-excursion (beginning-of-line) (point))
 188            (save-excursion (skip-syntax-backward "^(>") (1- (point))))
 189     (save-excursion (skip-syntax-backward "^'-()>") (point))))
 190
 191 \f
 192 ;;; Error display
 193
 194 (defun geiser-chicken--display-error (module key msg)
 195   (newline)
 196   (when (stringp msg)
 197     (save-excursion (insert msg))
 198     (geiser-edit--buttonize-files))
 199   (and (not key) msg (not (zerop (length msg)))))
 200
 201 \f
 202 ;;; Trying to ascertain whether a buffer is Chicken Scheme:
 203
 204 (defconst geiser-chicken--guess-re
 205   (regexp-opt (append '("csi" "chicken") geiser-chicken-builtin-keywords)))
 206
 207 (defun geiser-chicken--guess ()
 208   (save-excursion
 209     (goto-char (point-min))
 210     (re-search-forward geiser-chicken--guess-re nil t)))
 211
 212 (defun geiser-chicken--external-help (id module)
 213   "Loads chicken doc into a buffer"
 214   (browse-url (format "http://api.call-cc.org/cdoc?q=%s&query-name=Look+up" id)))
 215
 216 \f
 217 ;;; Keywords and syntax
 218
 219 (defun geiser-chicken--keywords ()
 220   (append
 221    (geiser-syntax--simple-keywords geiser-chicken-extra-keywords)
 222    (geiser-syntax--simple-keywords geiser-chicken-builtin-keywords)))
 223
 224 (geiser-syntax--scheme-indent
 225  (assume 1)
 226  (compiler-typecase 1)
 227  (cond-expand 0)
 228  (condition-case 1)
 229  (cut 1)
 230  (cute 1)
 231  (declare 0)
 232  (dotimes 1)
 233  (ecase 1)
 234  (fluid-let 1)
 235  (foreign-lambda 2)
 236  (foreign-lambda* 2)
 237  (foreign-primitive 2)
 238  (foreign-safe-lambda 2)
 239  (foreign-safe-lambda* 2)
 240  (functor 3)
 241  (handle-exceptions 2)
 242  (import 0)
 243  (let-location 1)
 244  (let-optionals 2)
 245  (let-optionals* 2)
 246  (letrec-values 1)
 247  (module 2)
 248  (regex-case 1)
 249  (select 1)
 250  (set! 1)
 251  (use 0)
 252  (with-input-from-pipe 1)
 253  (with-output-to-pipe 1))
 254
 255 \f
 256 ;;; REPL startup
 257
 258 (defconst geiser-chicken-minimum-version "4.8.0.0")
 259
 260 (defun geiser-chicken--version (binary)
 261   (shell-command-to-string
 262    (format "%s -e %s"
 263            (shell-quote-argument binary)
 264            (shell-quote-argument "(display (chicken-version))"))))
 265
 266 (defun connect-to-chicken ()
 267   "Start a Chicken REPL connected to a remote process."
 268   (interactive)
 269   (geiser-connect 'chicken))
 270
 271 (defun geiser-chicken--compile-or-load (force-load)
 272   (let ((target
 273          (expand-file-name "chicken/geiser/emacs.so" geiser-scheme-dir))
 274         (source
 275          (expand-file-name "chicken/geiser/emacs.scm" geiser-scheme-dir))
 276         (force-load (or force-load (eq system-type 'windows-nt)))
 277         (suppression-prefix
 278          "(define geiser-stdout (current-output-port))(current-output-port (make-output-port (lambda a #f) (lambda a #f)))")
 279         (suppression-postfix
 280          "(current-output-port geiser-stdout)"))
 281     (let ((load-sequence
 282            (cond
 283             (force-load
 284              (format "(load \"%s\")\n(import geiser)\n" source))
 285             ((file-exists-p target)
 286              (format "%s(load \"%s\")(import geiser)%s\n"
 287                      suppression-prefix target suppression-postfix))
 288             (t
 289              (format "%s(use utils)(compile-file \"%s\" options: '(\"-O3\" \"-s\") output-file: \"%s\" load: #t)(import geiser)%s\n"
 290                      suppression-prefix source target suppression-postfix)))))
 291       (geiser-eval--send/wait load-sequence))))
 292
 293 (defun geiser-chicken--startup (remote)
 294   (compilation-setup t)
 295   (geiser-chicken--compile-or-load (not geiser-chicken-compile-geiser-p)))
 296
 297 \f
 298 ;;; Implementation definition:
 299
 300 (define-geiser-implementation chicken
 301   (unsupported-procedures '(callers callees generic-methods))
 302   (binary geiser-chicken--binary)
 303   (arglist geiser-chicken--parameters)
 304   (version-command geiser-chicken--version)
 305   (minimum-version geiser-chicken-minimum-version)
 306   (repl-startup geiser-chicken--startup)
 307   (prompt-regexp geiser-chicken--prompt-regexp)
 308   (debugger-prompt-regexp nil)
 309   (enter-debugger nil)
 310   (marshall-procedure geiser-chicken--geiser-procedure)
 311   (find-module geiser-chicken--get-module)
 312   (enter-command geiser-chicken--enter-command)
 313   (exit-command geiser-chicken--exit-command)
 314   (import-command geiser-chicken--import-command)
 315   (find-symbol-begin geiser-chicken--symbol-begin)
 316   (display-error geiser-chicken--display-error)
 317   (external-help geiser-chicken--external-help)
 318   (check-buffer geiser-chicken--guess)
 319   (keywords geiser-chicken--keywords)
 320   (case-sensitive geiser-chicken-case-sensitive-p))
 321
 322 (geiser-impl--add-to-alist 'regexp "\\.scm$" 'chicken t)
 323 (geiser-impl--add-to-alist 'regexp "\\.release-info$" 'chicken t)
 324 (geiser-impl--add-to-alist 'regexp "\\.meta$" 'chicken t)
 325 (geiser-impl--add-to-alist 'regexp "\\.setup$" 'chicken t)
 326
 327 (provide 'geiser-chicken)