elisp/geiser-chicken.el

   1 ;; geiser-chicken.el -- chicken's implementation of the geiser protocols
   2
   3 ;; Copyright (C) 2014, 2015 Daniel Leslie
   4
   5 ;; Based on geiser-guile.el by Jose Antonio Ortego Ruize
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the Modified BSD License. You should
   9 ;; have received a copy of the license along with this program. If
  10 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
  11
  12 ;; Start date: Sun Mar 08, 2009 23:03
  13
  14
  15 (require 'geiser-connection)
  16 (require 'geiser-syntax)
  17 (require 'geiser-custom)
  18 (require 'geiser-base)
  19 (require 'geiser-eval)
  20 (require 'geiser-edit)
  21 (require 'geiser-log)
  22 (require 'geiser)
  23
  24 (require 'compile)
  25 (require 'info-look)
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (defconst geiser-chicken-builtin-keywords
  30   '("assume"
  31     "compiler-typecase"
  32     "cond-expand"
  33     "condition-case"
  34     "declare"
  35     "define-constant"
  36     "define-inline"
  37     "define-interface"
  38     "define-record"
  39     "define-specialization"
  40     "define-type"
  41     "dotimes"
  42     "ecase"
  43     "fluid-let"
  44     "foreign-lambda"
  45     "foreign-lambda*"
  46     "foreign-primitive"
  47     "foreign-safe-lambda"
  48     "foreign-safe-lambda*"
  49     "functor"
  50     "handle-exceptions"
  51     "let-location"
  52     "let-optionals"
  53     "let-optionals*"
  54     "letrec-values"
  55     "module"
  56     "regex-case"
  57     "select"
  58     "use"
  59     "with-input-from-pipe"))
  60
  61 \f
  62 ;;; Customization:
  63
  64 (defgroup geiser-chicken nil
  65   "Customization for Geiser's Chicken flavour."
  66   :group 'geiser)
  67
  68 (geiser-custom--defcustom geiser-chicken-prefix-delimiters
  69     '("^:" "^#")
  70     "Regex to match symbol prefix delimiters. Consider that it will be placed inside []."
  71   :type '(repeat string)
  72   :group 'geiser-chicken)
  73
  74 (geiser-custom--defcustom geiser-chicken-binary
  75   (cond ((eq system-type 'windows-nt) '("csi.exe" "-:c"))
  76         ((eq system-type 'darwin) "csi")
  77         (t "csi"))
  78   "Name to use to call the Chicken executable when starting a REPL."
  79   :type '(choice string (repeat string))
  80   :group 'geiser-chicken)
  81
  82 (geiser-custom--defcustom geiser-chicken-load-path nil
  83   "A list of paths to be added to Chicken's load path when it's
  84 started."
  85   :type '(repeat file)
  86   :group 'geiser-chicken)
  87
  88 (geiser-custom--defcustom geiser-chicken-compile-geiser-p t
  89   "Non-nil means that the Geiser runtime will be compiled on load."
  90   :type 'boolean
  91   :group 'geiser-chicken)
  92
  93 (geiser-custom--defcustom geiser-chicken-init-file "~/.chicken-geiser"
  94   "Initialization file with user code for the Chicken REPL.
  95 If all you want is to load ~/.csirc, set
  96 `geiser-chicken-load-init-file-p' instead."
  97   :type 'string
  98   :group 'geiser-chicken)
  99
 100 (geiser-custom--defcustom geiser-chicken-load-init-file-p nil
 101   "Whether to load ~/.chicken when starting Chicken.
 102 Note that, due to peculiarities in the way Chicken loads its init
 103 file, using `geiser-chicken-init-file' is not equivalent to setting
 104 this variable to t."
 105   :type 'boolean
 106   :group 'geiser-chicken)
 107
 108 (geiser-custom--defcustom geiser-chicken-extra-keywords nil
 109   "Extra keywords highlighted in Chicken scheme buffers."
 110   :type '(repeat string)
 111   :group 'geiser-chicken)
 112
 113 (geiser-custom--defcustom geiser-chicken-case-sensitive-p t
 114   "Non-nil means keyword highlighting is case-sensitive."
 115   :type 'boolean
 116   :group 'geiser-chicken)
 117
 118 \f
 119 ;;; REPL support:
 120
 121 (defun geiser-chicken--binary ()
 122   (if (listp geiser-chicken-binary)
 123       (car geiser-chicken-binary)
 124     geiser-chicken-binary))
 125
 126 (defun geiser-chicken--parameters ()
 127   "Return a list with all parameters needed to start Chicken.
 128 This function uses `geiser-chicken-init-file' if it exists."
 129   (let ((init-file (and (stringp geiser-chicken-init-file)
 130                         (expand-file-name geiser-chicken-init-file)))
 131         (n-flags (and (not geiser-chicken-load-init-file-p) '("-n"))))
 132   `(,@(and (listp geiser-chicken-binary) (cdr geiser-chicken-binary))
 133     ,@n-flags "-include-path" ,(expand-file-name "chicken/" geiser-scheme-dir)
 134     ,@(apply 'append (mapcar (lambda (p) (list "-include-path" p))
 135                              geiser-chicken-load-path))
 136     ,@(and init-file (file-readable-p init-file) (list init-file)))))
 137
 138 (defconst geiser-chicken--prompt-regexp "#[^;]*;[^:0-9]*:?[0-9]+> ")
 139
 140 \f
 141 ;;; Evaluation support:
 142
 143 (defun geiser-chicken--geiser-procedure (proc &rest args)
 144   (case proc
 145     ((eval compile)
 146      (let ((form (mapconcat 'identity (cdr args) " "))
 147            (module (if (car args) (concat "'" (car args)) "#f")))
 148        (format "(geiser-eval %s '%s)" module form)))
 149     ((load-file compile-file)
 150      (format "(geiser-load-file %s)" (car args)))
 151     ((no-values)
 152      "(geiser-no-values)")
 153     (t
 154      (let ((form (mapconcat 'identity args " ")))
 155        (format "(geiser-%s %s)" proc form)))))
 156
 157 (defconst geiser-chicken--module-re
 158   "( *module +\\(([^)]+)\\|[^ ]+\\)\\|( *define-library +\\(([^)]+)\\|[^ ]+\\)")
 159
 160 (defun geiser-chicken--get-module (&optional module)
 161   (cond ((null module)
 162          (save-excursion
 163            (geiser-syntax--pop-to-top)
 164            (if (or (re-search-backward geiser-chicken--module-re nil t)
 165                    (looking-at geiser-chicken--module-re)
 166                    (re-search-forward geiser-chicken--module-re nil t))
 167                (geiser-chicken--get-module (match-string-no-properties 1))
 168              :f)))
 169         ((listp module) module)
 170         ((stringp module)
 171          (condition-case nil
 172              (car (geiser-syntax--read-from-string module))
 173            (error :f)))
 174         (t :f)))
 175
 176 (defun geiser-chicken--module-cmd (module fmt &optional def)
 177   (when module
 178     (let* ((module (geiser-chicken--get-module module))
 179            (module (cond ((or (null module) (eq module :f)) def)
 180                          (t (format "%s" module)))))
 181       (and module (format fmt module)))))
 182
 183 (defun geiser-chicken--import-command (module)
 184   (geiser-chicken--module-cmd module "(use %s)"))
 185
 186 (defun geiser-chicken--enter-command (module)
 187   (geiser-chicken--module-cmd module ",m %s" module))
 188
 189 (defun geiser-chicken--exit-command () ",q")
 190
 191 (defun geiser-chicken--symbol-begin (module)
 192   (apply
 193    'max
 194    (cons
 195     (if module
 196         (max (save-excursion (beginning-of-line) (point))
 197              (save-excursion (skip-syntax-backward "^(>") (1- (point))))
 198       (save-excursion (skip-syntax-backward "^'-()>") (point)))
 199     (let ((distance-to-beginning-of-line (- (point) (line-beginning-position))))
 200       (mapcar
 201        (lambda (match-string)
 202          (save-excursion
 203            (skip-chars-backward match-string distance-to-beginning-of-line) (point)))
 204        geiser-chicken-prefix-delimiters)))))
 205
 206 \f
 207 ;;; Error display
 208
 209 (defun geiser-chicken--display-error (module key msg)
 210   (newline)
 211   (when (stringp msg)
 212     (save-excursion (insert msg))
 213     (geiser-edit--buttonize-files))
 214   (and (not key) msg (not (zerop (length msg)))))
 215
 216 \f
 217 ;;; Trying to ascertain whether a buffer is Chicken Scheme:
 218
 219 (defconst geiser-chicken--guess-re
 220   (regexp-opt (append '("csi" "chicken") geiser-chicken-builtin-keywords)))
 221
 222 (defun geiser-chicken--guess ()
 223   (save-excursion
 224     (goto-char (point-min))
 225     (re-search-forward geiser-chicken--guess-re nil t)))
 226
 227 (defun geiser-chicken--external-help (id module)
 228   "Loads chicken doc into a buffer"
 229   (browse-url (format "http://api.call-cc.org/cdoc?q=%s&query-name=Look+up" id)))
 230
 231 \f
 232 ;;; Keywords and syntax
 233
 234 (defun geiser-chicken--keywords ()
 235   (append
 236    (geiser-syntax--simple-keywords geiser-chicken-extra-keywords)
 237    (geiser-syntax--simple-keywords geiser-chicken-builtin-keywords)))
 238
 239 (geiser-syntax--scheme-indent
 240  (assume 1)
 241  (compiler-typecase 1)
 242  (cond-expand 0)
 243  (condition-case 1)
 244  (cut 1)
 245  (cute 1)
 246  (declare 0)
 247  (dotimes 1)
 248  (ecase 1)
 249  (fluid-let 1)
 250  (foreign-lambda 2)
 251  (foreign-lambda* 2)
 252  (foreign-primitive 2)
 253  (foreign-safe-lambda 2)
 254  (foreign-safe-lambda* 2)
 255  (functor 3)
 256  (handle-exceptions 2)
 257  (import 0)
 258  (let-location 1)
 259  (let-optionals 2)
 260  (let-optionals* 2)
 261  (letrec-values 1)
 262  (module 2)
 263  (regex-case 1)
 264  (select 1)
 265  (set! 1)
 266  (use 0)
 267  (with-input-from-pipe 1)
 268  (with-output-to-pipe 1))
 269
 270 \f
 271 ;;; REPL startup
 272
 273 (defconst geiser-chicken-minimum-version "4.8.0.0")
 274
 275 (defun geiser-chicken--version (binary)
 276   (shell-command-to-string
 277    (format "%s -e %s" binary
 278            (shell-quote-argument "(display (chicken-version))"))))
 279
 280 (defun connect-to-chicken ()
 281   "Start a Chicken REPL connected to a remote process."
 282   (interactive)
 283   (geiser-connect 'chicken))
 284
 285 (defun geiser-chicken--compile-or-load (force-load)
 286   (let ((target
 287          (expand-file-name "chicken/geiser/emacs.so" geiser-scheme-dir))
 288         (source
 289          (expand-file-name "chicken/geiser/emacs.scm" geiser-scheme-dir))
 290         (force-load (or force-load (eq system-type 'windows-nt)))
 291         (suppression-prefix
 292          "(define geiser-stdout (current-output-port))(current-output-port (make-output-port (lambda a #f) (lambda a #f)))")
 293         (suppression-postfix
 294          "(current-output-port geiser-stdout)"))
 295     (let ((load-sequence
 296            (cond
 297             (force-load
 298              (format "(load \"%s\")\n(import geiser)\n" source))
 299             ((file-exists-p target)
 300              (format "%s(load \"%s\")(import geiser)%s\n"
 301                      suppression-prefix target suppression-postfix))
 302             (t
 303              (format "%s(use utils)(compile-file \"%s\" options: '(\"-O3\" \"-s\") output-file: \"%s\" load: #t)(import geiser)%s\n"
 304                      suppression-prefix source target suppression-postfix)))))
 305       (geiser-eval--send/wait load-sequence))))
 306
 307 (defun geiser-chicken--startup (remote)
 308   (compilation-setup t)
 309   (geiser-chicken--compile-or-load (not geiser-chicken-compile-geiser-p)))
 310
 311 \f
 312 ;;; Implementation definition:
 313
 314 (define-geiser-implementation chicken
 315   (unsupported-procedures '(callers callees generic-methods))
 316   (binary geiser-chicken--binary)
 317   (arglist geiser-chicken--parameters)
 318   (version-command geiser-chicken--version)
 319   (minimum-version geiser-chicken-minimum-version)
 320   (repl-startup geiser-chicken--startup)
 321   (prompt-regexp geiser-chicken--prompt-regexp)
 322   (debugger-prompt-regexp nil)
 323   (enter-debugger nil)
 324   (marshall-procedure geiser-chicken--geiser-procedure)
 325   (find-module geiser-chicken--get-module)
 326   (enter-command geiser-chicken--enter-command)
 327   (exit-command geiser-chicken--exit-command)
 328   (import-command geiser-chicken--import-command)
 329   (find-symbol-begin geiser-chicken--symbol-begin)
 330   (display-error geiser-chicken--display-error)
 331   (external-help geiser-chicken--external-help)
 332   (check-buffer geiser-chicken--guess)
 333   (keywords geiser-chicken--keywords)
 334   (case-sensitive geiser-chicken-case-sensitive-p))
 335
 336 (geiser-impl--add-to-alist 'regexp "\\.scm$" 'chicken t)
 337 (geiser-impl--add-to-alist 'regexp "\\.release-info$" 'chicken t)
 338 (geiser-impl--add-to-alist 'regexp "\\.meta$" 'chicken t)
 339 (geiser-impl--add-to-alist 'regexp "\\.setup$" 'chicken t)
 340
 341 (provide 'geiser-chicken)