configure.ac

   1 dnl                                                      -*-Autoconf-*-
   2 dnl Process this file with autoconf to generate configure.
   3 dnl
   4 dnl The AX_* macros are defined in files in the top-level m4
   5 dnl directory.
   6
   7 #####################################################################
   8 # Set up configuration system
   9 #####################################################################
  10
  11 AC_INIT([gEDA Suite], [1.5.2], [geda-bug@seul.org], [gEDA])
  12 AC_PREREQ([2.60])
  13
  14 AC_CONFIG_SRCDIR([libgeda/src/libgeda.c])
  15 AC_CONFIG_AUX_DIR([build-tools])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADER([config.h])
  18
  19 AM_INIT_AUTOMAKE
  20
  21 AC_GNU_SOURCE # FIXME for some reason this is needed?
  22
  23 #####################################################################
  24 # Do version number magic
  25 #####################################################################
  26
  27 AX_GIT_VERSION([20090328])
  28
  29 # This is used for keeping the ChangeLog files up-to-date
  30 AC_SUBST([CHANGELOG_BASE], [1.0-20070526])
  31
  32 #####################################################################
  33 # Win32/MinGW support
  34 #####################################################################
  35
  36 # FIXME complete this
  37 AC_CANONICAL_HOST
  38
  39 #####################################################################
  40 # Check for compiling & linking tools
  41 #####################################################################
  42
  43 AC_PROG_CC
  44 AC_PROG_CPP
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AC_DISABLE_STATIC
  48 AC_PROG_LIBTOOL
  49
  50 AM_PROG_CC_C_O
  51 AX_GCC_FLAGS([-Wall])
  52
  53 AM_PROG_LEX
  54 AX_PROG_AWK
  55 AX_PROG_GROFF
  56
  57 #####################################################################
  58 # Internationalisation
  59 #####################################################################
  60
  61 AM_NLS
  62 AM_GNU_GETTEXT
  63 AM_GNU_GETTEXT_VERSION([0.16])
  64 AX_DESKTOP_I18N
  65
  66 #####################################################################
  67 # Check for libraries that use pkg-config
  68 #####################################################################
  69
  70 PKG_PROG_PKG_CONFIG
  71
  72 PKG_CHECK_MODULES(GUILE, [guile-1.8], ,
  73   AC_MSG_ERROR([Guile 1.8 or later is required.]))
  74
  75 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0], ,
  76   AC_MSG_ERROR([GLib 2.12.0 or later is required.]))
  77
  78 PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= 2.10.0], ,
  79   AC_MSG_ERROR([GTK+ 2.10.0 or later is required.]))
  80
  81 PKG_CHECK_MODULES(GDK_PIXBUF, [gdk-pixbuf-2.0 >= 0.15.0], ,
  82   AC_MSG_ERROR([GDK_PIXBUF 0.15.0 or later is required.]))
  83
  84 PKG_CHECK_MODULES(CAIRO, [cairo >= 1.2.0], ,
  85   AC_MSG_ERROR([CAIRO 1.2.0 or later is required.]))
  86
  87 #####################################################################
  88 # Header files & particular functions
  89 #####################################################################
  90
  91 AC_HEADER_SYS_WAIT
  92
  93 # FIXME these checks are obsolete, because every plausible platform
  94 # provides what they check for.
  95 AC_HEADER_STDC
  96 AC_HEADER_DIRENT
  97
  98 # FIXME these checks may be pointless for one of three reasons: every
  99 # even vaguely sane libc implementation provides them; we don't use
 100 # any of their functions in favour of GLib alternatives; or we don't
 101 # provide an alternative, so the build will fail anyway.
 102 AC_CHECK_HEADERS([stdlib.h string.h unistd.h])
 103
 104 # FIXME since we don't have a sensible alternative, if these headers
 105 # are missing we should fail. Also need to remove HAVE_ERRNO_H tests
 106 # in the C source code, since if we *don't* have it the build will
 107 # fail anyway.
 108 AC_CHECK_HEADERS([errno.h fcntl.h])
 109
 110 # Check for rint in math library. FIXME do we actually need to test
 111 # this? Should we use lrint instead?
 112 AC_CHECK_LIB([m], [lrint],
 113              AC_DEFINE([HAVE_LRINT], 1,
 114                        [If your math library has lrint in it, define this]))
 115
 116 AC_CHECK_FUNCS([chown getlogin])
 117
 118 # Check if the getopt header is present
 119 AC_CHECK_HEADERS([getopt.h])
 120 # Check for getopt_long
 121 # On FreeBSD the 'gnugetopt' library is needed.
 122 AC_SEARCH_LIBS([getopt_long], [gnugetopt],
 123                AC_DEFINE([HAVE_GETOPT_LONG], 1,
 124                          [Define to 1 if you have the `getopt_long' function.]))
 125
 126 # Check for misc features of awk
 127 AX_AWK_FEATURES
 128
 129 #####################################################################
 130 # Optional things
 131 #####################################################################
 132
 133 # Assertions
 134 AX_OPTION_ASSERT
 135 # API documentation
 136 AX_OPTION_DOXYGEN
 137 # XDG desktop files
 138 AX_OPTION_XDG_DATA
 139 # KDE 3 desktop files
 140 AX_OPTION_KDE3_DATA
 141 # XDG database updates
 142 AX_OPTION_XDG_DB
 143 # libstroke support
 144 AX_OPTION_STROKE
 145
 146 #####################################################################
 147 # Tool-specific setup
 148 #####################################################################
 149
 150 # Where should data files be installed/searched for?
 151 AX_DATA_DIRS
 152 # Where should PCB footprints be searched for?
 153 AX_PCB_DIRS
 154 # Set up libgeda with the correct ld version number
 155 AX_LIBGEDA([36:0:0])
 156
 157 #####################################################################
 158 # Generate output
 159 #####################################################################
 160
 161 AC_CONFIG_FILES([Makefile
 162                  intl/Makefile
 163
 164                  libgeda/Makefile
 165                  libgeda/libgeda.pc
 166                  libgeda/po/domain.mak
 167                  libgeda/po/Makefile.in
 168                  libgeda/data/Makefile
 169                  libgeda/docs/Makefile
 170                  libgeda/include/Makefile
 171                  libgeda/lib/Makefile
 172                  libgeda/scheme/Makefile
 173                  libgeda/share/Makefile
 174                  libgeda/src/Makefile
 175
 176                  gschem/Makefile
 177                  gschem/po/Makefile.in
 178                  gschem/docs/Makefile
 179                  gschem/include/Makefile
 180                  gschem/scripts/Makefile
 181                  gschem/src/Makefile
 182                  gschem/examples/Makefile
 183                  gschem/lib/Makefile
 184                  gschem/lib/system-gschemrc
 185                  gschem/data/Makefile
 186                  gschem/bitmap/Makefile
 187                  gschem/tests/Makefile
 188                  gschem/scheme/Makefile
 189
 190                  gattrib/Makefile
 191                  gattrib/po/Makefile.in
 192                  gattrib/design/Makefile
 193                  gattrib/docs/Makefile
 194                  gattrib/include/Makefile
 195                  gattrib/lib/Makefile
 196                  gattrib/lib/system-gattribrc
 197                  gattrib/src/Makefile
 198                  gattrib/data/Makefile
 199
 200                  gsymcheck/docs/Makefile
 201                  gsymcheck/include/Makefile
 202                  gsymcheck/lib/Makefile
 203                  gsymcheck/lib/system-gsymcheckrc
 204                  gsymcheck/src/Makefile
 205                  gsymcheck/tests/Makefile
 206                  gsymcheck/Makefile
 207
 208                  gnetlist/Makefile
 209                  gnetlist/src/Makefile
 210                  gnetlist/include/Makefile
 211                  gnetlist/scheme/Makefile
 212                  gnetlist/examples/Makefile
 213                  gnetlist/tests/Makefile
 214                  gnetlist/tests/hierarchy/Makefile
 215                  gnetlist/tests/hierarchy2/Makefile
 216                  gnetlist/tests/drc2/Makefile
 217                  gnetlist/tests/common/Makefile
 218                  gnetlist/docs/Makefile
 219                  gnetlist/docs/vams/Makefile
 220                  gnetlist/examples/vams/Makefile
 221                  gnetlist/examples/vams/vhdl/Makefile
 222                  gnetlist/examples/vams/vhdl/basic-vhdl/Makefile
 223                  gnetlist/examples/vams/vhdl/new-vhdl/Makefile
 224                  gnetlist/examples/switcap/Makefile
 225                  gnetlist/lib/Makefile
 226                  gnetlist/utils/Makefile
 227                  gnetlist/scripts/Makefile
 228                  gnetlist/scripts/annotate.sh
 229                  gnetlist/scripts/bom_xref.sh
 230                  gnetlist/scripts/bompp.sh
 231                  gnetlist/scripts/sw2asc
 232                  gnetlist/lib/system-gnetlistrc
 233
 234                  utils/Makefile
 235                  utils/docs/Makefile
 236                  utils/examples/Makefile
 237                  utils/examples/gmk_sym/Makefile
 238                  utils/examples/gsch2pcb/Makefile
 239                  utils/examples/tragesym/Makefile
 240                  utils/gschlas/Makefile
 241                  utils/gxyrs/Makefile
 242                  utils/include/Makefile
 243                  utils/lib/Makefile
 244                  utils/lib/system-gschlasrc
 245                  utils/man/Makefile
 246                  utils/scripts/Makefile
 247                  utils/src/Makefile
 248                  utils/tests/Makefile
 249                  utils/tests/gxyrs/Makefile
 250                  utils/tests/gxyrs/inputs/Makefile
 251                  utils/tests/gxyrs/outputs/Makefile
 252                  utils/tests/refdes_renum/Makefile
 253                  utils/tests/refdes_renum/inputs/Makefile
 254                  utils/tests/refdes_renum/outputs/Makefile
 255
 256                  symbols/Makefile
 257                  symbols/documentation/Makefile
 258
 259                  docs/Makefile
 260                  docs/scripts/Makefile
 261                  docs/toplevel/Makefile
 262                  docs/toplevel/gedadocs.html
 263                  docs/wiki/Makefile
 264                  docs/wiki/_detail/Makefile
 265                  docs/wiki/_media/Makefile
 266                  docs/wiki/lib/Makefile
 267                  docs/wiki/lib/exe/Makefile
 268                  docs/wiki/lib/images/Makefile
 269                  docs/wiki/lib/images/fileicons/Makefile
 270                  docs/wiki/lib/images/interwiki/Makefile
 271                  docs/wiki/lib/images/smileys/Makefile
 272                  docs/wiki/lib/plugins/Makefile
 273                  docs/wiki/lib/plugins/definitionlist/Makefile
 274                  docs/wiki/lib/plugins/definitionlist/images/Makefile
 275                  docs/wiki/lib/plugins/note/Makefile
 276                  docs/wiki/lib/plugins/note/images/Makefile
 277                  docs/wiki/lib/tpl/Makefile
 278                  docs/wiki/lib/tpl/geda/Makefile
 279                  docs/wiki/lib/tpl/geda/images/Makefile
 280
 281                  examples/Makefile
 282                  examples/RF_Amp/Makefile
 283                  examples/RF_Amp/model/Makefile
 284                  examples/RF_Amp/sym/Makefile
 285                  examples/TwoStageAmp/Makefile
 286                  examples/gTAG/Makefile
 287                  examples/lightning_detector/Makefile
 288 ])
 289 AC_OUTPUT