lib/common.m4

   1 divert(-1)
   2 #
   3 #                             COPYRIGHT
   4 #
   5 #   PCB, interactive printed circuit board design
   6 #   Copyright (C) 1994,1995,1996 Thomas Nau
   7 #
   8 #   This program is free software; you can redistribute it and/or modify
   9 #   it under the terms of the GNU General Public License as published by
  10 #   the Free Software Foundation; either version 2 of the License, or
  11 #   (at your option) any later version.
  12 #
  13 #   This program is distributed in the hope that it will be useful,
  14 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #   GNU General Public License for more details.
  17 #
  18 #   You should have received a copy of the GNU General Public License
  19 #   along with this program; if not, write to the Free Software
  20 #   Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  21 #
  22 #   Contact addresses for paper mail and Email:
  23 #   Thomas Nau, Schlehenweg 15, 88471 Baustetten, Germany
  24 #   Thomas.Nau@rz.uni-ulm.de
  25 #
  26 #   RCS: $Id$
  27 #
  28 # common defines for packages
  29 #
  30 # -------------------------------------------------------------------
  31 # create a single object
  32 # $1: mask name
  33 # $2: 'value' of the new object
  34 # $3: package of the circuit
  35 #
  36 define(`CreateObject',
  37         `ifdef(`PinList_$1', `DefinePinList(PinList_$1)')'
  38         `PKG_$3(`Description_$1', ,``$2'', Param1_$1, Param2_$1)'
  39 )
  40
  41 # this one is used to show the correct value for the footprint attribute
  42 # in a gschem (www.geda.seul.org) schematic.  See QueryLibrary.sh
  43 define(`QueryObject',
  44         `ifdef(`PinList_$1', `DefinePinList(PinList_$1)')'
  45 `$3 ifdef(`Param1_$1', `Param1_$1') ifdef(`Param2_$1', `Param2_$1')'
  46 )
  47
  48 # -------------------------------------------------------------------
  49 # define for-loops like the manual tells us
  50 #
  51 define(`forloop',
  52         `pushdef(`$1', `$2')_forloop(`$1', `$2', `$3', `$4')popdef(`$1')')
  53 define(`_forloop',
  54         `$4`'ifelse($1, `$3', ,
  55         `define(`$1', incr($1))_forloop(`$1', `$2', `$3', `$4')')')
  56
  57 # -------------------------------------------------------------------
  58 # the following definitions evaluate the list of pin-names
  59 # missing names will be defined as 'P_#'
  60 #
  61 # the first two arguments are skipped
  62 #
  63 define(`PIN', `Pin($1 $2 $3 $4 ifdef(`P_$5', "P_$5", "$5") ifelse($5, 1, 0x101, 0x01))')
  64 define(`PAD', `Pad($1 $2 $3 $4 $5 ifdef(`P_$6', "P_$6", "$6") ifelse($6, 1, 0x00, 0x100))')
  65
  66 define(`EDGECONN', `Pad($1 $2 $3 $4 $5 ifdef(`P_$6', "P_$6", "$6") "$6" $7)')
  67 define(`DEFPIN', `define(`count', incr(count))' `define(`P_'count, $1)')
  68 define(`DefinePinList', `ifelse($#, 1, ,
  69         `pushdef(`count')'
  70         `define(`count', 0)'
  71         `_DEFPINLIST($@)'
  72         `popdef(`count')')')
  73 define(`_DEFPINLIST', `ifelse($#, 0, , $#, 1, `DEFPIN(`$1')',
  74         `DEFPIN(`$1')'`
  75         _DEFPINLIST(shift($@))')')
  76
  77 define(`args',`
  78         ifelse($#, 0, , $#, 1,`define(`arg'cnt,`$1')',
  79         `define(`arg'cnt,`$1') define(`cnt',incr(cnt)) args(shift($@))')')
  80
  81 include(amp.inc)
  82 include(amphenol.inc)
  83 include(bga.inc)
  84 include(bourns.inc)
  85 include(candk.inc)
  86 include(connector.inc)
  87 include(cts.inc)
  88 include(dil.inc)
  89 include(geda.inc)
  90 include(johnstech.inc)
  91 include(minicircuits.inc)
  92 include(misc.inc)
  93 include(nichicon.inc)
  94 include(optek.inc)
  95 include(panasonic.inc)
  96 include(pci.inc)
  97 include(plcc.inc)
  98 include(qfn.inc)
  99 include(qfp.inc)
 100 include(qfp2.inc)
 101 include(qfpdj.inc)
 102 include(resistor_adjust.inc)
 103 include(rules.inc)
 104 include(smt.inc)
 105 include(to.inc)
 106 include(zif.inc)
 107
 108 # if any of these files exist, then include them.
 109 # this makes it a bit easier to configure pcb without
 110 # mucking with app-defaults every time you launch it
 111 sinclude(site-config.inc)
 112 sinclude(user-config.inc)
 113 sinclude(proj-config.inc)
 114
 115 divert(0)dnl