elisp/geiser-connection.el

   1 ;;; geiser-connection.el -- talking to a scheme process
   2
   3 ;; Copyright (C) 2009, 2010 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sat Feb 07, 2009 21:11
  11
  12 \f
  13
  14 ;; Connection datatype and functions for managing request queues
  15 ;; between emacs and inferior guile processes.
  16
  17 (require 'geiser-log)
  18 (require 'geiser-syntax)
  19 (require 'geiser-base)
  20 (require 'geiser-impl)
  21
  22 (require 'tq)
  23
  24 \f
  25 ;;; Buffer connections:
  26
  27 (make-variable-buffer-local
  28  (defvar geiser-con--connection nil))
  29
  30 (defun geiser-con--get-connection (buffer/proc)
  31   (if (processp buffer/proc)
  32       (geiser-con--get-connection (process-buffer buffer/proc))
  33     (with-current-buffer buffer/proc geiser-con--connection)))
  34
  35 \f
  36 ;;; Request datatype:
  37
  38 (defun geiser-con--make-request (con str cont &optional sender-buffer)
  39   (list (cons :id (geiser-con--connection-inc-count con))
  40         (cons :string str)
  41         (cons :continuation cont)
  42         (cons :buffer (or sender-buffer (current-buffer)))
  43         (cons :connection con)))
  44
  45 (defsubst geiser-con--request-id (req)
  46   (cdr (assoc :id req)))
  47
  48 (defsubst geiser-con--request-string (req)
  49   (cdr (assoc :string req)))
  50
  51 (defsubst geiser-con--request-continuation (req)
  52   (cdr (assoc :continuation req)))
  53
  54 (defsubst geiser-con--request-buffer (req)
  55   (cdr (assoc :buffer req)))
  56
  57 (defsubst geiser-con--request-connection (req)
  58   (cdr (assoc :connection req)))
  59
  60 (defsubst geiser-con--request-deactivate (req)
  61   (setcdr (assoc :continuation req) nil))
  62
  63 (defsubst geiser-con--request-deactivated-p (req)
  64   (null (cdr (assoc :continuation req))))
  65
  66 \f
  67 ;;; Connection datatype:
  68
  69 (defun geiser-con--combined-prompt (prompt debug)
  70   (format "\\(%s%s\\)" prompt (if debug (format "\\|%s" debug) "")))
  71
  72 (defun geiser-con--connection-eot-re (prompt debug)
  73   (geiser-con--combined-prompt (format "\n%s" prompt)
  74                                (and debug (format "\n%s" debug))))
  75
  76 (defun geiser-con--make-connection (proc prompt debug-prompt)
  77   (list t
  78         (cons :filter (process-filter proc))
  79         (cons :tq (tq-create proc))
  80         (cons :tq-filter (process-filter proc))
  81         (cons :eot (geiser-con--connection-eot-re prompt debug-prompt))
  82         (cons :prompt prompt)
  83         (cons :debug-prompt debug-prompt)
  84         (cons :count 0)
  85         (cons :completed (make-hash-table :weakness 'value))))
  86
  87 (defsubst geiser-con--connection-process (c)
  88   (tq-process (cdr (assoc :tq c))))
  89
  90 (defsubst geiser-con--connection-filter (c)
  91   (cdr (assoc :filter c)))
  92
  93 (defsubst geiser-con--connection-tq-filter (c)
  94   (cdr (assoc :tq-filter c)))
  95
  96 (defsubst geiser-con--connection-tq (c)
  97   (cdr (assoc :tq c)))
  98
  99 (defsubst geiser-con--connection-eot (c)
 100   (cdr (assoc :eot c)))
 101
 102 (defsubst geiser-con--connection-prompt (c)
 103   (cdr (assoc :prompt c)))
 104
 105 (defsubst geiser-con--connection-debug-prompt (c)
 106   (cdr (assoc :debug-prompt c)))
 107
 108 (defsubst geiser-con--connection-completed (c r)
 109   (geiser-con--request-deactivate r)
 110   (puthash (geiser-con--request-id r) r (cdr (assoc :completed c))))
 111
 112 (defsubst geiser-con--connection-completed-p (c id)
 113   (gethash id (cdr (assoc :completed c))))
 114
 115 (defun geiser-con--connection-inc-count (c)
 116   (let* ((cnt (assoc :count c))
 117          (new (1+ (cdr cnt))))
 118     (setcdr cnt new)
 119     new))
 120
 121 (defun geiser-con--has-entered-debugger (con answer)
 122   (let ((dp (geiser-con--connection-debug-prompt con)))
 123     (and (stringp dp) (string-match dp answer))))
 124
 125 (defun geiser-con--connection-close (con)
 126   (let ((tq (geiser-con--connection-tq con)))
 127     (and tq (tq-close tq))))
 128
 129 (defvar geiser-con--startup-prompt nil)
 130 (defun geiser-con--startup-prompt (p s)
 131   (setq geiser-con--startup-prompt
 132         (concat geiser-con--startup-prompt s))
 133   nil)
 134
 135 (defun geiser-con--connection-deactivate (c &optional no-wait)
 136   (when (car c)
 137     (let* ((tq (geiser-con--connection-tq c))
 138            (proc (geiser-con--connection-process c))
 139            (proc-filter (geiser-con--connection-filter c)))
 140       (unless no-wait
 141         (while (and (not (tq-queue-empty tq))
 142                     (accept-process-output proc 0.1))))
 143       (set-process-filter proc proc-filter)
 144       (setcar c nil))))
 145
 146 (defun geiser-con--connection-activate (c)
 147   (when (not (car c))
 148     (let* ((tq (geiser-con--connection-tq c))
 149            (proc (geiser-con--connection-process c))
 150            (tq-filter (geiser-con--connection-tq-filter c)))
 151       (while (accept-process-output proc 0.01))
 152       (set-process-filter proc tq-filter)
 153       (setcar c t))))
 154
 155 \f
 156 ;;; Requests handling:
 157
 158 (defun geiser-con--req-form (req answer)
 159   (let ((con (geiser-con--request-connection req)))
 160     (if (geiser-con--has-entered-debugger con answer)
 161         `((error (key . geiser-debugger))
 162           (output . ,answer))
 163       (condition-case err
 164           (let ((form (car (read-from-string answer))))
 165             (and (listp form) form))
 166         (error `((error (key . geiser-con-error))
 167                  (output . ,(format "%s\n(%s)"
 168                                     answer
 169                                     (error-message-string err)))))))))
 170
 171 (defun geiser-con--process-completed-request (req answer)
 172   (let ((cont (geiser-con--request-continuation req))
 173         (id (geiser-con--request-id req))
 174         (rstr (geiser-con--request-string req))
 175         (form (geiser-con--req-form req answer))
 176         (buffer (or (geiser-con--request-buffer req) (current-buffer)))
 177         (con (geiser-con--request-connection req)))
 178     (if (not cont)
 179         (geiser-log--warn "<%s> Droping result for request %S: %s"
 180                           id rstr form)
 181       (condition-case cerr
 182           (with-current-buffer buffer
 183             (funcall cont form)
 184             (geiser-log--info "<%s>: processed" id))
 185         (error (geiser-log--error
 186                 "<%s>: continuation failed %S \n\t%s" id rstr cerr))))
 187     (geiser-con--connection-completed con req)))
 188
 189 (defun geiser-con--connection-add-request (c r)
 190   (geiser-log--info "REQUEST: <%s>: %s"
 191                     (geiser-con--request-id r)
 192                     (geiser-con--request-string r))
 193   (geiser-con--connection-activate c)
 194   (tq-enqueue (geiser-con--connection-tq c)
 195               (concat (geiser-con--request-string r) "\n")
 196               (geiser-con--connection-eot c)
 197               r
 198               'geiser-con--process-completed-request
 199               nil))
 200
 201 \f
 202 ;;; Message sending interface:
 203
 204 (defun geiser-con--send-string (con str cont &optional sbuf)
 205   (let ((req (geiser-con--make-request con str cont sbuf)))
 206     (geiser-con--connection-add-request con req)
 207     req))
 208
 209 (defvar geiser-connection-timeout 30000
 210   "Time limit, in msecs, blocking on synchronous evaluation requests")
 211
 212 (defun geiser-con--send-string/wait (con str cont &optional timeout sbuf)
 213   (save-current-buffer
 214     (let ((proc (and con (geiser-con--connection-process con))))
 215       (unless proc (error "Geiser connection not active"))
 216       (let* ((req (geiser-con--send-string con str cont sbuf))
 217              (id (geiser-con--request-id req))
 218              (timeout (/ (or timeout geiser-connection-timeout) 1000.0)))
 219         (with-timeout (timeout (geiser-con--request-deactivate req))
 220           (condition-case nil
 221               (while (and (geiser-con--connection-process con)
 222                           (not (geiser-con--connection-completed-p con id)))
 223                 (accept-process-output proc (/ timeout 10)))
 224             (error (geiser-con--request-deactivate req))))))))
 225
 226 \f
 227 (provide 'geiser-connection)