scheme/racket/geiser/user.rkt

   1 ;;; user.rkt -- global bindings visible to geiser users
   2
   3 ;; Copyright (C) 2010, 2011, 2012, 2013 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Wed Mar 31, 2010 22:24
  11
  12 #lang racket
  13
  14 (provide init-geiser-repl run-geiser-server start-geiser)
  15
  16 (require (for-syntax racket/base)
  17          mzlib/thread
  18          racket/tcp
  19          racket/help
  20          geiser
  21          geiser/autodoc
  22          geiser/images
  23          geiser/enter
  24          geiser/eval
  25          geiser/modules)
  26
  27 (define top-namespace (current-namespace))
  28 (define last-entered (make-parameter ""))
  29
  30 (define (do-enter mod name)
  31   (enter-module mod)
  32   (current-namespace (module->namespace mod))
  33   (last-entered name))
  34
  35 (define (submod-path mod)
  36   (and (list? mod)
  37        (eq? 'submod (car mod))
  38        (> (length mod) 1)
  39        (let ([parent (cadr mod)])
  40          (cond [(path-string? parent) `(submod (file ,parent) ,@(cddr mod))]
  41                [(symbol? parent) mod]
  42                [else #f]))))
  43
  44 (define (enter! mod stx)
  45   (cond [(not mod)
  46          (current-namespace top-namespace)
  47          (last-entered "")]
  48         [(symbol? mod) (do-enter mod (symbol->string mod))]
  49         [(path-string? mod) (do-enter `(file ,mod) mod)]
  50         [(and (list? mod)
  51               (= 2 (length mod))
  52               (eq? 'file (car mod))
  53               (path-string? (cadr mod))) (do-enter mod (cadr mod))]
  54         [(submod-path mod) => (lambda (m) (do-enter m m))]
  55         [else (raise-syntax-error #f "Invalid module path" stx mod)]))
  56
  57 (define orig-loader (current-load/use-compiled))
  58 (define geiser-loader (module-loader orig-loader))
  59
  60 (define (geiser-eval)
  61   (define geiser-main (module->namespace 'geiser))
  62   (define (eval-here form) (eval form geiser-main))
  63   (let* ([mod (read)]
  64          [lang (read)]
  65          [form (read)])
  66     (datum->syntax #f
  67                    (list 'quote
  68                          (cond [(equal? form '(unquote apply))
  69                                 (let* ([proc (eval-here (read))]
  70                                        [args (map eval-here (read))]
  71                                        [ev (lambda () (apply proc args))])
  72                                   (eval-in `(,ev) mod lang))]
  73                                [else ((geiser:eval lang) form mod)])))))
  74
  75 (define ((geiser-read prompt))
  76   (prompt)
  77   (flush-output (current-error-port))
  78   (flush-output (current-output-port))
  79   (let* ([in ((current-get-interaction-input-port))]
  80          [form ((current-read-interaction) (object-name in) in)])
  81     (syntax-case form ()
  82       [(uq cmd) (eq? 'unquote (syntax-e #'uq))
  83        (case (syntax-e #'cmd)
  84          [(start-geiser) (datum->syntax #f `(list 'port ,(start-geiser)))]
  85          [(enter) (enter! (read) #'cmd)]
  86          [(geiser-eval) (geiser-eval)]
  87          [(geiser-no-values) (datum->syntax #f (void))]
  88          [(add-to-load-path) (add-to-load-path (read))]
  89          [(set-image-cache) (image-cache (read))]
  90          [(help) (get-help (read) (read))]
  91          [(image-cache) (image-cache)]
  92          [(gcd) (current-directory)]
  93          [(cd) (current-directory (read))]
  94          [else form])]
  95       [_ form])))
  96
  97 (define geiser-prompt
  98   (lambda ()
  99     (let ([m (namespace->module-name (current-namespace) (last-entered))])
 100       (printf "racket@~a> " (regexp-replace* " " m "_")))))
 101
 102 (define (geiser-prompt-read prompt)
 103   (make-repl-reader (geiser-read prompt)))
 104
 105 (define (init-geiser-repl)
 106   (compile-enforce-module-constants #f)
 107   (current-load/use-compiled geiser-loader)
 108   (preload-help)
 109   (current-prompt-read (geiser-prompt-read geiser-prompt))
 110   (current-print maybe-print-image))
 111
 112 (define (run-geiser-repl in out enforce-module-constants)
 113   (parameterize [(compile-enforce-module-constants enforce-module-constants)
 114                  (current-input-port in)
 115                  (current-output-port out)
 116                  (current-error-port out)
 117                  (current-load/use-compiled geiser-loader)
 118                  (current-prompt-read (geiser-prompt-read geiser-prompt))
 119                  (current-print maybe-print-image)]
 120     (preload-help)
 121     (read-eval-print-loop)))
 122
 123 (define server-channel (make-channel))
 124
 125 (define (run-geiser-server port enforce-module-constants (hostname #f))
 126   (run-server port
 127               (lambda (in out)
 128                 (run-geiser-repl in out enforce-module-constants))
 129               #f
 130               void
 131               (lambda (p _ __)
 132                 (let ([lsner (tcp-listen p 4 #f hostname)])
 133                   (let-values ([(_ p __ ___) (tcp-addresses lsner #t)])
 134                     (channel-put server-channel p)
 135                     lsner)))))
 136
 137 (define (start-geiser (port 0) (hostname #f) (enforce-module-constants #f))
 138   (thread (lambda ()
 139             (run-geiser-server port enforce-module-constants hostname)))
 140   (channel-get server-channel))