configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([pcb], [1.99z])
   4 AC_CONFIG_SRCDIR([src/draw.c])
   5 AC_PREREQ([2.60])
   6 AM_INIT_AUTOMAKE([1.9])
   7 AC_GNU_SOURCE
   8 AM_CONFIG_HEADER([config.h])
   9
  10 ##########################################################################
  11 #
  12 # Try to figure out if we are building from git sources.
  13 # If we are then unless building of the documentation has
  14 # been disabled then just require the user have all the right
  15 # tools.  Users building from a tarball won't need latex, makeinfo,
  16 # etc. but if you're already downloading development sources, then
  17 # it is not unreasonable to require development tools.  What motivated
  18 # this is that using maintainer mode proved to cause regular confusion.
  19
  20 pcb_sources="tarball"
  21 AC_MSG_CHECKING([if you are building from a git checkout])
  22 pcb_git_version=no
  23 if test -f $srcdir/.gitignore ; then
  24         pcb_git_version=yes
  25         AC_MSG_RESULT([yes])
  26         pcb_sources="GIT"
  27 else
  28         AC_MSG_RESULT([no])
  29 fi
  30 AM_CONDITIONAL(GIT_VERSION, test x$pcb_git_version = xyes)
  31
  32 AC_MSG_CHECKING([if you are building from a anoncvs checkout])
  33 pcb_cvs_version=no
  34 if test -f $srcdir/CVS/Root ; then
  35         pcb_cvs_version=yes
  36         AC_MSG_RESULT([yes])
  37         pcb_sources="CVS"
  38 else
  39         AC_MSG_RESULT([no])
  40 fi
  41 AM_CONDITIONAL(CVS_VERSION, test x$pcb_cvs_version = xyes)
  42 AM_CONDITIONAL(GIT_OR_CVS_VERSION, test x$pcb_git_version = xyes -o x$pcb_cvs_version = xyes)
  43
  44
  45 ##########################################################################
  46 #
  47 # See if we are supposed to build the docs
  48 #
  49
  50 docs_yesno=yes
  51 AC_MSG_CHECKING([if the documentation should be built])
  52 AC_ARG_ENABLE([doc],
  53 [  --enable-doc            Build and install the documentation [[default=yes]]],
  54 [
  55 if test "X$enable_doc" = "Xno" ; then
  56         DOC=""
  57         AC_MSG_RESULT([no])
  58         docs_yesno=no
  59 else
  60         DOC=doc
  61         AC_MSG_RESULT([yes])
  62         docs_yesno=yes
  63 fi
  64 ],
  65 [
  66 DOC=doc
  67 AC_MSG_RESULT([yes])
  68 docs_yesno=yes
  69 ])
  70 AC_SUBST(DOC)
  71
  72
  73 AC_MSG_CHECKING([if maintainer mode is required])
  74 if test "$docs_yesno" = "yes" -a "$pcb_git_version" = "yes" ; then
  75         AC_MSG_RESULT([yes -- the documentation build is enabled and your sources are from git])
  76         enable_maintainer_mode=yes
  77 else
  78         AC_MSG_RESULT([no])
  79 fi
  80
  81 AM_MAINTAINER_MODE
  82
  83
  84 dnl determine host type
  85 AC_CANONICAL_HOST
  86 AC_MSG_CHECKING(for windows)
  87 PCB_PATH_DELIMETER=":"
  88 PCB_DIR_SEPARATOR_S="/"
  89 PCB_DIR_SEPARATOR_C='/'
  90 case $host in
  91         *-*-cygwin* )
  92                 CFLAGS="$CFLAGS ${CYGWIN_CFLAGS}"
  93                 CPPFLAGS="$CPPFLAGS ${CYGWIN_CPPFLAGS}"
  94                 ;;
  95
  96         *-*-mingw* )
  97                 WIN32=yes
  98                 CFLAGS="$CFLAGS ${MINGW_CFLAGS:--mms-bitfields -mwindows}"
  99                 CPPFLAGS="$CPPFLAGS ${MINGW_CPPFLAGS:--mms-bitfields -mwindows}"
 100                 ;;
 101
 102         * )
 103                 WIN32=no
 104                 ;;
 105 esac
 106
 107 AC_MSG_RESULT($WIN32)
 108 AC_SUBST(WIN32)
 109 AM_CONDITIONAL(WIN32, test x$WIN32 = xyes)
 110 if test "x$WIN32" = "xyes" ; then
 111         PCB_PATH_DELIMETER=";"
 112         PCB_DIR_SEPARATOR_S="\\\\"
 113         PCB_DIR_SEPARATOR_C='\\'
 114 fi
 115
 116 AC_DEFINE_UNQUOTED(PCB_DIR_SEPARATOR_C,'$PCB_DIR_SEPARATOR_C',[Directory separator char])
 117 AC_DEFINE_UNQUOTED(PCB_DIR_SEPARATOR_S,"$PCB_DIR_SEPARATOR_S",[Directory separator string])
 118 AC_DEFINE_UNQUOTED(PCB_PATH_DELIMETER,"$PCB_PATH_DELIMETER",[Search path separator string])
 119
 120
 121 dnl Checks for programs.
 122 AC_PROG_CC
 123
 124 if test "x$WIN32" = "xyes" ; then
 125         AC_CHECK_TOOL(WINDRES, windres, [no])
 126         if test "$WINDRES" = "no" ; then
 127                 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 128         fi
 129 fi
 130
 131 # i18n
 132 GETTEXT_PACKAGE=$PACKAGE
 133 AH_TEMPLATE([GETTEXT_PACKAGE], [Name of this program's gettext domain])
 134 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"])
 135 AC_SUBST(GETTEXT_PACKAGE)
 136
 137 AM_GNU_GETTEXT_VERSION([0.14])
 138 AM_GNU_GETTEXT
 139 IT_PROG_INTLTOOL([0.35.0])
 140
 141 AC_C_INLINE
 142 AC_PROG_CC_STDC
 143 AM_PROG_CC_C_O
 144 AC_PROG_CPP
 145 AC_PROG_AWK
 146 AC_PROG_MKDIR_P
 147
 148 AM_PROG_LEX
 149 AC_PATH_PROG(LEX_PATH, $LEX, [notfound])
 150 if test "$LEX_PATH" = "notfound" ; then
 151         AC_MSG_ERROR([Couldn't find a usable lex program.
 152 Please install flex which is available from
 153 ftp://ftp.gnu.org/pub/non-gnu/flex/
 154 ])
 155 fi
 156
 157
 158 AC_PROG_YACC
 159 AC_PATH_PROG(YACC_PATH, $YACC, [notfound])
 160 if test "$YACC_PATH" = "notfound" ; then
 161         AC_MSG_ERROR([Couldn't find a usable yacc program.
 162 Please install bison which is available from
 163 ftp://ftp.gnu.org/pub/gnu/bison/
 164 ])
 165 fi
 166
 167 AC_PROG_INSTALL
 168 AC_PROG_RANLIB
 169
 170 #
 171 # Used for building the icons
 172 #
 173 AC_PATH_PROG(XPMTOPPM, xpmtoppm, notfound)
 174 AC_PATH_PROG(PPMTOWINICON, ppmtowinicon, notfound)
 175 AC_PATH_PROG(CONVERT, convert, notfound)
 176
 177 ##########################################################################
 178 #
 179 #
 180 if test "X$docs_yesno" = "Xyes" -a "X$pcb_git_version" = "Xyes" ; then
 181    AC_PATH_PROG(MKINFO, makeinfo, no)
 182    if test "X$MKINFO" != "Xno"; then
 183       AC_MSG_CHECKING([for GNU makeinfo version >= 4.6])
 184       v=`$MKINFO --version | grep "GNU texinfo"`
 185       if test $? -ne 0; then
 186          AC_MSG_RESULT([non-GNU])
 187          MKINFO="no"
 188       fi
 189    fi
 190    if test "X$MKINFO" != "Xno"; then
 191       vmajor=`echo "$v" | sed 's/.* \([[0-9]]*\)\.\([[0-9]]*\)$/\1/'`
 192       vminor=`echo "$v" | sed 's/.* \([[0-9]]*\)\.\([[0-9]]*\)$/\2/'`
 193       AC_MSG_RESULT([$vmajor.$vminor])
 194       if test "$vmajor" -lt 4 \
 195               || (test "$vmajor" -eq 4 && test "$vminor" -lt 6); then
 196          MKINFO=no
 197       fi
 198    fi
 199    if test "X$MKINFO" = "Xno"; then
 200       AC_MSG_ERROR([You have requested a build
 201 of the documentation.  For this to work, you must have version 4.6 or newer of
 202 the GNU texinfo package.  You seem to have
 203
 204 $v
 205
 206 Please update to a newer version of texinfo or disable building of
 207 the documentation with --disable-doc
 208 ])
 209    fi
 210
 211    AC_PATH_PROG(TEXI2DVI, texi2dvi, no)
 212    if test "X$TEXI2DVI" = "Xno"; then
 213       AC_MSG_ERROR([You have requested a build
 214 of the documentation.  For this to work, you must have the texi2dvi program
 215 installed.  Alternatively, you can disable building the documentation with
 216 --disable-doc.])
 217    fi
 218
 219
 220         AC_PATH_PROG(PERL, perl, notfound)
 221         if test "X$PERL" = "Xnotfound"; then
 222                         AC_MSG_ERROR([You have requested a build
 223 of the documentation.  For this to work, you must have perl installed.
 224 Alternatively, you can disable building the documentation with
 225 --disable-doc.
 226 ])
 227         fi
 228
 229
 230    AC_PATH_PROG([KPSEWHICH], [kpsewhich], [no])
 231    if test "X$KPSEWHICH" = "Xno"; then
 232       AC_MSG_ERROR([You have requested a build
 233 of the documentation.  For this to work, you must have a functional install of
 234 TeX and LaTeX.  kpsewhich is part of TeX.
 235 Alternatively, you can disable building the documentation with
 236 --disable-doc.])
 237    fi
 238
 239    AC_MSG_CHECKING([If your TeX installation contains epsf.tex])
 240    f=`$KPSEWHICH epsf.tex`
 241    if test $? -eq 0 ; then
 242         AC_MSG_RESULT([yes ($f)])
 243    else
 244         AC_MSG_RESULT([no])
 245         AC_MSG_ERROR([You have requested a build
 246 of the documentation.  For this to work, you must have a functional install of
 247 TeX and LaTeX that includes epsf.tex.  On some linux distributions this is
 248 part of the texlive-generic-recommended package.
 249 Alternatively, you can disable building the documentation with
 250 --disable-doc.])
 251    fi
 252
 253 fi
 254
 255 ##########################################################################
 256 #
 257 #
 258
 259 # FIXME:  for now, only try to add -rdynamic if we're using gcc.  We really
 260 # need to figure out what the correct test is here.  In the mean time, this
 261 # should let things build with SunPRO again.
 262 if test "x$GCC" = "xyes"; then
 263 AC_MSG_CHECKING([If the compiler accepts -rdynamic])
 264 old_LDFLAGS="$LDFLAGS"
 265 LDFLAGS="$LDFLAGS -rdynamic"
 266 AC_LINK_IFELSE([int main(){}],
 267         [AC_MSG_RESULT([yes])],
 268         [LDFLAGS="$old_LDFLAGS"
 269         AC_MSG_RESULT([no])
 270         ])
 271 fi
 272
 273 # ------------- HID config -------------------
 274
 275 hid_guis=""
 276 hid_printers=""
 277 hid_exporters=""
 278 hid_always=""
 279
 280 for hid in `cd $srcdir/src/hid; echo *`; do
 281     F=$srcdir/src/hid/$hid/hid.conf
 282     if test -f $F
 283     then
 284     echo checking $F
 285         . $F
 286         case $type in
 287           gui ) hid_guis="$hid_guis $hid" ;;
 288           printer ) hid_printers="$hid_printers $hid" ;;
 289           export ) hid_exporters="$hid_exporters $hid" ;;
 290           always ) hid_always="$hid_always $hid" ;;
 291         esac
 292     fi
 293 done
 294
 295 AC_MSG_CHECKING([for which gui to use])
 296 AC_ARG_WITH([gui],
 297 [  --with-gui=            Specify the GUI to use: batch gtk lesstif [[default=gtk]]],
 298 [],
 299 [with_gui=gtk]
 300 )
 301 AC_MSG_RESULT([$with_gui])
 302 case " $hid_guis no none " in
 303      *\ $with_gui\ * ) HIDLIST="$with_gui" ;;
 304      * ) AC_MSG_ERROR([$with_gui is not a valid gui]) ;;
 305 esac
 306
 307 if test x"$with_gui" = x"none" -o x"$with_gui" = x"no"
 308 then
 309     HIDLIST=
 310 fi
 311
 312 AC_MSG_CHECKING([whether to enable toporouter])
 313 AC_ARG_ENABLE([toporouter],
 314  [AS_HELP_STRING([--enable-toporouter], [build toporouter [default=yes]]) ]
 315 )
 316 AS_CASE(["x$enable_toporouter"],[xyes | xno],,
 317  [enable_toporouter=yes
 318  ]
 319 )
 320 AC_MSG_RESULT([$enable_toporouter])
 321 AM_CONDITIONAL([WITH_TOPOROUTER], test $enable_toporouter != no)
 322
 323 AC_MSG_CHECKING([whether to enable toporouter output])
 324 AC_ARG_ENABLE([toporouter-output],
 325  [AS_HELP_STRING([--enable-toporouter-output], [enable toporouter graphical output [default=no]]) ]
 326 )
 327 AS_CASE(["z$enable_toporouter_output"],[zyes | zno],,
 328  [enable_toporouter_output=no]
 329 )
 330 AC_MSG_RESULT([$enable_toporouter_output])
 331 AS_CASE([$enable_toporouter_output],[yes],
 332  [
 333   topo_output_enabled=1
 334  ],
 335  [
 336   topo_output_enabled=0
 337  ]
 338 )
 339 AC_DEFINE_UNQUOTED([TOPO_OUTPUT_ENABLED], [$topo_output_enabled],
 340  [Define to 1 to enable toporouter graphical output]
 341 )
 342
 343 PKG_PROG_PKG_CONFIG()
 344
 345 if test "x$enable_toporouter_output" = "xyes"; then
 346    PKG_CHECK_MODULES(CAIRO, cairo,,
 347                      [AC_MSG_ERROR([Cannot find cairo, needed by the toporouter
 348 Please review the following errors:
 349 $CAIRO_PKG_ERRORS])]
 350    )
 351 fi
 352
 353 AC_MSG_CHECKING([for whether to use DBUS])
 354 AC_ARG_ENABLE([dbus],
 355 [  --enable-dbus           Enable DBUS IPC],
 356 [],[
 357         case " $with_gui " in
 358                 *\ gtk\ *)     enable_dbus=yes ;;
 359                 *\ lesstif\ *) enable_dbus=yes ;;
 360                 * )            enable_dbus=no ;;
 361         esac
 362 ])
 363
 364 AC_MSG_RESULT([$enable_dbus])
 365 AM_CONDITIONAL(WITH_DBUS, test x$enable_dbus = xyes)
 366
 367 if test "x$enable_dbus" = "xyes"; then
 368         case " $with_gui " in
 369                 *\ gtk\ *) ;;
 370                 *\ lesstif\ *) ;;
 371                 * ) AC_MSG_ERROR([DBUS enabled but only works with a mainloop capable GUI HID.
 372 Either do not use --enable-dbus or enable the gtk or lesstif GUI HID.])
 373         esac
 374
 375         PKG_CHECK_MODULES(DBUS, dbus-1 >= 0.61,
 376                 [saved_LIBS="$LIBS"
 377                  LIBS="$LIBS $DBUS_LIBS"
 378                  AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 379                  LIBS="$saved_LIBS" ],
 380                 [AC_MSG_ERROR([Cannot find dbus-1 >= 0.61, install it and rerun ./configure
 381 Please review the following errors:
 382 $DBUS_PKG_ERRORS])]
 383         )
 384         DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 385
 386         AC_DEFINE([HAVE_DBUS], 1,
 387                 [Define to 1 if DBUS IPC is to be compiled in])
 388
 389 fi
 390
 391 AC_MSG_CHECKING([for which printer to use])
 392 AC_ARG_WITH([printer],
 393 [  --with-printer=        Specify the printer: lpr [[default=lpr]]],
 394 [],[with_printer=lpr])
 395 AC_MSG_RESULT([$with_printer])
 396 case " $hid_printers " in
 397      *\ $with_printer\ * )
 398          HIDLIST="$HIDLIST $with_printer"
 399          ;;
 400      * ) AC_MSG_ERROR([$with_printer is not a valid printer]) ;;
 401 esac
 402
 403 AC_MSG_CHECKING([for which exporters to use])
 404 AC_ARG_WITH([exporters],
 405 [  --with-exporters=       Enable export devices: bom gerber gcode nelma png ps [[default=bom gerber gcode nelma png ps]]],
 406 [],[with_exporters=$hid_exporters])
 407 AC_MSG_RESULT([$with_exporters])
 408 for e in `echo $with_exporters | sed 's/,/ /g'`; do
 409     case " $hid_exporters " in
 410       *\ $e\ * )
 411          HIDLIST="$HIDLIST $e"
 412          ;;
 413       * ) AC_MSG_ERROR([$e is not a valid exporter]) ;;
 414     esac
 415 done
 416
 417 if test "X$enable_jpeg" = "Xno" -a "X$enable_gif" = "Xno" -a "X$enable_png" = "Xno" ; then
 418         case " ${HIDLIST} " in
 419                 *\ png\ *)
 420                         AC_MSG_ERROR([you have requested the png HID but turned off all output
 421 formats!  If you do not want gif/jpeg/png output, use --with-exporters to list
 422 which exporters you want and do not list png there.])
 423                         ;;
 424
 425                 *)
 426                         ;;
 427         esac
 428 fi
 429
 430 for hid in $HIDLIST; do
 431     F=$srcdir/src/hid/$hid/hid.conf
 432     if test -f $F ; then
 433         echo checking $hid depedencies
 434         deps=
 435         . $F
 436         for dep in $deps; do
 437             if test "X`echo $HIDLIST | grep $dep`" = "X"; then
 438                 AC_MSG_ERROR([you have requested the $hid HID but not the $dep HID, which it depends on])
 439             fi
 440         done
 441    fi
 442 done
 443
 444 for e in $HIDLIST; do
 445     HIDLIBS="$HIDLIBS lib$e.a"
 446 done
 447
 448 AC_SUBST(HIDLIST)
 449 AC_SUBST(HIDLIBS)
 450
 451 # ------------- end HID config -------------------
 452
 453 ######################################################################
 454 #
 455 # desktop integration
 456 #
 457
 458 AC_PATH_PROG(SETENV, env, [])
 459 AC_PATH_PROG(GTK_UPDATE_ICON_CACHE_BIN, gtk-update-icon-path, [true])
 460
 461 # Change default location for XDG files (MIME and Icons)
 462 AC_ARG_WITH(xdgdatadir, [  --with-xdgdatadir=path  Change where the theme icons
 463 and mime registrations are installed [[DATADIR]]], [opt_xdgdatadir=$withval])
 464
 465 # Change default location for KDE data files (KDE MIME registrations)
 466 AC_ARG_WITH(kdedatadir, [  --with-kdedatadir=path  Change where the KDE mime reg
 467 istrations are installed [[DATADIR]]], [opt_kdedatadir=$withval])
 468
 469 if test x$opt_xdgdatadir = x; then
 470         # path was not specified with --with-xdgdatadir
 471         XDGDATADIR='${datadir}'
 472 else
 473         # path WAS specified with --with-xdgdatadir
 474         XDGDATADIR="$opt_xdgdatadir"
 475 fi
 476 AC_SUBST(XDGDATADIR)
 477
 478 if test x$opt_kdedatadir = x; then
 479         # path was not specified with --with-kdedatadir
 480         KDEDATADIR='${datadir}'
 481 else
 482         # path WAS specified with --with-kdedatadir
 483         KDEDATADIR="$opt_kdedatadir"
 484 fi
 485 AC_SUBST(KDEDATADIR)
 486
 487 AC_ARG_ENABLE(update-desktop-database,
 488         AC_HELP_STRING([--disable-update-desktop-database],
 489         [do not update desktop database after installation]),,
 490         enable_update_desktop_database=yes)
 491
 492 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOP_DATABASE, test x$enable_update_desktop_database = xyes)
 493
 494 if test x$enable_update_desktop_database = xyes ; then
 495         AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, [update-desktop-database], no)
 496         if test $UPDATE_DESKTOP_DATABASE = no; then
 497         AC_MSG_ERROR([Cannot find update-desktop-database, make sure it is installed and in your PATH, or configure with --disable-update-desktop-database])
 498         fi
 499 fi
 500
 501 AC_ARG_ENABLE(update-mime-database,
 502         AC_HELP_STRING([--disable-update-mime-database],
 503         [do not update mime database after installation]),,
 504         enable_update_mime_database=yes)
 505
 506 AM_CONDITIONAL(ENABLE_UPDATE_MIME_DATABASE, test x$enable_update_mime_database = xyes)
 507
 508 if test x$enable_update_mime_database = xyes ; then
 509         AC_PATH_PROG(UPDATE_MIME_DATABASE, [update-mime-database], no)
 510         if test $UPDATE_MIME_DATABASE = no; then
 511         AC_MSG_ERROR([Cannot find update-mime-database, make sure it is installed and in your PATH, or configure with --disable-update-mime-database])
 512         fi
 513 fi
 514
 515 #
 516 ######################################################################
 517
 518 AC_PATH_PROGS(M4, gm4 m4, [none])
 519 if test "X$M4" = "Xnone" ; then
 520         AC_MSG_ERROR([Did not find a m4 executible.  You need to make sure
 521         that m4 is installed on your system and that m4 is in your path])
 522 fi
 523 AC_MSG_CHECKING([if $M4 has the division involving negative numbers bug])
 524 pcb_m4_r=`echo "eval(-2/2)" | $M4`
 525 if test "$pcb_m4_r" != "-1" ; then
 526         AC_MSG_RESULT([yes])
 527         AC_MSG_ERROR([It appears that $M4 has a bug involving division
 528 with negative numbers.  In particular it just returned the result that
 529 -2/2 = $pcb_m4_r instead of -1.  This is a known bug in GNU m4-1.4.9.  Please
 530 install a non-broken m4.])
 531 else
 532         AC_MSG_RESULT([no])
 533 fi
 534
 535
 536 AC_PATH_PROGS(WISH, wish wish83 wish8.3 wish80 wish8.0 cygwish83 cygwish80,[none])
 537 if test "X$WISH" = "Xnone" ; then
 538         AC_MSG_ERROR([Did not find the wish executible.  You need to make sure
 539         that tcl is installed on your system and that wish is in your path])
 540 fi
 541
 542 AC_DEFINE_UNQUOTED(M4,$M4,[m4 executible])
 543 GNUM4=$M4
 544 AC_SUBST(GNUM4)
 545 AC_DEFINE_UNQUOTED(GNUM4,"$M4",[m4 program used by pcb])
 546
 547 AC_PATH_PROG(LATEX, latex, notfound)
 548 AM_CONDITIONAL(MISSING_LATEX, test x$LATEX = xnotfound)
 549
 550 AC_PATH_PROG(PDFLATEX, pdflatex, notfound)
 551 AM_CONDITIONAL(MISSING_PDFLATEX, test x$PDFLATEX = xnotfound)
 552
 553 AC_PATH_PROG(DVIPS, dvips, notfound)
 554 AM_CONDITIONAL(MISSING_DVIPS, test x$DVIPS = xnotfound)
 555
 556 AC_PATH_PROG(TEXI2DVI, texi2dvi, notfound)
 557 AM_CONDITIONAL(MISSING_TEXI2DVI, test x$TEXI2DVI = xnotfound)
 558
 559 AC_PATH_PROG(PS2PDF, ps2pdf, notfound)
 560 AM_CONDITIONAL(MISSING_PS2PDF, test x$PS2PDF = xnotfound)
 561
 562 # used to build some of the getting started guide
 563 AC_PATH_PROG(GSCHEM, gschem, notfound)
 564 AM_CONDITIONAL(MISSING_GSCHEM, test x$GSCHEM = xnotfound)
 565
 566 if test "X$docs_yesno" = "Xyes" -a "X$pcb_git_version" = "Xyes" ; then
 567         if test "$LATEX" = "notfound" -o "$PDFLATEX" = "notfound" -o "$DVIPS" = "notfound" -o "$TEXI2DVI" = "notfound" -o "$PS2PDF" = "notfound" ; then
 568                 AC_MSG_ERROR([It appears that you are building from a source tree obtained
 569 via git but you do not have the required tools installed to build the documentation.  Here
 570 is a list of tools and the detected values:
 571 LATEX:  $LATEX
 572 PDFLATEX:  $PDFLATEX
 573 DVIPS:     $DVIPS
 574 TEXI2DVI:  $TEXI2DVI
 575 PS2PDF:    $PS2PDF
 576 GSCHEM:    $GSCHEM
 577
 578 Either make sure these tools are installed or disable building and installing the documentation
 579 by using the --disable-doc configure option.
 580 ])
 581         fi
 582 fi
 583
 584 ############################################################################
 585 #
 586 # These checks are for tools used by the testsuite.  It will not be fatal
 587 # if these are missing because this is primarily for developer use.  It is
 588 # possible that we might add some --enable flag in the future that forces
 589 # full tools for development work.
 590
 591 # Check for ImageMagick tools used by the testsuite
 592 AC_PATH_PROG(IM_ANIMATE, animate, notfound)
 593 AC_PATH_PROG(IM_COMPARE, compare, notfound)
 594 AC_PATH_PROG(IM_COMPOSITE, composite, notfound)
 595 AC_PATH_PROG(IM_CONVERT, convert, notfound)
 596 AC_PATH_PROG(IM_DISPLAY, display, notfound)
 597 AC_PATH_PROG(IM_MONTAGE, montage, notfound)
 598 missing_magick=""
 599 test "${IM_ANIMATE}" != "notfound" || missing_magick="${missing_magick} animate"
 600 test "${IM_COMPARE}" != "notfound" || missing_magick="${missing_magick} compare"
 601 test "${IM_COMPOSITE}" != "notfound" || missing_magick="${missing_magick} composite"
 602 test "${IM_CONVERT}" != "notfound" || missing_magick="${missing_magick} convert"
 603 test "${IM_DISPLAY}" != "notfound" || missing_magick="${missing_magick} display"
 604 test "${IM_MONTAGE}" != "notfound" || missing_magick="${missing_magick} montage"
 605
 606 AC_MSG_CHECKING([if all ImageMagick tools needed for the testsuite were found])
 607 if test "X${missing_magick}" != "X" ; then
 608     AC_MSG_RESULT([no.  The testsuite will be disabled because the following
 609 tools from the ImageMagick suite were not found:
 610 ${missing_magick}
 611 No loss in pcb functionality should be experienced, you just will not
 612 be able to run the full regression testsuite.
 613 ])
 614     have_magick=no
 615 else
 616     AC_MSG_RESULT([yes])
 617     have_magick=yes
 618 fi
 619
 620 have_test_tools=yes
 621
 622 test $have_magick = yes || have_test_tools=no
 623
 624 # the RS274-X export HID is partially checked by looking at the result with
 625 # gerbv
 626 AC_PATH_PROG(GERBV, gerbv, notfound)
 627 test $GERBV != notfound || have_test_tools=no
 628
 629
 630 AM_CONDITIONAL(HAVE_TEST_TOOLS, test x$have_test_tools = xyes)
 631 AC_MSG_CHECKING([if all the requried testsuite tools were found])
 632 if test x$have_test_tools = xyes ; then
 633         AC_MSG_RESULT([yes])
 634 else
 635         AC_MSG_RESULT([no -- the testsuite will be disabled])
 636 fi
 637
 638
 639 #
 640 ############################################################################
 641
 642
 643 dnl Checks for libraries.
 644 AC_CHECK_LIB(m, sqrt)
 645 AC_CHECK_LIB(dl, dlopen)
 646 AC_CHECK_LIB(xnet, gethostbyname)
 647 AC_CHECK_LIB(fl, yywrap)
 648 AC_CHECK_FUNCS(strerror)
 649 AC_CHECK_FUNCS(regcomp re_comp)
 650 AC_CHECK_FUNCS(logf expf rint)
 651 AC_CHECK_FUNCS(vsnprintf)
 652 AC_CHECK_FUNCS(getpwuid gethostname getcwd)
 653 AC_CHECK_FUNCS(random)
 654 AC_CHECK_FUNCS(stat)
 655
 656 AC_CHECK_FUNCS(mkdtemp)
 657
 658 # normally used for all file i/o
 659 AC_CHECK_FUNCS(popen)
 660
 661 # for lrealpath.c
 662 AC_CHECK_FUNCS(realpath canonicalize_file_name)
 663 libiberty_NEED_DECLARATION(canonicalize_file_name)
 664
 665 AC_HEADER_STDC
 666 AC_CHECK_HEADERS(limits.h locale.h string.h sys/types.h regex.h pwd.h)
 667 AC_CHECK_HEADERS(sys/socket.h netinet/in.h netdb.h sys/param.h sys/times.h sys/wait.h)
 668 AC_CHECK_HEADERS(dlfcn.h)
 669
 670 if test "x${WIN32}" = "xyes" ; then
 671         AC_CHECK_HEADERS(windows.h)
 672 fi
 673 # Search for glib
 674 PKG_CHECK_MODULES(GLIB, glib-2.0, ,
 675                 [AC_MSG_RESULT([Note: cannot find glib-2.0.
 676 You may want to review the following errors:
 677 $GLIB_PKG_ERRORS])]
 678 )
 679
 680 for e in $HIDLIST; do
 681     case $e in
 682       lesstif )
 683         AC_PATH_XTRA
 684         CPPFLAGS="$CFLAGS $X_CFLAGS"
 685         AC_CHECK_LIB(X11, XOpenDisplay, , , $X_LIBS)
 686         AC_CHECK_LIB(ICE, main, , , $X_LIBS)
 687         AC_CHECK_LIB(SM, main, , , $X_LIBS)
 688         AC_CHECK_LIB(Xext, main, , , $X_LIBS)
 689         AC_CHECK_LIB(Xt, XtOpenDisplay, , , $X_LIBS)
 690         AC_CHECK_LIB(Xmu, main, , , $X_LIBS)
 691         AC_CHECK_LIB(Xpm, main, , , $X_LIBS)
 692         AC_CHECK_LIB(Xm, XmCreateMainWindow, , , $X_LIBS)
 693         case $ac_cv_lib_Xm_XmCreateMainWindow in
 694           no )
 695             AC_MSG_ERROR([You don't seem to have the Lesstif development environment installed.])
 696             ;;
 697           * ) ;;
 698         esac
 699         AC_CHECK_HEADERS(Xm/Xm.h)
 700         case $ac_cv_header_Xm_Xm_h in
 701           no )
 702             AC_MSG_ERROR([You don't seem to have the Lesstif development environment installed.])
 703             ;;
 704           * ) ;;
 705         esac
 706         ;;
 707
 708       gtk )
 709         # Check for pkg-config
 710         AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 711         if test "$PKG_CONFIG" = "no"; then
 712                 AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed and in your PATH])
 713         fi
 714
 715         PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4.0, ,
 716                 [AC_MSG_ERROR([Cannot find gtk+ >= 2.4.0, install it and rerun ./configure
 717 Please review the following errors:
 718 $GTK_PKG_ERRORS])]
 719         )
 720         GTK_VERSION=`$PKG_CONFIG gtk+-2.0 --modversion`
 721
 722         # if we are building for gtk >= 2.8.0, we can use gdk_display_warp_pointer()
 723         # otherwise we need XWarpPointer and we'll pull in the required headers with
 724         # gdk/gdkx.h and we'll need to link with X11
 725         if ! $PKG_CONFIG gtk+-2.0 --atleast-version=2.8.0 ; then
 726                 CPPFLAGS="$CFLAGS $GTK_CFLAGS"
 727                 AC_CHECK_HEADERS([gdk/gdkx.h])
 728         fi
 729
 730         GLIB_VERSION=`$PKG_CONFIG glib-2.0 --modversion`
 731         ;;
 732
 733       gcode|nelma|png )
 734         # Check for gdlib-config for gd (www.boutell.com/gd)
 735         AC_PATH_PROG(GDLIB_CONFIG, gdlib-config, no)
 736         if test "$GDLIB_CONFIG" = "no"; then
 737                 AC_MSG_RESULT([Cannot find gdlib-config.
 738 Make sure it is installed and in your PATH.
 739 gdlib-config is part of the GD library available from www.boutell.com/gd.
 740 This is needed for the png HID.  I will look for libgd anyway and maybe
 741 you will get lucky.
 742 ])
 743                 if test "$WIN32" != "yes" ; then
 744                         AC_CHECK_LIB(gd,main,,
 745                         AC_MSG_ERROR([[You have requested gcode, nelma, or png HIDs  but -lgd could not be found]]))
 746                 else
 747                         AC_CHECK_LIB(bgd,main,,
 748                         AC_MSG_ERROR([[You have requested gcode, nelma, or png HIDs  but -lbgd could not be found]]))
 749                 fi
 750         else
 751                 if test "$WIN32" = "yes" ; then
 752                         GD=bgd
 753                 else
 754                         GD=gd
 755                 fi
 756                 AC_MSG_CHECKING([for libgd cflags])
 757                 GD_CFLAGS="`$GDLIB_CONFIG --cflags`"
 758                 AC_MSG_RESULT([$GD_CFLAGS])
 759                 AC_MSG_CHECKING([for libgd libs])
 760                 GD_LIBS="`$GDLIB_CONFIG --ldflags` `$GDLIB_CONFIG --libs` -l${GD}"
 761                 AC_MSG_RESULT([$GD_LIBS])
 762         fi
 763
 764         # since some linux systems evidently install gdlib-config but fail to
 765         # install the headers (nice), check for the header too and fail if it
 766         # is not there.
 767         CFLAGS="$CFLAGS $GD_CFLAGS"
 768         CPPFLAGS="$CPPFLAGS $GD_CFLAGS"
 769         AC_CHECK_HEADERS(gd.h)
 770         case $ac_cv_header_gd_h in
 771              no )
 772                 AC_MSG_ERROR([
 773 You evidentally do not have a complete installation of the GD library available from www.boutell.com/gd.
 774 This is needed for the nelma and/or png HID.
 775 ])
 776                 ;;
 777              * ) ;;
 778         esac
 779
 780         # Some versions of gd (prior to the expiration of the
 781         # patent related to gif compression) do not support
 782         # gif output.  Check for that here.
 783         save_LIBS="$LIBS"
 784         LIBS="$save_LIBS $GD_LIBS $X_LIBS"
 785
 786         AC_MSG_CHECKING([if GIF output from the png HID is desired])
 787         AC_ARG_ENABLE([gif],
 788                 [  --disable-gif           Disable support for gif output when the png HID is used [[default=include gif support]]],
 789                 [
 790                 if test "X$enable_gif" != "Xno" ; then
 791                         AC_MSG_RESULT([yes])
 792                         with_gif=yes
 793                 else
 794                         AC_MSG_RESULT([no])
 795                         with_gif=no
 796                 fi
 797                 ],
 798                 [
 799                 AC_MSG_RESULT([yes])
 800                 with_gif=yes
 801                 ])
 802         if test "X$with_gif" = "Xyes" ; then
 803                 AC_CHECK_FUNCS(gdImageGif)
 804                 if test "$ac_cv_func_gdImageGif" != "yes"; then
 805                         AC_MSG_ERROR([Your gd installation does not appear to include gif support.
 806 You may need to update your installation of gd or disable
 807 gif export with --disable-gif])
 808                 fi
 809         fi
 810
 811         AC_MSG_CHECKING([if JPEG output from the png HID is desired])
 812         AC_ARG_ENABLE([jpeg],
 813                 [  --disable-jpeg          Disable support for JPEG output when the png HID is used [[default=include JPEG support]]],
 814                 [
 815                 if test "X$enable_jpeg" != "Xno" ; then
 816                         AC_MSG_RESULT([yes])
 817                         with_jpeg=yes
 818                 else
 819                         AC_MSG_RESULT([no])
 820                         with_jpeg=no
 821                 fi
 822                 ],
 823                 [
 824                 AC_MSG_RESULT([yes])
 825                 with_jpeg=yes
 826                 ])
 827         if test "X$with_jpeg" = "Xyes" ; then
 828                 AC_CHECK_FUNCS(gdImageJpeg)
 829                 if test "$ac_cv_func_gdImageJpeg" != "yes"; then
 830                         AC_MSG_ERROR([Your gd installation does not appear to include JPEG support.
 831 You may need to update your installation of gd or disable
 832 JPEG export with --disable-jpeg])
 833                 fi
 834         fi
 835
 836
 837         AC_MSG_CHECKING([if PNG output from the png HID is desired])
 838         AC_ARG_ENABLE([png],
 839                 [  --disable-png           Disable support for PNG output when the png HID is used [[default=include PNG support]]],
 840                 [
 841                 if test "X$enable_png" != "Xno" ; then
 842                         AC_MSG_RESULT([yes])
 843                         with_png=yes
 844                 else
 845                         AC_MSG_RESULT([no])
 846                         with_png=no
 847                 fi
 848                 ],
 849                 [
 850                 AC_MSG_RESULT([yes])
 851                 with_png=yes
 852                 ])
 853         if test "X$with_png" = "Xyes" ; then
 854                 AC_CHECK_FUNCS(gdImagePng)
 855                 if test "$ac_cv_func_gdImagePng" != "yes"; then
 856                         AC_MSG_ERROR([Your gd installation does not appear to include PNG support.
 857 You may need to update your installation of gd or disable
 858 PNG export with --disable-png])
 859                 fi
 860         fi
 861         LIBS="$save_LIBS"
 862         ;;
 863
 864     esac
 865 done
 866
 867
 868 AM_CONDITIONAL(PNG, test x$with_png = xyes)
 869 AM_CONDITIONAL(GIF, test x$with_gif = xyes)
 870
 871 # ------------- check if png previews should be built for pcblib-newlib
 872 AC_MSG_CHECKING([if the m4lib to newlib export should create png previews])
 873 AC_ARG_ENABLE(
 874         [m4lib-png],
 875         [  --enable-m4lib-png      Enable creating png previews for the m4 library],
 876         [],[enable_m4lib_png=no])
 877 AC_MSG_RESULT([$enable_m4lib_png])
 878 AM_CONDITIONAL(PNG_PREVIEW, test x$enable_m4lib_png = xyes)
 879
 880
 881 # Run away.... more ugly stuff here.  By default we don't actually build
 882 # pcblib-newlib from pcblib unless we are building from cvs or git sources.
 883 # The reason is it takes a while and requires the png HID.  The problem is,
 884 # what if someone wants to use --enable-m4lib-png but the tarball was built
 885 # without the previews.  Or, what if someone does not want the PNG previews
 886 # but the person building the tarball included them.  Ugh!  So what the following
 887 # code attempts to do is detect that mismatch situation.  Note that we only
 888 # want to kick this code in when *not* building from git or cvs sources.
 889 build_pcblib_newlib=no
 890 if test "$pcb_sources" = "tarball" ; then
 891         AC_MSG_CHECKING([If pcblib-newlib was built with png previews])
 892         stamp=$srcdir/lib/pcblib-newlib.stamp
 893         if test ! -f ${stamp} ; then
 894                 AC_MSG_RESULT([unknown, missing ${stamp}])
 895                 build_pcblib_newlib=yes
 896         else
 897                 if test "`cat ${stamp}`" = "png-preview=yes" ; then
 898                         AC_MSG_RESULT([yes])
 899                         # lib exists and built with preview.
 900                         # if we don't want the preview, than rebuild
 901                         if test x$enable_m4lib_png != xyes ; then
 902                                 build_pcblib_newlib=yes
 903                         fi
 904                 else
 905                         AC_MSG_RESULT([no])
 906                         # lib exists and built without preview.
 907                         # if we want the preview, than rebuild
 908                         if test x$enable_m4lib_png = xyes ; then
 909                                 build_pcblib_newlib=yes
 910                         fi
 911                 fi
 912         fi
 913 else
 914         build_pcblib_newlib=yes
 915 fi
 916 AC_MSG_CHECKING([If pcblib-newlib needs to be rebuilt])
 917 AC_MSG_RESULT([$build_pcblib_newlib])
 918 AM_CONDITIONAL(BUILD_PCBLIB_NEWLIB, test x$build_pcblib_newlib = xyes)
 919
 920 if test "X$cross_compiling" = "Xyes" ; then
 921         # we are cross compiling so we will need a build host binary for pcb
 922         AC_PATH_PROG(PCB, [pcb], [notfound])
 923 else
 924         PCB="\${top_builddir}/src/pcb"
 925 fi
 926 AC_SUBST(PCB)
 927
 928 # now make see how essential it was that we have a pcb executable for the build
 929 # host
 930 if test "X$pcb_git_version" = "Xyes" ; then
 931         if test "X$docs_yesno" = "Xyes" -o "X$enable_m4lib_png" = "Xyes" ; then
 932                 if test "$PCB" = "notfound" ; then
 933                         AC_MSG_ERROR([You have selected a build with m4lib png
 934 previews enabled and/or with building the documentation enabled but you also
 935 appear to be cross-compiling.  For this to work, you must have a pcb installed that
 936 can run on this machine (the build machine) because it is needed for generating
 937 library footprint png previews as well as some of the figures in the documentation.
 938 If you wish to skip building the documentation and the footprint previews then add
 939 --disable-doc --disable-m4lib-png
 940 This will allow your cross build to work.])
 941                 fi
 942         fi
 943 fi
 944
 945 # ------------- Xrender -------------------
 946 have_xrender=no
 947 AC_CHECK_LIB(Xrender,XRenderQueryExtension,have_xrender=yes,have_xrender=no,$X_LIBS)
 948
 949 AC_ARG_ENABLE([xrender],
 950 [  --disable-xrender       Compile and link with Xrender [default=yes]])
 951 case "$have_xrender:$enable_xrender" in
 952    no:* ) ;;
 953    *:no ) ;;
 954    * )
 955      X_LIBS="-lXrender $X_LIBS"
 956      AC_DEFINE([HAVE_XRENDER], 1,
 957                 [Define to 1 if Xrender is available])
 958      ;;
 959 esac
 960
 961 # ------------- dmalloc -------------------
 962 dnl dmalloc checks
 963 with_dmalloc=no
 964 AC_MSG_CHECKING([if dmalloc debugging should be enabled])
 965 AC_ARG_ENABLE([dmalloc],
 966 [  --enable-dmalloc        Compile and link with dmalloc for malloc debugging [default=no]],
 967 [
 968 if test "X$enable_dmalloc" != "Xno" ; then
 969         AC_MSG_RESULT([yes])
 970         AC_CHECK_HEADER(dmalloc.h,,
 971                 AC_MSG_ERROR([You have requested dmalloc debugging but dmalloc.h could not be found]))
 972         AC_CHECK_LIB(dmalloc,main,,
 973                 AC_MSG_ERROR([You have requested dmalloc debugging but -ldmalloc could not be found]))
 974         DMALLOC_LIBS="-ldmalloc"
 975         with_dmalloc=yes
 976 else
 977         AC_MSG_RESULT([no])
 978         DMALLOC_LIBS=""
 979 fi
 980 ],
 981 [
 982         AC_MSG_RESULT([no])
 983         DMALLOC_LIBS=""
 984 ])
 985
 986 # ------------- ElectricFence -------------------
 987 dnl ElectricFence checks
 988 with_efence=no
 989 AC_MSG_CHECKING([if ElectricFence debugging should be enabled])
 990 AC_ARG_ENABLE([efence],
 991 [  --enable-efence         Link with ElectricFence for malloc debugging [default=no]],
 992 [
 993 if test "X$enable_efence" != "Xno" ; then
 994         AC_MSG_RESULT([yes])
 995         AC_CHECK_LIB(efence,main,,
 996                 AC_MSG_ERROR([You have requested ElectricFence debugging but -lefence could not be found]))
 997         with_efence=yes
 998 else
 999         AC_MSG_RESULT([no])
1000 fi
1001 ],
1002 [
1003 AC_MSG_RESULT([no])
1004 ])
1005
1006 # ------------- Enable Debug code -------------------
1007 AC_MSG_CHECKING([for whether to enable debugging code])
1008 AC_ARG_ENABLE([debug],
1009 [  --enable-debug          Enable debugging code],
1010 [],[enable_debug=no])
1011
1012 AC_MSG_RESULT([$enable_debug])
1013 AM_CONDITIONAL(DEBUG_BUILD, test x$enable_debug = xyes)
1014
1015
1016 # ------------- Complete set of CFLAGS and LIBS -------------------
1017
1018 CFLAGS="$CFLAGS $X_CFLAGS $DBUS_CFLAGS $GLIB_CFLAGS $GTK_CFLAGS $CAIRO_CFLAGS"
1019 LIBS="$LIBS $XM_LIBS $DBUS_LIBS $X_LIBS $GLIB_LIBS $GTK_LIBS $DMALLOC_LIBS $GD_LIBS $INTLLIBS $CAIRO_LIBS"
1020
1021
1022 # if we have gcc then add -Wall
1023 if test "x$GCC" = "xyes"; then
1024         # see about adding some extra checks if the compiler takes them
1025         for flag in -Wall -Wdeclaration-after-statement ; do
1026                 case " ${CFLAGS} " in
1027                         *\ ${flag}\ *)
1028                                 # flag is already present
1029                                 ;;
1030                         *)
1031                                 AC_MSG_CHECKING([if the compiler accepts ${flag}])
1032                                 ac_save_CFLAGS="$CFLAGS"
1033                                 CFLAGS="$CFLAGS ${flag}"
1034                                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
1035                                         [AC_MSG_RESULT([yes])],
1036                                         [AC_MSG_RESULT([no])
1037                                          CFLAGS="$ac_save_CFLAGS"
1038                                         ]
1039                                 )
1040                                 ;;
1041                 esac
1042         done
1043 fi
1044
1045 # font filename
1046 FONTFILENAME=${FONTFILENAME:-"default_font"}
1047 AC_SUBST(FONTFILENAME)
1048 AC_DEFINE_UNQUOTED(FONTFILENAME,"$FONTFILENAME",[File for default font])
1049
1050 # standard autoconf variables
1051 CPPFLAGS="$CPPFLAGS -DPREFIXDIR=\\\"\${prefix}\\\""
1052 CPPFLAGS="$CPPFLAGS -DBINDIR=\\\"\${bindir}\\\""
1053 CPPFLAGS="$CPPFLAGS -DHOST=\\\"\${host}\\\""
1054
1055 # directory for old-style library and for fonts
1056 PCBLIBDIR=${datadir}/pcb
1057 AC_SUBST(PCBLIBDIR)
1058 #AC_DEFINE_UNQUOTED(PCBLIBDIR,"$PCBLIBDIR",[Library directory])
1059 CPPFLAGS="$CPPFLAGS -DPCBLIBDIR=\\\"$PCBLIBDIR\\\""
1060
1061 # name for old-style library
1062 LIBRARYFILENAME=pcblib
1063 AC_SUBST(LIBRARYFILENAME)
1064 AC_DEFINE_UNQUOTED(LIBRARYFILENAME,"$LIBRARYFILENAME",[library file name])
1065
1066
1067 # directory for new library
1068 PCBTREEDIR=${datadir}/pcb/newlib
1069 PCBTREEPATH=${PCBTREEDIR}:${PCBLIBDIR}/pcblib-newlib
1070 PCBTREEDIR=${PCBTREEDIR:-"$PCBTREEDIR"}
1071 AC_SUBST(PCBTREEDIR)
1072 AC_SUBST(PCBTREEPATH)
1073 #AC_DEFINE_UNQUOTED(PCBTREEDIR,"$PCBLIB",[top directory for new style pcb library])
1074 CPPFLAGS="$CPPFLAGS -DPCBTREEDIR=\\\"$PCBTREEDIR\\\""
1075 CPPFLAGS="$CPPFLAGS -DPCBTREEPATH=\\\"$PCBTREEPATH\\\""
1076
1077 # Figure out relative paths
1078 AC_MSG_CHECKING([for the bindir to pcblibdir relative path])
1079 adl_COMPUTE_RELATIVE_PATHS([bindir:PCBLIBDIR:bindir_to_pcblibdir])
1080 adl_NORMALIZE_PATH([bindir_to_pcblibdir], [$PCB_DIR_SEPARATOR_S])
1081 AC_MSG_RESULT([$bindir_to_pcblibdir])
1082 AC_DEFINE_UNQUOTED(BINDIR_TO_PCBLIBDIR, "$bindir_to_pcblibdir", [Relative path from bindir to pcblibdir])
1083
1084 AC_MSG_CHECKING([for the bindir to pcbtreedir relative path])
1085 adl_COMPUTE_RELATIVE_PATHS([bindir:PCBTREEDIR:bindir_to_pcbtreedir])
1086 adl_NORMALIZE_PATH([bindir_to_pcbtreedir], [$PCB_DIR_SEPARATOR_S])
1087 AC_MSG_RESULT([$bindir_to_pcbtreedir])
1088 AC_DEFINE_UNQUOTED(BINDIR_TO_PCBTREEDIR, "$bindir_to_pcbtreedir", [Relative path from bindir to pcbtreedir])
1089
1090
1091 AC_MSG_CHECKING([for the bindir to exec_prefix relative path])
1092 adl_COMPUTE_RELATIVE_PATHS([bindir:exec_prefix:bindir_to_execprefix])
1093 adl_NORMALIZE_PATH([bindir_to_execprefix], [$PCB_DIR_SEPARATOR_S])
1094 AC_MSG_RESULT([$bindir_to_execprefix])
1095 AC_DEFINE_UNQUOTED(BINDIR_TO_EXECPREFIX, "$bindir_to_execprefix", [Relative path from bindir to exec_prefix])
1096
1097
1098 BTNMOD=${BTNMOD:-"Mod1"}
1099 AC_SUBST(BTNMOD)
1100
1101 TOPDIRS=
1102 for dir in src lib newlib doc example tools tutorial README_FILES
1103 do
1104    test -d $dir/. && TOPDIRS="$TOPDIRS $dir"
1105 done
1106 AC_SUBST(TOPDIRS)
1107
1108 AC_CONFIG_FILES(Makefile data/Makefile intl/Makefile po/Makefile.in)
1109
1110 if test -d $srcdir/README_FILES; then
1111    AC_CONFIG_FILES(README_FILES/Makefile)
1112 fi
1113 if test -d $srcdir/doc; then
1114    AC_CONFIG_FILES(doc/Makefile)
1115 fi
1116 if test -d $srcdir/doc/gs; then
1117    AC_CONFIG_FILES(doc/gs/Makefile)
1118    AC_CONFIG_FILES(doc/gs/gafrc)
1119    AC_CONFIG_FILES(doc/gs/gschemrc)
1120 fi
1121 if test -d $srcdir/example; then
1122    AC_CONFIG_FILES(example/Makefile)
1123    AC_CONFIG_FILES(example/libraries/Makefile)
1124 fi
1125 if test -d $srcdir/lib; then
1126    AC_CONFIG_FILES(lib/CreateLibraryContents.sh)
1127    AC_CONFIG_FILES(lib/CreateLibrary.sh)
1128    AC_CONFIG_FILES(lib/ListLibraryContents.sh)
1129    AC_CONFIG_FILES(lib/Makefile)
1130    AC_CONFIG_FILES(lib/QueryLibrary.sh)
1131    AC_CONFIG_FILES(lib/qfp-ui)
1132 fi
1133 if test -d $srcdir/newlib; then
1134    AC_CONFIG_FILES(newlib/2_pin_thru-hole_packages/Makefile)
1135    AC_CONFIG_FILES(newlib/Makefile)
1136    AC_CONFIG_FILES(newlib/connectors/Makefile)
1137    AC_CONFIG_FILES(newlib/crystal/Makefile)
1138    AC_CONFIG_FILES(newlib/electro-optics/Makefile)
1139    AC_CONFIG_FILES(newlib/headers/Makefile)
1140    AC_CONFIG_FILES(newlib/keystone/Makefile)
1141    AC_CONFIG_FILES(newlib/msp430/Makefile)
1142    AC_CONFIG_FILES(newlib/not_vetted_ingo/Makefile)
1143    AC_CONFIG_FILES(newlib/sockets/Makefile)
1144    AC_CONFIG_FILES(newlib/tests/Makefile)
1145 fi
1146 AC_CONFIG_FILES(src/Makefile)
1147 AC_CONFIG_FILES(src/icons/Makefile)
1148 if test -d $srcdir/tools; then
1149    AC_CONFIG_FILES(tools/Makefile)
1150 fi
1151 if test -d $srcdir/tutorial; then
1152    AC_CONFIG_FILES(tutorial/Makefile)
1153 fi
1154
1155 dnl testsuite
1156 AC_CONFIG_FILES(tests/inputs/Makefile)
1157 AC_CONFIG_FILES(tests/golden/Makefile)
1158 AC_CONFIG_FILES(tests/golden/hid_bom1/Makefile)
1159 AC_CONFIG_FILES(tests/golden/hid_bom2/Makefile)
1160 AC_CONFIG_FILES(tests/golden/hid_bom3/Makefile)
1161 AC_CONFIG_FILES(tests/golden/hid_bom4/Makefile)
1162 AC_CONFIG_FILES(tests/golden/hid_gcode1/Makefile)
1163 AC_CONFIG_FILES(tests/golden/hid_gcode2/Makefile)
1164 AC_CONFIG_FILES(tests/golden/hid_gcode3/Makefile)
1165 AC_CONFIG_FILES(tests/golden/hid_gcode4/Makefile)
1166 AC_CONFIG_FILES(tests/golden/hid_gcode5/Makefile)
1167 AC_CONFIG_FILES(tests/golden/hid_gcode6/Makefile)
1168 AC_CONFIG_FILES(tests/golden/hid_gcode7/Makefile)
1169 AC_CONFIG_FILES(tests/golden/hid_gcode8/Makefile)
1170 AC_CONFIG_FILES(tests/golden/hid_gcode9/Makefile)
1171 AC_CONFIG_FILES(tests/golden/hid_gcode10/Makefile)
1172 AC_CONFIG_FILES(tests/golden/hid_gcode11/Makefile)
1173 AC_CONFIG_FILES(tests/golden/hid_gerber1/Makefile)
1174 AC_CONFIG_FILES(tests/golden/hid_gerber2/Makefile)
1175 AC_CONFIG_FILES(tests/golden/hid_png1/Makefile)
1176 AC_CONFIG_FILES(tests/golden/hid_png2/Makefile)
1177 AC_CONFIG_FILES(tests/golden/hid_png3/Makefile)
1178 AC_CONFIG_FILES(tests/Makefile)
1179
1180 dnl win32 build scripts
1181 AC_CONFIG_FILES(win32/Makefile)
1182
1183 AC_OUTPUT
1184
1185 with_gui=`echo $with_gui`
1186 with_printer=`echo $with_printer`
1187 with_exporters=`echo $with_exporters | sed 's/,/ /g'`
1188
1189 expandedXDGDATADIR=`eval "echo $XDGDATADIR"`
1190 expandedKDEDATADIR=`eval "echo $KDEDATADIR"`
1191
1192 AC_MSG_RESULT([
1193 ** Configuration summary for $PACKAGE $VERSION:
1194
1195    GUI:                      $with_gui
1196    Printer:                  $with_printer
1197    Exporters:                $with_exporters
1198    Source tree distribution: $pcb_sources
1199    Build documentation:      $docs_yesno
1200    Build toporouter:         $enable_toporouter
1201    Enable toporouter output: $enable_toporouter_output
1202    xdg data directory:       $expandedXDGDATADIR
1203    KDE data directory:       $expandedKDEDATADIR
1204    dmalloc debugging:        $with_dmalloc
1205    ElectricFence debugging:  $with_efence
1206
1207    Cross Compiling:          $cross_compiling
1208    CC:                       $CC
1209    CPPFLAGS:                 $CPPFLAGS
1210    CFLAGS:                   $CFLAGS
1211    LIBS:                     $LIBS
1212    PCB:                      $PCB
1213
1214 ])